configure.ac

   1 dnl #############################################################
   2 dnl #
   3 dnl #  For information about autoconf, see:
   4 dnl #
   5 dnl #  http://www.gnu.org/software/autoconf/
   6 dnl #
   7 dnl #  The recommended order is:
   8 dnl #
   9 dnl #  AC_INIT(file)
  10 dnl #  0. checks for compiler, libtool, and command line options
  11 dnl #  1. checks for programs
  12 dnl #  2. checks for libraries
  13 dnl #  3. checks for header files
  14 dnl #  4. checks for typedefs
  15 dnl #  5. checks for structures and functions
  16 dnl #  6. checks for compiler characteristics
  17 dnl #  7. checks for library functions
  18 dnl #  8. checks for system services
  19 dnl #  AC_OUTPUT([file...])
  20 dnl #
  21 dnl #############################################################
  22
  23 AC_PREREQ([2.59])
  24 export CFLAGS LIBS LDFLAGS CPPFLAGS
  25
  26 AC_INIT([freeradius],[$]Id[$],[http://bugs.freeradius.org],,[http://www.freeradius.org])
  27 AC_CONFIG_SRCDIR([src/main/radiusd.c])
  28 AC_CONFIG_HEADER([src/include/autoconf.h])
  29 m4_include([m4/ax_cc.m4])
  30
  31 dnl #############################################################
  32 dnl #
  33 dnl #  Custom hackery to discover version at configure time
  34 dnl #
  35 dnl #############################################################
  36 RADIUSD_MAJOR_VERSION=`cat VERSION | cut -f1 -d.`
  37 RADIUSD_MINOR_VERSION=`cat VERSION | cut -f2 -d.`
  38 RADIUSD_INCRM_VERSION=`cat VERSION | cut -f3 -d. | sed 's/[[\.-]].*$//'`
  39
  40 RADIUSD_VERSION=`printf "%02i%02i%02i" $RADIUSD_MAJOR_VERSION $RADIUSD_MINOR_VERSION $RADIUSD_INCRM_VERSION`
  41
  42 dnl #
  43 dnl #  Still useful for custom builds
  44 dnl #
  45 RADIUSD_VERSION_STRING=`cat VERSION`
  46
  47 dnl #
  48 dnl #  Add definitions to Make.inc as it's used by various build targets
  49 dnl #
  50 AC_SUBST([RADIUSD_VERSION_STRING])
  51
  52 dnl #
  53 dnl #  Add definitions to autoconf.h, so that the headers that we install
  54 dnl #  contain the version number of the server.
  55 dnl #
  56 AC_DEFINE_UNQUOTED([RADIUSD_VERSION], [${RADIUSD_VERSION}], [Version integer in format <ma><ma><mi><mi><in><in>])
  57 AC_DEFINE_UNQUOTED([RADIUSD_VERSION_STRING], ["${RADIUSD_VERSION_STRING}"], [Raw version string from VERSION file])
  58
  59 dnl #############################################################
  60 dnl #
  61 dnl #  Override some of the default autoconf variables such as
  62 dnl #  CFLAGS if were building in developer mode
  63 dnl #
  64 dnl #############################################################
  65
  66 dnl #
  67 dnl #  Enable developer features like debugging symbols.
  68 dnl #  These checks must be done before expanding the AC_PROG_CC
  69 dnl #  and AC_PROG_CXX macros.
  70 dnl #
  71 AC_ARG_ENABLE(developer,
  72 [  --enable-developer      enables features of interest to developers.],
  73 [ case "$enableval" in
  74   no)
  75     developer=no
  76     ;;
  77   *)
  78     developer=yes
  79   esac ]
  80 )
  81
  82 dnl #
  83 dnl #  Turn on the developer flag when taken from a git checkout (not a release)
  84 dnl #
  85 if test -d $srcdir/.git; then
  86   if test "x$developer" != "xno"; then
  87     AC_MSG_NOTICE([found .git directory, enabling developer build implicitly, disable with --disable-developer])
  88     developer="yes"
  89   fi
  90 fi
  91
  92 dnl #
  93 dnl #  Autoconf sets -O2 and -g by default, but this is a PITA for debugging
  94 dnl #  so we remove the defaults if were building in developer mode, and set
  95 dnl #  -g3 so nice things like macro values are included. Other arguments are
  96 dnl #  added later when we know what compiler were using.
  97 dnl #
  98 if test "x$developer" = "xyes"; then
  99   : ${CFLAGS=-g3}
 100 fi
 101
 102 dnl #############################################################
 103 dnl #
 104 dnl #  0. Checks for compiler, libtool, and command line options.
 105 dnl #
 106 dnl #############################################################
 107
 108 dnl #
 109 dnl #  Get system information
 110 dnl #
 111 AC_CANONICAL_SYSTEM
 112
 113 dnl #
 114 dnl #  Check for GNU cc
 115 dnl #
 116 AC_PROG_CC
 117 AC_PROG_CXX
 118
 119 dnl #
 120 dnl #  check for AIX, to allow us to use some BSD functions
 121 dnl #  must be before macros that call the compiler.
 122 dnl #
 123 AC_AIX
 124
 125 AC_PROG_GCC_TRADITIONAL
 126 AC_PROG_CC_SUNPRO
 127 AC_PROG_RANLIB
 128
 129 dnl #
 130 dnl #  Definitive check for whether the compiler is clang
 131 dnl #
 132 AX_CC_IS_CLANG
 133 if test "x$ax_cv_cc_clang" = "xyes"; then
 134   AC_SUBST(clang_path, "$CC")
 135 else
 136   AC_SUBST(clang_path, "")
 137 fi
 138
 139
 140 dnl #
 141 dnl #  Set Default CFLAGS for GCC compatible compilers
 142 dnl #
 143 if test "x$GCC" = "xyes"; then
 144   CFLAGS="$CFLAGS -Wall -std=c99 -D_GNU_SOURCE"
 145 fi
 146
 147 dnl #
 148 dnl #  -Qunused-arguments means the compiler won't complain about unsupported arguments
 149 dnl #
 150 AX_CC_QUNUSED_ARGUMENTS_FLAG
 151 if test "x$ax_cv_cc_qunused_arguments_flag" = "xyes"; then
 152   CFLAGS="$CFLAGS -Qunused-arguments"
 153   LDFLAGS="$LDFLAGS -Qunused-arguments"
 154 fi
 155
 156 dnl #
 157 dnl #  Compile in large (2G+) file support.
 158 dnl #
 159 AC_SYS_LARGEFILE
 160
 161 dnl #
 162 dnl #  check for system bytesex
 163 dnl #  AC_DEFINES WORDS_BIGENDIAN
 164 dnl #
 165 AC_C_BIGENDIAN(
 166   [AC_DEFINE(FR_BIG_ENDIAN, 1, [Define if your processor stores words with the most significant byte first])],
 167   [AC_DEFINE(FR_LITTLE_ENDIAN, 1, [Define if your processor stores words with the least significant byte first])]
 168 )
 169
 170 dnl #
 171 dnl #  Find GNU Make.
 172 dnl #
 173 AC_CHECK_PROG(GMAKE, gmake, yes, no)
 174 if test $GMAKE = no; then
 175   AC_PATH_PROG(MAKE, make, /usr/local/bin/make)
 176 else
 177   AC_PATH_PROG(MAKE, gmake, /usr/local/gnu/bin/make)
 178 fi
 179 makever=`$ac_cv_path_MAKE --version 2>&1 | grep "GNU Make"`
 180 if test -z "$makever"; then
 181   AC_MSG_ERROR([GNU Make is not installed.  Please download and install it from ftp://prep.ai.mit.edu/pub/gnu/make/ before continuing.])
 182 fi
 183
 184 dnl #
 185 dnl #  autoconf explicitly sets MAKEFLAGS and MFLAGS to '' even though we
 186 dnl #  didn't tell it to, so we have to use FR_MAKEFLAGS.
 187 dnl #
 188 dnl #  determine the number of cores available and set the number of build
 189 dnl #  processes appropriately.
 190 dnl #
 191 AX_SYSTEM_CORES
 192
 193 dnl #  Temporarily disabled because test and installation targets do not
 194 dnl #  have dependencies set up correctly for multiple build processes.
 195 dnl if test "x$ax_cv_system_cores" != "x"; then
 196 dnl  : ${FR_MAKEFLAGS=-j$ax_cv_system_cores}
 197 dnl fi
 198 AC_SUBST(FR_MAKEFLAGS)
 199
 200 dnl #
 201 dnl #  See if we have Git.
 202 dnl #
 203 AC_CHECK_PROG(GIT, git, yes, no)
 204
 205 dnl Put this in later, when all distributed modules use autoconf.
 206 dnl AC_ARG_WITH(disablemodulefoo,
 207 dnl [  --without-rlm_foo         Disables module compilation.  Module list:]
 208 dnl esyscmd([find src/modules -type d -name rlm_\* -print |\
 209 dnl   sed -e 's%src/modules/.*/% (sub)- %; s%.*/%- %' |\
 210 dnl   awk '{print "                            "$0}']))
 211
 212 AC_ARG_ENABLE(strict-dependencies,
 213 [  --enable-strict-dependencies  fail configure on lack of module dependancy.])
 214
 215 AC_ARG_ENABLE(werror,
 216 [  --enable-werror         causes the build to fail if any warnings are generated.],
 217 [ case "$enableval" in
 218     no)
 219       werror=no
 220     ;;
 221     *)
 222       werror=yes
 223   esac ]
 224 )
 225
 226 dnl #
 227 dnl #  extra argument: --with-docdir
 228 dnl #
 229 docdir='${datadir}/doc/freeradius'
 230 AC_MSG_CHECKING([docdir])
 231 AC_ARG_WITH(docdir,
 232 [  --with-docdir=DIR       directory for documentation [DATADIR/doc/freeradius] ],
 233 [ case "$withval" in
 234   no)
 235     docdir=no
 236     ;;
 237   yes)
 238     ;;
 239   [[\\/$]]* | ?:[[\\/]]* )
 240     docdir="$withval"
 241     ;;
 242   *)
 243     AC_MSG_ERROR([expected an absolute directory name for --with-docdir: $withval])
 244     ;;
 245   esac ]
 246 )
 247 AC_SUBST(docdir)
 248 AC_MSG_RESULT($docdir)
 249 if test "x$docdir" = xno; then
 250   AC_MSG_WARN([Documentation files will NOT be installed.])
 251 fi
 252
 253 dnl #
 254 dnl #  extra argument: --with-logdir
 255 dnl #
 256 logdir='${localstatedir}/log/radius'
 257 AC_MSG_CHECKING(logdir)
 258 AC_ARG_WITH(logdir,
 259 [  --with-logdir=DIR       directory for logfiles [LOCALSTATEDIR/log/radius] ],
 260 [ case "$withval" in
 261   no)
 262     AC_MSG_ERROR([Need logdir])
 263     ;;
 264   yes)
 265     ;;
 266   [[\\/$]]* | ?:[[\\/]]* )
 267     logdir="$withval"
 268     ;;
 269   *)
 270     AC_MSG_ERROR([expected an absolute directory name for --with-logdir: $withval])
 271     ;;
 272   esac ]
 273 )
 274 AC_SUBST(logdir)
 275 AC_MSG_RESULT($logdir)
 276
 277 dnl #
 278 dnl #  extra argument: --with-radacctdir
 279 dnl #
 280 radacctdir='${logdir}/radacct'
 281 AC_MSG_CHECKING(radacctdir)
 282 AC_ARG_WITH(radacctdir,
 283 [  --with-radacctdir=DIR   directory for detail files [LOGDIR/radacct] ],
 284 [ case "$withval" in
 285   no)
 286     AC_MSG_ERROR([Need radacctdir])
 287     ;;
 288   yes)
 289     ;;
 290   [[\\/$]]* | ?:[[\\/]]* )
 291     radacctdir="$withval"
 292     ;;
 293   *)
 294     AC_MSG_ERROR([expected an absolute directory name for --with-radacctdir: $withval])
 295     ;;
 296   esac ]
 297 )
 298 AC_SUBST(radacctdir)
 299 AC_MSG_RESULT($radacctdir)
 300
 301 dnl #
 302 dnl #  extra argument: --with-raddbdir
 303 dnl #
 304 raddbdir='${sysconfdir}/raddb'
 305 AC_MSG_CHECKING(raddbdir)
 306 AC_ARG_WITH(raddbdir,
 307 [  --with-raddbdir=DIR     directory for config files [SYSCONFDIR/raddb] ],
 308 [ case "$withval" in
 309   no)
 310     AC_MSG_ERROR([Need raddbdir])
 311     ;;
 312   yes)
 313     ;;
 314   [[\\/$]]* | ?:[[\\/]]* )
 315     raddbdir="$withval"
 316     ;;
 317   *)
 318     AC_MSG_ERROR([expected an absolute directory name for --with-raddbdir: $withval])
 319     ;;
 320   esac ]
 321 )
 322 AC_SUBST(raddbdir)
 323 AC_MSG_RESULT($raddbdir)
 324
 325 dnl #
 326 dnl #  extra argument: --with-dictdir
 327 dnl #
 328 dictdir='${datarootdir}/freeradius'
 329 AC_MSG_CHECKING(dictdir)
 330 AC_ARG_WITH(dictdir,
 331 [  --with-dictdir=DIR      directory for dictionary files [DATAROOTDIR/freeradius] ],
 332 [ case "$withval" in
 333   no)
 334     AC_MSG_ERROR([Need dictdir])
 335     ;;
 336   yes)
 337     ;;
 338   [[\\/$]]* | ?:[[\\/]]* )
 339     dictdir="$withval"
 340     ;;
 341   *)
 342     AC_MSG_ERROR([expected an absolute directory name for --with-dictdir: $withval])
 343     ;;
 344   esac ]
 345 )
 346 AC_SUBST(dictdir)
 347 AC_MSG_RESULT($dictdir)
 348
 349 modconfdir='${raddbdir}/mods-config'
 350 AC_SUBST(modconfdir)
 351
 352 dnl #
 353 dnl #  extra argument: --with-ascend-binary
 354 dnl #
 355 WITH_ASCEND_BINARY=yes
 356 AC_ARG_WITH(ascend-binary,
 357 [  --with-ascend-binary    include support for Ascend binary filter attributes (default=yes)],
 358 [ case "$withval" in
 359   yes)
 360     ;;
 361   *)
 362     WITH_ASCEND_BINARY=no
 363   esac ]
 364 )
 365 if test "x$WITH_ASCEND_BINARY" = "xyes"; then
 366   AC_DEFINE(WITH_ASCEND_BINARY, [1], [include support for Ascend binary filter attributes])
 367 fi
 368
 369 dnl #
 370 dnl #  extra argument: --with-threads
 371 dnl #
 372 WITH_THREADS=yes
 373 AC_ARG_WITH(threads,
 374 [  --with-threads          use threads, if available.  (default=yes) ],
 375 [ case "$withval" in
 376   yes)
 377     ;;
 378   *)
 379     WITH_THREADS=no
 380   esac ]
 381 )
 382
 383 dnl #
 384 dnl #  extra argument: --with-tcp
 385 dnl #
 386 WITH_TCP=yes
 387 AC_ARG_WITH(tcp,
 388 [  --with-tcp              compile in TCP support. (default=yes)],
 389 [ case "$withval" in
 390   yes)
 391     ;;
 392   *)
 393     WITH_TCP=no
 394   esac ]
 395 )
 396 if test "x$WITH_TCP" = "xyes"; then
 397   AC_DEFINE(WITH_TCP, [1], [define if you want TCP support (For RADSec et al)])
 398 fi
 399
 400 dnl #
 401 dnl #  extra argument: --with-vmps
 402 dnl #
 403 WITH_VMPS=yes
 404 AC_ARG_WITH(vmps,
 405 [  --with-vmps             compile in VMPS support. (default=yes)],
 406 [ case "$withval" in
 407   yes)
 408     ;;
 409   *)
 410     WITH_VMPS=no
 411   esac ]
 412 )
 413 if test "x$WITH_VMPS" = "xyes"; then
 414   AC_DEFINE(WITH_VMPS, [1], [define if you want VMPS support])
 415 fi
 416
 417 dnl #
 418 dnl #  extra argument: --with-dhcp
 419 dnl #
 420 WITH_DHCP=yes
 421 AC_ARG_WITH(dhcp,
 422 [  --with-dhcp             compile in DHCP support. (default=yes)],
 423 [ case "$withval" in
 424   yes)
 425     ;;
 426   *)
 427     WITH_DHCP=no
 428   esac ]
 429 )
 430 if test "x$WITH_DHCP" = "xyes"; then
 431   AC_DEFINE(WITH_DHCP, [1], [define if you want DHCP support])
 432 fi
 433
 434 dnl #
 435 dnl #  Allow the user to specify a list of modules to be linked
 436 dnl #  statically to the server.
 437 dnl #
 438 STATIC_MODULES=
 439 AC_ARG_WITH(static_modules,
 440 [  --with-static-modules=QUOTED-MODULE-LIST],[
 441   for i in $withval; do
 442     STATIC_MODULES="$STATIC_MODULES -dlpreopen ../modules/rlm_$i/rlm_$i.la"
 443   done
 444 ])
 445
 446 USE_SHARED_LIBS=yes
 447 AC_ARG_WITH(shared-libs,
 448 [AS_HELP_STRING([--with-shared-libs ],
 449 [build dynamic libraries and link against them. (default=yes)])],
 450 [ case "$withval" in
 451   no)
 452     USE_SHARED_LIBS=no
 453     ;;
 454   *)
 455   esac
 456 ])
 457
 458 MODULES=
 459 AC_ARG_WITH(modules,
 460 [  --with-modules=QUOTED-MODULE-LIST],[
 461  for i in $withval; do
 462    MODULES="$MODULES $i"
 463  done
 464 ])
 465
 466 dnl #
 467 dnl #  extra argument: --with-experimental-modules
 468 dnl #
 469 EXPERIMENTAL=
 470 AC_ARG_WITH(experimental-modules,
 471 [AS_HELP_STRING([--with-experimental-modules],
 472 [use experimental and unstable modules. (default=no, unless --enable-developer=yes)])],
 473 [ case "$withval" in
 474   yes)
 475     EXPERIMENTAL=yes
 476     ;;
 477   no)
 478     EXPERIMENTAL=no
 479     ;;
 480   *)
 481   esac ]
 482 )
 483
 484 dnl #
 485 dnl #  extra argument: --with-udpfromto
 486 dnl #
 487 WITH_UDPFROMTO=yes
 488 AC_ARG_WITH(udpfromto,
 489 [  --with-udpfromto        compile in UDPFROMTO support. (default=yes)],
 490 [ case "$withval" in
 491   yes)
 492     WITH_UDPFROMTO=yes
 493     ;;
 494   *)
 495     WITH_UDPFROMTO=no
 496   esac ]
 497 )
 498
 499 if test "x$WITH_UDPFROMTO" = "xyes"; then
 500   AC_DEFINE(WITH_UDPFROMTO, [], [define if you want udpfromto])
 501 fi
 502
 503 dnl #
 504 dnl #  These next two arguments don't actually do anything.  They're
 505 dnl #  place holders so that the top-level configure script can tell
 506 dnl #  the user how to configure lower-level modules
 507 dnl #
 508
 509 dnl #
 510 dnl #  extra argument: --with-rlm-FOO-lib-dir
 511 dnl #
 512 AC_ARG_WITH(rlm-FOO-lib-dir,
 513 [AS_HELP_STRING([--with-rlm-FOO-lib-dir=DIR],
 514 [directory in which to look for library files used by module FOO])],
 515 [ case "$withval" in
 516   *)
 517     ;;
 518   esac ]
 519 )
 520
 521 dnl #
 522 dnl #  extra argument: --with-rlm-FOO-include-dir
 523 dnl #
 524 AC_ARG_WITH(rlm-FOO-include-dir,
 525 [AS_HELP_STRING([--with-rlm-FOO-include-dir=DIR],
 526 [directory in which to look for include files used by module FOO])],
 527 [ case "$withval" in
 528   *)
 529     ;;
 530   esac ]
 531 )
 532
 533 dnl #
 534 dnl #  extra argument: --with-openssl
 535 dnl #
 536 WITH_OPENSSL=yes
 537 AC_ARG_WITH(openssl,
 538 [  --with-openssl          use OpenSSL. (default=yes)],
 539 [ case "$withval" in
 540   no)
 541     WITH_OPENSSL=no
 542     ;;
 543   *)
 544     WITH_OPENSSL=yes
 545     ;;
 546   esac ]
 547 )
 548
 549 dnl #
 550 dnl #  extra argument: --with-openssl-lib-dir=dir
 551 dnl #
 552 openssl_lib_dir=
 553 AC_ARG_WITH(openssl-lib-dir,
 554 [AS_HELP_STRING([--with-openssl-lib-dir=DIR],
 555 [directory to look for OpenSSL library files])],
 556 [ case "$withval" in
 557   *) openssl_lib_dir="$withval"
 558     ;;
 559   esac ]
 560 )
 561
 562 dnl #
 563 dnl #  extra argument: --with-openssl-includes=dir
 564 dnl #
 565 openssl_include_dir=
 566 AC_ARG_WITH(openssl-include-dir,
 567 [AS_HELP_STRING([--with-openssl-include-dir=DIR],
 568 [directory to look for OpenSSL include files])],
 569 [ case "$withval" in
 570   *) openssl_include_dir="$withval"
 571     ;;
 572   esac ]
 573 )
 574
 575 dnl #
 576 dnl #  extra argument: --disable-openssl-version-check
 577 dnl #
 578 AC_ARG_ENABLE(openssl-version-check,
 579 [AS_HELP_STRING([--disable-openssl-version-check],
 580                 [disable vulnerable OpenSSL version check])]
 581 )
 582 if test "x$enable_openssl_version_check" != "xno"; then
 583   AC_DEFINE(ENABLE_OPENSSL_VERSION_CHECK, [1],
 584             [Define to 1 to have OpenSSL version check enabled])
 585   openssl_version_check_config="\
 586         #
 587         #  allow_vulnerable_openssl: Allow the server to start with
 588         #  versions of OpenSSL known to have critical vulnerabilities.
 589         #
 590         #  This check is based on the version number reported by libssl
 591         #  and may not reflect patches applied to libssl by
 592         #  distribution maintainers.
 593         #
 594         allow_vulnerable_openssl = no"
 595 else
 596   openssl_version_check_config=
 597 fi
 598 AC_SUBST([openssl_version_check_config])
 599
 600
 601 dnl #############################################################
 602 dnl #
 603 dnl #  1. Checks for programs
 604 dnl #
 605 dnl #############################################################
 606
 607 CHECKRAD=checkrad
 608 AC_PATH_PROG(PERL, perl, /usr/local/bin/perl)
 609 if test "x$ac_cv_path_PERL" = "x"; then
 610   AC_MSG_WARN([perl not found - Simultaneous-Use and checkrad may not work])
 611 fi
 612 AC_PATH_PROG(SNMPGET, snmpget)
 613 if test "x$ac_cv_path_SNMPGET" = "x"; then
 614   AC_MSG_WARN([snmpget not found - Simultaneous-Use and checkrad may not work])
 615 fi
 616
 617 AC_PATH_PROG(SNMPWALK, snmpwalk)
 618 if test "x$ac_cv_path_SNMPWALK" = "x"; then
 619   AC_MSG_WARN([snmpwalk not found - Simultaneous-Use and checkrad may not work])
 620 fi
 621
 622 AC_PATH_PROG(RUSERS, rusers, /usr/bin/rusers)
 623
 624 dnl #
 625 dnl #  FIXME This is truly gross.
 626 dnl #
 627 missing_dir=`cd $ac_aux_dir && pwd`
 628 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
 629 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
 630 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
 631
 632 AC_PATH_PROG(LOCATE,locate)
 633 AC_PATH_PROG(DIRNAME,dirname)
 634 AC_PATH_PROG(GREP,grep)
 635
 636 dnl #############################################################
 637 dnl #
 638 dnl #  2. Checks for libraries
 639 dnl #
 640 dnl #############################################################
 641
 642 dnl Check for talloc
 643 dnl extra argument: --with-talloc-lib-dir=DIR
 644 talloc_lib_dir=
 645 AC_ARG_WITH(talloc-lib-dir,
 646   [AS_HELP_STRING([--with-talloc-lib-dir=DIR],
 647   [directory in which to look for talloc library files])],
 648   [case "$withval" in
 649     no)
 650       AC_MSG_ERROR([Need talloc-lib-dir])
 651       ;;
 652     yes)
 653       ;;
 654     *)
 655       talloc_lib_dir="$withval"
 656       ;;
 657   esac])
 658
 659 dnl extra argument: --with-talloc-include-dir=DIR
 660 talloc_include_dir=
 661 AC_ARG_WITH(talloc-include-dir,
 662   [AS_HELP_STRING([--with-talloc-include-dir=DIR],
 663   [directory in which to look for talloc include files])],
 664   [case "$withval" in
 665     no)
 666       AC_MSG_ERROR([Need talloc-include-dir])
 667       ;;
 668     yes)
 669       ;;
 670     *)
 671       talloc_include_dir="$withval"
 672       ;;
 673   esac])
 674
 675 smart_try_dir="$talloc_lib_dir"
 676 FR_SMART_CHECK_LIB(talloc, _talloc)
 677 if test "x$ac_cv_lib_talloc__talloc" != "xyes"; then
 678   AC_MSG_WARN([talloc library not found. Use --with-talloc-lib-dir=<path>.])
 679   AC_MSG_ERROR([FreeRADIUS requires libtalloc])
 680 fi
 681
 682 TALLOC_LIBS="${smart_lib}"
 683 TALLOC_LDFLAGS="${smart_ldflags}"
 684 AC_SUBST(TALLOC_LIBS)
 685 AC_SUBST(TALLOC_LDFLAGS)
 686 LIBS="$old_LIBS"
 687
 688 dnl #
 689 dnl #  If using pthreads, check for -lpthread (posix) or -lc_r (*BSD)
 690 dnl #
 691 old_CFLAGS=$CFLAGS
 692 if test "x$WITH_THREADS" = "xyes"; then
 693   if test $ac_cv_prog_suncc = "yes"; then
 694     CFLAGS="$CFLAGS -mt"
 695   fi
 696
 697   AC_CHECK_HEADERS(pthread.h, [],
 698     [
 699       WITH_THREADS="no"
 700       fail=[pthread.h]
 701     ])
 702
 703   dnl #
 704   dnl #  pthread stuff is usually in -lpthread
 705   dnl #  or in -lc_r, on *BSD
 706   dnl #
 707   dnl #  On Some systems, we need extra pre-processor flags, to get them to
 708   dnl #  to do the threading properly.
 709   dnl #
 710   if test "x$WITH_THREADS" != "xno"; then
 711     AC_CHECK_LIB(pthread, pthread_create,
 712       [
 713         HAVE_LPTHREAD='yes'
 714         CFLAGS="$CFLAGS -D_REENTRANT -D_POSIX_PTHREAD_SEMANTICS"
 715         LIBS="-lpthread $LIBS"
 716
 717         dnl #
 718         dnl #  -pthread should add all required CPP definitions and linker
 719         dnl #  arguments. But not all compilers support it, or some compilers
 720         dnl #  only support it on certain platforms.
 721         dnl #
 722         AX_CC_PTHREAD_FLAG
 723         if test "x$ax_cv_cc_pthread_flag" != 'xyes'; then
 724           CFLAGS="$CFLAGS -pthread"
 725         fi
 726       ]
 727     )
 728
 729     dnl #
 730     dnl #  Check for libc_r which used to be the threading library used
 731     dnl #  for FreeBSD. Internet says it may be deprecated, but if we
 732     dnl #  can't find lpthread it's probably worth checking.
 733     dnl #
 734     if test "x$HAVE_LPTHREAD" != "xyes"; then
 735       AC_CHECK_LIB(c_r, pthread_create,
 736         [
 737           CFLAGS="$CFLAGS -D_THREAD_SAFE"
 738
 739           dnl #
 740           dnl #  -pthread should add all required CPP definitions and linker
 741           dnl #  arguments. But not all compilers support it, or some compilers
 742           dnl #  only support it on certain platforms.
 743           dnl #
 744           AX_CC_PTHREAD_FLAG
 745           if test "x$ax_cv_cc_pthread_flag" != 'xyes'; then
 746             LIBS="-lc_r $LIBS"
 747           else
 748             CFLAGS="$CFLAGS -pthread"
 749           fi
 750         ],
 751         [ fail=[-lc_r or -lpthread] ]
 752       )
 753     fi
 754   fi
 755
 756   if test "x$WITH_THREADS" != "xyes"; then
 757     AC_MSG_WARN([silently not building with thread support.])
 758     AC_MSG_WARN([FAILURE: thread support requires: $fail.])
 759   else
 760     AC_DEFINE(WITH_THREADS, [1], [define if you want thread support])
 761   fi
 762 fi
 763
 764 dnl #
 765 dnl #  If we have NO pthread libraries, remove any knowledge of threads.
 766 dnl #
 767 if test "x$WITH_THREADS" != "xyes"; then
 768   CFLAGS=$old_CFLAGS
 769   ac_cv_header_pthread_h="no"
 770   WITH_THREADS=no
 771 else
 772   dnl #
 773   dnl #  We need sem_init() and friends, as they're the friendliest
 774   dnl #  semaphore functions for threading.
 775   dnl #
 776   dnl #  HP/UX requires linking with librt, too, to get the sem_* symbols.
 777   dnl #  Some systems have them in -lsem
 778   dnl #  Solaris has them in -lposix4
 779   dnl #  NetBSD has them in -lsemaphore
 780   dnl #
 781
 782   AC_SEARCH_LIBS(sem_init, pthread sem posix4 rt semaphore,
 783     [],
 784     [AC_MSG_ERROR([[-lsem not found.  You may want to download it from ftp://ftp.to.gd-es.com/pub/BSDI/libsem.tar.bz2 or ftp://ftp.freeradius.org/pub/radius/contrib/libsem.tar.gz]])]
 785   )
 786 fi
 787
 788 dnl #
 789 dnl #  Check if we have -ldl
 790 dnl #
 791 AC_CHECK_LIB(dl, dlopen)
 792
 793 dnl #
 794 dnl #  Check if we need -lsocket
 795 dnl #
 796 AC_CHECK_LIB(socket, getsockname)
 797
 798 dnl #
 799 dnl #  Check for -lresolv
 800 dnl #  This library may be needed later.
 801 dnl #
 802 AC_CHECK_LIB(resolv, inet_aton)
 803
 804 dnl #
 805 dnl #  Check if we need -lnsl. Usually if we want to
 806 dnl #  link against -lsocket we need to include -lnsl as well.
 807 dnl #
 808 AC_CHECK_LIB(nsl, inet_ntoa)
 809 AC_CHECK_LIB(ws2_32, htonl)
 810
 811 dnl #
 812 dnl #  Check the pcap library for the RADIUS sniffer.
 813 dnl #
 814 dnl extra argument: --with-pcap-lib-dir=DIR
 815 pcap_lib_dir=
 816 AC_ARG_WITH(pcap-lib-dir,
 817   [AS_HELP_STRING([--with-pcap-lib-dir=DIR],
 818   [directory in which to look for pcap library files])],
 819   [case "$withval" in
 820     no)
 821       AC_MSG_ERROR([Need pcap-lib-dir])
 822       ;;
 823     yes)
 824       ;;
 825     *)
 826       pcap_lib_dir="$withval"
 827       ;;
 828   esac])
 829
 830 dnl extra argument: --with-pcap-include-dir=DIR
 831 pcap_include_dir=
 832 AC_ARG_WITH(pcap-include-dir,
 833   [AS_HELP_STRING([--with-pcap-include-dir=DIR],
 834   [directory in which to look for pcap include files])],
 835   [case "$withval" in
 836     no)
 837       AC_MSG_ERROR([Need pcap-include-dir])
 838       ;;
 839     yes)
 840       ;;
 841     *)
 842       pcap_include_dir="$withval"
 843       ;;
 844   esac])
 845
 846 smart_try_dir="$pcap_lib_dir"
 847 FR_SMART_CHECK_LIB(pcap, pcap_open_live)
 848 if test "x$ac_cv_lib_pcap_pcap_open_live" != "xyes"; then
 849   AC_MSG_WARN([pcap library not found, silently disabling the RADIUS sniffer, and ARP listener.  Use --with-pcap-lib-dir=<path>.])
 850 else
 851   AC_DEFINE(HAVE_LIBPCAP, 1,
 852     [Define to 1 if you have the `pcap' library (-lpcap).]
 853   )
 854
 855   AC_CHECK_FUNCS(\
 856     pcap_fopen_offline \
 857     pcap_dump_fopen \
 858     pcap_create \
 859     pcap_activate
 860   )
 861
 862   PCAP_LIBS="${smart_lib}"
 863   PCAP_LDFLAGS="${smart_ldflags}"
 864 fi
 865 dnl Set by FR_SMART_CHECK_LIB
 866 LIBS="${old_LIBS}"
 867
 868 dnl Check for collectdclient
 869 dnl extra argument: --with-collectdclient-lib-dir=DIR
 870 collectdclient_lib_dir=
 871 AC_ARG_WITH(collectdclient-lib-dir,
 872   [AS_HELP_STRING([--with-collectdclient-lib-dir=DIR],
 873   [directory in which to look for collectdclient library files])],
 874   [case "$withval" in
 875     no)
 876       AC_MSG_ERROR([Need collectdclient-lib-dir])
 877       ;;
 878     yes)
 879       ;;
 880     *)
 881       collectdclient_lib_dir="$withval"
 882       ;;
 883   esac])
 884
 885 dnl extra argument: --with-collectdclient-include-dir=DIR
 886 collectdclient_include_dir=
 887 AC_ARG_WITH(collectdclient-include-dir,
 888   [AS_HELP_STRING([--with-collectdclient-include-dir=DIR],
 889   [directory in which to look for collectdclient include files])],
 890   [case "$withval" in
 891     no)
 892       AC_MSG_ERROR([Need collectdclient-include-dir])
 893       ;;
 894     yes)
 895       ;;
 896     *)
 897       collectdclient_include_dir="$withval"
 898       ;;
 899   esac])
 900
 901 smart_try_dir="$collectdclient_lib_dir"
 902 FR_SMART_CHECK_LIB(collectdclient, lcc_connect)
 903 if test "x$ac_cv_lib_collectdclient_lcc_connect" != "xyes"; then
 904   AC_MSG_WARN([collectdclient library not found. Use --with-collectdclient-lib-dir=<path>.])
 905 else
 906   COLLECTDC_LIBS="${smart_lib}"
 907   COLLECTDC_LDFLAGS="${smart_ldflags}"
 908 fi
 909 dnl Set by FR_SMART_CHECKLIB
 910 LIBS="${old_LIBS}"
 911
 912 dnl Check for cap
 913 dnl extra argument: --with-cap-lib-dir=DIR
 914 cap_lib_dir=
 915 AC_ARG_WITH(cap-lib-dir,
 916   [AS_HELP_STRING([--with-cap-lib-dir=DIR],
 917   [directory in which to look for cap library files])],
 918   [case "$withval" in
 919     no)
 920       AC_MSG_ERROR([Need cap-lib-dir])
 921       ;;
 922     yes)
 923       ;;
 924     *)
 925       cap_lib_dir="$withval"
 926       ;;
 927   esac])
 928
 929 dnl extra argument: --with-cap-include-dir=DIR
 930 cap_include_dir=
 931 AC_ARG_WITH(cap-include-dir,
 932   [AS_HELP_STRING([--with-cap-include-dir=DIR],
 933   [directory in which to look for cap include files])],
 934   [case "$withval" in
 935     no)
 936       AC_MSG_ERROR([Need cap-include-dir])
 937       ;;
 938     yes)
 939       ;;
 940     *)
 941       cap_include_dir="$withval"
 942       ;;
 943   esac])
 944
 945 smart_try_dir="$cap_lib_dir"
 946 FR_SMART_CHECK_LIB(cap, cap_get_proc)
 947 if test "x$ac_cv_lib_cap_cap_get_proc" != "xyes"; then
 948   AC_MSG_WARN([cap library not found, debugger checks will not be enabled. Use --with-cap-lib-dir=<path>.])
 949 else
 950   AC_DEFINE(HAVE_LIBCAP, 1,
 951     [Define to 1 if you have the `cap' library (-lcap).]
 952   )
 953   HAVE_LIBCAP=1
 954 fi
 955
 956 VL_LIB_READLINE
 957
 958 dnl #############################################################
 959 dnl #
 960 dnl #  3. Checks for header files
 961 dnl #
 962 dnl #############################################################
 963
 964 dnl #
 965 dnl # Check for talloc header files
 966 dnl #
 967 smart_try_dir="$talloc_include_dir"
 968 FR_SMART_CHECK_INCLUDE([talloc.h])
 969 if test "x$ac_cv_header_talloc_h" != "xyes"; then
 970   AC_MSG_WARN([talloc headers not found. Use --with-talloc-include-dir=<path>.])
 971   AC_MSG_ERROR([FreeRADIUS requires libtalloc])
 972 fi
 973
 974 dnl #
 975 dnl #  Interix requires us to set -D_ALL_SOURCE, otherwise
 976 dnl #  getopt will be #included, but won't link.  <sigh>
 977 dnl #
 978 case "$host" in
 979   *-interix*)
 980     CFLAGS="$CFLAGS -D_ALL_SOURCE"
 981     ;;
 982   *-darwin*)
 983     CFLAGS="$CFLAGS -DDARWIN"
 984     LIBS="-framework DirectoryService $LIBS"
 985     AC_DEFINE([__APPLE_USE_RFC_3542], 1, [Force OSX >= 10.7 Lion to use RFC2292 IPv6 socket options])
 986     ;;
 987 esac
 988
 989 AC_HEADER_DIRENT
 990 AC_HEADER_STDC
 991 AC_HEADER_TIME
 992 AC_HEADER_SYS_WAIT
 993
 994 AC_CHECK_HEADERS( \
 995   arpa/inet.h \
 996   crypt.h \
 997   dlfcn.h \
 998   errno.h \
 999   fcntl.h \
1000   features.h \
1001   fnmatch.h \
1002   getopt.h \
1003   glob.h \
1004   grp.h \
1005   inttypes.h \
1006   limits.h \
1007   malloc.h \
1008   netdb.h \
1009   netinet/in.h \
1010   prot.h \
1011   pwd.h \
1012   resource.h \
1013   semaphore.h \
1014   sia.h \
1015   siad.h \
1016   signal.h \
1017   stdbool.h \
1018   stddef.h \
1019   stdint.h \
1020   stdio.h \
1021   sys/event.h \
1022   sys/fcntl.h \
1023   sys/prctl.h \
1024   sys/ptrace.h \
1025   sys/resource.h \
1026   sys/security.h \
1027   sys/select.h \
1028   sys/socket.h \
1029   sys/time.h \
1030   sys/types.h \
1031   sys/un.h \
1032   sys/wait.h \
1033   syslog.h \
1034   unistd.h \
1035   utime.h \
1036   utmp.h \
1037   utmpx.h \
1038   winsock.h
1039 )
1040
1041 dnl #
1042 dnl #  FreeBSD requires sys/socket.h before net/if.h
1043 dnl #
1044 AC_CHECK_HEADERS(net/if.h, [], [],
1045   [
1046     #ifdef HAVE_SYS_SOCKET_H
1047     #  include <sys/socket.h>
1048     #endif
1049   ]
1050 )
1051
1052 dnl #
1053 dnl #  other checks which require headers
1054 dnl #
1055 if test "x$ac_cv_header_sys_security_h" = "xyes" && test "x$ac_cv_header_prot_h" = "xyes"
1056 then
1057   AC_DEFINE(OSFC2, [], [define if you have OSFC2 authentication])
1058 fi
1059
1060 if test "x$ac_cv_header_sia_h" = "xyes" && test "x$ac_cv_header_siad_h" = "xyes"
1061 then
1062   AC_DEFINE(OSFSIA, [], [define if you have OSFSIA authentication])
1063 fi
1064
1065 dnl #
1066 dnl #  Were we told to use OpenSSL, if we were and we find an error, call AC_MSG_FAILURE and exit
1067 dnl #
1068 if test "x$WITH_OPENSSL" = xyes; then
1069   OLD_LIBS="$LIBS"
1070
1071   dnl #
1072   dnl #  Apparently OpenSSL will attempt to build with kerberos if we don't pass this?!
1073   dnl #
1074   CFLAGS="$CFLAGS -DOPENSSL_NO_KRB5"
1075
1076   dnl #
1077   dnl #  Check we can link to libcrypto and libssl
1078   dnl #
1079   smart_try_dir="$openssl_lib_dir"
1080   FR_SMART_CHECK_LIB(crypto, DH_new)
1081   if test "x$ac_cv_lib_crypto_DH_new" = "xyes"; then
1082     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
1083     OPENSSL_LIBS="$smart_lib"
1084     OPENSSL_LDFLAGS="$smart_ldflags"
1085
1086     FR_SMART_CHECK_LIB(ssl, SSL_new)
1087     if test "x$ac_cv_lib_ssl_SSL_new" != "xyes"; then
1088       AC_MSG_FAILURE([failed linking to libssl. Use --with-openssl-lib-dir=<path>, or --with-openssl=no (builds without OpenSSL)])
1089     else
1090       AC_DEFINE(HAVE_LIBSSL, 1, [Define to 1 if you have the `ssl' library (-lssl).])
1091       OPENSSL_LIBS="$OPENSSL_LIBS $smart_lib"
1092
1093       if test "$OPENSSL_LDFLAGS" != "$smart_ldflags"; then
1094         AC_MSG_FAILURE(["inconsistent LDFLAGS between -lssl '$smart_ldflags' and -lcrypto '$OPENSSL_LDFLAGS'"])
1095       fi
1096     fi
1097   else
1098     AC_MSG_FAILURE([failed linking to libcrypto. Use --with-openssl-lib-dir=<path>, or --with-openssl=no (builds without OpenSSL)])
1099   fi
1100
1101   smart_try_dir="$openssl_include_dir"
1102   FR_SMART_CHECK_INCLUDE(openssl/ssl.h)
1103   if test "x$ac_cv_header_openssl_ssl_h" = "xyes"; then
1104     AC_DEFINE(HAVE_OPENSSL_SSL_H, 1, [Define to 1 if you have the <openssl/ssl.h> header file.])
1105
1106     AC_CHECK_HEADERS( \
1107       openssl/crypto.h \
1108       openssl/err.h \
1109       openssl/evp.h \
1110       openssl/md5.h \
1111       openssl/md4.h \
1112       openssl/sha.h \
1113       openssl/ssl.h \
1114       openssl/ocsp.h \
1115       openssl/engine.h,
1116       [ OPENSSL_CPPFLAGS="$smart_include" ],
1117       [
1118         AC_MSG_FAILURE([failed locating OpenSSL headers. Use --with-openssl-include-dir=<path>, or --with-openssl=no (builds without OpenSSL)])
1119       ]
1120     )
1121
1122     AC_MSG_CHECKING([for OpenSSL version >= 0.9.7])
1123     AC_EGREP_CPP(yes,
1124       [#include <openssl/crypto.h>
1125        #if (OPENSSL_VERSION_NUMBER >= 0x00907000L)
1126        yes
1127        #endif
1128       ],
1129       [
1130         AC_MSG_RESULT(yes)
1131       ],
1132       [
1133         AC_MSG_RESULT(no)
1134         AC_MSG_FAILURE([OpenSSL version too old])
1135       ]
1136     )
1137
1138     dnl #
1139     dnl #  CPPFLAGS are passed to the compiler first, so we use
1140     dnl #  them to ensure things like --sysroot don't override the
1141     dnl #  library location we discovered previously.
1142     dnl #
1143     old_CPPFLAGS="$CPPFLAGS"
1144     CPPFLAGS="$OPENSSL_CPPFLAGS $CPPFLAGS"
1145
1146     dnl #
1147     dnl #  Now check that the header versions match the library
1148     dnl #
1149     AC_MSG_CHECKING([OpenSSL library and header version consistency])
1150     AC_RUN_IFELSE(
1151       [AC_LANG_PROGRAM(
1152         [[
1153           #include <stdio.h>
1154           #include <openssl/opensslv.h>
1155           #include <openssl/crypto.h>
1156         ]],
1157         [[
1158           printf("library: %lx header: %lx... ", (unsigned long) SSLeay(), (unsigned long) OPENSSL_VERSION_NUMBER);
1159           if (SSLeay() == OPENSSL_VERSION_NUMBER) {
1160             return 0;
1161           } else {
1162             return 1;
1163           }
1164         ]]
1165       )],
1166       [
1167         AC_MSG_RESULT(yes)
1168       ],
1169       [
1170         AC_MSG_RESULT(no)
1171         AC_MSG_FAILURE([OpenSSL library version does not match header version])
1172       ],
1173       [
1174         AC_MSG_RESULT([cross-compiling (assuming yes)])
1175       ]
1176     )
1177     dnl #
1178     dnl #  Check if the new HMAC_CTX interface is defined
1179     dnl #
1180     AC_CHECK_FUNCS( \
1181       SSL_get_client_random \
1182       SSL_get_server_random \
1183     )
1184     CPPFLAGS="$old_CPPFLAGS"
1185   fi
1186
1187   LIBS="$OLD_LIBS"
1188   AC_SUBST(OPENSSL_LIBS)
1189   AC_SUBST(OPENSSL_LDFLAGS)
1190   AC_SUBST(OPENSSL_CPPFLAGS)
1191   export OPENSSL_LIBS OPENSSL_LDFLAGS OPENSSL_CPPFLAGS
1192 fi
1193
1194 dnl #
1195 dnl #  Check the pcap includes for the RADIUS sniffer.
1196 dnl #
1197 if test "x$PCAP_LIBS" = x; then
1198   AC_MSG_NOTICE([skipping test for pcap.h.])
1199 else
1200   dnl #
1201   dnl # Check for pcap header files
1202   dnl #
1203   smart_try_dir="$pcap_include_dir"
1204   FR_SMART_CHECK_INCLUDE([pcap.h])
1205   if test "x$ac_cv_header_pcap_h" == "xyes"; then
1206     AC_DEFINE(HAVE_PCAP_H, 1, [Define to 1 if you have the <pcap.h> header file.])
1207     AC_SUBST(PCAP_LIBS)
1208     AC_SUBST(PCAP_LDFLAGS)
1209   else
1210     AC_MSG_WARN([pcap headers not found, silently disabling the RADIUS sniffer, and ARP listener. Use --with-pcap-include-dir=<path>.])
1211   fi
1212 fi
1213
1214 dnl Check for collectd-client
1215 if test "x$COLLECTDC_LIBS" = x; then
1216   AC_MSG_NOTICE([skipping test for collectd/client.h.])
1217 else
1218   dnl #
1219   dnl # Check for collectd-client header files
1220   dnl #
1221   smart_try_dir="$collectdclient_include_dir"
1222   FR_SMART_CHECK_INCLUDE([collectd/client.h])
1223   if test "x$ac_cv_header_collectd_client_h" == "xyes"; then
1224     AC_DEFINE(HAVE_COLLECTDC_H, 1, [Define to 1 if you have the `collectdclient' library (-lcollectdclient).])
1225     AC_SUBST(COLLECTDC_LIBS)
1226     AC_SUBST(COLLECTDC_LDFLAGS)
1227   else
1228     AC_MSG_WARN([collectdclient headers not found. Use --with-collectdclient-include-dir=<path>.])
1229   fi
1230 fi
1231
1232 dnl #
1233 dnl #  Check the CAP includes for debugger checks
1234 dnl #
1235 if test "x$HAVE_LIBCAP" = x; then
1236   AC_MSG_NOTICE([skipping test for cap.h.])
1237 else
1238   dnl #
1239   dnl # Check for CAP header files
1240   dnl #
1241   smart_try_dir="$cap_include_dir"
1242   FR_SMART_CHECK_INCLUDE([sys/capability.h])
1243   if test "x$ac_cv_header_sys_capability_h" == "xyes"; then
1244     AC_DEFINE(HAVE_CAPABILITY_H, 1, [Define to 1 if you have the <sys/capability.h> header file.])
1245   else
1246     AC_MSG_WARN([cap headers not found, will not perform debugger checks. Use --with-cap-include-dir=<path>.])
1247   fi
1248 fi
1249
1250 dnl #############################################################
1251 dnl #
1252 dnl #  4. Checks for typedefs
1253 dnl #
1254 dnl #############################################################
1255
1256 dnl #
1257 dnl #  Ensure that these are defined
1258 dnl #
1259 AC_TYPE_OFF_T
1260 AC_TYPE_PID_T
1261 AC_TYPE_SIZE_T
1262 AC_TYPE_UID_T
1263
1264 dnl #
1265 dnl #  Check for socklen_t
1266 dnl #
1267 FR_CHECK_TYPE_INCLUDE(
1268   [
1269     #ifdef HAVE_SYS_TYPES_H
1270     #  include <sys/types.h>
1271     #endif
1272
1273     #ifdef HAVE_SYS_SOCKET_H
1274     #  include <sys/socket.h>
1275     #endif
1276   ],
1277   socklen_t, int, [socklen_t is generally 'int' on systems which don't use it]
1278 )
1279
1280 dnl #
1281 dnl #  Check for uint8_t
1282 dnl #
1283 FR_CHECK_TYPE_INCLUDE(
1284   [
1285     #ifdef HAVE_INTTYPES_H
1286     #  include <inttypes.h>
1287     #endif
1288
1289     #ifdef HAVE_STDINT_H
1290     #  include <stdint.h>
1291     #endif
1292   ],
1293   uint8_t, unsigned char, [uint8_t should be the canonical 'octet' for network traffic]
1294 )
1295
1296 dnl #
1297 dnl #  Check for uint16_t
1298 dnl #
1299 FR_CHECK_TYPE_INCLUDE(
1300   [
1301     #ifdef HAVE_INTTYPES_H
1302     #  include <inttypes.h>
1303     #endif
1304
1305     #ifdef HAVE_STDINT_H
1306     #  include <stdint.h>
1307     #endif
1308   ],
1309   uint16_t, unsigned short, [uint16_t should be the canonical '2 octets' for network traffic]
1310 )
1311
1312 dnl #
1313 dnl #  Check for uint32_t
1314 dnl #
1315 FR_CHECK_TYPE_INCLUDE(
1316   [
1317     #ifdef HAVE_INTTYPES_H
1318     #  include <inttypes.h>
1319     #endif
1320
1321     #ifdef HAVE_STDINT_H
1322     #  include <stdint.h>
1323     #endif
1324   ],
1325   uint32_t, unsigned int, [uint32_t should be the canonical 'network integer']
1326 )
1327
1328 dnl #
1329 dnl #  Check for uint64_t
1330 dnl #
1331 FR_CHECK_TYPE_INCLUDE(
1332   [
1333     #ifdef HAVE_INTTYPES_H
1334     #  include <inttypes.h>
1335     #endif
1336
1337     #ifdef HAVE_STDINT_H
1338     #  include <stdint.h>
1339     #endif
1340   ],
1341   uint64_t, unsigned long long, [uint64_t is required for larger counters]
1342 )
1343
1344 dnl #
1345 dnl #  Check for __uint128_t (compiler builtin)
1346 dnl #
1347 AC_CHECK_TYPE(__uint128_t, AC_DEFINE(HAVE___UINT128_T, 1, [compiler specific 128 bit unsigned integer]), [], [])
1348
1349 dnl #
1350 dnl #  Check for uint128_t (fictitious future data type)
1351 dnl #
1352 AC_CHECK_TYPE(uint128_t, AC_DEFINE(HAVE_UINT128_T, 1, [128 bit unsigned integer]), [],
1353   [
1354     #ifdef HAVE_INTTYPES_H
1355     #  include <inttypes.h>
1356     #endif
1357
1358     #ifdef HAVE_STDINT_H
1359     #  include <stdint.h>
1360     #endif
1361   ]
1362 )
1363
1364 AC_CHECK_TYPE(struct in6_addr, AC_DEFINE(HAVE_STRUCT_IN6_ADDR, 1, [IPv6 address structure]), [],
1365   [
1366     #ifdef HAVE_NETINET_IN_H
1367     #  include <netinet/in.h>
1368     #endif
1369   ]
1370 )
1371
1372 AC_CHECK_TYPE(struct sockaddr_storage, AC_DEFINE(HAVE_STRUCT_SOCKADDR_STORAGE, 1, [Generic socket addresses]), [],
1373   [
1374     #ifdef HAVE_NETINET_IN_H
1375     #  include <netinet/in.h>
1376     #endif
1377
1378     #ifdef HAVE_SYS_SOCKET_H
1379     #  include <sys/socket.h>
1380     #endif
1381 ])
1382
1383 AC_CHECK_TYPE(struct sockaddr_in6, AC_DEFINE(HAVE_STRUCT_SOCKADDR_IN6, 1, [IPv6 socket addresses]), [],
1384   [
1385     #ifdef HAVE_NETINET_IN_H
1386     #  include <netinet/in.h>
1387     #endif
1388 ])
1389
1390 AC_CHECK_TYPE(struct addrinfo, AC_DEFINE(HAVE_STRUCT_ADDRINFO, 1, [Generic DNS lookups]), [],
1391   [
1392     #ifdef HAVE_SYS_TYPES_H
1393     #  include <sys/types.h>
1394     #endif
1395
1396     #ifdef HAVE_SYS_SOCKET_H
1397     #  include <sys/socket.h>
1398     #endif
1399
1400     #ifdef HAVE_NETDB_H
1401     #  include <netdb.h>
1402     #endif
1403   ]
1404 )
1405
1406 dnl #
1407 dnl #  Check for sig_t
1408 dnl #
1409 dnl #  FR_CHECK_TYPE_INCLUDE doesn't work for callbacks as it doesn't produce typedefs
1410 dnl #
1411 AC_MSG_CHECKING([if sig_t is defined])
1412 AC_LINK_IFELSE(
1413   [AC_LANG_PROGRAM(
1414     [[
1415       #ifdef HAVE_SIGNAL_H
1416       #  include <signal.h>
1417       #endif
1418     ]],
1419     [[
1420       sig_t func;
1421       return 0;
1422     ]]
1423   )],
1424   [
1425       AC_MSG_RESULT(yes)
1426       AC_DEFINE(HAVE_SIG_T, 1, [Define if the type sig_t is defined by signal.h])
1427   ],
1428   [
1429       AC_MSG_RESULT(no)
1430   ]
1431 )
1432
1433 dnl #############################################################
1434 dnl #
1435 dnl #  5. Checks for structures and functions
1436 dnl #
1437 dnl #############################################################
1438 AC_CHECK_FUNCS( \
1439   bindat \
1440   clock_gettime \
1441   closefrom \
1442   ctime_r \
1443   dladdr \
1444   fcntl \
1445   fopencookie \
1446   funopen \
1447   getaddrinfo \
1448   getnameinfo \
1449   getopt_long \
1450   getpeereid \
1451   getresuid \
1452   gettimeofday \
1453   getusershell \
1454   gmtime_r \
1455   if_indextoname \
1456   inet_aton \
1457   inet_ntop \
1458   inet_pton \
1459   initgroups \
1460   kqueue \
1461   localtime_r \
1462   mallopt \
1463   mkdirat \
1464   openat \
1465   pthread_sigmask \
1466   setlinebuf \
1467   setresuid \
1468   setsid \
1469   setuid \
1470   setvbuf \
1471   sigaction \
1472   sigprocmask \
1473   snprintf \
1474   strcasecmp \
1475   strlcat \
1476   strlcpy \
1477   strncasecmp \
1478   strsep \
1479   strsignal \
1480   unlinkat \
1481   vdprintf \
1482   vsnprintf
1483 )
1484
1485 AC_TYPE_SIGNAL
1486
1487 dnl #
1488 dnl #  Check if we have utmpx.h
1489 dnl #  if so, check if struct utmpx has entry ut_xtime
1490 dnl #  if not, set it to define ut_xtime == ut_tv.tv_sec
1491 dnl #
1492 if test "x$ac_cv_header_utmpx_h" = "xyes"; then
1493  FR_CHECK_STRUCT_HAS_MEMBER([#include <utmpx.h>], [struct utmpx], ut_xtime)
1494  if test "x$ac_cv_type_struct_utmpx_has_ut_xtime" = "x"; then
1495    AC_DEFINE(ut_xtime, ut_tv.tv_sec, [define to something if you don't have ut_xtime in struct utmpx])
1496  fi
1497 fi
1498
1499 dnl #
1500 dnl #  struct ip_pktinfo
1501 dnl #
1502 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in_pktinfo], ipi_addr)
1503 if test "x$ac_cv_type_struct_in_pktinfo_has_ipi_addr" = "xyes"; then
1504   AC_DEFINE(HAVE_IP_PKTINFO, [], [define if you have IP_PKTINFO (Linux)])
1505 fi
1506
1507 dnl #
1508 dnl #  struct in6_pktinfo
1509 dnl #
1510 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in6_pktinfo], ipi6_addr)
1511 if test "x$ac_cv_type_struct_in6_pktinfo_has_ipi6_addr" = "xyes"; then
1512   AC_DEFINE(HAVE_IN6_PKTINFO, [], [define if you have IN6_PKTINFO (Linux)])
1513 fi
1514
1515 dnl #
1516 dnl #  Check for htonll and htonlll
1517 dnl #
1518 AC_MSG_CHECKING([if htonll is defined])
1519 AC_LINK_IFELSE(
1520   [AC_LANG_PROGRAM(
1521     [[
1522       #include <sys/types.h>
1523       #include <netinet/in.h>
1524     ]],
1525     [[
1526       return htonll(0);
1527     ]]
1528   )],
1529   [
1530       AC_MSG_RESULT(yes)
1531       AC_DEFINE(HAVE_HTONLL, 1, [Define if the function (or macro) htonll exists.])
1532   ],
1533   [
1534       AC_MSG_RESULT(no)
1535   ]
1536 )
1537
1538 AC_MSG_CHECKING([if htonlll is defined])
1539 AC_LINK_IFELSE(
1540   [AC_LANG_PROGRAM(
1541     [[
1542       #include <sys/types.h>
1543       #include <netinet/in.h>
1544     ]],
1545     [[
1546       return htonlll(0);
1547     ]]
1548   )],
1549   [
1550       AC_MSG_RESULT(yes)
1551       AC_DEFINE(HAVE_HTONLLL, 1, [Define if the function (or macro) htonlll exists.])
1552   ],
1553   [
1554       AC_MSG_RESULT(no)
1555   ]
1556 )
1557
1558 dnl #############################################################
1559 dnl #
1560 dnl #  6. Checks for compiler characteristics
1561 dnl #
1562 dnl #############################################################
1563
1564 dnl #
1565 dnl #  Ensure that these are defined
1566 dnl #
1567 AC_C_CONST
1568
1569 dnl #
1570 dnl #  See if this is OS/2
1571 dnl #
1572 AC_MSG_CHECKING([type of OS])
1573 OS=`uname -s`
1574 AC_MSG_RESULT($OS)
1575 if test "$OS" = "OS/2"; then
1576   LIBPREFIX=
1577 else
1578   LIBPREFIX=lib
1579 fi
1580 AC_SUBST(LIBPREFIX)
1581
1582 if test "x$developer" = "xyes"; then
1583   AC_MSG_NOTICE([Setting additional developer CFLAGS])
1584
1585   dnl #
1586   dnl #  Tell the compiler to parse doxygen documentation and verify it against function and variable declarations
1587   dnl #
1588   AX_CC_WDOCUMENTATION_FLAG
1589   if test "x$ax_cv_cc_wdocumentation_flag" = "xyes"; then
1590     devflags="-Wdocumentation"
1591   fi
1592
1593   dnl #
1594   dnl #  If we have -Weverything, it really means *everything* unlike -Wall
1595   dnl #  It's so verbose we need to turn off warnings which aren't useful.
1596   dnl #
1597   AX_CC_WEVERYTHING_FLAG
1598   if test "x$ax_cv_cc_weverything_flag" = "xyes"; then
1599     devflags="$devflags -W -Weverything -Wformat=2 -Wno-missing-field-initializers -Wno-date-time -Wno-padded -Wno-gnu-zero-variadic-macro-arguments -Wno-shorten-64-to-32 -Wno-sign-conversion -Wno-conversion -Wno-switch-enum -Wno-gnu-statement-expression -Wno-extended-offsetof -Wno-cast-align -Wno-documentation-unknown-command -Wno-covered-switch-default -Wno-packed -DWITH_VERIFY_PTR=1"
1600   else
1601     if test "x$GCC" = "xyes"; then
1602       devflags="$devflags -Wshadow -Wpointer-arith -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -W -Wredundant-decls -Wundef -Wformat-y2k -Wno-format-extra-args -Wno-format-zero-length -Wno-cast-align -Wformat-nonliteral -Wformat-security -Wformat=2 -DWITH_VERIFY_PTR=1"
1603       INSTALLSTRIP=""
1604     fi
1605   fi
1606
1607   AC_MSG_NOTICE([Developer CFLAGS are "$devflags"])
1608
1609   CFLAGS="$CFLAGS $devflags"
1610   dnl #
1611   dnl #  Enable experimental modules (we want to know if code changes breaks one of them)
1612   dnl #
1613   if test "x$EXPERIMENTAL" != "xno"; then
1614     AC_MSG_NOTICE([is developer build, enabling experimental modules implicitly, disable with --without-experimental-modules])
1615     EXPERIMENTAL=yes
1616   fi
1617 else
1618   devflags=""
1619   CFLAGS="$CFLAGS -DNDEBUG"
1620   INSTALLSTRIP=""
1621 fi
1622
1623 dnl #
1624 dnl #  May of been set outside of this configure script
1625 dnl #
1626 AC_MSG_CHECKING([if building with -DNDEBUG])
1627 if echo "$CFLAGS" | grep '\-DNDEBUG' > /dev/null; then
1628   AC_MSG_RESULT([yes])
1629   AC_DEFINE([WITH_NDEBUG], [1], [define if the server was built with -DNDEBUG])
1630 else
1631   AC_MSG_RESULT([no])
1632 fi
1633
1634 export EXPERIMENTAL
1635
1636 dnl #
1637 dnl #  append the current git hash onto the version string
1638 dnl #
1639 if test -d $srcdir/.git -a "x$GIT" = "xyes"; then
1640   RADIUSD_VERSION_COMMIT=`git log --pretty=format:'%h' -n 1`
1641   AC_DEFINE_UNQUOTED([RADIUSD_VERSION_COMMIT],[${RADIUSD_VERSION_COMMIT}],[Commit HEAD at time of configuring])
1642 fi
1643
1644 dnl #
1645 dnl #  check for some compiler features
1646 dnl #
1647 FR_TLS
1648 FR_HAVE_BUILTIN_CHOOSE_EXPR
1649 FR_HAVE_BUILTIN_TYPES_COMPATIBLE_P
1650 FR_HAVE_BUILTIN_BSWAP64
1651 FR_HAVE_BOUNDED_ATTRIBUTE
1652
1653 dnl #############################################################
1654 dnl #
1655 dnl #  7. Checks for library functions
1656 dnl #
1657 dnl #############################################################
1658
1659 dnl #
1660 dnl # Check for talloc_set_memlimit
1661 dnl # This was only included in version 2.0.8
1662 dnl #
1663 AC_CHECK_LIB(talloc, talloc_set_memlimit,
1664   [
1665     AC_DEFINE(HAVE_TALLOC_SET_MEMLIMIT, 1, [Define to 1 if you have the function talloc_set_memlimit.])
1666   ]
1667 )
1668
1669 dnl #
1670 dnl # Check for libcrypt
1671 dnl # We use crypt(3) which may be in libc, or in libcrypt (eg FreeBSD)
1672 dnl #
1673 AC_CHECK_LIB(crypt, crypt,
1674   CRYPTLIB="-lcrypt"
1675 )
1676
1677 if test "$CRYPTLIB" != ""; then
1678   AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function])
1679 else
1680   AC_CHECK_FUNC(crypt, AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function]))
1681 fi
1682
1683 dnl Check for libcipher
1684 AC_CHECK_LIB(cipher, setkey,
1685    CRYPTLIB="${CRYPTLIB} -lcipher"
1686 )
1687 AC_SUBST(CRYPTLIB)
1688
1689 dnl #
1690 dnl #  Check for libexecinfo support, on some systems this is built into libc
1691 dnl #  on others it's a separate library.
1692 dnl #
1693 dnl extra argument: --with-execinfo-lib-dir
1694 execinfo_lib_dir=
1695 AC_ARG_WITH(execinfo-lib-dir,
1696 [AS_HELP_STRING([--with-execinfo-lib-dir=DIR],
1697 [directory in which to look for execinfo library files])],
1698 [ case "$withval" in
1699     no)
1700         AC_MSG_ERROR([Need execinfo-lib-dir])
1701         ;;
1702     yes)
1703         ;;
1704     *)
1705         execinfo_lib_dir="$withval"
1706         ;;
1707   esac ]
1708 )
1709
1710 dnl extra argument: --with-execinfo-include-dir
1711 execinfo_include_dir=
1712 AC_ARG_WITH(execinfo-include-dir,
1713 [AS_HELP_STRING([--with-execinfo-include-dir=DIR],
1714 [directory in which to look for execinfo include files])],
1715 [ case "$withval" in
1716     no)
1717         AC_MSG_ERROR([Need execinfo-include-dir])
1718         ;;
1719     yes)
1720         ;;
1721     *)
1722         execinfo_include_dir="$withval"
1723         ;;
1724   esac ]
1725 )
1726
1727 dnl #
1728 dnl #  Look for execinfo.h and symbols
1729 dnl #
1730 smart_try_dir=$execinfo_include_dir
1731 FR_SMART_CHECK_INCLUDE(execinfo.h)
1732 if test "x$ac_cv_header_execinfo_h" = "xyes"; then
1733   smart_try_dir=$execinfo_lib_dir
1734   FR_SMART_CHECK_LIB(execinfo, backtrace_symbols)
1735   if test "x$ac_cv_lib_execinfo_backtrace_symbols" != "xyes"; then
1736     dnl # Might be provided as part of libc
1737     AC_MSG_CHECKING([if execinfo provided as part of libc])
1738     AC_TRY_LINK(
1739       [
1740         #include <execinfo.h>
1741       ],
1742       [
1743         void *sym[1];
1744         backtrace_symbols(&sym, sizeof(sym)) ],
1745       [
1746         AC_MSG_RESULT(yes)
1747         ac_cv_lib_execinfo_backtrace_symbols="yes"
1748       ],
1749       [
1750         AC_MSG_RESULT(no)
1751       ]
1752     )
1753   fi
1754
1755   if test "x$ac_cv_lib_execinfo_backtrace_symbols" = "xyes"; then
1756     AC_DEFINE(HAVE_EXECINFO, [1], [define this if we have <execinfo.h> and symbols])
1757   fi
1758 fi
1759
1760 dnl #
1761 dnl #  Check for regular expression support.
1762 dnl #
1763 dnl extra argument: --with-pcre
1764 PCRE=yes
1765 AC_ARG_WITH(pcre,
1766 [AS_HELP_STRING([--with-pcre],
1767 [use libpcre (if available). (default=yes)])],
1768 [ case "$withval" in
1769     no)
1770     PCRE=no
1771         ;;
1772     yes)
1773     PCRE=yes
1774         ;;
1775   esac ]
1776 )
1777
1778 dnl extra argument: --with-pcre-lib-dir
1779 pcre_lib_dir=
1780 AC_ARG_WITH(pcre-lib-dir,
1781 [AS_HELP_STRING([--with-pcre-lib-dir=DIR],
1782 [directory in which to look for pcre library files])],
1783 [ case "$withval" in
1784     no)
1785         AC_MSG_ERROR(Need pcre-lib-dir)
1786         ;;
1787     yes)
1788         ;;
1789     *)
1790         pcre_lib_dir="$withval"
1791         ;;
1792   esac ]
1793 )
1794
1795 dnl extra argument: --with-pcre-include-dir
1796 pcre_include_dir=
1797 AC_ARG_WITH(pcre-include-dir,
1798 [AS_HELP_STRING([--with-pcre-include-dir=DIR],
1799 [directory in which to look for pcre include files])],
1800 [ case "$withval" in
1801     no)
1802         AC_MSG_ERROR(Need pcre-include-dir)
1803         ;;
1804     yes)
1805         ;;
1806     *)
1807         pcre_include_dir="$withval"
1808         ;;
1809   esac ]
1810 )
1811
1812 dnl extra argument: --with-regex
1813 REGEX=
1814 AC_ARG_WITH(regex,
1815 [AS_HELP_STRING([--with-regex],
1816 [Whether to build with regular expressions (default=yes)])],
1817 [ case "$withval" in
1818     no)
1819         REGEX=no
1820         ;;
1821     *)
1822         ;;
1823   esac ]
1824 )
1825
1826 dnl #
1827 dnl #  First look for PCRE
1828 dnl #
1829 if test "x$REGEX" != "xno" && test "x$PCRE" != "xno"; then
1830   smart_try_dir=$pcre_include_dir
1831   FR_SMART_CHECK_INCLUDE(pcre.h)
1832   if test "x$ac_cv_header_pcre_h" = "xyes"; then
1833     smart_try_dir=$pcre_lib_dir
1834     FR_SMART_CHECK_LIB(pcre, pcre_compile)
1835     if test "x$ac_cv_lib_pcre_pcre_compile" = "xyes"; then
1836       REGEX=yes
1837       AC_DEFINE(HAVE_PCRE, [1], [define this if we have libpcre])
1838       AC_DEFINE(HAVE_BINSAFE_REGEX, 1, [Define if we have a binary safe regular expression library])
1839     fi
1840   fi
1841 fi
1842
1843 dnl #
1844 dnl #  If no PCRE, fallback to POSIX regular expressions
1845 dnl #
1846 if test "x$REGEX" = "x"; then
1847   smart_try_dir=
1848   FR_SMART_CHECK_INCLUDE(regex.h)
1849   if test "x$ac_cv_header_regex_h" = "xyes"; then
1850     REGEX=yes
1851     AC_MSG_CHECKING([for extended regular expressions])
1852     AC_EGREP_CPP(yes,
1853       [
1854         #include <regex.h>
1855         #ifdef REG_EXTENDED
1856         yes
1857         #endif
1858       ],
1859       [
1860         AC_MSG_RESULT(yes)
1861         AC_DEFINE(HAVE_REG_EXTENDED, [1], [define this if we have REG_EXTENDED (from <regex.h>)])
1862       ],
1863       [
1864         AC_MSG_RESULT(no)
1865       ]
1866     )
1867
1868     dnl #
1869     dnl #  Some platforms require the regex library to be linked explicitly
1870     dnl #
1871     AC_CHECK_LIB(regex, regcomp,
1872       [
1873         LIBS="-lregex $LIBS"
1874       ]
1875     )
1876
1877     dnl #
1878     dnl #  Check for some BSD extensions which allow normal regexes to be
1879     dnl #  binary safe.
1880     dnl #
1881     AC_CHECK_FUNCS(\
1882       regncomp \
1883       regnexec
1884     )
1885     if test x"$ac_cv_func_regncomp" = x"yes" && test  x"$ac_cv_func_regnexec" = x"yes"; then
1886       AC_DEFINE(HAVE_BINSAFE_REGEX, 1, [Define if we have a binary safe regular expression library])
1887     fi
1888   fi
1889 fi
1890
1891 if test "x$REGEX" = "xyes"; then
1892   AC_DEFINE(HAVE_REGEX, 1, [Define if we have any regular expression library])
1893 fi
1894
1895 dnl #
1896 dnl #  Check the style of gethostbyaddr, in order of preference
1897 dnl #  GNU (_r eight args)
1898 dnl #
1899 AC_DEFINE(GNUSTYLE, [1], [GNU-Style get*byaddr_r])
1900
1901 dnl #
1902 dnl #  SYSV (_r six args)
1903 dnl #
1904 AC_DEFINE(SYSVSTYLE, [2], [SYSV-Style get*byaddr_r])
1905
1906 dnl #
1907 dnl #  BSD (three args, may not be thread safe)
1908 dnl #
1909 AC_DEFINE(BSDSTYLE, [3], [BSD-Style get*byaddr_r])
1910
1911 dnl #
1912 dnl #  Tru64 has BSD version, but it is thread safe
1913 dnl #  http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1739____.HTM
1914 dnl #  We need #stdio.h to define NULL on FreeBSD (at least)
1915 dnl #
1916 gethostbyaddrrstyle=""
1917 AC_MSG_CHECKING([gethostbyaddr_r() syntax])
1918 case "$host" in
1919   *-freebsd*)
1920     dnl #
1921     dnl #  With FreeBSD, check if there's a prototype for gethostbyaddr_r.
1922     dnl #  Some versions (FreeBSD 5.1?) have a symbol but no prototype - so we
1923     dnl #  override this test to BSDSTYLE. FreeBSD 6.2 and up have proper GNU
1924     dnl #  style support.
1925     dnl #
1926     AC_CHECK_DECLS([gethostbyaddr_r], [],
1927       [
1928         AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE,
1929           [style of gethostbyaddr_r functions ])
1930         gethostbyaddrrstyle=BSD
1931         AC_MSG_WARN([FreeBSD overridden to BSD-style])
1932       ],
1933       [
1934         #ifdef HAVE_NETDB_H
1935         #include <netdb.h>
1936         #endif
1937       ])
1938     ;;
1939 esac
1940
1941 if test "x$gethostbyaddrrstyle" = "x"; then
1942   AC_TRY_LINK(
1943     [
1944       #include <stdio.h>
1945       #include <netdb.h>
1946     ],
1947     [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL, NULL) ],
1948     [
1949       AC_DEFINE(GETHOSTBYADDRRSTYLE, GNUSTYLE, [style of gethostbyaddr_r functions ])
1950       gethostbyaddrrstyle=GNU
1951     ]
1952   )
1953 fi
1954
1955 if test "x$gethostbyaddrrstyle" = "x"; then
1956   AC_TRY_LINK(
1957     [
1958       #include <stdio.h>
1959       #include <netdb.h>
1960     ],
1961     [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL) ] ,
1962     [
1963       AC_DEFINE(GETHOSTBYADDRRSTYLE, SYSVSTYLE, [style of gethostbyaddr_r functions ])
1964       gethostbyaddrrstyle=SYSV
1965     ]
1966   )
1967 fi
1968
1969
1970 if test "x$gethostbyaddrrstyle" = "x"; then
1971   AC_TRY_LINK(
1972     [
1973       #include <stdio.h>
1974       #include <netdb.h>
1975     ],
1976     [ gethostbyaddr(NULL, 0, 0)  ],
1977     [
1978       AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE, [style of gethostbyaddr_r functions ])
1979       gethostbyaddrrstyle=BSD
1980     ]
1981   )
1982 fi
1983
1984 if test "x$gethostbyaddrrstyle" = "x"; then
1985   AC_MSG_RESULT([none!  It must not exist, here.])
1986 else
1987   AC_MSG_RESULT([${gethostbyaddrrstyle}-style])
1988 fi
1989
1990 if test "x$gethostbyaddrrstyle" = "xBSD"; then
1991   AC_MSG_WARN([ ****** BSD-style gethostbyaddr might NOT be thread-safe! ****** ])
1992 fi
1993
1994 dnl #
1995 dnl #  Check the style of gethostbyname, in order of preference
1996 dnl #  GNU (_r seven args)
1997 dnl #  SYSV (_r five args)
1998 dnl #  BSD (two args, may not be thread safe)
1999 dnl #  Tru64 has BSD version, but it _is_ thread safe
2000 dnl #    http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1946____.HTM
2001 dnl #  We need #stdio.h to define NULL on FreeBSD (at least)
2002 dnl #
2003 gethostbynamerstyle=""
2004 AC_MSG_CHECKING([gethostbyname_r() syntax])
2005 AC_TRY_LINK(
2006   [
2007     #include <stdio.h>
2008     #include <netdb.h>
2009   ],
2010   [ gethostbyname_r(NULL, NULL, NULL, 0, NULL, NULL) ],
2011   [
2012     AC_DEFINE(GETHOSTBYNAMERSTYLE, GNUSTYLE, [style of gethostbyname_r functions ])
2013     gethostbynamerstyle=GNU
2014   ]
2015 )
2016
2017 if test "x$gethostbynamerstyle" = "x"; then
2018   AC_TRY_LINK(
2019     [
2020       #include <stdio.h>
2021       #include <netdb.h>
2022     ],
2023     [ gethostbyname_r(NULL, NULL, NULL, 0, NULL) ] ,
2024     [
2025       AC_DEFINE(GETHOSTBYNAMERSTYLE, SYSVSTYLE, [style of gethostbyname_r functions ])
2026       gethostbynamerstyle=SYSV
2027     ]
2028   )
2029 fi
2030
2031 if test "x$gethostbynamerstyle" = "x"; then
2032   AC_TRY_LINK(
2033     [
2034       #include <stdio.h>
2035       #include <netdb.h>
2036     ],
2037     [ gethostbyname(NULL) ],
2038     [
2039       AC_DEFINE(GETHOSTBYNAMERSTYLE, BSDSTYLE, [style of gethostbyname_r functions ])
2040       gethostbynamerstyle=BSD
2041     ]
2042   )
2043 fi
2044
2045 if test "x$gethostbynamerstyle" = "x"; then
2046   AC_MSG_RESULT([none!  It must not exist, here.])
2047 else
2048   AC_MSG_RESULT([${gethostbynamerstyle}-style])
2049 fi
2050
2051 if test "x$gethostbynamerstyle" = "xBSD"; then
2052   AC_MSG_WARN([ ****** BSD-style gethostbyname might NOT be thread-safe! ****** ])
2053 fi
2054
2055 dnl #
2056 dnl #  Check for thread-safe getpwnam_r and getgrnam_r
2057 dnl #
2058 if test "x$ac_cv_header_pwd_h" = "xyes"; then
2059   AC_MSG_CHECKING([getpwnam_r])
2060   AC_TRY_LINK(
2061     [
2062       #include <stdlib.h>
2063       #include <sys/types.h>
2064       #include <pwd.h>
2065     ],
2066     [ getpwnam_r(NULL, NULL, NULL, 0, NULL) ],
2067     [
2068       AC_MSG_RESULT([yes])
2069       AC_DEFINE(HAVE_GETPWNAM_R, 1,
2070                 [Define to 1 if you have the getpwnam_r.]
2071                 )
2072     ],
2073     [
2074         AC_MSG_RESULT(no)
2075     ]
2076   )
2077 fi
2078
2079 if test "x$ac_cv_header_grp_h" = "xyes"; then
2080   AC_MSG_CHECKING([getgrnam_r])
2081   AC_TRY_LINK(
2082     [
2083       #include <stdlib.h>
2084       #include <sys/types.h>
2085       #include <grp.h>
2086     ],
2087     [ getgrnam_r(NULL, NULL, NULL, 0, NULL) ],
2088     [
2089       AC_MSG_RESULT([yes])
2090       AC_DEFINE(HAVE_GETGRNAM_R, 1,
2091                 [Define to 1 if you have the getgrnam_r.]
2092                 )
2093     ],
2094     [
2095         AC_MSG_RESULT(no)
2096     ]
2097   )
2098 fi
2099
2100
2101 dnl #
2102 dnl #  Check for non-posix solaris ctime_r (extra buflen int arg)
2103 dnl #
2104 AC_DEFINE(POSIXSTYLE, [1], [Posix-Style ctime_r])
2105 AC_DEFINE(SOLARISSTYLE, [2], [Solaris-Style ctime_r])
2106 ctimerstyle=""
2107 AC_MSG_CHECKING([ctime_r() syntax])
2108 AC_TRY_LINK(
2109   [
2110     #include <time.h>
2111   ],
2112   [ ctime_r(NULL, NULL, 0) ],
2113   [
2114     AC_DEFINE(CTIMERSTYLE, SOLARISSTYLE, [style of ctime_r function])
2115     ctimerstyle="SOLARIS"
2116   ]
2117 )
2118
2119 if test "x$ctimerstyle" = "x"; then
2120   AC_TRY_LINK(
2121     [
2122       #include <time.h>
2123     ],
2124     [ ctime_r(NULL, NULL) ],
2125     [
2126       AC_DEFINE(CTIMERSTYLE, POSIXSTYLE, [style of ctime_r function])
2127       ctimerstyle="POSIX"
2128     ]
2129   )
2130 fi
2131
2132 if test "x$ctimerstyle" = "x"; then
2133     AC_MSG_RESULT([none!  It must not exist, here.])
2134 else
2135     AC_MSG_RESULT([${ctimerstyle}-style])
2136 fi
2137
2138 AC_SUBST(HOSTINFO, $host)
2139
2140 dnl #############################################################
2141 dnl #
2142 dnl #  8. Checks for system services
2143 dnl #
2144 dnl #############################################################
2145
2146 dnl #
2147 dnl #  Figure out where libtool is located,
2148 dnl #
2149 top_builddir=`pwd`
2150 export top_builddir
2151 AC_MSG_RESULT([top_builddir=$top_builddir])
2152 dnl #  AC_SUBST(top_builddir)
2153
2154 dnl #
2155 dnl #  import libtool stuff
2156 dnl #
2157 dnl #############################################################
2158 dnl #
2159 dnl #  Configure in any module directories.
2160 dnl #
2161 dnl #############################################################
2162
2163 dnl ############################################################
2164 dnl #  Remove any conflicting definitions if autoconf.h
2165 dnl #  is being included by a module.
2166 dnl #############################################################
2167 AH_BOTTOM([#include <freeradius-devel/automask.h>])
2168
2169 dnl ############################################################
2170 dnl #  make modules by list
2171 dnl #############################################################
2172 if test "x$EXPERIMENTAL" = "xyes"; then
2173   for foo in `ls -1 "${srcdir}"/src/modules | grep rlm_`; do
2174     MODULES="$MODULES $foo"
2175   done
2176 else
2177    dnl #
2178    dnl #  make ONLY the stable modules
2179    dnl #
2180    for foo in `cat "${srcdir}"/src/modules/stable`; do
2181       MODULES="$MODULES $foo"
2182    done
2183 fi
2184
2185 dnl ############################################################
2186 dnl #  Add autoconf subdirs, based on the module list we
2187 dnl #  previously created.
2188 dnl #############################################################
2189 mysubdirs=""
2190 for bar in $MODULES; do
2191   if test -f "${srcdir}"/src/modules/$bar/configure; then
2192     mysubdirs="$mysubdirs src/modules/$bar"
2193   fi
2194 done
2195
2196 dnl #
2197 dnl #  Don't change the variable name here.  Autoconf goes bonkers
2198 dnl #  if you do.
2199 dnl #
2200 AC_CONFIG_SUBDIRS($mysubdirs)
2201 AC_SUBST(MODULES)
2202
2203 dnl #############################################################
2204 dnl #
2205 dnl #  Add -Werror last, so it doesn't interfere with autoconf's
2206 dnl #  test programs.
2207 dnl #
2208 dnl #############################################################
2209 if test "x$werror" == "xyes"; then
2210   CFLAGS="-Werror $CFLAGS"
2211 fi
2212
2213 dnl #############################################################
2214 dnl #
2215 dnl #  And finally, output the results.
2216 dnl #
2217 dnl #############################################################
2218 AC_CONFIG_COMMANDS([stamp-h], [echo timestamp > src/include/stamp-h])
2219 AC_CONFIG_COMMANDS([build-radpaths-h], [(cd ./src/include && /bin/sh ./build-radpaths-h)])
2220 AC_CONFIG_COMMANDS([main-chmod], [(cd ./src/main && chmod +x checkrad radlast radtest)])
2221 AC_CONFIG_COMMANDS([scripts-chmod], [(cd ./scripts && chmod +x rc.radiusd cron/radiusd.cron.daily cron/radiusd.cron.monthly cryptpasswd)])
2222
2223 dnl #
2224 dnl #  Substitute whatever libraries we found to be necessary
2225 dnl #
2226 AC_SUBST(LIBS)
2227 AC_SUBST(INSTALLSTRIP)
2228
2229 AC_SUBST(USE_SHARED_LIBS)
2230 USE_STATIC_LIBS="yes"
2231 AC_SUBST(USE_STATIC_LIBS)
2232 AC_SUBST(STATIC_MODULES)
2233
2234 AC_OUTPUT(\
2235   ./Make.inc \
2236   ./src/include/build-radpaths-h \
2237   ./src/main/radsniff.mk \
2238   ./src/main/checkrad \
2239   ./src/main/radlast \
2240   ./src/main/radtest \
2241   ./scripts/rc.radiusd \
2242   ./scripts/cron/radiusd.cron.daily \
2243   ./scripts/cron/radiusd.cron.monthly \
2244   ./scripts/cryptpasswd \
2245   ./raddb/radrelay.conf \
2246   ./raddb/radiusd.conf
2247 )