configure.in

   1 dnl #############################################################
   2 dnl #
   3 dnl #  For information about autoconf, see:
   4 dnl #
   5 dnl #  http://www.gnu.org/software/autoconf/
   6 dnl #
   7 dnl #  The recommended order is:
   8 dnl #
   9 dnl #  AC_INIT(file)
  10 dnl #  0. checks for compiler, libtool, and command line options
  11 dnl #  1. checks for programs
  12 dnl #  2. checks for libraries
  13 dnl #  3. checks for header files
  14 dnl #  4. checks for typedefs
  15 dnl #  5. checks for structures and functions
  16 dnl #  6. checks for compiler characteristics
  17 dnl #  7. checks for library functions
  18 dnl #  8. checks for system services
  19 dnl #  AC_OUTPUT([file...])
  20 dnl #
  21 dnl #############################################################
  22
  23 AC_INIT(src/main/radiusd.c)
  24 AC_CONFIG_HEADER(src/include/autoconf.h)
  25 AC_REVISION($Revision$)dnl
  26
  27 dnl # The version of the software, 0.5
  28 RADIUSD_MAJOR_VERSION=0
  29 RADIUSD_MINOR_VERSION=5
  30 RADIUSD_VERSION="${RADIUSD_MAJOR_VERSION}.${RADIUSD_MINOR_VERSION}"
  31
  32 dnl #############################################################
  33 dnl #
  34 dnl #  0. Checks for compiler, libtool, and command line options.
  35 dnl #
  36 dnl #############################################################
  37
  38 dnl Check for GNU cc
  39 AC_PROG_CC
  40 AC_PROG_GCC_TRADITIONAL
  41 AC_PROG_CC_SUNPRO
  42 AC_PROG_RANLIB
  43
  44 PACKAGE=freeradius
  45
  46 dnl Find GNU Make.
  47 AC_CHECK_PROG(GMAKE, gmake, yes, no)
  48 if test $GMAKE = no; then
  49   AC_PATH_PROG(MAKE, make, /usr/local/bin/make)
  50 else
  51   AC_PATH_PROG(MAKE, gmake, /usr/local/gnu/bin/make)
  52 fi
  53 makever=`$ac_cv_path_MAKE --version 2>&1 | grep "GNU Make"`
  54 if test -z "$makever"; then
  55   AC_MSG_ERROR(GNU Make is not installed.  Please download and install it
  56                 from ftp://prep.ai.mit.edu/pub/gnu/make/ before continuing.)
  57 fi
  58
  59 dnl libltdl is installable
  60 AC_LIBLTDL_INSTALLABLE
  61
  62 dnl ensure that we're looking for dlopen
  63 AC_LIBTOOL_DLOPEN
  64
  65 dnl Figure out how to build shared libraries
  66 AC_PROG_LIBTOOL
  67
  68 dnl Put this in later, when all distributed modules use autoconf.
  69 dnl AC_ARG_WITH(disablemodulefoo,
  70 dnl [  --without-rlm_foo       Disables module compilation.  Module list:]
  71 dnl esyscmd([find src/modules -type d -name rlm_\* -print |\
  72 dnl     sed -e 's%src/modules/.*/% (sub)- %; s%.*/%- %' |\
  73 dnl     awk '{print "                            "$0}']))
  74
  75 AC_ARG_ENABLE(strict-dependencies,
  76 [  --enable-strict-dependencies  Fail configure on lack of module dependancy.])
  77
  78 AC_ARG_WITH(fooincludedir,
  79 [  --with-FOO-include-dir=DIR   Dir for includes for FOO, module dependancy.])
  80
  81 AC_ARG_WITH(foolibdir,
  82 [  --with-FOO-lib-dir=DIR  Dir for libraries for FOO, module dependancy.])
  83
  84 dnl extra argument: --with-logdir
  85 logdir='${localstatedir}/log/radius'
  86 AC_MSG_CHECKING(logdir)
  87 AC_ARG_WITH(logdir,
  88 [  --with-logdir=DIR       Directory for logfiles [LOCALSTATEDIR/log/radius] ],
  89 [ case "$withval" in
  90     no)
  91         AC_MSG_ERROR(Need logdir)
  92         ;;
  93     yes)
  94         ;;
  95     *)
  96         logdir="$withval"
  97         ;;
  98   esac ]
  99 )
 100 AC_SUBST(logdir)
 101 AC_MSG_RESULT($logdir)
 102
 103 dnl extra argument: --with-radacctdir
 104 radacctdir='${logdir}/radacct'
 105 AC_MSG_CHECKING(radacctdir)
 106 AC_ARG_WITH(radacctdir,
 107 [  --with-radacctdir=PATH  Directory for detail files [LOGDIR/radacct] ],
 108 [ case "$withval" in
 109     no)
 110         AC_MSG_ERROR(Need radacctdir)
 111         ;;
 112     yes)
 113         ;;
 114     *)
 115         radacctdir="$withval"
 116         ;;
 117   esac ]
 118 )
 119 AC_SUBST(radacctdir)
 120 AC_MSG_RESULT($radacctdir)
 121
 122 dnl extra argument: --with-raddbdir
 123 raddbdir='${sysconfdir}/raddb'
 124 AC_MSG_CHECKING(raddbdir)
 125 AC_ARG_WITH(raddbdir,
 126 [  --with-raddbdir=DIR     Directory for config files [SYSCONFDIR/raddb] ],
 127 [ case "$withval" in
 128     no)
 129         AC_MSG_ERROR(Need raddbdir)
 130         ;;
 131     yes)
 132         ;;
 133     *)
 134         raddbdir="$withval"
 135         ;;
 136   esac ]
 137 )
 138 AC_SUBST(raddbdir)
 139 AC_MSG_RESULT($raddbdir)
 140
 141 dnl extra argument: --with-dict-nocase
 142 WITH_DICT_NOCASE=yes
 143 AC_ARG_WITH(dict-nocase,
 144 [  --with-dict-nocase      Make dictionary case-independant (default=yes)],
 145 [  case "$withval" in
 146     yes)
 147         ;;
 148     *)
 149         WITH_DICT_NOCASE=""
 150   esac ]
 151 )
 152 if test "X$WITH_DICT_NOCASE" = "Xyes"; then
 153   AC_DEFINE(WITH_DICT_NOCASE)
 154 fi
 155
 156 dnl extra argument: --with-ascend-binary
 157 ASCEND_BINARY=yes
 158 AC_ARG_WITH(ascend-binary,
 159 [  --with-ascend-binary    Include support for Ascend binary filter attributes (default=yes)],
 160 [ case "$withval" in
 161     yes)
 162         ;;
 163     *)
 164         ASCEND_BINARY=""
 165   esac ]
 166 )
 167 if test "X$ASCEND_BINARY" = "Xyes"; then
 168   AC_DEFINE(ASCEND_BINARY)
 169 fi
 170
 171 dnl extra argument: --with-threads
 172 WITH_THREADS=yes
 173 WITH_THREAD_POOL=yes
 174 AC_ARG_WITH(threads,
 175 [  --with-threads          Use threads, if available.  (default=yes) ],
 176 [ case "$withval" in
 177     yes)
 178         ;;
 179     *)
 180         WITH_THREADS=""
 181         WITH_THREAD_POOL=""
 182   esac ]
 183 )
 184
 185 dnl extra argument: --with-snmp
 186 WITH_SNMP=yes
 187 AC_ARG_WITH(snmp,
 188 [  --with-snmp             Compile in SNMP support. (default=yes)],
 189 [ case "$withval" in
 190     yes)
 191         ;;
 192     *)
 193         WITH_SNMP=no
 194   esac ]
 195 )
 196
 197 AC_ARG_ENABLE(ltdl-install,
 198 [  --disable-ltdl-install  do not install libltdl])
 199 if test x"${enable_ltdl_install+set}" != xset; then
 200   enable_ltdl_install=yes
 201   ac_configure_args="$ac_configure_args --enable-ltdl-install"
 202 fi
 203 AC_CONFIG_SUBDIRS(libltdl)
 204
 205 dnl #
 206 dnl #  Allow the user to specify a list of modules to be linked
 207 dnl #  statically to the server.
 208 dnl #
 209 STATIC_MODULES=
 210 AC_ARG_WITH(static_modules,
 211 [  --with-static-modules=QUOTED-MODULE-LIST],[
 212   for i in $withval; do
 213     STATIC_MODULES="$STATIC_MODULES -dlpreopen ../modules/rlm_$i/rlm_$i.la"
 214   done
 215 ])
 216
 217 dnl #
 218 dnl #  Enable developer C compiler warnings
 219 dnl #
 220 AC_ARG_ENABLE(developer,
 221 [  --enable-developer      Turns on flags of interest to developers.],
 222 [ case "$withval" in
 223     *)
 224         developer=no
 225         ;;
 226     yes)
 227         developer=yes
 228   esac ]
 229 )
 230
 231 if test "x$developer" != "xno" -a -d $srcdir/CVS; then
 232   dnl turn on the developer flag when taken from a CVS checkout (not a release)
 233   developer="yes"
 234 fi
 235
 236 dnl #
 237 dnl #  These next two arguments don't actually do anything.  They're
 238 dnl #  place holders so that the top-level configure script can tell
 239 dnl #  the user how to configure lower-level modules
 240 dnl #
 241
 242 dnl #
 243 dnl # extra argument: --with-rlm-FOO-lib-dir
 244 dnl #
 245 AC_ARG_WITH(rlm-FOO-lib-dir,
 246 [  --with-rlm-FOO-lib-dir=DIR       Directory to look for library files used by module FOO],
 247 [ case "$withval" in
 248     *)
 249         ;;
 250   esac ]
 251 )
 252
 253 dnl #
 254 dnl # extra argument: --with-rlm-FOO-include-dir
 255 dnl #
 256 AC_ARG_WITH(rlm-FOO-include-dir,
 257 [  --with-rlm-FOO-include-dir=DIR   Directory to look for include files used by module FOO],
 258 [ case "$withval" in
 259     *)
 260         ;;
 261   esac ]
 262 )
 263
 264 dnl See what include-style is used by the make program.
 265 dnl AC_MSG_CHECKING(include style for make)
 266 dnl echo "include /dev/null" > testmake.$$
 267 dnl echo "all:" >> testmake.$$
 268 dnl make -f testmake.$$ >/dev/null 2>&1
 269 dnl if test $? = 0
 270 dnl then
 271 dnl     INCLUDE=include
 272 dnl     IQUOTE=
 273 dnl else
 274 dnl     INCLUDE=.include
 275 dnl     IQUOTE='"'
 276 dnl fi
 277 dnl rm -f testmake.$$
 278 dnl AC_MSG_RESULT(" $INCLUDE")
 279 dnl AC_SUBST(INCLUDE)
 280 dnl AC_SUBST(IQUOTE)
 281
 282 dnl #############################################################
 283 dnl #
 284 dnl #  1. Checks for programs
 285 dnl #
 286 dnl #############################################################
 287
 288 AC_PATH_PROG(PERL, perl, /usr/local/bin/perl)
 289 if test ! -x $ac_cv_path_PERL; then
 290   AC_MSG_ERROR(perl not found - fatal)
 291 fi
 292 AC_PATH_PROG(SNMPGET, snmpget, /usr/local/bin/snmpget)
 293 AC_PATH_PROG(SNMPWALK, snmpwalk, /usr/local/bin/snmpwalk)
 294 AC_PATH_PROG(RUSERS, rusers, /usr/bin/rusers)
 295
 296 dnl FIXME This is truly gross.
 297 missing_dir=`cd $ac_aux_dir && pwd`
 298 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
 299 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
 300 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
 301
 302 AC_PATH_PROG(LOCATE,locate)
 303 AC_PATH_PROG(DIRNAME,dirname)
 304 AC_PATH_PROG(GREP,grep)
 305
 306 dnl #
 307 dnl # check for AIX, to allow us to use some BSD functions
 308 dnl # must be before macros that call the compiler.
 309 dnl #
 310 AC_AIX
 311
 312 dnl #############################################################
 313 dnl #
 314 dnl #  2. Checks for libraries
 315 dnl #
 316 dnl #############################################################
 317
 318 dnl If using pthreads, check for -lpthread (posix) or -lc_r (*BSD)
 319 PTHREADLIB=
 320 if test "$WITH_THREADS" = "yes"; then
 321   if test $ac_cv_prog_suncc = "yes"; then
 322     CFLAGS="$CFLAGS -mt"
 323   fi
 324
 325   AC_CHECK_HEADERS(pthread.h)
 326
 327   if test "X$ac_cv_header_pthread_h" = "X"; then
 328     AC_MSG_ERROR("You are trying to use threads without a POSIX <pthread.h>")
 329   fi
 330
 331 dnl #
 332 dnl # pthread stuff is usually in -lpthread
 333 dnl #
 334   AC_CHECK_LIB(pthread, pthread_join,
 335     PTHREADLIB="-lpthread"
 336   )
 337
 338 dnl # HP/UX requires linking with librt, too, to get the sem_* symbols.  :\
 339
 340   AC_SEARCH_LIBS(sem_init, pthread rt,
 341         [
 342         dnl    Er, this usage of $ac_cv_search_sem_init may be unfounded
 343         dnl    chumminess with the autoconf internals.  -chad
 344         PTHREADLIB="$PTHREADLIB $ac_cv_search_sem_init"
 345         ],
 346         [],
 347         "-lpthread"
 348   )
 349
 350 dnl #
 351 dnl # Except for *BSD, where it's in -lc_r,
 352 dnl # and where we've got to add extra CFLAGS.
 353 dnl #
 354   if test "X$PTHREADLIB" = "X"; then
 355     SAVED_CFLAGS=$CFLAGS
 356     CFLAGS="$CFLAGS -pthread -D_THREAD_SAFE"
 357     AC_CHECK_LIB(c_r, pthread_create,
 358       PTHREADLIB="-lc_r"
 359     )
 360   fi
 361
 362 dnl # Set libs, etc, if we have them.
 363   if test "x$PTHREADLIB" != "x"; then
 364     LIBS="$LIBS $PTHREADLIB"
 365     CFLAGS="$CFLAGS -D_REENTRANT -D_POSIX_PTHREAD_SEMANTICS"
 366   fi
 367 fi
 368
 369 dnl #
 370 dnl # If we have NO pthread libraries, remove any knowledge of threads.
 371 dnl #
 372 if test "x$PTHREADLIB" = "x"; then
 373   CFLAGS=$SAVED_CFLAGS
 374   ac_cv_header_pthread_h="no"
 375   WITH_THREADS=no
 376   WITH_THREAD_POOL=no
 377 fi
 378
 379 dnl Check if we need -lsocket
 380 AC_CHECK_LIB(socket, getsockname)
 381
 382 dnl Check for -lresolv
 383 dnl This library may be needed later.
 384 AC_CHECK_LIB(resolv, inet_aton)
 385
 386 dnl Check if we need -lnsl. Usually if we want to
 387 dnl link against -lsocket we need to include -lnsl as well.
 388 AC_CHECK_LIB(nsl, inet_ntoa)
 389
 390 dnl #############################################################
 391 dnl #
 392 dnl #  3. Checks for header files
 393 dnl #
 394 dnl #############################################################
 395
 396 AC_HEADER_DIRENT
 397 AC_HEADER_STDC
 398 AC_HEADER_TIME
 399 AC_HEADER_SYS_WAIT
 400
 401 AC_CHECK_HEADERS( \
 402         unistd.h \
 403         crypt.h \
 404         errno.h \
 405         resource.h \
 406         getopt.h \
 407         malloc.h \
 408         utmp.h \
 409         utmpx.h \
 410         signal.h \
 411         sys/select.h \
 412         syslog.h \
 413         inttypes.h \
 414         stdint.h \
 415         stdio.h \
 416         netdb.h \
 417         semaphore.h \
 418         arpa/inet.h \
 419         netinet/in.h \
 420         sys/types.h \
 421         sys/socket.h \
 422         sys/time.h \
 423         sys/security.h \
 424         prot.h \
 425         sia.h \
 426         siad.h
 427 )
 428
 429 REGEX=no
 430 AC_CHECK_HEADER(regex.h, AC_DEFINE(HAVE_REGEX_H))
 431 if test "x$ac_cv_header_regex_h" = "xyes"; then
 432   REGEX_EXTENDED=no
 433   REGEX=yes
 434   AC_EGREP_CPP(yes,
 435     [#include <regex.h>
 436      #ifdef REG_EXTENDED
 437        yes
 438      #endif
 439      ], [AC_DEFINE(HAVE_REG_EXTENDED) REGEX_EXTENDED=yes])
 440 fi
 441 AC_SUBST(REGEX)
 442 AC_SUBST(REGEX_EXTENDED)
 443
 444 dnl #
 445 dnl #  other checks which require headers
 446 dnl #
 447 if test "x$ac_cv_header_sys_security_h" = "xyes" && test "x$ac_cv_header_prot_h" = "xyes"
 448 then
 449   AC_DEFINE(OSFC2)
 450 fi
 451
 452 if test "x$ac_cv_header_sia_h" = "xyes" && test "x$ac_cv_header_siad_h" = "xyes"
 453 then
 454   AC_DEFINE(OSFSIA)
 455 fi
 456
 457
 458 dnl #############################################################
 459 dnl #
 460 dnl #  4. Checks for typedefs
 461 dnl #
 462 dnl #############################################################
 463
 464 dnl #
 465 dnl # Ensure that these are defined
 466 dnl #
 467 AC_TYPE_OFF_T
 468 AC_TYPE_PID_T
 469 AC_TYPE_SIZE_T
 470 AC_TYPE_UID_T
 471
 472 dnl check for socklen_t
 473 AC_CHECK_TYPE_INCLUDE([
 474 #ifdef HAVE_SYS_TYPES_H
 475 #include <sys/types.h>
 476 #endif
 477 #ifdef HAVE_SYS_SOCKET_H
 478 #include <sys/socket.h>
 479 #endif
 480 ],socklen_t, int)
 481
 482 dnl check for uint8_t
 483 AC_CHECK_TYPE_INCLUDE([
 484 #ifdef HAVE_INTTYPES_H
 485 #include <inttypes.h>
 486 #endif
 487 #ifdef HAVE_STDINT_H
 488 #include <stdint.h>
 489 #endif
 490 ],uint8_t, unsigned char)
 491
 492 dnl check for uint32_t
 493 AC_CHECK_TYPE_INCLUDE([
 494 #ifdef HAVE_INTTYPES_H
 495 #include <inttypes.h>
 496 #endif
 497 #ifdef HAVE_STDINT_H
 498 #include <stdint.h>
 499 #endif
 500 ],uint32_t, unsigned int)
 501
 502 dnl #############################################################
 503 dnl #
 504 dnl #  5. Checks for structures and functions
 505 dnl #
 506 dnl #############################################################
 507 AC_CHECK_FUNCS( \
 508         getopt_long \
 509         lockf \
 510         strsignal \
 511         sigaction \
 512         sigprocmask \
 513         pthread_sigmask \
 514         snprintf \
 515         vsnprintf \
 516         setsid \
 517         strncasecmp \
 518         strcasecmp \
 519         localtime_r \
 520         ctime_r \
 521         strsep \
 522         inet_aton \
 523         gethostname \
 524         setlinebuf \
 525         setvbuf \
 526         sem_init \
 527         getusershell
 528 )
 529 RADIUSD_NEED_DECLARATIONS( \
 530         crypt \
 531         strncasecmp \
 532         strcasecmp \
 533         inet_aton \
 534         gethostname \
 535         setlinebuf \
 536         getusershell \
 537         endusershell
 538 )
 539
 540 AC_TYPE_SIGNAL
 541
 542 dnl # check if we have utmpx.h
 543 dnl # if so, check if struct utmpx has entry ut_xtime
 544 dnl # if not, set it to define ut_xtime == ut_tv.tv_sec
 545 if test "x$ac_cv_header_utmpx_h" = "xyes"
 546 then
 547  AC_CHECK_STRUCT_HAS_MEMBER([#include <utmpx.h>], [struct utmpx], ut_xtime)
 548  if test "x$ac_cv_type_struct_utmpx_ut_xtime" = "x"
 549  then
 550    AC_DEFINE(ut_xtime,ut_tv.tv_sec)
 551  fi
 552 fi
 553
 554 dnl #############################################################
 555 dnl #
 556 dnl #  6. Checks for compiler characteristics
 557 dnl #
 558 dnl #############################################################
 559
 560 dnl #
 561 dnl # Ensure that these are defined
 562 dnl #
 563 AC_C_CONST
 564
 565 dnl #
 566 dnl # See if this is OS/2
 567 dnl #
 568 AC_MSG_CHECKING(type of OS)
 569 OS=`uname -s`
 570 AC_MSG_RESULT($OS)
 571 if test "$OS" = "OS/2"; then
 572         LIBPREFIX=
 573 else
 574         LIBPREFIX=lib
 575 fi
 576 AC_SUBST(LIBPREFIX)
 577
 578 dnl #
 579 dnl # Set Default CFLAGS
 580 dnl #
 581 if test "x$GCC" = "xyes"; then
 582     CFLAGS="$CFLAGS -Wall -D_GNU_SOURCE"
 583 fi
 584
 585 AC_MSG_CHECKING(for developer gcc flags)
 586 if test "x$developer" = "xyes" -a "x$GCC" = "xyes"; then
 587   devflags="-g -Wshadow -Wpointer-arith -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wmissing-prototypes -Wmissing-declarations -Wnested-externs"
 588   CFLAGS="$CFLAGS $devflags"
 589   INSTALLSTRIP=""
 590   AC_MSG_RESULT(yes.  Using $devflags)
 591 else
 592   devflags=""
 593   CFLAGS="$CFLAGS -DNDEBUG"
 594   INSTALLSTRIP="-s"
 595   AC_MSG_RESULT(no.)
 596 fi
 597
 598 dnl #############################################################
 599 dnl #
 600 dnl #  7. Checks for library functions
 601 dnl #
 602 dnl #############################################################
 603
 604 dnl Check for libcrypt
 605 dnl We use crypt(3) which may be in libc, or in libcrypt (eg FreeBSD)
 606 AC_CHECK_LIB(crypt, crypt,
 607   CRYPTLIB="-lcrypt"
 608 )
 609 if test "$CRYPTLIB" != ""; then
 610   AC_DEFINE(HAVE_CRYPT)
 611 else
 612   AC_CHECK_FUNC(crypt, AC_DEFINE(HAVE_CRYPT))
 613 fi
 614
 615 dnl Check for libcipher
 616 AC_CHECK_LIB(cipher, setkey,
 617    CRYPTLIB="${CRYPTLIB} -lcipher"
 618 )
 619 AC_SUBST(CRYPTLIB)
 620
 621 if test "x$WITH_SNMP" = "xyes"; then
 622   SNMP_CHECKS
 623 fi
 624
 625 dnl #
 626 dnl #  Check for sem_init all by itself
 627 dnl #
 628 if test "X$ac_cv_func_sem_init" = "Xno"; then
 629
 630 dnl #
 631 dnl #  If not found, sem_init is in -lposix4 on Solaris
 632 dnl #
 633  AC_CHECK_LIB(posix4, sem_init)
 634
 635   if test "X$ac_cv_lib_posix4_sem_init" = "X"; then
 636     if test "$WITH_THREAD_POOL" = "yes"; then
 637       AC_MSG_WARN(You do not have posix semaphores.  Disabling thread pools)
 638     fi
 639     WITH_THREAD_POOL=no
 640   fi
 641 fi
 642
 643 ODBC_CHECKS
 644
 645 dnl #############################################################
 646 dnl #
 647 dnl #  8. Checks for system services
 648 dnl #
 649 dnl #############################################################
 650
 651 dnl #
 652 dnl # Figure out where libtool is located,
 653 dnl #
 654 LIBTOOL="`pwd`/libtool"
 655 AC_SUBST(LIBTOOL)
 656 AC_SUBST(LIBLTDL)
 657 AC_SUBST(INCLTDL)
 658 top_builddir=`pwd`
 659 AC_SUBST(top_builddir)
 660
 661 dnl import libtool stuff
 662
 663 dnl #
 664 dnl #  Checks to ensure that the thread pool code can build.
 665 dnl #
 666 if test "$WITH_THREAD_POOL" = "yes"; then
 667   dnl #
 668   dnl # If using thread pools, check that threading is enabled
 669   dnl #
 670   if test "$WITH_THREADS" != "yes"; then
 671     AC_MSG_ERROR(You must have threads enabled for thread pools to work.)
 672   fi
 673
 674   dnl #
 675   dnl # If using thread pools, check that we have thread libraries
 676   dnl #
 677   if test "X$PTHREADLIB" = "X"; then
 678     AC_MSG_ERROR(You must have threading libraries for thread pools to work.)
 679   fi
 680
 681 fi
 682
 683 dnl #############################################################
 684 dnl #
 685 dnl #  Configure in any module directories.
 686 dnl #
 687 dnl #############################################################
 688
 689 mysubdirs=
 690 for foo in `find src/modules -name configure -print`; do
 691   bar=`echo $foo | sed 's%/configure$%%g'`
 692   mysubdirs="$mysubdirs $bar"
 693 done
 694
 695 dnl #
 696 dnl #  Don't change the variable name here.  Autoconf goes bonkers
 697 dnl #  if you do.
 698 dnl #
 699 AC_CONFIG_SUBDIRS($mysubdirs)
 700
 701 dnl #############################################################
 702 dnl #
 703 dnl #  And finally, output the results.
 704 dnl #
 705 dnl #############################################################
 706
 707 dnl #
 708 dnl #  Substitute whatever libraries we found to be necessary
 709 dnl #
 710 AC_SUBST(LIBS)
 711 AC_SUBST(INSTALLSTRIP)
 712
 713 USE_SHARED_LIBS=$enable_shared
 714 AC_SUBST(USE_SHARED_LIBS)
 715 USE_STATIC_LIBS=$enable_static
 716 AC_SUBST(USE_STATIC_LIBS)
 717 AC_SUBST(STATIC_MODULES)
 718 AC_SUBST(RADIUSD_MAJOR_VERSION)
 719 AC_SUBST(RADIUSD_MINOR_VERSION)
 720 AC_SUBST(RADIUSD_VERSION)
 721 export CFLAGS LIBS
 722
 723 AC_OUTPUT(\
 724         ./Make.inc \
 725         ./src/include/build-radpaths-h \
 726         ./src/main/checkrad.pl \
 727         ./src/main/radlast \
 728         ./src/main/radtest \
 729         ./scripts/rc.radiusd \
 730         ./scripts/radwatch \
 731         ./scripts/check-radiusd-config \
 732         ./scripts/radiusd.cron.daily \
 733         ./scripts/radiusd.cron.monthly \
 734         ./scripts/cryptpasswd \
 735         ./raddb/radiusd.conf
 736 )
 737
 738 AC_OUTPUT_COMMANDS([echo timestamp > src/include/stamp-h])
 739 AC_OUTPUT_COMMANDS([(cd ./src/include && /bin/sh ./build-radpaths-h)])
 740 AC_OUTPUT_COMMANDS([(cd ./src/main   && chmod +x checkrad.pl radlast radtest)])
 741 AC_OUTPUT_COMMANDS([(cd ./scripts    && chmod +x rc.radiusd radwatch check-radiusd-config radiusd.cron.daily radiusd.cron.monthly cryptpasswd)])
 742 AC_OUTPUT_COMMANDS([
 743 cat >> src/include/autoconf.h <<EOF
 744
 745 #define HOSTINFO        "$host"
 746 #define RADIUSD_VERSION "$RADIUSD_VERSION"
 747 EOF
 748 ],host=$host)