configure.in

   1 dnl #############################################################
   2 dnl #
   3 dnl #  For information about autoconf, see:
   4 dnl #
   5 dnl #  http://www.gnu.org/software/autoconf/
   6 dnl #
   7 dnl #  The recommended order is:
   8 dnl #
   9 dnl #  AC_INIT(file)
  10 dnl #  0. checks for compiler, libtool, and command line options
  11 dnl #  1. checks for programs
  12 dnl #  2. checks for libraries
  13 dnl #  3. checks for header files
  14 dnl #  4. checks for typedefs
  15 dnl #  5. checks for structures and functions
  16 dnl #  6. checks for compiler characteristics
  17 dnl #  7. checks for library functions
  18 dnl #  8. checks for system services
  19 dnl #  AC_OUTPUT([file...])
  20 dnl #
  21 dnl #############################################################
  22
  23 AC_INIT(src/main/radiusd.c)
  24 AC_CONFIG_HEADER(src/include/autoconf.h)
  25 AC_REVISION($Revision$)dnl
  26 dnl AC_PREFIX_DEFAULT(/usr/local)
  27
  28 dnl #############################################################
  29 dnl #
  30 dnl #  0. Checks for compiler, libtool, and command line options.
  31 dnl #
  32 dnl #############################################################
  33
  34 dnl Check for GNU cc
  35 AC_PROG_CC
  36 AC_PROG_GCC_TRADITIONAL
  37 AC_PROG_RANLIB
  38
  39 PACKAGE=freeradius
  40
  41 dnl Find GNU Make.
  42 AC_CHECK_PROG(GMAKE, gmake, yes, no)
  43 if test $GMAKE = no; then
  44   AC_PATH_PROG(MAKE, make, /usr/local/bin/make)
  45 else
  46   AC_PATH_PROG(MAKE, gmake, /usr/local/gnu/bin/make)
  47 fi
  48 makever=`$ac_cv_path_MAKE --version 2>&1 | grep "GNU Make"`
  49 if test -z "$makever"; then
  50   AC_MSG_ERROR(GNU Make is not installed.  Please download and install it
  51                 from ftp://prep.ai.mit.edu/pub/gnu/make/ before continuing.)
  52 fi
  53
  54 dnl libltdl is installable
  55 AC_LIBLTDL_INSTALLABLE
  56
  57 dnl ensure that we're looking for dlopen
  58 AC_LIBTOOL_DLOPEN
  59
  60 dnl Figure out how to build shared libraries
  61 AC_PROG_LIBTOOL
  62
  63 dnl extra argument: --with-logdir
  64 logdir='${localstatedir}/log'
  65 AC_MSG_CHECKING(logdir)
  66 AC_ARG_WITH(logdir,
  67 [  --with-logdir=DIR       Directory for logfiles [LOCALSTATEDIR/log] ],
  68 [ case "$withval" in
  69     no)
  70         AC_MSG_ERROR(Need logdir)
  71         ;;
  72     yes)
  73         ;;
  74     *)
  75         logdir="$withval"
  76         ;;
  77   esac ]
  78 )
  79 AC_SUBST(logdir)
  80 AC_MSG_RESULT($logdir)
  81
  82 dnl extra argument: --with-radacctdir
  83 radacctdir='${logdir}/radacct'
  84 AC_MSG_CHECKING(radacctdir)
  85 AC_ARG_WITH(radacctdir,
  86 [  --with-radacctdir=PATH  Directory for detail files [LOGDIR/radacct] ],
  87 [ case "$withval" in
  88     no)
  89         AC_MSG_ERROR(Need radacctdir)
  90         ;;
  91     yes)
  92         ;;
  93     *)
  94         radacctdir="$withval"
  95         ;;
  96   esac ]
  97 )
  98 AC_SUBST(radacctdir)
  99 AC_MSG_RESULT($radacctdir)
 100
 101 dnl extra argument: --with-raddbdir
 102 raddbdir='${sysconfdir}/raddb'
 103 AC_MSG_CHECKING(raddbdir)
 104 AC_ARG_WITH(raddbdir,
 105 [  --with-raddbdir=DIR     Directory for config files [SYSCONFDIR/raddb] ],
 106 [ case "$withval" in
 107     no)
 108         AC_MSG_ERROR(Need raddbdir)
 109         ;;
 110     yes)
 111         ;;
 112     *)
 113         raddbdir="$withval"
 114         ;;
 115   esac ]
 116 )
 117 AC_SUBST(raddbdir)
 118 AC_MSG_RESULT($raddbdir)
 119
 120 dnl extra argument: --with-dbm
 121 DBMLIB=
 122 BUILDDBM=
 123 AC_ARG_WITH(dbm,
 124 [  --with-dbm              Compile in DBM support],
 125 [ case "$withval" in
 126     no)
 127         ;;
 128     yes)
 129         AC_DEFINE(WITH_DBM)
 130         DBMLIB=-ldbm
 131         BUILDDBM=builddbm
 132   esac ]
 133 )
 134
 135 dnl extra argument: --with-ndbm
 136 AC_ARG_WITH(ndbm,
 137 [  --with-ndbm             Compile in NDBM support],
 138 [ case "$withval" in
 139     no)
 140         ;;
 141     yes)
 142         AC_DEFINE(WITH_NDBM)
 143         DBMLIB=-ldb
 144         BUILDDBM=builddbm
 145   esac ]
 146 )
 147
 148 AC_SUBST(DBMLIB)
 149 AC_SUBST(BUILDDBM)
 150
 151 dnl extra argument: --with-ascend-hack
 152 AC_ARG_WITH(ascend-hack,
 153 [  --with-ascend-hack      Include Ascend hacks],
 154 [ case "$withval" in
 155     no)
 156         ;;
 157     yes)
 158         AC_DEFINE(WITH_ASCEND_HACK)
 159         dnl if they haven't said to use it, do so.
 160         if test "${with_ascend_cpl+set}" != "set"; then
 161                 with_ascend_cpl=23
 162         fi
 163     esac ]
 164 )
 165
 166 dnl extra argument: --with-ascend-cpl=N
 167 AC_ARG_WITH(ascend-cpl,
 168 [  --with-ascend-cpl=N     Set Ascend Channels Per Line to N [23] ],
 169 [ case "$withval" in
 170     *)
 171         AC_DEFINE_UNQUOTED(ASCEND_CHANNELS_PER_LINE, $withval)
 172   esac ]
 173 )
 174
 175 dnl extra argument: --with-ntdomain-hack
 176 AC_ARG_WITH(ntdomain-hack,
 177 [  --with-ntdomain-hack    Include NT Domain hack],
 178 [ case "$withval" in
 179     no)
 180         ;;
 181     yes)
 182         AC_DEFINE(WITH_NTDOMAIN_HACK)
 183   esac ]
 184 )
 185
 186 dnl extra argument: --with-spcj-hack
 187 AC_ARG_WITH(spcj-hack,
 188 [  --with-spcj-hack        Include Specialix Jetstream hacks],
 189 [ case "$withval" in
 190     no)
 191         ;;
 192     yes)
 193         AC_DEFINE(WITH_SPECIALIX_JETSTREAM_HACK)
 194   esac ]
 195 )
 196
 197 dnl extra argument: --with-dict-nocase
 198 WITH_DICT_NOCASE=yes
 199 AC_ARG_WITH(dict-nocase,
 200 [  --with-dict-nocase      Make dictionary case-independant (default=yes)],
 201 [  case "$withval" in
 202     yes)
 203         ;;
 204     *)
 205         WITH_DICT_NOCASE=""
 206   esac ]
 207 )
 208 if test "X$WITH_DICT_NOCASE" = "Xyes"; then
 209   AC_DEFINE(WITH_DICT_NOCASE)
 210 fi
 211
 212 dnl extra argument: --with-attrib-nmc
 213 ATTRIB_NMC=yes
 214 AC_ARG_WITH(attrib-nmc,
 215 [  --with-attrib-nmc       Include USR-style vendor specific attributes (default=yes)],
 216 [ case "$withval" in
 217     yes)
 218         ;;
 219     *)
 220         ATTRIB_NMC=""
 221   esac ]
 222 )
 223 if test "X$ATTRIB_NMC" = "Xyes"; then
 224   AC_DEFINE(ATTRIB_NMC)
 225 fi
 226
 227 dnl extra argument: --with-ascend-binary
 228 ASCEND_BINARY=yes
 229 AC_ARG_WITH(ascend-binary,
 230 [  --with-ascend-binary    Include support for Ascend binary filter attributes (default=yes)],
 231 [ case "$withval" in
 232     yes)
 233         ;;
 234     *)
 235         ASCEND_BINARY=""
 236   esac ]
 237 )
 238 if test "X$ASCEND_BINARY" = "Xyes"; then
 239   AC_DEFINE(ASCEND_BINARY)
 240 fi
 241
 242 dnl extra argument: --with-threads
 243 WITH_THREADS=yes
 244 AC_ARG_WITH(threads,
 245 [  --with-threads          Use threads, if available.  (default=yes) ],
 246 [ case "$withval" in
 247     yes)
 248         ;;
 249     *)
 250         WITH_THREADS=""
 251   esac ]
 252 )
 253
 254 dnl extra argument: --with-thread-pool
 255 WITH_THREAD_POOL=no
 256 AC_ARG_WITH(thread-pool,
 257 [  --with-thread-pool      Use a pool of threads for high-load systems.  (default=no) ],
 258 [ case "$withval" in
 259     *)
 260         WITH_THREAD_POOL=$withval
 261   esac ]
 262 )
 263
 264 AC_ARG_ENABLE(ltdl-install,
 265 [  --disable-ltdl-install  do not install libltdl])
 266 if test x"${enable_ltdl_install+set}" != xset; then
 267   enable_ltdl_install=yes
 268   ac_configure_args="$ac_configure_args --enable-ltdl-install"
 269 fi
 270 AC_CONFIG_SUBDIRS(src/libltdl)
 271
 272 dnl See what include-style is used by the make program.
 273 dnl AC_MSG_CHECKING(include style for make)
 274 dnl echo "include /dev/null" > testmake.$$
 275 dnl echo "all:" >> testmake.$$
 276 dnl make -f testmake.$$ >/dev/null 2>&1
 277 dnl if test $? = 0
 278 dnl then
 279 dnl     INCLUDE=include
 280 dnl     IQUOTE=
 281 dnl else
 282 dnl     INCLUDE=.include
 283 dnl     IQUOTE='"'
 284 dnl fi
 285 dnl rm -f testmake.$$
 286 dnl AC_MSG_RESULT(" $INCLUDE")
 287 dnl AC_SUBST(INCLUDE)
 288 dnl AC_SUBST(IQUOTE)
 289
 290 dnl #############################################################
 291 dnl #
 292 dnl #  1. Checks for programs
 293 dnl #
 294 dnl #############################################################
 295
 296 AC_PATH_PROG(PERL, perl, /usr/local/bin/perl)
 297 if test ! -x $ac_cv_path_PERL; then
 298   AC_MSG_ERROR(perl not found - fatal)
 299 fi
 300 AC_PATH_PROG(SNMPGET, snmpget, /usr/local/bin/snmpget)
 301 AC_PATH_PROG(SNMPWALK, snmpwalk, /usr/local/bin/snmpwalk)
 302 AC_PATH_PROG(RUSERS, rusers, /usr/bin/rusers)
 303
 304 dnl FIXME This is truly gross.
 305 missing_dir=`cd $ac_aux_dir && pwd`
 306 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
 307 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
 308 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
 309
 310 dnl #
 311 dnl # check for AIX, to allow us to use some BSD functions
 312 dnl # must be before macros that call the compiler.
 313 dnl #
 314 AC_AIX
 315
 316 dnl #############################################################
 317 dnl #
 318 dnl #  2. Checks for libraries
 319 dnl #
 320 dnl #############################################################
 321
 322 dnl If using pthreads, check for -lpthread (posix) or -lc_r (*BSD)
 323 PTHREADLIB=
 324 if test "$WITH_THREADS" = "yes"; then
 325   AC_CHECK_HEADERS(pthread.h)
 326
 327   if test "X$ac_cv_header_pthread_h" = "X"; then
 328     AC_MSG_ERROR("You are trying to use threads without a POSIX <pthread.h>")
 329   fi
 330
 331 dnl #
 332 dnl # pthread stuff is usually in -lpthread
 333 dnl #
 334   AC_CHECK_LIB(pthread, pthread_create,
 335     PTHREADLIB="-lpthread"
 336   )
 337
 338 dnl #
 339 dnl # Except for *BSD, where it's in -lc_r,
 340 dnl # and where we've got to add extra CFLAGS.
 341 dnl #
 342   if test "X$PTHREADLIB" = "X"; then
 343     SAVED_CFLAGS=$CFLAGS
 344     CFLAGS="$CFLAGS -pthread -D_THREAD_SAFE"
 345     AC_CHECK_LIB(c_r, pthread_create,
 346       PTHREADLIB="-lc_r"
 347     )
 348   fi
 349   LIBS="$LIBS $PTHREADLIB"
 350   CFLAGS="$CFLAGS -D_REENTRANT"
 351 fi
 352
 353 dnl #
 354 dnl #  Checks to ensure that the thread pool code can build.
 355 dnl #
 356 if test "$WITH_THREAD_POOL" = "yes"; then
 357   dnl #
 358   dnl # If using thread pools, check that threading is enabled
 359   dnl #
 360   if test "$WITH_THREADS" != "yes"; then
 361     AC_MSG_ERROR(You must have threads enabled for thread pools to work.)
 362   fi
 363
 364   dnl #
 365   dnl # If using thread pools, check that we have thread libraries
 366   dnl #
 367   if test "X$PTHREADLIB" = "X"; then
 368     AC_MSG_ERROR(You must have threading libraries for thread pools to work.)
 369   fi
 370
 371 dnl #
 372 dnl #  Check for sem_init all by itself
 373 dnl #
 374   AC_CHECK_FUNC(sem_init)
 375   if test "X$ac_cv_func_sem_init" = "Xno"; then
 376
 377 dnl #
 378 dnl #  If not found, sem_init is in -lposix4 on Solaris
 379 dnl #
 380     AC_CHECK_LIB(posix4, sem_init)
 381
 382     if test "X$ac_cv_lib_posix4_sem_init" = "X"; then
 383       AC_MSG_WARN(You do not have posix semaphores.  Disabling thread pools)
 384       WITH_THREAD_POOL=no
 385     fi
 386   fi
 387
 388 dnl #
 389 dnl #  Finally, after all of the checks above, we see if
 390 dnl #  we can REALLY use the thread pools.
 391 dnl #
 392   if test "$WITH_THREAD_POOL" = "yes"; then
 393     AC_DEFINE(WITH_THREAD_POOL,1)
 394   fi
 395 fi
 396
 397 dnl Check if we need -lsocket
 398 AC_CHECK_LIB(socket, getsockname)
 399
 400 dnl Check for -lresolv
 401 dnl This library may be needed later.
 402 AC_CHECK_LIB(resolv, inet_aton)
 403
 404 dnl Check if we need -lnsl. Usually if we want to
 405 dnl link against -lsocket we need to include -lnsl as well.
 406 AC_CHECK_LIB(nsl, inet_ntoa)
 407
 408 dnl #############################################################
 409 dnl #
 410 dnl #  3. Checks for header files
 411 dnl #
 412 dnl #############################################################
 413
 414 AC_HEADER_DIRENT
 415 AC_HEADER_STDC
 416 AC_HEADER_TIME
 417 AC_HEADER_SYS_WAIT
 418
 419 AC_CHECK_HEADERS( \
 420         unistd.h \
 421         crypt.h \
 422         errno.h \
 423         resource.h \
 424         getopt.h \
 425         malloc.h \
 426         utmp.h \
 427         utmpx.h \
 428         sys/select.h \
 429         dlfcn.h \
 430         regex.h \
 431         syslog.h \
 432         inttypes.h \
 433         stdint.h \
 434         arpa/inet.h \
 435         sys/time.h
 436 )
 437
 438 dnl #############################################################
 439 dnl #
 440 dnl #  4. Checks for typedefs
 441 dnl #
 442 dnl #############################################################
 443
 444 dnl #
 445 dnl # Ensure that these are defined
 446 dnl #
 447 AC_TYPE_OFF_T
 448 AC_TYPE_PID_T
 449 AC_TYPE_SIZE_T
 450 AC_TYPE_UID_T
 451
 452 dnl Check for socklen_t
 453 AC_CACHE_CHECK(for socklen_t,
 454                fr_cv_socklen_t,
 455     [ fr_cv_socklen_t=no
 456       AC_TRY_COMPILE([#include <sys/types.h>
 457         #include <sys/socket.h>],
 458         [socklen_t foo],
 459         fr_cv_socklen_t=yes,
 460       )
 461      ]
 462 )
 463
 464 if test "$fr_cv_socklen_t" != "yes"; then
 465          AC_DEFINE(socklen_t, int)
 466 fi
 467
 468 dnl Check for uint8_t
 469 AC_CACHE_CHECK(for uint8_t,
 470                fr_cv_uint8_t,
 471      [ fr_cv_uint8_t=no
 472        AC_TRY_COMPILE([
 473 #ifdef HAVE_INTTYPES_H
 474 #include <inttypes.h>
 475 #endif
 476 #ifdef HAVE_STDINT_H
 477 #include <stdint.h>
 478 #endif
 479 ],
 480          [uint8_t foo],
 481          fr_cv_uint8_t=yes
 482        )
 483      ]
 484 )
 485
 486 if test "$fr_cv_uint8_t" != "yes"; then
 487          AC_DEFINE(uint8_t, unsigned char)
 488 fi
 489
 490 dnl Check for uint32_t
 491 AC_CACHE_CHECK(for uint32_t,
 492                fr_cv_uint32_t,
 493      [ fr_cv_uint32_t=no
 494        AC_TRY_COMPILE([
 495 #ifdef HAVE_INTTYPES_H
 496 #include <inttypes.h>
 497 #endif
 498 #ifdef HAVE_STDINT_H
 499 #include <stdint.h>
 500 #endif
 501 ],
 502          [uint32_t foo],
 503          fr_cv_uint32_t=yes
 504        )
 505      ]
 506 )
 507
 508 if test "$fr_cv_uint32_t" != "yes"; then
 509         AC_DEFINE(uint32_t, unsigned int)
 510         UINT32_T_AS_INT=yes
 511 fi
 512
 513 dnl #
 514 dnl #  If we don't have uint32_t, then verify that sizeof(unsigned int)==4
 515 dnl #  If the integers are NOT 4 octets long, then the previous definition
 516 dnl #  won't work, and we won't produce correct RADIUS packets.
 517 dnl #
 518 if test "x$UINT32_T_AS_INT" != "x"; then
 519   AC_CHECK_SIZEOF(unsigned int, [4])
 520 fi
 521
 522 dnl #############################################################
 523 dnl #
 524 dnl #  5. Checks for structures and functions
 525 dnl #
 526 dnl #############################################################
 527 AC_CHECK_FUNCS( \
 528         getopt_long \
 529         lockf \
 530         strsignal \
 531         sigaction \
 532         sigprocmask \
 533         snprintf \
 534         vsnprintf \
 535         setsid \
 536         strncasecmp \
 537         strcasecmp \
 538         strsep \
 539         inet_aton \
 540         gethostname \
 541         setlinebuf \
 542         getusershell
 543 )
 544 RADIUSD_NEED_DECLARATIONS( \
 545         crypt \
 546         strncasecmp \
 547         strcasecmp \
 548         inet_aton \
 549         gethostname \
 550         setlinebuf \
 551         getusershell \
 552         endusershell
 553 )
 554
 555 AC_TYPE_SIGNAL
 556
 557 dnl #############################################################
 558 dnl #
 559 dnl #  6. Checks for compiler characteristics
 560 dnl #
 561 dnl #############################################################
 562
 563 dnl #
 564 dnl # Ensure that these are defined
 565 dnl #
 566 AC_C_CONST
 567
 568 dnl #
 569 dnl # See if this is OS/2
 570 dnl #
 571 AC_MSG_CHECKING(type of OS)
 572 OS=`uname -s`
 573 AC_MSG_RESULT($OS)
 574 if test "$OS" = "OS/2"; then
 575         LIBPREFIX=
 576 else
 577         LIBPREFIX=lib
 578 fi
 579 AC_SUBST(LIBPREFIX)
 580
 581 dnl #
 582 dnl # Set Default CFLAGS
 583 dnl #
 584 if test "$GCC" = "yes"; then
 585     CFLAGS="$CFLAGS -Wall -D_GNU_SOURCE"
 586 fi
 587
 588 dnl #############################################################
 589 dnl #
 590 dnl #  7. Checks for library functions
 591 dnl #
 592 dnl #############################################################
 593
 594 dnl Check for libcrypt
 595 dnl We use crypt(3) which may be in libc, or in libcrypt (eg FreeBSD)
 596 AC_CHECK_LIB(crypt, crypt,
 597   CRYPTLIB="-lcrypt"
 598 )
 599 AC_SUBST(CRYPTLIB)
 600 if test "$CRYPTLIB" != ""; then
 601   AC_DEFINE(HAVE_CRYPT)
 602 else
 603   AC_CHECK_FUNC(crypt, AC_DEFINE(HAVE_CRYPT))
 604 fi
 605
 606 dnl #############################################################
 607 dnl #
 608 dnl #  8. Checks for system services
 609 dnl #
 610 dnl #############################################################
 611
 612 dnl #
 613 dnl # Figure out where libtool is located,
 614 dnl #
 615 LIBTOOL="`pwd`/libtool"
 616 AC_SUBST(LIBTOOL)
 617 AC_SUBST(LIBLTDL)
 618 AC_SUBST(INCLTDL)
 619
 620 dnl #############################################################
 621 dnl #
 622 dnl #  And finally, output the results.
 623 dnl #
 624 dnl #############################################################
 625
 626 dnl #
 627 dnl #  Substitute whatever libraries we found to be necessary
 628 dnl #
 629 AC_SUBST(LIBS)
 630
 631 AC_OUTPUT(\
 632         ./Make.inc \
 633         ./src/include/build-radpaths-h \
 634         ./src/main/checkrad.pl \
 635         ./src/main/radlast \
 636         ./src/main/radtest \
 637         ./scripts/rc.radiusd \
 638         ./scripts/radwatch \
 639         ./scripts/check-radiusd-config \
 640         ./raddb/radiusd.conf
 641 )
 642
 643 AC_OUTPUT_COMMANDS([echo timestamp > src/include/stamp-h])
 644 AC_OUTPUT_COMMANDS([(cd ./src/include && /bin/sh ./build-radpaths-h)])
 645 AC_OUTPUT_COMMANDS([(cd ./src/main   && chmod +x checkrad.pl radlast radtest)])
 646 AC_OUTPUT_COMMANDS([(cd ./scripts    && chmod +x rc.radiusd radwatch check-radiusd-config)])