configure.in

   1 dnl #############################################################
   2 dnl #
   3 dnl #  For information about autoconf, see:
   4 dnl #
   5 dnl #  http://www.gnu.org/software/autoconf/
   6 dnl #
   7 dnl #  The recommended order is:
   8 dnl #
   9 dnl #  AC_INIT(file)
  10 dnl #  0. checks for compiler, libtool, and command line options
  11 dnl #  1. checks for programs
  12 dnl #  2. checks for libraries
  13 dnl #  3. checks for header files
  14 dnl #  4. checks for typedefs
  15 dnl #  5. checks for structures and functions
  16 dnl #  6. checks for compiler characteristics
  17 dnl #  7. checks for library functions
  18 dnl #  8. checks for system services
  19 dnl #  AC_OUTPUT([file...])
  20 dnl #
  21 dnl #############################################################
  22
  23 AC_INIT(src/main/radiusd.c)
  24 AC_CONFIG_HEADER(src/include/autoconf.h)
  25 AC_REVISION($Revision$)dnl
  26
  27 dnl # The version of the software, second beta, is 0.2
  28 RADIUSD_VERSION=0.2
  29
  30 dnl #############################################################
  31 dnl #
  32 dnl #  0. Checks for compiler, libtool, and command line options.
  33 dnl #
  34 dnl #############################################################
  35
  36 dnl Check for GNU cc
  37 AC_PROG_CC
  38 AC_PROG_GCC_TRADITIONAL
  39 AC_PROG_CC_SUNPRO
  40 AC_PROG_RANLIB
  41
  42 PACKAGE=freeradius
  43
  44 dnl Find GNU Make.
  45 AC_CHECK_PROG(GMAKE, gmake, yes, no)
  46 if test $GMAKE = no; then
  47   AC_PATH_PROG(MAKE, make, /usr/local/bin/make)
  48 else
  49   AC_PATH_PROG(MAKE, gmake, /usr/local/gnu/bin/make)
  50 fi
  51 makever=`$ac_cv_path_MAKE --version 2>&1 | grep "GNU Make"`
  52 if test -z "$makever"; then
  53   AC_MSG_ERROR(GNU Make is not installed.  Please download and install it
  54                 from ftp://prep.ai.mit.edu/pub/gnu/make/ before continuing.)
  55 fi
  56
  57 dnl libltdl is installable
  58 AC_LIBLTDL_INSTALLABLE
  59
  60 dnl ensure that we're looking for dlopen
  61 AC_LIBTOOL_DLOPEN
  62
  63 dnl Figure out how to build shared libraries
  64 AC_PROG_LIBTOOL
  65
  66 dnl Put this in later, when all distributed modules use autoconf.
  67 dnl AC_ARG_WITH(disablemodulefoo,
  68 dnl [  --without-rlm_foo       Disables module compilation.  Module list:]
  69 dnl esyscmd([find src/modules -type d -name rlm_\* -print |\
  70 dnl     sed -e 's%src/modules/.*/% (sub)- %; s%.*/%- %' |\
  71 dnl     awk '{print "                            "$0}']))
  72
  73 AC_ARG_ENABLE(strict-dependencies,
  74 [  --enable-strict-dependencies  Fail configure on lack of module dependancy.])
  75
  76 AC_ARG_WITH(fooincludedir,
  77 [  --with-FOO-include-dir=DIR   Dir for includes for FOO, module dependancy.])
  78
  79 AC_ARG_WITH(foolibdir,
  80 [  --with-FOO-lib-dir=DIR  Dir for libraries for FOO, module dependancy.])
  81
  82 dnl extra argument: --with-logdir
  83 logdir='${localstatedir}/log/radius'
  84 AC_MSG_CHECKING(logdir)
  85 AC_ARG_WITH(logdir,
  86 [  --with-logdir=DIR       Directory for logfiles [LOCALSTATEDIR/log/radius] ],
  87 [ case "$withval" in
  88     no)
  89         AC_MSG_ERROR(Need logdir)
  90         ;;
  91     yes)
  92         ;;
  93     *)
  94         logdir="$withval"
  95         ;;
  96   esac ]
  97 )
  98 AC_SUBST(logdir)
  99 AC_MSG_RESULT($logdir)
 100
 101 dnl extra argument: --with-radacctdir
 102 radacctdir='${logdir}/radacct'
 103 AC_MSG_CHECKING(radacctdir)
 104 AC_ARG_WITH(radacctdir,
 105 [  --with-radacctdir=PATH  Directory for detail files [LOGDIR/radacct] ],
 106 [ case "$withval" in
 107     no)
 108         AC_MSG_ERROR(Need radacctdir)
 109         ;;
 110     yes)
 111         ;;
 112     *)
 113         radacctdir="$withval"
 114         ;;
 115   esac ]
 116 )
 117 AC_SUBST(radacctdir)
 118 AC_MSG_RESULT($radacctdir)
 119
 120 dnl extra argument: --with-raddbdir
 121 raddbdir='${sysconfdir}/raddb'
 122 AC_MSG_CHECKING(raddbdir)
 123 AC_ARG_WITH(raddbdir,
 124 [  --with-raddbdir=DIR     Directory for config files [SYSCONFDIR/raddb] ],
 125 [ case "$withval" in
 126     no)
 127         AC_MSG_ERROR(Need raddbdir)
 128         ;;
 129     yes)
 130         ;;
 131     *)
 132         raddbdir="$withval"
 133         ;;
 134   esac ]
 135 )
 136 AC_SUBST(raddbdir)
 137 AC_MSG_RESULT($raddbdir)
 138
 139 dnl extra argument: --with-dict-nocase
 140 WITH_DICT_NOCASE=yes
 141 AC_ARG_WITH(dict-nocase,
 142 [  --with-dict-nocase      Make dictionary case-independant (default=yes)],
 143 [  case "$withval" in
 144     yes)
 145         ;;
 146     *)
 147         WITH_DICT_NOCASE=""
 148   esac ]
 149 )
 150 if test "X$WITH_DICT_NOCASE" = "Xyes"; then
 151   AC_DEFINE(WITH_DICT_NOCASE)
 152 fi
 153
 154 dnl extra argument: --with-ascend-binary
 155 ASCEND_BINARY=yes
 156 AC_ARG_WITH(ascend-binary,
 157 [  --with-ascend-binary    Include support for Ascend binary filter attributes (default=yes)],
 158 [ case "$withval" in
 159     yes)
 160         ;;
 161     *)
 162         ASCEND_BINARY=""
 163   esac ]
 164 )
 165 if test "X$ASCEND_BINARY" = "Xyes"; then
 166   AC_DEFINE(ASCEND_BINARY)
 167 fi
 168
 169 dnl extra argument: --with-threads
 170 WITH_THREADS=yes
 171 WITH_THREAD_POOL=yes
 172 AC_ARG_WITH(threads,
 173 [  --with-threads          Use threads, if available.  (default=yes) ],
 174 [ case "$withval" in
 175     yes)
 176         ;;
 177     *)
 178         WITH_THREADS=""
 179         WITH_THREAD_POOL=""
 180   esac ]
 181 )
 182
 183 dnl extra argument: --with-snmp
 184 WITH_SNMP=yes
 185 AC_ARG_WITH(snmp,
 186 [  --with-snmp             Compile in SNMP support. (default=yes)],
 187 [ case "$withval" in
 188     yes)
 189         ;;
 190     *)
 191         WITH_SNMP=no
 192   esac ]
 193 )
 194
 195 AC_ARG_ENABLE(ltdl-install,
 196 [  --disable-ltdl-install  do not install libltdl])
 197 if test x"${enable_ltdl_install+set}" != xset; then
 198   enable_ltdl_install=yes
 199   ac_configure_args="$ac_configure_args --enable-ltdl-install"
 200 fi
 201 AC_CONFIG_SUBDIRS(libltdl)
 202
 203 dnl #
 204 dnl #  Allow the user to specify a list of modules to be linked
 205 dnl #  statically to the server.
 206 dnl #
 207 STATIC_MODULES=
 208 AC_ARG_WITH(static_modules,
 209 [  --with-static-modules=QUOTED-MODULE-LIST],[
 210   for i in $withval; do
 211     STATIC_MODULES="$STATIC_MODULES -dlpreopen ../modules/rlm_$i/rlm_$i.la"
 212   done
 213 ])
 214
 215 dnl #
 216 dnl #  Enable developer C compiler warnings
 217 dnl #
 218 AC_ARG_ENABLE(developer,
 219 [  --enable-developer      Turns on flags of interest to developers.],
 220 [ case "$withval" in
 221     *)
 222         developer=no
 223         ;;
 224     yes)
 225         developer=yes
 226   esac ]
 227 )
 228
 229 if test "x$developer" != "xno" -a -d $srcdir/CVS; then
 230   dnl turn on the developer flag when taken from a CVS checkout (not a release)
 231   developer="yes"
 232 fi
 233
 234 dnl #
 235 dnl #  These next two arguments don't actually do anything.  They're
 236 dnl #  place holders so that the top-level configure script can tell
 237 dnl #  the user how to configure lower-level modules
 238 dnl #
 239
 240 dnl #
 241 dnl # extra argument: --with-rlm-FOO-lib-dir
 242 dnl #
 243 AC_ARG_WITH(rlm-FOO-lib-dir,
 244 [  --with-rlm-FOO-lib-dir=DIR       Directory to look for library files used by module FOO],
 245 [ case "$withval" in
 246     *)
 247         ;;
 248   esac ]
 249 )
 250
 251 dnl #
 252 dnl # extra argument: --with-rlm-FOO-include-dir
 253 dnl #
 254 AC_ARG_WITH(rlm-FOO-include-dir,
 255 [  --with-rlm-FOO-include-dir=DIR   Directory to look for include files used by module FOO],
 256 [ case "$withval" in
 257     *)
 258         ;;
 259   esac ]
 260 )
 261
 262 dnl See what include-style is used by the make program.
 263 dnl AC_MSG_CHECKING(include style for make)
 264 dnl echo "include /dev/null" > testmake.$$
 265 dnl echo "all:" >> testmake.$$
 266 dnl make -f testmake.$$ >/dev/null 2>&1
 267 dnl if test $? = 0
 268 dnl then
 269 dnl     INCLUDE=include
 270 dnl     IQUOTE=
 271 dnl else
 272 dnl     INCLUDE=.include
 273 dnl     IQUOTE='"'
 274 dnl fi
 275 dnl rm -f testmake.$$
 276 dnl AC_MSG_RESULT(" $INCLUDE")
 277 dnl AC_SUBST(INCLUDE)
 278 dnl AC_SUBST(IQUOTE)
 279
 280 dnl #############################################################
 281 dnl #
 282 dnl #  1. Checks for programs
 283 dnl #
 284 dnl #############################################################
 285
 286 AC_PATH_PROG(PERL, perl, /usr/local/bin/perl)
 287 if test ! -x $ac_cv_path_PERL; then
 288   AC_MSG_ERROR(perl not found - fatal)
 289 fi
 290 AC_PATH_PROG(SNMPGET, snmpget, /usr/local/bin/snmpget)
 291 AC_PATH_PROG(SNMPWALK, snmpwalk, /usr/local/bin/snmpwalk)
 292 AC_PATH_PROG(RUSERS, rusers, /usr/bin/rusers)
 293
 294 dnl FIXME This is truly gross.
 295 missing_dir=`cd $ac_aux_dir && pwd`
 296 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
 297 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
 298 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
 299
 300 AC_PATH_PROG(LOCATE,locate)
 301 AC_PATH_PROG(DIRNAME,dirname)
 302 AC_PATH_PROG(GREP,grep)
 303
 304 dnl #
 305 dnl # check for AIX, to allow us to use some BSD functions
 306 dnl # must be before macros that call the compiler.
 307 dnl #
 308 AC_AIX
 309
 310 dnl #############################################################
 311 dnl #
 312 dnl #  2. Checks for libraries
 313 dnl #
 314 dnl #############################################################
 315
 316 dnl If using pthreads, check for -lpthread (posix) or -lc_r (*BSD)
 317 PTHREADLIB=
 318 if test "$WITH_THREADS" = "yes"; then
 319   if test $ac_cv_prog_suncc = "yes"; then
 320     CFLAGS="$CFLAGS -mt"
 321   fi
 322
 323   AC_CHECK_HEADERS(pthread.h)
 324
 325   if test "X$ac_cv_header_pthread_h" = "X"; then
 326     AC_MSG_ERROR("You are trying to use threads without a POSIX <pthread.h>")
 327   fi
 328
 329 dnl #
 330 dnl # pthread stuff is usually in -lpthread
 331 dnl #
 332   AC_CHECK_LIB(pthread, pthread_join,
 333     PTHREADLIB="-lpthread"
 334   )
 335
 336 dnl # HP/UX requires linking with librt, too, to get the sem_* symbols.  :\
 337
 338   AC_SEARCH_LIBS(sem_init, pthread rt,
 339         [
 340         dnl    Er, this usage of $ac_cv_search_sem_init may be unfounded
 341         dnl    chumminess with the autoconf internals.  -chad
 342         PTHREADLIB="$PTHREADLIB $ac_cv_search_sem_init"
 343         ],
 344         [],
 345         "-lpthread"
 346   )
 347
 348 dnl #
 349 dnl # Except for *BSD, where it's in -lc_r,
 350 dnl # and where we've got to add extra CFLAGS.
 351 dnl #
 352   if test "X$PTHREADLIB" = "X"; then
 353     SAVED_CFLAGS=$CFLAGS
 354     CFLAGS="$CFLAGS -pthread -D_THREAD_SAFE"
 355     AC_CHECK_LIB(c_r, pthread_create,
 356       PTHREADLIB="-lc_r"
 357     )
 358   fi
 359
 360 dnl # Set libs, etc, if we have them.
 361   if test "x$PTHREADLIB" != "x"; then
 362     LIBS="$LIBS $PTHREADLIB"
 363     CFLAGS="$CFLAGS -D_REENTRANT"
 364   fi
 365 fi
 366
 367 dnl #
 368 dnl # If we have NO pthread libraries, remove any knowledge of threads.
 369 dnl #
 370 if test "x$PTHREADLIB" = "x"; then
 371   CFLAGS=$SAVED_CFLAGS
 372   ac_cv_header_pthread_h="no"
 373   WITH_THREADS=no
 374   WITH_THREAD_POOL=no
 375 fi
 376
 377 dnl Check if we need -lsocket
 378 AC_CHECK_LIB(socket, getsockname)
 379
 380 dnl Check for -lresolv
 381 dnl This library may be needed later.
 382 AC_CHECK_LIB(resolv, inet_aton)
 383
 384 dnl Check if we need -lnsl. Usually if we want to
 385 dnl link against -lsocket we need to include -lnsl as well.
 386 AC_CHECK_LIB(nsl, inet_ntoa)
 387
 388 dnl #############################################################
 389 dnl #
 390 dnl #  3. Checks for header files
 391 dnl #
 392 dnl #############################################################
 393
 394 AC_HEADER_DIRENT
 395 AC_HEADER_STDC
 396 AC_HEADER_TIME
 397 AC_HEADER_SYS_WAIT
 398
 399 AC_CHECK_HEADERS( \
 400         unistd.h \
 401         crypt.h \
 402         errno.h \
 403         resource.h \
 404         getopt.h \
 405         malloc.h \
 406         utmp.h \
 407         utmpx.h \
 408         signal.h \
 409         sys/select.h \
 410         syslog.h \
 411         inttypes.h \
 412         stdint.h \
 413         stdio.h \
 414         netdb.h \
 415         semaphore.h \
 416         arpa/inet.h \
 417         netinet/in.h \
 418         sys/types.h \
 419         sys/socket.h \
 420         sys/time.h \
 421         sys/security.h \
 422         prot.h \
 423         sia.h \
 424         siad.h
 425 )
 426
 427 REGEX=no
 428 AC_CHECK_HEADER(regex.h, AC_DEFINE(HAVE_REGEX_H))
 429 if test "x$ac_cv_header_regex_h" = "xyes"; then
 430   REGEX_EXTENDED=no
 431   REGEX=yes
 432   AC_EGREP_CPP(yes,
 433     [#include <regex.h>
 434      #ifdef REG_EXTENDED
 435        yes
 436      #endif
 437      ], [AC_DEFINE(HAVE_REG_EXTENDED) REGEX_EXTENDED=yes])
 438 fi
 439 AC_SUBST(REGEX)
 440 AC_SUBST(REGEX_EXTENDED)
 441
 442 dnl #
 443 dnl #  other checks which require headers
 444 dnl #
 445 if test "x$ac_cv_header_sys_security_h" = "xyes" && test "x$ac_cv_header_prot_h" = "xyes"
 446 then
 447   AC_DEFINE(OSFC2)
 448 fi
 449
 450 if test "x$ac_cv_header_sia_h" = "xyes" && test "x$ac_cv_header_siad_h" = "xyes"
 451 then
 452   AC_DEFINE(OSFSIA)
 453 fi
 454
 455
 456 dnl #############################################################
 457 dnl #
 458 dnl #  4. Checks for typedefs
 459 dnl #
 460 dnl #############################################################
 461
 462 dnl #
 463 dnl # Ensure that these are defined
 464 dnl #
 465 AC_TYPE_OFF_T
 466 AC_TYPE_PID_T
 467 AC_TYPE_SIZE_T
 468 AC_TYPE_UID_T
 469
 470 dnl check for socklen_t
 471 AC_CHECK_TYPE_INCLUDE([
 472 #ifdef HAVE_SYS_TYPES_H
 473 #include <sys/types.h>
 474 #endif
 475 #ifdef HAVE_SYS_SOCKET_H
 476 #include <sys/socket.h>
 477 #endif
 478 ],socklen_t, int)
 479
 480 dnl check for uint8_t
 481 AC_CHECK_TYPE_INCLUDE([
 482 #ifdef HAVE_INTTYPES_H
 483 #include <inttypes.h>
 484 #endif
 485 #ifdef HAVE_STDINT_H
 486 #include <stdint.h>
 487 #endif
 488 ],uint8_t, unsigned char)
 489
 490 dnl check for uint32_t
 491 AC_CHECK_TYPE_INCLUDE([
 492 #ifdef HAVE_INTTYPES_H
 493 #include <inttypes.h>
 494 #endif
 495 #ifdef HAVE_STDINT_H
 496 #include <stdint.h>
 497 #endif
 498 ],uint32_t, unsigned int)
 499
 500 dnl #############################################################
 501 dnl #
 502 dnl #  5. Checks for structures and functions
 503 dnl #
 504 dnl #############################################################
 505 AC_CHECK_FUNCS( \
 506         getopt_long \
 507         lockf \
 508         strsignal \
 509         sigaction \
 510         sigprocmask \
 511         snprintf \
 512         vsnprintf \
 513         setsid \
 514         strncasecmp \
 515         strcasecmp \
 516         strsep \
 517         inet_aton \
 518         gethostname \
 519         setlinebuf \
 520         setvbuf \
 521         sem_init \
 522         getusershell
 523 )
 524 RADIUSD_NEED_DECLARATIONS( \
 525         crypt \
 526         strncasecmp \
 527         strcasecmp \
 528         inet_aton \
 529         gethostname \
 530         setlinebuf \
 531         getusershell \
 532         endusershell
 533 )
 534
 535 AC_TYPE_SIGNAL
 536
 537 dnl # check if we have utmpx.h
 538 dnl # if so, check if struct utmpx has entry ut_xtime
 539 dnl # if not, set it to define ut_xtime == ut_tv.tv_sec
 540 if test "x$ac_cv_header_utmpx_h" = "xyes"
 541 then
 542  AC_CHECK_STRUCT_HAS_MEMBER([#include <utmpx.h>], [struct utmpx], ut_xtime)
 543  if test "x$ac_cv_type_struct_utmpx_ut_xtime" = "x"
 544  then
 545    AC_DEFINE(ut_xtime,ut_tv.tv_sec)
 546  fi
 547 fi
 548
 549 dnl #############################################################
 550 dnl #
 551 dnl #  6. Checks for compiler characteristics
 552 dnl #
 553 dnl #############################################################
 554
 555 dnl #
 556 dnl # Ensure that these are defined
 557 dnl #
 558 AC_C_CONST
 559
 560 dnl #
 561 dnl # See if this is OS/2
 562 dnl #
 563 AC_MSG_CHECKING(type of OS)
 564 OS=`uname -s`
 565 AC_MSG_RESULT($OS)
 566 if test "$OS" = "OS/2"; then
 567         LIBPREFIX=
 568 else
 569         LIBPREFIX=lib
 570 fi
 571 AC_SUBST(LIBPREFIX)
 572
 573 dnl #
 574 dnl # Set Default CFLAGS
 575 dnl #
 576 if test "x$GCC" = "xyes"; then
 577     CFLAGS="$CFLAGS -Wall -D_GNU_SOURCE"
 578 fi
 579
 580 AC_MSG_CHECKING(for developer gcc flags)
 581 if test "x$developer" = "xyes" -a "x$GCC" = "xyes"; then
 582   devflags="-Wshadow -Wpointer-arith -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wmissing-prototypes -Wmissing-declarations -Wnested-externs"
 583   CFLAGS="$CFLAGS $devflags"
 584   INSTALLSTRIP=""
 585   AC_MSG_RESULT(yes.  Using $devflags)
 586 else
 587   devflags=""
 588   CFLAGS="$CFLAGS -DNDEBUG"
 589   INSTALLSTRIP="-s"
 590   AC_MSG_RESULT(no.)
 591 fi
 592
 593 dnl #############################################################
 594 dnl #
 595 dnl #  7. Checks for library functions
 596 dnl #
 597 dnl #############################################################
 598
 599 dnl Check for libcrypt
 600 dnl We use crypt(3) which may be in libc, or in libcrypt (eg FreeBSD)
 601 AC_CHECK_LIB(crypt, crypt,
 602   CRYPTLIB="-lcrypt"
 603 )
 604 AC_SUBST(CRYPTLIB)
 605 if test "$CRYPTLIB" != ""; then
 606   AC_DEFINE(HAVE_CRYPT)
 607 else
 608   AC_CHECK_FUNC(crypt, AC_DEFINE(HAVE_CRYPT))
 609 fi
 610
 611 if test "x$WITH_SNMP" = "xyes"; then
 612   SNMP_CHECKS
 613 fi
 614
 615 dnl #
 616 dnl #  Check for sem_init all by itself
 617 dnl #
 618 if test "X$ac_cv_func_sem_init" = "Xno"; then
 619
 620 dnl #
 621 dnl #  If not found, sem_init is in -lposix4 on Solaris
 622 dnl #
 623  AC_CHECK_LIB(posix4, sem_init)
 624
 625   if test "X$ac_cv_lib_posix4_sem_init" = "X"; then
 626     if test "$WITH_THREAD_POOL" = "yes"; then
 627       AC_MSG_WARN(You do not have posix semaphores.  Disabling thread pools)
 628     fi
 629     WITH_THREAD_POOL=no
 630   fi
 631 fi
 632
 633 POSTGRESQL_CHECKS
 634 ODBC_CHECKS
 635
 636 dnl #############################################################
 637 dnl #
 638 dnl #  8. Checks for system services
 639 dnl #
 640 dnl #############################################################
 641
 642 dnl #
 643 dnl # Figure out where libtool is located,
 644 dnl #
 645 LIBTOOL="`pwd`/libtool"
 646 AC_SUBST(LIBTOOL)
 647 AC_SUBST(LIBLTDL)
 648 AC_SUBST(INCLTDL)
 649 top_builddir=`pwd`
 650 AC_SUBST(top_builddir)
 651
 652 dnl import libtool stuff
 653
 654 dnl #
 655 dnl #  Checks to ensure that the thread pool code can build.
 656 dnl #
 657 if test "$WITH_THREAD_POOL" = "yes"; then
 658   dnl #
 659   dnl # If using thread pools, check that threading is enabled
 660   dnl #
 661   if test "$WITH_THREADS" != "yes"; then
 662     AC_MSG_ERROR(You must have threads enabled for thread pools to work.)
 663   fi
 664
 665   dnl #
 666   dnl # If using thread pools, check that we have thread libraries
 667   dnl #
 668   if test "X$PTHREADLIB" = "X"; then
 669     AC_MSG_ERROR(You must have threading libraries for thread pools to work.)
 670   fi
 671
 672 dnl #
 673 dnl #  Finally, after all of the checks above, we see if
 674 dnl #  we can REALLY use the thread pools.
 675 dnl #
 676   if test "$WITH_THREAD_POOL" = "yes"; then
 677     AC_DEFINE(WITH_THREAD_POOL,1)
 678   fi
 679 fi
 680
 681 dnl #############################################################
 682 dnl #
 683 dnl #  Configure in any module directories.
 684 dnl #
 685 dnl #############################################################
 686
 687 mysubdirs=
 688 for foo in `find src/modules -name configure -print`; do
 689   bar=`echo $foo | sed 's%/configure$%%g'`
 690   mysubdirs="$mysubdirs $bar"
 691 done
 692
 693 dnl #
 694 dnl #  Don't change the variable name here.  Autoconf goes bonkers
 695 dnl #  if you do.
 696 dnl #
 697 AC_CONFIG_SUBDIRS($mysubdirs)
 698
 699 dnl #############################################################
 700 dnl #
 701 dnl #  And finally, output the results.
 702 dnl #
 703 dnl #############################################################
 704
 705 dnl #
 706 dnl #  Substitute whatever libraries we found to be necessary
 707 dnl #
 708 AC_SUBST(LIBS)
 709 AC_SUBST(INSTALLSTRIP)
 710
 711 USE_SHARED_LIBS=$enable_shared
 712 AC_SUBST(USE_SHARED_LIBS)
 713 USE_STATIC_LIBS=$enable_static
 714 AC_SUBST(USE_STATIC_LIBS)
 715 AC_SUBST(STATIC_MODULES)
 716 AC_SUBST(RADIUSD_VERSION)
 717 export CFLAGS LIBS
 718
 719 AC_OUTPUT(\
 720         ./Make.inc \
 721         ./src/include/build-radpaths-h \
 722         ./src/main/checkrad.pl \
 723         ./src/main/radlast \
 724         ./src/main/radtest \
 725         ./scripts/rc.radiusd \
 726         ./scripts/radwatch \
 727         ./scripts/check-radiusd-config \
 728         ./scripts/radiusd.cron.daily \
 729         ./scripts/radiusd.cron.monthly \
 730         ./scripts/cryptpasswd \
 731         ./raddb/radiusd.conf
 732 )
 733
 734 AC_OUTPUT_COMMANDS([echo timestamp > src/include/stamp-h])
 735 AC_OUTPUT_COMMANDS([(cd ./src/include && /bin/sh ./build-radpaths-h)])
 736 AC_OUTPUT_COMMANDS([(cd ./src/main   && chmod +x checkrad.pl radlast radtest)])
 737 AC_OUTPUT_COMMANDS([(cd ./scripts    && chmod +x rc.radiusd radwatch check-radiusd-config radiusd.cron.daily radiusd.cron.monthly cryptpasswd)])
 738 AC_OUTPUT_COMMANDS([
 739 cat >> src/include/autoconf.h <<EOF
 740
 741 #define HOSTINFO        "$host"
 742 #define RADIUSD_VERSION "$RADIUSD_VERSION"
 743 EOF
 744 ],host=$host)