configure.in

   1 dnl #############################################################
   2 dnl #
   3 dnl #  For information about autoconf, see:
   4 dnl #
   5 dnl #  http://www.gnu.org/software/autoconf/
   6 dnl #
   7 dnl #  The recommended order is:
   8 dnl #
   9 dnl #  AC_INIT(file)
  10 dnl #  0. checks for compiler, libtool, and command line options
  11 dnl #  1. checks for programs
  12 dnl #  2. checks for libraries
  13 dnl #  3. checks for header files
  14 dnl #  4. checks for typedefs
  15 dnl #  5. checks for structures and functions
  16 dnl #  6. checks for compiler characteristics
  17 dnl #  7. checks for library functions
  18 dnl #  8. checks for system services
  19 dnl #  AC_OUTPUT([file...])
  20 dnl #
  21 dnl #############################################################
  22
  23 AC_PREREQ([2.59])
  24 export CFLAGS LIBS LDFLAGS CPPFLAGS
  25 AC_INIT(src/main/radiusd.c)
  26 AC_CONFIG_HEADER(src/include/autoconf.h)
  27 AC_REVISION($Revision$)dnl
  28
  29 dnl # The version of the software
  30 RADIUSD_VERSION=`cat VERSION`
  31 RADIUSD_MAJOR_VERSION=`cat VERSION | sed 's/\..*//'`
  32 RADIUSD_MINOR_VERSION=`cat VERSION | sed 's/^2\.//'`
  33 PACKAGE=freeradius
  34
  35 dnl #############################################################
  36 dnl #
  37 dnl #  0. Checks for compiler, libtool, and command line options.
  38 dnl #
  39 dnl #############################################################
  40
  41 dnl Check for GNU cc
  42 AC_PROG_CC
  43 AC_PROG_CXX
  44
  45 dnl #
  46 dnl # check for AIX, to allow us to use some BSD functions
  47 dnl # must be before macros that call the compiler.
  48 dnl #
  49 AC_AIX
  50
  51 AC_PROG_GCC_TRADITIONAL
  52 AC_PROG_CC_SUNPRO
  53 AC_PROG_RANLIB
  54
  55 dnl Compile in large (2G+) file support.
  56 AC_SYS_LARGEFILE
  57
  58 dnl # check for system bytesex
  59 dnl # AC_DEFINES WORDS_BIGENDIAN
  60 AC_C_BIGENDIAN
  61
  62 dnl Find GNU Make.
  63 AC_CHECK_PROG(GMAKE, gmake, yes, no)
  64 if test $GMAKE = no; then
  65   AC_PATH_PROG(MAKE, make, /usr/local/bin/make)
  66 else
  67   AC_PATH_PROG(MAKE, gmake, /usr/local/gnu/bin/make)
  68 fi
  69 makever=`$ac_cv_path_MAKE --version 2>&1 | grep "GNU Make"`
  70 if test -z "$makever"; then
  71   AC_MSG_ERROR(GNU Make is not installed.  Please download and install it
  72                 from ftp://prep.ai.mit.edu/pub/gnu/make/ before continuing.)
  73 fi
  74
  75 AC_ARG_WITH(system-libltdl,
  76 [  --with-system-libltdl   Use the libltdl installed in your system (default=use our own)],
  77 [
  78 LIBLTDL="-lltdl"
  79 INCLTDL=
  80 LTDL_SUBDIRS=
  81 ],
  82 [
  83 dnl If libltdl isn't installable, set it to be installable.
  84 [test x"$enable_ltdl_install" = x && enable_ltdl_install=yes]
  85 AC_LIBLTDL_INSTALLABLE
  86
  87 dnl tell Makefile to build ltdl if needed
  88 if test x"$enable_ltdl_install" = x"yes"; then
  89   LTDL_SUBDIRS=libltdl
  90 fi
  91 ])
  92 AC_SUBST(LTDL_SUBDIRS)
  93
  94 dnl use system-wide libtool, if it exists
  95 AC_ARG_WITH(system-libtool,
  96 [  --with-system-libtool   Use the libtool installed in your system (default=use our own)],
  97 [ AC_PATH_PROG(LIBTOOL, libtool,,$PATH:/usr/local/bin) ],
  98 [
  99   LIBTOOL="`pwd`/libtool"
 100   AC_SUBST(LIBTOOL)
 101   dnl ensure that we're looking for dlopen
 102   AC_LIBTOOL_DLOPEN
 103
 104   dnl Figure out how to build shared libraries
 105   AC_PROG_LIBTOOL
 106 ])
 107
 108
 109 dnl Put this in later, when all distributed modules use autoconf.
 110 dnl AC_ARG_WITH(disablemodulefoo,
 111 dnl [  --without-rlm_foo       Disables module compilation.  Module list:]
 112 dnl esyscmd([find src/modules -type d -name rlm_\* -print |\
 113 dnl     sed -e 's%src/modules/.*/% (sub)- %; s%.*/%- %' |\
 114 dnl     awk '{print "                            "$0}']))
 115
 116 AC_ARG_ENABLE(strict-dependencies,
 117 [  --enable-strict-dependencies  Fail configure on lack of module dependancy.])
 118
 119 dnl extra argument: --with-docdir
 120 docdir='${datadir}/doc/freeradius'
 121 AC_MSG_CHECKING(docdir)
 122 AC_ARG_WITH(docdir,
 123 [  --with-docdir=DIR       Directory for documentation [DATADIR/doc/freeradius] ],
 124 [ case "$withval" in
 125     no)
 126         docdir=no
 127         ;;
 128     yes)
 129         ;;
 130     [[\\/$]]* | ?:[[\\/]]* )
 131         docdir="$withval"
 132         ;;
 133     *)
 134         AC_MSG_ERROR([expected an absolute directory name for --with-docdir: $withval])
 135         ;;
 136   esac ]
 137 )
 138 AC_SUBST(docdir)
 139 AC_MSG_RESULT($docdir)
 140 if test "x$docdir" = xno; then
 141         AC_MSG_WARN(Documentation files will NOT be installed.)
 142 fi
 143
 144 dnl extra argument: --with-logdir
 145 logdir='${localstatedir}/log/radius'
 146 AC_MSG_CHECKING(logdir)
 147 AC_ARG_WITH(logdir,
 148 [  --with-logdir=DIR       Directory for logfiles [LOCALSTATEDIR/log/radius] ],
 149 [ case "$withval" in
 150     no)
 151         AC_MSG_ERROR(Need logdir)
 152         ;;
 153     yes)
 154         ;;
 155     [[\\/$]]* | ?:[[\\/]]* )
 156         logdir="$withval"
 157         ;;
 158     *)
 159         AC_MSG_ERROR([expected an absolute directory name for --with-logdir: $withval])
 160         ;;
 161   esac ]
 162 )
 163 AC_SUBST(logdir)
 164 AC_MSG_RESULT($logdir)
 165
 166 dnl extra argument: --with-radacctdir
 167 radacctdir='${logdir}/radacct'
 168 AC_MSG_CHECKING(radacctdir)
 169 AC_ARG_WITH(radacctdir,
 170 [  --with-radacctdir=DIR   Directory for detail files [LOGDIR/radacct] ],
 171 [ case "$withval" in
 172     no)
 173         AC_MSG_ERROR(Need radacctdir)
 174         ;;
 175     yes)
 176         ;;
 177     [[\\/$]]* | ?:[[\\/]]* )
 178         radacctdir="$withval"
 179         ;;
 180     *)
 181         AC_MSG_ERROR([expected an absolute directory name for --with-radacctdir: $withval])
 182         ;;
 183   esac ]
 184 )
 185 AC_SUBST(radacctdir)
 186 AC_MSG_RESULT($radacctdir)
 187
 188 dnl extra argument: --with-raddbdir
 189 raddbdir='${sysconfdir}/raddb'
 190 AC_MSG_CHECKING(raddbdir)
 191 AC_ARG_WITH(raddbdir,
 192 [  --with-raddbdir=DIR     Directory for config files [SYSCONFDIR/raddb] ],
 193 [ case "$withval" in
 194     no)
 195         AC_MSG_ERROR(Need raddbdir)
 196         ;;
 197     yes)
 198         ;;
 199     [[\\/$]]* | ?:[[\\/]]* )
 200         raddbdir="$withval"
 201         ;;
 202     *)
 203         AC_MSG_ERROR([expected an absolute directory name for --with-raddbdir: $withval])
 204         ;;
 205   esac ]
 206 )
 207 AC_SUBST(raddbdir)
 208 AC_MSG_RESULT($raddbdir)
 209
 210 dnl extra argument: --with-ascend-binary
 211 ASCEND_BINARY=yes
 212 AC_ARG_WITH(ascend-binary,
 213 [  --with-ascend-binary    Include support for Ascend binary filter attributes (default=yes)],
 214 [ case "$withval" in
 215     yes)
 216         ;;
 217     *)
 218         ASCEND_BINARY=""
 219   esac ]
 220 )
 221 if test "X$ASCEND_BINARY" = "Xyes"; then
 222   AC_DEFINE(ASCEND_BINARY, [], [Include support for Ascend binary filter attributes])
 223 fi
 224
 225 dnl extra argument: --with-threads
 226 WITH_THREADS=yes
 227 AC_ARG_WITH(threads,
 228 [  --with-threads          Use threads, if available.  (default=yes) ],
 229 [ case "$withval" in
 230     yes)
 231         ;;
 232     *)
 233         WITH_THREADS=""
 234   esac ]
 235 )
 236
 237 dnl extra argument: --with-vmps
 238 WITH_VMPS=yes
 239 AC_ARG_WITH(vmps,
 240 [  --with-vmps             Compile in VMPS support. (default=yes)],
 241 [ case "$withval" in
 242     yes)
 243         ;;
 244     *)
 245         WITH_VMPS=no
 246   esac ]
 247 )
 248 if test "x$WITH_VMPS" = "xyes"; then
 249         AC_DEFINE(WITH_VMPS, [1], [define if you want VMPS support])
 250 fi
 251
 252 dnl extra argument: --with-dhcp
 253 AC_ARG_WITH(dhcp,
 254 [  --with-dhcp             Compile in DHCP support. (default=no)],
 255 [ case "$withval" in
 256     yes)
 257         AC_DEFINE(WITH_DHCP, [1], [Include experimental support for DHCP])
 258         ;;
 259     *)
 260         ;;
 261   esac ]
 262 )
 263
 264
 265 dnl #
 266 dnl #  Allow the user to specify a list of modules to be linked
 267 dnl #  statically to the server.
 268 dnl #
 269 STATIC_MODULES=
 270 AC_ARG_WITH(static_modules,
 271 [  --with-static-modules=QUOTED-MODULE-LIST],[
 272   for i in $withval; do
 273     STATIC_MODULES="$STATIC_MODULES -dlpreopen ../modules/rlm_$i/rlm_$i.la"
 274   done
 275 ])
 276
 277 MODULES=
 278 AC_ARG_WITH(modules,
 279 [ --with-modules=QUOTED-MODULE-LIST],[
 280  for i in $withval; do
 281    MODULES="$MODULES $i"
 282  done
 283 ])
 284
 285 dnl #
 286 dnl #  Enable developer C compiler warnings
 287 dnl #
 288 AC_ARG_ENABLE(developer,
 289 [  --enable-developer               Enables features of interest to developers.],
 290 [ case "$enableval" in
 291     no)
 292         developer=no
 293         ;;
 294     *)
 295         developer=yes
 296   esac ]
 297 )
 298
 299 if test "x$developer" != "xno" -a -d $srcdir/CVS; then
 300   dnl turn on the developer flag when taken from a CVS checkout (not a release)
 301   developer="yes"
 302 fi
 303
 304 if test "x$developer" != "xno" -a -d $srcdir/.git; then
 305   dnl turn on the developer flag when taken from a git checkout (not a release)
 306   developer="yes"
 307 fi
 308
 309 dnl extra argument: --with-experimental-modules
 310 EXPERIMENTAL=
 311 AC_ARG_WITH(experimental-modules,
 312 [  --with-experimental-modules      Use experimental and unstable modules. (default=no) ],
 313 [ case "$withval" in
 314     yes)
 315         EXPERIMENTAL=yes
 316         ;;
 317     *)
 318   esac ]
 319 )
 320
 321 dnl extra argument: --with-openssl
 322 WITH_OPENSSL=yes
 323 AC_ARG_WITH(openssl,
 324 [  --with-openssl                   Use OpenSSL. (default=yes)],
 325 [ case "$withval" in
 326     no)
 327         WITH_OPENSSL=no
 328         ;;
 329     *)
 330         WITH_OPENSSL=yes
 331         ;;
 332   esac ]
 333 )
 334
 335 dnl #
 336 dnl # extra argument: --with-openssl-includes=dir
 337 dnl #
 338 OPENSSL_INCLUDE_DIR=
 339 AC_ARG_WITH(openssl-includes,
 340 [  --with-openssl-includes=DIR      Directory to look for OpenSSL include files],
 341 [ case "$withval" in
 342     *) OPENSSL_INCLUDE_DIR="$withval"
 343         ;;
 344   esac ]
 345 )
 346
 347 dnl #
 348 dnl # extra argument: --with-openssl-libraries=dir
 349 dnl #
 350 OPENSSL_LIB_DIR=
 351 AC_ARG_WITH(openssl-libraries,
 352 [  --with-openssl-libraries=DIR     Directory to look for OpenSSL library files],
 353 [ case "$withval" in
 354     *) OPENSSL_LIB_DIR="$withval"
 355         ;;
 356   esac ]
 357 )
 358
 359 dnl #
 360 dnl #  These next two arguments don't actually do anything.  They're
 361 dnl #  place holders so that the top-level configure script can tell
 362 dnl #  the user how to configure lower-level modules
 363 dnl #
 364
 365 dnl #
 366 dnl # extra argument: --with-rlm-FOO-lib-dir
 367 dnl #
 368 AC_ARG_WITH(rlm-FOO-lib-dir,
 369 [  --with-rlm-FOO-lib-dir=DIR       Directory to look for library files used by module FOO],
 370 [ case "$withval" in
 371     *)
 372         ;;
 373   esac ]
 374 )
 375
 376 dnl #
 377 dnl # extra argument: --with-rlm-FOO-include-dir
 378 dnl #
 379 AC_ARG_WITH(rlm-FOO-include-dir,
 380 [  --with-rlm-FOO-include-dir=DIR   Directory to look for include files used by module FOO],
 381 [ case "$withval" in
 382     *)
 383         ;;
 384   esac ]
 385 )
 386
 387 dnl See what include-style is used by the make program.
 388 dnl AC_MSG_CHECKING(include style for make)
 389 dnl echo "include /dev/null" > testmake.$$
 390 dnl echo "all:" >> testmake.$$
 391 dnl make -f testmake.$$ >/dev/null 2>&1
 392 dnl if test $? = 0
 393 dnl then
 394 dnl     INCLUDE=include
 395 dnl     IQUOTE=
 396 dnl else
 397 dnl     INCLUDE=.include
 398 dnl     IQUOTE='"'
 399 dnl fi
 400 dnl rm -f testmake.$$
 401 dnl AC_MSG_RESULT(" $INCLUDE")
 402 dnl AC_SUBST(INCLUDE)
 403 dnl AC_SUBST(IQUOTE)
 404
 405 dnl extra argument: --with-udpfromto
 406 WITH_UDPFROMTO=no
 407 AC_ARG_WITH(udpfromto,
 408 [  --with-udpfromto        Compile in UDPFROMTO support. (default=no)],
 409 [ case "$withval" in
 410     yes)
 411         WITH_UDPFROMTO=yes
 412         ;;
 413     *)
 414         WITH_UDPFROMTO=no
 415   esac ]
 416 )
 417
 418 if test "x$WITH_UDPFROMTO" = "xyes"; then
 419         AC_DEFINE(WITH_UDPFROMTO, [], [define if you want udpfromto])
 420 fi
 421
 422 dnl #############################################################
 423 dnl #
 424 dnl #  1. Checks for programs
 425 dnl #
 426 dnl #############################################################
 427
 428 CHECKRAD=checkrad.pl
 429 AC_PATH_PROG(PERL, perl, /usr/local/bin/perl)
 430 if test "x$ac_cv_path_PERL" = "x"; then
 431   AC_MSG_WARN(perl not found - Simultaneous-Use and checkrad.pl may not work)
 432 fi
 433 AC_PATH_PROG(SNMPGET, snmpget)
 434 if test "x$ac_cv_path_SNMPGET" = "x"; then
 435   AC_MSG_WARN(snmpget not found - Simultaneous-Use and checkrad.pl may not work)
 436 fi
 437
 438 AC_PATH_PROG(SNMPWALK, snmpwalk)
 439 if test "x$ac_cv_path_SNMPWALK" = "x"; then
 440   AC_MSG_WARN(snmpwalk not found - Simultaneous-Use and checkrad.pl may not work)
 441 fi
 442
 443 AC_PATH_PROG(RUSERS, rusers, /usr/bin/rusers)
 444
 445 dnl FIXME This is truly gross.
 446 missing_dir=`cd $ac_aux_dir && pwd`
 447 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
 448 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
 449 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
 450
 451 AC_PATH_PROG(LOCATE,locate)
 452 AC_PATH_PROG(DIRNAME,dirname)
 453 AC_PATH_PROG(GREP,grep)
 454
 455 dnl #############################################################
 456 dnl #
 457 dnl #  2. Checks for libraries
 458 dnl #
 459 dnl #############################################################
 460
 461 dnl If using pthreads, check for -lpthread (posix) or -lc_r (*BSD)
 462 old_CFLAGS=$CFLAGS
 463 if test "x$WITH_THREADS" = "xyes"; then
 464   if test $ac_cv_prog_suncc = "yes"; then
 465     CFLAGS="$CFLAGS -mt"
 466   fi
 467
 468   AC_CHECK_HEADERS(pthread.h, [], [ WITH_THREADS="no" ])
 469
 470 dnl #
 471 dnl # pthread stuff is usually in -lpthread
 472 dnl # or in -lc_r, on *BSD
 473 dnl #
 474 dnl # On Some systems, we need extra pre-processor flags, to get them to
 475 dnl # to do the threading properly.
 476 dnl #
 477   AC_CHECK_LIB(pthread, pthread_create,
 478                 [ CFLAGS="$CFLAGS -D_REENTRANT -D_POSIX_PTHREAD_SEMANTICS"
 479                   LIBS="$LIBS -lpthread" ],
 480                 AC_CHECK_LIB(c_r, pthread_create,
 481                             [ CFLAGS="$CFLAGS -pthread -D_THREAD_SAFE" ],
 482                             [ WITH_THREADS="no" ]
 483                             )
 484                 )
 485 fi
 486
 487 dnl #
 488 dnl # If we have NO pthread libraries, remove any knowledge of threads.
 489 dnl #
 490 if test "x$WITH_THREADS" != "xyes"; then
 491   CFLAGS=$old_CFLAGS
 492   ac_cv_header_pthread_h="no"
 493   WITH_THREADS=no
 494 else
 495   dnl #
 496   dnl #  We need sem_init() and friends, as they're the friendliest
 497   dnl #  semaphore functions for threading.
 498   dnl #
 499   dnl # HP/UX requires linking with librt, too, to get the sem_* symbols.
 500   dnl # Some systems have them in -lsem
 501   dnl # Solaris has them in -lposix4
 502   dnl # NetBSD has them in -lsemaphore
 503
 504   AC_SEARCH_LIBS(sem_init, pthread sem posix4 rt semaphore,
 505         [],
 506         [AC_MSG_ERROR(-lsem not found.  You may want to download it from ftp://ftp.to.gd-es.com/pub/BSDI/libsem.tar.bz2 or ftp://ftp.freeradius.org/pub/radius/contrib/libsem.tar.gz)]
 507    )
 508 fi
 509
 510 dnl Check if we need -lsocket
 511 AC_CHECK_LIB(socket, getsockname)
 512
 513 dnl Check for -lresolv
 514 dnl This library may be needed later.
 515 AC_CHECK_LIB(resolv, inet_aton)
 516
 517 dnl Check if we need -lnsl. Usually if we want to
 518 dnl link against -lsocket we need to include -lnsl as well.
 519 AC_CHECK_LIB(nsl, inet_ntoa)
 520
 521 dnl Check for OpenSSL libraries.
 522 OPENSSL_LIBS=
 523 if test "x$WITH_OPENSSL" = xyes; then
 524   old_LIBS=$LIBS
 525   old_LDFLAGS="$LDFLAGS"
 526   if test "x$OPENSSL_LIB_DIR" != "x"; then
 527     LDFLAGS="$LDFLAGS -L$OPENSSL_LIB_DIR"
 528   fi
 529   AC_CHECK_LIB(crypto, DH_new,
 530     [
 531         LIBS="-lcrypto $LIBS"
 532         AC_DEFINE(HAVE_LIBCRYPTO, 1,
 533             [Define to 1 if you have the `crypto' library (-lcrypto).])
 534         AC_CHECK_LIB(ssl, SSL_new,
 535             [
 536                 AC_DEFINE(HAVE_LIBSSL, 1,
 537                     [Define to 1 if you have the `ssl' library (-lssl).])
 538                 if test "x$OPENSSL_LIB_DIR" != "x"; then
 539                     OPENSSL_LIBS="-L$OPENSSL_LIB_DIR"
 540                 fi
 541                 OPENSSL_LIBS="$OPENSSL_LIBS -lcrypto -lssl -lcrypto"
 542             ], [])
 543     ], [])
 544   LIBS=$old_LIBS
 545   LDFLAGS="$old_LDFLAGS"
 546 fi
 547
 548 AC_CHECK_LIB(ws2_32, htonl)
 549
 550 dnl Check the pcap library for the RADIUS sniffer.
 551 PCAP_LIBS=
 552 AC_CHECK_LIB(pcap, pcap_open_live,
 553         [ PCAP_LIBS="-lpcap"
 554         AC_DEFINE(HAVE_LIBPCAP, 1,
 555                 [Define to 1 if you have the `pcap' library (-lpcap).])
 556         ],
 557         [ AC_MSG_WARN([pcap library not found, silently disabling the RADIUS sniffer.]) ])
 558
 559 AC_LIB_READLINE
 560
 561 dnl #############################################################
 562 dnl #
 563 dnl #  3. Checks for header files
 564 dnl #
 565 dnl #############################################################
 566
 567 dnl #
 568 dnl # Interix requires us to set -D_ALL_SOURCE, otherwise
 569 dnl # getopt will be #included, but won't link.  <sigh>
 570 dnl #
 571 dnl #
 572 case "$host" in
 573 *-interix*)
 574         CFLAGS="$CFLAGS -D_ALL_SOURCE"
 575         ;;
 576 *-darwin*)
 577         CFLAGS="$CFLAGS -DDARWIN"
 578         LIBS="-framework DirectoryService $LIBS"
 579         ;;
 580 esac
 581
 582 AC_HEADER_DIRENT
 583 AC_HEADER_STDC
 584 AC_HEADER_TIME
 585 AC_HEADER_SYS_WAIT
 586
 587 AC_CHECK_HEADERS( \
 588         unistd.h \
 589         crypt.h \
 590         errno.h \
 591         resource.h \
 592         sys/resource.h \
 593         getopt.h \
 594         malloc.h \
 595         utmp.h \
 596         utmpx.h \
 597         signal.h \
 598         sys/select.h \
 599         syslog.h \
 600         inttypes.h \
 601         stdint.h \
 602         stdio.h \
 603         netdb.h \
 604         semaphore.h \
 605         arpa/inet.h \
 606         netinet/in.h \
 607         sys/types.h \
 608         sys/socket.h \
 609         winsock.h \
 610         sys/time.h \
 611         sys/wait.h \
 612         sys/security.h \
 613         fcntl.h \
 614         sys/fcntl.h \
 615         sys/prctl.h \
 616         sys/un.h \
 617         glob.h \
 618         prot.h \
 619         pwd.h \
 620         grp.h \
 621         sia.h \
 622         siad.h
 623 )
 624
 625 dnl FreeBSD requires sys/socket.h before net/if.h
 626 AC_CHECK_HEADERS(net/if.h, [], [],
 627 [#ifdef HAVE_SYS_SOCKET_H
 628 # include <sys/socket.h>
 629 # endif
 630 ])
 631
 632 REGEX=no
 633 AC_CHECK_HEADER(regex.h, AC_DEFINE(HAVE_REGEX_H, [], [define this if we have the <regex.h> header file]))
 634 if test "x$ac_cv_header_regex_h" = "xyes"; then
 635   REGEX_EXTENDED=no
 636   REGEX=yes
 637   AC_EGREP_CPP(yes,
 638     [#include <regex.h>
 639      #ifdef REG_EXTENDED
 640        yes
 641      #endif
 642      ], [AC_DEFINE(HAVE_REG_EXTENDED, [], [define this if we have REG_EXTENDED (from <regex.h>)]) REGEX_EXTENDED=yes])
 643 fi
 644 AC_SUBST(REGEX)
 645 AC_SUBST(REGEX_EXTENDED)
 646
 647 dnl #
 648 dnl #  other checks which require headers
 649 dnl #
 650 if test "x$ac_cv_header_sys_security_h" = "xyes" && test "x$ac_cv_header_prot_h" = "xyes"
 651 then
 652   AC_DEFINE(OSFC2, [], [define if you have OSFC2 authentication])
 653 fi
 654
 655 if test "x$ac_cv_header_sia_h" = "xyes" && test "x$ac_cv_header_siad_h" = "xyes"
 656 then
 657   AC_DEFINE(OSFSIA, [], [define if you have OSFSIA authentication])
 658 fi
 659
 660 dnl Check for OpenSSL includes.
 661 OPENSSL_INCLUDE="-DNO_OPENSSL"
 662 if test "x$WITH_OPENSSL" = xyes; then
 663   if test "x$OPENSSL_LIBS" = "x"; then
 664     AC_MSG_NOTICE([skipping test for openssl/ssl.h])
 665   else
 666     old_CPPFLAGS=$CPPFLAGS
 667     if test "x$OPENSSL_INCLUDE_DIR" != "x"; then
 668         CPPFLAGS="$CPPFLAGS -I$OPENSSL_INCLUDE_DIR"
 669     fi
 670     dnl # stupid RedHat shit
 671     CPPFLAGS="$CPPFLAGS -DOPENSSL_NO_KRB5"
 672     AC_CHECK_HEADERS( \
 673         openssl/ssl.h \
 674         openssl/crypto.h \
 675         openssl/err.h \
 676         openssl/evp.h \
 677         openssl/engine.h,
 678         [],
 679         OPENSSL_LIBS=
 680     )
 681     if test "x$OPENSSL_LIBS" != "x"; then
 682         AC_MSG_CHECKING([for OpenSSL version >= 0.9.7])
 683         AC_EGREP_CPP(yes,
 684             [#include <openssl/crypto.h>
 685              #if (OPENSSL_VERSION_NUMBER >= 0x00907000L)
 686              yes
 687              #endif
 688             ], goodssl="yes")
 689         if test "x$goodssl" != "xyes"; then
 690             AC_MSG_RESULT(no)
 691             OPENSSL_LIBS=
 692         else
 693             AC_MSG_RESULT(yes)
 694             if test "x$OPENSSL_INCLUDE_DIR" != "x"; then
 695                 OPENSSL_INCLUDE="-I$OPENSSL_INCLUDE_DIR -DOPENSSL_NO_KRB5"
 696             else
 697                 OPENSSL_INCLUDE="-DOPENSSL_NO_KRB5"
 698             fi
 699         fi
 700     fi
 701     CPPFLAGS=$old_CPPFLAGS
 702   fi
 703 fi
 704 AC_SUBST(OPENSSL_INCLUDE)
 705 AC_SUBST(OPENSSL_LIBS)
 706 export OPENSSL_LIBS
 707
 708 dnl Check the pcap includes for the RADIUS sniffer.
 709 if test "x$PCAP_LIBS" = x; then
 710     AC_MSG_NOTICE([skipping test for pcap.h.])
 711 else
 712     AC_CHECK_HEADER(pcap.h,
 713         AC_DEFINE(HAVE_PCAP_H, 1,
 714                 [Define to 1 if you have the <pcap.h> header file.]),
 715         [ PCAP_LIBS=
 716         AC_MSG_WARN([pcap.h not found, silently disabling the RADIUS sniffer.])
 717         ])
 718 fi
 719 AC_SUBST(PCAP_LIBS)
 720
 721 dnl #############################################################
 722 dnl #
 723 dnl #  4. Checks for typedefs
 724 dnl #
 725 dnl #############################################################
 726
 727 dnl #
 728 dnl # Ensure that these are defined
 729 dnl #
 730 AC_TYPE_OFF_T
 731 AC_TYPE_PID_T
 732 AC_TYPE_SIZE_T
 733 AC_TYPE_UID_T
 734
 735 dnl check for socklen_t
 736 FR_CHECK_TYPE_INCLUDE([
 737 #ifdef HAVE_SYS_TYPES_H
 738 #include <sys/types.h>
 739 #endif
 740 #ifdef HAVE_SYS_SOCKET_H
 741 #include <sys/socket.h>
 742 #endif
 743 ],socklen_t, int, [socklen_t is generally 'int' on systems which don't use it])
 744
 745 dnl check for uint8_t
 746 FR_CHECK_TYPE_INCLUDE([
 747 #ifdef HAVE_INTTYPES_H
 748 #include <inttypes.h>
 749 #endif
 750 #ifdef HAVE_STDINT_H
 751 #include <stdint.h>
 752 #endif
 753 ],uint8_t, unsigned char, [uint8_t should be the canonical 'octet' for network traffic])
 754
 755 dnl check for uint16_t
 756 FR_CHECK_TYPE_INCLUDE([
 757 #ifdef HAVE_INTTYPES_H
 758 #include <inttypes.h>
 759 #endif
 760 #ifdef HAVE_STDINT_H
 761 #include <stdint.h>
 762 #endif
 763 ],uint16_t, unsigned short, [uint16_t should be the canonical '2 octets' for network traffic])
 764
 765 dnl check for uint32_t
 766 FR_CHECK_TYPE_INCLUDE([
 767 #ifdef HAVE_INTTYPES_H
 768 #include <inttypes.h>
 769 #endif
 770 #ifdef HAVE_STDINT_H
 771 #include <stdint.h>
 772 #endif
 773 ],uint32_t, unsigned int, [uint32_t should be the canonical 'network integer])
 774
 775 AC_CHECK_TYPE(struct in6_addr, AC_DEFINE(HAVE_STRUCT_IN6_ADDR, 1, [IPv6 address structure]), [], [
 776 #ifdef HAVE_NETINET_IN_H
 777 #include <netinet/in.h>
 778 #endif
 779 ])
 780
 781 AC_CHECK_TYPE(struct sockaddr_storage, AC_DEFINE(HAVE_STRUCT_SOCKADDR_STORAGE, 1, [Generic socket addresses]), [], [
 782 #ifdef HAVE_NETINET_IN_H
 783 #include <netinet/in.h>
 784 #endif
 785 #ifdef HAVE_SYS_SOCKET_H
 786 #include <sys/socket.h>
 787 #endif
 788 ])
 789
 790 AC_CHECK_TYPE(struct sockaddr_in6, AC_DEFINE(HAVE_STRUCT_SOCKADDR_IN6, 1, [IPv6 socket addresses]), [], [
 791 #ifdef HAVE_NETINET_IN_H
 792 #include <netinet/in.h>
 793 #endif
 794 ])
 795
 796 AC_CHECK_TYPE(struct addrinfo, AC_DEFINE(HAVE_STRUCT_ADDRINFO, 1, [Generic DNS lookups]), [], [
 797 #ifdef HAVE_SYS_TYPES_H
 798 #include <sys/types.h>
 799 #endif
 800 #ifdef HAVE_SYS_SOCKET_H
 801 #include <sys/socket.h>
 802 #endif
 803 #ifdef HAVE_NETDB_H
 804 #include <netdb.h>
 805 #endif
 806 ])
 807
 808 dnl #############################################################
 809 dnl #
 810 dnl #  5. Checks for structures and functions
 811 dnl #
 812 dnl #############################################################
 813 AC_CHECK_FUNCS( \
 814         getopt_long \
 815         lockf \
 816         strsignal \
 817         sigaction \
 818         sigprocmask \
 819         pthread_sigmask \
 820         snprintf \
 821         vsnprintf \
 822         setsid \
 823         strncasecmp \
 824         strcasecmp \
 825         localtime_r \
 826         ctime_r \
 827         gmtime_r \
 828         strsep \
 829         inet_aton \
 830         inet_pton \
 831         inet_ntop \
 832         setlinebuf \
 833         setvbuf \
 834         getusershell \
 835         initgroups \
 836         getaddrinfo \
 837         getnameinfo \
 838         closefrom \
 839         gettimeofday \
 840         getpeereid \
 841         setuid \
 842         setresuid \
 843         getresuid \
 844         strlcat \
 845         strlcpy
 846 )
 847 RADIUSD_NEED_DECLARATIONS( \
 848         crypt \
 849         strncasecmp \
 850         strcasecmp \
 851         inet_aton \
 852         setlinebuf \
 853         getusershell \
 854         endusershell
 855 )
 856
 857 AC_TYPE_SIGNAL
 858
 859 dnl # check if we have utmpx.h
 860 dnl # if so, check if struct utmpx has entry ut_xtime
 861 dnl # if not, set it to define ut_xtime == ut_tv.tv_sec
 862 if test "x$ac_cv_header_utmpx_h" = "xyes"
 863 then
 864  FR_CHECK_STRUCT_HAS_MEMBER([#include <utmpx.h>], [struct utmpx], ut_xtime)
 865  if test "x$ac_cv_type_struct_utmpx_has_ut_xtime" = "x"
 866  then
 867    AC_DEFINE(ut_xtime,ut_tv.tv_sec, [define to something if you don't have ut_xtime in struct utmpx])
 868  fi
 869 fi
 870
 871 dnl # struct ip_pktinfo
 872 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in_pktinfo], ipi_addr)
 873 if test "x$ac_cv_type_struct_in_pktinfo_has_ipi_addr" = "xyes"
 874 then
 875         AC_DEFINE(HAVE_IP_PKTINFO, [], [define if you have IP_PKTINFO (Linux)])
 876 fi
 877
 878 dnl # struct in6_pktinfo
 879 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in6_pktinfo], ipi6_addr)
 880 if test "x$ac_cv_type_struct_in6_pktinfo_has_ipi6_addr" = "xyes"
 881 then
 882         AC_DEFINE(HAVE_IN6_PKTINFO, [], [define if you have IN6_PKTINFO (Linux)])
 883 fi
 884
 885 dnl #############################################################
 886 dnl #
 887 dnl #  6. Checks for compiler characteristics
 888 dnl #
 889 dnl #############################################################
 890
 891 dnl #
 892 dnl # Ensure that these are defined
 893 dnl #
 894 AC_C_CONST
 895
 896 dnl #
 897 dnl # See if this is OS/2
 898 dnl #
 899 AC_MSG_CHECKING(type of OS)
 900 OS=`uname -s`
 901 AC_MSG_RESULT($OS)
 902 if test "$OS" = "OS/2"; then
 903         LIBPREFIX=
 904 else
 905         LIBPREFIX=lib
 906 fi
 907 AC_SUBST(LIBPREFIX)
 908
 909 dnl #
 910 dnl # Set Default CFLAGS
 911 dnl #
 912 if test "x$GCC" = "xyes"; then
 913     CFLAGS="$CFLAGS -Wall -D_GNU_SOURCE"
 914 fi
 915
 916 AC_MSG_CHECKING(for developer gcc flags)
 917 if test "x$developer" = "xyes" -a "x$GCC" = "xyes"; then
 918   devflags="-g -Wshadow -Wpointer-arith -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -W -Wredundant-decls -Wundef"
 919   CFLAGS="$CFLAGS $devflags"
 920   INSTALLSTRIP=""
 921   AC_MSG_RESULT(yes.  Using $devflags)
 922 else
 923   devflags=""
 924   CFLAGS="$CFLAGS -DNDEBUG"
 925   INSTALLSTRIP=""
 926   AC_MSG_RESULT(no.)
 927 fi
 928
 929 FR_TLS
 930
 931 dnl #############################################################
 932 dnl #
 933 dnl #  7. Checks for library functions
 934 dnl #
 935 dnl #############################################################
 936
 937 old_LIBS="$LIBS"
 938 LIBS="$LIBS $LIBLTDL"
 939 AC_CHECK_FUNC(lt_dladvise_init, AC_DEFINE(HAVE_HAVE_LT_DLADVISE_INIT, [], [Do we have the lt_dladvise_init function]))
 940 LIBS="$old_LIBS"
 941
 942 dnl Check for libcrypt
 943 dnl We use crypt(3) which may be in libc, or in libcrypt (eg FreeBSD)
 944 AC_CHECK_LIB(crypt, crypt,
 945   CRYPTLIB="-lcrypt"
 946 )
 947 if test "$CRYPTLIB" != ""; then
 948   AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function])
 949 else
 950   AC_CHECK_FUNC(crypt, AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function]))
 951 fi
 952
 953 dnl Check for libcipher
 954 AC_CHECK_LIB(cipher, setkey,
 955    CRYPTLIB="${CRYPTLIB} -lcipher"
 956 )
 957 AC_SUBST(CRYPTLIB)
 958
 959 dnl Check the style of gethostbyaddr, in order of preference
 960 dnl GNU (_r eight args)
 961 AC_DEFINE(GNUSTYLE, [1], [GNU-Style get*byaddr_r])
 962 dnl SYSV (_r six args)
 963 AC_DEFINE(SYSVSTYLE, [2], [SYSV-Style get*byaddr_r])
 964 dnl BSD (three args, may not be thread safe)
 965 AC_DEFINE(BSDSTYLE, [3], [BSD-Style get*byaddr_r])
 966 dnl Tru64 has BSD version, but it is thread safe
 967 dnl     http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1739____.HTM
 968 dnl We need #stdio.h to define NULL on FreeBSD (at least)
 969 gethostbyaddrrstyle=""
 970 AC_MSG_CHECKING([gethostbyaddr_r() syntax])
 971 case "$host" in
 972 *-freebsd*)
 973 dnl With FreeBSD, check if there's a prototype for gethostbyaddr_r.
 974 dnl Some versions (FreeBSD 5.1?) have a symbol but no prototype - so we
 975 dnl override this test to BSDSTYLE. FreeBSD 6.2 and up have proper GNU
 976 dnl style support.
 977         AC_CHECK_DECLS([gethostbyaddr_r], [], [
 978                 AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE,
 979                         [style of gethostbyaddr_r functions ])
 980                 gethostbyaddrrstyle=BSD
 981                 AC_MSG_WARN([FreeBSD overridden to BSD-style])
 982         ], [
 983 #ifdef HAVE_NETDB_H
 984 #include <netdb.h>
 985 #endif
 986 ])
 987         ;;
 988 esac
 989 if test "x$gethostbyaddrrstyle" = "x"; then
 990         AC_TRY_LINK([
 991 #include <stdio.h>
 992 #include <netdb.h>
 993 ], [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL, NULL) ], [
 994         AC_DEFINE(GETHOSTBYADDRRSTYLE, GNUSTYLE, [style of gethostbyaddr_r functions ])
 995         gethostbyaddrrstyle=GNU
 996 ])
 997 fi
 998 if test "x$gethostbyaddrrstyle" = "x"; then
 999         AC_TRY_LINK([
1000 #include <stdio.h>
1001 #include <netdb.h>
1002 ], [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL) ] , [
1003                 AC_DEFINE(GETHOSTBYADDRRSTYLE, SYSVSTYLE, [style of gethostbyaddr_r functions ])
1004                 gethostbyaddrrstyle=SYSV
1005         ])
1006 fi
1007 if test "x$gethostbyaddrrstyle" = "x"; then
1008         AC_TRY_LINK([
1009 #include <stdio.h>
1010 #include <netdb.h>
1011 ], [ gethostbyaddr(NULL, 0, 0)  ], [
1012                 AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE, [style of gethostbyaddr_r functions ])
1013                 gethostbyaddrrstyle=BSD
1014         ])
1015 fi
1016
1017 if test "x$gethostbyaddrrstyle" = "x"; then
1018         AC_MSG_RESULT([none!  It must not exist, here.])
1019 else
1020         AC_MSG_RESULT([${gethostbyaddrrstyle}-style])
1021 fi
1022
1023 if test "x$gethostbyaddrrstyle" = "xBSD"; then
1024         AC_MSG_WARN([ ****** BSD-style gethostbyaddr might NOT be thread-safe! ****** ])
1025 fi
1026
1027 dnl Check the style of gethostbyname, in order of preference
1028 dnl GNU (_r seven args)
1029 dnl SYSV (_r five args)
1030 dnl BSD (two args, may not be thread safe)
1031 dnl Tru64 has BSD version, but it _is_ thread safe
1032 dnl     http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1946____.HTM
1033 dnl We need #stdio.h to define NULL on FreeBSD (at least)
1034 gethostbynamerstyle=""
1035 AC_MSG_CHECKING([gethostbyname_r() syntax])
1036 AC_TRY_LINK([
1037 #include <stdio.h>
1038 #include <netdb.h>
1039 ], [ gethostbyname_r(NULL, NULL, NULL, 0, NULL, NULL) ], [
1040         AC_DEFINE(GETHOSTBYNAMERSTYLE, GNUSTYLE, [style of gethostbyname_r functions ])
1041         gethostbynamerstyle=GNU
1042 ])
1043 if test "x$gethostbynamerstyle" = "x"; then
1044         AC_TRY_LINK([
1045 #include <stdio.h>
1046 #include <netdb.h>
1047 ], [ gethostbyname_r(NULL, NULL, NULL, 0, NULL) ] , [
1048                 AC_DEFINE(GETHOSTBYNAMERSTYLE, SYSVSTYLE, [style of gethostbyname_r functions ])
1049                 gethostbynamerstyle=SYSV
1050         ])
1051 fi
1052 if test "x$gethostbynamerstyle" = "x"; then
1053         AC_TRY_LINK([
1054 #include <stdio.h>
1055 #include <netdb.h>
1056 ], [ gethostbyname(NULL)  ], [
1057                 AC_DEFINE(GETHOSTBYNAMERSTYLE, BSDSTYLE, [style of gethostbyname_r functions ])
1058                 gethostbynamerstyle=BSD
1059         ])
1060 fi
1061
1062 if test "x$gethostbynamerstyle" = "x"; then
1063         AC_MSG_RESULT([none!  It must not exist, here.])
1064 else
1065         AC_MSG_RESULT([${gethostbynamerstyle}-style])
1066 fi
1067
1068 if test "x$gethostbynamerstyle" = "xBSD"; then
1069         AC_MSG_WARN([ ****** BSD-style gethostbyname might NOT be thread-safe! ****** ])
1070 fi
1071
1072 dnl check for non-posix solaris ctime_r (extra buflen int arg)
1073 AC_DEFINE(POSIXSTYLE, [1], [Posix-Style ctime_r])
1074 AC_DEFINE(SOLARISSTYLE, [2], [Solaris-Style ctime_r])
1075 ctimerstyle=""
1076 AC_MSG_CHECKING([ctime_r() syntax])
1077 AC_TRY_LINK([
1078 #include <time.h>
1079 ], [ ctime_r(NULL, NULL, 0) ], [
1080         AC_DEFINE(CTIMERSTYLE, SOLARISSTYLE, [style of ctime_r function])
1081         ctimerstyle="SOLARIS"
1082 ])
1083 if test "x$ctimerstyle" = "x"; then
1084         AC_TRY_LINK([
1085 #include <time.h>
1086 ], [ ctime_r(NULL, NULL) ], [
1087                 AC_DEFINE(CTIMERSTYLE, POSIXSTYLE, [style of ctime_r function])
1088                 ctimerstyle="POSIX"
1089         ])
1090 fi
1091
1092 if test "x$ctimerstyle" = "x"; then
1093         AC_MSG_RESULT([none!  It must not exist, here.])
1094 else
1095         AC_MSG_RESULT([${ctimerstyle}-style])
1096 fi
1097
1098 AC_SUBST(HOSTINFO, $host)
1099
1100 dnl #############################################################
1101 dnl #
1102 dnl #  8. Checks for system services
1103 dnl #
1104 dnl #############################################################
1105
1106 dnl #
1107 dnl # Figure out where libtool is located,
1108 dnl #
1109 top_builddir=`pwd`
1110 export top_builddir
1111 AC_MSG_RESULT([top_builddir=$top_builddir])
1112 dnl # AC_SUBST(top_builddir)
1113 AC_SUBST(LIBLTDL)
1114 AC_SUBST(INCLTDL)
1115
1116 dnl import libtool stuff
1117
1118 dnl #############################################################
1119 dnl #
1120 dnl #  Configure in any module directories.
1121 dnl #
1122 dnl #############################################################
1123
1124 mysubdirs="$LIBLTDLPATH"
1125 if test "x$EXPERIMENTAL" = "xyes"; then
1126   bar=`ls -1 "${srcdir}"/src/modules/rlm_*/configure | sed 's%/configure%%'`
1127   dnl # get rid of LF's.
1128   mysubdirs=`echo $mysubdirs $bar`
1129 else
1130   dnl #
1131   dnl # Find 'configure' in ONLY the stable modules
1132   dnl #
1133   for bar in `cat "${srcdir}"/src/modules/stable`; do
1134     if test -f "${srcdir}"/src/modules/$bar/configure; then
1135       mysubdirs="$mysubdirs src/modules/$bar"
1136     fi
1137   done
1138 fi
1139
1140 dnl ############################################################
1141 dnl # make modules by list
1142 dnl #############################################################
1143 if test "x$EXPERIMENTAL" = "xyes"; then
1144   for foo in `ls -1 "${srcdir}"/src/modules | grep rlm_`; do
1145     MODULES="$MODULES $foo"
1146   done
1147 else
1148    dnl #
1149    dnl # make ONLY the stable modules
1150    dnl #
1151    for foo in `cat "${srcdir}"/src/modules/stable`; do
1152     MODULES="$MODULES $foo"
1153    done
1154 fi
1155
1156 dnl #
1157 dnl #  Don't change the variable name here.  Autoconf goes bonkers
1158 dnl #  if you do.
1159 dnl #
1160 AC_CONFIG_SUBDIRS($LTDL_SUBDIRS $mysubdirs)
1161 AC_SUBST(MODULES)
1162
1163 dnl #############################################################
1164 dnl #
1165 dnl #  And finally, output the results.
1166 dnl #
1167 dnl #############################################################
1168
1169 AC_CONFIG_COMMANDS([stamp-h], [echo timestamp > src/include/stamp-h])
1170 AC_CONFIG_COMMANDS([build-radpaths-h], [(cd ./src/include && /bin/sh ./build-radpaths-h)])
1171 AC_CONFIG_COMMANDS([main-chmod], [(cd ./src/main   && chmod +x checkrad.pl radlast radtest)])
1172 AC_CONFIG_COMMANDS([scripts-chmod], [(cd ./scripts    && chmod +x rc.radiusd radwatch radiusd.cron.daily radiusd.cron.monthly cryptpasswd)])
1173
1174 dnl #
1175 dnl #  Substitute whatever libraries we found to be necessary
1176 dnl #
1177 AC_SUBST(LIBS)
1178 AC_SUBST(INSTALLSTRIP)
1179
1180 USE_SHARED_LIBS=$enable_shared
1181 AC_SUBST(USE_SHARED_LIBS)
1182 USE_STATIC_LIBS=$enable_static
1183 AC_SUBST(USE_STATIC_LIBS)
1184 AC_SUBST(STATIC_MODULES)
1185 AC_SUBST(RADIUSD_MAJOR_VERSION)
1186 AC_SUBST(RADIUSD_MINOR_VERSION)
1187 AC_SUBST(RADIUSD_VERSION)
1188
1189 AC_OUTPUT(\
1190         ./Make.inc \
1191         ./src/include/build-radpaths-h \
1192         ./src/main/Makefile \
1193         ./src/main/checkrad.pl \
1194         ./src/main/radlast \
1195         ./src/main/radtest \
1196         ./scripts/rc.radiusd \
1197         ./scripts/radwatch \
1198         ./scripts/radiusd.cron.daily \
1199         ./scripts/radiusd.cron.monthly \
1200         ./scripts/cryptpasswd \
1201         ./raddb/dictionary \
1202         ./raddb/radrelay.conf \
1203         ./raddb/radiusd.conf
1204 )