configure.in

   1 dnl #############################################################
   2 dnl #
   3 dnl #  For information about autoconf, see:
   4 dnl #
   5 dnl #  http://www.gnu.org/software/autoconf/
   6 dnl #
   7 dnl #  The recommended order is:
   8 dnl #
   9 dnl #  AC_INIT(file)
  10 dnl #  0. checks for compiler, libtool, and command line options
  11 dnl #  1. checks for programs
  12 dnl #  2. checks for libraries
  13 dnl #  3. checks for header files
  14 dnl #  4. checks for typedefs
  15 dnl #  5. checks for structures and functions
  16 dnl #  6. checks for compiler characteristics
  17 dnl #  7. checks for library functions
  18 dnl #  8. checks for system services
  19 dnl #  AC_OUTPUT([file...])
  20 dnl #
  21 dnl #############################################################
  22
  23 AC_PREREQ([2.59])
  24 export CFLAGS LIBS LDFLAGS CPPFLAGS
  25 AC_INIT(src/main/radiusd.c)
  26 AC_CONFIG_HEADER(src/include/autoconf.h)
  27 AC_REVISION($Revision$)dnl
  28
  29 dnl # The version of the software
  30 RADIUSD_VERSION=`cat VERSION`
  31 RADIUSD_MAJOR_VERSION=`cat VERSION | sed 's/\..*//'`
  32 RADIUSD_MINOR_VERSION=`cat VERSION | sed 's/^3\.//'`
  33 PACKAGE=freeradius
  34
  35 dnl #############################################################
  36 dnl #
  37 dnl #  0. Checks for compiler, libtool, and command line options.
  38 dnl #
  39 dnl #############################################################
  40
  41 dnl Check for GNU cc
  42 AC_PROG_CC
  43 AC_PROG_CXX
  44
  45 dnl #
  46 dnl # check for AIX, to allow us to use some BSD functions
  47 dnl # must be before macros that call the compiler.
  48 dnl #
  49 AC_AIX
  50
  51 AC_PROG_GCC_TRADITIONAL
  52 AC_PROG_CC_SUNPRO
  53 AC_PROG_RANLIB
  54
  55 dnl #
  56 dnl # Set Default CFLAGS
  57 dnl #
  58 if test "x$GCC" = "xyes"; then
  59     CFLAGS="$CFLAGS -Wall -D_GNU_SOURCE"
  60 fi
  61
  62 dnl Compile in large (2G+) file support.
  63 AC_SYS_LARGEFILE
  64
  65 dnl # check for system bytesex
  66 dnl # AC_DEFINES WORDS_BIGENDIAN
  67 AC_C_BIGENDIAN
  68
  69 dnl Find GNU Make.
  70 AC_CHECK_PROG(GMAKE, gmake, yes, no)
  71 if test $GMAKE = no; then
  72   AC_PATH_PROG(MAKE, make, /usr/local/bin/make)
  73 else
  74   AC_PATH_PROG(MAKE, gmake, /usr/local/gnu/bin/make)
  75 fi
  76 makever=`$ac_cv_path_MAKE --version 2>&1 | grep "GNU Make"`
  77 if test -z "$makever"; then
  78   AC_MSG_ERROR(GNU Make is not installed.  Please download and install it
  79                 from ftp://prep.ai.mit.edu/pub/gnu/make/ before continuing.)
  80 fi
  81
  82 AC_ARG_WITH(system-libltdl,
  83 [  --with-system-libltdl   Use the libltdl installed in your system (default=use dlopen)],
  84 [
  85 LIBLTDL="-lltdl"
  86 INCLTDL=-DWITH_SYSTEM_LTDL
  87 ],
  88 )
  89
  90 dnl use system-wide libtool, if it exists
  91 AC_ARG_WITH(system-libtool,
  92 [  --with-system-libtool   Use the libtool installed in your system (default=use our own)],
  93 [ AC_PATH_PROG(LIBTOOL, libtool,,$PATH:/usr/local/bin) AC_LIBTOOL_DLOPEN
  94  AC_PROG_LIBTOOL],
  95 [
  96   LIBTOOL='${top_srcdir}/scripts/jlibtool'
  97   AC_SUBST(LIBTOOL)
  98   dnl ensure that we're looking for dlopen
  99   AC_LIBTOOL_DLOPEN
 100 ])
 101
 102
 103 dnl Put this in later, when all distributed modules use autoconf.
 104 dnl AC_ARG_WITH(disablemodulefoo,
 105 dnl [  --without-rlm_foo       Disables module compilation.  Module list:]
 106 dnl esyscmd([find src/modules -type d -name rlm_\* -print |\
 107 dnl     sed -e 's%src/modules/.*/% (sub)- %; s%.*/%- %' |\
 108 dnl     awk '{print "                            "$0}']))
 109
 110 AC_ARG_ENABLE(strict-dependencies,
 111 [  --enable-strict-dependencies  Fail configure on lack of module dependancy.])
 112
 113 dnl extra argument: --with-docdir
 114 docdir='${datadir}/doc/freeradius'
 115 AC_MSG_CHECKING(docdir)
 116 AC_ARG_WITH(docdir,
 117 [  --with-docdir=DIR       Directory for documentation [DATADIR/doc/freeradius] ],
 118 [ case "$withval" in
 119     no)
 120         docdir=no
 121         ;;
 122     yes)
 123         ;;
 124     [[\\/$]]* | ?:[[\\/]]* )
 125         docdir="$withval"
 126         ;;
 127     *)
 128         AC_MSG_ERROR([expected an absolute directory name for --with-docdir: $withval])
 129         ;;
 130   esac ]
 131 )
 132 AC_SUBST(docdir)
 133 AC_MSG_RESULT($docdir)
 134 if test "x$docdir" = xno; then
 135         AC_MSG_WARN(Documentation files will NOT be installed.)
 136 fi
 137
 138 dnl extra argument: --with-logdir
 139 logdir='${localstatedir}/log/radius'
 140 AC_MSG_CHECKING(logdir)
 141 AC_ARG_WITH(logdir,
 142 [  --with-logdir=DIR       Directory for logfiles [LOCALSTATEDIR/log/radius] ],
 143 [ case "$withval" in
 144     no)
 145         AC_MSG_ERROR(Need logdir)
 146         ;;
 147     yes)
 148         ;;
 149     [[\\/$]]* | ?:[[\\/]]* )
 150         logdir="$withval"
 151         ;;
 152     *)
 153         AC_MSG_ERROR([expected an absolute directory name for --with-logdir: $withval])
 154         ;;
 155   esac ]
 156 )
 157 AC_SUBST(logdir)
 158 AC_MSG_RESULT($logdir)
 159
 160 dnl extra argument: --with-radacctdir
 161 radacctdir='${logdir}/radacct'
 162 AC_MSG_CHECKING(radacctdir)
 163 AC_ARG_WITH(radacctdir,
 164 [  --with-radacctdir=DIR   Directory for detail files [LOGDIR/radacct] ],
 165 [ case "$withval" in
 166     no)
 167         AC_MSG_ERROR(Need radacctdir)
 168         ;;
 169     yes)
 170         ;;
 171     [[\\/$]]* | ?:[[\\/]]* )
 172         radacctdir="$withval"
 173         ;;
 174     *)
 175         AC_MSG_ERROR([expected an absolute directory name for --with-radacctdir: $withval])
 176         ;;
 177   esac ]
 178 )
 179 AC_SUBST(radacctdir)
 180 AC_MSG_RESULT($radacctdir)
 181
 182 dnl extra argument: --with-raddbdir
 183 raddbdir='${sysconfdir}/raddb'
 184 AC_MSG_CHECKING(raddbdir)
 185 AC_ARG_WITH(raddbdir,
 186 [  --with-raddbdir=DIR     Directory for config files [SYSCONFDIR/raddb] ],
 187 [ case "$withval" in
 188     no)
 189         AC_MSG_ERROR(Need raddbdir)
 190         ;;
 191     yes)
 192         ;;
 193     [[\\/$]]* | ?:[[\\/]]* )
 194         raddbdir="$withval"
 195         ;;
 196     *)
 197         AC_MSG_ERROR([expected an absolute directory name for --with-raddbdir: $withval])
 198         ;;
 199   esac ]
 200 )
 201 AC_SUBST(raddbdir)
 202 AC_MSG_RESULT($raddbdir)
 203
 204 dnl extra argument: --with-ascend-binary
 205 ASCEND_BINARY=yes
 206 AC_ARG_WITH(ascend-binary,
 207 [  --with-ascend-binary    Include support for Ascend binary filter attributes (default=yes)],
 208 [ case "$withval" in
 209     yes)
 210         ;;
 211     *)
 212         ASCEND_BINARY=""
 213   esac ]
 214 )
 215 if test "X$ASCEND_BINARY" = "Xyes"; then
 216   AC_DEFINE(ASCEND_BINARY, [], [Include support for Ascend binary filter attributes])
 217 fi
 218
 219 dnl extra argument: --with-threads
 220 WITH_THREADS=yes
 221 AC_ARG_WITH(threads,
 222 [  --with-threads          Use threads, if available.  (default=yes) ],
 223 [ case "$withval" in
 224     yes)
 225         ;;
 226     *)
 227         WITH_THREADS=""
 228   esac ]
 229 )
 230
 231 dnl extra argument: --with-vmps
 232 WITH_VMPS=yes
 233 AC_ARG_WITH(vmps,
 234 [  --with-vmps             Compile in VMPS support. (default=yes)],
 235 [ case "$withval" in
 236     yes)
 237         ;;
 238     *)
 239         WITH_VMPS=no
 240   esac ]
 241 )
 242 if test "x$WITH_VMPS" = "xyes"; then
 243         AC_DEFINE(WITH_VMPS, [1], [define if you want VMPS support])
 244 fi
 245
 246 dnl extra argument: --with-dhcp
 247 WITH_DHCP=yes
 248 AC_ARG_WITH(dhcp,
 249 [  --with-dhcp             Compile in DHCP support. (default=yes)],
 250 [ case "$withval" in
 251     yes)
 252         ;;
 253     *)
 254         WITH_DHCP=no
 255   esac ]
 256 )
 257 if test "x$WITH_DHCP" = "xyes"; then
 258         AC_DEFINE(WITH_DHCP, [1], [define if you want DHCP support])
 259 fi
 260
 261
 262 dnl #
 263 dnl #  Allow the user to specify a list of modules to be linked
 264 dnl #  statically to the server.
 265 dnl #
 266 STATIC_MODULES=
 267 AC_ARG_WITH(static_modules,
 268 [  --with-static-modules=QUOTED-MODULE-LIST],[
 269   for i in $withval; do
 270     STATIC_MODULES="$STATIC_MODULES -dlpreopen ../modules/rlm_$i/rlm_$i.la"
 271   done
 272 ])
 273
 274 MODULES=
 275 AC_ARG_WITH(modules,
 276 [ --with-modules=QUOTED-MODULE-LIST],[
 277  for i in $withval; do
 278    MODULES="$MODULES $i"
 279  done
 280 ])
 281
 282 dnl #
 283 dnl #  Enable developer C compiler warnings
 284 dnl #
 285 AC_ARG_ENABLE(developer,
 286 [  --enable-developer               Enables features of interest to developers.],
 287 [ case "$enableval" in
 288     no)
 289         developer=no
 290         ;;
 291     *)
 292         developer=yes
 293   esac ]
 294 )
 295
 296 if test "x$developer" != "xno" -a -d $srcdir/CVS; then
 297   dnl turn on the developer flag when taken from a CVS checkout (not a release)
 298   developer="yes"
 299 fi
 300
 301 if test "x$developer" != "xno" -a -d $srcdir/.git; then
 302   dnl turn on the developer flag when taken from a git checkout (not a release)
 303   developer="yes"
 304 fi
 305
 306 dnl extra argument: --with-experimental-modules
 307 EXPERIMENTAL=
 308 AC_ARG_WITH(experimental-modules,
 309 [  --with-experimental-modules      Use experimental and unstable modules. (default=no) ],
 310 [ case "$withval" in
 311     yes)
 312         EXPERIMENTAL=yes
 313         ;;
 314     *)
 315   esac ]
 316 )
 317
 318 dnl extra argument: --with-openssl
 319 WITH_OPENSSL=yes
 320 AC_ARG_WITH(openssl,
 321 [  --with-openssl                   Use OpenSSL. (default=yes)],
 322 [ case "$withval" in
 323     no)
 324         WITH_OPENSSL=no
 325         ;;
 326     *)
 327         WITH_OPENSSL=yes
 328         ;;
 329   esac ]
 330 )
 331
 332 dnl #
 333 dnl # extra argument: --with-openssl-includes=dir
 334 dnl #
 335 OPENSSL_INCLUDE_DIR=
 336 AC_ARG_WITH(openssl-includes,
 337 [  --with-openssl-includes=DIR      Directory to look for OpenSSL include files],
 338 [ case "$withval" in
 339     *) OPENSSL_INCLUDE_DIR="$withval"
 340         ;;
 341   esac ]
 342 )
 343
 344 dnl #
 345 dnl # extra argument: --with-openssl-libraries=dir
 346 dnl #
 347 OPENSSL_LIB_DIR=
 348 AC_ARG_WITH(openssl-libraries,
 349 [  --with-openssl-libraries=DIR     Directory to look for OpenSSL library files],
 350 [ case "$withval" in
 351     *) OPENSSL_LIB_DIR="$withval"
 352         ;;
 353   esac ]
 354 )
 355
 356 dnl #
 357 dnl #  These next two arguments don't actually do anything.  They're
 358 dnl #  place holders so that the top-level configure script can tell
 359 dnl #  the user how to configure lower-level modules
 360 dnl #
 361
 362 dnl #
 363 dnl # extra argument: --with-rlm-FOO-lib-dir
 364 dnl #
 365 AC_ARG_WITH(rlm-FOO-lib-dir,
 366 [  --with-rlm-FOO-lib-dir=DIR       Directory to look for library files used by module FOO],
 367 [ case "$withval" in
 368     *)
 369         ;;
 370   esac ]
 371 )
 372
 373 dnl #
 374 dnl # extra argument: --with-rlm-FOO-include-dir
 375 dnl #
 376 AC_ARG_WITH(rlm-FOO-include-dir,
 377 [  --with-rlm-FOO-include-dir=DIR   Directory to look for include files used by module FOO],
 378 [ case "$withval" in
 379     *)
 380         ;;
 381   esac ]
 382 )
 383
 384 dnl See what include-style is used by the make program.
 385 dnl AC_MSG_CHECKING(include style for make)
 386 dnl echo "include /dev/null" > testmake.$$
 387 dnl echo "all:" >> testmake.$$
 388 dnl make -f testmake.$$ >/dev/null 2>&1
 389 dnl if test $? = 0
 390 dnl then
 391 dnl     INCLUDE=include
 392 dnl     IQUOTE=
 393 dnl else
 394 dnl     INCLUDE=.include
 395 dnl     IQUOTE='"'
 396 dnl fi
 397 dnl rm -f testmake.$$
 398 dnl AC_MSG_RESULT(" $INCLUDE")
 399 dnl AC_SUBST(INCLUDE)
 400 dnl AC_SUBST(IQUOTE)
 401
 402 dnl extra argument: --with-udpfromto
 403 WITH_UDPFROMTO=no
 404 AC_ARG_WITH(udpfromto,
 405 [  --with-udpfromto        Compile in UDPFROMTO support. (default=no)],
 406 [ case "$withval" in
 407     yes)
 408         WITH_UDPFROMTO=yes
 409         ;;
 410     *)
 411         WITH_UDPFROMTO=no
 412   esac ]
 413 )
 414
 415 if test "x$WITH_UDPFROMTO" = "xyes"; then
 416         AC_DEFINE(WITH_UDPFROMTO, [], [define if you want udpfromto])
 417 fi
 418
 419 dnl #############################################################
 420 dnl #
 421 dnl #  1. Checks for programs
 422 dnl #
 423 dnl #############################################################
 424
 425 CHECKRAD=checkrad.pl
 426 AC_PATH_PROG(PERL, perl, /usr/local/bin/perl)
 427 if test "x$ac_cv_path_PERL" = "x"; then
 428   AC_MSG_WARN(perl not found - Simultaneous-Use and checkrad.pl may not work)
 429 fi
 430 AC_PATH_PROG(SNMPGET, snmpget)
 431 if test "x$ac_cv_path_SNMPGET" = "x"; then
 432   AC_MSG_WARN(snmpget not found - Simultaneous-Use and checkrad.pl may not work)
 433 fi
 434
 435 AC_PATH_PROG(SNMPWALK, snmpwalk)
 436 if test "x$ac_cv_path_SNMPWALK" = "x"; then
 437   AC_MSG_WARN(snmpwalk not found - Simultaneous-Use and checkrad.pl may not work)
 438 fi
 439
 440 AC_PATH_PROG(RUSERS, rusers, /usr/bin/rusers)
 441
 442 dnl FIXME This is truly gross.
 443 missing_dir=`cd $ac_aux_dir && pwd`
 444 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
 445 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
 446 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
 447
 448 AC_PATH_PROG(LOCATE,locate)
 449 AC_PATH_PROG(DIRNAME,dirname)
 450 AC_PATH_PROG(GREP,grep)
 451
 452 dnl #############################################################
 453 dnl #
 454 dnl #  2. Checks for libraries
 455 dnl #
 456 dnl #############################################################
 457
 458 dnl If using pthreads, check for -lpthread (posix) or -lc_r (*BSD)
 459 old_CFLAGS=$CFLAGS
 460 if test "x$WITH_THREADS" = "xyes"; then
 461   if test $ac_cv_prog_suncc = "yes"; then
 462     CFLAGS="$CFLAGS -mt"
 463   fi
 464
 465   AC_CHECK_HEADERS(pthread.h, [], [ WITH_THREADS="no" ])
 466
 467 dnl #
 468 dnl # pthread stuff is usually in -lpthread
 469 dnl # or in -lc_r, on *BSD
 470 dnl #
 471 dnl # On Some systems, we need extra pre-processor flags, to get them to
 472 dnl # to do the threading properly.
 473 dnl #
 474   AC_CHECK_LIB(pthread, pthread_create,
 475                 [ CFLAGS="$CFLAGS -D_REENTRANT -D_POSIX_PTHREAD_SEMANTICS"
 476                   LIBS="-lpthread $LIBS" ],
 477                 AC_CHECK_LIB(c_r, pthread_create,
 478                             [ CFLAGS="$CFLAGS -pthread -D_THREAD_SAFE" ],
 479                             [ WITH_THREADS="no" ]
 480                             )
 481                 )
 482 fi
 483
 484 dnl #
 485 dnl # If we have NO pthread libraries, remove any knowledge of threads.
 486 dnl #
 487 if test "x$WITH_THREADS" != "xyes"; then
 488   CFLAGS=$old_CFLAGS
 489   ac_cv_header_pthread_h="no"
 490   WITH_THREADS=no
 491 else
 492   dnl #
 493   dnl #  We need sem_init() and friends, as they're the friendliest
 494   dnl #  semaphore functions for threading.
 495   dnl #
 496   dnl # HP/UX requires linking with librt, too, to get the sem_* symbols.
 497   dnl # Some systems have them in -lsem
 498   dnl # Solaris has them in -lposix4
 499   dnl # NetBSD has them in -lsemaphore
 500
 501   AC_SEARCH_LIBS(sem_init, pthread sem posix4 rt semaphore,
 502         [],
 503         [AC_MSG_ERROR(-lsem not found.  You may want to download it from ftp://ftp.to.gd-es.com/pub/BSDI/libsem.tar.bz2 or ftp://ftp.freeradius.org/pub/radius/contrib/libsem.tar.gz)]
 504    )
 505 fi
 506
 507 dnl Check if we need -lsocket
 508 AC_CHECK_LIB(socket, getsockname)
 509
 510 dnl Check for -lresolv
 511 dnl This library may be needed later.
 512 AC_CHECK_LIB(resolv, inet_aton)
 513
 514 dnl Check if we need -lnsl. Usually if we want to
 515 dnl link against -lsocket we need to include -lnsl as well.
 516 AC_CHECK_LIB(nsl, inet_ntoa)
 517
 518 dnl Check for OpenSSL libraries.
 519 OPENSSL_LIBS=
 520 if test "x$WITH_OPENSSL" = xyes; then
 521   old_LIBS=$LIBS
 522   old_LDFLAGS="$LDFLAGS"
 523   if test "x$OPENSSL_LIB_DIR" != "x"; then
 524     LDFLAGS="$LDFLAGS -L$OPENSSL_LIB_DIR"
 525   fi
 526   AC_CHECK_LIB(crypto, DH_new,
 527     [
 528         LIBS="-lcrypto $LIBS"
 529         AC_DEFINE(HAVE_LIBCRYPTO, 1,
 530             [Define to 1 if you have the `crypto' library (-lcrypto).])
 531         AC_CHECK_LIB(ssl, SSL_new,
 532             [
 533                 AC_DEFINE(HAVE_LIBSSL, 1,
 534                     [Define to 1 if you have the `ssl' library (-lssl).])
 535                 if test "x$OPENSSL_LIB_DIR" != "x"; then
 536                     OPENSSL_LIBS="-L$OPENSSL_LIB_DIR"
 537                 fi
 538                 OPENSSL_LIBS="$OPENSSL_LIBS -lcrypto -lssl -lcrypto"
 539             ], [])
 540     ], [])
 541   LIBS=$old_LIBS
 542   LDFLAGS="$old_LDFLAGS"
 543 fi
 544
 545 AC_CHECK_LIB(ws2_32, htonl)
 546
 547 dnl Check the pcap library for the RADIUS sniffer.
 548 PCAP_LIBS=
 549 AC_CHECK_LIB(pcap, pcap_open_live,
 550         [ PCAP_LIBS="-lpcap"
 551         AC_DEFINE(HAVE_LIBPCAP, 1,
 552                 [Define to 1 if you have the `pcap' library (-lpcap).])
 553         ],
 554         [ AC_MSG_WARN([pcap library not found, silently disabling the RADIUS sniffer.]) ])
 555
 556 AC_LIB_READLINE
 557
 558 dnl #############################################################
 559 dnl #
 560 dnl #  3. Checks for header files
 561 dnl #
 562 dnl #############################################################
 563
 564 dnl #
 565 dnl # Interix requires us to set -D_ALL_SOURCE, otherwise
 566 dnl # getopt will be #included, but won't link.  <sigh>
 567 dnl #
 568 dnl #
 569 case "$host" in
 570 *-interix*)
 571         CFLAGS="$CFLAGS -D_ALL_SOURCE"
 572         ;;
 573 *-darwin*)
 574         CFLAGS="$CFLAGS -DDARWIN"
 575         LIBS="-framework DirectoryService $LIBS"
 576         ;;
 577 esac
 578
 579 AC_HEADER_DIRENT
 580 AC_HEADER_STDC
 581 AC_HEADER_TIME
 582 AC_HEADER_SYS_WAIT
 583
 584 AC_CHECK_HEADERS( \
 585         unistd.h \
 586         crypt.h \
 587         errno.h \
 588         resource.h \
 589         sys/resource.h \
 590         getopt.h \
 591         malloc.h \
 592         utmp.h \
 593         utmpx.h \
 594         signal.h \
 595         sys/select.h \
 596         syslog.h \
 597         inttypes.h \
 598         stdint.h \
 599         stdio.h \
 600         netdb.h \
 601         semaphore.h \
 602         arpa/inet.h \
 603         netinet/in.h \
 604         sys/types.h \
 605         sys/socket.h \
 606         winsock.h \
 607         sys/time.h \
 608         sys/wait.h \
 609         sys/security.h \
 610         fcntl.h \
 611         sys/fcntl.h \
 612         sys/prctl.h \
 613         sys/un.h \
 614         glob.h \
 615         prot.h \
 616         pwd.h \
 617         grp.h \
 618         stddef.h \
 619         fnmatch.h \
 620         sia.h \
 621         siad.h
 622 )
 623
 624 dnl FreeBSD requires sys/socket.h before net/if.h
 625 AC_CHECK_HEADERS(net/if.h, [], [],
 626 [#ifdef HAVE_SYS_SOCKET_H
 627 # include <sys/socket.h>
 628 # endif
 629 ])
 630
 631 REGEX=no
 632 AC_CHECK_HEADER(pcreposix.h, AC_DEFINE(HAVE_PCREPOSIX_H, [], [define this if we have the <pcreposix.h> header file]))
 633 if test "x$ac_cv_header_pcreposix_h" = "xyes"; then
 634   AC_DEFINE(HAVE_REGEX_H, [], [define if we have any regex])
 635   REGEX_EXTENDED=yes
 636   REGEX_PCRE=yes
 637   REGEX=yes
 638   LIBS="$LIBS -lpcreposix"
 639 else
 640
 641 AC_CHECK_HEADER(regex.h, AC_DEFINE(HAVE_REGEX_H, [], [define this if we have the <regex.h> header file]))
 642 if test "x$ac_cv_header_regex_h" = "xyes"; then
 643   REGEX_EXTENDED=no
 644   REGEX_PCRE=no
 645   REGEX=yes
 646   AC_EGREP_CPP(yes,
 647     [#include <regex.h>
 648      #ifdef REG_EXTENDED
 649        yes
 650      #endif
 651      ], [AC_DEFINE(HAVE_REG_EXTENDED, [], [define this if we have REG_EXTENDED (from <regex.h>)]) REGEX_EXTENDED=yes])
 652 fi
 653 fi
 654
 655 AC_SUBST(REGEX)
 656 AC_SUBST(REGEX_PCRE)
 657 AC_SUBST(REGEX_EXTENDED)
 658
 659 dnl #
 660 dnl #  other checks which require headers
 661 dnl #
 662 if test "x$ac_cv_header_sys_security_h" = "xyes" && test "x$ac_cv_header_prot_h" = "xyes"
 663 then
 664   AC_DEFINE(OSFC2, [], [define if you have OSFC2 authentication])
 665 fi
 666
 667 if test "x$ac_cv_header_sia_h" = "xyes" && test "x$ac_cv_header_siad_h" = "xyes"
 668 then
 669   AC_DEFINE(OSFSIA, [], [define if you have OSFSIA authentication])
 670 fi
 671
 672 dnl Check for OpenSSL includes.
 673 OPENSSL_INCLUDE="-DNO_OPENSSL"
 674 if test "x$WITH_OPENSSL" = xyes; then
 675   if test "x$OPENSSL_LIBS" = "x"; then
 676     AC_MSG_NOTICE([skipping test for openssl/ssl.h])
 677   else
 678     old_CPPFLAGS=$CPPFLAGS
 679     if test "x$OPENSSL_INCLUDE_DIR" != "x"; then
 680         CPPFLAGS="$CPPFLAGS -I$OPENSSL_INCLUDE_DIR"
 681     fi
 682     dnl # stupid RedHat shit
 683     CPPFLAGS="$CPPFLAGS -DOPENSSL_NO_KRB5"
 684     AC_CHECK_HEADERS( \
 685         openssl/ssl.h \
 686         openssl/crypto.h \
 687         openssl/err.h \
 688         openssl/evp.h \
 689         openssl/md5.h \
 690         openssl/md4.h \
 691         openssl/sha.h \
 692         openssl/ocsp.h \
 693         openssl/engine.h,
 694         [],
 695         OPENSSL_LIBS=
 696     )
 697     if test "x$OPENSSL_LIBS" != "x"; then
 698         AC_MSG_CHECKING([for OpenSSL version >= 0.9.7])
 699         AC_EGREP_CPP(yes,
 700             [#include <openssl/crypto.h>
 701              #if (OPENSSL_VERSION_NUMBER >= 0x00907000L)
 702              yes
 703              #endif
 704             ], goodssl="yes")
 705         if test "x$goodssl" != "xyes"; then
 706             AC_MSG_RESULT(no)
 707             OPENSSL_LIBS=
 708         else
 709             AC_MSG_RESULT(yes)
 710             if test "x$OPENSSL_INCLUDE_DIR" != "x"; then
 711                 OPENSSL_INCLUDE="-I$OPENSSL_INCLUDE_DIR -DOPENSSL_NO_KRB5"
 712             else
 713                 OPENSSL_INCLUDE="-DOPENSSL_NO_KRB5"
 714             fi
 715         fi
 716     fi
 717     CPPFLAGS=$old_CPPFLAGS
 718   fi
 719 fi
 720 AC_SUBST(OPENSSL_INCLUDE)
 721 AC_SUBST(OPENSSL_LIBS)
 722 export OPENSSL_LIBS
 723
 724 dnl Check the pcap includes for the RADIUS sniffer.
 725 if test "x$PCAP_LIBS" = x; then
 726     AC_MSG_NOTICE([skipping test for pcap.h.])
 727 else
 728     AC_CHECK_HEADER(pcap.h,
 729         AC_DEFINE(HAVE_PCAP_H, 1,
 730                 [Define to 1 if you have the <pcap.h> header file.]),
 731         [ PCAP_LIBS=
 732         AC_MSG_WARN([pcap.h not found, silently disabling the RADIUS sniffer.])
 733         ])
 734
 735     AC_CHECK_LIB(pcap, pcap_fopen_offline,
 736         [ AC_DEFINE(HAVE_PCAP_FOPEN_OFFLINE, 1,
 737                 [Define to 1 if you have the function pcap_fopen_offline.])
 738         ])
 739     AC_CHECK_LIB(pcap, pcap_dump_fopen,
 740         [ AC_DEFINE(HAVE_PCAP_DUMP_FOPEN, 1,
 741                 [Define to 1 if you have the function pcap_dump_fopen.])
 742         ])
 743 fi
 744 AC_SUBST(PCAP_LIBS)
 745
 746 dnl #############################################################
 747 dnl #
 748 dnl #  4. Checks for typedefs
 749 dnl #
 750 dnl #############################################################
 751
 752 dnl #
 753 dnl # Ensure that these are defined
 754 dnl #
 755 AC_TYPE_OFF_T
 756 AC_TYPE_PID_T
 757 AC_TYPE_SIZE_T
 758 AC_TYPE_UID_T
 759
 760 dnl check for socklen_t
 761 FR_CHECK_TYPE_INCLUDE([
 762 #ifdef HAVE_SYS_TYPES_H
 763 #include <sys/types.h>
 764 #endif
 765 #ifdef HAVE_SYS_SOCKET_H
 766 #include <sys/socket.h>
 767 #endif
 768 ],socklen_t, int, [socklen_t is generally 'int' on systems which don't use it])
 769
 770 dnl check for uint8_t
 771 FR_CHECK_TYPE_INCLUDE([
 772 #ifdef HAVE_INTTYPES_H
 773 #include <inttypes.h>
 774 #endif
 775 #ifdef HAVE_STDINT_H
 776 #include <stdint.h>
 777 #endif
 778 ],uint8_t, unsigned char, [uint8_t should be the canonical 'octet' for network traffic])
 779
 780 dnl check for uint16_t
 781 FR_CHECK_TYPE_INCLUDE([
 782 #ifdef HAVE_INTTYPES_H
 783 #include <inttypes.h>
 784 #endif
 785 #ifdef HAVE_STDINT_H
 786 #include <stdint.h>
 787 #endif
 788 ],uint16_t, unsigned short, [uint16_t should be the canonical '2 octets' for network traffic])
 789
 790 dnl check for uint32_t
 791 FR_CHECK_TYPE_INCLUDE([
 792 #ifdef HAVE_INTTYPES_H
 793 #include <inttypes.h>
 794 #endif
 795 #ifdef HAVE_STDINT_H
 796 #include <stdint.h>
 797 #endif
 798 ],uint32_t, unsigned int, [uint32_t should be the canonical 'network integer])
 799
 800 AC_CHECK_TYPE(struct in6_addr, AC_DEFINE(HAVE_STRUCT_IN6_ADDR, 1, [IPv6 address structure]), [], [
 801 #ifdef HAVE_NETINET_IN_H
 802 #include <netinet/in.h>
 803 #endif
 804 ])
 805
 806 AC_CHECK_TYPE(struct sockaddr_storage, AC_DEFINE(HAVE_STRUCT_SOCKADDR_STORAGE, 1, [Generic socket addresses]), [], [
 807 #ifdef HAVE_NETINET_IN_H
 808 #include <netinet/in.h>
 809 #endif
 810 #ifdef HAVE_SYS_SOCKET_H
 811 #include <sys/socket.h>
 812 #endif
 813 ])
 814
 815 AC_CHECK_TYPE(struct sockaddr_in6, AC_DEFINE(HAVE_STRUCT_SOCKADDR_IN6, 1, [IPv6 socket addresses]), [], [
 816 #ifdef HAVE_NETINET_IN_H
 817 #include <netinet/in.h>
 818 #endif
 819 ])
 820
 821 AC_CHECK_TYPE(struct addrinfo, AC_DEFINE(HAVE_STRUCT_ADDRINFO, 1, [Generic DNS lookups]), [], [
 822 #ifdef HAVE_SYS_TYPES_H
 823 #include <sys/types.h>
 824 #endif
 825 #ifdef HAVE_SYS_SOCKET_H
 826 #include <sys/socket.h>
 827 #endif
 828 #ifdef HAVE_NETDB_H
 829 #include <netdb.h>
 830 #endif
 831 ])
 832
 833 dnl #############################################################
 834 dnl #
 835 dnl #  5. Checks for structures and functions
 836 dnl #
 837 dnl #############################################################
 838 AC_CHECK_FUNCS( \
 839         getopt_long \
 840         lockf \
 841         strsignal \
 842         sigaction \
 843         sigprocmask \
 844         pthread_sigmask \
 845         snprintf \
 846         vsnprintf \
 847         setsid \
 848         strncasecmp \
 849         strcasecmp \
 850         localtime_r \
 851         ctime_r \
 852         gmtime_r \
 853         strsep \
 854         inet_aton \
 855         inet_pton \
 856         inet_ntop \
 857         setlinebuf \
 858         setvbuf \
 859         getusershell \
 860         initgroups \
 861         getaddrinfo \
 862         getnameinfo \
 863         closefrom \
 864         gettimeofday \
 865         getpeereid \
 866         setuid \
 867         setresuid \
 868         getresuid \
 869         strlcat \
 870         strlcpy
 871 )
 872 RADIUSD_NEED_DECLARATIONS( \
 873         crypt \
 874         strncasecmp \
 875         strcasecmp \
 876         inet_aton \
 877         setlinebuf \
 878         getusershell \
 879         endusershell
 880 )
 881
 882 AC_TYPE_SIGNAL
 883
 884 dnl # check if we have utmpx.h
 885 dnl # if so, check if struct utmpx has entry ut_xtime
 886 dnl # if not, set it to define ut_xtime == ut_tv.tv_sec
 887 if test "x$ac_cv_header_utmpx_h" = "xyes"
 888 then
 889  FR_CHECK_STRUCT_HAS_MEMBER([#include <utmpx.h>], [struct utmpx], ut_xtime)
 890  if test "x$ac_cv_type_struct_utmpx_has_ut_xtime" = "x"
 891  then
 892    AC_DEFINE(ut_xtime,ut_tv.tv_sec, [define to something if you don't have ut_xtime in struct utmpx])
 893  fi
 894 fi
 895
 896 dnl # struct ip_pktinfo
 897 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in_pktinfo], ipi_addr)
 898 if test "x$ac_cv_type_struct_in_pktinfo_has_ipi_addr" = "xyes"
 899 then
 900         AC_DEFINE(HAVE_IP_PKTINFO, [], [define if you have IP_PKTINFO (Linux)])
 901 fi
 902
 903 dnl # struct in6_pktinfo
 904 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in6_pktinfo], ipi6_addr)
 905 if test "x$ac_cv_type_struct_in6_pktinfo_has_ipi6_addr" = "xyes"
 906 then
 907         AC_DEFINE(HAVE_IN6_PKTINFO, [], [define if you have IN6_PKTINFO (Linux)])
 908 fi
 909
 910 dnl #############################################################
 911 dnl #
 912 dnl #  6. Checks for compiler characteristics
 913 dnl #
 914 dnl #############################################################
 915
 916 dnl #
 917 dnl # Ensure that these are defined
 918 dnl #
 919 AC_C_CONST
 920
 921 dnl #
 922 dnl # See if this is OS/2
 923 dnl #
 924 AC_MSG_CHECKING(type of OS)
 925 OS=`uname -s`
 926 AC_MSG_RESULT($OS)
 927 if test "$OS" = "OS/2"; then
 928         LIBPREFIX=
 929 else
 930         LIBPREFIX=lib
 931 fi
 932 AC_SUBST(LIBPREFIX)
 933
 934 AC_MSG_CHECKING(for developer gcc flags)
 935 if test "x$developer" = "xyes" -a "x$GCC" = "xyes"; then
 936   devflags="-g -Wshadow -Wpointer-arith -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -W -Wredundant-decls -Wundef -Wformat-y2k -Wno-format-extra-args -Wno-format-zero-length  -Wformat-nonliteral -Wformat-security -Wformat=2"
 937   CFLAGS="$CFLAGS $devflags"
 938   INSTALLSTRIP=""
 939   AC_MSG_RESULT(yes.  Using $devflags)
 940 else
 941   devflags=""
 942   CFLAGS="$CFLAGS -DNDEBUG"
 943   INSTALLSTRIP=""
 944   AC_MSG_RESULT(no.)
 945 fi
 946
 947 FR_TLS
 948
 949 dnl #############################################################
 950 dnl #
 951 dnl #  7. Checks for library functions
 952 dnl #
 953 dnl #############################################################
 954
 955 old_LIBS="$LIBS"
 956 LIBS="$LIBS $LIBLTDL"
 957 AC_CHECK_FUNC(lt_dladvise_init, AC_DEFINE(HAVE_LT_DLADVISE_INIT, [], [Do we have the lt_dladvise_init function]))
 958 LIBS="$old_LIBS"
 959
 960 dnl Check for libcrypt
 961 dnl We use crypt(3) which may be in libc, or in libcrypt (eg FreeBSD)
 962 AC_CHECK_LIB(crypt, crypt,
 963   CRYPTLIB="-lcrypt"
 964 )
 965 if test "$CRYPTLIB" != ""; then
 966   AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function])
 967 else
 968   AC_CHECK_FUNC(crypt, AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function]))
 969 fi
 970
 971 dnl Check for libcipher
 972 AC_CHECK_LIB(cipher, setkey,
 973    CRYPTLIB="${CRYPTLIB} -lcipher"
 974 )
 975 AC_SUBST(CRYPTLIB)
 976
 977 dnl Check the style of gethostbyaddr, in order of preference
 978 dnl GNU (_r eight args)
 979 AC_DEFINE(GNUSTYLE, [1], [GNU-Style get*byaddr_r])
 980 dnl SYSV (_r six args)
 981 AC_DEFINE(SYSVSTYLE, [2], [SYSV-Style get*byaddr_r])
 982 dnl BSD (three args, may not be thread safe)
 983 AC_DEFINE(BSDSTYLE, [3], [BSD-Style get*byaddr_r])
 984 dnl Tru64 has BSD version, but it is thread safe
 985 dnl     http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1739____.HTM
 986 dnl We need #stdio.h to define NULL on FreeBSD (at least)
 987 gethostbyaddrrstyle=""
 988 AC_MSG_CHECKING([gethostbyaddr_r() syntax])
 989 case "$host" in
 990 *-freebsd*)
 991 dnl With FreeBSD, check if there's a prototype for gethostbyaddr_r.
 992 dnl Some versions (FreeBSD 5.1?) have a symbol but no prototype - so we
 993 dnl override this test to BSDSTYLE. FreeBSD 6.2 and up have proper GNU
 994 dnl style support.
 995         AC_CHECK_DECLS([gethostbyaddr_r], [], [
 996                 AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE,
 997                         [style of gethostbyaddr_r functions ])
 998                 gethostbyaddrrstyle=BSD
 999                 AC_MSG_WARN([FreeBSD overridden to BSD-style])
1000         ], [
1001 #ifdef HAVE_NETDB_H
1002 #include <netdb.h>
1003 #endif
1004 ])
1005         ;;
1006 esac
1007 if test "x$gethostbyaddrrstyle" = "x"; then
1008         AC_TRY_LINK([
1009 #include <stdio.h>
1010 #include <netdb.h>
1011 ], [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL, NULL) ], [
1012         AC_DEFINE(GETHOSTBYADDRRSTYLE, GNUSTYLE, [style of gethostbyaddr_r functions ])
1013         gethostbyaddrrstyle=GNU
1014 ])
1015 fi
1016 if test "x$gethostbyaddrrstyle" = "x"; then
1017         AC_TRY_LINK([
1018 #include <stdio.h>
1019 #include <netdb.h>
1020 ], [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL) ] , [
1021                 AC_DEFINE(GETHOSTBYADDRRSTYLE, SYSVSTYLE, [style of gethostbyaddr_r functions ])
1022                 gethostbyaddrrstyle=SYSV
1023         ])
1024 fi
1025 if test "x$gethostbyaddrrstyle" = "x"; then
1026         AC_TRY_LINK([
1027 #include <stdio.h>
1028 #include <netdb.h>
1029 ], [ gethostbyaddr(NULL, 0, 0)  ], [
1030                 AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE, [style of gethostbyaddr_r functions ])
1031                 gethostbyaddrrstyle=BSD
1032         ])
1033 fi
1034
1035 if test "x$gethostbyaddrrstyle" = "x"; then
1036         AC_MSG_RESULT([none!  It must not exist, here.])
1037 else
1038         AC_MSG_RESULT([${gethostbyaddrrstyle}-style])
1039 fi
1040
1041 if test "x$gethostbyaddrrstyle" = "xBSD"; then
1042         AC_MSG_WARN([ ****** BSD-style gethostbyaddr might NOT be thread-safe! ****** ])
1043 fi
1044
1045 dnl Check the style of gethostbyname, in order of preference
1046 dnl GNU (_r seven args)
1047 dnl SYSV (_r five args)
1048 dnl BSD (two args, may not be thread safe)
1049 dnl Tru64 has BSD version, but it _is_ thread safe
1050 dnl     http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1946____.HTM
1051 dnl We need #stdio.h to define NULL on FreeBSD (at least)
1052 gethostbynamerstyle=""
1053 AC_MSG_CHECKING([gethostbyname_r() syntax])
1054 AC_TRY_LINK([
1055 #include <stdio.h>
1056 #include <netdb.h>
1057 ], [ gethostbyname_r(NULL, NULL, NULL, 0, NULL, NULL) ], [
1058         AC_DEFINE(GETHOSTBYNAMERSTYLE, GNUSTYLE, [style of gethostbyname_r functions ])
1059         gethostbynamerstyle=GNU
1060 ])
1061 if test "x$gethostbynamerstyle" = "x"; then
1062         AC_TRY_LINK([
1063 #include <stdio.h>
1064 #include <netdb.h>
1065 ], [ gethostbyname_r(NULL, NULL, NULL, 0, NULL) ] , [
1066                 AC_DEFINE(GETHOSTBYNAMERSTYLE, SYSVSTYLE, [style of gethostbyname_r functions ])
1067                 gethostbynamerstyle=SYSV
1068         ])
1069 fi
1070 if test "x$gethostbynamerstyle" = "x"; then
1071         AC_TRY_LINK([
1072 #include <stdio.h>
1073 #include <netdb.h>
1074 ], [ gethostbyname(NULL)  ], [
1075                 AC_DEFINE(GETHOSTBYNAMERSTYLE, BSDSTYLE, [style of gethostbyname_r functions ])
1076                 gethostbynamerstyle=BSD
1077         ])
1078 fi
1079
1080 if test "x$gethostbynamerstyle" = "x"; then
1081         AC_MSG_RESULT([none!  It must not exist, here.])
1082 else
1083         AC_MSG_RESULT([${gethostbynamerstyle}-style])
1084 fi
1085
1086 if test "x$gethostbynamerstyle" = "xBSD"; then
1087         AC_MSG_WARN([ ****** BSD-style gethostbyname might NOT be thread-safe! ****** ])
1088 fi
1089
1090 dnl check for non-posix solaris ctime_r (extra buflen int arg)
1091 AC_DEFINE(POSIXSTYLE, [1], [Posix-Style ctime_r])
1092 AC_DEFINE(SOLARISSTYLE, [2], [Solaris-Style ctime_r])
1093 ctimerstyle=""
1094 AC_MSG_CHECKING([ctime_r() syntax])
1095 AC_TRY_LINK([
1096 #include <time.h>
1097 ], [ ctime_r(NULL, NULL, 0) ], [
1098         AC_DEFINE(CTIMERSTYLE, SOLARISSTYLE, [style of ctime_r function])
1099         ctimerstyle="SOLARIS"
1100 ])
1101 if test "x$ctimerstyle" = "x"; then
1102         AC_TRY_LINK([
1103 #include <time.h>
1104 ], [ ctime_r(NULL, NULL) ], [
1105                 AC_DEFINE(CTIMERSTYLE, POSIXSTYLE, [style of ctime_r function])
1106                 ctimerstyle="POSIX"
1107         ])
1108 fi
1109
1110 if test "x$ctimerstyle" = "x"; then
1111         AC_MSG_RESULT([none!  It must not exist, here.])
1112 else
1113         AC_MSG_RESULT([${ctimerstyle}-style])
1114 fi
1115
1116 AC_SUBST(HOSTINFO, $host)
1117
1118 dnl #############################################################
1119 dnl #
1120 dnl #  8. Checks for system services
1121 dnl #
1122 dnl #############################################################
1123
1124 dnl #
1125 dnl # Figure out where libtool is located,
1126 dnl #
1127 top_builddir=`pwd`
1128 export top_builddir
1129 AC_MSG_RESULT([top_builddir=$top_builddir])
1130 dnl # AC_SUBST(top_builddir)
1131 AC_SUBST(LIBLTDL)
1132 AC_SUBST(INCLTDL)
1133
1134 dnl import libtool stuff
1135
1136 dnl #############################################################
1137 dnl #
1138 dnl #  Configure in any module directories.
1139 dnl #
1140 dnl #############################################################
1141
1142 mysubdirs=""
1143 if test "x$EXPERIMENTAL" = "xyes"; then
1144   bar=`ls -1 "${srcdir}"/src/modules/rlm_*/configure | sed 's%/configure%%'`
1145   dnl # get rid of LF's.
1146   mysubdirs=`echo $mysubdirs $bar`
1147 else
1148   dnl #
1149   dnl # Find 'configure' in ONLY the stable modules
1150   dnl #
1151   for bar in `cat "${srcdir}"/src/modules/stable`; do
1152     if test -f "${srcdir}"/src/modules/$bar/configure; then
1153       mysubdirs="$mysubdirs src/modules/$bar"
1154     fi
1155   done
1156 fi
1157
1158 dnl ############################################################
1159 dnl # make modules by list
1160 dnl #############################################################
1161 if test "x$EXPERIMENTAL" = "xyes"; then
1162   for foo in `ls -1 "${srcdir}"/src/modules | grep rlm_`; do
1163     MODULES="$MODULES $foo"
1164   done
1165 else
1166    dnl #
1167    dnl # make ONLY the stable modules
1168    dnl #
1169    for foo in `cat "${srcdir}"/src/modules/stable`; do
1170     MODULES="$MODULES $foo"
1171    done
1172 fi
1173
1174 dnl #
1175 dnl #  Don't change the variable name here.  Autoconf goes bonkers
1176 dnl #  if you do.
1177 dnl #
1178 AC_CONFIG_SUBDIRS($mysubdirs)
1179 AC_SUBST(MODULES)
1180
1181 dnl #############################################################
1182 dnl #
1183 dnl #  And finally, output the results.
1184 dnl #
1185 dnl #############################################################
1186
1187 AC_CONFIG_COMMANDS([stamp-h], [echo timestamp > src/include/stamp-h])
1188 AC_CONFIG_COMMANDS([build-radpaths-h], [(cd ./src/include && /bin/sh ./build-radpaths-h)])
1189 AC_CONFIG_COMMANDS([main-chmod], [(cd ./src/main   && chmod +x checkrad.pl radlast radtest)])
1190 AC_CONFIG_COMMANDS([scripts-chmod], [(cd ./scripts    && chmod +x rc.radiusd radiusd.cron.daily radiusd.cron.monthly cryptpasswd)])
1191
1192 dnl #
1193 dnl #  Substitute whatever libraries we found to be necessary
1194 dnl #
1195 AC_SUBST(LIBS)
1196 AC_SUBST(INSTALLSTRIP)
1197
1198 USE_SHARED_LIBS=$enable_shared
1199 AC_SUBST(USE_SHARED_LIBS)
1200 USE_STATIC_LIBS=$enable_static
1201 AC_SUBST(USE_STATIC_LIBS)
1202 AC_SUBST(STATIC_MODULES)
1203 AC_SUBST(RADIUSD_MAJOR_VERSION)
1204 AC_SUBST(RADIUSD_MINOR_VERSION)
1205 AC_SUBST(RADIUSD_VERSION)
1206
1207 AC_OUTPUT(\
1208         ./Make.inc \
1209         ./src/include/build-radpaths-h \
1210         ./src/main/Makefile \
1211         ./src/main/radsniff.mk \
1212         ./src/main/checkrad.pl \
1213         ./src/main/radlast \
1214         ./src/main/radtest \
1215         ./scripts/rc.radiusd \
1216         ./scripts/radiusd.cron.daily \
1217         ./scripts/radiusd.cron.monthly \
1218         ./scripts/cryptpasswd \
1219         ./raddb/dictionary \
1220         ./raddb/radrelay.conf \
1221         ./raddb/radiusd.conf
1222 )