configure.in

   1 dnl #############################################################
   2 dnl #
   3 dnl #  For information about autoconf, see:
   4 dnl #
   5 dnl #  http://www.gnu.org/software/autoconf/
   6 dnl #
   7 dnl #  The recommended order is:
   8 dnl #
   9 dnl #  AC_INIT(file)
  10 dnl #  0. checks for compiler, libtool, and command line options
  11 dnl #  1. checks for programs
  12 dnl #  2. checks for libraries
  13 dnl #  3. checks for header files
  14 dnl #  4. checks for typedefs
  15 dnl #  5. checks for structures and functions
  16 dnl #  6. checks for compiler characteristics
  17 dnl #  7. checks for library functions
  18 dnl #  8. checks for system services
  19 dnl #  AC_OUTPUT([file...])
  20 dnl #
  21 dnl #############################################################
  22
  23 AC_PREREQ([2.59])
  24 export CFLAGS LIBS LDFLAGS CPPFLAGS
  25 AC_INIT(src/main/radiusd.c)
  26 AC_CONFIG_HEADER(src/include/autoconf.h)
  27 AC_REVISION($Revision$)dnl
  28
  29 dnl # The version of the software
  30 RADIUSD_VERSION=`cat VERSION`
  31 RADIUSD_MAJOR_VERSION=`cat VERSION | sed 's/\..*//'`
  32 RADIUSD_MINOR_VERSION=`cat VERSION | sed 's/^2\.//'`
  33 PACKAGE=freeradius
  34
  35 dnl #############################################################
  36 dnl #
  37 dnl #  0. Checks for compiler, libtool, and command line options.
  38 dnl #
  39 dnl #############################################################
  40
  41 dnl Check for GNU cc
  42 AC_PROG_CC
  43 AC_PROG_CXX
  44
  45 dnl #
  46 dnl # check for AIX, to allow us to use some BSD functions
  47 dnl # must be before macros that call the compiler.
  48 dnl #
  49 AC_AIX
  50
  51 AC_PROG_GCC_TRADITIONAL
  52 AC_PROG_CC_SUNPRO
  53 AC_PROG_RANLIB
  54
  55 dnl Compile in large (2G+) file support.
  56 AC_SYS_LARGEFILE
  57
  58 dnl # check for system bytesex
  59 dnl # AC_DEFINES WORDS_BIGENDIAN
  60 AC_C_BIGENDIAN
  61
  62 dnl Find GNU Make.
  63 AC_CHECK_PROG(GMAKE, gmake, yes, no)
  64 if test $GMAKE = no; then
  65   AC_PATH_PROG(MAKE, make, /usr/local/bin/make)
  66 else
  67   AC_PATH_PROG(MAKE, gmake, /usr/local/gnu/bin/make)
  68 fi
  69 makever=`$ac_cv_path_MAKE --version 2>&1 | grep "GNU Make"`
  70 if test -z "$makever"; then
  71   AC_MSG_ERROR(GNU Make is not installed.  Please download and install it
  72                 from ftp://prep.ai.mit.edu/pub/gnu/make/ before continuing.)
  73 fi
  74
  75 AC_ARG_WITH(system-libltdl,
  76 [  --with-system-libltdl   Use the libltdl installed in your system (default=use our own)],
  77 [
  78 LIBLTDL="-lltdl"
  79 INCLTDL=
  80 LTDL_SUBDIRS=
  81 enable_ltdl_install=no
  82 ],
  83 [
  84 dnl If libltdl isn't installable, set it to be installable.
  85 [test x"$enable_ltdl_install" = x && enable_ltdl_install=yes]
  86 AC_LIBLTDL_INSTALLABLE
  87
  88 dnl tell Makefile to build ltdl if needed
  89 if test x"$enable_ltdl_install" = x"yes"; then
  90   LTDL_SUBDIRS=libltdl
  91 fi
  92 ])
  93 AC_SUBST(LTDL_SUBDIRS)
  94
  95 dnl use system-wide libtool, if it exists
  96 AC_ARG_WITH(system-libtool,
  97 [  --with-system-libtool   Use the libtool installed in your system (default=use our own)],
  98 [ AC_PATH_PROG(LIBTOOL, libtool,,$PATH:/usr/local/bin) AC_LIBTOOL_DLOPEN
  99  AC_PROG_LIBTOOL],
 100 [
 101   LIBTOOL="`pwd`/libtool"
 102   AC_SUBST(LIBTOOL)
 103   dnl ensure that we're looking for dlopen
 104   AC_LIBTOOL_DLOPEN
 105
 106   dnl Figure out how to build shared libraries
 107   AC_PROG_LIBTOOL
 108 ])
 109
 110
 111 dnl Put this in later, when all distributed modules use autoconf.
 112 dnl AC_ARG_WITH(disablemodulefoo,
 113 dnl [  --without-rlm_foo       Disables module compilation.  Module list:]
 114 dnl esyscmd([find src/modules -type d -name rlm_\* -print |\
 115 dnl     sed -e 's%src/modules/.*/% (sub)- %; s%.*/%- %' |\
 116 dnl     awk '{print "                            "$0}']))
 117
 118 AC_ARG_ENABLE(strict-dependencies,
 119 [  --enable-strict-dependencies  Fail configure on lack of module dependancy.])
 120
 121 dnl extra argument: --with-docdir
 122 docdir='${datadir}/doc/freeradius'
 123 AC_MSG_CHECKING(docdir)
 124 AC_ARG_WITH(docdir,
 125 [  --with-docdir=DIR       Directory for documentation [DATADIR/doc/freeradius] ],
 126 [ case "$withval" in
 127     no)
 128         docdir=no
 129         ;;
 130     yes)
 131         ;;
 132     [[\\/$]]* | ?:[[\\/]]* )
 133         docdir="$withval"
 134         ;;
 135     *)
 136         AC_MSG_ERROR([expected an absolute directory name for --with-docdir: $withval])
 137         ;;
 138   esac ]
 139 )
 140 AC_SUBST(docdir)
 141 AC_MSG_RESULT($docdir)
 142 if test "x$docdir" = xno; then
 143         AC_MSG_WARN(Documentation files will NOT be installed.)
 144 fi
 145
 146 dnl extra argument: --with-logdir
 147 logdir='${localstatedir}/log/radius'
 148 AC_MSG_CHECKING(logdir)
 149 AC_ARG_WITH(logdir,
 150 [  --with-logdir=DIR       Directory for logfiles [LOCALSTATEDIR/log/radius] ],
 151 [ case "$withval" in
 152     no)
 153         AC_MSG_ERROR(Need logdir)
 154         ;;
 155     yes)
 156         ;;
 157     [[\\/$]]* | ?:[[\\/]]* )
 158         logdir="$withval"
 159         ;;
 160     *)
 161         AC_MSG_ERROR([expected an absolute directory name for --with-logdir: $withval])
 162         ;;
 163   esac ]
 164 )
 165 AC_SUBST(logdir)
 166 AC_MSG_RESULT($logdir)
 167
 168 dnl extra argument: --with-radacctdir
 169 radacctdir='${logdir}/radacct'
 170 AC_MSG_CHECKING(radacctdir)
 171 AC_ARG_WITH(radacctdir,
 172 [  --with-radacctdir=DIR   Directory for detail files [LOGDIR/radacct] ],
 173 [ case "$withval" in
 174     no)
 175         AC_MSG_ERROR(Need radacctdir)
 176         ;;
 177     yes)
 178         ;;
 179     [[\\/$]]* | ?:[[\\/]]* )
 180         radacctdir="$withval"
 181         ;;
 182     *)
 183         AC_MSG_ERROR([expected an absolute directory name for --with-radacctdir: $withval])
 184         ;;
 185   esac ]
 186 )
 187 AC_SUBST(radacctdir)
 188 AC_MSG_RESULT($radacctdir)
 189
 190 dnl extra argument: --with-raddbdir
 191 raddbdir='${sysconfdir}/raddb'
 192 AC_MSG_CHECKING(raddbdir)
 193 AC_ARG_WITH(raddbdir,
 194 [  --with-raddbdir=DIR     Directory for config files [SYSCONFDIR/raddb] ],
 195 [ case "$withval" in
 196     no)
 197         AC_MSG_ERROR(Need raddbdir)
 198         ;;
 199     yes)
 200         ;;
 201     [[\\/$]]* | ?:[[\\/]]* )
 202         raddbdir="$withval"
 203         ;;
 204     *)
 205         AC_MSG_ERROR([expected an absolute directory name for --with-raddbdir: $withval])
 206         ;;
 207   esac ]
 208 )
 209 AC_SUBST(raddbdir)
 210 AC_MSG_RESULT($raddbdir)
 211
 212 dnl extra argument: --with-ascend-binary
 213 ASCEND_BINARY=yes
 214 AC_ARG_WITH(ascend-binary,
 215 [  --with-ascend-binary    Include support for Ascend binary filter attributes (default=yes)],
 216 [ case "$withval" in
 217     yes)
 218         ;;
 219     *)
 220         ASCEND_BINARY=""
 221   esac ]
 222 )
 223 if test "X$ASCEND_BINARY" = "Xyes"; then
 224   AC_DEFINE(ASCEND_BINARY, [], [Include support for Ascend binary filter attributes])
 225 fi
 226
 227 dnl extra argument: --with-threads
 228 WITH_THREADS=yes
 229 AC_ARG_WITH(threads,
 230 [  --with-threads          Use threads, if available.  (default=yes) ],
 231 [ case "$withval" in
 232     yes)
 233         ;;
 234     *)
 235         WITH_THREADS=""
 236   esac ]
 237 )
 238
 239 dnl extra argument: --with-vmps
 240 WITH_VMPS=yes
 241 AC_ARG_WITH(vmps,
 242 [  --with-vmps             Compile in VMPS support. (default=yes)],
 243 [ case "$withval" in
 244     yes)
 245         ;;
 246     *)
 247         WITH_VMPS=no
 248   esac ]
 249 )
 250 if test "x$WITH_VMPS" = "xyes"; then
 251         AC_DEFINE(WITH_VMPS, [1], [define if you want VMPS support])
 252 fi
 253
 254 dnl extra argument: --with-dhcp
 255 AC_ARG_WITH(dhcp,
 256 [  --with-dhcp             Compile in DHCP support. (default=no)],
 257 [ case "$withval" in
 258     yes)
 259         AC_DEFINE(WITH_DHCP, [1], [Include experimental support for DHCP])
 260         ;;
 261     *)
 262         ;;
 263   esac ]
 264 )
 265
 266
 267 dnl #
 268 dnl #  Allow the user to specify a list of modules to be linked
 269 dnl #  statically to the server.
 270 dnl #
 271 STATIC_MODULES=
 272 AC_ARG_WITH(static_modules,
 273 [  --with-static-modules=QUOTED-MODULE-LIST],[
 274   for i in $withval; do
 275     STATIC_MODULES="$STATIC_MODULES -dlpreopen ../modules/rlm_$i/rlm_$i.la"
 276   done
 277 ])
 278
 279 MODULES=
 280 AC_ARG_WITH(modules,
 281 [ --with-modules=QUOTED-MODULE-LIST],[
 282  for i in $withval; do
 283    MODULES="$MODULES $i"
 284  done
 285 ])
 286
 287 dnl #
 288 dnl #  Enable developer C compiler warnings
 289 dnl #
 290 AC_ARG_ENABLE(developer,
 291 [  --enable-developer               Enables features of interest to developers.],
 292 [ case "$enableval" in
 293     no)
 294         developer=no
 295         ;;
 296     *)
 297         developer=yes
 298   esac ]
 299 )
 300
 301 if test "x$developer" != "xno" -a -d $srcdir/CVS; then
 302   dnl turn on the developer flag when taken from a CVS checkout (not a release)
 303   developer="yes"
 304 fi
 305
 306 if test "x$developer" != "xno" -a -d $srcdir/.git; then
 307   dnl turn on the developer flag when taken from a git checkout (not a release)
 308   developer="yes"
 309 fi
 310
 311 dnl extra argument: --with-experimental-modules
 312 EXPERIMENTAL=
 313 AC_ARG_WITH(experimental-modules,
 314 [  --with-experimental-modules      Use experimental and unstable modules. (default=no) ],
 315 [ case "$withval" in
 316     yes)
 317         EXPERIMENTAL=yes
 318         ;;
 319     *)
 320   esac ]
 321 )
 322
 323 dnl extra argument: --with-openssl
 324 WITH_OPENSSL=yes
 325 AC_ARG_WITH(openssl,
 326 [  --with-openssl                   Use OpenSSL. (default=yes)],
 327 [ case "$withval" in
 328     no)
 329         WITH_OPENSSL=no
 330         ;;
 331     *)
 332         WITH_OPENSSL=yes
 333         ;;
 334   esac ]
 335 )
 336
 337 dnl #
 338 dnl # extra argument: --with-openssl-includes=dir
 339 dnl #
 340 OPENSSL_INCLUDE_DIR=
 341 AC_ARG_WITH(openssl-includes,
 342 [  --with-openssl-includes=DIR      Directory to look for OpenSSL include files],
 343 [ case "$withval" in
 344     *) OPENSSL_INCLUDE_DIR="$withval"
 345         ;;
 346   esac ]
 347 )
 348
 349 dnl #
 350 dnl # extra argument: --with-openssl-libraries=dir
 351 dnl #
 352 OPENSSL_LIB_DIR=
 353 AC_ARG_WITH(openssl-libraries,
 354 [  --with-openssl-libraries=DIR     Directory to look for OpenSSL library files],
 355 [ case "$withval" in
 356     *) OPENSSL_LIB_DIR="$withval"
 357         ;;
 358   esac ]
 359 )
 360
 361 dnl #
 362 dnl #  These next two arguments don't actually do anything.  They're
 363 dnl #  place holders so that the top-level configure script can tell
 364 dnl #  the user how to configure lower-level modules
 365 dnl #
 366
 367 dnl #
 368 dnl # extra argument: --with-rlm-FOO-lib-dir
 369 dnl #
 370 AC_ARG_WITH(rlm-FOO-lib-dir,
 371 [  --with-rlm-FOO-lib-dir=DIR       Directory to look for library files used by module FOO],
 372 [ case "$withval" in
 373     *)
 374         ;;
 375   esac ]
 376 )
 377
 378 dnl #
 379 dnl # extra argument: --with-rlm-FOO-include-dir
 380 dnl #
 381 AC_ARG_WITH(rlm-FOO-include-dir,
 382 [  --with-rlm-FOO-include-dir=DIR   Directory to look for include files used by module FOO],
 383 [ case "$withval" in
 384     *)
 385         ;;
 386   esac ]
 387 )
 388
 389 dnl See what include-style is used by the make program.
 390 dnl AC_MSG_CHECKING(include style for make)
 391 dnl echo "include /dev/null" > testmake.$$
 392 dnl echo "all:" >> testmake.$$
 393 dnl make -f testmake.$$ >/dev/null 2>&1
 394 dnl if test $? = 0
 395 dnl then
 396 dnl     INCLUDE=include
 397 dnl     IQUOTE=
 398 dnl else
 399 dnl     INCLUDE=.include
 400 dnl     IQUOTE='"'
 401 dnl fi
 402 dnl rm -f testmake.$$
 403 dnl AC_MSG_RESULT(" $INCLUDE")
 404 dnl AC_SUBST(INCLUDE)
 405 dnl AC_SUBST(IQUOTE)
 406
 407 dnl extra argument: --with-udpfromto
 408 WITH_UDPFROMTO=no
 409 AC_ARG_WITH(udpfromto,
 410 [  --with-udpfromto        Compile in UDPFROMTO support. (default=no)],
 411 [ case "$withval" in
 412     yes)
 413         WITH_UDPFROMTO=yes
 414         ;;
 415     *)
 416         WITH_UDPFROMTO=no
 417   esac ]
 418 )
 419
 420 if test "x$WITH_UDPFROMTO" = "xyes"; then
 421         AC_DEFINE(WITH_UDPFROMTO, [], [define if you want udpfromto])
 422 fi
 423
 424 dnl #############################################################
 425 dnl #
 426 dnl #  1. Checks for programs
 427 dnl #
 428 dnl #############################################################
 429
 430 CHECKRAD=checkrad.pl
 431 AC_PATH_PROG(PERL, perl, /usr/local/bin/perl)
 432 if test "x$ac_cv_path_PERL" = "x"; then
 433   AC_MSG_WARN(perl not found - Simultaneous-Use and checkrad.pl may not work)
 434 fi
 435 AC_PATH_PROG(SNMPGET, snmpget)
 436 if test "x$ac_cv_path_SNMPGET" = "x"; then
 437   AC_MSG_WARN(snmpget not found - Simultaneous-Use and checkrad.pl may not work)
 438 fi
 439
 440 AC_PATH_PROG(SNMPWALK, snmpwalk)
 441 if test "x$ac_cv_path_SNMPWALK" = "x"; then
 442   AC_MSG_WARN(snmpwalk not found - Simultaneous-Use and checkrad.pl may not work)
 443 fi
 444
 445 AC_PATH_PROG(RUSERS, rusers, /usr/bin/rusers)
 446
 447 dnl FIXME This is truly gross.
 448 missing_dir=`cd $ac_aux_dir && pwd`
 449 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
 450 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
 451 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
 452
 453 AC_PATH_PROG(LOCATE,locate)
 454 AC_PATH_PROG(DIRNAME,dirname)
 455 AC_PATH_PROG(GREP,grep)
 456
 457 dnl #############################################################
 458 dnl #
 459 dnl #  2. Checks for libraries
 460 dnl #
 461 dnl #############################################################
 462
 463 dnl If using pthreads, check for -lpthread (posix) or -lc_r (*BSD)
 464 old_CFLAGS=$CFLAGS
 465 if test "x$WITH_THREADS" = "xyes"; then
 466   if test $ac_cv_prog_suncc = "yes"; then
 467     CFLAGS="$CFLAGS -mt"
 468   fi
 469
 470   AC_CHECK_HEADERS(pthread.h, [], [ WITH_THREADS="no" ])
 471
 472 dnl #
 473 dnl # pthread stuff is usually in -lpthread
 474 dnl # or in -lc_r, on *BSD
 475 dnl #
 476 dnl # On Some systems, we need extra pre-processor flags, to get them to
 477 dnl # to do the threading properly.
 478 dnl #
 479   AC_CHECK_LIB(pthread, pthread_create,
 480                 [ CFLAGS="$CFLAGS -D_REENTRANT -D_POSIX_PTHREAD_SEMANTICS"
 481                   LIBS="$LIBS -lpthread" ],
 482                 AC_CHECK_LIB(c_r, pthread_create,
 483                             [ CFLAGS="$CFLAGS -pthread -D_THREAD_SAFE" ],
 484                             [ WITH_THREADS="no" ]
 485                             )
 486                 )
 487 fi
 488
 489 dnl #
 490 dnl # If we have NO pthread libraries, remove any knowledge of threads.
 491 dnl #
 492 if test "x$WITH_THREADS" != "xyes"; then
 493   CFLAGS=$old_CFLAGS
 494   ac_cv_header_pthread_h="no"
 495   WITH_THREADS=no
 496 else
 497   dnl #
 498   dnl #  We need sem_init() and friends, as they're the friendliest
 499   dnl #  semaphore functions for threading.
 500   dnl #
 501   dnl # HP/UX requires linking with librt, too, to get the sem_* symbols.
 502   dnl # Some systems have them in -lsem
 503   dnl # Solaris has them in -lposix4
 504   dnl # NetBSD has them in -lsemaphore
 505
 506   AC_SEARCH_LIBS(sem_init, pthread sem posix4 rt semaphore,
 507         [],
 508         [AC_MSG_ERROR(-lsem not found.  You may want to download it from ftp://ftp.to.gd-es.com/pub/BSDI/libsem.tar.bz2 or ftp://ftp.freeradius.org/pub/radius/contrib/libsem.tar.gz)]
 509    )
 510 fi
 511
 512 dnl Check if we need -lsocket
 513 AC_CHECK_LIB(socket, getsockname)
 514
 515 dnl Check for -lresolv
 516 dnl This library may be needed later.
 517 AC_CHECK_LIB(resolv, inet_aton)
 518
 519 dnl Check if we need -lnsl. Usually if we want to
 520 dnl link against -lsocket we need to include -lnsl as well.
 521 AC_CHECK_LIB(nsl, inet_ntoa)
 522
 523 dnl Check for OpenSSL libraries.
 524 OPENSSL_LIBS=
 525 if test "x$WITH_OPENSSL" = xyes; then
 526   old_LIBS=$LIBS
 527   old_LDFLAGS="$LDFLAGS"
 528   if test "x$OPENSSL_LIB_DIR" != "x"; then
 529     LDFLAGS="$LDFLAGS -L$OPENSSL_LIB_DIR"
 530   fi
 531   AC_CHECK_LIB(crypto, DH_new,
 532     [
 533         LIBS="-lcrypto $LIBS"
 534         AC_DEFINE(HAVE_LIBCRYPTO, 1,
 535             [Define to 1 if you have the `crypto' library (-lcrypto).])
 536         AC_CHECK_LIB(ssl, SSL_new,
 537             [
 538                 AC_DEFINE(HAVE_LIBSSL, 1,
 539                     [Define to 1 if you have the `ssl' library (-lssl).])
 540                 if test "x$OPENSSL_LIB_DIR" != "x"; then
 541                     OPENSSL_LIBS="-L$OPENSSL_LIB_DIR"
 542                 fi
 543                 OPENSSL_LIBS="$OPENSSL_LIBS -lcrypto -lssl -lcrypto"
 544             ], [])
 545     ], [])
 546   LIBS=$old_LIBS
 547   LDFLAGS="$old_LDFLAGS"
 548 fi
 549
 550 AC_CHECK_LIB(ws2_32, htonl)
 551
 552 dnl Check the pcap library for the RADIUS sniffer.
 553 PCAP_LIBS=
 554 AC_CHECK_LIB(pcap, pcap_open_live,
 555         [ PCAP_LIBS="-lpcap"
 556         AC_DEFINE(HAVE_LIBPCAP, 1,
 557                 [Define to 1 if you have the `pcap' library (-lpcap).])
 558         ],
 559         [ AC_MSG_WARN([pcap library not found, silently disabling the RADIUS sniffer.]) ])
 560
 561 AC_LIB_READLINE
 562
 563 dnl #############################################################
 564 dnl #
 565 dnl #  3. Checks for header files
 566 dnl #
 567 dnl #############################################################
 568
 569 dnl #
 570 dnl # Interix requires us to set -D_ALL_SOURCE, otherwise
 571 dnl # getopt will be #included, but won't link.  <sigh>
 572 dnl #
 573 dnl #
 574 case "$host" in
 575 *-interix*)
 576         CFLAGS="$CFLAGS -D_ALL_SOURCE"
 577         ;;
 578 *-darwin*)
 579         CFLAGS="$CFLAGS -DDARWIN"
 580         LIBS="-framework DirectoryService $LIBS"
 581         ;;
 582 esac
 583
 584 AC_HEADER_DIRENT
 585 AC_HEADER_STDC
 586 AC_HEADER_TIME
 587 AC_HEADER_SYS_WAIT
 588
 589 AC_CHECK_HEADERS( \
 590         unistd.h \
 591         crypt.h \
 592         errno.h \
 593         resource.h \
 594         sys/resource.h \
 595         getopt.h \
 596         malloc.h \
 597         utmp.h \
 598         utmpx.h \
 599         signal.h \
 600         sys/select.h \
 601         syslog.h \
 602         inttypes.h \
 603         stdint.h \
 604         stdio.h \
 605         netdb.h \
 606         semaphore.h \
 607         arpa/inet.h \
 608         netinet/in.h \
 609         sys/types.h \
 610         sys/socket.h \
 611         winsock.h \
 612         sys/time.h \
 613         sys/wait.h \
 614         sys/security.h \
 615         fcntl.h \
 616         sys/fcntl.h \
 617         sys/prctl.h \
 618         sys/un.h \
 619         glob.h \
 620         prot.h \
 621         pwd.h \
 622         grp.h \
 623         fnmatch.h \
 624         sia.h \
 625         siad.h
 626 )
 627
 628 dnl FreeBSD requires sys/socket.h before net/if.h
 629 AC_CHECK_HEADERS(net/if.h, [], [],
 630 [#ifdef HAVE_SYS_SOCKET_H
 631 # include <sys/socket.h>
 632 # endif
 633 ])
 634
 635 REGEX=no
 636 AC_CHECK_HEADER(regex.h, AC_DEFINE(HAVE_REGEX_H, [], [define this if we have the <regex.h> header file]))
 637 if test "x$ac_cv_header_regex_h" = "xyes"; then
 638   REGEX_EXTENDED=no
 639   REGEX=yes
 640   AC_EGREP_CPP(yes,
 641     [#include <regex.h>
 642      #ifdef REG_EXTENDED
 643        yes
 644      #endif
 645      ], [AC_DEFINE(HAVE_REG_EXTENDED, [], [define this if we have REG_EXTENDED (from <regex.h>)]) REGEX_EXTENDED=yes])
 646 fi
 647 AC_SUBST(REGEX)
 648 AC_SUBST(REGEX_EXTENDED)
 649
 650 dnl #
 651 dnl #  other checks which require headers
 652 dnl #
 653 if test "x$ac_cv_header_sys_security_h" = "xyes" && test "x$ac_cv_header_prot_h" = "xyes"
 654 then
 655   AC_DEFINE(OSFC2, [], [define if you have OSFC2 authentication])
 656 fi
 657
 658 if test "x$ac_cv_header_sia_h" = "xyes" && test "x$ac_cv_header_siad_h" = "xyes"
 659 then
 660   AC_DEFINE(OSFSIA, [], [define if you have OSFSIA authentication])
 661 fi
 662
 663 dnl Check for OpenSSL includes.
 664 OPENSSL_INCLUDE="-DNO_OPENSSL"
 665 if test "x$WITH_OPENSSL" = xyes; then
 666   if test "x$OPENSSL_LIBS" = "x"; then
 667     AC_MSG_NOTICE([skipping test for openssl/ssl.h])
 668   else
 669     old_CPPFLAGS=$CPPFLAGS
 670     if test "x$OPENSSL_INCLUDE_DIR" != "x"; then
 671         CPPFLAGS="$CPPFLAGS -I$OPENSSL_INCLUDE_DIR"
 672     fi
 673     dnl # stupid RedHat shit
 674     CPPFLAGS="$CPPFLAGS -DOPENSSL_NO_KRB5"
 675     AC_CHECK_HEADERS( \
 676         openssl/ssl.h \
 677         openssl/crypto.h \
 678         openssl/err.h \
 679         openssl/evp.h \
 680         openssl/md5.h \
 681         openssl/md4.h \
 682         openssl/sha.h \
 683         openssl/ocsp.h \
 684         openssl/engine.h,
 685         [],
 686         OPENSSL_LIBS=
 687     )
 688     if test "x$OPENSSL_LIBS" != "x"; then
 689         AC_MSG_CHECKING([for OpenSSL version >= 0.9.7])
 690         AC_EGREP_CPP(yes,
 691             [#include <openssl/crypto.h>
 692              #if (OPENSSL_VERSION_NUMBER >= 0x00907000L)
 693              yes
 694              #endif
 695             ], goodssl="yes")
 696         if test "x$goodssl" != "xyes"; then
 697             AC_MSG_RESULT(no)
 698             OPENSSL_LIBS=
 699         else
 700             AC_MSG_RESULT(yes)
 701             if test "x$OPENSSL_INCLUDE_DIR" != "x"; then
 702                 OPENSSL_INCLUDE="-I$OPENSSL_INCLUDE_DIR -DOPENSSL_NO_KRB5"
 703             else
 704                 OPENSSL_INCLUDE="-DOPENSSL_NO_KRB5"
 705             fi
 706         fi
 707     fi
 708     CPPFLAGS=$old_CPPFLAGS
 709   fi
 710 fi
 711 AC_SUBST(OPENSSL_INCLUDE)
 712 AC_SUBST(OPENSSL_LIBS)
 713 export OPENSSL_LIBS
 714
 715 dnl Check the pcap includes for the RADIUS sniffer.
 716 if test "x$PCAP_LIBS" = x; then
 717     AC_MSG_NOTICE([skipping test for pcap.h.])
 718 else
 719     AC_CHECK_HEADER(pcap.h,
 720         AC_DEFINE(HAVE_PCAP_H, 1,
 721                 [Define to 1 if you have the <pcap.h> header file.]),
 722         [ PCAP_LIBS=
 723         AC_MSG_WARN([pcap.h not found, silently disabling the RADIUS sniffer.])
 724         ])
 725
 726     AC_CHECK_LIB(pcap, pcap_fopen_offline,
 727         [ AC_DEFINE(HAVE_PCAP_FOPEN_OFFLINE, 1,
 728                 [Define to 1 if you have the function pcap_fopen_offline.])
 729         ])
 730     AC_CHECK_LIB(pcap, pcap_dump_fopen,
 731         [ AC_DEFINE(HAVE_PCAP_DUMP_FOPEN, 1,
 732                 [Define to 1 if you have the function pcap_dump_fopen.])
 733         ])
 734 fi
 735 AC_SUBST(PCAP_LIBS)
 736
 737 dnl #############################################################
 738 dnl #
 739 dnl #  4. Checks for typedefs
 740 dnl #
 741 dnl #############################################################
 742
 743 dnl #
 744 dnl # Ensure that these are defined
 745 dnl #
 746 AC_TYPE_OFF_T
 747 AC_TYPE_PID_T
 748 AC_TYPE_SIZE_T
 749 AC_TYPE_UID_T
 750
 751 dnl check for socklen_t
 752 FR_CHECK_TYPE_INCLUDE([
 753 #ifdef HAVE_SYS_TYPES_H
 754 #include <sys/types.h>
 755 #endif
 756 #ifdef HAVE_SYS_SOCKET_H
 757 #include <sys/socket.h>
 758 #endif
 759 ],socklen_t, int, [socklen_t is generally 'int' on systems which don't use it])
 760
 761 dnl check for uint8_t
 762 FR_CHECK_TYPE_INCLUDE([
 763 #ifdef HAVE_INTTYPES_H
 764 #include <inttypes.h>
 765 #endif
 766 #ifdef HAVE_STDINT_H
 767 #include <stdint.h>
 768 #endif
 769 ],uint8_t, unsigned char, [uint8_t should be the canonical 'octet' for network traffic])
 770
 771 dnl check for uint16_t
 772 FR_CHECK_TYPE_INCLUDE([
 773 #ifdef HAVE_INTTYPES_H
 774 #include <inttypes.h>
 775 #endif
 776 #ifdef HAVE_STDINT_H
 777 #include <stdint.h>
 778 #endif
 779 ],uint16_t, unsigned short, [uint16_t should be the canonical '2 octets' for network traffic])
 780
 781 dnl check for uint32_t
 782 FR_CHECK_TYPE_INCLUDE([
 783 #ifdef HAVE_INTTYPES_H
 784 #include <inttypes.h>
 785 #endif
 786 #ifdef HAVE_STDINT_H
 787 #include <stdint.h>
 788 #endif
 789 ],uint32_t, unsigned int, [uint32_t should be the canonical 'network integer])
 790
 791 AC_CHECK_TYPE(struct in6_addr, AC_DEFINE(HAVE_STRUCT_IN6_ADDR, 1, [IPv6 address structure]), [], [
 792 #ifdef HAVE_NETINET_IN_H
 793 #include <netinet/in.h>
 794 #endif
 795 ])
 796
 797 AC_CHECK_TYPE(struct sockaddr_storage, AC_DEFINE(HAVE_STRUCT_SOCKADDR_STORAGE, 1, [Generic socket addresses]), [], [
 798 #ifdef HAVE_NETINET_IN_H
 799 #include <netinet/in.h>
 800 #endif
 801 #ifdef HAVE_SYS_SOCKET_H
 802 #include <sys/socket.h>
 803 #endif
 804 ])
 805
 806 AC_CHECK_TYPE(struct sockaddr_in6, AC_DEFINE(HAVE_STRUCT_SOCKADDR_IN6, 1, [IPv6 socket addresses]), [], [
 807 #ifdef HAVE_NETINET_IN_H
 808 #include <netinet/in.h>
 809 #endif
 810 ])
 811
 812 AC_CHECK_TYPE(struct addrinfo, AC_DEFINE(HAVE_STRUCT_ADDRINFO, 1, [Generic DNS lookups]), [], [
 813 #ifdef HAVE_SYS_TYPES_H
 814 #include <sys/types.h>
 815 #endif
 816 #ifdef HAVE_SYS_SOCKET_H
 817 #include <sys/socket.h>
 818 #endif
 819 #ifdef HAVE_NETDB_H
 820 #include <netdb.h>
 821 #endif
 822 ])
 823
 824 dnl #############################################################
 825 dnl #
 826 dnl #  5. Checks for structures and functions
 827 dnl #
 828 dnl #############################################################
 829 AC_CHECK_FUNCS( \
 830         getopt_long \
 831         lockf \
 832         strsignal \
 833         sigaction \
 834         sigprocmask \
 835         pthread_sigmask \
 836         snprintf \
 837         vsnprintf \
 838         setsid \
 839         strncasecmp \
 840         strcasecmp \
 841         localtime_r \
 842         ctime_r \
 843         gmtime_r \
 844         strsep \
 845         inet_aton \
 846         inet_pton \
 847         inet_ntop \
 848         setlinebuf \
 849         setvbuf \
 850         getusershell \
 851         initgroups \
 852         getaddrinfo \
 853         getnameinfo \
 854         closefrom \
 855         gettimeofday \
 856         getpeereid \
 857         setuid \
 858         setresuid \
 859         getresuid \
 860         strlcat \
 861         strlcpy
 862 )
 863 RADIUSD_NEED_DECLARATIONS( \
 864         crypt \
 865         strncasecmp \
 866         strcasecmp \
 867         inet_aton \
 868         setlinebuf \
 869         getusershell \
 870         endusershell
 871 )
 872
 873 AC_TYPE_SIGNAL
 874
 875 dnl # check if we have utmpx.h
 876 dnl # if so, check if struct utmpx has entry ut_xtime
 877 dnl # if not, set it to define ut_xtime == ut_tv.tv_sec
 878 if test "x$ac_cv_header_utmpx_h" = "xyes"
 879 then
 880  FR_CHECK_STRUCT_HAS_MEMBER([#include <utmpx.h>], [struct utmpx], ut_xtime)
 881  if test "x$ac_cv_type_struct_utmpx_has_ut_xtime" = "x"
 882  then
 883    AC_DEFINE(ut_xtime,ut_tv.tv_sec, [define to something if you don't have ut_xtime in struct utmpx])
 884  fi
 885 fi
 886
 887 dnl # struct ip_pktinfo
 888 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in_pktinfo], ipi_addr)
 889 if test "x$ac_cv_type_struct_in_pktinfo_has_ipi_addr" = "xyes"
 890 then
 891         AC_DEFINE(HAVE_IP_PKTINFO, [], [define if you have IP_PKTINFO (Linux)])
 892 fi
 893
 894 dnl # struct in6_pktinfo
 895 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in6_pktinfo], ipi6_addr)
 896 if test "x$ac_cv_type_struct_in6_pktinfo_has_ipi6_addr" = "xyes"
 897 then
 898         AC_DEFINE(HAVE_IN6_PKTINFO, [], [define if you have IN6_PKTINFO (Linux)])
 899 fi
 900
 901 dnl #############################################################
 902 dnl #
 903 dnl #  6. Checks for compiler characteristics
 904 dnl #
 905 dnl #############################################################
 906
 907 dnl #
 908 dnl # Ensure that these are defined
 909 dnl #
 910 AC_C_CONST
 911
 912 dnl #
 913 dnl # See if this is OS/2
 914 dnl #
 915 AC_MSG_CHECKING(type of OS)
 916 OS=`uname -s`
 917 AC_MSG_RESULT($OS)
 918 if test "$OS" = "OS/2"; then
 919         LIBPREFIX=
 920 else
 921         LIBPREFIX=lib
 922 fi
 923 AC_SUBST(LIBPREFIX)
 924
 925 dnl #
 926 dnl # Set Default CFLAGS
 927 dnl #
 928 if test "x$GCC" = "xyes"; then
 929     CFLAGS="$CFLAGS -Wall -D_GNU_SOURCE"
 930 fi
 931
 932 AC_MSG_CHECKING(for developer gcc flags)
 933 if test "x$developer" = "xyes" -a "x$GCC" = "xyes"; then
 934   devflags="-g -Wshadow -Wpointer-arith -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -W -Wredundant-decls -Wundef"
 935   CFLAGS="$CFLAGS $devflags"
 936   INSTALLSTRIP=""
 937   AC_MSG_RESULT(yes.  Using $devflags)
 938 else
 939   devflags=""
 940   CFLAGS="$CFLAGS -DNDEBUG"
 941   INSTALLSTRIP=""
 942   AC_MSG_RESULT(no.)
 943 fi
 944
 945 FR_TLS
 946
 947 dnl #############################################################
 948 dnl #
 949 dnl #  7. Checks for library functions
 950 dnl #
 951 dnl #############################################################
 952
 953 old_LIBS="$LIBS"
 954 LIBS="$LIBS $LIBLTDL"
 955 AC_CHECK_FUNC(lt_dladvise_init, AC_DEFINE(HAVE_LT_DLADVISE_INIT, [], [Do we have the lt_dladvise_init function]))
 956 LIBS="$old_LIBS"
 957
 958 dnl Check for libcrypt
 959 dnl We use crypt(3) which may be in libc, or in libcrypt (eg FreeBSD)
 960 AC_CHECK_LIB(crypt, crypt,
 961   CRYPTLIB="-lcrypt"
 962 )
 963 if test "$CRYPTLIB" != ""; then
 964   AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function])
 965 else
 966   AC_CHECK_FUNC(crypt, AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function]))
 967 fi
 968
 969 dnl Check for libcipher
 970 AC_CHECK_LIB(cipher, setkey,
 971    CRYPTLIB="${CRYPTLIB} -lcipher"
 972 )
 973 AC_SUBST(CRYPTLIB)
 974
 975 dnl Check the style of gethostbyaddr, in order of preference
 976 dnl GNU (_r eight args)
 977 AC_DEFINE(GNUSTYLE, [1], [GNU-Style get*byaddr_r])
 978 dnl SYSV (_r six args)
 979 AC_DEFINE(SYSVSTYLE, [2], [SYSV-Style get*byaddr_r])
 980 dnl BSD (three args, may not be thread safe)
 981 AC_DEFINE(BSDSTYLE, [3], [BSD-Style get*byaddr_r])
 982 dnl Tru64 has BSD version, but it is thread safe
 983 dnl     http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1739____.HTM
 984 dnl We need #stdio.h to define NULL on FreeBSD (at least)
 985 gethostbyaddrrstyle=""
 986 AC_MSG_CHECKING([gethostbyaddr_r() syntax])
 987 case "$host" in
 988 *-freebsd*)
 989 dnl With FreeBSD, check if there's a prototype for gethostbyaddr_r.
 990 dnl Some versions (FreeBSD 5.1?) have a symbol but no prototype - so we
 991 dnl override this test to BSDSTYLE. FreeBSD 6.2 and up have proper GNU
 992 dnl style support.
 993         AC_CHECK_DECLS([gethostbyaddr_r], [], [
 994                 AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE,
 995                         [style of gethostbyaddr_r functions ])
 996                 gethostbyaddrrstyle=BSD
 997                 AC_MSG_WARN([FreeBSD overridden to BSD-style])
 998         ], [
 999 #ifdef HAVE_NETDB_H
1000 #include <netdb.h>
1001 #endif
1002 ])
1003         ;;
1004 esac
1005 if test "x$gethostbyaddrrstyle" = "x"; then
1006         AC_TRY_LINK([
1007 #include <stdio.h>
1008 #include <netdb.h>
1009 ], [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL, NULL) ], [
1010         AC_DEFINE(GETHOSTBYADDRRSTYLE, GNUSTYLE, [style of gethostbyaddr_r functions ])
1011         gethostbyaddrrstyle=GNU
1012 ])
1013 fi
1014 if test "x$gethostbyaddrrstyle" = "x"; then
1015         AC_TRY_LINK([
1016 #include <stdio.h>
1017 #include <netdb.h>
1018 ], [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL) ] , [
1019                 AC_DEFINE(GETHOSTBYADDRRSTYLE, SYSVSTYLE, [style of gethostbyaddr_r functions ])
1020                 gethostbyaddrrstyle=SYSV
1021         ])
1022 fi
1023 if test "x$gethostbyaddrrstyle" = "x"; then
1024         AC_TRY_LINK([
1025 #include <stdio.h>
1026 #include <netdb.h>
1027 ], [ gethostbyaddr(NULL, 0, 0)  ], [
1028                 AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE, [style of gethostbyaddr_r functions ])
1029                 gethostbyaddrrstyle=BSD
1030         ])
1031 fi
1032
1033 if test "x$gethostbyaddrrstyle" = "x"; then
1034         AC_MSG_RESULT([none!  It must not exist, here.])
1035 else
1036         AC_MSG_RESULT([${gethostbyaddrrstyle}-style])
1037 fi
1038
1039 if test "x$gethostbyaddrrstyle" = "xBSD"; then
1040         AC_MSG_WARN([ ****** BSD-style gethostbyaddr might NOT be thread-safe! ****** ])
1041 fi
1042
1043 dnl Check the style of gethostbyname, in order of preference
1044 dnl GNU (_r seven args)
1045 dnl SYSV (_r five args)
1046 dnl BSD (two args, may not be thread safe)
1047 dnl Tru64 has BSD version, but it _is_ thread safe
1048 dnl     http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1946____.HTM
1049 dnl We need #stdio.h to define NULL on FreeBSD (at least)
1050 gethostbynamerstyle=""
1051 AC_MSG_CHECKING([gethostbyname_r() syntax])
1052 AC_TRY_LINK([
1053 #include <stdio.h>
1054 #include <netdb.h>
1055 ], [ gethostbyname_r(NULL, NULL, NULL, 0, NULL, NULL) ], [
1056         AC_DEFINE(GETHOSTBYNAMERSTYLE, GNUSTYLE, [style of gethostbyname_r functions ])
1057         gethostbynamerstyle=GNU
1058 ])
1059 if test "x$gethostbynamerstyle" = "x"; then
1060         AC_TRY_LINK([
1061 #include <stdio.h>
1062 #include <netdb.h>
1063 ], [ gethostbyname_r(NULL, NULL, NULL, 0, NULL) ] , [
1064                 AC_DEFINE(GETHOSTBYNAMERSTYLE, SYSVSTYLE, [style of gethostbyname_r functions ])
1065                 gethostbynamerstyle=SYSV
1066         ])
1067 fi
1068 if test "x$gethostbynamerstyle" = "x"; then
1069         AC_TRY_LINK([
1070 #include <stdio.h>
1071 #include <netdb.h>
1072 ], [ gethostbyname(NULL)  ], [
1073                 AC_DEFINE(GETHOSTBYNAMERSTYLE, BSDSTYLE, [style of gethostbyname_r functions ])
1074                 gethostbynamerstyle=BSD
1075         ])
1076 fi
1077
1078 if test "x$gethostbynamerstyle" = "x"; then
1079         AC_MSG_RESULT([none!  It must not exist, here.])
1080 else
1081         AC_MSG_RESULT([${gethostbynamerstyle}-style])
1082 fi
1083
1084 if test "x$gethostbynamerstyle" = "xBSD"; then
1085         AC_MSG_WARN([ ****** BSD-style gethostbyname might NOT be thread-safe! ****** ])
1086 fi
1087
1088 dnl check for non-posix solaris ctime_r (extra buflen int arg)
1089 AC_DEFINE(POSIXSTYLE, [1], [Posix-Style ctime_r])
1090 AC_DEFINE(SOLARISSTYLE, [2], [Solaris-Style ctime_r])
1091 ctimerstyle=""
1092 AC_MSG_CHECKING([ctime_r() syntax])
1093 AC_TRY_LINK([
1094 #include <time.h>
1095 ], [ ctime_r(NULL, NULL, 0) ], [
1096         AC_DEFINE(CTIMERSTYLE, SOLARISSTYLE, [style of ctime_r function])
1097         ctimerstyle="SOLARIS"
1098 ])
1099 if test "x$ctimerstyle" = "x"; then
1100         AC_TRY_LINK([
1101 #include <time.h>
1102 ], [ ctime_r(NULL, NULL) ], [
1103                 AC_DEFINE(CTIMERSTYLE, POSIXSTYLE, [style of ctime_r function])
1104                 ctimerstyle="POSIX"
1105         ])
1106 fi
1107
1108 if test "x$ctimerstyle" = "x"; then
1109         AC_MSG_RESULT([none!  It must not exist, here.])
1110 else
1111         AC_MSG_RESULT([${ctimerstyle}-style])
1112 fi
1113
1114 AC_SUBST(HOSTINFO, $host)
1115
1116 dnl #############################################################
1117 dnl #
1118 dnl #  8. Checks for system services
1119 dnl #
1120 dnl #############################################################
1121
1122 dnl #
1123 dnl # Figure out where libtool is located,
1124 dnl #
1125 top_builddir=`pwd`
1126 export top_builddir
1127 AC_MSG_RESULT([top_builddir=$top_builddir])
1128 dnl # AC_SUBST(top_builddir)
1129 AC_SUBST(LIBLTDL)
1130 AC_SUBST(INCLTDL)
1131
1132 dnl import libtool stuff
1133
1134 dnl #############################################################
1135 dnl #
1136 dnl #  Configure in any module directories.
1137 dnl #
1138 dnl #############################################################
1139
1140 mysubdirs="$LIBLTDLPATH"
1141 if test "x$EXPERIMENTAL" = "xyes"; then
1142   bar=`ls -1 "${srcdir}"/src/modules/rlm_*/configure | sed 's%/configure%%'`
1143   dnl # get rid of LF's.
1144   mysubdirs=`echo $mysubdirs $bar`
1145 else
1146   dnl #
1147   dnl # Find 'configure' in ONLY the stable modules
1148   dnl #
1149   for bar in `cat "${srcdir}"/src/modules/stable`; do
1150     if test -f "${srcdir}"/src/modules/$bar/configure; then
1151       mysubdirs="$mysubdirs src/modules/$bar"
1152     fi
1153   done
1154 fi
1155
1156 dnl ############################################################
1157 dnl # make modules by list
1158 dnl #############################################################
1159 if test "x$EXPERIMENTAL" = "xyes"; then
1160   for foo in `ls -1 "${srcdir}"/src/modules | grep rlm_`; do
1161     MODULES="$MODULES $foo"
1162   done
1163 else
1164    dnl #
1165    dnl # make ONLY the stable modules
1166    dnl #
1167    for foo in `cat "${srcdir}"/src/modules/stable`; do
1168     MODULES="$MODULES $foo"
1169    done
1170 fi
1171
1172 dnl #
1173 dnl #  Don't change the variable name here.  Autoconf goes bonkers
1174 dnl #  if you do.
1175 dnl #
1176 AC_CONFIG_SUBDIRS($LTDL_SUBDIRS $mysubdirs)
1177 AC_SUBST(MODULES)
1178
1179 dnl #############################################################
1180 dnl #
1181 dnl #  And finally, output the results.
1182 dnl #
1183 dnl #############################################################
1184
1185 AC_CONFIG_COMMANDS([stamp-h], [echo timestamp > src/include/stamp-h])
1186 AC_CONFIG_COMMANDS([build-radpaths-h], [(cd ./src/include && /bin/sh ./build-radpaths-h)])
1187 AC_CONFIG_COMMANDS([main-chmod], [(cd ./src/main   && chmod +x checkrad.pl radlast radtest)])
1188 AC_CONFIG_COMMANDS([scripts-chmod], [(cd ./scripts    && chmod +x rc.radiusd radwatch radiusd.cron.daily radiusd.cron.monthly cryptpasswd)])
1189
1190 dnl #
1191 dnl #  Substitute whatever libraries we found to be necessary
1192 dnl #
1193 AC_SUBST(LIBS)
1194 AC_SUBST(INSTALLSTRIP)
1195
1196 USE_SHARED_LIBS=$enable_shared
1197 AC_SUBST(USE_SHARED_LIBS)
1198 USE_STATIC_LIBS=$enable_static
1199 AC_SUBST(USE_STATIC_LIBS)
1200 AC_SUBST(STATIC_MODULES)
1201 AC_SUBST(RADIUSD_MAJOR_VERSION)
1202 AC_SUBST(RADIUSD_MINOR_VERSION)
1203 AC_SUBST(RADIUSD_VERSION)
1204
1205 AC_OUTPUT(\
1206         ./Make.inc \
1207         ./src/include/build-radpaths-h \
1208         ./src/main/Makefile \
1209         ./src/main/checkrad.pl \
1210         ./src/main/radlast \
1211         ./src/main/radtest \
1212         ./scripts/rc.radiusd \
1213         ./scripts/radwatch \
1214         ./scripts/radiusd.cron.daily \
1215         ./scripts/radiusd.cron.monthly \
1216         ./scripts/cryptpasswd \
1217         ./raddb/dictionary \
1218         ./raddb/radrelay.conf \
1219         ./raddb/radiusd.conf
1220 )