configure.in

   1 dnl #############################################################
   2 dnl #
   3 dnl #  For information about autoconf, see:
   4 dnl #
   5 dnl #  http://www.gnu.org/software/autoconf/
   6 dnl #
   7 dnl #  The recommended order is:
   8 dnl #
   9 dnl #  AC_INIT(file)
  10 dnl #  0. checks for compiler, libtool, and command line options
  11 dnl #  1. checks for programs
  12 dnl #  2. checks for libraries
  13 dnl #  3. checks for header files
  14 dnl #  4. checks for typedefs
  15 dnl #  5. checks for structures and functions
  16 dnl #  6. checks for compiler characteristics
  17 dnl #  7. checks for library functions
  18 dnl #  8. checks for system services
  19 dnl #  AC_OUTPUT([file...])
  20 dnl #
  21 dnl #############################################################
  22
  23 AC_PREREQ([2.59])
  24 export CFLAGS LIBS LDFLAGS CPPFLAGS
  25 AC_INIT(src/main/radiusd.c)
  26 AC_CONFIG_HEADER(src/include/autoconf.h)
  27 AC_REVISION($Revision$)dnl
  28
  29 dnl # The version of the software
  30 RADIUSD_VERSION=`cat VERSION`
  31 RADIUSD_MAJOR_VERSION=`cat VERSION | sed 's/\..*//'`
  32 RADIUSD_MINOR_VERSION=`cat VERSION | sed 's/^2\.//'`
  33 PACKAGE=freeradius
  34
  35 dnl #############################################################
  36 dnl #
  37 dnl #  0. Checks for compiler, libtool, and command line options.
  38 dnl #
  39 dnl #############################################################
  40
  41 dnl Check for GNU cc
  42 AC_PROG_CC
  43 AC_PROG_CXX
  44
  45 dnl #
  46 dnl # check for AIX, to allow us to use some BSD functions
  47 dnl # must be before macros that call the compiler.
  48 dnl #
  49 AC_AIX
  50
  51 AC_PROG_GCC_TRADITIONAL
  52 AC_PROG_CC_SUNPRO
  53 AC_PROG_RANLIB
  54
  55 dnl #
  56 dnl # Set Default CFLAGS
  57 dnl #
  58 if test "x$GCC" = "xyes"; then
  59     CFLAGS="$CFLAGS -Wall -D_GNU_SOURCE"
  60 fi
  61
  62 dnl Compile in large (2G+) file support.
  63 AC_SYS_LARGEFILE
  64
  65 dnl # check for system bytesex
  66 dnl # AC_DEFINES WORDS_BIGENDIAN
  67 AC_C_BIGENDIAN
  68
  69 dnl Find GNU Make.
  70 AC_CHECK_PROG(GMAKE, gmake, yes, no)
  71 if test $GMAKE = no; then
  72   AC_PATH_PROG(MAKE, make, /usr/local/bin/make)
  73 else
  74   AC_PATH_PROG(MAKE, gmake, /usr/local/gnu/bin/make)
  75 fi
  76 makever=`$ac_cv_path_MAKE --version 2>&1 | grep "GNU Make"`
  77 if test -z "$makever"; then
  78   AC_MSG_ERROR(GNU Make is not installed.  Please download and install it
  79                 from ftp://prep.ai.mit.edu/pub/gnu/make/ before continuing.)
  80 fi
  81
  82 AC_ARG_WITH(system-libltdl,
  83 [  --with-system-libltdl   Use the libltdl installed in your system (default=use our own)],
  84 [
  85 LIBLTDL="-lltdl"
  86 INCLTDL=
  87 LTDL_SUBDIRS=
  88 ],
  89 [
  90 dnl If libltdl isn't installable, set it to be installable.
  91 [test x"$enable_ltdl_install" = x && enable_ltdl_install=yes]
  92 AC_LIBLTDL_INSTALLABLE
  93
  94 dnl tell Makefile to build ltdl if needed
  95 if test x"$enable_ltdl_install" = x"yes"; then
  96   LTDL_SUBDIRS=libltdl
  97 fi
  98 ])
  99 AC_SUBST(LTDL_SUBDIRS)
 100
 101 dnl use system-wide libtool, if it exists
 102 AC_ARG_WITH(system-libtool,
 103 [  --with-system-libtool   Use the libtool installed in your system (default=use our own)],
 104 [ AC_PATH_PROG(LIBTOOL, libtool,,$PATH:/usr/local/bin) AC_LIBTOOL_DLOPEN
 105  AC_PROG_LIBTOOL],
 106 [
 107   LIBTOOL="`pwd`/libtool"
 108   AC_SUBST(LIBTOOL)
 109   dnl ensure that we're looking for dlopen
 110   AC_LIBTOOL_DLOPEN
 111
 112   dnl Figure out how to build shared libraries
 113   AC_PROG_LIBTOOL
 114 ])
 115
 116
 117 dnl Put this in later, when all distributed modules use autoconf.
 118 dnl AC_ARG_WITH(disablemodulefoo,
 119 dnl [  --without-rlm_foo       Disables module compilation.  Module list:]
 120 dnl esyscmd([find src/modules -type d -name rlm_\* -print |\
 121 dnl     sed -e 's%src/modules/.*/% (sub)- %; s%.*/%- %' |\
 122 dnl     awk '{print "                            "$0}']))
 123
 124 AC_ARG_ENABLE(strict-dependencies,
 125 [  --enable-strict-dependencies  Fail configure on lack of module dependancy.])
 126
 127 dnl extra argument: --with-docdir
 128 docdir='${datadir}/doc/freeradius'
 129 AC_MSG_CHECKING(docdir)
 130 AC_ARG_WITH(docdir,
 131 [  --with-docdir=DIR       Directory for documentation [DATADIR/doc/freeradius] ],
 132 [ case "$withval" in
 133     no)
 134         docdir=no
 135         ;;
 136     yes)
 137         ;;
 138     [[\\/$]]* | ?:[[\\/]]* )
 139         docdir="$withval"
 140         ;;
 141     *)
 142         AC_MSG_ERROR([expected an absolute directory name for --with-docdir: $withval])
 143         ;;
 144   esac ]
 145 )
 146 AC_SUBST(docdir)
 147 AC_MSG_RESULT($docdir)
 148 if test "x$docdir" = xno; then
 149         AC_MSG_WARN(Documentation files will NOT be installed.)
 150 fi
 151
 152 dnl extra argument: --with-logdir
 153 logdir='${localstatedir}/log/radius'
 154 AC_MSG_CHECKING(logdir)
 155 AC_ARG_WITH(logdir,
 156 [  --with-logdir=DIR       Directory for logfiles [LOCALSTATEDIR/log/radius] ],
 157 [ case "$withval" in
 158     no)
 159         AC_MSG_ERROR(Need logdir)
 160         ;;
 161     yes)
 162         ;;
 163     [[\\/$]]* | ?:[[\\/]]* )
 164         logdir="$withval"
 165         ;;
 166     *)
 167         AC_MSG_ERROR([expected an absolute directory name for --with-logdir: $withval])
 168         ;;
 169   esac ]
 170 )
 171 AC_SUBST(logdir)
 172 AC_MSG_RESULT($logdir)
 173
 174 dnl extra argument: --with-radacctdir
 175 radacctdir='${logdir}/radacct'
 176 AC_MSG_CHECKING(radacctdir)
 177 AC_ARG_WITH(radacctdir,
 178 [  --with-radacctdir=DIR   Directory for detail files [LOGDIR/radacct] ],
 179 [ case "$withval" in
 180     no)
 181         AC_MSG_ERROR(Need radacctdir)
 182         ;;
 183     yes)
 184         ;;
 185     [[\\/$]]* | ?:[[\\/]]* )
 186         radacctdir="$withval"
 187         ;;
 188     *)
 189         AC_MSG_ERROR([expected an absolute directory name for --with-radacctdir: $withval])
 190         ;;
 191   esac ]
 192 )
 193 AC_SUBST(radacctdir)
 194 AC_MSG_RESULT($radacctdir)
 195
 196 dnl extra argument: --with-raddbdir
 197 raddbdir='${sysconfdir}/raddb'
 198 AC_MSG_CHECKING(raddbdir)
 199 AC_ARG_WITH(raddbdir,
 200 [  --with-raddbdir=DIR     Directory for config files [SYSCONFDIR/raddb] ],
 201 [ case "$withval" in
 202     no)
 203         AC_MSG_ERROR(Need raddbdir)
 204         ;;
 205     yes)
 206         ;;
 207     [[\\/$]]* | ?:[[\\/]]* )
 208         raddbdir="$withval"
 209         ;;
 210     *)
 211         AC_MSG_ERROR([expected an absolute directory name for --with-raddbdir: $withval])
 212         ;;
 213   esac ]
 214 )
 215 AC_SUBST(raddbdir)
 216 AC_MSG_RESULT($raddbdir)
 217
 218 dnl extra argument: --with-ascend-binary
 219 ASCEND_BINARY=yes
 220 AC_ARG_WITH(ascend-binary,
 221 [  --with-ascend-binary    Include support for Ascend binary filter attributes (default=yes)],
 222 [ case "$withval" in
 223     yes)
 224         ;;
 225     *)
 226         ASCEND_BINARY=""
 227   esac ]
 228 )
 229 if test "X$ASCEND_BINARY" = "Xyes"; then
 230   AC_DEFINE(ASCEND_BINARY, [], [Include support for Ascend binary filter attributes])
 231 fi
 232
 233 dnl extra argument: --with-threads
 234 WITH_THREADS=yes
 235 AC_ARG_WITH(threads,
 236 [  --with-threads          Use threads, if available.  (default=yes) ],
 237 [ case "$withval" in
 238     yes)
 239         ;;
 240     *)
 241         WITH_THREADS=""
 242   esac ]
 243 )
 244
 245 dnl extra argument: --with-vmps
 246 WITH_VMPS=yes
 247 AC_ARG_WITH(vmps,
 248 [  --with-vmps             Compile in VMPS support. (default=yes)],
 249 [ case "$withval" in
 250     yes)
 251         ;;
 252     *)
 253         WITH_VMPS=no
 254   esac ]
 255 )
 256 if test "x$WITH_VMPS" = "xyes"; then
 257         AC_DEFINE(WITH_VMPS, [1], [define if you want VMPS support])
 258 fi
 259
 260 dnl extra argument: --with-dhcp
 261 AC_ARG_WITH(dhcp,
 262 [  --with-dhcp             Compile in DHCP support. (default=no)],
 263 [ case "$withval" in
 264     yes)
 265         AC_DEFINE(WITH_DHCP, [1], [Include experimental support for DHCP])
 266         ;;
 267     *)
 268         ;;
 269   esac ]
 270 )
 271
 272
 273 dnl #
 274 dnl #  Allow the user to specify a list of modules to be linked
 275 dnl #  statically to the server.
 276 dnl #
 277 STATIC_MODULES=
 278 AC_ARG_WITH(static_modules,
 279 [  --with-static-modules=QUOTED-MODULE-LIST],[
 280   for i in $withval; do
 281     STATIC_MODULES="$STATIC_MODULES -dlpreopen ../modules/rlm_$i/rlm_$i.la"
 282   done
 283 ])
 284
 285 MODULES=
 286 AC_ARG_WITH(modules,
 287 [ --with-modules=QUOTED-MODULE-LIST],[
 288  for i in $withval; do
 289    MODULES="$MODULES $i"
 290  done
 291 ])
 292
 293 dnl #
 294 dnl #  Enable developer C compiler warnings
 295 dnl #
 296 AC_ARG_ENABLE(developer,
 297 [  --enable-developer               Enables features of interest to developers.],
 298 [ case "$enableval" in
 299     no)
 300         developer=no
 301         ;;
 302     *)
 303         developer=yes
 304   esac ]
 305 )
 306
 307 if test "x$developer" != "xno" -a -d $srcdir/CVS; then
 308   dnl turn on the developer flag when taken from a CVS checkout (not a release)
 309   developer="yes"
 310 fi
 311
 312 if test "x$developer" != "xno" -a -d $srcdir/.git; then
 313   dnl turn on the developer flag when taken from a git checkout (not a release)
 314   developer="yes"
 315 fi
 316
 317 dnl extra argument: --with-experimental-modules
 318 EXPERIMENTAL=
 319 AC_ARG_WITH(experimental-modules,
 320 [  --with-experimental-modules      Use experimental and unstable modules. (default=no) ],
 321 [ case "$withval" in
 322     yes)
 323         EXPERIMENTAL=yes
 324         ;;
 325     *)
 326   esac ]
 327 )
 328
 329 dnl extra argument: --with-openssl
 330 WITH_OPENSSL=yes
 331 AC_ARG_WITH(openssl,
 332 [  --with-openssl                   Use OpenSSL. (default=yes)],
 333 [ case "$withval" in
 334     no)
 335         WITH_OPENSSL=no
 336         ;;
 337     *)
 338         WITH_OPENSSL=yes
 339         ;;
 340   esac ]
 341 )
 342
 343 dnl #
 344 dnl # extra argument: --with-openssl-includes=dir
 345 dnl #
 346 OPENSSL_INCLUDE_DIR=
 347 AC_ARG_WITH(openssl-includes,
 348 [  --with-openssl-includes=DIR      Directory to look for OpenSSL include files],
 349 [ case "$withval" in
 350     *) OPENSSL_INCLUDE_DIR="$withval"
 351         ;;
 352   esac ]
 353 )
 354
 355 dnl #
 356 dnl # extra argument: --with-openssl-libraries=dir
 357 dnl #
 358 OPENSSL_LIB_DIR=
 359 AC_ARG_WITH(openssl-libraries,
 360 [  --with-openssl-libraries=DIR     Directory to look for OpenSSL library files],
 361 [ case "$withval" in
 362     *) OPENSSL_LIB_DIR="$withval"
 363         ;;
 364   esac ]
 365 )
 366
 367 dnl #
 368 dnl #  These next two arguments don't actually do anything.  They're
 369 dnl #  place holders so that the top-level configure script can tell
 370 dnl #  the user how to configure lower-level modules
 371 dnl #
 372
 373 dnl #
 374 dnl # extra argument: --with-rlm-FOO-lib-dir
 375 dnl #
 376 AC_ARG_WITH(rlm-FOO-lib-dir,
 377 [  --with-rlm-FOO-lib-dir=DIR       Directory to look for library files used by module FOO],
 378 [ case "$withval" in
 379     *)
 380         ;;
 381   esac ]
 382 )
 383
 384 dnl #
 385 dnl # extra argument: --with-rlm-FOO-include-dir
 386 dnl #
 387 AC_ARG_WITH(rlm-FOO-include-dir,
 388 [  --with-rlm-FOO-include-dir=DIR   Directory to look for include files used by module FOO],
 389 [ case "$withval" in
 390     *)
 391         ;;
 392   esac ]
 393 )
 394
 395 dnl See what include-style is used by the make program.
 396 dnl AC_MSG_CHECKING(include style for make)
 397 dnl echo "include /dev/null" > testmake.$$
 398 dnl echo "all:" >> testmake.$$
 399 dnl make -f testmake.$$ >/dev/null 2>&1
 400 dnl if test $? = 0
 401 dnl then
 402 dnl     INCLUDE=include
 403 dnl     IQUOTE=
 404 dnl else
 405 dnl     INCLUDE=.include
 406 dnl     IQUOTE='"'
 407 dnl fi
 408 dnl rm -f testmake.$$
 409 dnl AC_MSG_RESULT(" $INCLUDE")
 410 dnl AC_SUBST(INCLUDE)
 411 dnl AC_SUBST(IQUOTE)
 412
 413 dnl extra argument: --with-udpfromto
 414 WITH_UDPFROMTO=no
 415 AC_ARG_WITH(udpfromto,
 416 [  --with-udpfromto        Compile in UDPFROMTO support. (default=no)],
 417 [ case "$withval" in
 418     yes)
 419         WITH_UDPFROMTO=yes
 420         ;;
 421     *)
 422         WITH_UDPFROMTO=no
 423   esac ]
 424 )
 425
 426 if test "x$WITH_UDPFROMTO" = "xyes"; then
 427         AC_DEFINE(WITH_UDPFROMTO, [], [define if you want udpfromto])
 428 fi
 429
 430 dnl #############################################################
 431 dnl #
 432 dnl #  1. Checks for programs
 433 dnl #
 434 dnl #############################################################
 435
 436 CHECKRAD=checkrad.pl
 437 AC_PATH_PROG(PERL, perl, /usr/local/bin/perl)
 438 if test "x$ac_cv_path_PERL" = "x"; then
 439   AC_MSG_WARN(perl not found - Simultaneous-Use and checkrad.pl may not work)
 440 fi
 441 AC_PATH_PROG(SNMPGET, snmpget)
 442 if test "x$ac_cv_path_SNMPGET" = "x"; then
 443   AC_MSG_WARN(snmpget not found - Simultaneous-Use and checkrad.pl may not work)
 444 fi
 445
 446 AC_PATH_PROG(SNMPWALK, snmpwalk)
 447 if test "x$ac_cv_path_SNMPWALK" = "x"; then
 448   AC_MSG_WARN(snmpwalk not found - Simultaneous-Use and checkrad.pl may not work)
 449 fi
 450
 451 AC_PATH_PROG(RUSERS, rusers, /usr/bin/rusers)
 452
 453 dnl FIXME This is truly gross.
 454 missing_dir=`cd $ac_aux_dir && pwd`
 455 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
 456 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
 457 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
 458
 459 AC_PATH_PROG(LOCATE,locate)
 460 AC_PATH_PROG(DIRNAME,dirname)
 461 AC_PATH_PROG(GREP,grep)
 462
 463 dnl #############################################################
 464 dnl #
 465 dnl #  2. Checks for libraries
 466 dnl #
 467 dnl #############################################################
 468
 469 dnl If using pthreads, check for -lpthread (posix) or -lc_r (*BSD)
 470 old_CFLAGS=$CFLAGS
 471 if test "x$WITH_THREADS" = "xyes"; then
 472   if test $ac_cv_prog_suncc = "yes"; then
 473     CFLAGS="$CFLAGS -mt"
 474   fi
 475
 476   AC_CHECK_HEADERS(pthread.h, [], [ WITH_THREADS="no" ])
 477
 478 dnl #
 479 dnl # pthread stuff is usually in -lpthread
 480 dnl # or in -lc_r, on *BSD
 481 dnl #
 482 dnl # On Some systems, we need extra pre-processor flags, to get them to
 483 dnl # to do the threading properly.
 484 dnl #
 485   AC_CHECK_LIB(pthread, pthread_create,
 486                 [ CFLAGS="$CFLAGS -D_REENTRANT -D_POSIX_PTHREAD_SEMANTICS"
 487                   LIBS="$LIBS -lpthread" ],
 488                 AC_CHECK_LIB(c_r, pthread_create,
 489                             [ CFLAGS="$CFLAGS -pthread -D_THREAD_SAFE" ],
 490                             [ WITH_THREADS="no" ]
 491                             )
 492                 )
 493 fi
 494
 495 dnl #
 496 dnl # If we have NO pthread libraries, remove any knowledge of threads.
 497 dnl #
 498 if test "x$WITH_THREADS" != "xyes"; then
 499   CFLAGS=$old_CFLAGS
 500   ac_cv_header_pthread_h="no"
 501   WITH_THREADS=no
 502 else
 503   dnl #
 504   dnl #  We need sem_init() and friends, as they're the friendliest
 505   dnl #  semaphore functions for threading.
 506   dnl #
 507   dnl # HP/UX requires linking with librt, too, to get the sem_* symbols.
 508   dnl # Some systems have them in -lsem
 509   dnl # Solaris has them in -lposix4
 510   dnl # NetBSD has them in -lsemaphore
 511
 512   AC_SEARCH_LIBS(sem_init, pthread sem posix4 rt semaphore,
 513         [],
 514         [AC_MSG_ERROR(-lsem not found.  You may want to download it from ftp://ftp.to.gd-es.com/pub/BSDI/libsem.tar.bz2 or ftp://ftp.freeradius.org/pub/radius/contrib/libsem.tar.gz)]
 515    )
 516 fi
 517
 518 dnl Check if we need -lsocket
 519 AC_CHECK_LIB(socket, getsockname)
 520
 521 dnl Check for -lresolv
 522 dnl This library may be needed later.
 523 AC_CHECK_LIB(resolv, inet_aton)
 524
 525 dnl Check if we need -lnsl. Usually if we want to
 526 dnl link against -lsocket we need to include -lnsl as well.
 527 AC_CHECK_LIB(nsl, inet_ntoa)
 528
 529 dnl Check for OpenSSL libraries.
 530 OPENSSL_LIBS=
 531 if test "x$WITH_OPENSSL" = xyes; then
 532   old_LIBS=$LIBS
 533   old_LDFLAGS="$LDFLAGS"
 534   if test "x$OPENSSL_LIB_DIR" != "x"; then
 535     LDFLAGS="$LDFLAGS -L$OPENSSL_LIB_DIR"
 536   fi
 537   AC_CHECK_LIB(crypto, DH_new,
 538     [
 539         LIBS="-lcrypto $LIBS"
 540         AC_DEFINE(HAVE_LIBCRYPTO, 1,
 541             [Define to 1 if you have the `crypto' library (-lcrypto).])
 542         AC_CHECK_LIB(ssl, SSL_new,
 543             [
 544                 AC_DEFINE(HAVE_LIBSSL, 1,
 545                     [Define to 1 if you have the `ssl' library (-lssl).])
 546                 if test "x$OPENSSL_LIB_DIR" != "x"; then
 547                     OPENSSL_LIBS="-L$OPENSSL_LIB_DIR"
 548                 fi
 549                 OPENSSL_LIBS="$OPENSSL_LIBS -lcrypto -lssl -lcrypto"
 550             ], [])
 551     ], [])
 552   LIBS=$old_LIBS
 553   LDFLAGS="$old_LDFLAGS"
 554 fi
 555
 556 AC_CHECK_LIB(ws2_32, htonl)
 557
 558 dnl Check the pcap library for the RADIUS sniffer.
 559 PCAP_LIBS=
 560 AC_CHECK_LIB(pcap, pcap_open_live,
 561         [ PCAP_LIBS="-lpcap"
 562         AC_DEFINE(HAVE_LIBPCAP, 1,
 563                 [Define to 1 if you have the `pcap' library (-lpcap).])
 564         ],
 565         [ AC_MSG_WARN([pcap library not found, silently disabling the RADIUS sniffer.]) ])
 566
 567 AC_LIB_READLINE
 568
 569 dnl #############################################################
 570 dnl #
 571 dnl #  3. Checks for header files
 572 dnl #
 573 dnl #############################################################
 574
 575 dnl #
 576 dnl # Interix requires us to set -D_ALL_SOURCE, otherwise
 577 dnl # getopt will be #included, but won't link.  <sigh>
 578 dnl #
 579 dnl #
 580 case "$host" in
 581 *-interix*)
 582         CFLAGS="$CFLAGS -D_ALL_SOURCE"
 583         ;;
 584 *-darwin*)
 585         CFLAGS="$CFLAGS -DDARWIN"
 586         LIBS="-framework DirectoryService $LIBS"
 587         ;;
 588 esac
 589
 590 AC_HEADER_DIRENT
 591 AC_HEADER_STDC
 592 AC_HEADER_TIME
 593 AC_HEADER_SYS_WAIT
 594
 595 AC_CHECK_HEADERS( \
 596         unistd.h \
 597         crypt.h \
 598         errno.h \
 599         resource.h \
 600         sys/resource.h \
 601         getopt.h \
 602         malloc.h \
 603         utmp.h \
 604         utmpx.h \
 605         signal.h \
 606         sys/select.h \
 607         syslog.h \
 608         inttypes.h \
 609         stdint.h \
 610         stdio.h \
 611         netdb.h \
 612         semaphore.h \
 613         arpa/inet.h \
 614         netinet/in.h \
 615         sys/types.h \
 616         sys/socket.h \
 617         winsock.h \
 618         sys/time.h \
 619         sys/wait.h \
 620         sys/security.h \
 621         fcntl.h \
 622         sys/fcntl.h \
 623         sys/prctl.h \
 624         sys/un.h \
 625         glob.h \
 626         prot.h \
 627         pwd.h \
 628         grp.h \
 629         stddef.h \
 630         fnmatch.h \
 631         sia.h \
 632         siad.h
 633 )
 634
 635 dnl FreeBSD requires sys/socket.h before net/if.h
 636 AC_CHECK_HEADERS(net/if.h, [], [],
 637 [#ifdef HAVE_SYS_SOCKET_H
 638 # include <sys/socket.h>
 639 # endif
 640 ])
 641
 642 REGEX=no
 643 AC_CHECK_HEADER(regex.h, AC_DEFINE(HAVE_REGEX_H, [], [define this if we have the <regex.h> header file]))
 644 if test "x$ac_cv_header_regex_h" = "xyes"; then
 645   REGEX_EXTENDED=no
 646   REGEX=yes
 647   AC_EGREP_CPP(yes,
 648     [#include <regex.h>
 649      #ifdef REG_EXTENDED
 650        yes
 651      #endif
 652      ], [AC_DEFINE(HAVE_REG_EXTENDED, [], [define this if we have REG_EXTENDED (from <regex.h>)]) REGEX_EXTENDED=yes])
 653 fi
 654 AC_SUBST(REGEX)
 655 AC_SUBST(REGEX_EXTENDED)
 656
 657 dnl #
 658 dnl #  other checks which require headers
 659 dnl #
 660 if test "x$ac_cv_header_sys_security_h" = "xyes" && test "x$ac_cv_header_prot_h" = "xyes"
 661 then
 662   AC_DEFINE(OSFC2, [], [define if you have OSFC2 authentication])
 663 fi
 664
 665 if test "x$ac_cv_header_sia_h" = "xyes" && test "x$ac_cv_header_siad_h" = "xyes"
 666 then
 667   AC_DEFINE(OSFSIA, [], [define if you have OSFSIA authentication])
 668 fi
 669
 670 dnl Check for OpenSSL includes.
 671 OPENSSL_INCLUDE="-DNO_OPENSSL"
 672 if test "x$WITH_OPENSSL" = xyes; then
 673   if test "x$OPENSSL_LIBS" = "x"; then
 674     AC_MSG_NOTICE([skipping test for openssl/ssl.h])
 675   else
 676     old_CPPFLAGS=$CPPFLAGS
 677     if test "x$OPENSSL_INCLUDE_DIR" != "x"; then
 678         CPPFLAGS="$CPPFLAGS -I$OPENSSL_INCLUDE_DIR"
 679     fi
 680     dnl # stupid RedHat shit
 681     CPPFLAGS="$CPPFLAGS -DOPENSSL_NO_KRB5"
 682     AC_CHECK_HEADERS( \
 683         openssl/ssl.h \
 684         openssl/crypto.h \
 685         openssl/err.h \
 686         openssl/evp.h \
 687         openssl/ocsp.h \
 688         openssl/engine.h,
 689         [],
 690         OPENSSL_LIBS=
 691     )
 692     if test "x$OPENSSL_LIBS" != "x"; then
 693         AC_MSG_CHECKING([for OpenSSL version >= 0.9.7])
 694         AC_EGREP_CPP(yes,
 695             [#include <openssl/crypto.h>
 696              #if (OPENSSL_VERSION_NUMBER >= 0x00907000L)
 697              yes
 698              #endif
 699             ], goodssl="yes")
 700         if test "x$goodssl" != "xyes"; then
 701             AC_MSG_RESULT(no)
 702             OPENSSL_LIBS=
 703         else
 704             AC_MSG_RESULT(yes)
 705             if test "x$OPENSSL_INCLUDE_DIR" != "x"; then
 706                 OPENSSL_INCLUDE="-I$OPENSSL_INCLUDE_DIR -DOPENSSL_NO_KRB5"
 707             else
 708                 OPENSSL_INCLUDE="-DOPENSSL_NO_KRB5"
 709             fi
 710         fi
 711     fi
 712     CPPFLAGS=$old_CPPFLAGS
 713   fi
 714 fi
 715 AC_SUBST(OPENSSL_INCLUDE)
 716 AC_SUBST(OPENSSL_LIBS)
 717 export OPENSSL_LIBS
 718
 719 dnl Check the pcap includes for the RADIUS sniffer.
 720 if test "x$PCAP_LIBS" = x; then
 721     AC_MSG_NOTICE([skipping test for pcap.h.])
 722 else
 723     AC_CHECK_HEADER(pcap.h,
 724         AC_DEFINE(HAVE_PCAP_H, 1,
 725                 [Define to 1 if you have the <pcap.h> header file.]),
 726         [ PCAP_LIBS=
 727         AC_MSG_WARN([pcap.h not found, silently disabling the RADIUS sniffer.])
 728         ])
 729
 730     AC_CHECK_LIB(pcap, pcap_fopen_offline,
 731         [ AC_DEFINE(HAVE_PCAP_FOPEN_OFFLINE, 1,
 732                 [Define to 1 if you have the function pcap_fopen_offline.])
 733         ])
 734     AC_CHECK_LIB(pcap, pcap_dump_fopen,
 735         [ AC_DEFINE(HAVE_PCAP_DUMP_FOPEN, 1,
 736                 [Define to 1 if you have the function pcap_dump_fopen.])
 737         ])
 738 fi
 739 AC_SUBST(PCAP_LIBS)
 740
 741 dnl #############################################################
 742 dnl #
 743 dnl #  4. Checks for typedefs
 744 dnl #
 745 dnl #############################################################
 746
 747 dnl #
 748 dnl # Ensure that these are defined
 749 dnl #
 750 AC_TYPE_OFF_T
 751 AC_TYPE_PID_T
 752 AC_TYPE_SIZE_T
 753 AC_TYPE_UID_T
 754
 755 dnl check for socklen_t
 756 FR_CHECK_TYPE_INCLUDE([
 757 #ifdef HAVE_SYS_TYPES_H
 758 #include <sys/types.h>
 759 #endif
 760 #ifdef HAVE_SYS_SOCKET_H
 761 #include <sys/socket.h>
 762 #endif
 763 ],socklen_t, int, [socklen_t is generally 'int' on systems which don't use it])
 764
 765 dnl check for uint8_t
 766 FR_CHECK_TYPE_INCLUDE([
 767 #ifdef HAVE_INTTYPES_H
 768 #include <inttypes.h>
 769 #endif
 770 #ifdef HAVE_STDINT_H
 771 #include <stdint.h>
 772 #endif
 773 ],uint8_t, unsigned char, [uint8_t should be the canonical 'octet' for network traffic])
 774
 775 dnl check for uint16_t
 776 FR_CHECK_TYPE_INCLUDE([
 777 #ifdef HAVE_INTTYPES_H
 778 #include <inttypes.h>
 779 #endif
 780 #ifdef HAVE_STDINT_H
 781 #include <stdint.h>
 782 #endif
 783 ],uint16_t, unsigned short, [uint16_t should be the canonical '2 octets' for network traffic])
 784
 785 dnl check for uint32_t
 786 FR_CHECK_TYPE_INCLUDE([
 787 #ifdef HAVE_INTTYPES_H
 788 #include <inttypes.h>
 789 #endif
 790 #ifdef HAVE_STDINT_H
 791 #include <stdint.h>
 792 #endif
 793 ],uint32_t, unsigned int, [uint32_t should be the canonical 'network integer])
 794
 795 AC_CHECK_TYPE(struct in6_addr, AC_DEFINE(HAVE_STRUCT_IN6_ADDR, 1, [IPv6 address structure]), [], [
 796 #ifdef HAVE_NETINET_IN_H
 797 #include <netinet/in.h>
 798 #endif
 799 ])
 800
 801 AC_CHECK_TYPE(struct sockaddr_storage, AC_DEFINE(HAVE_STRUCT_SOCKADDR_STORAGE, 1, [Generic socket addresses]), [], [
 802 #ifdef HAVE_NETINET_IN_H
 803 #include <netinet/in.h>
 804 #endif
 805 #ifdef HAVE_SYS_SOCKET_H
 806 #include <sys/socket.h>
 807 #endif
 808 ])
 809
 810 AC_CHECK_TYPE(struct sockaddr_in6, AC_DEFINE(HAVE_STRUCT_SOCKADDR_IN6, 1, [IPv6 socket addresses]), [], [
 811 #ifdef HAVE_NETINET_IN_H
 812 #include <netinet/in.h>
 813 #endif
 814 ])
 815
 816 AC_CHECK_TYPE(struct addrinfo, AC_DEFINE(HAVE_STRUCT_ADDRINFO, 1, [Generic DNS lookups]), [], [
 817 #ifdef HAVE_SYS_TYPES_H
 818 #include <sys/types.h>
 819 #endif
 820 #ifdef HAVE_SYS_SOCKET_H
 821 #include <sys/socket.h>
 822 #endif
 823 #ifdef HAVE_NETDB_H
 824 #include <netdb.h>
 825 #endif
 826 ])
 827
 828 dnl #############################################################
 829 dnl #
 830 dnl #  5. Checks for structures and functions
 831 dnl #
 832 dnl #############################################################
 833 AC_CHECK_FUNCS( \
 834         getopt_long \
 835         lockf \
 836         strsignal \
 837         sigaction \
 838         sigprocmask \
 839         pthread_sigmask \
 840         snprintf \
 841         vsnprintf \
 842         setsid \
 843         strncasecmp \
 844         strcasecmp \
 845         localtime_r \
 846         ctime_r \
 847         gmtime_r \
 848         strsep \
 849         inet_aton \
 850         inet_pton \
 851         inet_ntop \
 852         setlinebuf \
 853         setvbuf \
 854         getusershell \
 855         initgroups \
 856         getaddrinfo \
 857         getnameinfo \
 858         closefrom \
 859         gettimeofday \
 860         getpeereid \
 861         setuid \
 862         setresuid \
 863         getresuid \
 864         strlcat \
 865         strlcpy
 866 )
 867 RADIUSD_NEED_DECLARATIONS( \
 868         crypt \
 869         strncasecmp \
 870         strcasecmp \
 871         inet_aton \
 872         setlinebuf \
 873         getusershell \
 874         endusershell
 875 )
 876
 877 AC_TYPE_SIGNAL
 878
 879 dnl # check if we have utmpx.h
 880 dnl # if so, check if struct utmpx has entry ut_xtime
 881 dnl # if not, set it to define ut_xtime == ut_tv.tv_sec
 882 if test "x$ac_cv_header_utmpx_h" = "xyes"
 883 then
 884  FR_CHECK_STRUCT_HAS_MEMBER([#include <utmpx.h>], [struct utmpx], ut_xtime)
 885  if test "x$ac_cv_type_struct_utmpx_has_ut_xtime" = "x"
 886  then
 887    AC_DEFINE(ut_xtime,ut_tv.tv_sec, [define to something if you don't have ut_xtime in struct utmpx])
 888  fi
 889 fi
 890
 891 dnl # struct ip_pktinfo
 892 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in_pktinfo], ipi_addr)
 893 if test "x$ac_cv_type_struct_in_pktinfo_has_ipi_addr" = "xyes"
 894 then
 895         AC_DEFINE(HAVE_IP_PKTINFO, [], [define if you have IP_PKTINFO (Linux)])
 896 fi
 897
 898 dnl # struct in6_pktinfo
 899 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in6_pktinfo], ipi6_addr)
 900 if test "x$ac_cv_type_struct_in6_pktinfo_has_ipi6_addr" = "xyes"
 901 then
 902         AC_DEFINE(HAVE_IN6_PKTINFO, [], [define if you have IN6_PKTINFO (Linux)])
 903 fi
 904
 905 dnl #############################################################
 906 dnl #
 907 dnl #  6. Checks for compiler characteristics
 908 dnl #
 909 dnl #############################################################
 910
 911 dnl #
 912 dnl # Ensure that these are defined
 913 dnl #
 914 AC_C_CONST
 915
 916 dnl #
 917 dnl # See if this is OS/2
 918 dnl #
 919 AC_MSG_CHECKING(type of OS)
 920 OS=`uname -s`
 921 AC_MSG_RESULT($OS)
 922 if test "$OS" = "OS/2"; then
 923         LIBPREFIX=
 924 else
 925         LIBPREFIX=lib
 926 fi
 927 AC_SUBST(LIBPREFIX)
 928
 929 AC_MSG_CHECKING(for developer gcc flags)
 930 if test "x$developer" = "xyes" -a "x$GCC" = "xyes"; then
 931   devflags="-g -Wshadow -Wpointer-arith -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -W -Wredundant-decls -Wundef"
 932   CFLAGS="$CFLAGS $devflags"
 933   INSTALLSTRIP=""
 934   AC_MSG_RESULT(yes.  Using $devflags)
 935 else
 936   devflags=""
 937   CFLAGS="$CFLAGS -DNDEBUG"
 938   INSTALLSTRIP=""
 939   AC_MSG_RESULT(no.)
 940 fi
 941
 942 FR_TLS
 943
 944 dnl #############################################################
 945 dnl #
 946 dnl #  7. Checks for library functions
 947 dnl #
 948 dnl #############################################################
 949
 950 old_LIBS="$LIBS"
 951 LIBS="$LIBS $LIBLTDL"
 952 AC_CHECK_FUNC(lt_dladvise_init, AC_DEFINE(HAVE_LT_DLADVISE_INIT, [], [Do we have the lt_dladvise_init function]))
 953 LIBS="$old_LIBS"
 954
 955 dnl Check for libcrypt
 956 dnl We use crypt(3) which may be in libc, or in libcrypt (eg FreeBSD)
 957 AC_CHECK_LIB(crypt, crypt,
 958   CRYPTLIB="-lcrypt"
 959 )
 960 if test "$CRYPTLIB" != ""; then
 961   AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function])
 962 else
 963   AC_CHECK_FUNC(crypt, AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function]))
 964 fi
 965
 966 dnl Check for libcipher
 967 AC_CHECK_LIB(cipher, setkey,
 968    CRYPTLIB="${CRYPTLIB} -lcipher"
 969 )
 970 AC_SUBST(CRYPTLIB)
 971
 972 dnl Check the style of gethostbyaddr, in order of preference
 973 dnl GNU (_r eight args)
 974 AC_DEFINE(GNUSTYLE, [1], [GNU-Style get*byaddr_r])
 975 dnl SYSV (_r six args)
 976 AC_DEFINE(SYSVSTYLE, [2], [SYSV-Style get*byaddr_r])
 977 dnl BSD (three args, may not be thread safe)
 978 AC_DEFINE(BSDSTYLE, [3], [BSD-Style get*byaddr_r])
 979 dnl Tru64 has BSD version, but it is thread safe
 980 dnl     http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1739____.HTM
 981 dnl We need #stdio.h to define NULL on FreeBSD (at least)
 982 gethostbyaddrrstyle=""
 983 AC_MSG_CHECKING([gethostbyaddr_r() syntax])
 984 case "$host" in
 985 *-freebsd*)
 986 dnl With FreeBSD, check if there's a prototype for gethostbyaddr_r.
 987 dnl Some versions (FreeBSD 5.1?) have a symbol but no prototype - so we
 988 dnl override this test to BSDSTYLE. FreeBSD 6.2 and up have proper GNU
 989 dnl style support.
 990         AC_CHECK_DECLS([gethostbyaddr_r], [], [
 991                 AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE,
 992                         [style of gethostbyaddr_r functions ])
 993                 gethostbyaddrrstyle=BSD
 994                 AC_MSG_WARN([FreeBSD overridden to BSD-style])
 995         ], [
 996 #ifdef HAVE_NETDB_H
 997 #include <netdb.h>
 998 #endif
 999 ])
1000         ;;
1001 esac
1002 if test "x$gethostbyaddrrstyle" = "x"; then
1003         AC_TRY_LINK([
1004 #include <stdio.h>
1005 #include <netdb.h>
1006 ], [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL, NULL) ], [
1007         AC_DEFINE(GETHOSTBYADDRRSTYLE, GNUSTYLE, [style of gethostbyaddr_r functions ])
1008         gethostbyaddrrstyle=GNU
1009 ])
1010 fi
1011 if test "x$gethostbyaddrrstyle" = "x"; then
1012         AC_TRY_LINK([
1013 #include <stdio.h>
1014 #include <netdb.h>
1015 ], [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL) ] , [
1016                 AC_DEFINE(GETHOSTBYADDRRSTYLE, SYSVSTYLE, [style of gethostbyaddr_r functions ])
1017                 gethostbyaddrrstyle=SYSV
1018         ])
1019 fi
1020 if test "x$gethostbyaddrrstyle" = "x"; then
1021         AC_TRY_LINK([
1022 #include <stdio.h>
1023 #include <netdb.h>
1024 ], [ gethostbyaddr(NULL, 0, 0)  ], [
1025                 AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE, [style of gethostbyaddr_r functions ])
1026                 gethostbyaddrrstyle=BSD
1027         ])
1028 fi
1029
1030 if test "x$gethostbyaddrrstyle" = "x"; then
1031         AC_MSG_RESULT([none!  It must not exist, here.])
1032 else
1033         AC_MSG_RESULT([${gethostbyaddrrstyle}-style])
1034 fi
1035
1036 if test "x$gethostbyaddrrstyle" = "xBSD"; then
1037         AC_MSG_WARN([ ****** BSD-style gethostbyaddr might NOT be thread-safe! ****** ])
1038 fi
1039
1040 dnl Check the style of gethostbyname, in order of preference
1041 dnl GNU (_r seven args)
1042 dnl SYSV (_r five args)
1043 dnl BSD (two args, may not be thread safe)
1044 dnl Tru64 has BSD version, but it _is_ thread safe
1045 dnl     http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1946____.HTM
1046 dnl We need #stdio.h to define NULL on FreeBSD (at least)
1047 gethostbynamerstyle=""
1048 AC_MSG_CHECKING([gethostbyname_r() syntax])
1049 AC_TRY_LINK([
1050 #include <stdio.h>
1051 #include <netdb.h>
1052 ], [ gethostbyname_r(NULL, NULL, NULL, 0, NULL, NULL) ], [
1053         AC_DEFINE(GETHOSTBYNAMERSTYLE, GNUSTYLE, [style of gethostbyname_r functions ])
1054         gethostbynamerstyle=GNU
1055 ])
1056 if test "x$gethostbynamerstyle" = "x"; then
1057         AC_TRY_LINK([
1058 #include <stdio.h>
1059 #include <netdb.h>
1060 ], [ gethostbyname_r(NULL, NULL, NULL, 0, NULL) ] , [
1061                 AC_DEFINE(GETHOSTBYNAMERSTYLE, SYSVSTYLE, [style of gethostbyname_r functions ])
1062                 gethostbynamerstyle=SYSV
1063         ])
1064 fi
1065 if test "x$gethostbynamerstyle" = "x"; then
1066         AC_TRY_LINK([
1067 #include <stdio.h>
1068 #include <netdb.h>
1069 ], [ gethostbyname(NULL)  ], [
1070                 AC_DEFINE(GETHOSTBYNAMERSTYLE, BSDSTYLE, [style of gethostbyname_r functions ])
1071                 gethostbynamerstyle=BSD
1072         ])
1073 fi
1074
1075 if test "x$gethostbynamerstyle" = "x"; then
1076         AC_MSG_RESULT([none!  It must not exist, here.])
1077 else
1078         AC_MSG_RESULT([${gethostbynamerstyle}-style])
1079 fi
1080
1081 if test "x$gethostbynamerstyle" = "xBSD"; then
1082         AC_MSG_WARN([ ****** BSD-style gethostbyname might NOT be thread-safe! ****** ])
1083 fi
1084
1085 dnl check for non-posix solaris ctime_r (extra buflen int arg)
1086 AC_DEFINE(POSIXSTYLE, [1], [Posix-Style ctime_r])
1087 AC_DEFINE(SOLARISSTYLE, [2], [Solaris-Style ctime_r])
1088 ctimerstyle=""
1089 AC_MSG_CHECKING([ctime_r() syntax])
1090 AC_TRY_LINK([
1091 #include <time.h>
1092 ], [ ctime_r(NULL, NULL, 0) ], [
1093         AC_DEFINE(CTIMERSTYLE, SOLARISSTYLE, [style of ctime_r function])
1094         ctimerstyle="SOLARIS"
1095 ])
1096 if test "x$ctimerstyle" = "x"; then
1097         AC_TRY_LINK([
1098 #include <time.h>
1099 ], [ ctime_r(NULL, NULL) ], [
1100                 AC_DEFINE(CTIMERSTYLE, POSIXSTYLE, [style of ctime_r function])
1101                 ctimerstyle="POSIX"
1102         ])
1103 fi
1104
1105 if test "x$ctimerstyle" = "x"; then
1106         AC_MSG_RESULT([none!  It must not exist, here.])
1107 else
1108         AC_MSG_RESULT([${ctimerstyle}-style])
1109 fi
1110
1111 AC_SUBST(HOSTINFO, $host)
1112
1113 dnl #############################################################
1114 dnl #
1115 dnl #  8. Checks for system services
1116 dnl #
1117 dnl #############################################################
1118
1119 dnl #
1120 dnl # Figure out where libtool is located,
1121 dnl #
1122 top_builddir=`pwd`
1123 export top_builddir
1124 AC_MSG_RESULT([top_builddir=$top_builddir])
1125 dnl # AC_SUBST(top_builddir)
1126 AC_SUBST(LIBLTDL)
1127 AC_SUBST(INCLTDL)
1128
1129 dnl import libtool stuff
1130
1131 dnl #############################################################
1132 dnl #
1133 dnl #  Configure in any module directories.
1134 dnl #
1135 dnl #############################################################
1136
1137 mysubdirs="$LIBLTDLPATH"
1138 if test "x$EXPERIMENTAL" = "xyes"; then
1139   bar=`ls -1 "${srcdir}"/src/modules/rlm_*/configure | sed 's%/configure%%'`
1140   dnl # get rid of LF's.
1141   mysubdirs=`echo $mysubdirs $bar`
1142 else
1143   dnl #
1144   dnl # Find 'configure' in ONLY the stable modules
1145   dnl #
1146   for bar in `cat "${srcdir}"/src/modules/stable`; do
1147     if test -f "${srcdir}"/src/modules/$bar/configure; then
1148       mysubdirs="$mysubdirs src/modules/$bar"
1149     fi
1150   done
1151 fi
1152
1153 dnl ############################################################
1154 dnl # make modules by list
1155 dnl #############################################################
1156 if test "x$EXPERIMENTAL" = "xyes"; then
1157   for foo in `ls -1 "${srcdir}"/src/modules | grep rlm_`; do
1158     MODULES="$MODULES $foo"
1159   done
1160 else
1161    dnl #
1162    dnl # make ONLY the stable modules
1163    dnl #
1164    for foo in `cat "${srcdir}"/src/modules/stable`; do
1165     MODULES="$MODULES $foo"
1166    done
1167 fi
1168
1169 dnl #
1170 dnl #  Don't change the variable name here.  Autoconf goes bonkers
1171 dnl #  if you do.
1172 dnl #
1173 AC_CONFIG_SUBDIRS($LTDL_SUBDIRS $mysubdirs)
1174 AC_SUBST(MODULES)
1175
1176 dnl #############################################################
1177 dnl #
1178 dnl #  And finally, output the results.
1179 dnl #
1180 dnl #############################################################
1181
1182 AC_CONFIG_COMMANDS([stamp-h], [echo timestamp > src/include/stamp-h])
1183 AC_CONFIG_COMMANDS([build-radpaths-h], [(cd ./src/include && /bin/sh ./build-radpaths-h)])
1184 AC_CONFIG_COMMANDS([main-chmod], [(cd ./src/main   && chmod +x checkrad.pl radlast radtest)])
1185 AC_CONFIG_COMMANDS([scripts-chmod], [(cd ./scripts    && chmod +x rc.radiusd radwatch radiusd.cron.daily radiusd.cron.monthly cryptpasswd)])
1186
1187 dnl #
1188 dnl #  Substitute whatever libraries we found to be necessary
1189 dnl #
1190 AC_SUBST(LIBS)
1191 AC_SUBST(INSTALLSTRIP)
1192
1193 USE_SHARED_LIBS=$enable_shared
1194 AC_SUBST(USE_SHARED_LIBS)
1195 USE_STATIC_LIBS=$enable_static
1196 AC_SUBST(USE_STATIC_LIBS)
1197 AC_SUBST(STATIC_MODULES)
1198 AC_SUBST(RADIUSD_MAJOR_VERSION)
1199 AC_SUBST(RADIUSD_MINOR_VERSION)
1200 AC_SUBST(RADIUSD_VERSION)
1201
1202 AC_OUTPUT(\
1203         ./Make.inc \
1204         ./src/include/build-radpaths-h \
1205         ./src/main/Makefile \
1206         ./src/main/checkrad.pl \
1207         ./src/main/radlast \
1208         ./src/main/radtest \
1209         ./scripts/rc.radiusd \
1210         ./scripts/radwatch \
1211         ./scripts/radiusd.cron.daily \
1212         ./scripts/radiusd.cron.monthly \
1213         ./scripts/cryptpasswd \
1214         ./raddb/dictionary \
1215         ./raddb/radrelay.conf \
1216         ./raddb/radiusd.conf
1217 )