configure.in

   1 dnl #############################################################
   2 dnl #
   3 dnl #  For information about autoconf, see:
   4 dnl #
   5 dnl #  http://www.gnu.org/software/autoconf/
   6 dnl #
   7 dnl #  The recommended order is:
   8 dnl #
   9 dnl #  AC_INIT(file)
  10 dnl #  0. checks for compiler, libtool, and command line options
  11 dnl #  1. checks for programs
  12 dnl #  2. checks for libraries
  13 dnl #  3. checks for header files
  14 dnl #  4. checks for typedefs
  15 dnl #  5. checks for structures and functions
  16 dnl #  6. checks for compiler characteristics
  17 dnl #  7. checks for library functions
  18 dnl #  8. checks for system services
  19 dnl #  AC_OUTPUT([file...])
  20 dnl #
  21 dnl #############################################################
  22
  23 AC_PREREQ([2.59])
  24 export CFLAGS LIBS LDFLAGS CPPFLAGS
  25 AC_INIT(src/main/radiusd.c)
  26 AC_CONFIG_HEADER(src/include/autoconf.h)
  27 AC_REVISION($Revision$)dnl
  28
  29 dnl # The version of the software
  30 RADIUSD_VERSION=`cat VERSION`
  31 RADIUSD_MAJOR_VERSION=`cat VERSION | sed 's/\..*//'`
  32 RADIUSD_MINOR_VERSION=`cat VERSION | sed 's/^2\.//'`
  33 PACKAGE=freeradius
  34
  35 dnl #############################################################
  36 dnl #
  37 dnl #  0. Checks for compiler, libtool, and command line options.
  38 dnl #
  39 dnl #############################################################
  40
  41 dnl Check for GNU cc
  42 AC_PROG_CC
  43 AC_PROG_CXX
  44
  45 dnl #
  46 dnl # check for AIX, to allow us to use some BSD functions
  47 dnl # must be before macros that call the compiler.
  48 dnl #
  49 AC_AIX
  50
  51 AC_PROG_GCC_TRADITIONAL
  52 AC_PROG_CC_SUNPRO
  53 AC_PROG_RANLIB
  54
  55 dnl #
  56 dnl # Set Default CFLAGS
  57 dnl #
  58 if test "x$GCC" = "xyes"; then
  59     CFLAGS="$CFLAGS -Wall -D_GNU_SOURCE"
  60 fi
  61
  62 dnl Compile in large (2G+) file support.
  63 AC_SYS_LARGEFILE
  64
  65 dnl # check for system bytesex
  66 dnl # AC_DEFINES WORDS_BIGENDIAN
  67 AC_C_BIGENDIAN
  68
  69 dnl Find GNU Make.
  70 AC_CHECK_PROG(GMAKE, gmake, yes, no)
  71 if test $GMAKE = no; then
  72   AC_PATH_PROG(MAKE, make, /usr/local/bin/make)
  73 else
  74   AC_PATH_PROG(MAKE, gmake, /usr/local/gnu/bin/make)
  75 fi
  76 makever=`$ac_cv_path_MAKE --version 2>&1 | grep "GNU Make"`
  77 if test -z "$makever"; then
  78   AC_MSG_ERROR(GNU Make is not installed.  Please download and install it
  79                 from ftp://prep.ai.mit.edu/pub/gnu/make/ before continuing.)
  80 fi
  81
  82 AC_ARG_WITH(system-libltdl,
  83 [  --with-system-libltdl   Use the libltdl installed in your system (default=use our own)],
  84 [
  85 LIBLTDL="-lltdl"
  86 INCLTDL=
  87 LTDL_SUBDIRS=
  88 enable_ltdl_install=no
  89 ],
  90 [
  91 dnl If libltdl isn't installable, set it to be installable.
  92 [test x"$enable_ltdl_install" = x && enable_ltdl_install=yes]
  93 AC_LIBLTDL_INSTALLABLE
  94
  95 dnl tell Makefile to build ltdl if needed
  96 if test x"$enable_ltdl_install" = x"yes"; then
  97   LTDL_SUBDIRS=libltdl
  98 fi
  99 ])
 100 AC_SUBST(LTDL_SUBDIRS)
 101
 102 dnl use system-wide libtool, if it exists
 103 AC_ARG_WITH(system-libtool,
 104 [  --with-system-libtool   Use the libtool installed in your system (default=use our own)],
 105 [ AC_PATH_PROG(LIBTOOL, libtool,,$PATH:/usr/local/bin) AC_LIBTOOL_DLOPEN
 106  AC_PROG_LIBTOOL],
 107 [
 108   LIBTOOL="`pwd`/libtool"
 109   AC_SUBST(LIBTOOL)
 110   dnl ensure that we're looking for dlopen
 111   AC_LIBTOOL_DLOPEN
 112
 113   dnl Figure out how to build shared libraries
 114   AC_PROG_LIBTOOL
 115 ])
 116
 117
 118 dnl Put this in later, when all distributed modules use autoconf.
 119 dnl AC_ARG_WITH(disablemodulefoo,
 120 dnl [  --without-rlm_foo       Disables module compilation.  Module list:]
 121 dnl esyscmd([find src/modules -type d -name rlm_\* -print |\
 122 dnl     sed -e 's%src/modules/.*/% (sub)- %; s%.*/%- %' |\
 123 dnl     awk '{print "                            "$0}']))
 124
 125 AC_ARG_ENABLE(strict-dependencies,
 126 [  --enable-strict-dependencies  Fail configure on lack of module dependancy.])
 127
 128 dnl extra argument: --with-docdir
 129 docdir='${datadir}/doc/freeradius'
 130 AC_MSG_CHECKING(docdir)
 131 AC_ARG_WITH(docdir,
 132 [  --with-docdir=DIR       Directory for documentation [DATADIR/doc/freeradius] ],
 133 [ case "$withval" in
 134     no)
 135         docdir=no
 136         ;;
 137     yes)
 138         ;;
 139     [[\\/$]]* | ?:[[\\/]]* )
 140         docdir="$withval"
 141         ;;
 142     *)
 143         AC_MSG_ERROR([expected an absolute directory name for --with-docdir: $withval])
 144         ;;
 145   esac ]
 146 )
 147 AC_SUBST(docdir)
 148 AC_MSG_RESULT($docdir)
 149 if test "x$docdir" = xno; then
 150         AC_MSG_WARN(Documentation files will NOT be installed.)
 151 fi
 152
 153 dnl extra argument: --with-logdir
 154 logdir='${localstatedir}/log/radius'
 155 AC_MSG_CHECKING(logdir)
 156 AC_ARG_WITH(logdir,
 157 [  --with-logdir=DIR       Directory for logfiles [LOCALSTATEDIR/log/radius] ],
 158 [ case "$withval" in
 159     no)
 160         AC_MSG_ERROR(Need logdir)
 161         ;;
 162     yes)
 163         ;;
 164     [[\\/$]]* | ?:[[\\/]]* )
 165         logdir="$withval"
 166         ;;
 167     *)
 168         AC_MSG_ERROR([expected an absolute directory name for --with-logdir: $withval])
 169         ;;
 170   esac ]
 171 )
 172 AC_SUBST(logdir)
 173 AC_MSG_RESULT($logdir)
 174
 175 dnl extra argument: --with-radacctdir
 176 radacctdir='${logdir}/radacct'
 177 AC_MSG_CHECKING(radacctdir)
 178 AC_ARG_WITH(radacctdir,
 179 [  --with-radacctdir=DIR   Directory for detail files [LOGDIR/radacct] ],
 180 [ case "$withval" in
 181     no)
 182         AC_MSG_ERROR(Need radacctdir)
 183         ;;
 184     yes)
 185         ;;
 186     [[\\/$]]* | ?:[[\\/]]* )
 187         radacctdir="$withval"
 188         ;;
 189     *)
 190         AC_MSG_ERROR([expected an absolute directory name for --with-radacctdir: $withval])
 191         ;;
 192   esac ]
 193 )
 194 AC_SUBST(radacctdir)
 195 AC_MSG_RESULT($radacctdir)
 196
 197 dnl extra argument: --with-raddbdir
 198 raddbdir='${sysconfdir}/raddb'
 199 AC_MSG_CHECKING(raddbdir)
 200 AC_ARG_WITH(raddbdir,
 201 [  --with-raddbdir=DIR     Directory for config files [SYSCONFDIR/raddb] ],
 202 [ case "$withval" in
 203     no)
 204         AC_MSG_ERROR(Need raddbdir)
 205         ;;
 206     yes)
 207         ;;
 208     [[\\/$]]* | ?:[[\\/]]* )
 209         raddbdir="$withval"
 210         ;;
 211     *)
 212         AC_MSG_ERROR([expected an absolute directory name for --with-raddbdir: $withval])
 213         ;;
 214   esac ]
 215 )
 216 AC_SUBST(raddbdir)
 217 AC_MSG_RESULT($raddbdir)
 218
 219 dnl extra argument: --with-ascend-binary
 220 ASCEND_BINARY=yes
 221 AC_ARG_WITH(ascend-binary,
 222 [  --with-ascend-binary    Include support for Ascend binary filter attributes (default=yes)],
 223 [ case "$withval" in
 224     yes)
 225         ;;
 226     *)
 227         ASCEND_BINARY=""
 228   esac ]
 229 )
 230 if test "X$ASCEND_BINARY" = "Xyes"; then
 231   AC_DEFINE(ASCEND_BINARY, [], [Include support for Ascend binary filter attributes])
 232 fi
 233
 234 dnl extra argument: --with-threads
 235 WITH_THREADS=yes
 236 AC_ARG_WITH(threads,
 237 [  --with-threads          Use threads, if available.  (default=yes) ],
 238 [ case "$withval" in
 239     yes)
 240         ;;
 241     *)
 242         WITH_THREADS=""
 243   esac ]
 244 )
 245
 246 dnl extra argument: --with-vmps
 247 WITH_VMPS=yes
 248 AC_ARG_WITH(vmps,
 249 [  --with-vmps             Compile in VMPS support. (default=yes)],
 250 [ case "$withval" in
 251     yes)
 252         ;;
 253     *)
 254         WITH_VMPS=no
 255   esac ]
 256 )
 257 if test "x$WITH_VMPS" = "xyes"; then
 258         AC_DEFINE(WITH_VMPS, [1], [define if you want VMPS support])
 259 fi
 260
 261 dnl extra argument: --with-dhcp
 262 AC_ARG_WITH(dhcp,
 263 [  --with-dhcp             Compile in DHCP support. (default=no)],
 264 [ case "$withval" in
 265     yes)
 266         AC_DEFINE(WITH_DHCP, [1], [Include experimental support for DHCP])
 267         ;;
 268     *)
 269         ;;
 270   esac ]
 271 )
 272
 273
 274 dnl #
 275 dnl #  Allow the user to specify a list of modules to be linked
 276 dnl #  statically to the server.
 277 dnl #
 278 STATIC_MODULES=
 279 AC_ARG_WITH(static_modules,
 280 [  --with-static-modules=QUOTED-MODULE-LIST],[
 281   for i in $withval; do
 282     STATIC_MODULES="$STATIC_MODULES -dlpreopen ../modules/rlm_$i/rlm_$i.la"
 283   done
 284 ])
 285
 286 MODULES=
 287 AC_ARG_WITH(modules,
 288 [ --with-modules=QUOTED-MODULE-LIST],[
 289  for i in $withval; do
 290    MODULES="$MODULES $i"
 291  done
 292 ])
 293
 294 dnl #
 295 dnl #  Enable developer C compiler warnings
 296 dnl #
 297 AC_ARG_ENABLE(developer,
 298 [  --enable-developer               Enables features of interest to developers.],
 299 [ case "$enableval" in
 300     no)
 301         developer=no
 302         ;;
 303     *)
 304         developer=yes
 305   esac ]
 306 )
 307
 308 if test "x$developer" != "xno" -a -d $srcdir/CVS; then
 309   dnl turn on the developer flag when taken from a CVS checkout (not a release)
 310   developer="yes"
 311 fi
 312
 313 if test "x$developer" != "xno" -a -d $srcdir/.git; then
 314   dnl turn on the developer flag when taken from a git checkout (not a release)
 315   developer="yes"
 316 fi
 317
 318 dnl extra argument: --with-experimental-modules
 319 EXPERIMENTAL=
 320 AC_ARG_WITH(experimental-modules,
 321 [  --with-experimental-modules      Use experimental and unstable modules. (default=no) ],
 322 [ case "$withval" in
 323     yes)
 324         EXPERIMENTAL=yes
 325         ;;
 326     *)
 327   esac ]
 328 )
 329
 330 dnl extra argument: --with-openssl
 331 WITH_OPENSSL=yes
 332 AC_ARG_WITH(openssl,
 333 [  --with-openssl                   Use OpenSSL. (default=yes)],
 334 [ case "$withval" in
 335     no)
 336         WITH_OPENSSL=no
 337         ;;
 338     *)
 339         WITH_OPENSSL=yes
 340         ;;
 341   esac ]
 342 )
 343
 344 dnl #
 345 dnl # extra argument: --with-openssl-includes=dir
 346 dnl #
 347 OPENSSL_INCLUDE_DIR=
 348 AC_ARG_WITH(openssl-includes,
 349 [  --with-openssl-includes=DIR      Directory to look for OpenSSL include files],
 350 [ case "$withval" in
 351     *) OPENSSL_INCLUDE_DIR="$withval"
 352         ;;
 353   esac ]
 354 )
 355
 356 dnl #
 357 dnl # extra argument: --with-openssl-libraries=dir
 358 dnl #
 359 OPENSSL_LIB_DIR=
 360 AC_ARG_WITH(openssl-libraries,
 361 [  --with-openssl-libraries=DIR     Directory to look for OpenSSL library files],
 362 [ case "$withval" in
 363     *) OPENSSL_LIB_DIR="$withval"
 364         ;;
 365   esac ]
 366 )
 367
 368 dnl #
 369 dnl #  These next two arguments don't actually do anything.  They're
 370 dnl #  place holders so that the top-level configure script can tell
 371 dnl #  the user how to configure lower-level modules
 372 dnl #
 373
 374 dnl #
 375 dnl # extra argument: --with-rlm-FOO-lib-dir
 376 dnl #
 377 AC_ARG_WITH(rlm-FOO-lib-dir,
 378 [  --with-rlm-FOO-lib-dir=DIR       Directory to look for library files used by module FOO],
 379 [ case "$withval" in
 380     *)
 381         ;;
 382   esac ]
 383 )
 384
 385 dnl #
 386 dnl # extra argument: --with-rlm-FOO-include-dir
 387 dnl #
 388 AC_ARG_WITH(rlm-FOO-include-dir,
 389 [  --with-rlm-FOO-include-dir=DIR   Directory to look for include files used by module FOO],
 390 [ case "$withval" in
 391     *)
 392         ;;
 393   esac ]
 394 )
 395
 396 dnl See what include-style is used by the make program.
 397 dnl AC_MSG_CHECKING(include style for make)
 398 dnl echo "include /dev/null" > testmake.$$
 399 dnl echo "all:" >> testmake.$$
 400 dnl make -f testmake.$$ >/dev/null 2>&1
 401 dnl if test $? = 0
 402 dnl then
 403 dnl     INCLUDE=include
 404 dnl     IQUOTE=
 405 dnl else
 406 dnl     INCLUDE=.include
 407 dnl     IQUOTE='"'
 408 dnl fi
 409 dnl rm -f testmake.$$
 410 dnl AC_MSG_RESULT(" $INCLUDE")
 411 dnl AC_SUBST(INCLUDE)
 412 dnl AC_SUBST(IQUOTE)
 413
 414 dnl extra argument: --with-udpfromto
 415 WITH_UDPFROMTO=no
 416 AC_ARG_WITH(udpfromto,
 417 [  --with-udpfromto        Compile in UDPFROMTO support. (default=no)],
 418 [ case "$withval" in
 419     yes)
 420         WITH_UDPFROMTO=yes
 421         ;;
 422     *)
 423         WITH_UDPFROMTO=no
 424   esac ]
 425 )
 426
 427 if test "x$WITH_UDPFROMTO" = "xyes"; then
 428         AC_DEFINE(WITH_UDPFROMTO, [], [define if you want udpfromto])
 429 fi
 430
 431 dnl #############################################################
 432 dnl #
 433 dnl #  1. Checks for programs
 434 dnl #
 435 dnl #############################################################
 436
 437 CHECKRAD=checkrad.pl
 438 AC_PATH_PROG(PERL, perl, /usr/local/bin/perl)
 439 if test "x$ac_cv_path_PERL" = "x"; then
 440   AC_MSG_WARN(perl not found - Simultaneous-Use and checkrad.pl may not work)
 441 fi
 442 AC_PATH_PROG(SNMPGET, snmpget)
 443 if test "x$ac_cv_path_SNMPGET" = "x"; then
 444   AC_MSG_WARN(snmpget not found - Simultaneous-Use and checkrad.pl may not work)
 445 fi
 446
 447 AC_PATH_PROG(SNMPWALK, snmpwalk)
 448 if test "x$ac_cv_path_SNMPWALK" = "x"; then
 449   AC_MSG_WARN(snmpwalk not found - Simultaneous-Use and checkrad.pl may not work)
 450 fi
 451
 452 AC_PATH_PROG(RUSERS, rusers, /usr/bin/rusers)
 453
 454 dnl FIXME This is truly gross.
 455 missing_dir=`cd $ac_aux_dir && pwd`
 456 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
 457 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
 458 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
 459
 460 AC_PATH_PROG(LOCATE,locate)
 461 AC_PATH_PROG(DIRNAME,dirname)
 462 AC_PATH_PROG(GREP,grep)
 463
 464 dnl #############################################################
 465 dnl #
 466 dnl #  2. Checks for libraries
 467 dnl #
 468 dnl #############################################################
 469
 470 dnl If using pthreads, check for -lpthread (posix) or -lc_r (*BSD)
 471 old_CFLAGS=$CFLAGS
 472 if test "x$WITH_THREADS" = "xyes"; then
 473   if test $ac_cv_prog_suncc = "yes"; then
 474     CFLAGS="$CFLAGS -mt"
 475   fi
 476
 477   AC_CHECK_HEADERS(pthread.h, [], [ WITH_THREADS="no" ])
 478
 479 dnl #
 480 dnl # pthread stuff is usually in -lpthread
 481 dnl # or in -lc_r, on *BSD
 482 dnl #
 483 dnl # On Some systems, we need extra pre-processor flags, to get them to
 484 dnl # to do the threading properly.
 485 dnl #
 486   AC_CHECK_LIB(pthread, pthread_create,
 487                 [ CFLAGS="$CFLAGS -D_REENTRANT -D_POSIX_PTHREAD_SEMANTICS"
 488                   LIBS="$LIBS -lpthread" ],
 489                 AC_CHECK_LIB(c_r, pthread_create,
 490                             [ CFLAGS="$CFLAGS -pthread -D_THREAD_SAFE" ],
 491                             [ WITH_THREADS="no" ]
 492                             )
 493                 )
 494 fi
 495
 496 dnl #
 497 dnl # If we have NO pthread libraries, remove any knowledge of threads.
 498 dnl #
 499 if test "x$WITH_THREADS" != "xyes"; then
 500   CFLAGS=$old_CFLAGS
 501   ac_cv_header_pthread_h="no"
 502   WITH_THREADS=no
 503 else
 504   dnl #
 505   dnl #  We need sem_init() and friends, as they're the friendliest
 506   dnl #  semaphore functions for threading.
 507   dnl #
 508   dnl # HP/UX requires linking with librt, too, to get the sem_* symbols.
 509   dnl # Some systems have them in -lsem
 510   dnl # Solaris has them in -lposix4
 511   dnl # NetBSD has them in -lsemaphore
 512
 513   AC_SEARCH_LIBS(sem_init, pthread sem posix4 rt semaphore,
 514         [],
 515         [AC_MSG_ERROR(-lsem not found.  You may want to download it from ftp://ftp.to.gd-es.com/pub/BSDI/libsem.tar.bz2 or ftp://ftp.freeradius.org/pub/radius/contrib/libsem.tar.gz)]
 516    )
 517 fi
 518
 519 dnl Check if we need -lsocket
 520 AC_CHECK_LIB(socket, getsockname)
 521
 522 dnl Check for -lresolv
 523 dnl This library may be needed later.
 524 AC_CHECK_LIB(resolv, inet_aton)
 525
 526 dnl Check if we need -lnsl. Usually if we want to
 527 dnl link against -lsocket we need to include -lnsl as well.
 528 AC_CHECK_LIB(nsl, inet_ntoa)
 529
 530 dnl Check for OpenSSL libraries.
 531 OPENSSL_LIBS=
 532 if test "x$WITH_OPENSSL" = xyes; then
 533   old_LIBS=$LIBS
 534   old_LDFLAGS="$LDFLAGS"
 535   if test "x$OPENSSL_LIB_DIR" != "x"; then
 536     LDFLAGS="$LDFLAGS -L$OPENSSL_LIB_DIR"
 537   fi
 538   AC_CHECK_LIB(crypto, DH_new,
 539     [
 540         LIBS="-lcrypto $LIBS"
 541         AC_DEFINE(HAVE_LIBCRYPTO, 1,
 542             [Define to 1 if you have the `crypto' library (-lcrypto).])
 543         AC_CHECK_LIB(ssl, SSL_new,
 544             [
 545                 AC_DEFINE(HAVE_LIBSSL, 1,
 546                     [Define to 1 if you have the `ssl' library (-lssl).])
 547                 if test "x$OPENSSL_LIB_DIR" != "x"; then
 548                     OPENSSL_LIBS="-L$OPENSSL_LIB_DIR"
 549                 fi
 550                 OPENSSL_LIBS="$OPENSSL_LIBS -lcrypto -lssl -lcrypto"
 551             ], [])
 552     ], [])
 553   LIBS=$old_LIBS
 554   LDFLAGS="$old_LDFLAGS"
 555 fi
 556
 557 AC_CHECK_LIB(ws2_32, htonl)
 558
 559 dnl Check the pcap library for the RADIUS sniffer.
 560 PCAP_LIBS=
 561 AC_CHECK_LIB(pcap, pcap_open_live,
 562         [ PCAP_LIBS="-lpcap"
 563         AC_DEFINE(HAVE_LIBPCAP, 1,
 564                 [Define to 1 if you have the `pcap' library (-lpcap).])
 565         ],
 566         [ AC_MSG_WARN([pcap library not found, silently disabling the RADIUS sniffer.]) ])
 567
 568 AC_LIB_READLINE
 569
 570 dnl #############################################################
 571 dnl #
 572 dnl #  3. Checks for header files
 573 dnl #
 574 dnl #############################################################
 575
 576 dnl #
 577 dnl # Interix requires us to set -D_ALL_SOURCE, otherwise
 578 dnl # getopt will be #included, but won't link.  <sigh>
 579 dnl #
 580 dnl #
 581 case "$host" in
 582 *-interix*)
 583         CFLAGS="$CFLAGS -D_ALL_SOURCE"
 584         ;;
 585 *-darwin*)
 586         CFLAGS="$CFLAGS -DDARWIN"
 587         LIBS="-framework DirectoryService $LIBS"
 588         ;;
 589 esac
 590
 591 AC_HEADER_DIRENT
 592 AC_HEADER_STDC
 593 AC_HEADER_TIME
 594 AC_HEADER_SYS_WAIT
 595
 596 AC_CHECK_HEADERS( \
 597         unistd.h \
 598         crypt.h \
 599         errno.h \
 600         resource.h \
 601         sys/resource.h \
 602         getopt.h \
 603         malloc.h \
 604         utmp.h \
 605         utmpx.h \
 606         signal.h \
 607         sys/select.h \
 608         syslog.h \
 609         inttypes.h \
 610         stdint.h \
 611         stdio.h \
 612         netdb.h \
 613         semaphore.h \
 614         arpa/inet.h \
 615         netinet/in.h \
 616         sys/types.h \
 617         sys/socket.h \
 618         winsock.h \
 619         sys/time.h \
 620         sys/wait.h \
 621         sys/security.h \
 622         fcntl.h \
 623         sys/fcntl.h \
 624         sys/prctl.h \
 625         sys/un.h \
 626         glob.h \
 627         prot.h \
 628         pwd.h \
 629         grp.h \
 630         stddef.h \
 631         fnmatch.h \
 632         sia.h \
 633         siad.h
 634 )
 635
 636 dnl FreeBSD requires sys/socket.h before net/if.h
 637 AC_CHECK_HEADERS(net/if.h, [], [],
 638 [#ifdef HAVE_SYS_SOCKET_H
 639 # include <sys/socket.h>
 640 # endif
 641 ])
 642
 643 REGEX=no
 644 AC_CHECK_HEADER(regex.h, AC_DEFINE(HAVE_REGEX_H, [], [define this if we have the <regex.h> header file]))
 645 if test "x$ac_cv_header_regex_h" = "xyes"; then
 646   REGEX_EXTENDED=no
 647   REGEX=yes
 648   AC_EGREP_CPP(yes,
 649     [#include <regex.h>
 650      #ifdef REG_EXTENDED
 651        yes
 652      #endif
 653      ], [AC_DEFINE(HAVE_REG_EXTENDED, [], [define this if we have REG_EXTENDED (from <regex.h>)]) REGEX_EXTENDED=yes])
 654 fi
 655 AC_SUBST(REGEX)
 656 AC_SUBST(REGEX_EXTENDED)
 657
 658 dnl #
 659 dnl #  other checks which require headers
 660 dnl #
 661 if test "x$ac_cv_header_sys_security_h" = "xyes" && test "x$ac_cv_header_prot_h" = "xyes"
 662 then
 663   AC_DEFINE(OSFC2, [], [define if you have OSFC2 authentication])
 664 fi
 665
 666 if test "x$ac_cv_header_sia_h" = "xyes" && test "x$ac_cv_header_siad_h" = "xyes"
 667 then
 668   AC_DEFINE(OSFSIA, [], [define if you have OSFSIA authentication])
 669 fi
 670
 671 dnl Check for OpenSSL includes.
 672 OPENSSL_INCLUDE="-DNO_OPENSSL"
 673 if test "x$WITH_OPENSSL" = xyes; then
 674   if test "x$OPENSSL_LIBS" = "x"; then
 675     AC_MSG_NOTICE([skipping test for openssl/ssl.h])
 676   else
 677     old_CPPFLAGS=$CPPFLAGS
 678     if test "x$OPENSSL_INCLUDE_DIR" != "x"; then
 679         CPPFLAGS="$CPPFLAGS -I$OPENSSL_INCLUDE_DIR"
 680     fi
 681     dnl # stupid RedHat shit
 682     CPPFLAGS="$CPPFLAGS -DOPENSSL_NO_KRB5"
 683     AC_CHECK_HEADERS( \
 684         openssl/ssl.h \
 685         openssl/crypto.h \
 686         openssl/err.h \
 687         openssl/evp.h \
 688         openssl/md5.h \
 689         openssl/md4.h \
 690         openssl/sha.h \
 691         openssl/ocsp.h \
 692         openssl/engine.h,
 693         [],
 694         OPENSSL_LIBS=
 695     )
 696     if test "x$OPENSSL_LIBS" != "x"; then
 697         AC_MSG_CHECKING([for OpenSSL version >= 0.9.7])
 698         AC_EGREP_CPP(yes,
 699             [#include <openssl/crypto.h>
 700              #if (OPENSSL_VERSION_NUMBER >= 0x00907000L)
 701              yes
 702              #endif
 703             ], goodssl="yes")
 704         if test "x$goodssl" != "xyes"; then
 705             AC_MSG_RESULT(no)
 706             OPENSSL_LIBS=
 707         else
 708             AC_MSG_RESULT(yes)
 709             if test "x$OPENSSL_INCLUDE_DIR" != "x"; then
 710                 OPENSSL_INCLUDE="-I$OPENSSL_INCLUDE_DIR -DOPENSSL_NO_KRB5"
 711             else
 712                 OPENSSL_INCLUDE="-DOPENSSL_NO_KRB5"
 713             fi
 714         fi
 715     fi
 716     CPPFLAGS=$old_CPPFLAGS
 717   fi
 718 fi
 719 AC_SUBST(OPENSSL_INCLUDE)
 720 AC_SUBST(OPENSSL_LIBS)
 721 export OPENSSL_LIBS
 722
 723 dnl Check the pcap includes for the RADIUS sniffer.
 724 if test "x$PCAP_LIBS" = x; then
 725     AC_MSG_NOTICE([skipping test for pcap.h.])
 726 else
 727     AC_CHECK_HEADER(pcap.h,
 728         AC_DEFINE(HAVE_PCAP_H, 1,
 729                 [Define to 1 if you have the <pcap.h> header file.]),
 730         [ PCAP_LIBS=
 731         AC_MSG_WARN([pcap.h not found, silently disabling the RADIUS sniffer.])
 732         ])
 733
 734     AC_CHECK_LIB(pcap, pcap_fopen_offline,
 735         [ AC_DEFINE(HAVE_PCAP_FOPEN_OFFLINE, 1,
 736                 [Define to 1 if you have the function pcap_fopen_offline.])
 737         ])
 738     AC_CHECK_LIB(pcap, pcap_dump_fopen,
 739         [ AC_DEFINE(HAVE_PCAP_DUMP_FOPEN, 1,
 740                 [Define to 1 if you have the function pcap_dump_fopen.])
 741         ])
 742 fi
 743 AC_SUBST(PCAP_LIBS)
 744
 745 dnl #############################################################
 746 dnl #
 747 dnl #  4. Checks for typedefs
 748 dnl #
 749 dnl #############################################################
 750
 751 dnl #
 752 dnl # Ensure that these are defined
 753 dnl #
 754 AC_TYPE_OFF_T
 755 AC_TYPE_PID_T
 756 AC_TYPE_SIZE_T
 757 AC_TYPE_UID_T
 758
 759 dnl check for socklen_t
 760 FR_CHECK_TYPE_INCLUDE([
 761 #ifdef HAVE_SYS_TYPES_H
 762 #include <sys/types.h>
 763 #endif
 764 #ifdef HAVE_SYS_SOCKET_H
 765 #include <sys/socket.h>
 766 #endif
 767 ],socklen_t, int, [socklen_t is generally 'int' on systems which don't use it])
 768
 769 dnl check for uint8_t
 770 FR_CHECK_TYPE_INCLUDE([
 771 #ifdef HAVE_INTTYPES_H
 772 #include <inttypes.h>
 773 #endif
 774 #ifdef HAVE_STDINT_H
 775 #include <stdint.h>
 776 #endif
 777 ],uint8_t, unsigned char, [uint8_t should be the canonical 'octet' for network traffic])
 778
 779 dnl check for uint16_t
 780 FR_CHECK_TYPE_INCLUDE([
 781 #ifdef HAVE_INTTYPES_H
 782 #include <inttypes.h>
 783 #endif
 784 #ifdef HAVE_STDINT_H
 785 #include <stdint.h>
 786 #endif
 787 ],uint16_t, unsigned short, [uint16_t should be the canonical '2 octets' for network traffic])
 788
 789 dnl check for uint32_t
 790 FR_CHECK_TYPE_INCLUDE([
 791 #ifdef HAVE_INTTYPES_H
 792 #include <inttypes.h>
 793 #endif
 794 #ifdef HAVE_STDINT_H
 795 #include <stdint.h>
 796 #endif
 797 ],uint32_t, unsigned int, [uint32_t should be the canonical 'network integer])
 798
 799 AC_CHECK_TYPE(struct in6_addr, AC_DEFINE(HAVE_STRUCT_IN6_ADDR, 1, [IPv6 address structure]), [], [
 800 #ifdef HAVE_NETINET_IN_H
 801 #include <netinet/in.h>
 802 #endif
 803 ])
 804
 805 AC_CHECK_TYPE(struct sockaddr_storage, AC_DEFINE(HAVE_STRUCT_SOCKADDR_STORAGE, 1, [Generic socket addresses]), [], [
 806 #ifdef HAVE_NETINET_IN_H
 807 #include <netinet/in.h>
 808 #endif
 809 #ifdef HAVE_SYS_SOCKET_H
 810 #include <sys/socket.h>
 811 #endif
 812 ])
 813
 814 AC_CHECK_TYPE(struct sockaddr_in6, AC_DEFINE(HAVE_STRUCT_SOCKADDR_IN6, 1, [IPv6 socket addresses]), [], [
 815 #ifdef HAVE_NETINET_IN_H
 816 #include <netinet/in.h>
 817 #endif
 818 ])
 819
 820 AC_CHECK_TYPE(struct addrinfo, AC_DEFINE(HAVE_STRUCT_ADDRINFO, 1, [Generic DNS lookups]), [], [
 821 #ifdef HAVE_SYS_TYPES_H
 822 #include <sys/types.h>
 823 #endif
 824 #ifdef HAVE_SYS_SOCKET_H
 825 #include <sys/socket.h>
 826 #endif
 827 #ifdef HAVE_NETDB_H
 828 #include <netdb.h>
 829 #endif
 830 ])
 831
 832 dnl #############################################################
 833 dnl #
 834 dnl #  5. Checks for structures and functions
 835 dnl #
 836 dnl #############################################################
 837 AC_CHECK_FUNCS( \
 838         getopt_long \
 839         lockf \
 840         strsignal \
 841         sigaction \
 842         sigprocmask \
 843         pthread_sigmask \
 844         snprintf \
 845         vsnprintf \
 846         setsid \
 847         strncasecmp \
 848         strcasecmp \
 849         localtime_r \
 850         ctime_r \
 851         gmtime_r \
 852         strsep \
 853         inet_aton \
 854         inet_pton \
 855         inet_ntop \
 856         setlinebuf \
 857         setvbuf \
 858         getusershell \
 859         initgroups \
 860         getaddrinfo \
 861         getnameinfo \
 862         closefrom \
 863         gettimeofday \
 864         getpeereid \
 865         setuid \
 866         setresuid \
 867         getresuid \
 868         strlcat \
 869         strlcpy
 870 )
 871 RADIUSD_NEED_DECLARATIONS( \
 872         crypt \
 873         strncasecmp \
 874         strcasecmp \
 875         inet_aton \
 876         setlinebuf \
 877         getusershell \
 878         endusershell
 879 )
 880
 881 AC_TYPE_SIGNAL
 882
 883 dnl # check if we have utmpx.h
 884 dnl # if so, check if struct utmpx has entry ut_xtime
 885 dnl # if not, set it to define ut_xtime == ut_tv.tv_sec
 886 if test "x$ac_cv_header_utmpx_h" = "xyes"
 887 then
 888  FR_CHECK_STRUCT_HAS_MEMBER([#include <utmpx.h>], [struct utmpx], ut_xtime)
 889  if test "x$ac_cv_type_struct_utmpx_has_ut_xtime" = "x"
 890  then
 891    AC_DEFINE(ut_xtime,ut_tv.tv_sec, [define to something if you don't have ut_xtime in struct utmpx])
 892  fi
 893 fi
 894
 895 dnl # struct ip_pktinfo
 896 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in_pktinfo], ipi_addr)
 897 if test "x$ac_cv_type_struct_in_pktinfo_has_ipi_addr" = "xyes"
 898 then
 899         AC_DEFINE(HAVE_IP_PKTINFO, [], [define if you have IP_PKTINFO (Linux)])
 900 fi
 901
 902 dnl # struct in6_pktinfo
 903 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in6_pktinfo], ipi6_addr)
 904 if test "x$ac_cv_type_struct_in6_pktinfo_has_ipi6_addr" = "xyes"
 905 then
 906         AC_DEFINE(HAVE_IN6_PKTINFO, [], [define if you have IN6_PKTINFO (Linux)])
 907 fi
 908
 909 dnl #############################################################
 910 dnl #
 911 dnl #  6. Checks for compiler characteristics
 912 dnl #
 913 dnl #############################################################
 914
 915 dnl #
 916 dnl # Ensure that these are defined
 917 dnl #
 918 AC_C_CONST
 919
 920 dnl #
 921 dnl # See if this is OS/2
 922 dnl #
 923 AC_MSG_CHECKING(type of OS)
 924 OS=`uname -s`
 925 AC_MSG_RESULT($OS)
 926 if test "$OS" = "OS/2"; then
 927         LIBPREFIX=
 928 else
 929         LIBPREFIX=lib
 930 fi
 931 AC_SUBST(LIBPREFIX)
 932
 933 AC_MSG_CHECKING(for developer gcc flags)
 934 if test "x$developer" = "xyes" -a "x$GCC" = "xyes"; then
 935   devflags="-g -Wshadow -Wpointer-arith -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -W -Wredundant-decls -Wundef"
 936   CFLAGS="$CFLAGS $devflags"
 937   INSTALLSTRIP=""
 938   AC_MSG_RESULT(yes.  Using $devflags)
 939 else
 940   devflags=""
 941   CFLAGS="$CFLAGS -DNDEBUG"
 942   INSTALLSTRIP=""
 943   AC_MSG_RESULT(no.)
 944 fi
 945
 946 FR_TLS
 947
 948 dnl #############################################################
 949 dnl #
 950 dnl #  7. Checks for library functions
 951 dnl #
 952 dnl #############################################################
 953
 954 old_LIBS="$LIBS"
 955 LIBS="$LIBS $LIBLTDL"
 956 AC_CHECK_FUNC(lt_dladvise_init, AC_DEFINE(HAVE_LT_DLADVISE_INIT, [], [Do we have the lt_dladvise_init function]))
 957 LIBS="$old_LIBS"
 958
 959 dnl Check for libcrypt
 960 dnl We use crypt(3) which may be in libc, or in libcrypt (eg FreeBSD)
 961 AC_CHECK_LIB(crypt, crypt,
 962   CRYPTLIB="-lcrypt"
 963 )
 964 if test "$CRYPTLIB" != ""; then
 965   AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function])
 966 else
 967   AC_CHECK_FUNC(crypt, AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function]))
 968 fi
 969
 970 dnl Check for libcipher
 971 AC_CHECK_LIB(cipher, setkey,
 972    CRYPTLIB="${CRYPTLIB} -lcipher"
 973 )
 974 AC_SUBST(CRYPTLIB)
 975
 976 dnl Check the style of gethostbyaddr, in order of preference
 977 dnl GNU (_r eight args)
 978 AC_DEFINE(GNUSTYLE, [1], [GNU-Style get*byaddr_r])
 979 dnl SYSV (_r six args)
 980 AC_DEFINE(SYSVSTYLE, [2], [SYSV-Style get*byaddr_r])
 981 dnl BSD (three args, may not be thread safe)
 982 AC_DEFINE(BSDSTYLE, [3], [BSD-Style get*byaddr_r])
 983 dnl Tru64 has BSD version, but it is thread safe
 984 dnl     http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1739____.HTM
 985 dnl We need #stdio.h to define NULL on FreeBSD (at least)
 986 gethostbyaddrrstyle=""
 987 AC_MSG_CHECKING([gethostbyaddr_r() syntax])
 988 case "$host" in
 989 *-freebsd*)
 990 dnl With FreeBSD, check if there's a prototype for gethostbyaddr_r.
 991 dnl Some versions (FreeBSD 5.1?) have a symbol but no prototype - so we
 992 dnl override this test to BSDSTYLE. FreeBSD 6.2 and up have proper GNU
 993 dnl style support.
 994         AC_CHECK_DECLS([gethostbyaddr_r], [], [
 995                 AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE,
 996                         [style of gethostbyaddr_r functions ])
 997                 gethostbyaddrrstyle=BSD
 998                 AC_MSG_WARN([FreeBSD overridden to BSD-style])
 999         ], [
1000 #ifdef HAVE_NETDB_H
1001 #include <netdb.h>
1002 #endif
1003 ])
1004         ;;
1005 esac
1006 if test "x$gethostbyaddrrstyle" = "x"; then
1007         AC_TRY_LINK([
1008 #include <stdio.h>
1009 #include <netdb.h>
1010 ], [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL, NULL) ], [
1011         AC_DEFINE(GETHOSTBYADDRRSTYLE, GNUSTYLE, [style of gethostbyaddr_r functions ])
1012         gethostbyaddrrstyle=GNU
1013 ])
1014 fi
1015 if test "x$gethostbyaddrrstyle" = "x"; then
1016         AC_TRY_LINK([
1017 #include <stdio.h>
1018 #include <netdb.h>
1019 ], [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL) ] , [
1020                 AC_DEFINE(GETHOSTBYADDRRSTYLE, SYSVSTYLE, [style of gethostbyaddr_r functions ])
1021                 gethostbyaddrrstyle=SYSV
1022         ])
1023 fi
1024 if test "x$gethostbyaddrrstyle" = "x"; then
1025         AC_TRY_LINK([
1026 #include <stdio.h>
1027 #include <netdb.h>
1028 ], [ gethostbyaddr(NULL, 0, 0)  ], [
1029                 AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE, [style of gethostbyaddr_r functions ])
1030                 gethostbyaddrrstyle=BSD
1031         ])
1032 fi
1033
1034 if test "x$gethostbyaddrrstyle" = "x"; then
1035         AC_MSG_RESULT([none!  It must not exist, here.])
1036 else
1037         AC_MSG_RESULT([${gethostbyaddrrstyle}-style])
1038 fi
1039
1040 if test "x$gethostbyaddrrstyle" = "xBSD"; then
1041         AC_MSG_WARN([ ****** BSD-style gethostbyaddr might NOT be thread-safe! ****** ])
1042 fi
1043
1044 dnl Check the style of gethostbyname, in order of preference
1045 dnl GNU (_r seven args)
1046 dnl SYSV (_r five args)
1047 dnl BSD (two args, may not be thread safe)
1048 dnl Tru64 has BSD version, but it _is_ thread safe
1049 dnl     http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1946____.HTM
1050 dnl We need #stdio.h to define NULL on FreeBSD (at least)
1051 gethostbynamerstyle=""
1052 AC_MSG_CHECKING([gethostbyname_r() syntax])
1053 AC_TRY_LINK([
1054 #include <stdio.h>
1055 #include <netdb.h>
1056 ], [ gethostbyname_r(NULL, NULL, NULL, 0, NULL, NULL) ], [
1057         AC_DEFINE(GETHOSTBYNAMERSTYLE, GNUSTYLE, [style of gethostbyname_r functions ])
1058         gethostbynamerstyle=GNU
1059 ])
1060 if test "x$gethostbynamerstyle" = "x"; then
1061         AC_TRY_LINK([
1062 #include <stdio.h>
1063 #include <netdb.h>
1064 ], [ gethostbyname_r(NULL, NULL, NULL, 0, NULL) ] , [
1065                 AC_DEFINE(GETHOSTBYNAMERSTYLE, SYSVSTYLE, [style of gethostbyname_r functions ])
1066                 gethostbynamerstyle=SYSV
1067         ])
1068 fi
1069 if test "x$gethostbynamerstyle" = "x"; then
1070         AC_TRY_LINK([
1071 #include <stdio.h>
1072 #include <netdb.h>
1073 ], [ gethostbyname(NULL)  ], [
1074                 AC_DEFINE(GETHOSTBYNAMERSTYLE, BSDSTYLE, [style of gethostbyname_r functions ])
1075                 gethostbynamerstyle=BSD
1076         ])
1077 fi
1078
1079 if test "x$gethostbynamerstyle" = "x"; then
1080         AC_MSG_RESULT([none!  It must not exist, here.])
1081 else
1082         AC_MSG_RESULT([${gethostbynamerstyle}-style])
1083 fi
1084
1085 if test "x$gethostbynamerstyle" = "xBSD"; then
1086         AC_MSG_WARN([ ****** BSD-style gethostbyname might NOT be thread-safe! ****** ])
1087 fi
1088
1089 dnl check for non-posix solaris ctime_r (extra buflen int arg)
1090 AC_DEFINE(POSIXSTYLE, [1], [Posix-Style ctime_r])
1091 AC_DEFINE(SOLARISSTYLE, [2], [Solaris-Style ctime_r])
1092 ctimerstyle=""
1093 AC_MSG_CHECKING([ctime_r() syntax])
1094 AC_TRY_LINK([
1095 #include <time.h>
1096 ], [ ctime_r(NULL, NULL, 0) ], [
1097         AC_DEFINE(CTIMERSTYLE, SOLARISSTYLE, [style of ctime_r function])
1098         ctimerstyle="SOLARIS"
1099 ])
1100 if test "x$ctimerstyle" = "x"; then
1101         AC_TRY_LINK([
1102 #include <time.h>
1103 ], [ ctime_r(NULL, NULL) ], [
1104                 AC_DEFINE(CTIMERSTYLE, POSIXSTYLE, [style of ctime_r function])
1105                 ctimerstyle="POSIX"
1106         ])
1107 fi
1108
1109 if test "x$ctimerstyle" = "x"; then
1110         AC_MSG_RESULT([none!  It must not exist, here.])
1111 else
1112         AC_MSG_RESULT([${ctimerstyle}-style])
1113 fi
1114
1115 AC_SUBST(HOSTINFO, $host)
1116
1117 dnl #############################################################
1118 dnl #
1119 dnl #  8. Checks for system services
1120 dnl #
1121 dnl #############################################################
1122
1123 dnl #
1124 dnl # Figure out where libtool is located,
1125 dnl #
1126 top_builddir=`pwd`
1127 export top_builddir
1128 AC_MSG_RESULT([top_builddir=$top_builddir])
1129 dnl # AC_SUBST(top_builddir)
1130 AC_SUBST(LIBLTDL)
1131 AC_SUBST(INCLTDL)
1132
1133 dnl import libtool stuff
1134
1135 dnl #############################################################
1136 dnl #
1137 dnl #  Configure in any module directories.
1138 dnl #
1139 dnl #############################################################
1140
1141 mysubdirs="$LIBLTDLPATH"
1142 if test "x$EXPERIMENTAL" = "xyes"; then
1143   bar=`ls -1 "${srcdir}"/src/modules/rlm_*/configure | sed 's%/configure%%'`
1144   dnl # get rid of LF's.
1145   mysubdirs=`echo $mysubdirs $bar`
1146 else
1147   dnl #
1148   dnl # Find 'configure' in ONLY the stable modules
1149   dnl #
1150   for bar in `cat "${srcdir}"/src/modules/stable`; do
1151     if test -f "${srcdir}"/src/modules/$bar/configure; then
1152       mysubdirs="$mysubdirs src/modules/$bar"
1153     fi
1154   done
1155 fi
1156
1157 dnl ############################################################
1158 dnl # make modules by list
1159 dnl #############################################################
1160 if test "x$EXPERIMENTAL" = "xyes"; then
1161   for foo in `ls -1 "${srcdir}"/src/modules | grep rlm_`; do
1162     MODULES="$MODULES $foo"
1163   done
1164 else
1165    dnl #
1166    dnl # make ONLY the stable modules
1167    dnl #
1168    for foo in `cat "${srcdir}"/src/modules/stable`; do
1169     MODULES="$MODULES $foo"
1170    done
1171 fi
1172
1173 dnl #
1174 dnl #  Don't change the variable name here.  Autoconf goes bonkers
1175 dnl #  if you do.
1176 dnl #
1177 AC_CONFIG_SUBDIRS($LTDL_SUBDIRS $mysubdirs)
1178 AC_SUBST(MODULES)
1179
1180 dnl #############################################################
1181 dnl #
1182 dnl #  And finally, output the results.
1183 dnl #
1184 dnl #############################################################
1185
1186 AC_CONFIG_COMMANDS([stamp-h], [echo timestamp > src/include/stamp-h])
1187 AC_CONFIG_COMMANDS([build-radpaths-h], [(cd ./src/include && /bin/sh ./build-radpaths-h)])
1188 AC_CONFIG_COMMANDS([main-chmod], [(cd ./src/main   && chmod +x checkrad.pl radlast radtest)])
1189 AC_CONFIG_COMMANDS([scripts-chmod], [(cd ./scripts    && chmod +x rc.radiusd radwatch radiusd.cron.daily radiusd.cron.monthly cryptpasswd)])
1190
1191 dnl #
1192 dnl #  Substitute whatever libraries we found to be necessary
1193 dnl #
1194 AC_SUBST(LIBS)
1195 AC_SUBST(INSTALLSTRIP)
1196
1197 USE_SHARED_LIBS=$enable_shared
1198 AC_SUBST(USE_SHARED_LIBS)
1199 USE_STATIC_LIBS=$enable_static
1200 AC_SUBST(USE_STATIC_LIBS)
1201 AC_SUBST(STATIC_MODULES)
1202 AC_SUBST(RADIUSD_MAJOR_VERSION)
1203 AC_SUBST(RADIUSD_MINOR_VERSION)
1204 AC_SUBST(RADIUSD_VERSION)
1205
1206 AC_OUTPUT(\
1207         ./Make.inc \
1208         ./src/include/build-radpaths-h \
1209         ./src/main/Makefile \
1210         ./src/main/checkrad.pl \
1211         ./src/main/radlast \
1212         ./src/main/radtest \
1213         ./scripts/rc.radiusd \
1214         ./scripts/radwatch \
1215         ./scripts/radiusd.cron.daily \
1216         ./scripts/radiusd.cron.monthly \
1217         ./scripts/cryptpasswd \
1218         ./raddb/dictionary \
1219         ./raddb/radrelay.conf \
1220         ./raddb/radiusd.conf
1221 )