configure.in

   1 dnl #############################################################
   2 dnl #
   3 dnl #  For information about autoconf, see:
   4 dnl #
   5 dnl #  http://www.gnu.org/software/autoconf/
   6 dnl #
   7 dnl #  The recommended order is:
   8 dnl #
   9 dnl #  AC_INIT(file)
  10 dnl #  0. checks for compiler, libtool, and command line options
  11 dnl #  1. checks for programs
  12 dnl #  2. checks for libraries
  13 dnl #  3. checks for header files
  14 dnl #  4. checks for typedefs
  15 dnl #  5. checks for structures and functions
  16 dnl #  6. checks for compiler characteristics
  17 dnl #  7. checks for library functions
  18 dnl #  8. checks for system services
  19 dnl #  AC_OUTPUT([file...])
  20 dnl #
  21 dnl #############################################################
  22
  23 AC_PREREQ([2.59])
  24 export CFLAGS LIBS LDFLAGS CPPFLAGS
  25 AC_INIT(src/main/radiusd.c)
  26 AC_CONFIG_HEADER(src/include/autoconf.h)
  27 AC_REVISION($Revision$)dnl
  28
  29 dnl # The version of the software
  30 RADIUSD_VERSION=`cat VERSION`
  31 RADIUSD_MAJOR_VERSION=`cat VERSION | sed 's/\..*//'`
  32 RADIUSD_MINOR_VERSION=`cat VERSION | sed 's/^3\.//'`
  33 PACKAGE=freeradius
  34
  35 dnl #############################################################
  36 dnl #
  37 dnl #  0. Checks for compiler, libtool, and command line options.
  38 dnl #
  39 dnl #############################################################
  40
  41 dnl Check for GNU cc
  42 AC_PROG_CC
  43 AC_PROG_CXX
  44
  45 dnl #
  46 dnl # check for AIX, to allow us to use some BSD functions
  47 dnl # must be before macros that call the compiler.
  48 dnl #
  49 AC_AIX
  50
  51 AC_PROG_GCC_TRADITIONAL
  52 AC_PROG_CC_SUNPRO
  53 AC_PROG_RANLIB
  54
  55 dnl #
  56 dnl # Set Default CFLAGS
  57 dnl #
  58 if test "x$GCC" = "xyes"; then
  59     CFLAGS="$CFLAGS -Wall -D_GNU_SOURCE"
  60 fi
  61
  62 dnl Compile in large (2G+) file support.
  63 AC_SYS_LARGEFILE
  64
  65 dnl # check for system bytesex
  66 dnl # AC_DEFINES WORDS_BIGENDIAN
  67 AC_C_BIGENDIAN
  68
  69 dnl Find GNU Make.
  70 AC_CHECK_PROG(GMAKE, gmake, yes, no)
  71 if test $GMAKE = no; then
  72   AC_PATH_PROG(MAKE, make, /usr/local/bin/make)
  73 else
  74   AC_PATH_PROG(MAKE, gmake, /usr/local/gnu/bin/make)
  75 fi
  76 makever=`$ac_cv_path_MAKE --version 2>&1 | grep "GNU Make"`
  77 if test -z "$makever"; then
  78   AC_MSG_ERROR(GNU Make is not installed.  Please download and install it
  79                 from ftp://prep.ai.mit.edu/pub/gnu/make/ before continuing.)
  80 fi
  81
  82 AC_ARG_WITH(system-libltdl,
  83 [  --with-system-libltdl   Use the libltdl installed in your system (default=use dlopen)],
  84 [
  85 LIBLTDL="-lltdl"
  86 INCLTDL=-DWITH_SYSTEM_LTDL
  87 ],
  88
  89 dnl use system-wide libtool, if it exists
  90 AC_ARG_WITH(system-libtool,
  91 [  --with-system-libtool   Use the libtool installed in your system (default=use our own)],
  92 [ AC_PATH_PROG(LIBTOOL, libtool,,$PATH:/usr/local/bin) AC_LIBTOOL_DLOPEN
  93  AC_PROG_LIBTOOL],
  94 [
  95   LIBTOOL="`pwd`/libtool"
  96   AC_SUBST(LIBTOOL)
  97   dnl ensure that we're looking for dlopen
  98   AC_LIBTOOL_DLOPEN
  99
 100   dnl Figure out how to build shared libraries
 101   AC_PROG_LIBTOOL
 102 ])
 103
 104
 105 dnl Put this in later, when all distributed modules use autoconf.
 106 dnl AC_ARG_WITH(disablemodulefoo,
 107 dnl [  --without-rlm_foo       Disables module compilation.  Module list:]
 108 dnl esyscmd([find src/modules -type d -name rlm_\* -print |\
 109 dnl     sed -e 's%src/modules/.*/% (sub)- %; s%.*/%- %' |\
 110 dnl     awk '{print "                            "$0}']))
 111
 112 AC_ARG_ENABLE(strict-dependencies,
 113 [  --enable-strict-dependencies  Fail configure on lack of module dependancy.])
 114
 115 dnl extra argument: --with-docdir
 116 docdir='${datadir}/doc/freeradius'
 117 AC_MSG_CHECKING(docdir)
 118 AC_ARG_WITH(docdir,
 119 [  --with-docdir=DIR       Directory for documentation [DATADIR/doc/freeradius] ],
 120 [ case "$withval" in
 121     no)
 122         docdir=no
 123         ;;
 124     yes)
 125         ;;
 126     [[\\/$]]* | ?:[[\\/]]* )
 127         docdir="$withval"
 128         ;;
 129     *)
 130         AC_MSG_ERROR([expected an absolute directory name for --with-docdir: $withval])
 131         ;;
 132   esac ]
 133 )
 134 AC_SUBST(docdir)
 135 AC_MSG_RESULT($docdir)
 136 if test "x$docdir" = xno; then
 137         AC_MSG_WARN(Documentation files will NOT be installed.)
 138 fi
 139
 140 dnl extra argument: --with-logdir
 141 logdir='${localstatedir}/log/radius'
 142 AC_MSG_CHECKING(logdir)
 143 AC_ARG_WITH(logdir,
 144 [  --with-logdir=DIR       Directory for logfiles [LOCALSTATEDIR/log/radius] ],
 145 [ case "$withval" in
 146     no)
 147         AC_MSG_ERROR(Need logdir)
 148         ;;
 149     yes)
 150         ;;
 151     [[\\/$]]* | ?:[[\\/]]* )
 152         logdir="$withval"
 153         ;;
 154     *)
 155         AC_MSG_ERROR([expected an absolute directory name for --with-logdir: $withval])
 156         ;;
 157   esac ]
 158 )
 159 AC_SUBST(logdir)
 160 AC_MSG_RESULT($logdir)
 161
 162 dnl extra argument: --with-radacctdir
 163 radacctdir='${logdir}/radacct'
 164 AC_MSG_CHECKING(radacctdir)
 165 AC_ARG_WITH(radacctdir,
 166 [  --with-radacctdir=DIR   Directory for detail files [LOGDIR/radacct] ],
 167 [ case "$withval" in
 168     no)
 169         AC_MSG_ERROR(Need radacctdir)
 170         ;;
 171     yes)
 172         ;;
 173     [[\\/$]]* | ?:[[\\/]]* )
 174         radacctdir="$withval"
 175         ;;
 176     *)
 177         AC_MSG_ERROR([expected an absolute directory name for --with-radacctdir: $withval])
 178         ;;
 179   esac ]
 180 )
 181 AC_SUBST(radacctdir)
 182 AC_MSG_RESULT($radacctdir)
 183
 184 dnl extra argument: --with-raddbdir
 185 raddbdir='${sysconfdir}/raddb'
 186 AC_MSG_CHECKING(raddbdir)
 187 AC_ARG_WITH(raddbdir,
 188 [  --with-raddbdir=DIR     Directory for config files [SYSCONFDIR/raddb] ],
 189 [ case "$withval" in
 190     no)
 191         AC_MSG_ERROR(Need raddbdir)
 192         ;;
 193     yes)
 194         ;;
 195     [[\\/$]]* | ?:[[\\/]]* )
 196         raddbdir="$withval"
 197         ;;
 198     *)
 199         AC_MSG_ERROR([expected an absolute directory name for --with-raddbdir: $withval])
 200         ;;
 201   esac ]
 202 )
 203 AC_SUBST(raddbdir)
 204 AC_MSG_RESULT($raddbdir)
 205
 206 dnl extra argument: --with-ascend-binary
 207 ASCEND_BINARY=yes
 208 AC_ARG_WITH(ascend-binary,
 209 [  --with-ascend-binary    Include support for Ascend binary filter attributes (default=yes)],
 210 [ case "$withval" in
 211     yes)
 212         ;;
 213     *)
 214         ASCEND_BINARY=""
 215   esac ]
 216 )
 217 if test "X$ASCEND_BINARY" = "Xyes"; then
 218   AC_DEFINE(ASCEND_BINARY, [], [Include support for Ascend binary filter attributes])
 219 fi
 220
 221 dnl extra argument: --with-threads
 222 WITH_THREADS=yes
 223 AC_ARG_WITH(threads,
 224 [  --with-threads          Use threads, if available.  (default=yes) ],
 225 [ case "$withval" in
 226     yes)
 227         ;;
 228     *)
 229         WITH_THREADS=""
 230   esac ]
 231 )
 232
 233 dnl extra argument: --with-vmps
 234 WITH_VMPS=yes
 235 AC_ARG_WITH(vmps,
 236 [  --with-vmps             Compile in VMPS support. (default=yes)],
 237 [ case "$withval" in
 238     yes)
 239         ;;
 240     *)
 241         WITH_VMPS=no
 242   esac ]
 243 )
 244 if test "x$WITH_VMPS" = "xyes"; then
 245         AC_DEFINE(WITH_VMPS, [1], [define if you want VMPS support])
 246 fi
 247
 248 dnl extra argument: --with-dhcp
 249 WITH_DHCP=yes
 250 AC_ARG_WITH(dhcp,
 251 [  --with-dhcp             Compile in DHCP support. (default=yes)],
 252 [ case "$withval" in
 253     yes)
 254         ;;
 255     *)
 256         WITH_DHCP=no
 257   esac ]
 258 )
 259 if test "x$WITH_DHCP" = "xyes"; then
 260         AC_DEFINE(WITH_DHCP, [1], [define if you want DHCP support])
 261 fi
 262
 263
 264 dnl #
 265 dnl #  Allow the user to specify a list of modules to be linked
 266 dnl #  statically to the server.
 267 dnl #
 268 STATIC_MODULES=
 269 AC_ARG_WITH(static_modules,
 270 [  --with-static-modules=QUOTED-MODULE-LIST],[
 271   for i in $withval; do
 272     STATIC_MODULES="$STATIC_MODULES -dlpreopen ../modules/rlm_$i/rlm_$i.la"
 273   done
 274 ])
 275
 276 MODULES=
 277 AC_ARG_WITH(modules,
 278 [ --with-modules=QUOTED-MODULE-LIST],[
 279  for i in $withval; do
 280    MODULES="$MODULES $i"
 281  done
 282 ])
 283
 284 dnl #
 285 dnl #  Enable developer C compiler warnings
 286 dnl #
 287 AC_ARG_ENABLE(developer,
 288 [  --enable-developer               Enables features of interest to developers.],
 289 [ case "$enableval" in
 290     no)
 291         developer=no
 292         ;;
 293     *)
 294         developer=yes
 295   esac ]
 296 )
 297
 298 if test "x$developer" != "xno" -a -d $srcdir/CVS; then
 299   dnl turn on the developer flag when taken from a CVS checkout (not a release)
 300   developer="yes"
 301 fi
 302
 303 if test "x$developer" != "xno" -a -d $srcdir/.git; then
 304   dnl turn on the developer flag when taken from a git checkout (not a release)
 305   developer="yes"
 306 fi
 307
 308 dnl extra argument: --with-experimental-modules
 309 EXPERIMENTAL=
 310 AC_ARG_WITH(experimental-modules,
 311 [  --with-experimental-modules      Use experimental and unstable modules. (default=no) ],
 312 [ case "$withval" in
 313     yes)
 314         EXPERIMENTAL=yes
 315         ;;
 316     *)
 317   esac ]
 318 )
 319
 320 dnl extra argument: --with-openssl
 321 WITH_OPENSSL=yes
 322 AC_ARG_WITH(openssl,
 323 [  --with-openssl                   Use OpenSSL. (default=yes)],
 324 [ case "$withval" in
 325     no)
 326         WITH_OPENSSL=no
 327         ;;
 328     *)
 329         WITH_OPENSSL=yes
 330         ;;
 331   esac ]
 332 )
 333
 334 dnl #
 335 dnl # extra argument: --with-openssl-includes=dir
 336 dnl #
 337 OPENSSL_INCLUDE_DIR=
 338 AC_ARG_WITH(openssl-includes,
 339 [  --with-openssl-includes=DIR      Directory to look for OpenSSL include files],
 340 [ case "$withval" in
 341     *) OPENSSL_INCLUDE_DIR="$withval"
 342         ;;
 343   esac ]
 344 )
 345
 346 dnl #
 347 dnl # extra argument: --with-openssl-libraries=dir
 348 dnl #
 349 OPENSSL_LIB_DIR=
 350 AC_ARG_WITH(openssl-libraries,
 351 [  --with-openssl-libraries=DIR     Directory to look for OpenSSL library files],
 352 [ case "$withval" in
 353     *) OPENSSL_LIB_DIR="$withval"
 354         ;;
 355   esac ]
 356 )
 357
 358 dnl #
 359 dnl #  These next two arguments don't actually do anything.  They're
 360 dnl #  place holders so that the top-level configure script can tell
 361 dnl #  the user how to configure lower-level modules
 362 dnl #
 363
 364 dnl #
 365 dnl # extra argument: --with-rlm-FOO-lib-dir
 366 dnl #
 367 AC_ARG_WITH(rlm-FOO-lib-dir,
 368 [  --with-rlm-FOO-lib-dir=DIR       Directory to look for library files used by module FOO],
 369 [ case "$withval" in
 370     *)
 371         ;;
 372   esac ]
 373 )
 374
 375 dnl #
 376 dnl # extra argument: --with-rlm-FOO-include-dir
 377 dnl #
 378 AC_ARG_WITH(rlm-FOO-include-dir,
 379 [  --with-rlm-FOO-include-dir=DIR   Directory to look for include files used by module FOO],
 380 [ case "$withval" in
 381     *)
 382         ;;
 383   esac ]
 384 )
 385
 386 dnl See what include-style is used by the make program.
 387 dnl AC_MSG_CHECKING(include style for make)
 388 dnl echo "include /dev/null" > testmake.$$
 389 dnl echo "all:" >> testmake.$$
 390 dnl make -f testmake.$$ >/dev/null 2>&1
 391 dnl if test $? = 0
 392 dnl then
 393 dnl     INCLUDE=include
 394 dnl     IQUOTE=
 395 dnl else
 396 dnl     INCLUDE=.include
 397 dnl     IQUOTE='"'
 398 dnl fi
 399 dnl rm -f testmake.$$
 400 dnl AC_MSG_RESULT(" $INCLUDE")
 401 dnl AC_SUBST(INCLUDE)
 402 dnl AC_SUBST(IQUOTE)
 403
 404 dnl extra argument: --with-udpfromto
 405 WITH_UDPFROMTO=no
 406 AC_ARG_WITH(udpfromto,
 407 [  --with-udpfromto        Compile in UDPFROMTO support. (default=no)],
 408 [ case "$withval" in
 409     yes)
 410         WITH_UDPFROMTO=yes
 411         ;;
 412     *)
 413         WITH_UDPFROMTO=no
 414   esac ]
 415 )
 416
 417 if test "x$WITH_UDPFROMTO" = "xyes"; then
 418         AC_DEFINE(WITH_UDPFROMTO, [], [define if you want udpfromto])
 419 fi
 420
 421 dnl #############################################################
 422 dnl #
 423 dnl #  1. Checks for programs
 424 dnl #
 425 dnl #############################################################
 426
 427 CHECKRAD=checkrad.pl
 428 AC_PATH_PROG(PERL, perl, /usr/local/bin/perl)
 429 if test "x$ac_cv_path_PERL" = "x"; then
 430   AC_MSG_WARN(perl not found - Simultaneous-Use and checkrad.pl may not work)
 431 fi
 432 AC_PATH_PROG(SNMPGET, snmpget)
 433 if test "x$ac_cv_path_SNMPGET" = "x"; then
 434   AC_MSG_WARN(snmpget not found - Simultaneous-Use and checkrad.pl may not work)
 435 fi
 436
 437 AC_PATH_PROG(SNMPWALK, snmpwalk)
 438 if test "x$ac_cv_path_SNMPWALK" = "x"; then
 439   AC_MSG_WARN(snmpwalk not found - Simultaneous-Use and checkrad.pl may not work)
 440 fi
 441
 442 AC_PATH_PROG(RUSERS, rusers, /usr/bin/rusers)
 443
 444 dnl FIXME This is truly gross.
 445 missing_dir=`cd $ac_aux_dir && pwd`
 446 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
 447 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
 448 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
 449
 450 AC_PATH_PROG(LOCATE,locate)
 451 AC_PATH_PROG(DIRNAME,dirname)
 452 AC_PATH_PROG(GREP,grep)
 453
 454 dnl #############################################################
 455 dnl #
 456 dnl #  2. Checks for libraries
 457 dnl #
 458 dnl #############################################################
 459
 460 dnl If using pthreads, check for -lpthread (posix) or -lc_r (*BSD)
 461 old_CFLAGS=$CFLAGS
 462 if test "x$WITH_THREADS" = "xyes"; then
 463   if test $ac_cv_prog_suncc = "yes"; then
 464     CFLAGS="$CFLAGS -mt"
 465   fi
 466
 467   AC_CHECK_HEADERS(pthread.h, [], [ WITH_THREADS="no" ])
 468
 469 dnl #
 470 dnl # pthread stuff is usually in -lpthread
 471 dnl # or in -lc_r, on *BSD
 472 dnl #
 473 dnl # On Some systems, we need extra pre-processor flags, to get them to
 474 dnl # to do the threading properly.
 475 dnl #
 476   AC_CHECK_LIB(pthread, pthread_create,
 477                 [ CFLAGS="$CFLAGS -D_REENTRANT -D_POSIX_PTHREAD_SEMANTICS"
 478                   LIBS="-lpthread $LIBS" ],
 479                 AC_CHECK_LIB(c_r, pthread_create,
 480                             [ CFLAGS="$CFLAGS -pthread -D_THREAD_SAFE" ],
 481                             [ WITH_THREADS="no" ]
 482                             )
 483                 )
 484 fi
 485
 486 dnl #
 487 dnl # If we have NO pthread libraries, remove any knowledge of threads.
 488 dnl #
 489 if test "x$WITH_THREADS" != "xyes"; then
 490   CFLAGS=$old_CFLAGS
 491   ac_cv_header_pthread_h="no"
 492   WITH_THREADS=no
 493 else
 494   dnl #
 495   dnl #  We need sem_init() and friends, as they're the friendliest
 496   dnl #  semaphore functions for threading.
 497   dnl #
 498   dnl # HP/UX requires linking with librt, too, to get the sem_* symbols.
 499   dnl # Some systems have them in -lsem
 500   dnl # Solaris has them in -lposix4
 501   dnl # NetBSD has them in -lsemaphore
 502
 503   AC_SEARCH_LIBS(sem_init, pthread sem posix4 rt semaphore,
 504         [],
 505         [AC_MSG_ERROR(-lsem not found.  You may want to download it from ftp://ftp.to.gd-es.com/pub/BSDI/libsem.tar.bz2 or ftp://ftp.freeradius.org/pub/radius/contrib/libsem.tar.gz)]
 506    )
 507 fi
 508
 509 dnl Check if we need -lsocket
 510 AC_CHECK_LIB(socket, getsockname)
 511
 512 dnl Check for -lresolv
 513 dnl This library may be needed later.
 514 AC_CHECK_LIB(resolv, inet_aton)
 515
 516 dnl Check if we need -lnsl. Usually if we want to
 517 dnl link against -lsocket we need to include -lnsl as well.
 518 AC_CHECK_LIB(nsl, inet_ntoa)
 519
 520 dnl Check for OpenSSL libraries.
 521 OPENSSL_LIBS=
 522 if test "x$WITH_OPENSSL" = xyes; then
 523   old_LIBS=$LIBS
 524   old_LDFLAGS="$LDFLAGS"
 525   if test "x$OPENSSL_LIB_DIR" != "x"; then
 526     LDFLAGS="$LDFLAGS -L$OPENSSL_LIB_DIR"
 527   fi
 528   AC_CHECK_LIB(crypto, DH_new,
 529     [
 530         LIBS="-lcrypto $LIBS"
 531         AC_DEFINE(HAVE_LIBCRYPTO, 1,
 532             [Define to 1 if you have the `crypto' library (-lcrypto).])
 533         AC_CHECK_LIB(ssl, SSL_new,
 534             [
 535                 AC_DEFINE(HAVE_LIBSSL, 1,
 536                     [Define to 1 if you have the `ssl' library (-lssl).])
 537                 if test "x$OPENSSL_LIB_DIR" != "x"; then
 538                     OPENSSL_LIBS="-L$OPENSSL_LIB_DIR"
 539                 fi
 540                 OPENSSL_LIBS="$OPENSSL_LIBS -lcrypto -lssl -lcrypto"
 541             ], [])
 542     ], [])
 543   LIBS=$old_LIBS
 544   LDFLAGS="$old_LDFLAGS"
 545 fi
 546
 547 AC_CHECK_LIB(ws2_32, htonl)
 548
 549 dnl Check the pcap library for the RADIUS sniffer.
 550 PCAP_LIBS=
 551 AC_CHECK_LIB(pcap, pcap_open_live,
 552         [ PCAP_LIBS="-lpcap"
 553         AC_DEFINE(HAVE_LIBPCAP, 1,
 554                 [Define to 1 if you have the `pcap' library (-lpcap).])
 555         ],
 556         [ AC_MSG_WARN([pcap library not found, silently disabling the RADIUS sniffer.]) ])
 557
 558 AC_LIB_READLINE
 559
 560 dnl #############################################################
 561 dnl #
 562 dnl #  3. Checks for header files
 563 dnl #
 564 dnl #############################################################
 565
 566 dnl #
 567 dnl # Interix requires us to set -D_ALL_SOURCE, otherwise
 568 dnl # getopt will be #included, but won't link.  <sigh>
 569 dnl #
 570 dnl #
 571 case "$host" in
 572 *-interix*)
 573         CFLAGS="$CFLAGS -D_ALL_SOURCE"
 574         ;;
 575 *-darwin*)
 576         CFLAGS="$CFLAGS -DDARWIN"
 577         LIBS="-framework DirectoryService $LIBS"
 578         ;;
 579 esac
 580
 581 AC_HEADER_DIRENT
 582 AC_HEADER_STDC
 583 AC_HEADER_TIME
 584 AC_HEADER_SYS_WAIT
 585
 586 AC_CHECK_HEADERS( \
 587         unistd.h \
 588         crypt.h \
 589         errno.h \
 590         resource.h \
 591         sys/resource.h \
 592         getopt.h \
 593         malloc.h \
 594         utmp.h \
 595         utmpx.h \
 596         signal.h \
 597         sys/select.h \
 598         syslog.h \
 599         inttypes.h \
 600         stdint.h \
 601         stdio.h \
 602         netdb.h \
 603         semaphore.h \
 604         arpa/inet.h \
 605         netinet/in.h \
 606         sys/types.h \
 607         sys/socket.h \
 608         winsock.h \
 609         sys/time.h \
 610         sys/wait.h \
 611         sys/security.h \
 612         fcntl.h \
 613         sys/fcntl.h \
 614         sys/prctl.h \
 615         sys/un.h \
 616         glob.h \
 617         prot.h \
 618         pwd.h \
 619         grp.h \
 620         stddef.h \
 621         fnmatch.h \
 622         sia.h \
 623         siad.h
 624 )
 625
 626 dnl FreeBSD requires sys/socket.h before net/if.h
 627 AC_CHECK_HEADERS(net/if.h, [], [],
 628 [#ifdef HAVE_SYS_SOCKET_H
 629 # include <sys/socket.h>
 630 # endif
 631 ])
 632
 633 REGEX=no
 634 AC_CHECK_HEADER(pcreposix.h, AC_DEFINE(HAVE_PCREPOSIX_H, [], [define this if we have the <pcreposix.h> header file]))
 635 if test "x$ac_cv_header_pcreposix_h" = "xyes"; then
 636   AC_DEFINE(HAVE_REGEX_H, [], [define if we have any regex])
 637   REGEX_EXTENDED=yes
 638   REGEX_PCRE=yes
 639   REGEX=yes
 640   LIBS="$LIBS -lpcreposix"
 641 else
 642
 643 AC_CHECK_HEADER(regex.h, AC_DEFINE(HAVE_REGEX_H, [], [define this if we have the <regex.h> header file]))
 644 if test "x$ac_cv_header_regex_h" = "xyes"; then
 645   REGEX_EXTENDED=no
 646   REGEX_PCRE=no
 647   REGEX=yes
 648   AC_EGREP_CPP(yes,
 649     [#include <regex.h>
 650      #ifdef REG_EXTENDED
 651        yes
 652      #endif
 653      ], [AC_DEFINE(HAVE_REG_EXTENDED, [], [define this if we have REG_EXTENDED (from <regex.h>)]) REGEX_EXTENDED=yes])
 654 fi
 655 fi
 656
 657 AC_SUBST(REGEX)
 658 AC_SUBST(REGEX_PCRE)
 659 AC_SUBST(REGEX_EXTENDED)
 660
 661 dnl #
 662 dnl #  other checks which require headers
 663 dnl #
 664 if test "x$ac_cv_header_sys_security_h" = "xyes" && test "x$ac_cv_header_prot_h" = "xyes"
 665 then
 666   AC_DEFINE(OSFC2, [], [define if you have OSFC2 authentication])
 667 fi
 668
 669 if test "x$ac_cv_header_sia_h" = "xyes" && test "x$ac_cv_header_siad_h" = "xyes"
 670 then
 671   AC_DEFINE(OSFSIA, [], [define if you have OSFSIA authentication])
 672 fi
 673
 674 dnl Check for OpenSSL includes.
 675 OPENSSL_INCLUDE="-DNO_OPENSSL"
 676 if test "x$WITH_OPENSSL" = xyes; then
 677   if test "x$OPENSSL_LIBS" = "x"; then
 678     AC_MSG_NOTICE([skipping test for openssl/ssl.h])
 679   else
 680     old_CPPFLAGS=$CPPFLAGS
 681     if test "x$OPENSSL_INCLUDE_DIR" != "x"; then
 682         CPPFLAGS="$CPPFLAGS -I$OPENSSL_INCLUDE_DIR"
 683     fi
 684     dnl # stupid RedHat shit
 685     CPPFLAGS="$CPPFLAGS -DOPENSSL_NO_KRB5"
 686     AC_CHECK_HEADERS( \
 687         openssl/ssl.h \
 688         openssl/crypto.h \
 689         openssl/err.h \
 690         openssl/evp.h \
 691         openssl/md5.h \
 692         openssl/md4.h \
 693         openssl/sha.h \
 694         openssl/ocsp.h \
 695         openssl/engine.h,
 696         [],
 697         OPENSSL_LIBS=
 698     )
 699     if test "x$OPENSSL_LIBS" != "x"; then
 700         AC_MSG_CHECKING([for OpenSSL version >= 0.9.7])
 701         AC_EGREP_CPP(yes,
 702             [#include <openssl/crypto.h>
 703              #if (OPENSSL_VERSION_NUMBER >= 0x00907000L)
 704              yes
 705              #endif
 706             ], goodssl="yes")
 707         if test "x$goodssl" != "xyes"; then
 708             AC_MSG_RESULT(no)
 709             OPENSSL_LIBS=
 710         else
 711             AC_MSG_RESULT(yes)
 712             if test "x$OPENSSL_INCLUDE_DIR" != "x"; then
 713                 OPENSSL_INCLUDE="-I$OPENSSL_INCLUDE_DIR -DOPENSSL_NO_KRB5"
 714             else
 715                 OPENSSL_INCLUDE="-DOPENSSL_NO_KRB5"
 716             fi
 717         fi
 718     fi
 719     CPPFLAGS=$old_CPPFLAGS
 720   fi
 721 fi
 722 AC_SUBST(OPENSSL_INCLUDE)
 723 AC_SUBST(OPENSSL_LIBS)
 724 export OPENSSL_LIBS
 725
 726 dnl Check the pcap includes for the RADIUS sniffer.
 727 if test "x$PCAP_LIBS" = x; then
 728     AC_MSG_NOTICE([skipping test for pcap.h.])
 729 else
 730     AC_CHECK_HEADER(pcap.h,
 731         AC_DEFINE(HAVE_PCAP_H, 1,
 732                 [Define to 1 if you have the <pcap.h> header file.]),
 733         [ PCAP_LIBS=
 734         AC_MSG_WARN([pcap.h not found, silently disabling the RADIUS sniffer.])
 735         ])
 736
 737     AC_CHECK_LIB(pcap, pcap_fopen_offline,
 738         [ AC_DEFINE(HAVE_PCAP_FOPEN_OFFLINE, 1,
 739                 [Define to 1 if you have the function pcap_fopen_offline.])
 740         ])
 741     AC_CHECK_LIB(pcap, pcap_dump_fopen,
 742         [ AC_DEFINE(HAVE_PCAP_DUMP_FOPEN, 1,
 743                 [Define to 1 if you have the function pcap_dump_fopen.])
 744         ])
 745 fi
 746 AC_SUBST(PCAP_LIBS)
 747
 748 dnl #############################################################
 749 dnl #
 750 dnl #  4. Checks for typedefs
 751 dnl #
 752 dnl #############################################################
 753
 754 dnl #
 755 dnl # Ensure that these are defined
 756 dnl #
 757 AC_TYPE_OFF_T
 758 AC_TYPE_PID_T
 759 AC_TYPE_SIZE_T
 760 AC_TYPE_UID_T
 761
 762 dnl check for socklen_t
 763 FR_CHECK_TYPE_INCLUDE([
 764 #ifdef HAVE_SYS_TYPES_H
 765 #include <sys/types.h>
 766 #endif
 767 #ifdef HAVE_SYS_SOCKET_H
 768 #include <sys/socket.h>
 769 #endif
 770 ],socklen_t, int, [socklen_t is generally 'int' on systems which don't use it])
 771
 772 dnl check for uint8_t
 773 FR_CHECK_TYPE_INCLUDE([
 774 #ifdef HAVE_INTTYPES_H
 775 #include <inttypes.h>
 776 #endif
 777 #ifdef HAVE_STDINT_H
 778 #include <stdint.h>
 779 #endif
 780 ],uint8_t, unsigned char, [uint8_t should be the canonical 'octet' for network traffic])
 781
 782 dnl check for uint16_t
 783 FR_CHECK_TYPE_INCLUDE([
 784 #ifdef HAVE_INTTYPES_H
 785 #include <inttypes.h>
 786 #endif
 787 #ifdef HAVE_STDINT_H
 788 #include <stdint.h>
 789 #endif
 790 ],uint16_t, unsigned short, [uint16_t should be the canonical '2 octets' for network traffic])
 791
 792 dnl check for uint32_t
 793 FR_CHECK_TYPE_INCLUDE([
 794 #ifdef HAVE_INTTYPES_H
 795 #include <inttypes.h>
 796 #endif
 797 #ifdef HAVE_STDINT_H
 798 #include <stdint.h>
 799 #endif
 800 ],uint32_t, unsigned int, [uint32_t should be the canonical 'network integer])
 801
 802 AC_CHECK_TYPE(struct in6_addr, AC_DEFINE(HAVE_STRUCT_IN6_ADDR, 1, [IPv6 address structure]), [], [
 803 #ifdef HAVE_NETINET_IN_H
 804 #include <netinet/in.h>
 805 #endif
 806 ])
 807
 808 AC_CHECK_TYPE(struct sockaddr_storage, AC_DEFINE(HAVE_STRUCT_SOCKADDR_STORAGE, 1, [Generic socket addresses]), [], [
 809 #ifdef HAVE_NETINET_IN_H
 810 #include <netinet/in.h>
 811 #endif
 812 #ifdef HAVE_SYS_SOCKET_H
 813 #include <sys/socket.h>
 814 #endif
 815 ])
 816
 817 AC_CHECK_TYPE(struct sockaddr_in6, AC_DEFINE(HAVE_STRUCT_SOCKADDR_IN6, 1, [IPv6 socket addresses]), [], [
 818 #ifdef HAVE_NETINET_IN_H
 819 #include <netinet/in.h>
 820 #endif
 821 ])
 822
 823 AC_CHECK_TYPE(struct addrinfo, AC_DEFINE(HAVE_STRUCT_ADDRINFO, 1, [Generic DNS lookups]), [], [
 824 #ifdef HAVE_SYS_TYPES_H
 825 #include <sys/types.h>
 826 #endif
 827 #ifdef HAVE_SYS_SOCKET_H
 828 #include <sys/socket.h>
 829 #endif
 830 #ifdef HAVE_NETDB_H
 831 #include <netdb.h>
 832 #endif
 833 ])
 834
 835 dnl #############################################################
 836 dnl #
 837 dnl #  5. Checks for structures and functions
 838 dnl #
 839 dnl #############################################################
 840 AC_CHECK_FUNCS( \
 841         getopt_long \
 842         lockf \
 843         strsignal \
 844         sigaction \
 845         sigprocmask \
 846         pthread_sigmask \
 847         snprintf \
 848         vsnprintf \
 849         setsid \
 850         strncasecmp \
 851         strcasecmp \
 852         localtime_r \
 853         ctime_r \
 854         gmtime_r \
 855         strsep \
 856         inet_aton \
 857         inet_pton \
 858         inet_ntop \
 859         setlinebuf \
 860         setvbuf \
 861         getusershell \
 862         initgroups \
 863         getaddrinfo \
 864         getnameinfo \
 865         closefrom \
 866         gettimeofday \
 867         getpeereid \
 868         setuid \
 869         setresuid \
 870         getresuid \
 871         strlcat \
 872         strlcpy
 873 )
 874 RADIUSD_NEED_DECLARATIONS( \
 875         crypt \
 876         strncasecmp \
 877         strcasecmp \
 878         inet_aton \
 879         setlinebuf \
 880         getusershell \
 881         endusershell
 882 )
 883
 884 AC_TYPE_SIGNAL
 885
 886 dnl # check if we have utmpx.h
 887 dnl # if so, check if struct utmpx has entry ut_xtime
 888 dnl # if not, set it to define ut_xtime == ut_tv.tv_sec
 889 if test "x$ac_cv_header_utmpx_h" = "xyes"
 890 then
 891  FR_CHECK_STRUCT_HAS_MEMBER([#include <utmpx.h>], [struct utmpx], ut_xtime)
 892  if test "x$ac_cv_type_struct_utmpx_has_ut_xtime" = "x"
 893  then
 894    AC_DEFINE(ut_xtime,ut_tv.tv_sec, [define to something if you don't have ut_xtime in struct utmpx])
 895  fi
 896 fi
 897
 898 dnl # struct ip_pktinfo
 899 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in_pktinfo], ipi_addr)
 900 if test "x$ac_cv_type_struct_in_pktinfo_has_ipi_addr" = "xyes"
 901 then
 902         AC_DEFINE(HAVE_IP_PKTINFO, [], [define if you have IP_PKTINFO (Linux)])
 903 fi
 904
 905 dnl # struct in6_pktinfo
 906 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in6_pktinfo], ipi6_addr)
 907 if test "x$ac_cv_type_struct_in6_pktinfo_has_ipi6_addr" = "xyes"
 908 then
 909         AC_DEFINE(HAVE_IN6_PKTINFO, [], [define if you have IN6_PKTINFO (Linux)])
 910 fi
 911
 912 dnl #############################################################
 913 dnl #
 914 dnl #  6. Checks for compiler characteristics
 915 dnl #
 916 dnl #############################################################
 917
 918 dnl #
 919 dnl # Ensure that these are defined
 920 dnl #
 921 AC_C_CONST
 922
 923 dnl #
 924 dnl # See if this is OS/2
 925 dnl #
 926 AC_MSG_CHECKING(type of OS)
 927 OS=`uname -s`
 928 AC_MSG_RESULT($OS)
 929 if test "$OS" = "OS/2"; then
 930         LIBPREFIX=
 931 else
 932         LIBPREFIX=lib
 933 fi
 934 AC_SUBST(LIBPREFIX)
 935
 936 AC_MSG_CHECKING(for developer gcc flags)
 937 if test "x$developer" = "xyes" -a "x$GCC" = "xyes"; then
 938   devflags="-g -Wshadow -Wpointer-arith -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -W -Wredundant-decls -Wundef -Wformat-y2k -Wno-format-extra-args -Wno-format-zero-length  -Wformat-nonliteral -Wformat-security -Wformat=2"
 939   CFLAGS="$CFLAGS $devflags"
 940   INSTALLSTRIP=""
 941   AC_MSG_RESULT(yes.  Using $devflags)
 942 else
 943   devflags=""
 944   CFLAGS="$CFLAGS -DNDEBUG"
 945   INSTALLSTRIP=""
 946   AC_MSG_RESULT(no.)
 947 fi
 948
 949 FR_TLS
 950
 951 dnl #############################################################
 952 dnl #
 953 dnl #  7. Checks for library functions
 954 dnl #
 955 dnl #############################################################
 956
 957 old_LIBS="$LIBS"
 958 LIBS="$LIBS $LIBLTDL"
 959 AC_CHECK_FUNC(lt_dladvise_init, AC_DEFINE(HAVE_LT_DLADVISE_INIT, [], [Do we have the lt_dladvise_init function]))
 960 LIBS="$old_LIBS"
 961
 962 dnl Check for libcrypt
 963 dnl We use crypt(3) which may be in libc, or in libcrypt (eg FreeBSD)
 964 AC_CHECK_LIB(crypt, crypt,
 965   CRYPTLIB="-lcrypt"
 966 )
 967 if test "$CRYPTLIB" != ""; then
 968   AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function])
 969 else
 970   AC_CHECK_FUNC(crypt, AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function]))
 971 fi
 972
 973 dnl Check for libcipher
 974 AC_CHECK_LIB(cipher, setkey,
 975    CRYPTLIB="${CRYPTLIB} -lcipher"
 976 )
 977 AC_SUBST(CRYPTLIB)
 978
 979 dnl Check the style of gethostbyaddr, in order of preference
 980 dnl GNU (_r eight args)
 981 AC_DEFINE(GNUSTYLE, [1], [GNU-Style get*byaddr_r])
 982 dnl SYSV (_r six args)
 983 AC_DEFINE(SYSVSTYLE, [2], [SYSV-Style get*byaddr_r])
 984 dnl BSD (three args, may not be thread safe)
 985 AC_DEFINE(BSDSTYLE, [3], [BSD-Style get*byaddr_r])
 986 dnl Tru64 has BSD version, but it is thread safe
 987 dnl     http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1739____.HTM
 988 dnl We need #stdio.h to define NULL on FreeBSD (at least)
 989 gethostbyaddrrstyle=""
 990 AC_MSG_CHECKING([gethostbyaddr_r() syntax])
 991 case "$host" in
 992 *-freebsd*)
 993 dnl With FreeBSD, check if there's a prototype for gethostbyaddr_r.
 994 dnl Some versions (FreeBSD 5.1?) have a symbol but no prototype - so we
 995 dnl override this test to BSDSTYLE. FreeBSD 6.2 and up have proper GNU
 996 dnl style support.
 997         AC_CHECK_DECLS([gethostbyaddr_r], [], [
 998                 AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE,
 999                         [style of gethostbyaddr_r functions ])
1000                 gethostbyaddrrstyle=BSD
1001                 AC_MSG_WARN([FreeBSD overridden to BSD-style])
1002         ], [
1003 #ifdef HAVE_NETDB_H
1004 #include <netdb.h>
1005 #endif
1006 ])
1007         ;;
1008 esac
1009 if test "x$gethostbyaddrrstyle" = "x"; then
1010         AC_TRY_LINK([
1011 #include <stdio.h>
1012 #include <netdb.h>
1013 ], [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL, NULL) ], [
1014         AC_DEFINE(GETHOSTBYADDRRSTYLE, GNUSTYLE, [style of gethostbyaddr_r functions ])
1015         gethostbyaddrrstyle=GNU
1016 ])
1017 fi
1018 if test "x$gethostbyaddrrstyle" = "x"; then
1019         AC_TRY_LINK([
1020 #include <stdio.h>
1021 #include <netdb.h>
1022 ], [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL) ] , [
1023                 AC_DEFINE(GETHOSTBYADDRRSTYLE, SYSVSTYLE, [style of gethostbyaddr_r functions ])
1024                 gethostbyaddrrstyle=SYSV
1025         ])
1026 fi
1027 if test "x$gethostbyaddrrstyle" = "x"; then
1028         AC_TRY_LINK([
1029 #include <stdio.h>
1030 #include <netdb.h>
1031 ], [ gethostbyaddr(NULL, 0, 0)  ], [
1032                 AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE, [style of gethostbyaddr_r functions ])
1033                 gethostbyaddrrstyle=BSD
1034         ])
1035 fi
1036
1037 if test "x$gethostbyaddrrstyle" = "x"; then
1038         AC_MSG_RESULT([none!  It must not exist, here.])
1039 else
1040         AC_MSG_RESULT([${gethostbyaddrrstyle}-style])
1041 fi
1042
1043 if test "x$gethostbyaddrrstyle" = "xBSD"; then
1044         AC_MSG_WARN([ ****** BSD-style gethostbyaddr might NOT be thread-safe! ****** ])
1045 fi
1046
1047 dnl Check the style of gethostbyname, in order of preference
1048 dnl GNU (_r seven args)
1049 dnl SYSV (_r five args)
1050 dnl BSD (two args, may not be thread safe)
1051 dnl Tru64 has BSD version, but it _is_ thread safe
1052 dnl     http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1946____.HTM
1053 dnl We need #stdio.h to define NULL on FreeBSD (at least)
1054 gethostbynamerstyle=""
1055 AC_MSG_CHECKING([gethostbyname_r() syntax])
1056 AC_TRY_LINK([
1057 #include <stdio.h>
1058 #include <netdb.h>
1059 ], [ gethostbyname_r(NULL, NULL, NULL, 0, NULL, NULL) ], [
1060         AC_DEFINE(GETHOSTBYNAMERSTYLE, GNUSTYLE, [style of gethostbyname_r functions ])
1061         gethostbynamerstyle=GNU
1062 ])
1063 if test "x$gethostbynamerstyle" = "x"; then
1064         AC_TRY_LINK([
1065 #include <stdio.h>
1066 #include <netdb.h>
1067 ], [ gethostbyname_r(NULL, NULL, NULL, 0, NULL) ] , [
1068                 AC_DEFINE(GETHOSTBYNAMERSTYLE, SYSVSTYLE, [style of gethostbyname_r functions ])
1069                 gethostbynamerstyle=SYSV
1070         ])
1071 fi
1072 if test "x$gethostbynamerstyle" = "x"; then
1073         AC_TRY_LINK([
1074 #include <stdio.h>
1075 #include <netdb.h>
1076 ], [ gethostbyname(NULL)  ], [
1077                 AC_DEFINE(GETHOSTBYNAMERSTYLE, BSDSTYLE, [style of gethostbyname_r functions ])
1078                 gethostbynamerstyle=BSD
1079         ])
1080 fi
1081
1082 if test "x$gethostbynamerstyle" = "x"; then
1083         AC_MSG_RESULT([none!  It must not exist, here.])
1084 else
1085         AC_MSG_RESULT([${gethostbynamerstyle}-style])
1086 fi
1087
1088 if test "x$gethostbynamerstyle" = "xBSD"; then
1089         AC_MSG_WARN([ ****** BSD-style gethostbyname might NOT be thread-safe! ****** ])
1090 fi
1091
1092 dnl check for non-posix solaris ctime_r (extra buflen int arg)
1093 AC_DEFINE(POSIXSTYLE, [1], [Posix-Style ctime_r])
1094 AC_DEFINE(SOLARISSTYLE, [2], [Solaris-Style ctime_r])
1095 ctimerstyle=""
1096 AC_MSG_CHECKING([ctime_r() syntax])
1097 AC_TRY_LINK([
1098 #include <time.h>
1099 ], [ ctime_r(NULL, NULL, 0) ], [
1100         AC_DEFINE(CTIMERSTYLE, SOLARISSTYLE, [style of ctime_r function])
1101         ctimerstyle="SOLARIS"
1102 ])
1103 if test "x$ctimerstyle" = "x"; then
1104         AC_TRY_LINK([
1105 #include <time.h>
1106 ], [ ctime_r(NULL, NULL) ], [
1107                 AC_DEFINE(CTIMERSTYLE, POSIXSTYLE, [style of ctime_r function])
1108                 ctimerstyle="POSIX"
1109         ])
1110 fi
1111
1112 if test "x$ctimerstyle" = "x"; then
1113         AC_MSG_RESULT([none!  It must not exist, here.])
1114 else
1115         AC_MSG_RESULT([${ctimerstyle}-style])
1116 fi
1117
1118 AC_SUBST(HOSTINFO, $host)
1119
1120 dnl #############################################################
1121 dnl #
1122 dnl #  8. Checks for system services
1123 dnl #
1124 dnl #############################################################
1125
1126 dnl #
1127 dnl # Figure out where libtool is located,
1128 dnl #
1129 top_builddir=`pwd`
1130 export top_builddir
1131 AC_MSG_RESULT([top_builddir=$top_builddir])
1132 dnl # AC_SUBST(top_builddir)
1133 AC_SUBST(LIBLTDL)
1134 AC_SUBST(INCLTDL)
1135
1136 dnl import libtool stuff
1137
1138 dnl #############################################################
1139 dnl #
1140 dnl #  Configure in any module directories.
1141 dnl #
1142 dnl #############################################################
1143
1144 mysubdirs=""
1145 if test "x$EXPERIMENTAL" = "xyes"; then
1146   bar=`ls -1 "${srcdir}"/src/modules/rlm_*/configure | sed 's%/configure%%'`
1147   dnl # get rid of LF's.
1148   mysubdirs=`echo $mysubdirs $bar`
1149 else
1150   dnl #
1151   dnl # Find 'configure' in ONLY the stable modules
1152   dnl #
1153   for bar in `cat "${srcdir}"/src/modules/stable`; do
1154     if test -f "${srcdir}"/src/modules/$bar/configure; then
1155       mysubdirs="$mysubdirs src/modules/$bar"
1156     fi
1157   done
1158 fi
1159
1160 dnl ############################################################
1161 dnl # make modules by list
1162 dnl #############################################################
1163 if test "x$EXPERIMENTAL" = "xyes"; then
1164   for foo in `ls -1 "${srcdir}"/src/modules | grep rlm_`; do
1165     MODULES="$MODULES $foo"
1166   done
1167 else
1168    dnl #
1169    dnl # make ONLY the stable modules
1170    dnl #
1171    for foo in `cat "${srcdir}"/src/modules/stable`; do
1172     MODULES="$MODULES $foo"
1173    done
1174 fi
1175
1176 dnl #
1177 dnl #  Don't change the variable name here.  Autoconf goes bonkers
1178 dnl #  if you do.
1179 dnl #
1180 AC_CONFIG_SUBDIRS($mysubdirs)
1181 AC_SUBST(MODULES)
1182
1183 dnl #############################################################
1184 dnl #
1185 dnl #  And finally, output the results.
1186 dnl #
1187 dnl #############################################################
1188
1189 AC_CONFIG_COMMANDS([stamp-h], [echo timestamp > src/include/stamp-h])
1190 AC_CONFIG_COMMANDS([build-radpaths-h], [(cd ./src/include && /bin/sh ./build-radpaths-h)])
1191 AC_CONFIG_COMMANDS([main-chmod], [(cd ./src/main   && chmod +x checkrad.pl radlast radtest)])
1192 AC_CONFIG_COMMANDS([scripts-chmod], [(cd ./scripts    && chmod +x rc.radiusd radwatch radiusd.cron.daily radiusd.cron.monthly cryptpasswd)])
1193
1194 dnl #
1195 dnl #  Substitute whatever libraries we found to be necessary
1196 dnl #
1197 AC_SUBST(LIBS)
1198 AC_SUBST(INSTALLSTRIP)
1199
1200 USE_SHARED_LIBS=$enable_shared
1201 AC_SUBST(USE_SHARED_LIBS)
1202 USE_STATIC_LIBS=$enable_static
1203 AC_SUBST(USE_STATIC_LIBS)
1204 AC_SUBST(STATIC_MODULES)
1205 AC_SUBST(RADIUSD_MAJOR_VERSION)
1206 AC_SUBST(RADIUSD_MINOR_VERSION)
1207 AC_SUBST(RADIUSD_VERSION)
1208
1209 AC_OUTPUT(\
1210         ./Make.inc \
1211         ./src/include/build-radpaths-h \
1212         ./src/main/Makefile \
1213         ./src/main/radsniff.mk \
1214         ./src/main/checkrad.pl \
1215         ./src/main/radlast \
1216         ./src/main/radtest \
1217         ./scripts/rc.radiusd \
1218         ./scripts/radwatch \
1219         ./scripts/radiusd.cron.daily \
1220         ./scripts/radiusd.cron.monthly \
1221         ./scripts/cryptpasswd \
1222         ./raddb/dictionary \
1223         ./raddb/radrelay.conf \
1224         ./raddb/radiusd.conf
1225 )