src/moonshot-identities-manager.vala

   1 /*
   2  * Copyright (c) 2011-2014, JANET(UK)
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  *
   9  * 1. Redistributions of source code must retain the above copyright
  10  *    notice, this list of conditions and the following disclaimer.
  11  *
  12  * 2. Redistributions in binary form must reproduce the above copyright
  13  *    notice, this list of conditions and the following disclaimer in the
  14  *    documentation and/or other materials provided with the distribution.
  15  *
  16  * 3. Neither the name of JANET(UK) nor the names of its contributors
  17  *    may be used to endorse or promote products derived from this software
  18  *    without specific prior written permission.
  19  *
  20  * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
  21  * AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  22  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  23  * ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE
  24  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  25  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  26  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  27  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  28  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  29  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  30  * SUCH DAMAGE.
  31 */
  32 using Gee;
  33
  34 public class Password {
  35 #if GNOME_KEYRING
  36     private unowned string _password;
  37     public string password {
  38         get {
  39             return _password;
  40         }
  41         set {
  42             if (_password != null) {
  43                 GnomeKeyring.memory_free((void *)_password);
  44                 _password = null;
  45             }
  46             if (value != null)
  47                 _password = GnomeKeyring.memory_strdup(value);
  48         }
  49     }
  50 #else
  51     public string password { get; set; default = null; }
  52 #endif
  53
  54     public Password(string in_password) {
  55         password = in_password;
  56     }
  57
  58     ~Password() {
  59         password = null;
  60     }
  61 }
  62
  63 public class PasswordHashTable : Object {
  64     private HashTable<string, Password> password_table;
  65
  66     private static string ComputeHashKey(IdCard card, IIdentityCardStore store) {
  67         return "%s_store_%d".printf( card.display_name, store.get_store_type() );
  68     }
  69
  70     public void CachePassword(IdCard card, IIdentityCardStore store) {
  71         password_table.replace(ComputeHashKey(card, store), new Password(card.password));
  72     }
  73
  74     public void RemovePassword(IdCard card, IIdentityCardStore store) {
  75         password_table.remove(ComputeHashKey(card, store));
  76     }
  77     public void RetrievePassword(IdCard card, IIdentityCardStore store) {
  78         weak Password password = password_table.lookup(ComputeHashKey(card, store));
  79         if (password != null) {
  80             card.password = password.password;
  81         }
  82     }
  83     public PasswordHashTable() {
  84         password_table = new HashTable<string, Password>(GLib.str_hash, GLib.str_equal);
  85     }
  86 }
  87
  88 public class IdentityManagerModel : Object {
  89     static MoonshotLogger logger = get_logger("IdentityManagerModel");
  90
  91     private const string FILE_NAME = "identities.txt";
  92     private PasswordHashTable password_table;
  93     private IIdentityCardStore store;
  94     public LinkedList<IdCard>  get_card_list() {
  95         var identities = store.get_card_list();
  96         identities.sort((a, b) => {
  97                 IdCard id_a = (IdCard )a;
  98                 IdCard id_b = (IdCard )b;
  99                 if (id_a.is_no_identity() && !id_b.is_no_identity()) {
 100                     return -1;
 101                 } else if (id_b.is_no_identity() && !id_a.is_no_identity()) {
 102                     return 1;
 103                 }
 104                 return strcmp(id_a.display_name, id_b.display_name);
 105             });
 106         if (identities.is_empty || !identities[0].is_no_identity())
 107             identities.insert(0, IdCard.NewNoIdentity());
 108         foreach (IdCard id_card in identities) {
 109             if (!id_card.store_password) {
 110                 password_table.RetrievePassword(id_card, store);
 111             }
 112         }
 113         return identities;
 114     }
 115     public signal void card_list_changed();
 116
 117     /* This method finds a valid display name */
 118     public bool display_name_is_valid(string name,
 119                                       out string? candidate)
 120     {
 121         if (&candidate != null)
 122             candidate = null;
 123         foreach (IdCard id_card in this.store.get_card_list())
 124         {
 125             if (id_card.display_name == name)
 126             {
 127                 if (&candidate != null)
 128                 {
 129                     for (int i = 0; i < 1000; i++)
 130                     {
 131                         string tmp = "%s %d".printf(name, i);
 132                         if (display_name_is_valid(tmp, null))
 133                         {
 134                             candidate = tmp;
 135                             break;
 136                         }
 137                     }
 138                 }
 139                 return false;
 140             }
 141         }
 142         return true;
 143     }
 144
 145     private bool remove_duplicates(IdCard new_card, out ArrayList<IdCard>? old_duplicates)
 146     {
 147         ArrayList<IdCard> dups = new ArrayList<IdCard>();
 148         var cards = this.store.get_card_list();
 149         foreach (IdCard id_card in cards) {
 150             if ((new_card != id_card) && (id_card.nai == new_card.nai)) {
 151                 dups.add(id_card);
 152             }
 153         }
 154
 155         foreach (IdCard id_card in dups) {
 156             logger.trace("removing duplicate id for '%s'\n".printf(new_card.nai));
 157             remove_card_internal(id_card);
 158
 159             if (new_card.trust_anchor.Compare(id_card.trust_anchor) == 0) {
 160                 logger.trace("Old and new cards have same trust anchor. Re-using the datetime_added field from the old card.");
 161                 new_card.trust_anchor.set_datetime_added(id_card.trust_anchor.datetime_added);
 162             }
 163         }
 164
 165         if (&old_duplicates != null) {
 166             old_duplicates = dups;
 167         }
 168
 169         return (dups.size > 0);
 170     }
 171
 172     public IdCard? find_id_card(string nai, bool force_flat_file_store) {
 173         IdCard? retval = null;
 174         IIdentityCardStore.StoreType saved_store_type = get_store_type();
 175         if (force_flat_file_store)
 176             set_store_type(IIdentityCardStore.StoreType.FLAT_FILE);
 177
 178         foreach (IdCard id in get_card_list()) {
 179             if (id.nai == nai) {
 180                 retval = id;
 181                 break;
 182             }
 183         }
 184         set_store_type(saved_store_type);
 185         if (force_flat_file_store &&
 186             (saved_store_type != IIdentityCardStore.StoreType.FLAT_FILE))
 187             card_list_changed();
 188         return retval;
 189     }
 190
 191     public void add_card(IdCard card, bool force_flat_file_store, out ArrayList<IdCard>? old_duplicates=null) {
 192         if (card.temporary) {
 193             logger.trace("add_card: card is temporary; returning.");
 194             return;
 195         }
 196
 197         string candidate;
 198         IIdentityCardStore.StoreType saved_store_type = get_store_type();
 199
 200         if (force_flat_file_store)
 201             set_store_type(IIdentityCardStore.StoreType.FLAT_FILE);
 202
 203         remove_duplicates(card, out old_duplicates);
 204
 205         if (!display_name_is_valid(card.display_name, out candidate))
 206         {
 207             card.display_name = candidate;
 208         }
 209
 210         if (!card.store_password)
 211             password_table.CachePassword(card, store);
 212
 213         logger.trace("add_card: Adding card '%s' with services: '%s'"
 214                      .printf(card.display_name, card.get_services_string("; ")));
 215
 216         store.add_card(card);
 217         set_store_type(saved_store_type);
 218         card_list_changed();
 219     }
 220
 221     public IdCard update_card(IdCard card) {
 222         logger.trace("update_card");
 223
 224         IdCard retval;
 225         if (card.temporary) {
 226             retval = card;
 227             return retval;
 228         }
 229
 230         if (!card.store_password)
 231             password_table.CachePassword(card, store);
 232         else
 233             password_table.RemovePassword(card, store);
 234         retval = store.update_card(card);
 235         card_list_changed();
 236         return retval;
 237     }
 238
 239     private bool remove_card_internal(IdCard card) {
 240         if (card.temporary)
 241             return false;
 242         password_table.RemovePassword(card, store);
 243         return store.remove_card(card);
 244     }
 245
 246     public bool remove_card(IdCard card) {
 247         if (remove_card_internal(card)) {
 248             logger.trace(@"remove_card: Removed '$(card.display_name)'");
 249             card_list_changed();
 250             return true;
 251         }
 252         logger.warn(@"remove_card: Couldn't remove '$(card.display_name)'");
 253         return false;
 254     }
 255
 256     // The name is misleading: This not only sets the store type,
 257     // it also creates a new store instance, which loads the card data.
 258     public void set_store_type(IIdentityCardStore.StoreType type) {
 259         if ((store != null) && (store.get_store_type() == type))
 260             return;
 261         switch (type) {
 262             #if GNOME_KEYRING
 263         case IIdentityCardStore.StoreType.KEYRING:
 264             store = new KeyringStore();
 265             break;
 266             #endif
 267         case IIdentityCardStore.StoreType.FLAT_FILE:
 268         default:
 269             store = new LocalFlatFileStore();
 270             break;
 271         }
 272
 273         // Loop through the loaded IDs. If any trust anchors are old enough that we didn't record
 274         // the datetime_added, add it now.
 275         string before_now = _("Before ") + TrustAnchor.format_datetime_now();
 276         bool save_needed = false;
 277         foreach (IdCard id in this.store.get_card_list()) {
 278             if (!id.trust_anchor.is_empty() && id.trust_anchor.datetime_added == "") {
 279                 logger.trace("set_store_type : Set ta_datetime_added for old trust anchor on '%s' to '%s'".printf(id.display_name, before_now));
 280                 id.trust_anchor.set_datetime_added(before_now);
 281                 save_needed = true;
 282             }
 283         }
 284         if (save_needed) {
 285             this.store.store_id_cards();
 286         }
 287     }
 288
 289     public IIdentityCardStore.StoreType get_store_type() {
 290         return store.get_store_type();
 291     }
 292
 293     public bool HasNonTrivialIdentities() {
 294         foreach (IdCard card in this.store.get_card_list()) {
 295             // The 'NoIdentity' card is non-trivial if it has services or rules.
 296             // All other cards are automatically non-trivial.
 297             if ((!card.is_no_identity()) ||
 298                 (card.services.size > 0) ||
 299                 (card.rules.length > 0)) {
 300                 return true;
 301             }
 302         }
 303         return false;
 304     }
 305
 306
 307     private IdentityManagerApp parent;
 308
 309     public IdentityManagerModel(IdentityManagerApp parent_app, IIdentityCardStore.StoreType store_type) {
 310         logger.trace("IdentityManagerModel: store_type=" + store_type.to_string());
 311         parent = parent_app;
 312         password_table = new PasswordHashTable();
 313         set_store_type(store_type);
 314     }
 315 }