src/moonshot-identity-manager-app.vala

   1 using Gtk;
   2
   3 class IdentityManagerApp : Window {
   4     public IdentityManagerModel model;
   5     private IdentityManagerView view;
   6     private MoonshotServer ipc_server;
   7     private const int WINDOW_WIDTH = 400;
   8     private const int WINDOW_HEIGHT = 500;
   9     public void show() {
  10         view.show();
  11     }
  12     public IdentityManagerApp () {
  13         model = new IdentityManagerModel(this);
  14         view = new IdentityManagerView(this);
  15         init_ipc_server ();
  16         view.show();
  17     }
  18
  19 #if IPC_MSRPC
  20     private void init_ipc_server ()
  21     {
  22         // Errors will currently be sent via g_log - ie. to an
  23         // obtrusive message box, on Windows
  24         //
  25         this.ipc_server = MoonshotServer.get_instance ();
  26         MoonshotServer.start (this.view);
  27     }
  28 #elif IPC_DBUS_GLIB
  29     private void init_ipc_server ()
  30     {
  31
  32         try {
  33             var conn = DBus.Bus.get (DBus.BusType.SESSION);
  34             dynamic DBus.Object bus = conn.get_object ("org.freedesktop.DBus",
  35                                                        "/org/freedesktop/DBus",
  36                                                        "org.freedesktop.DBus");
  37
  38             // try to register service in session bus
  39             uint reply = bus.request_name ("org.janet.Moonshot", (uint) 0);
  40             assert (reply == DBus.RequestNameReply.PRIMARY_OWNER);
  41
  42             this.ipc_server = new MoonshotServer (this.view);
  43             conn.register_object ("/org/janet/moonshot", ipc_server);
  44         }
  45         catch (DBus.Error e)
  46         {
  47             stderr.printf ("%s\n", e.message);
  48         }
  49     }
  50 #else
  51     private void bus_acquired_cb (DBusConnection conn)
  52     {
  53         try {
  54             conn.register_object ("/org/janet/moonshot", ipc_server);
  55         }
  56         catch (Error e)
  57         {
  58             stderr.printf ("%s\n", e.message);
  59         }
  60     }
  61
  62     private void init_ipc_server ()
  63     {
  64         this.ipc_server = new MoonshotServer (this.view);
  65         GLib.Bus.own_name (GLib.BusType.SESSION,
  66                            "org.janet.Moonshot",
  67                            GLib.BusNameOwnerFlags.NONE,
  68                            bus_acquired_cb,
  69                            (conn, name) => {},
  70                            (conn, name) => {
  71                                error ("Couldn't own name %s on DBus.", name);
  72                            });
  73     }
  74 #endif
  75 }
  76
  77
  78 public static int main(string[] args){
  79         Gtk.init(ref args);
  80
  81 #if OS_WIN32
  82         // Force specific theme settings on Windows without requiring a gtkrc file
  83         Gtk.Settings settings = Gtk.Settings.get_default ();
  84         settings.set_string_property ("gtk-theme-name", "ms-windows", "moonshot");
  85         settings.set_long_property ("gtk-menu-images", 0, "moonshot");
  86 #endif
  87
  88         Intl.bindtextdomain (Config.GETTEXT_PACKAGE, Config.LOCALEDIR);
  89         Intl.bind_textdomain_codeset (Config.GETTEXT_PACKAGE, "UTF-8");
  90         Intl.textdomain (Config.GETTEXT_PACKAGE);
  91
  92         var app = new IdentityManagerApp();
  93
  94         app.show();
  95
  96         Gtk.main();
  97
  98         return 0;
  99     }
 100