--- /dev/null
+dnl @synopsis ACX_PTHREAD([ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])\r
+dnl\r
+dnl This macro figures out how to build C programs using POSIX\r
+dnl threads. It sets the PTHREAD_LIBS output variable to the threads\r
+dnl library and linker flags, and the PTHREAD_CFLAGS output variable\r
+dnl to any special C compiler flags that are needed. (The user can also\r
+dnl force certain compiler flags/libs to be tested by setting these\r
+dnl environment variables.)\r
+dnl\r
+dnl Also sets PTHREAD_CC to any special C compiler that is needed for\r
+dnl multi-threaded programs (defaults to the value of CC otherwise).\r
+dnl (This is necessary on AIX to use the special cc_r compiler alias.)\r
+dnl\r
+dnl If you are only building threads programs, you may wish to\r
+dnl use these variables in your default LIBS, CFLAGS, and CC:\r
+dnl\r
+dnl LIBS="$PTHREAD_LIBS $LIBS"\r
+dnl CFLAGS="$CFLAGS $PTHREAD_CFLAGS"\r
+dnl CC="$PTHREAD_CC"\r
+dnl\r
+dnl In addition, if the PTHREAD_CREATE_JOINABLE thread-attribute\r
+dnl constant has a nonstandard name, defines PTHREAD_CREATE_JOINABLE\r
+dnl to that name (e.g. PTHREAD_CREATE_UNDETACHED on AIX).\r
+dnl\r
+dnl ACTION-IF-FOUND is a list of shell commands to run if a threads\r
+dnl library is found, and ACTION-IF-NOT-FOUND is a list of commands\r
+dnl to run it if it is not found. If ACTION-IF-FOUND is not specified,\r
+dnl the default action will define HAVE_PTHREAD.\r
+dnl\r
+dnl Please let the authors know if this macro fails on any platform,\r
+dnl or if you have any other suggestions or comments. This macro was\r
+dnl based on work by SGJ on autoconf scripts for FFTW (www.fftw.org)\r
+dnl (with help from M. Frigo), as well as ac_pthread and hb_pthread\r
+dnl macros posted by AFC to the autoconf macro repository. We are also\r
+dnl grateful for the helpful feedback of numerous users.\r
+dnl\r
+dnl @author Steven G. Johnson <stevenj@alum.mit.edu> and Alejandro Forero Cuervo <bachue@bachue.com>\r
+\r
+AC_DEFUN([ACX_PTHREAD], [\r
+AC_REQUIRE([AC_CANONICAL_HOST])\r
+AC_LANG_SAVE\r
+AC_LANG_C\r
+acx_pthread_ok=no\r
+\r
+# We used to check for pthread.h first, but this fails if pthread.h\r
+# requires special compiler flags (e.g. on True64 or Sequent).\r
+# It gets checked for in the link test anyway.\r
+\r
+# First of all, check if the user has set any of the PTHREAD_LIBS,\r
+# etcetera environment variables, and if threads linking works using\r
+# them:\r
+if test x"$PTHREAD_LIBS$PTHREAD_CFLAGS" != x; then\r
+ save_CFLAGS="$CFLAGS"\r
+ CFLAGS="$CFLAGS $PTHREAD_CFLAGS"\r
+ save_LIBS="$LIBS"\r
+ LIBS="$PTHREAD_LIBS $LIBS"\r
+ AC_MSG_CHECKING([for pthread_join in LIBS=$PTHREAD_LIBS with CFLAGS=$PTHREAD_CFLAGS])\r
+ AC_TRY_LINK_FUNC(pthread_join, acx_pthread_ok=yes)\r
+ AC_MSG_RESULT($acx_pthread_ok)\r
+ if test x"$acx_pthread_ok" = xno; then\r
+ PTHREAD_LIBS=""\r
+ PTHREAD_CFLAGS=""\r
+ fi\r
+ LIBS="$save_LIBS"\r
+ CFLAGS="$save_CFLAGS"\r
+fi\r
+\r
+# We must check for the threads library under a number of different\r
+# names; the ordering is very important because some systems\r
+# (e.g. DEC) have both -lpthread and -lpthreads, where one of the\r
+# libraries is broken (non-POSIX).\r
+\r
+# Create a list of thread flags to try. Items starting with a "-" are\r
+# C compiler flags, and other items are library names, except for "none"\r
+# which indicates that we try without any flags at all.\r
+\r
+acx_pthread_flags="pthreads none -Kthread -kthread lthread -pthread -pthreads -mthreads pthread --thread-safe -mt"\r
+\r
+# The ordering *is* (sometimes) important. Some notes on the\r
+# individual items follow:\r
+\r
+# pthreads: AIX (must check this before -lpthread)\r
+# none: in case threads are in libc; should be tried before -Kthread and\r
+# other compiler flags to prevent continual compiler warnings\r
+# -Kthread: Sequent (threads in libc, but -Kthread needed for pthread.h)\r
+# -kthread: FreeBSD kernel threads (preferred to -pthread since SMP-able)\r
+# lthread: LinuxThreads port on FreeBSD (also preferred to -pthread)\r
+# -pthread: Linux/gcc (kernel threads), BSD/gcc (userland threads)\r
+# -pthreads: Solaris/gcc\r
+# -mthreads: Mingw32/gcc, Lynx/gcc\r
+# -mt: Sun Workshop C (may only link SunOS threads [-lthread], but it\r
+# doesn't hurt to check since this sometimes defines pthreads too;\r
+# also defines -D_REENTRANT)\r
+# pthread: Linux, etcetera\r
+# --thread-safe: KAI C++\r
+\r
+case "${host_cpu}-${host_os}" in\r
+ *solaris*)\r
+\r
+ # On Solaris (at least, for some versions), libc contains stubbed\r
+ # (non-functional) versions of the pthreads routines, so link-based\r
+ # tests will erroneously succeed. (We need to link with -pthread or\r
+ # -lpthread.) (The stubs are missing pthread_cleanup_push, or rather\r
+ # a function called by this macro, so we could check for that, but\r
+ # who knows whether they'll stub that too in a future libc.) So,\r
+ # we'll just look for -pthreads and -lpthread first:\r
+\r
+ acx_pthread_flags="-pthread -pthreads pthread -mt $acx_pthread_flags"\r
+ ;;\r
+esac\r
+\r
+if test x"$acx_pthread_ok" = xno; then\r
+for flag in $acx_pthread_flags; do\r
+\r
+ case $flag in\r
+ none)\r
+ AC_MSG_CHECKING([whether pthreads work without any flags])\r
+ ;;\r
+\r
+ -*)\r
+ AC_MSG_CHECKING([whether pthreads work with $flag])\r
+ PTHREAD_CFLAGS="$flag"\r
+ ;;\r
+\r
+ *)\r
+ AC_MSG_CHECKING([for the pthreads library -l$flag])\r
+ PTHREAD_LIBS="-l$flag"\r
+ ;;\r
+ esac\r
+\r
+ save_LIBS="$LIBS"\r
+ save_CFLAGS="$CFLAGS"\r
+ LIBS="$PTHREAD_LIBS $LIBS"\r
+ CFLAGS="$CFLAGS $PTHREAD_CFLAGS"\r
+\r
+ # Check for various functions. We must include pthread.h,\r
+ # since some functions may be macros. (On the Sequent, we\r
+ # need a special flag -Kthread to make this header compile.)\r
+ # We check for pthread_join because it is in -lpthread on IRIX\r
+ # while pthread_create is in libc. We check for pthread_attr_init\r
+ # due to DEC craziness with -lpthreads. We check for\r
+ # pthread_cleanup_push because it is one of the few pthread\r
+ # functions on Solaris that doesn't have a non-functional libc stub.\r
+ # We try pthread_create on general principles.\r
+ AC_TRY_LINK([#include <pthread.h>],\r
+ [pthread_t th; pthread_join(th, 0);\r
+ pthread_attr_init(0); pthread_cleanup_push(0, 0);\r
+ pthread_create(0,0,0,0); pthread_cleanup_pop(0); ],\r
+ [acx_pthread_ok=yes])\r
+\r
+ LIBS="$save_LIBS"\r
+ CFLAGS="$save_CFLAGS"\r
+\r
+ AC_MSG_RESULT($acx_pthread_ok)\r
+ if test "x$acx_pthread_ok" = xyes; then\r
+ break;\r
+ fi\r
+\r
+ PTHREAD_LIBS=""\r
+ PTHREAD_CFLAGS=""\r
+done\r
+fi\r
+\r
+# Various other checks:\r
+if test "x$acx_pthread_ok" = xyes; then\r
+ save_LIBS="$LIBS"\r
+ LIBS="$PTHREAD_LIBS $LIBS"\r
+ save_CFLAGS="$CFLAGS"\r
+ CFLAGS="$CFLAGS $PTHREAD_CFLAGS"\r
+\r
+ # Detect AIX lossage: threads are created detached by default\r
+ # and the JOINABLE attribute has a nonstandard name (UNDETACHED).\r
+ AC_MSG_CHECKING([for joinable pthread attribute])\r
+ AC_TRY_LINK([#include <pthread.h>],\r
+ [int attr=PTHREAD_CREATE_JOINABLE;],\r
+ ok=PTHREAD_CREATE_JOINABLE, ok=unknown)\r
+ if test x"$ok" = xunknown; then\r
+ AC_TRY_LINK([#include <pthread.h>],\r
+ [int attr=PTHREAD_CREATE_UNDETACHED;],\r
+ ok=PTHREAD_CREATE_UNDETACHED, ok=unknown)\r
+ fi\r
+ if test x"$ok" != xPTHREAD_CREATE_JOINABLE; then\r
+ AC_DEFINE(PTHREAD_CREATE_JOINABLE, $ok,\r
+ [Define to the necessary symbol if this constant\r
+ uses a non-standard name on your system.])\r
+ fi\r
+ AC_MSG_RESULT(${ok})\r
+ if test x"$ok" = xunknown; then\r
+ AC_MSG_WARN([we do not know how to create joinable pthreads])\r
+ fi\r
+\r
+ AC_MSG_CHECKING([if more special flags are required for pthreads])\r
+ flag=no\r
+ case "${host_cpu}-${host_os}" in\r
+ *-aix* | *-freebsd*) flag="-D_THREAD_SAFE";;\r
+ *-osf* | *-hpux*) flag="-D_REENTRANT";;\r
+ *solaris*)\r
+ if test "$GCC" = "yes"; then\r
+ flag="-D_REENTRANT"\r
+ else\r
+ flag="-mt -D_REENTRANT"\r
+ fi\r
+ ;;\r
+ esac\r
+ AC_MSG_RESULT(${flag})\r
+ if test "x$flag" != xno; then\r
+ PTHREAD_CFLAGS="$flag $PTHREAD_CFLAGS"\r
+ fi\r
+\r
+ LIBS="$save_LIBS"\r
+ CFLAGS="$save_CFLAGS"\r
+\r
+ # More AIX lossage: must compile with cc_r\r
+ AC_CHECK_PROG(PTHREAD_CC, cc_r, cc_r, ${CC})\r
+else\r
+ PTHREAD_CC="$CC"\r
+fi\r
+\r
+AC_SUBST(PTHREAD_LIBS)\r
+AC_SUBST(PTHREAD_CFLAGS)\r
+AC_SUBST(PTHREAD_CC)\r
+\r
+# Finally, execute ACTION-IF-FOUND/ACTION-IF-NOT-FOUND:\r
+if test x"$acx_pthread_ok" = xyes; then\r
+ ifelse([$1],,AC_DEFINE(HAVE_PTHREAD,1,[Define if you have POSIX threads libraries and header files.]),[$1])\r
+ :\r
+else\r
+ acx_pthread_ok=no\r
+ $2\r
+fi\r
+AC_LANG_RESTORE\r
+])dnl ACX_PTHREAD\r
projects / shibboleth / xmltooling.git / blobdiff