doxygen.m4

   1 # This file is part of Autoconf.                       -*- Autoconf -*-
   2
   3 # Copyright (C) 2004 Oren Ben-Kiki
   4 # This file is distributed under the same terms as the Autoconf macro files.
   5
   6 # Generate automatic documentation using Doxygen. Works in concert with the
   7 # aminclude.m4 file and a compatible doxygen configuration file. Defines the
   8 # following public macros:
   9 #
  10 # DX_???_FEATURE(ON|OFF) - control the default setting fo a Doxygen feature.
  11 # Supported features are 'DOXYGEN' itself, 'DOT' for generating graphics,
  12 # 'HTML' for plain HTML, 'CHM' for compressed HTML help (for MS users), 'CHI'
  13 # for generating a seperate .chi file by the .chm file, and 'MAN', 'RTF',
  14 # 'XML', 'PDF' and 'PS' for the appropriate output formats. The environment
  15 # variable DOXYGEN_PAPER_SIZE may be specified to override the default 'a4wide'
  16 # paper size.
  17 #
  18 # By default, HTML, PDF and PS documentation is generated as this seems to be
  19 # the most popular and portable combination. MAN pages created by Doxygen are
  20 # usually problematic, though by picking an appropriate subset and doing some
  21 # massaging they might be better than nothing. CHM and RTF are specific for MS
  22 # (note that you can't generate both HTML and CHM at the same time). The XML is
  23 # rather useless unless you apply specialized post-processing to it.
  24 #
  25 # The macro mainly controls the default state of the feature. The use can
  26 # override the default by specifying --enable or --disable. The macros ensure
  27 # that contradictory flags are not given (e.g., --enable-doxygen-html and
  28 # --enable-doxygen-chm, --enable-doxygen-anything with --disable-doxygen, etc.)
  29 # Finally, each feature will be automatically disabled (with a warning) if the
  30 # required programs are missing.
  31 #
  32 # Once all the feature defaults have been specified, call DX_INIT_DOXYGEN with
  33 # the following parameters: a one-word name for the project for use as a
  34 # filename base etc., an optional configuration file name (the default is
  35 # 'Doxyfile', the same as Doxygen's default), and an optional output directory
  36 # name (the default is 'doxygen-doc').
  37
  38 ## ----------##
  39 ## Defaults. ##
  40 ## ----------##
  41
  42 DX_ENV=""
  43 AC_DEFUN([DX_FEATURE_doc],  ON)
  44 AC_DEFUN([DX_FEATURE_dot],  ON)
  45 AC_DEFUN([DX_FEATURE_man],  OFF)
  46 AC_DEFUN([DX_FEATURE_html], ON)
  47 AC_DEFUN([DX_FEATURE_chm],  OFF)
  48 AC_DEFUN([DX_FEATURE_chi],  OFF)
  49 AC_DEFUN([DX_FEATURE_rtf],  OFF)
  50 AC_DEFUN([DX_FEATURE_xml],  OFF)
  51 AC_DEFUN([DX_FEATURE_pdf],  ON)
  52 AC_DEFUN([DX_FEATURE_ps],   ON)
  53
  54 # Compatibility with older autoconf versions.
  55 m4_ifdef([AS_HELP_STRING], , [m4_define([AS_HELP_STRING], m4_defn([AC_HELP_STRING]))])
  56
  57 ## --------------- ##
  58 ## Private macros. ##
  59 ## --------------- ##
  60
  61 # DX_ENV_APPEND(VARIABLE, VALUE)
  62 # ------------------------------
  63 # Append VARIABLE="VALUE" to DX_ENV for invoking doxygen.
  64 AC_DEFUN([DX_ENV_APPEND], [AC_SUBST([DX_ENV], ["$DX_ENV $1='$2'"])])
  65
  66 # DX_DIRNAME_EXPR
  67 # ---------------
  68 # Expand into a shell expression prints the directory part of a path.
  69 AC_DEFUN([DX_DIRNAME_EXPR],
  70          [[expr ".$1" : '\(\.\)[^/]*$' \| "x$1" : 'x\(.*\)/[^/]*$']])
  71
  72 # DX_IF_FEATURE(FEATURE, IF-ON, IF-OFF)
  73 # -------------------------------------
  74 # Expands according to the M4 (static) status of the feature.
  75 AC_DEFUN([DX_IF_FEATURE], [ifelse(DX_FEATURE_$1, ON, [$2], [$3])])
  76
  77 # DX_REQUIRE_PROG(VARIABLE, PROGRAM)
  78 # ----------------------------------
  79 # Require the specified program to be found for the DX_CURRENT_FEATURE to work.
  80 AC_DEFUN([DX_REQUIRE_PROG], [
  81 AC_PATH_TOOL([$1], [$2])
  82 if test "$DX_FLAG_[]DX_CURRENT_FEATURE$$1" = 1; then
  83     AC_MSG_WARN([$2 not found - will not DX_CURRENT_DESCRIPTION])
  84     AC_SUBST([DX_FLAG_]DX_CURRENT_FEATURE, 0)
  85 fi
  86 ])
  87
  88 # DX_TEST_FEATURE(FEATURE)
  89 # ------------------------
  90 # Expand to a shell expression testing whether the feature is active.
  91 AC_DEFUN([DX_TEST_FEATURE], [test "$DX_FLAG_$1" = 1])
  92
  93 # DX_CHECK_DEPEND(REQUIRED_FEATURE, REQUIRED_STATE)
  94 # -------------------------------------------------
  95 # Verify that a required features has the right state before trying to turn on
  96 # the DX_CURRENT_FEATURE.
  97 AC_DEFUN([DX_CHECK_DEPEND], [
  98 test "$DX_FLAG_$1" = "$2" \
  99 || AC_MSG_ERROR([doxygen-DX_CURRENT_FEATURE ifelse([$2], 1,
 100                             requires, contradicts) doxygen-DX_CURRENT_FEATURE])
 101 ])
 102
 103 # DX_CLEAR_DEPEND(FEATURE, REQUIRED_FEATURE, REQUIRED_STATE)
 104 # ----------------------------------------------------------
 105 # Turn off the DX_CURRENT_FEATURE if the required feature is off.
 106 AC_DEFUN([DX_CLEAR_DEPEND], [
 107 test "$DX_FLAG_$1" = "$2" || AC_SUBST([DX_FLAG_]DX_CURRENT_FEATURE, 0)
 108 ])
 109
 110 # DX_FEATURE_ARG(FEATURE, DESCRIPTION,
 111 #                CHECK_DEPEND, CLEAR_DEPEND,
 112 #                REQUIRE, DO-IF-ON, DO-IF-OFF)
 113 # --------------------------------------------
 114 # Parse the command-line option controlling a feature. CHECK_DEPEND is called
 115 # if the user explicitly turns the feature on (and invokes DX_CHECK_DEPEND),
 116 # otherwise CLEAR_DEPEND is called to turn off the default state if a required
 117 # feature is disabled (using DX_CLEAR_DEPEND). REQUIRE performs additional
 118 # requirement tests (DX_REQUIRE_PROG). Finally, an automake flag is set and
 119 # DO-IF-ON or DO-IF-OFF are called according to the final state of the feature.
 120 AC_DEFUN([DX_ARG_ABLE], [
 121     AC_DEFUN([DX_CURRENT_FEATURE], [$1])
 122     AC_DEFUN([DX_CURRENT_DESCRIPTION], [$2])
 123     AC_ARG_ENABLE(doxygen-$1,
 124                   [AS_HELP_STRING(DX_IF_FEATURE([$1], [--disable-doxygen-$1],
 125                                                       [--enable-doxygen-$1]),
 126                                   DX_IF_FEATURE([$1], [don't $2], [$2]))],
 127                   [
 128 case "$enableval" in
 129 #(
 130 y|Y|yes|Yes|YES)
 131     AC_SUBST([DX_FLAG_$1], 1)
 132     $3
 133 ;; #(
 134 n|N|no|No|NO)
 135     AC_SUBST([DX_FLAG_$1], 0)
 136 ;; #(
 137 *)
 138     AC_MSG_ERROR([invalid value '$enableval' given to doxygen-$1])
 139 ;;
 140 esac
 141 ], [
 142 AC_SUBST([DX_FLAG_$1], [DX_IF_FEATURE([$1], 1, 0)])
 143 $4
 144 ])
 145 if DX_TEST_FEATURE([$1]); then
 146     $5
 147     :
 148 fi
 149 if DX_TEST_FEATURE([$1]); then
 150     AM_CONDITIONAL(DX_COND_$1, :)
 151     $6
 152     :
 153 else
 154     AM_CONDITIONAL(DX_COND_$1, false)
 155     $7
 156     :
 157 fi
 158 ])
 159
 160 ## -------------- ##
 161 ## Public macros. ##
 162 ## -------------- ##
 163
 164 # DX_XXX_FEATURE(DEFAULT_STATE)
 165 # -----------------------------
 166 AC_DEFUN([DX_DOXYGEN_FEATURE], [AC_DEFUN([DX_FEATURE_doc],  [$1])])
 167 AC_DEFUN([DX_MAN_FEATURE],     [AC_DEFUN([DX_FEATURE_man],  [$1])])
 168 AC_DEFUN([DX_HTML_FEATURE],    [AC_DEFUN([DX_FEATURE_html], [$1])])
 169 AC_DEFUN([DX_CHM_FEATURE],     [AC_DEFUN([DX_FEATURE_chm],  [$1])])
 170 AC_DEFUN([DX_CHI_FEATURE],     [AC_DEFUN([DX_FEATURE_chi],  [$1])])
 171 AC_DEFUN([DX_RTF_FEATURE],     [AC_DEFUN([DX_FEATURE_rtf],  [$1])])
 172 AC_DEFUN([DX_XML_FEATURE],     [AC_DEFUN([DX_FEATURE_xml],  [$1])])
 173 AC_DEFUN([DX_XML_FEATURE],     [AC_DEFUN([DX_FEATURE_xml],  [$1])])
 174 AC_DEFUN([DX_PDF_FEATURE],     [AC_DEFUN([DX_FEATURE_pdf],  [$1])])
 175 AC_DEFUN([DX_PS_FEATURE],      [AC_DEFUN([DX_FEATURE_ps],   [$1])])
 176
 177 # DX_INIT_DOXYGEN(PROJECT, [CONFIG-FILE], [OUTPUT-DOC-DIR])
 178 # ---------------------------------------------------------
 179 # PROJECT also serves as the base name for the documentation files.
 180 # The default CONFIG-FILE is "Doxyfile" and OUTPUT-DOC-DIR is "doxygen-doc".
 181 AC_DEFUN([DX_INIT_DOXYGEN], [
 182
 183 # Files:
 184 AC_SUBST([DX_PROJECT], [$1])
 185 AC_SUBST([DX_CONFIG], [ifelse([$2], [], Doxyfile, [$2])])
 186 AC_SUBST([DX_DOCDIR], [ifelse([$3], [], doxygen-doc, [$3])])
 187
 188 # Environment variables used inside doxygen.cfg:
 189 DX_ENV_APPEND(SRCDIR, $srcdir)
 190 DX_ENV_APPEND(PROJECT, $DX_PROJECT)
 191 DX_ENV_APPEND(DOCDIR, $DX_DOCDIR)
 192 DX_ENV_APPEND(VERSION, $PACKAGE_VERSION)
 193
 194 # Doxygen itself:
 195 DX_ARG_ABLE(doc, [generate any doxygen documentation],
 196             [],
 197             [],
 198             [DX_REQUIRE_PROG([DX_DOXYGEN], doxygen)
 199              DX_REQUIRE_PROG([DX_PERL], perl)],
 200             [DX_ENV_APPEND(PERL_PATH, $DX_PERL)])
 201
 202 # Dot for graphics:
 203 DX_ARG_ABLE(dot, [generate graphics for doxygen documentation],
 204             [DX_CHECK_DEPEND(doc, 1)],
 205             [DX_CLEAR_DEPEND(doc, 1)],
 206             [DX_REQUIRE_PROG([DX_DOT], dot)],
 207             [DX_ENV_APPEND(HAVE_DOT, YES)
 208              DX_ENV_APPEND(DOT_PATH, [`DX_DIRNAME_EXPR($DX_DOT)`])],
 209             [DX_ENV_APPEND(HAVE_DOT, NO)])
 210
 211 # Man pages generation:
 212 DX_ARG_ABLE(man, [generate doxygen manual pages],
 213             [DX_CHECK_DEPEND(doc, 1)],
 214             [DX_CLEAR_DEPEND(doc, 1)],
 215             [],
 216             [DX_ENV_APPEND(GENERATE_MAN, YES)],
 217             [DX_ENV_APPEND(GENERATE_MAN, NO)])
 218
 219 # RTF file generation:
 220 DX_ARG_ABLE(rtf, [generate doxygen RTF documentation],
 221             [DX_CHECK_DEPEND(doc, 1)],
 222             [DX_CLEAR_DEPEND(doc, 1)],
 223             [],
 224             [DX_ENV_APPEND(GENERATE_RTF, YES)],
 225             [DX_ENV_APPEND(GENERATE_RTF, NO)])
 226
 227 # XML file generation:
 228 DX_ARG_ABLE(xml, [generate doxygen XML documentation],
 229             [DX_CHECK_DEPEND(doc, 1)],
 230             [DX_CLEAR_DEPEND(doc, 1)],
 231             [],
 232             [DX_ENV_APPEND(GENERATE_XML, YES)],
 233             [DX_ENV_APPEND(GENERATE_XML, NO)])
 234
 235 # (Compressed) HTML help generation:
 236 DX_ARG_ABLE(chm, [generate doxygen compressed HTML help documentation],
 237             [DX_CHECK_DEPEND(doc, 1)],
 238             [DX_CLEAR_DEPEND(doc, 1)],
 239             [DX_REQUIRE_PROG([DX_HHC], hhc)],
 240             [DX_ENV_APPEND(HHC_PATH, $DX_HHC)
 241              DX_ENV_APPEND(GENERATE_HTML, YES)
 242              DX_ENV_APPEND(GENERATE_HTMLHELP, YES)],
 243             [DX_ENV_APPEND(GENERATE_HTMLHELP, NO)])
 244
 245 # Seperate CHI file generation.
 246 DX_ARG_ABLE(chi, [generate doxygen seperate compressed HTML help index file],
 247             [DX_CHECK_DEPEND(chm, 1)],
 248             [DX_CLEAR_DEPEND(chm, 1)],
 249             [],
 250             [DX_ENV_APPEND(GENERATE_CHI, YES)],
 251             [DX_ENV_APPEND(GENERATE_CHI, NO)])
 252
 253 # Plain HTML pages generation:
 254 DX_ARG_ABLE(html, [generate doxygen plain HTML documentation],
 255             [DX_CHECK_DEPEND(doc, 1) DX_CHECK_DEPEND(chm, 0)],
 256             [DX_CLEAR_DEPEND(doc, 1) DX_CLEAR_DEPEND(chm, 0)],
 257             [],
 258             [DX_ENV_APPEND(GENERATE_HTML, YES)],
 259             [DX_TEST_FEATURE(chm) || DX_ENV_APPEND(GENERATE_HTML, NO)])
 260
 261 # PostScript file generation:
 262 DX_ARG_ABLE(ps, [generate doxygen PostScript documentation],
 263             [DX_CHECK_DEPEND(doc, 1)],
 264             [DX_CLEAR_DEPEND(doc, 1)],
 265             [DX_REQUIRE_PROG([DX_LATEX], latex)
 266              DX_REQUIRE_PROG([DX_MAKEINDEX], makeindex)
 267              DX_REQUIRE_PROG([DX_DVIPS], dvips)
 268              DX_REQUIRE_PROG([DX_EGREP], egrep)])
 269
 270 # PDF file generation:
 271 DX_ARG_ABLE(pdf, [generate doxygen PDF documentation],
 272             [DX_CHECK_DEPEND(doc, 1)],
 273             [DX_CLEAR_DEPEND(doc, 1)],
 274             [DX_REQUIRE_PROG([DX_PDFLATEX], pdflatex)
 275              DX_REQUIRE_PROG([DX_MAKEINDEX], makeindex)
 276              DX_REQUIRE_PROG([DX_EGREP], egrep)])
 277
 278 # LaTeX generation for PS and/or PDF:
 279 if DX_TEST_FEATURE(ps) || DX_TEST_FEATURE(pdf); then
 280     AM_CONDITIONAL(DX_COND_latex, :)
 281     DX_ENV_APPEND(GENERATE_LATEX, YES)
 282 else
 283     AM_CONDITIONAL(DX_COND_latex, false)
 284     DX_ENV_APPEND(GENERATE_LATEX, NO)
 285 fi
 286
 287 # Paper size for PS and/or PDF:
 288 AC_ARG_VAR(DOXYGEN_PAPER_SIZE,
 289            [a4wide (default), a4, letter, legal or executive])
 290 case "$DOXYGEN_PAPER_SIZE" in
 291 #(
 292 "")
 293     AC_SUBST(DOXYGEN_PAPER_SIZE, "")
 294 ;; #(
 295 a4wide|a4|letter|legal|executive)
 296     DX_ENV_APPEND(PAPER_SIZE, $DOXYGEN_PAPER_SIZE)
 297 ;; #(
 298 *)
 299     AC_MSG_ERROR([unknown DOXYGEN_PAPER_SIZE='$DOXYGEN_PAPER_SIZE'])
 300 ;;
 301 esac
 302
 303 #For debugging:
 304 #echo DX_FLAG_doc=$DX_FLAG_doc
 305 #echo DX_FLAG_dot=$DX_FLAG_dot
 306 #echo DX_FLAG_man=$DX_FLAG_man
 307 #echo DX_FLAG_html=$DX_FLAG_html
 308 #echo DX_FLAG_chm=$DX_FLAG_chm
 309 #echo DX_FLAG_chi=$DX_FLAG_chi
 310 #echo DX_FLAG_rtf=$DX_FLAG_rtf
 311 #echo DX_FLAG_xml=$DX_FLAG_xml
 312 #echo DX_FLAG_pdf=$DX_FLAG_pdf
 313 #echo DX_FLAG_ps=$DX_FLAG_ps
 314 #echo DX_ENV=$DX_ENV
 315 ])