configure.ac

   1 # Process this file with autoreconf
   2 AC_PREREQ([2.50])
   3 AC_INIT([xmltooling],[1.5],[https://issues.shibboleth.net/],[xmltooling])
   4 AC_CONFIG_SRCDIR(xmltooling)
   5 AC_CONFIG_AUX_DIR(build-aux)
   6 AC_CONFIG_MACRO_DIR(m4)
   7 AM_INIT_AUTOMAKE
   8 AC_DISABLE_STATIC
   9 AC_PROG_LIBTOOL
  10
  11 # Docygen features
  12 DX_HTML_FEATURE(ON)
  13 DX_CHM_FEATURE(OFF)
  14 DX_CHI_FEATURE(OFF)
  15 DX_MAN_FEATURE(OFF)
  16 DX_RTF_FEATURE(OFF)
  17 DX_XML_FEATURE(OFF)
  18 DX_PDF_FEATURE(OFF)
  19 DX_PS_FEATURE(OFF)
  20 DX_INIT_DOXYGEN(xmltooling, doxygen.cfg, doc/api)
  21
  22 AC_ARG_ENABLE(debug,
  23     AS_HELP_STRING([--enable-debug],[Have GCC compile with symbols (Default = no)]),
  24     enable_debug=$enableval, enable_debug=no)
  25
  26 if test "$enable_debug" = "yes" ; then
  27     GCC_CFLAGS="$CFLAGS -g -D_DEBUG"
  28     GCC_CXXFLAGS="$CXXFLAGS -g -D_DEBUG"
  29 else
  30     GCC_CFLAGS="$CFLAGS -O2 -DNDEBUG"
  31     GCC_CXXFLAGS="$CXXFLAGS -O2 -DNDEBUG"
  32 fi
  33
  34 AC_CONFIG_HEADERS([config.h xmltooling/config_pub.h])
  35 AC_CONFIG_FILES([xmltooling.spec])
  36 AC_CONFIG_FILES([Makefile xmltooling/Makefile xmltoolingtest/Makefile schemas/Makefile doc/Makefile])
  37
  38 AC_PROG_CC([gcc gcc3 cc])
  39 AC_PROG_CXX([g++ g++3 c++ CC])
  40 AC_CANONICAL_HOST
  41
  42 if test "$GCC" = "yes" ; then
  43 #    AC_HAVE_GCC_VERSION(4,0,0,0,
  44 #        [
  45 #        AC_DEFINE(GCC_HASCLASSVISIBILITY,1,
  46 #            [Define to enable class visibility control in gcc.])
  47 #        GCC_CFLAGS="$GCC_CFLAGS -fvisibility=hidden -fvisibility-inlines-hidden"
  48 #        GCC_CXXFLAGS="$GCC_CXXFLAGS -fvisibility=hidden -fvisibility-inlines-hidden"
  49 #        ])
  50     CFLAGS="-Wall $GCC_CFLAGS"
  51     CXXFLAGS="-Wall $GCC_CXXFLAGS"
  52 fi
  53
  54 # Fix for Sun Workshop compiler in debug mode, may be Sun case #6360993
  55 # Also enables POSIX semantics for some functions.
  56 case "${host_cpu}-${host_os}" in
  57     *solaris*)
  58         CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS"
  59         CXXFLAGS="$CXXFLAGS -D_POSIX_PTHREAD_SEMANTICS"
  60         if test "$CXX" = "CC" ; then
  61                 CXXFLAGS="$CXXFLAGS -Qoption ccfe -stabs=no%dfltlit+no%dflthlp"
  62         fi
  63     ;;
  64 esac
  65
  66 # Checks for typedefs, structures, and compiler characteristics.
  67 AC_C_CONST
  68 AC_TYPE_SIZE_T
  69 AC_CHECK_SIZEOF([long])
  70
  71 # Checks for library functions.
  72 AC_CHECK_FUNCS([strchr strdup strstr timegm strcasecmp])
  73 AC_CHECK_HEADERS([dlfcn.h])
  74 AC_CHECK_FUNC(dlclose, , [ AC_CHECK_LIB(dl, dlopen) ])
  75
  76 # checks for pthreads
  77 ACX_PTHREAD([enable_threads="pthread"],[enable_threads="no"])
  78 if test $enable_threads != "pthread"; then
  79     AC_MSG_ERROR([unable to find pthreads, currently this is required])
  80 else
  81     AC_DEFINE([HAVE_PTHREAD],[1],[Define if you have POSIX threads libraries and header files.])
  82         AM_CONDITIONAL(BUILD_PTHREAD,test "$enable_threads" = "pthread")
  83     LIBS="$PTHREAD_LIBS $LIBS"
  84     CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
  85     CXXFLAGS="$PTHREAD_CFLAGS $CXXFLAGS"
  86 fi
  87
  88 AC_CHECK_FUNCS([pthread_rwlock_init])
  89
  90 AC_LANG([C++])
  91
  92 # C++ requirements
  93 AC_CXX_NAMESPACES
  94 AC_CXX_REQUIRE_STL
  95
  96 # Boost
  97 BOOST_REQUIRE
  98 BOOST_BIND
  99 BOOST_CONVERSION
 100 BOOST_LAMBDA
 101 BOOST_PTR_CONTAINER
 102 BOOST_STRING_ALGO
 103 BOOST_TOKENIZER
 104
 105 # are covariant methods allowed?
 106 AC_LINK_IFELSE(
 107     [AC_LANG_PROGRAM([[]],
 108         [[
 109         class base { public: virtual base *GetPtr( void ) { return this; } };
 110         class derived: virtual public base { public: virtual derived *GetPtr( void ) { return this; } };
 111         ]])],
 112     [AC_DEFINE([HAVE_COVARIANT_RETURNS],[1],[Define to 1 if C++ compiler supports covariant virtual methods.])])
 113
 114 # is nullptr supported?
 115 AC_COMPILE_IFELSE(
 116     [AC_LANG_PROGRAM([[]],[[const char* ptr = nullptr;]])],
 117     [AC_DEFINE([HAVE_NULLPTR],[1],[Define to 1 if C++ compiler supports nullptr keyword.])])
 118
 119 # log4shib settings (favor this version over the log4cpp code)
 120 AC_PATH_PROG(LOG4SHIB_CONFIG,log4shib-config)
 121 AC_ARG_WITH(log4shib,
 122     AS_HELP_STRING([--with-log4shib=PATH],[where log4shib-config is installed]),
 123     [
 124     LOG4SHIB_CONFIG="${with_log4shib}"
 125     if ! test -f "${LOG4SHIB_CONFIG}" ; then
 126         LOG4SHIB_CONFIG="${with_log4shib}/bin/log4shib-config"
 127     fi
 128     ])
 129 if test -f "${LOG4SHIB_CONFIG}" ; then
 130     LIBS="`${LOG4SHIB_CONFIG} --libs` $LIBS"
 131     CPPFLAGS="`${LOG4SHIB_CONFIG} --cflags` $CPPFLAGS"
 132     AC_CHECK_HEADER([log4shib/CategoryStream.hh],,AC_MSG_ERROR([unable to find log4shib header files]))
 133     AC_LINK_IFELSE(
 134         [AC_LANG_PROGRAM([[#include <log4shib/Category.hh>
 135 #include <log4shib/CategoryStream.hh>]],
 136             [[log4shib::Category::getInstance("foo").errorStream() << log4shib::eol]])],
 137         [AC_DEFINE([XMLTOOLING_LOG4SHIB],[1],[Define to 1 if log4shib library is used.])],
 138         [AC_MSG_ERROR([unable to link with log4shib])])
 139 else
 140     AC_MSG_WARN([log4shib-config not found, may need to use --with-log4shib option])
 141     AC_MSG_WARN([will look for original log4cpp library])
 142
 143     # log4cpp settings
 144     AC_PATH_PROG(LOG4CPP_CONFIG,log4cpp-config)
 145     AC_ARG_WITH(log4cpp,
 146         AS_HELP_STRING([--with-log4cpp=PATH],[where log4cpp-config is installed]),
 147         [
 148         LOG4CPP_CONFIG="${with_log4cpp}"
 149         if ! test -f "${LOG4CPP_CONFIG}" ; then
 150                 LOG4CPP_CONFIG="${with_log4cpp}/bin/log4cpp-config"
 151         fi
 152         ])
 153     if test -f "${LOG4CPP_CONFIG}"; then
 154         AC_MSG_WARN([will try to use log4cpp, note that most non-Internet2 supplied versions are not thread-safe])
 155         LIBS="`${LOG4CPP_CONFIG} --libs` $LIBS"
 156         CPPFLAGS="`${LOG4CPP_CONFIG} --cflags` $CPPFLAGS"
 157         AC_CHECK_HEADER([log4cpp/CategoryStream.hh],,AC_MSG_ERROR([unable to find log4cpp header files]))
 158         AC_LINK_IFELSE(
 159             [AC_LANG_PROGRAM([[#include <log4cpp/Category.hh>
 160 #include <log4cpp/CategoryStream.hh>]],
 161                 [[log4cpp::Category::getInstance("foo").errorStream() << log4cpp::eol]])],
 162             [AC_DEFINE([XMLTOOLING_LOG4CPP],[1],[Define to 1 if log4cpp library is used.])],
 163             [AC_MSG_ERROR([unable to link with log4cpp, need version 1.0 or later])])
 164         else
 165             AC_MSG_ERROR([log4cpp-config not found, may need to use --with-log4cpp option])
 166         fi
 167 fi
 168
 169 # Xerces settings
 170 AC_ARG_WITH(xerces,
 171     AS_HELP_STRING([--with-xerces=PATH],[where xerces-c is installed]),,
 172     [with_xerces=/usr])
 173 if test x_$with_xerces != x_/usr; then
 174     CPPFLAGS="-I${with_xerces}/include $CPPFLAGS"
 175     LIBS="-L${with_xerces}/lib -lxerces-c $LIBS"
 176 else
 177     LIBS="-lxerces-c $LIBS"
 178 fi
 179
 180 AC_CHECK_HEADER([xercesc/dom/DOM.hpp],,AC_MSG_ERROR([unable to find xerces header files]))
 181 AC_MSG_CHECKING([Xerces version])
 182 AC_PREPROC_IFELSE(
 183     [AC_LANG_PROGRAM([#include <xercesc/util/XercesVersion.hpp>],
 184 [#if  _XERCES_VERSION != 20600
 185 int i = 0;
 186 #else
 187 #error cannot use version 2.6.0
 188 #endif])],
 189     [AC_MSG_RESULT(OK)],
 190     [AC_MSG_FAILURE([Xerces-C v2.6.0 has bugs that inhibit use with signed XML, please use a newer version])])
 191 AC_LINK_IFELSE(
 192     [AC_LANG_PROGRAM([[#include <xercesc/util/PlatformUtils.hpp>]],
 193         [[xercesc::XMLPlatformUtils::Initialize()]])],
 194     ,[AC_MSG_ERROR([unable to link with Xerces])])
 195
 196 AC_MSG_CHECKING([whether Xerces is 64-bit clean])
 197 AC_COMPILE_IFELSE(
 198     [AC_LANG_PROGRAM([[#include <xercesc/framework/MemBufInputSource.hpp>]],
 199         [[using namespace XERCES_CPP_NAMESPACE; XMLFilePos testvar;]])],
 200     [AC_MSG_RESULT([yes])AC_DEFINE([XMLTOOLING_XERCESC_64BITSAFE],[1],[Define to 1 if Xerces has a 64-bit-safe API.])],
 201     [AC_MSG_RESULT([no])])
 202
 203 AC_MSG_CHECKING([whether Xerces BinInputStream requires getContentType])
 204 AC_COMPILE_IFELSE(
 205     [AC_LANG_PROGRAM([[#include <xercesc/util/BinMemInputStream.hpp>]],
 206         [[using namespace XERCES_CPP_NAMESPACE; XMLByte buf[1024]; BinMemInputStream in(buf,1024); in.getContentType();]])],
 207     [AC_MSG_RESULT([yes])AC_DEFINE([XMLTOOLING_XERCESC_INPUTSTREAM_HAS_CONTENTTYPE],[1],[Define to 1 if Xerces InputStream class requires getContentType.])],
 208     [AC_MSG_RESULT([no])])
 209
 210 AC_MSG_CHECKING([whether Xerces DOMLS API is compliant])
 211 AC_COMPILE_IFELSE(
 212     [AC_LANG_PROGRAM([[#include <xercesc/dom/DOM.hpp>]],
 213         [[using namespace XERCES_CPP_NAMESPACE;
 214         DOMImplementation *impl = DOMImplementationRegistry::getDOMImplementation(NULL);
 215         DOMLSSerializer *ls = ((DOMImplementationLS*)impl)->createLSSerializer();]])],
 216     [AC_MSG_RESULT([yes])AC_DEFINE([XMLTOOLING_XERCESC_COMPLIANT_DOMLS],[1],[Define to 1 if Xerces supports a compliant DOMLS API.])],
 217     [AC_MSG_RESULT([no])])
 218
 219 AC_MSG_CHECKING([whether Xerces has setIdAttribute(XMLCh*, bool)])
 220 AC_COMPILE_IFELSE(
 221     [AC_LANG_PROGRAM([[#include <xercesc/dom/DOM.hpp>]],
 222         [[using namespace XERCES_CPP_NAMESPACE; DOMElement * elt; elt->setIdAttribute(NULL, false);]])],
 223     [AC_MSG_RESULT([yes])AC_DEFINE([XMLTOOLING_XERCESC_BOOLSETIDATTRIBUTE],[1],[Define to 1 if Xerces DOM ID methods take extra parameter.])],
 224     [AC_MSG_RESULT([no])])
 225
 226 AC_MSG_CHECKING([whether Xerces XMLString::release(XMLByte**) exists])
 227 AC_COMPILE_IFELSE(
 228     [AC_LANG_PROGRAM([[#include <xercesc/util/XMLString.hpp>]],
 229     [[using namespace XERCES_CPP_NAMESPACE; XMLByte* buf=NULL; XMLString::release(&buf);]])],
 230     [AC_MSG_RESULT([yes])AC_DEFINE([XMLTOOLING_XERCESC_HAS_XMLBYTE_RELEASE],[1],[Define to 1 if Xerces XMLString includes XMLByte release.])],
 231     [AC_MSG_RESULT([no])])
 232
 233 # XML-Security settings
 234 AC_ARG_WITH(xmlsec,
 235     AS_HELP_STRING([--with-xmlsec=PATH], [where xmlsec is installed]),,
 236     [with_xmlsec=/usr])
 237
 238 if test x_$with_xmlsec != x_no; then
 239
 240     # OpenSSL settings (need to do this first in case it's in a different spot from xmlsec)
 241     AC_ARG_WITH(openssl,
 242         AS_HELP_STRING([--with-openssl=PATH], [where openssl is installed]),
 243         [if test x_$with_openssl != x_/usr; then
 244             SSLFLAGS="-I${with_openssl}/include"
 245             SSLLIBS="-L${with_openssl}/lib -lcrypto -lssl"
 246         else
 247             SSLLIBS="-lcrypto -lssl"
 248         fi])
 249
 250     if test "x$SSLLIBS" = "x" ; then
 251         AC_PATH_PROG(PKG_CONFIG, pkg-config)
 252         if test "x$PKG_CONFIG" != x && test "x$PKG_CONFIG" != "xno" ; then
 253             if pkg-config openssl ; then
 254                 SSLLIBS="`$PKG_CONFIG --libs openssl`"
 255                 SSLFLAGS="`$PKG_CONFIG --cflags openssl`"
 256             else
 257                 AC_MSG_WARN([OpenSSL not supported by pkg-config, try --with-openssl instead])
 258             fi
 259         fi
 260     fi
 261
 262     if test "x$SSLLIBS" = "x" ; then
 263         SSLLIBS="-lcrypto -lssl"
 264     fi
 265
 266     AC_MSG_CHECKING(for OpenSSL cflags)
 267     AC_MSG_RESULT($SSLFLAGS)
 268     CPPFLAGS="$CPPFLAGS $SSLFLAGS"
 269     AC_MSG_CHECKING(for OpenSSL libraries)
 270     AC_MSG_RESULT($SSLLIBS)
 271     XMLSEC_LIBS="$XMLSEC_LIBS $SSLLIBS"
 272
 273     # save and append master libs
 274     save_LIBS="$LIBS"
 275     LIBS="$XMLSEC_LIBS $LIBS"
 276
 277     AC_CHECK_HEADER([openssl/pem.h],,AC_MSG_ERROR([unable to find openssl header files]))
 278     AC_MSG_CHECKING(for ERR_load_CRYPTO_string)
 279     AC_TRY_LINK_FUNC([ERR_load_CRYPTO_strings],,AC_MSG_ERROR([unable to link with openssl libraries]))
 280     AC_MSG_RESULT(yes)
 281
 282     AC_CHECK_DECL(EVP_sha512,
 283         [AC_DEFINE([XMLTOOLING_OPENSSL_HAVE_SHA2],[1],[Define to 1 if OpenSSL supports the SHA-2 hash family.])],
 284                 ,[#include <openssl/evp.h>])
 285     AC_CHECK_DECL(EVP_PKEY_set1_EC_KEY,
 286         [AC_DEFINE([XMLTOOLING_OPENSSL_HAVE_EC],[1],[Define to 1 if OpenSSL has EC support.])],
 287         ,[#include <openssl/evp.h>])
 288
 289     # restore master libs
 290     LIBS="$save_LIBS"
 291
 292     if test x_$with_xmlsec != x_/usr; then
 293         CPPFLAGS="-I${with_xmlsec}/include $CPPFLAGS"
 294         XMLSEC_LIBS="-L${with_xmlsec}/lib -lxml-security-c $XMLSEC_LIBS"
 295     else
 296         XMLSEC_LIBS="-lxml-security-c $XMLSEC_LIBS"
 297     fi
 298
 299     # save and append master libs
 300     save_LIBS="$LIBS"
 301     LIBS="$XMLSEC_LIBS $LIBS"
 302
 303     AC_CHECK_HEADER([xsec/utils/XSECPlatformUtils.hpp],,AC_MSG_ERROR([unable to find XML-Security header files]))
 304     AC_MSG_CHECKING([XML-Security version])
 305     AC_PREPROC_IFELSE(
 306             [AC_LANG_PROGRAM([#include <xsec/utils/XSECPlatformUtils.hpp>],
 307         [#if XSEC_VERSION_MAJOR > 1 || (XSEC_VERSION_MAJOR == 1 && XSEC_VERSION_MEDIUM > 3)
 308 int i = 0;
 309 #else
 310 #error need version 1.4.0 or later
 311 #endif])],
 312         [AC_MSG_RESULT(OK)],
 313         [AC_MSG_FAILURE([XML-Security version 1.4.0 or greater is required.])])
 314
 315     AC_LINK_IFELSE(
 316         [AC_LANG_PROGRAM([[#include <xsec/utils/XSECPlatformUtils.hpp>]],
 317             [[XSECPlatformUtils::Initialise()]])],,
 318         [AC_MSG_ERROR([unable to link with XML-Security])])
 319     AC_CHECK_TYPE([xsecsize_t],[AC_DEFINE([HAVE_XSECSIZE_T],[1],[Define to 1 if you have the 'xsecsize_t' type.])])
 320
 321     AC_MSG_CHECKING([whether XML-Security-C has multiple CRL support])
 322     AC_COMPILE_IFELSE(
 323         [AC_LANG_PROGRAM([[#include <xsec/dsig/DSIGKeyInfoX509.hpp>]],
 324             [[DSIGKeyInfoX509* klist; klist->getX509CRLListSize();]])],
 325         [AC_MSG_RESULT([yes])AC_DEFINE([XMLTOOLING_XMLSEC_MULTIPLECRL],[1],[Define to 1 if XML-Security-C handles multiple CRLs.])],
 326         [AC_MSG_RESULT([no])])
 327
 328     AC_MSG_CHECKING([whether XML-Security-C exposes the signature algorithm URI])
 329     AC_COMPILE_IFELSE(
 330         [AC_LANG_PROGRAM([[#include <xsec/dsig/DSIGSignature.hpp>]],
 331             [[DSIGSignature* sig; sig->getAlgorithmURI();]])],
 332         [AC_MSG_RESULT([yes])AC_DEFINE([XMLTOOLING_XMLSEC_SIGALGORITHM],[1],[Define to 1 if XML-Security-C exposes the signature algorithm URI.])],
 333         [AC_MSG_RESULT([no])])
 334
 335     AC_MSG_CHECKING([whether XML-Security-C includes ECC support])
 336     AC_COMPILE_IFELSE(
 337         [AC_LANG_PROGRAM([[#include <xsec/dsig/DSIGKeyInfoValue.hpp>]],
 338             [[DSIGKeyInfoValue* info; info->getECNamedCurve();]])],
 339         [AC_MSG_RESULT([yes])AC_DEFINE([XMLTOOLING_XMLSEC_ECC],[1],[Define to 1 if XML-Security-C includes ECC support.])],
 340         [AC_MSG_RESULT([no])])
 341
 342     AC_MSG_CHECKING([whether XML-Security-C includes C14N 1.1 support])
 343     AC_COMPILE_IFELSE(
 344         [AC_LANG_PROGRAM([[#include <xsec/dsig/DSIGConstants.hpp>]],
 345             [[transformType t = TRANSFORM_C14N11;]])],
 346         [AC_MSG_RESULT([yes])AC_DEFINE([XMLTOOLING_XMLSEC_C14N11],[1],[Define to 1 if XML-Security-C includes C14N 1.1 support.])],
 347         [AC_MSG_RESULT([no])])
 348
 349     AC_MSG_CHECKING([whether XML-Security-C includes debug logging support])
 350     AC_COMPILE_IFELSE(
 351         [AC_LANG_PROGRAM([[#include <xsec/utils/XSECPlatformUtils.hpp>]],
 352             [[XSECPlatformUtils::SetReferenceLoggingSink(NULL)]])],
 353         [AC_MSG_RESULT([yes])AC_DEFINE([XMLTOOLING_XMLSEC_DEBUGLOGGING],[1],[Define to 1 if XML-Security-C includes debug logging support.])],
 354         [AC_MSG_RESULT([no])])
 355
 356     # restore master libs
 357     LIBS="$save_LIBS"
 358
 359     # libcurl settings
 360     AC_PATH_PROG(CURL_CONFIG,curl-config)
 361     AC_ARG_WITH(curl,
 362         AS_HELP_STRING([--with-curl=PATH], [where curl-config is installed]),
 363         [
 364         CURL_CONFIG="${with_curl}"
 365         if ! test -f "${CURL_CONFIG}" ; then
 366             CURL_CONFIG="${with_curl}/bin/curl-config"
 367         fi
 368         ])
 369     if test -f "${CURL_CONFIG}" ; then
 370         CPPFLAGS="`${CURL_CONFIG} --cflags` $CPPFLAGS"
 371         XMLSEC_LIBS="`${CURL_CONFIG} --libs` $XMLSEC_LIBS"
 372     else
 373         AC_MSG_ERROR([curl-config not found, may need to use --with-curl option])
 374     fi
 375
 376     # save and append master libs
 377     save_LIBS="$LIBS"
 378     LIBS="$XMLSEC_LIBS $LIBS"
 379
 380     AC_CHECK_HEADER([curl/curl.h],,AC_MSG_ERROR([unable to find libcurl header files]))
 381     AC_LINK_IFELSE(
 382         [AC_LANG_PROGRAM([[#include <curl/curl.h>]],
 383             [[curl_global_init(CURL_GLOBAL_ALL)]])],,
 384         [AC_MSG_ERROR([unable to link with libcurl])])
 385     AC_MSG_CHECKING([for CURLOPT_SSL_CTX_FUNCTION in curl.h])
 386     AC_EGREP_HEADER([CURLOPT_SSL_CTX_FUNCTION], [curl/curl.h],
 387         [AC_MSG_RESULT(yes)],
 388         [AC_MSG_ERROR([need libcurl that supports CURLOPT_SSL_CTX_FUNCTION])])
 389     AC_CHECK_TYPE([curl_off_t],[AC_DEFINE([HAVE_CURL_OFF_T],[1],[Define to 1 if you have the 'curl_off_t' type.])],,[[#include <curl/curl.h>]])
 390
 391     # restore master libs
 392     LIBS="$save_LIBS"
 393
 394     AC_SUBST(XMLSEC_LIBS)
 395 else
 396     AC_MSG_WARN([xmlsec disabled, building without signature/encryption support])
 397     AC_DEFINE([XMLTOOLING_NO_XMLSEC],[1],[Define to 1 if you wish to disable XML-Security-dependent features.])
 398 fi
 399 AM_CONDITIONAL(BUILD_XMLSEC,test x_$with_xmlsec != x_no)
 400
 401 # Does the STL in use help or screw us?
 402 AC_LINK_IFELSE(
 403     [AC_LANG_PROGRAM([[#include <string>]],[[std::basic_string<unsigned short> foo; foo=foo+(unsigned short)65]])],
 404     [AC_DEFINE([HAVE_GOOD_STL],[1],[Define to 1 if you have an STL implementation that supports useful string specialization.])],[])
 405 AC_LINK_IFELSE(
 406     [AC_LANG_PROGRAM([[#include <vector>]],[[std::iterator_traits<std::vector<int>::iterator>::value_type foo=0]])],
 407     [AC_DEFINE([HAVE_ITERATOR_TRAITS],[1],[Define to 1 if you have an STL implementation that supports std::iterator_traits.])],[])
 408
 409 # Check for unit test support
 410 CXXTEST="/usr/bin/cxxtestgen.pl"
 411 CXXTESTFLAGS=""
 412 AC_ARG_WITH(cxxtest,
 413     AS_HELP_STRING([--with-cxxtest=PATH], [where cxxtest is installed]),
 414     [if test x_$with_cxxtest != x_/usr; then
 415         CXXTEST="${with_cxxtest}/cxxtestgen.pl"
 416         CXXTESTFLAGS="-I${with_cxxtest}"
 417     fi])
 418 if ! test -f "${CXXTEST}"; then
 419     AC_MSG_WARN([cxxtestgen not found, won't build unit tests])
 420 fi
 421
 422 AC_SUBST(CXXTEST)
 423 AC_SUBST(CXXTESTFLAGS)
 424 AM_CONDITIONAL(BUILD_UNITTEST,test -f ${CXXTEST})
 425
 426 AX_CREATE_PKGCONFIG_INFO(,,[$XMLSEC_LIBS -lxmltooling],[OpenSAML XMLTooling-C library])
 427
 428 LIBTOOL="$LIBTOOL --silent"
 429
 430 # output packaging and makefiles
 431 AC_OUTPUT