configure.ac

   1 # Process this file with autoreconf
   2 AC_PREREQ([2.60])
   3 AC_INIT([xmltooling],[1.4],[https://bugs.internet2.edu/],[xmltooling])
   4 AC_CONFIG_SRCDIR(xmltooling)
   5 AC_CONFIG_AUX_DIR(build-aux)
   6 AC_CONFIG_MACRO_DIR(m4)
   7 AM_INIT_AUTOMAKE
   8 LT_INIT
   9
  10 # Docygen features
  11 DX_HTML_FEATURE(ON)
  12 DX_CHM_FEATURE(OFF)
  13 DX_CHI_FEATURE(OFF)
  14 DX_MAN_FEATURE(OFF)
  15 DX_RTF_FEATURE(OFF)
  16 DX_XML_FEATURE(OFF)
  17 DX_PDF_FEATURE(OFF)
  18 DX_PS_FEATURE(OFF)
  19 DX_INIT_DOXYGEN(xmltooling, doxygen.cfg, doc/api)
  20
  21 AC_ARG_ENABLE(debug,
  22     AS_HELP_STRING([--enable-debug],[Have GCC compile with symbols (Default = no)]),
  23     enable_debug=$enableval, enable_debug=no)
  24
  25 if test "$enable_debug" = "yes" ; then
  26     GCC_CFLAGS="$CFLAGS -g -D_DEBUG"
  27     GCC_CXXFLAGS="$CXXFLAGS -g -D_DEBUG"
  28 else
  29     GCC_CFLAGS="$CFLAGS -O2 -DNDEBUG"
  30     GCC_CXXFLAGS="$CXXFLAGS -O2 -DNDEBUG"
  31 fi
  32
  33 AC_CONFIG_HEADERS([config.h xmltooling/config_pub.h])
  34 AC_CONFIG_FILES([xmltooling.spec pkginfo Portfile])
  35 AC_CONFIG_FILES([Makefile xmltooling/Makefile xmltoolingtest/Makefile schemas/Makefile doc/Makefile])
  36
  37 AC_PROG_CC([gcc gcc3 cc])
  38 AC_PROG_CXX([g++ g++3 c++ CC])
  39 AC_DISABLE_STATIC
  40 AC_CANONICAL_HOST
  41
  42 if test "$GCC" = "yes" ; then
  43 #    AC_HAVE_GCC_VERSION(4,0,0,0,
  44 #        [
  45 #        AC_DEFINE(GCC_HASCLASSVISIBILITY,1,
  46 #            [Define to enable class visibility control in gcc.])
  47 #        GCC_CFLAGS="$GCC_CFLAGS -fvisibility=hidden -fvisibility-inlines-hidden"
  48 #        GCC_CXXFLAGS="$GCC_CXXFLAGS -fvisibility=hidden -fvisibility-inlines-hidden"
  49 #        ])
  50     CFLAGS="-Wall $GCC_CFLAGS"
  51     CXXFLAGS="-Wall $GCC_CXXFLAGS"
  52 else
  53 # Fix for Sun Workshop compiler in debug mode, may be Sun case #6360993
  54         case "${host_cpu}-${host_os}" in
  55                 *solaris*)
  56                         if test "$CXX" = "CC" ; then
  57                                 CXXFLAGS="$CXXFLAGS -Qoption ccfe -stabs=no%dfltlit+no%dflthlp"
  58                         fi
  59                 ;;
  60         esac
  61 fi
  62
  63 # Checks for typedefs, structures, and compiler characteristics.
  64 AC_C_CONST
  65 AC_TYPE_SIZE_T
  66 AC_CHECK_SIZEOF([long])
  67
  68 # Checks for library functions.
  69 AC_CHECK_FUNCS([strchr strdup strstr timegm strcasecmp])
  70 AC_CHECK_HEADERS([dlfcn.h])
  71 AC_CHECK_FUNC(dlclose, , [ AC_CHECK_LIB(dl, dlopen) ])
  72
  73 # checks for pthreads
  74 ACX_PTHREAD([enable_threads="pthread"],[enable_threads="no"])
  75 if test $enable_threads != "pthread"; then
  76     AC_MSG_ERROR([unable to find pthreads, currently this is required])
  77 else
  78     AC_DEFINE([HAVE_PTHREAD],[1],[Define if you have POSIX threads libraries and header files.])
  79         AM_CONDITIONAL(BUILD_PTHREAD,test "$enable_threads" = "pthread")
  80     LIBS="$PTHREAD_LIBS $LIBS"
  81     CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
  82     CXXFLAGS="$PTHREAD_CFLAGS $CXXFLAGS"
  83 fi
  84
  85 AC_CHECK_FUNCS([pthread_rwlock_init])
  86
  87 AC_LANG(C++)
  88
  89 # C++ requirements
  90 AC_CXX_REQUIRE_STL
  91 AC_CXX_NAMESPACES
  92
  93 # are covariant methods allowed?
  94 AC_LINK_IFELSE(
  95         [AC_LANG_PROGRAM([[]],
  96                 [[
  97                 class base { public: virtual base *GetPtr( void ) { return this; } };
  98                 class derived: virtual public base { public: virtual derived *GetPtr( void ) { return this; } };
  99                 ]])],
 100     [AC_DEFINE([HAVE_COVARIANT_RETURNS], [1], [Define to 1 if C++ compiler supports covariant virtual methods.])]
 101         )
 102
 103 # is nullptr supported?
 104 AC_COMPILE_IFELSE(
 105         [AC_LANG_PROGRAM([[]],
 106                 [[
 107                 const char* ptr = nullptr;
 108                 ]])],
 109         [AC_DEFINE([HAVE_NULLPTR], [1], [Define to 1 if C++ compiler supports nullptr keyword.])]
 110         )
 111
 112 # log4shib settings (favor this version over the log4cpp code)
 113 AC_PATH_PROG(LOG4SHIB_CONFIG,log4shib-config)
 114 AC_ARG_WITH(log4shib,
 115     AS_HELP_STRING([--with-log4shib=PATH], [where log4shib-config is installed]),
 116     [
 117     LOG4SHIB_CONFIG="${with_log4shib}"
 118     if ! test -f "${LOG4SHIB_CONFIG}" ; then
 119         LOG4SHIB_CONFIG="${with_log4shib}/bin/log4shib-config"
 120     fi
 121     ])
 122 if test -f "${LOG4SHIB_CONFIG}"; then
 123     LIBS="`${LOG4SHIB_CONFIG} --libs` $LIBS"
 124     CPPFLAGS="`${LOG4SHIB_CONFIG} --cflags` $CPPFLAGS"
 125         AC_CHECK_HEADER([log4shib/CategoryStream.hh],,AC_MSG_ERROR([unable to find log4shib header files]))
 126         AC_TRY_LINK(
 127                 [#include <log4shib/Category.hh>
 128 #include <log4shib/CategoryStream.hh>],
 129                 [log4shib::Category::getInstance("foo").errorStream() << log4shib::eol],
 130                 [AC_DEFINE([XMLTOOLING_LOG4SHIB], [1], [Define to 1 if log4shib library is used.])],
 131                 [AC_MSG_ERROR([unable to link with log4shib])])
 132 else
 133     AC_MSG_WARN([log4shib-config not found, may need to use --with-log4shib option])
 134     AC_MSG_WARN([will look for original log4cpp library])
 135
 136         # log4cpp settings
 137         AC_PATH_PROG(LOG4CPP_CONFIG,log4cpp-config)
 138         AC_ARG_WITH(log4cpp,
 139             AS_HELP_STRING([--with-log4cpp=PATH], [where log4cpp-config is installed]),
 140             [
 141             LOG4CPP_CONFIG="${with_log4cpp}"
 142             if ! test -f "${LOG4CPP_CONFIG}" ; then
 143                 LOG4CPP_CONFIG="${with_log4cpp}/bin/log4cpp-config"
 144             fi
 145             ])
 146         if test -f "${LOG4CPP_CONFIG}"; then
 147                 AC_MSG_WARN([will try to use log4cpp, note that most non-Internet2 supplied versions are not thread-safe])
 148             LIBS="`${LOG4CPP_CONFIG} --libs` $LIBS"
 149             CPPFLAGS="`${LOG4CPP_CONFIG} --cflags` $CPPFLAGS"
 150                 AC_CHECK_HEADER([log4cpp/CategoryStream.hh],,AC_MSG_ERROR([unable to find log4cpp header files]))
 151                 AC_TRY_LINK(
 152                         [#include <log4cpp/Category.hh>
 153 #include <log4cpp/CategoryStream.hh>],
 154                         [log4cpp::Category::getInstance("foo").errorStream() << log4cpp::eol],
 155                         [AC_DEFINE([XMLTOOLING_LOG4CPP], [1], [Define to 1 if log4cpp library is used.])],
 156                         [AC_MSG_ERROR([unable to link with log4cpp, need version 1.0 or later])])
 157         else
 158             AC_MSG_ERROR([log4cpp-config not found, may need to use --with-log4cpp option])
 159         fi
 160 fi
 161
 162 # Xerces settings
 163 AC_ARG_WITH(xerces,
 164             AS_HELP_STRING([--with-xerces=PATH], [where xerces-c is installed]),
 165             [if test x_$with_xerces != x_/usr; then
 166                 LDFLAGS="-L${with_xerces}/lib $LDFLAGS"
 167                 CPPFLAGS="-I${with_xerces}/include $CPPFLAGS"
 168             fi])
 169 LIBS="-lxerces-c $LIBS"
 170 AC_CHECK_HEADER([xercesc/dom/DOM.hpp],,AC_MSG_ERROR([unable to find xerces header files]))
 171 AC_MSG_CHECKING([Xerces version])
 172 AC_PREPROC_IFELSE(
 173     [AC_LANG_PROGRAM([#include <xercesc/util/XercesVersion.hpp>],
 174 [#if  _XERCES_VERSION != 20600
 175 int i = 0;
 176 #else
 177 #error cannot use version 2.6.0
 178 #endif])],
 179     [AC_MSG_RESULT(OK)],
 180     [AC_MSG_FAILURE([Xerces-C v2.6.0 has bugs that inhibit use with signed XML, please use a newer version])])
 181 AC_TRY_LINK(
 182         [#include <xercesc/util/PlatformUtils.hpp>],
 183         [xercesc::XMLPlatformUtils::Initialize()],
 184         [AC_DEFINE([HAVE_LIBXERCESC], [1], [Define to 1 if Xerces-C library was found])],
 185         [AC_MSG_ERROR([unable to link with Xerces])])
 186
 187 AC_MSG_CHECKING([whether Xerces is 64-bit clean])
 188 AC_TRY_COMPILE([#include <xercesc/framework/MemBufInputSource.hpp>],
 189     [using namespace XERCES_CPP_NAMESPACE;
 190       XMLFilePos testvar;
 191     ],
 192     [AC_MSG_RESULT([yes])]
 193     [AC_DEFINE([XMLTOOLING_XERCESC_64BITSAFE], [1], [Define to 1 if Xerces has a 64-bit-safe API.])],
 194     [AC_MSG_RESULT([no])])
 195
 196 AC_MSG_CHECKING([whether Xerces BinInputStream requires getContentType])
 197 AC_TRY_COMPILE([#include <xercesc/util/BinMemInputStream.hpp>],
 198     [using namespace XERCES_CPP_NAMESPACE;
 199       XMLByte buf[1024];
 200       BinMemInputStream in(buf,1024);
 201       in.getContentType();
 202     ],
 203     [AC_MSG_RESULT([yes])]
 204     [AC_DEFINE([XMLTOOLING_XERCESC_INPUTSTREAM_HAS_CONTENTTYPE], [1], [Define to 1 if Xerces InputStream class requires getContentType.])],
 205     [AC_MSG_RESULT([no])])
 206
 207 AC_MSG_CHECKING([whether Xerces DOMLS API is compliant])
 208 AC_TRY_COMPILE([#include <xercesc/dom/DOM.hpp>],
 209     [using namespace XERCES_CPP_NAMESPACE;
 210         DOMImplementation *impl = DOMImplementationRegistry::getDOMImplementation(NULL);
 211         DOMLSSerializer *ls = ((DOMImplementationLS*)impl)->createLSSerializer();
 212     ],
 213     [AC_MSG_RESULT([yes])]
 214     [AC_DEFINE([XMLTOOLING_XERCESC_COMPLIANT_DOMLS], [1], [Define to 1 if Xerces supports a compliant DOMLS API.])],
 215     [AC_MSG_RESULT([no])])
 216
 217 AC_MSG_CHECKING([whether Xerces has setIdAttribute(XMLCh*, bool)])
 218 AC_TRY_COMPILE([#include <xercesc/dom/DOM.hpp>],
 219       [using namespace XERCES_CPP_NAMESPACE;
 220           DOMElement * elt;
 221           elt->setIdAttribute(NULL, false);
 222       ],
 223       [AC_MSG_RESULT([yes])]
 224       [AC_DEFINE([XMLTOOLING_XERCESC_BOOLSETIDATTRIBUTE], [1], [Define to 1 if Xerces DOM ID methods take extra parameter.])],
 225       [AC_MSG_RESULT([no])])
 226
 227 AC_MSG_CHECKING([whether Xerces XMLString::release(XMLByte**) exists])
 228 AC_TRY_COMPILE([#include <xercesc/util/XMLString.hpp>],
 229     [using namespace XERCES_CPP_NAMESPACE;
 230       XMLByte* buf=NULL;
 231       XMLString::release(&buf);
 232     ],
 233     [AC_MSG_RESULT([yes])]
 234     [AC_DEFINE([XMLTOOLING_XERCESC_HAS_XMLBYTE_RELEASE], [1], [Define to 1 if Xerces XMLString includes XMLByte release.])],
 235     [AC_MSG_RESULT([no])])
 236
 237 # XML-Security settings
 238 AC_ARG_WITH(xmlsec,
 239             AS_HELP_STRING([--with-xmlsec=PATH], [where xmlsec is installed]),,
 240             [with_xmlsec=/usr])
 241
 242 if test x_$with_xmlsec != x_no; then
 243
 244     # OpenSSL settings (need to do this first in case it's in a different spot from xmlsec)
 245     AC_ARG_WITH(openssl,
 246         AS_HELP_STRING([--with-openssl=PATH], [where openssl is installed]),
 247         [if test x_$with_openssl != x_/usr; then
 248             SSLFLAGS="-I${with_openssl}/include"
 249             SSLLIBS="-L${with_openssl}/lib -lcrypto -lssl"
 250         else
 251             SSLLIBS="-lcrypto -lssl"
 252         fi])
 253
 254     if test "x$SSLLIBS" = "x" ; then
 255         AC_PATH_PROG(PKG_CONFIG, pkg-config)
 256         if test "x$PKG_CONFIG" != x && test "x$PKG_CONFIG" != "xno" ; then
 257             if pkg-config openssl ; then
 258                 SSLLIBS="`$PKG_CONFIG --libs openssl`"
 259                 SSLFLAGS="`$PKG_CONFIG --cflags openssl`"
 260             else
 261                 AC_MSG_WARN([OpenSSL not supported by pkg-config, try --with-openssl instead])
 262             fi
 263         fi
 264     fi
 265
 266     if test "x$SSLLIBS" = "x" ; then
 267         SSLLIBS="-lcrypto -lssl"
 268     fi
 269
 270     AC_MSG_CHECKING(for OpenSSL cflags)
 271     AC_MSG_RESULT($SSLFLAGS)
 272     CPPFLAGS="$CPPFLAGS $SSLFLAGS"
 273     AC_MSG_CHECKING(for OpenSSL libraries)
 274     AC_MSG_RESULT($SSLLIBS)
 275     XMLSEC_LIBS="$XMLSEC_LIBS $SSLLIBS"
 276
 277     # save and append master libs
 278     save_LIBS="$LIBS"
 279     LIBS="$XMLSEC_LIBS $LIBS"
 280
 281     AC_CHECK_HEADER([openssl/pem.h],,
 282                     AC_MSG_ERROR([unable to find openssl header files]))
 283     AC_MSG_CHECKING(for ERR_load_CRYPTO_string)
 284     AC_TRY_LINK_FUNC([ERR_load_CRYPTO_strings],,
 285                  AC_MSG_ERROR([unable to link with openssl libraries]))
 286     AC_MSG_RESULT(yes)
 287
 288         AC_CHECK_DECL(EVP_sha512,
 289                 [AC_DEFINE([XMLTOOLING_OPENSSL_HAVE_SHA2],[],[Define to 1 if OpenSSL supports the SHA-2 hash family.])],
 290                 ,[#include <openssl/evp.h>])
 291
 292     # restore master libs
 293     LIBS="$save_LIBS"
 294
 295     if test x_$with_xmlsec != x_/usr; then
 296         CPPFLAGS="-I${with_xmlsec}/include $CPPFLAGS"
 297         LDFLAGS="-L${with_xmlsec}/lib $LDFLAGS"
 298     fi
 299     XMLSEC_LIBS="$XMLSEC_LIBS -lxml-security-c"
 300
 301     # save and append master libs
 302     save_LIBS="$LIBS"
 303     LIBS="$XMLSEC_LIBS $LIBS"
 304
 305     AC_CHECK_HEADER([xsec/utils/XSECPlatformUtils.hpp],,AC_MSG_ERROR([unable to find XML-Security header files]))
 306     AC_MSG_CHECKING([XML-Security version])
 307     AC_PREPROC_IFELSE(
 308             [AC_LANG_PROGRAM([#include <xsec/utils/XSECPlatformUtils.hpp>],
 309         [#if XSEC_VERSION_MAJOR > 1 || (XSEC_VERSION_MAJOR == 1 && XSEC_VERSION_MEDIUM > 3)
 310 int i = 0;
 311 #else
 312 #error need version 1.4.0 or later
 313 #endif])],
 314         [AC_MSG_RESULT(OK)],
 315         [AC_MSG_FAILURE([XML-Security version 1.4.0 or greater is required.])])
 316     AC_TRY_LINK(
 317             [#include <xsec/utils/XSECPlatformUtils.hpp>],
 318             [XSECPlatformUtils::Initialise()],,
 319             [AC_MSG_ERROR([unable to link with XML-Security])])
 320     AC_CHECK_TYPE([xsecsize_t],[AC_DEFINE([HAVE_XSECSIZE_T], [1], [Define to 1 if you have the 'xsecsize_t' type.])])
 321
 322     AC_MSG_CHECKING([whether XML-Security-C has multiple CRL support])
 323     AC_TRY_COMPILE([#include <xsec/dsig/DSIGKeyInfoList.hpp>],
 324           [DSIGKeyInfoList* klist; klist->getX509CRLListSize();],
 325           [AC_MSG_RESULT([yes])]
 326           [AC_DEFINE([XMLTOOLING_XMLSEC_MULTIPLECRL], [1], [Define to 1 if XML-Security-C handles multiple CRLs.])],
 327           [AC_MSG_RESULT([no])])
 328
 329     AC_MSG_CHECKING([whether XML-Security-C exposes the signature algorithm URI])
 330     AC_TRY_COMPILE([#include <xsec/dsig/DSIGSignature.hpp>],
 331           [DSIGSignature* sig; sig->getAlgorithmURI();],
 332           [AC_MSG_RESULT([yes])]
 333           [AC_DEFINE([XMLTOOLING_XMLSEC_SIGALGORITHM], [1], [Define to 1 if XML-Security-C exposes the signature algorithm URI.])],
 334           [AC_MSG_RESULT([no])])
 335
 336     AC_MSG_CHECKING([whether XML-Security-C includes ECC support])
 337     AC_TRY_COMPILE([#include <xsec/dsig/DSIGKeyInfoValue.hpp>],
 338           [DSIGKeyInfoValue* info; info->getECNamedCurve();],
 339           [AC_MSG_RESULT([yes])]
 340           [AC_DEFINE([XMLTOOLING_XMLSEC_ECC], [1], [Define to 1 if XML-Security-C includes ECC support.])],
 341           [AC_MSG_RESULT([no])])
 342
 343     AC_MSG_CHECKING([whether XML-Security-C includes debug logging support])
 344     AC_TRY_COMPILE([#include <xsec/utils/XSECPlatformUtils.hpp>],
 345           [XSECPlatformUtils::SetReferenceLoggingSink(NULL)],
 346           [AC_MSG_RESULT([yes])]
 347           [AC_DEFINE([XMLTOOLING_XMLSEC_DEBUGLOGGING], [1], [Define to 1 if XML-Security-C includes debug logging support.])],
 348           [AC_MSG_RESULT([no])])
 349
 350         # restore master libs
 351         LIBS="$save_LIBS"
 352
 353         # libcurl settings
 354         AC_PATH_PROG(CURL_CONFIG,curl-config)
 355         AC_ARG_WITH(curl,
 356             AS_HELP_STRING([--with-curl=PATH], [where curl-config is installed]),
 357             [
 358             CURL_CONFIG="${with_curl}"
 359             if ! test -f "${CURL_CONFIG}" ; then
 360                 CURL_CONFIG="${with_curl}/bin/curl-config"
 361             fi
 362             ])
 363         if test -f "${CURL_CONFIG}" ; then
 364             CPPFLAGS="`${CURL_CONFIG} --cflags` $CPPFLAGS"
 365             XMLSEC_LIBS="`${CURL_CONFIG} --libs` $XMLSEC_LIBS"
 366         else
 367             AC_MSG_ERROR([curl-config not found, may need to use --with-curl option])
 368         fi
 369
 370         # save and append master libs
 371         save_LIBS="$LIBS"
 372         LIBS="$XMLSEC_LIBS $LIBS"
 373
 374         AC_CHECK_HEADER([curl/curl.h],,AC_MSG_ERROR([unable to find libcurl header files]))
 375         AC_CHECK_LIB([curl],[curl_global_init],,AC_MSG_ERROR([unable to link with libcurl]))
 376         AC_MSG_CHECKING([for CURLOPT_SSL_CTX_FUNCTION in curl.h])
 377         AC_EGREP_HEADER([CURLOPT_SSL_CTX_FUNCTION], [curl/curl.h],
 378                         [AC_MSG_RESULT(yes)],
 379                         [AC_MSG_ERROR([need libcurl that supports CURLOPT_SSL_CTX_FUNCTION])])
 380     AC_CHECK_TYPE([curl_off_t],[AC_DEFINE([HAVE_CURL_OFF_T], [1], [Define to 1 if you have the 'curl_off_t' type.])])
 381
 382         # restore master libs
 383         LIBS="$save_LIBS"
 384
 385         AC_SUBST(XMLSEC_LIBS)
 386 else
 387     AC_MSG_WARN([xmlsec disabled, building without signature/encryption support])
 388     AC_DEFINE([XMLTOOLING_NO_XMLSEC], [1], [Define to 1 if you wish to disable XML-Security-dependent features.])
 389 fi
 390 AM_CONDITIONAL(BUILD_XMLSEC,test x_$with_xmlsec != x_no)
 391
 392 # Does the STL in use help or screw us?
 393 AC_TRY_LINK(
 394         [#include <string>],
 395         [std::basic_string<unsigned short> foo; foo=foo+(unsigned short)65],
 396         [AC_DEFINE([HAVE_GOOD_STL], [1],
 397             [Define to 1 if you have an STL implementation that supports useful string specialization.])],
 398         )
 399 AC_TRY_LINK(
 400         [#include <vector>],
 401         [std::iterator_traits<std::vector<int>::iterator>::value_type foo=0],
 402         [AC_DEFINE([HAVE_ITERATOR_TRAITS], [1],
 403             [Define to 1 if you have an STL implementation that supports std::iterator_traits.])],
 404         )
 405
 406 # Check for unit test support
 407 CXXTEST="/usr/bin/cxxtestgen.pl"
 408 CXXTESTFLAGS=""
 409 AC_ARG_WITH(cxxtest,
 410             AS_HELP_STRING([--with-cxxtest=PATH], [where cxxtest is installed]),
 411             [if test x_$with_cxxtest != x_/usr; then
 412                 CXXTEST="${with_cxxtest}/cxxtestgen.pl"
 413                 CXXTESTFLAGS="-I${with_cxxtest}"
 414             fi])
 415 if ! test -f "${CXXTEST}"; then
 416     AC_MSG_WARN([cxxtestgen not found, won't build unit tests])
 417 fi
 418
 419 AC_SUBST(CXXTEST)
 420 AC_SUBST(CXXTESTFLAGS)
 421 AM_CONDITIONAL(BUILD_UNITTEST,test -f ${CXXTEST})
 422
 423 AX_CREATE_PKGCONFIG_INFO(,,[$XMLSEC_LIBS -lxmltooling],[OpenSAML XMLTooling-C library])
 424
 425 LIBTOOL="$LIBTOOL --silent"
 426
 427 # output packaging and makefiles
 428 AC_OUTPUT