configure.ac

   1 # Process this file with autoreconf
   2 AC_PREREQ([2.50])
   3 AC_INIT([xmltooling],[1.5],[https://issues.shibboleth.net/],[xmltooling])
   4 AC_CONFIG_SRCDIR(xmltooling)
   5 AC_CONFIG_AUX_DIR(build-aux)
   6 AC_CONFIG_MACRO_DIR(m4)
   7 AM_INIT_AUTOMAKE
   8 AC_DISABLE_STATIC
   9 AC_PROG_LIBTOOL
  10
  11 # Docygen features
  12 DX_HTML_FEATURE(ON)
  13 DX_CHM_FEATURE(OFF)
  14 DX_CHI_FEATURE(OFF)
  15 DX_MAN_FEATURE(OFF)
  16 DX_RTF_FEATURE(OFF)
  17 DX_XML_FEATURE(OFF)
  18 DX_PDF_FEATURE(OFF)
  19 DX_PS_FEATURE(OFF)
  20 DX_INIT_DOXYGEN(xmltooling, doxygen.cfg, doc/api)
  21
  22 AC_ARG_ENABLE(debug,
  23     AS_HELP_STRING([--enable-debug],[Have GCC compile with symbols (Default = no)]),
  24     enable_debug=$enableval, enable_debug=no)
  25
  26 if test "$enable_debug" = "yes" ; then
  27     GCC_CFLAGS="$CFLAGS -g -D_DEBUG"
  28     GCC_CXXFLAGS="$CXXFLAGS -g -D_DEBUG"
  29 else
  30     GCC_CFLAGS="$CFLAGS -O2 -DNDEBUG"
  31     GCC_CXXFLAGS="$CXXFLAGS -O2 -DNDEBUG"
  32 fi
  33
  34 AC_CONFIG_HEADERS([config.h xmltooling/config_pub.h])
  35 AC_CONFIG_FILES([xmltooling.spec])
  36 AC_CONFIG_FILES([Makefile xmltooling/Makefile xmltoolingtest/Makefile schemas/Makefile doc/Makefile])
  37
  38 AC_PROG_CC([gcc gcc3 cc])
  39 AC_PROG_CXX([g++ g++3 c++ CC])
  40 AC_CANONICAL_HOST
  41
  42 if test "$GCC" = "yes" ; then
  43 #    AC_HAVE_GCC_VERSION(4,0,0,0,
  44 #        [
  45 #        AC_DEFINE(GCC_HASCLASSVISIBILITY,1,
  46 #            [Define to enable class visibility control in gcc.])
  47 #        GCC_CFLAGS="$GCC_CFLAGS -fvisibility=hidden -fvisibility-inlines-hidden"
  48 #        GCC_CXXFLAGS="$GCC_CXXFLAGS -fvisibility=hidden -fvisibility-inlines-hidden"
  49 #        ])
  50     CFLAGS="-Wall $GCC_CFLAGS"
  51     CXXFLAGS="-Wall $GCC_CXXFLAGS"
  52 fi
  53
  54 # Fix for Sun Workshop compiler in debug mode, may be Sun case #6360993
  55 # Also enables POSIX semantics for some functions.
  56 case "${host_cpu}-${host_os}" in
  57     *solaris*)
  58         CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS"
  59         CXXFLAGS="$CXXFLAGS -D_POSIX_PTHREAD_SEMANTICS"
  60         if test "$CXX" = "CC" ; then
  61                 CXXFLAGS="$CXXFLAGS -Qoption ccfe -stabs=no%dfltlit+no%dflthlp"
  62         fi
  63     ;;
  64 esac
  65
  66 # Checks for typedefs, structures, and compiler characteristics.
  67 AC_C_CONST
  68 AC_TYPE_SIZE_T
  69 AC_CHECK_SIZEOF([long])
  70
  71 # Checks for library functions.
  72 AC_CHECK_FUNCS([strchr strdup strstr timegm strcasecmp])
  73 AC_CHECK_HEADERS([dlfcn.h])
  74 AC_CHECK_FUNC(dlclose, , [ AC_CHECK_LIB(dl, dlopen) ])
  75
  76 # checks for pthreads
  77 ACX_PTHREAD([enable_threads="pthread"],[enable_threads="no"])
  78 if test $enable_threads != "pthread"; then
  79     AC_MSG_ERROR([unable to find pthreads, currently this is required])
  80 else
  81     AC_DEFINE([HAVE_PTHREAD],[1],[Define if you have POSIX threads libraries and header files.])
  82         AM_CONDITIONAL(BUILD_PTHREAD,test "$enable_threads" = "pthread")
  83     LIBS="$PTHREAD_LIBS $LIBS"
  84     CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
  85     CXXFLAGS="$PTHREAD_CFLAGS $CXXFLAGS"
  86 fi
  87
  88 AC_CHECK_FUNCS([pthread_rwlock_init])
  89
  90 AC_LANG([C++])
  91
  92 # C++ requirements
  93 AC_CXX_NAMESPACES
  94 AC_CXX_REQUIRE_STL
  95
  96 # Boost
  97 BOOST_REQUIRE
  98 BOOST_BIND
  99 BOOST_LAMBDA
 100 BOOST_STRING_ALGO
 101
 102 # are covariant methods allowed?
 103 AC_LINK_IFELSE(
 104     [AC_LANG_PROGRAM([[]],
 105         [[
 106         class base { public: virtual base *GetPtr( void ) { return this; } };
 107         class derived: virtual public base { public: virtual derived *GetPtr( void ) { return this; } };
 108         ]])],
 109     [AC_DEFINE([HAVE_COVARIANT_RETURNS],[1],[Define to 1 if C++ compiler supports covariant virtual methods.])])
 110
 111 # is nullptr supported?
 112 AC_COMPILE_IFELSE(
 113     [AC_LANG_PROGRAM([[]],[[const char* ptr = nullptr;]])],
 114     [AC_DEFINE([HAVE_NULLPTR],[1],[Define to 1 if C++ compiler supports nullptr keyword.])])
 115
 116 # log4shib settings (favor this version over the log4cpp code)
 117 AC_PATH_PROG(LOG4SHIB_CONFIG,log4shib-config)
 118 AC_ARG_WITH(log4shib,
 119     AS_HELP_STRING([--with-log4shib=PATH],[where log4shib-config is installed]),
 120     [
 121     LOG4SHIB_CONFIG="${with_log4shib}"
 122     if ! test -f "${LOG4SHIB_CONFIG}" ; then
 123         LOG4SHIB_CONFIG="${with_log4shib}/bin/log4shib-config"
 124     fi
 125     ])
 126 if test -f "${LOG4SHIB_CONFIG}" ; then
 127     LIBS="`${LOG4SHIB_CONFIG} --libs` $LIBS"
 128     CPPFLAGS="`${LOG4SHIB_CONFIG} --cflags` $CPPFLAGS"
 129     AC_CHECK_HEADER([log4shib/CategoryStream.hh],,AC_MSG_ERROR([unable to find log4shib header files]))
 130     AC_LINK_IFELSE(
 131         [AC_LANG_PROGRAM([[#include <log4shib/Category.hh>
 132 #include <log4shib/CategoryStream.hh>]],
 133             [[log4shib::Category::getInstance("foo").errorStream() << log4shib::eol]])],
 134         [AC_DEFINE([XMLTOOLING_LOG4SHIB],[1],[Define to 1 if log4shib library is used.])],
 135         [AC_MSG_ERROR([unable to link with log4shib])])
 136 else
 137     AC_MSG_WARN([log4shib-config not found, may need to use --with-log4shib option])
 138     AC_MSG_WARN([will look for original log4cpp library])
 139
 140     # log4cpp settings
 141     AC_PATH_PROG(LOG4CPP_CONFIG,log4cpp-config)
 142     AC_ARG_WITH(log4cpp,
 143         AS_HELP_STRING([--with-log4cpp=PATH],[where log4cpp-config is installed]),
 144         [
 145         LOG4CPP_CONFIG="${with_log4cpp}"
 146         if ! test -f "${LOG4CPP_CONFIG}" ; then
 147                 LOG4CPP_CONFIG="${with_log4cpp}/bin/log4cpp-config"
 148         fi
 149         ])
 150     if test -f "${LOG4CPP_CONFIG}"; then
 151         AC_MSG_WARN([will try to use log4cpp, note that most non-Internet2 supplied versions are not thread-safe])
 152         LIBS="`${LOG4CPP_CONFIG} --libs` $LIBS"
 153         CPPFLAGS="`${LOG4CPP_CONFIG} --cflags` $CPPFLAGS"
 154         AC_CHECK_HEADER([log4cpp/CategoryStream.hh],,AC_MSG_ERROR([unable to find log4cpp header files]))
 155         AC_LINK_IFELSE(
 156             [AC_LANG_PROGRAM([[#include <log4cpp/Category.hh>
 157 #include <log4cpp/CategoryStream.hh>]],
 158                 [[log4cpp::Category::getInstance("foo").errorStream() << log4cpp::eol]])],
 159             [AC_DEFINE([XMLTOOLING_LOG4CPP],[1],[Define to 1 if log4cpp library is used.])],
 160             [AC_MSG_ERROR([unable to link with log4cpp, need version 1.0 or later])])
 161         else
 162             AC_MSG_ERROR([log4cpp-config not found, may need to use --with-log4cpp option])
 163         fi
 164 fi
 165
 166 # Xerces settings
 167 AC_ARG_WITH(xerces,
 168     AS_HELP_STRING([--with-xerces=PATH],[where xerces-c is installed]),,
 169     [with_xerces=/usr])
 170 if test x_$with_xerces != x_/usr; then
 171     CPPFLAGS="-I${with_xerces}/include $CPPFLAGS"
 172     LIBS="-L${with_xerces}/lib -lxerces-c $LIBS"
 173 else
 174     LIBS="-lxerces-c $LIBS"
 175 fi
 176
 177 AC_CHECK_HEADER([xercesc/dom/DOM.hpp],,AC_MSG_ERROR([unable to find xerces header files]))
 178 AC_MSG_CHECKING([Xerces version])
 179 AC_PREPROC_IFELSE(
 180     [AC_LANG_PROGRAM([#include <xercesc/util/XercesVersion.hpp>],
 181 [#if  _XERCES_VERSION != 20600
 182 int i = 0;
 183 #else
 184 #error cannot use version 2.6.0
 185 #endif])],
 186     [AC_MSG_RESULT(OK)],
 187     [AC_MSG_FAILURE([Xerces-C v2.6.0 has bugs that inhibit use with signed XML, please use a newer version])])
 188 AC_LINK_IFELSE(
 189     [AC_LANG_PROGRAM([[#include <xercesc/util/PlatformUtils.hpp>]],
 190         [[xercesc::XMLPlatformUtils::Initialize()]])],
 191     ,[AC_MSG_ERROR([unable to link with Xerces])])
 192
 193 AC_MSG_CHECKING([whether Xerces is 64-bit clean])
 194 AC_COMPILE_IFELSE(
 195     [AC_LANG_PROGRAM([[#include <xercesc/framework/MemBufInputSource.hpp>]],
 196         [[using namespace XERCES_CPP_NAMESPACE; XMLFilePos testvar;]])],
 197     [AC_MSG_RESULT([yes])AC_DEFINE([XMLTOOLING_XERCESC_64BITSAFE],[1],[Define to 1 if Xerces has a 64-bit-safe API.])],
 198     [AC_MSG_RESULT([no])])
 199
 200 AC_MSG_CHECKING([whether Xerces BinInputStream requires getContentType])
 201 AC_COMPILE_IFELSE(
 202     [AC_LANG_PROGRAM([[#include <xercesc/util/BinMemInputStream.hpp>]],
 203         [[using namespace XERCES_CPP_NAMESPACE; XMLByte buf[1024]; BinMemInputStream in(buf,1024); in.getContentType();]])],
 204     [AC_MSG_RESULT([yes])AC_DEFINE([XMLTOOLING_XERCESC_INPUTSTREAM_HAS_CONTENTTYPE],[1],[Define to 1 if Xerces InputStream class requires getContentType.])],
 205     [AC_MSG_RESULT([no])])
 206
 207 AC_MSG_CHECKING([whether Xerces DOMLS API is compliant])
 208 AC_COMPILE_IFELSE(
 209     [AC_LANG_PROGRAM([[#include <xercesc/dom/DOM.hpp>]],
 210         [[using namespace XERCES_CPP_NAMESPACE;
 211         DOMImplementation *impl = DOMImplementationRegistry::getDOMImplementation(NULL);
 212         DOMLSSerializer *ls = ((DOMImplementationLS*)impl)->createLSSerializer();]])],
 213     [AC_MSG_RESULT([yes])AC_DEFINE([XMLTOOLING_XERCESC_COMPLIANT_DOMLS],[1],[Define to 1 if Xerces supports a compliant DOMLS API.])],
 214     [AC_MSG_RESULT([no])])
 215
 216 AC_MSG_CHECKING([whether Xerces has setIdAttribute(XMLCh*, bool)])
 217 AC_COMPILE_IFELSE(
 218     [AC_LANG_PROGRAM([[#include <xercesc/dom/DOM.hpp>]],
 219         [[using namespace XERCES_CPP_NAMESPACE; DOMElement * elt; elt->setIdAttribute(NULL, false);]])],
 220     [AC_MSG_RESULT([yes])AC_DEFINE([XMLTOOLING_XERCESC_BOOLSETIDATTRIBUTE],[1],[Define to 1 if Xerces DOM ID methods take extra parameter.])],
 221     [AC_MSG_RESULT([no])])
 222
 223 AC_MSG_CHECKING([whether Xerces XMLString::release(XMLByte**) exists])
 224 AC_COMPILE_IFELSE(
 225     [AC_LANG_PROGRAM([[#include <xercesc/util/XMLString.hpp>]],
 226     [[using namespace XERCES_CPP_NAMESPACE; XMLByte* buf=NULL; XMLString::release(&buf);]])],
 227     [AC_MSG_RESULT([yes])AC_DEFINE([XMLTOOLING_XERCESC_HAS_XMLBYTE_RELEASE],[1],[Define to 1 if Xerces XMLString includes XMLByte release.])],
 228     [AC_MSG_RESULT([no])])
 229
 230 # XML-Security settings
 231 AC_ARG_WITH(xmlsec,
 232     AS_HELP_STRING([--with-xmlsec=PATH], [where xmlsec is installed]),,
 233     [with_xmlsec=/usr])
 234
 235 if test x_$with_xmlsec != x_no; then
 236
 237     # OpenSSL settings (need to do this first in case it's in a different spot from xmlsec)
 238     AC_ARG_WITH(openssl,
 239         AS_HELP_STRING([--with-openssl=PATH], [where openssl is installed]),
 240         [if test x_$with_openssl != x_/usr; then
 241             SSLFLAGS="-I${with_openssl}/include"
 242             SSLLIBS="-L${with_openssl}/lib -lcrypto -lssl"
 243         else
 244             SSLLIBS="-lcrypto -lssl"
 245         fi])
 246
 247     if test "x$SSLLIBS" = "x" ; then
 248         AC_PATH_PROG(PKG_CONFIG, pkg-config)
 249         if test "x$PKG_CONFIG" != x && test "x$PKG_CONFIG" != "xno" ; then
 250             if pkg-config openssl ; then
 251                 SSLLIBS="`$PKG_CONFIG --libs openssl`"
 252                 SSLFLAGS="`$PKG_CONFIG --cflags openssl`"
 253             else
 254                 AC_MSG_WARN([OpenSSL not supported by pkg-config, try --with-openssl instead])
 255             fi
 256         fi
 257     fi
 258
 259     if test "x$SSLLIBS" = "x" ; then
 260         SSLLIBS="-lcrypto -lssl"
 261     fi
 262
 263     AC_MSG_CHECKING(for OpenSSL cflags)
 264     AC_MSG_RESULT($SSLFLAGS)
 265     CPPFLAGS="$CPPFLAGS $SSLFLAGS"
 266     AC_MSG_CHECKING(for OpenSSL libraries)
 267     AC_MSG_RESULT($SSLLIBS)
 268     XMLSEC_LIBS="$XMLSEC_LIBS $SSLLIBS"
 269
 270     # save and append master libs
 271     save_LIBS="$LIBS"
 272     LIBS="$XMLSEC_LIBS $LIBS"
 273
 274     AC_CHECK_HEADER([openssl/pem.h],,AC_MSG_ERROR([unable to find openssl header files]))
 275     AC_MSG_CHECKING(for ERR_load_CRYPTO_string)
 276     AC_TRY_LINK_FUNC([ERR_load_CRYPTO_strings],,AC_MSG_ERROR([unable to link with openssl libraries]))
 277     AC_MSG_RESULT(yes)
 278
 279     AC_CHECK_DECL(EVP_sha512,
 280         [AC_DEFINE([XMLTOOLING_OPENSSL_HAVE_SHA2],[1],[Define to 1 if OpenSSL supports the SHA-2 hash family.])],
 281                 ,[#include <openssl/evp.h>])
 282     AC_CHECK_DECL(EVP_PKEY_set1_EC_KEY,
 283         [AC_DEFINE([XMLTOOLING_OPENSSL_HAVE_EC],[1],[Define to 1 if OpenSSL has EC support.])],
 284         ,[#include <openssl/evp.h>])
 285
 286     # restore master libs
 287     LIBS="$save_LIBS"
 288
 289     if test x_$with_xmlsec != x_/usr; then
 290         CPPFLAGS="-I${with_xmlsec}/include $CPPFLAGS"
 291         XMLSEC_LIBS="-L${with_xmlsec}/lib -lxml-security-c $XMLSEC_LIBS"
 292     else
 293         XMLSEC_LIBS="-lxml-security-c $XMLSEC_LIBS"
 294     fi
 295
 296     # save and append master libs
 297     save_LIBS="$LIBS"
 298     LIBS="$XMLSEC_LIBS $LIBS"
 299
 300     AC_CHECK_HEADER([xsec/utils/XSECPlatformUtils.hpp],,AC_MSG_ERROR([unable to find XML-Security header files]))
 301     AC_MSG_CHECKING([XML-Security version])
 302     AC_PREPROC_IFELSE(
 303             [AC_LANG_PROGRAM([#include <xsec/utils/XSECPlatformUtils.hpp>],
 304         [#if XSEC_VERSION_MAJOR > 1 || (XSEC_VERSION_MAJOR == 1 && XSEC_VERSION_MEDIUM > 3)
 305 int i = 0;
 306 #else
 307 #error need version 1.4.0 or later
 308 #endif])],
 309         [AC_MSG_RESULT(OK)],
 310         [AC_MSG_FAILURE([XML-Security version 1.4.0 or greater is required.])])
 311
 312     AC_LINK_IFELSE(
 313         [AC_LANG_PROGRAM([[#include <xsec/utils/XSECPlatformUtils.hpp>]],
 314             [[XSECPlatformUtils::Initialise()]])],,
 315         [AC_MSG_ERROR([unable to link with XML-Security])])
 316     AC_CHECK_TYPE([xsecsize_t],[AC_DEFINE([HAVE_XSECSIZE_T],[1],[Define to 1 if you have the 'xsecsize_t' type.])])
 317
 318     AC_MSG_CHECKING([whether XML-Security-C has multiple CRL support])
 319     AC_COMPILE_IFELSE(
 320         [AC_LANG_PROGRAM([[#include <xsec/dsig/DSIGKeyInfoX509.hpp>]],
 321             [[DSIGKeyInfoX509* klist; klist->getX509CRLListSize();]])],
 322         [AC_MSG_RESULT([yes])AC_DEFINE([XMLTOOLING_XMLSEC_MULTIPLECRL],[1],[Define to 1 if XML-Security-C handles multiple CRLs.])],
 323         [AC_MSG_RESULT([no])])
 324
 325     AC_MSG_CHECKING([whether XML-Security-C exposes the signature algorithm URI])
 326     AC_COMPILE_IFELSE(
 327         [AC_LANG_PROGRAM([[#include <xsec/dsig/DSIGSignature.hpp>]],
 328             [[DSIGSignature* sig; sig->getAlgorithmURI();]])],
 329         [AC_MSG_RESULT([yes])AC_DEFINE([XMLTOOLING_XMLSEC_SIGALGORITHM],[1],[Define to 1 if XML-Security-C exposes the signature algorithm URI.])],
 330         [AC_MSG_RESULT([no])])
 331
 332     AC_MSG_CHECKING([whether XML-Security-C includes ECC support])
 333     AC_COMPILE_IFELSE(
 334         [AC_LANG_PROGRAM([[#include <xsec/dsig/DSIGKeyInfoValue.hpp>]],
 335             [[DSIGKeyInfoValue* info; info->getECNamedCurve();]])],
 336         [AC_MSG_RESULT([yes])AC_DEFINE([XMLTOOLING_XMLSEC_ECC],[1],[Define to 1 if XML-Security-C includes ECC support.])],
 337         [AC_MSG_RESULT([no])])
 338
 339     AC_MSG_CHECKING([whether XML-Security-C includes C14N 1.1 support])
 340     AC_COMPILE_IFELSE(
 341         [AC_LANG_PROGRAM([[#include <xsec/dsig/DSIGConstants.hpp>]],
 342             [[transformType t = TRANSFORM_C14N11;]])],
 343         [AC_MSG_RESULT([yes])AC_DEFINE([XMLTOOLING_XMLSEC_C14N11],[1],[Define to 1 if XML-Security-C includes C14N 1.1 support.])],
 344         [AC_MSG_RESULT([no])])
 345
 346     AC_MSG_CHECKING([whether XML-Security-C includes debug logging support])
 347     AC_COMPILE_IFELSE(
 348         [AC_LANG_PROGRAM([[#include <xsec/utils/XSECPlatformUtils.hpp>]],
 349             [[XSECPlatformUtils::SetReferenceLoggingSink(NULL)]])],
 350         [AC_MSG_RESULT([yes])AC_DEFINE([XMLTOOLING_XMLSEC_DEBUGLOGGING],[1],[Define to 1 if XML-Security-C includes debug logging support.])],
 351         [AC_MSG_RESULT([no])])
 352
 353     # restore master libs
 354     LIBS="$save_LIBS"
 355
 356     # libcurl settings
 357     AC_PATH_PROG(CURL_CONFIG,curl-config)
 358     AC_ARG_WITH(curl,
 359         AS_HELP_STRING([--with-curl=PATH], [where curl-config is installed]),
 360         [
 361         CURL_CONFIG="${with_curl}"
 362         if ! test -f "${CURL_CONFIG}" ; then
 363             CURL_CONFIG="${with_curl}/bin/curl-config"
 364         fi
 365         ])
 366     if test -f "${CURL_CONFIG}" ; then
 367         CPPFLAGS="`${CURL_CONFIG} --cflags` $CPPFLAGS"
 368         XMLSEC_LIBS="`${CURL_CONFIG} --libs` $XMLSEC_LIBS"
 369     else
 370         AC_MSG_ERROR([curl-config not found, may need to use --with-curl option])
 371     fi
 372
 373     # save and append master libs
 374     save_LIBS="$LIBS"
 375     LIBS="$XMLSEC_LIBS $LIBS"
 376
 377     AC_CHECK_HEADER([curl/curl.h],,AC_MSG_ERROR([unable to find libcurl header files]))
 378     AC_LINK_IFELSE(
 379         [AC_LANG_PROGRAM([[#include <curl/curl.h>]],
 380             [[curl_global_init(CURL_GLOBAL_ALL)]])],,
 381         [AC_MSG_ERROR([unable to link with libcurl])])
 382     AC_MSG_CHECKING([for CURLOPT_SSL_CTX_FUNCTION in curl.h])
 383     AC_EGREP_HEADER([CURLOPT_SSL_CTX_FUNCTION], [curl/curl.h],
 384         [AC_MSG_RESULT(yes)],
 385         [AC_MSG_ERROR([need libcurl that supports CURLOPT_SSL_CTX_FUNCTION])])
 386     AC_CHECK_TYPE([curl_off_t],[AC_DEFINE([HAVE_CURL_OFF_T],[1],[Define to 1 if you have the 'curl_off_t' type.])],,[[#include <curl/curl.h>]])
 387
 388     # restore master libs
 389     LIBS="$save_LIBS"
 390
 391     AC_SUBST(XMLSEC_LIBS)
 392 else
 393     AC_MSG_WARN([xmlsec disabled, building without signature/encryption support])
 394     AC_DEFINE([XMLTOOLING_NO_XMLSEC],[1],[Define to 1 if you wish to disable XML-Security-dependent features.])
 395 fi
 396 AM_CONDITIONAL(BUILD_XMLSEC,test x_$with_xmlsec != x_no)
 397
 398 # Does the STL in use help or screw us?
 399 AC_LINK_IFELSE(
 400     [AC_LANG_PROGRAM([[#include <string>]],[[std::basic_string<unsigned short> foo; foo=foo+(unsigned short)65]])],
 401     [AC_DEFINE([HAVE_GOOD_STL],[1],[Define to 1 if you have an STL implementation that supports useful string specialization.])],[])
 402 AC_LINK_IFELSE(
 403     [AC_LANG_PROGRAM([[#include <vector>]],[[std::iterator_traits<std::vector<int>::iterator>::value_type foo=0]])],
 404     [AC_DEFINE([HAVE_ITERATOR_TRAITS],[1],[Define to 1 if you have an STL implementation that supports std::iterator_traits.])],[])
 405
 406 # Check for unit test support
 407 CXXTEST="/usr/bin/cxxtestgen.pl"
 408 CXXTESTFLAGS=""
 409 AC_ARG_WITH(cxxtest,
 410     AS_HELP_STRING([--with-cxxtest=PATH], [where cxxtest is installed]),
 411     [if test x_$with_cxxtest != x_/usr; then
 412         CXXTEST="${with_cxxtest}/cxxtestgen.pl"
 413         CXXTESTFLAGS="-I${with_cxxtest}"
 414     fi])
 415 if ! test -f "${CXXTEST}"; then
 416     AC_MSG_WARN([cxxtestgen not found, won't build unit tests])
 417 fi
 418
 419 AC_SUBST(CXXTEST)
 420 AC_SUBST(CXXTESTFLAGS)
 421 AM_CONDITIONAL(BUILD_UNITTEST,test -f ${CXXTEST})
 422
 423 AX_CREATE_PKGCONFIG_INFO(,,[$XMLSEC_LIBS -lxmltooling],[OpenSAML XMLTooling-C library])
 424
 425 LIBTOOL="$LIBTOOL --silent"
 426
 427 # output packaging and makefiles
 428 AC_OUTPUT