configure.ac

   1 # Process this file with autoreconf
   2 AC_PREREQ([2.50])
   3 AC_INIT([xmltooling],[1.5.6],[https://issues.shibboleth.net/],[xmltooling])
   4 AC_CONFIG_SRCDIR(xmltooling)
   5 AC_CONFIG_AUX_DIR(build-aux)
   6 AC_CONFIG_MACRO_DIR(m4)
   7 AM_INIT_AUTOMAKE
   8 AC_DISABLE_STATIC
   9 AC_PROG_LIBTOOL
  10
  11 # Docygen features
  12 DX_HTML_FEATURE(ON)
  13 DX_CHM_FEATURE(OFF)
  14 DX_CHI_FEATURE(OFF)
  15 DX_MAN_FEATURE(OFF)
  16 DX_RTF_FEATURE(OFF)
  17 DX_XML_FEATURE(OFF)
  18 DX_PDF_FEATURE(OFF)
  19 DX_PS_FEATURE(OFF)
  20 DX_INIT_DOXYGEN(xmltooling, doxygen.cfg, doc/api)
  21
  22 AC_ARG_ENABLE(debug,
  23     AS_HELP_STRING([--enable-debug],[Have GCC compile with symbols (Default = no)]),
  24     enable_debug=$enableval, enable_debug=no)
  25
  26 if test "$enable_debug" = "yes" ; then
  27     GCC_CFLAGS="$CFLAGS -g -D_DEBUG"
  28     GCC_CXXFLAGS="$CXXFLAGS -g -D_DEBUG"
  29 else
  30     GCC_CFLAGS="$CFLAGS -O2 -DNDEBUG"
  31     GCC_CXXFLAGS="$CXXFLAGS -O2 -DNDEBUG"
  32 fi
  33
  34 AC_CONFIG_HEADERS([config.h xmltooling/config_pub.h])
  35 AC_CONFIG_FILES([xmltooling.spec])
  36 AC_CONFIG_FILES([Makefile xmltooling/Makefile xmltoolingtest/Makefile schemas/Makefile doc/Makefile])
  37
  38 AC_PROG_CC([gcc gcc3 cc])
  39 AC_PROG_CXX([g++ g++3 c++ CC])
  40 AC_CANONICAL_HOST
  41
  42 if test "$GCC" = "yes" ; then
  43 #    AC_HAVE_GCC_VERSION(4,0,0,0,
  44 #        [
  45 #        AC_DEFINE(GCC_HASCLASSVISIBILITY,1,
  46 #            [Define to enable class visibility control in gcc.])
  47 #        GCC_CFLAGS="$GCC_CFLAGS -fvisibility=hidden -fvisibility-inlines-hidden"
  48 #        GCC_CXXFLAGS="$GCC_CXXFLAGS -fvisibility=hidden -fvisibility-inlines-hidden"
  49 #        ])
  50     CFLAGS="-Wall $GCC_CFLAGS"
  51     CXXFLAGS="-Wall $GCC_CXXFLAGS"
  52 fi
  53
  54 # Fix for Sun Workshop compiler in debug mode, may be Sun case #6360993
  55 # Also enables POSIX semantics for some functions.
  56 case "${host_cpu}-${host_os}" in
  57     *solaris*)
  58         CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS"
  59         CXXFLAGS="$CXXFLAGS -D_POSIX_PTHREAD_SEMANTICS"
  60         if test "$CXX" = "CC" ; then
  61                 CXXFLAGS="$CXXFLAGS -Qoption ccfe -stabs=no%dfltlit+no%dflthlp"
  62         fi
  63     ;;
  64 esac
  65
  66 # Checks for typedefs, structures, and compiler characteristics.
  67 AC_C_CONST
  68 AC_TYPE_SIZE_T
  69
  70 # Checks for library functions.
  71 AC_CHECK_FUNCS([strchr strdup strstr timegm gmtime_r strcasecmp])
  72 AC_CHECK_HEADERS([dlfcn.h])
  73 AC_CHECK_FUNC(dlclose, , [ AC_CHECK_LIB(dl, dlopen) ])
  74
  75 # checks for pthreads
  76 ACX_PTHREAD([enable_threads="pthread"],[enable_threads="no"])
  77 if test $enable_threads != "pthread"; then
  78     AC_MSG_ERROR([unable to find pthreads, currently this is required])
  79 else
  80     AC_DEFINE([HAVE_PTHREAD],[1],[Define if you have POSIX threads libraries and header files.])
  81         AM_CONDITIONAL(BUILD_PTHREAD,test "$enable_threads" = "pthread")
  82     LIBS="$PTHREAD_LIBS $LIBS"
  83     CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
  84     CXXFLAGS="$PTHREAD_CFLAGS $CXXFLAGS"
  85 fi
  86
  87 AC_CHECK_FUNCS([pthread_rwlock_init])
  88
  89 AC_LANG([C++])
  90
  91 # C++ requirements
  92 AC_CXX_NAMESPACES
  93 AC_CXX_REQUIRE_STL
  94
  95 # Boost
  96 BOOST_REQUIRE
  97 BOOST_BIND
  98 BOOST_CONVERSION
  99 BOOST_LAMBDA
 100 BOOST_POINTER_CONTAINER
 101 BOOST_SMART_PTR
 102 BOOST_STRING_ALGO
 103 BOOST_TOKENIZER
 104 CPPFLAGS="$BOOST_CPPFLAGS $CPPFLAGS"
 105
 106 # are covariant methods allowed?
 107 AC_LINK_IFELSE(
 108     [AC_LANG_PROGRAM([[]],
 109         [[
 110         class base { public: virtual base *GetPtr( void ) { return this; } };
 111         class derived: virtual public base { public: virtual derived *GetPtr( void ) { return this; } };
 112         ]])],
 113     [AC_DEFINE([HAVE_COVARIANT_RETURNS],[1],[Define to 1 if C++ compiler supports covariant virtual methods.])])
 114
 115 # is nullptr supported?
 116 AC_COMPILE_IFELSE(
 117     [AC_LANG_PROGRAM([[]],[[const char* ptr = nullptr;]])],
 118     [AC_DEFINE([HAVE_NULLPTR],[1],[Define to 1 if C++ compiler supports nullptr keyword.])])
 119
 120 # log4shib settings (favor this version over the log4cpp code)
 121 AC_PATH_PROG(LOG4SHIB_CONFIG,log4shib-config)
 122 AC_ARG_WITH(log4shib,
 123     AS_HELP_STRING([--with-log4shib=PATH],[where log4shib-config is installed]),
 124     [
 125     LOG4SHIB_CONFIG="${with_log4shib}"
 126     if ! test -f "${LOG4SHIB_CONFIG}" ; then
 127         LOG4SHIB_CONFIG="${with_log4shib}/bin/log4shib-config"
 128     fi
 129     ])
 130 if test -f "${LOG4SHIB_CONFIG}" ; then
 131     LIBS="`${LOG4SHIB_CONFIG} --libs` $LIBS"
 132     CPPFLAGS="`${LOG4SHIB_CONFIG} --cflags` $CPPFLAGS"
 133     AC_CHECK_HEADER([log4shib/CategoryStream.hh],,AC_MSG_ERROR([unable to find log4shib header files]))
 134     AC_LINK_IFELSE(
 135         [AC_LANG_PROGRAM([[#include <log4shib/Category.hh>
 136 #include <log4shib/CategoryStream.hh>]],
 137             [[log4shib::Category::getInstance("foo").errorStream() << log4shib::eol]])],
 138         [AC_DEFINE([XMLTOOLING_LOG4SHIB],[1],[Define to 1 if log4shib library is used.])],
 139         [AC_MSG_ERROR([unable to link with log4shib])])
 140 else
 141     AC_MSG_WARN([log4shib-config not found, may need to use --with-log4shib option])
 142     AC_MSG_WARN([will look for original log4cpp library])
 143
 144     # log4cpp settings
 145     AC_PATH_PROG(LOG4CPP_CONFIG,log4cpp-config)
 146     AC_ARG_WITH(log4cpp,
 147         AS_HELP_STRING([--with-log4cpp=PATH],[where log4cpp-config is installed]),
 148         [
 149         LOG4CPP_CONFIG="${with_log4cpp}"
 150         if ! test -f "${LOG4CPP_CONFIG}" ; then
 151                 LOG4CPP_CONFIG="${with_log4cpp}/bin/log4cpp-config"
 152         fi
 153         ])
 154     if test -f "${LOG4CPP_CONFIG}"; then
 155         AC_MSG_WARN([will try to use log4cpp, note that most non-Internet2 supplied versions are not thread-safe])
 156         LIBS="`${LOG4CPP_CONFIG} --libs` $LIBS"
 157         CPPFLAGS="`${LOG4CPP_CONFIG} --cflags` $CPPFLAGS"
 158         AC_CHECK_HEADER([log4cpp/CategoryStream.hh],,AC_MSG_ERROR([unable to find log4cpp header files]))
 159         AC_LINK_IFELSE(
 160             [AC_LANG_PROGRAM([[#include <log4cpp/Category.hh>
 161 #include <log4cpp/CategoryStream.hh>]],
 162                 [[log4cpp::Category::getInstance("foo").errorStream() << log4cpp::eol]])],
 163             [AC_DEFINE([XMLTOOLING_LOG4CPP],[1],[Define to 1 if log4cpp library is used.])],
 164             [AC_MSG_ERROR([unable to link with log4cpp, need version 1.0 or later])])
 165         else
 166             AC_MSG_ERROR([log4cpp-config not found, may need to use --with-log4cpp option])
 167         fi
 168 fi
 169
 170 # Xerces settings
 171 AC_ARG_WITH(xerces,
 172     AS_HELP_STRING([--with-xerces=PATH],[where xerces-c is installed]),,
 173     [with_xerces=/usr])
 174 if test x_$with_xerces != x_/usr; then
 175     CPPFLAGS="-I${with_xerces}/include $CPPFLAGS"
 176     LIBS="-L${with_xerces}/lib -lxerces-c $LIBS"
 177 else
 178     LIBS="-lxerces-c $LIBS"
 179 fi
 180
 181 AC_CHECK_HEADER([xercesc/dom/DOM.hpp],,AC_MSG_ERROR([unable to find xerces header files]))
 182 AC_MSG_CHECKING([Xerces version])
 183 AC_PREPROC_IFELSE(
 184     [AC_LANG_PROGRAM([#include <xercesc/util/XercesVersion.hpp>],
 185 [#if  _XERCES_VERSION != 20600
 186 int i = 0;
 187 #else
 188 #error cannot use version 2.6.0
 189 #endif])],
 190     [AC_MSG_RESULT(OK)],
 191     [AC_MSG_FAILURE([Xerces-C v2.6.0 has bugs that inhibit use with signed XML, please use a newer version])])
 192 AC_LINK_IFELSE(
 193     [AC_LANG_PROGRAM([[#include <xercesc/util/PlatformUtils.hpp>]],
 194         [[xercesc::XMLPlatformUtils::Initialize()]])],
 195     ,[AC_MSG_ERROR([unable to link with Xerces])])
 196
 197 AC_MSG_CHECKING([whether Xerces is 64-bit clean])
 198 AC_COMPILE_IFELSE(
 199     [AC_LANG_PROGRAM([[#include <xercesc/framework/MemBufInputSource.hpp>]],
 200         [[using namespace XERCES_CPP_NAMESPACE; XMLFilePos testvar;]])],
 201     [AC_MSG_RESULT([yes])AC_DEFINE([XMLTOOLING_XERCESC_64BITSAFE],[1],[Define to 1 if Xerces has a 64-bit-safe API.])],
 202     [AC_MSG_RESULT([no])])
 203
 204 AC_MSG_CHECKING([whether Xerces BinInputStream requires getContentType])
 205 AC_COMPILE_IFELSE(
 206     [AC_LANG_PROGRAM([[#include <xercesc/util/BinMemInputStream.hpp>]],
 207         [[using namespace XERCES_CPP_NAMESPACE; XMLByte buf[1024]; BinMemInputStream in(buf,1024); in.getContentType();]])],
 208     [AC_MSG_RESULT([yes])AC_DEFINE([XMLTOOLING_XERCESC_INPUTSTREAM_HAS_CONTENTTYPE],[1],[Define to 1 if Xerces InputStream class requires getContentType.])],
 209     [AC_MSG_RESULT([no])])
 210
 211 AC_MSG_CHECKING([whether Xerces DOMLS API is compliant])
 212 AC_COMPILE_IFELSE(
 213     [AC_LANG_PROGRAM([[#include <xercesc/dom/DOM.hpp>]],
 214         [[using namespace XERCES_CPP_NAMESPACE;
 215         DOMImplementation *impl = DOMImplementationRegistry::getDOMImplementation(NULL);
 216         DOMLSSerializer *ls = ((DOMImplementationLS*)impl)->createLSSerializer();]])],
 217     [AC_MSG_RESULT([yes])AC_DEFINE([XMLTOOLING_XERCESC_COMPLIANT_DOMLS],[1],[Define to 1 if Xerces supports a compliant DOMLS API.])],
 218     [AC_MSG_RESULT([no])])
 219
 220 AC_MSG_CHECKING([whether Xerces has setIdAttribute(XMLCh*, bool)])
 221 AC_COMPILE_IFELSE(
 222     [AC_LANG_PROGRAM([[#include <xercesc/dom/DOM.hpp>]],
 223         [[using namespace XERCES_CPP_NAMESPACE; DOMElement * elt; elt->setIdAttribute(NULL, false);]])],
 224     [AC_MSG_RESULT([yes])AC_DEFINE([XMLTOOLING_XERCESC_BOOLSETIDATTRIBUTE],[1],[Define to 1 if Xerces DOM ID methods take extra parameter.])],
 225     [AC_MSG_RESULT([no])])
 226
 227 AC_MSG_CHECKING([whether Xerces XMLString::release(XMLByte**) exists])
 228 AC_COMPILE_IFELSE(
 229     [AC_LANG_PROGRAM([[#include <xercesc/util/XMLString.hpp>]],
 230     [[using namespace XERCES_CPP_NAMESPACE; XMLByte* buf=NULL; XMLString::release(&buf);]])],
 231     [AC_MSG_RESULT([yes])AC_DEFINE([XMLTOOLING_XERCESC_HAS_XMLBYTE_RELEASE],[1],[Define to 1 if Xerces XMLString includes XMLByte release.])],
 232     [AC_MSG_RESULT([no])])
 233
 234 # XML-Security settings
 235 AC_ARG_WITH(xmlsec,
 236     AS_HELP_STRING([--with-xmlsec=PATH], [where xmlsec is installed]),,
 237     [with_xmlsec=/usr])
 238
 239 if test x_$with_xmlsec != x_no; then
 240
 241     # OpenSSL settings (need to do this first in case it's in a different spot from xmlsec)
 242     AC_ARG_WITH(openssl,
 243         AS_HELP_STRING([--with-openssl=PATH], [where openssl is installed]),
 244         [if test x_$with_openssl != x_/usr; then
 245             SSLFLAGS="-I${with_openssl}/include"
 246             SSLLIBS="-L${with_openssl}/lib -lcrypto -lssl"
 247         else
 248             SSLLIBS="-lcrypto -lssl"
 249         fi])
 250
 251     if test "x$SSLLIBS" = "x" ; then
 252         AC_PATH_PROG(PKG_CONFIG, pkg-config)
 253         if test "x$PKG_CONFIG" != x && test "x$PKG_CONFIG" != "xno" ; then
 254             if pkg-config openssl ; then
 255                 SSLLIBS="`$PKG_CONFIG --libs openssl`"
 256                 SSLFLAGS="`$PKG_CONFIG --cflags openssl`"
 257             else
 258                 AC_MSG_WARN([OpenSSL not supported by pkg-config, try --with-openssl instead])
 259             fi
 260         fi
 261     fi
 262
 263     if test "x$SSLLIBS" = "x" ; then
 264         SSLLIBS="-lcrypto -lssl"
 265     fi
 266
 267     AC_MSG_CHECKING(for OpenSSL cflags)
 268     AC_MSG_RESULT($SSLFLAGS)
 269     CPPFLAGS="$CPPFLAGS $SSLFLAGS"
 270     AC_MSG_CHECKING(for OpenSSL libraries)
 271     AC_MSG_RESULT($SSLLIBS)
 272     XMLSEC_LIBS="$XMLSEC_LIBS $SSLLIBS"
 273
 274     # save and append master libs
 275     save_LIBS="$LIBS"
 276     LIBS="$XMLSEC_LIBS $LIBS"
 277
 278     AC_CHECK_HEADER([openssl/pem.h],,AC_MSG_ERROR([unable to find openssl header files]))
 279     AC_MSG_CHECKING(for ERR_load_CRYPTO_string)
 280     AC_TRY_LINK_FUNC([ERR_load_CRYPTO_strings],,AC_MSG_ERROR([unable to link with openssl libraries]))
 281     AC_MSG_RESULT(yes)
 282
 283     AC_CHECK_DECL(EVP_sha512,
 284         [AC_DEFINE([XMLTOOLING_OPENSSL_HAVE_SHA2],[1],[Define to 1 if OpenSSL supports the SHA-2 hash family.])],
 285                 ,[#include <openssl/evp.h>])
 286     AC_CHECK_DECL(EVP_PKEY_set1_EC_KEY,
 287         [AC_DEFINE([XMLTOOLING_OPENSSL_HAVE_EC],[1],[Define to 1 if OpenSSL has EC support.])],
 288         ,[#include <openssl/evp.h>])
 289
 290     # restore master libs
 291     LIBS="$save_LIBS"
 292
 293     if test x_$with_xmlsec != x_/usr; then
 294         CPPFLAGS="-I${with_xmlsec}/include $CPPFLAGS"
 295         XMLSEC_LIBS="-L${with_xmlsec}/lib -lxml-security-c $XMLSEC_LIBS"
 296     else
 297         XMLSEC_LIBS="-lxml-security-c $XMLSEC_LIBS"
 298     fi
 299
 300     # save and append master libs
 301     save_LIBS="$LIBS"
 302     LIBS="$XMLSEC_LIBS $LIBS"
 303
 304     AC_CHECK_HEADER([xsec/utils/XSECPlatformUtils.hpp],,AC_MSG_ERROR([unable to find XML-Security header files]))
 305     AC_MSG_CHECKING([XML-Security version])
 306     AC_PREPROC_IFELSE(
 307             [AC_LANG_PROGRAM([#include <xsec/utils/XSECPlatformUtils.hpp>],
 308         [#if XSEC_VERSION_MAJOR > 1 || (XSEC_VERSION_MAJOR == 1 && XSEC_VERSION_MEDIUM > 3)
 309 int i = 0;
 310 #else
 311 #error need version 1.4.0 or later
 312 #endif])],
 313         [AC_MSG_RESULT(OK)],
 314         [AC_MSG_FAILURE([XML-Security version 1.4.0 or greater is required.])])
 315
 316     AC_LINK_IFELSE(
 317         [AC_LANG_PROGRAM([[#include <xsec/utils/XSECPlatformUtils.hpp>]],
 318             [[XSECPlatformUtils::Initialise()]])],,
 319         [AC_MSG_ERROR([unable to link with XML-Security])])
 320     AC_CHECK_TYPE([xsecsize_t],[AC_DEFINE([HAVE_XSECSIZE_T],[1],[Define to 1 if you have the 'xsecsize_t' type.])])
 321
 322     AC_MSG_CHECKING([whether XML-Security-C has multiple CRL support])
 323     AC_COMPILE_IFELSE(
 324         [AC_LANG_PROGRAM([[#include <xsec/dsig/DSIGKeyInfoX509.hpp>]],
 325             [[DSIGKeyInfoX509* klist; klist->getX509CRLListSize();]])],
 326         [AC_MSG_RESULT([yes])AC_DEFINE([XMLTOOLING_XMLSEC_MULTIPLECRL],[1],[Define to 1 if XML-Security-C handles multiple CRLs.])],
 327         [AC_MSG_RESULT([no])])
 328
 329     AC_MSG_CHECKING([whether XML-Security-C exposes the signature algorithm URI])
 330     AC_COMPILE_IFELSE(
 331         [AC_LANG_PROGRAM([[#include <xsec/dsig/DSIGSignature.hpp>]],
 332             [[DSIGSignature* sig; sig->getAlgorithmURI();]])],
 333         [AC_MSG_RESULT([yes])AC_DEFINE([XMLTOOLING_XMLSEC_SIGALGORITHM],[1],[Define to 1 if XML-Security-C exposes the signature algorithm URI.])],
 334         [AC_MSG_RESULT([no])])
 335
 336     AC_MSG_CHECKING([whether XML-Security-C includes ECC support])
 337     AC_COMPILE_IFELSE(
 338         [AC_LANG_PROGRAM([[#include <xsec/dsig/DSIGKeyInfoValue.hpp>]],
 339             [[DSIGKeyInfoValue* info; info->getECNamedCurve();]])],
 340         [AC_MSG_RESULT([yes])AC_DEFINE([XMLTOOLING_XMLSEC_ECC],[1],[Define to 1 if XML-Security-C includes ECC support.])],
 341         [AC_MSG_RESULT([no])])
 342
 343     AC_MSG_CHECKING([whether XML-Security-C includes C14N 1.1 support])
 344     AC_COMPILE_IFELSE(
 345         [AC_LANG_PROGRAM([[#include <xsec/dsig/DSIGConstants.hpp>]],
 346             [[transformType t = TRANSFORM_C14N11;]])],
 347         [AC_MSG_RESULT([yes])AC_DEFINE([XMLTOOLING_XMLSEC_C14N11],[1],[Define to 1 if XML-Security-C includes C14N 1.1 support.])],
 348         [AC_MSG_RESULT([no])])
 349
 350     AC_MSG_CHECKING([whether XML-Security-C includes debug logging support])
 351     AC_COMPILE_IFELSE(
 352         [AC_LANG_PROGRAM([[#include <xsec/utils/XSECPlatformUtils.hpp>]],
 353             [[XSECPlatformUtils::SetReferenceLoggingSink(NULL)]])],
 354         [AC_MSG_RESULT([yes])AC_DEFINE([XMLTOOLING_XMLSEC_DEBUGLOGGING],[1],[Define to 1 if XML-Security-C includes debug logging support.])],
 355         [AC_MSG_RESULT([no])])
 356
 357     # restore master libs
 358     LIBS="$save_LIBS"
 359
 360     # libcurl settings
 361     AC_PATH_PROG(CURL_CONFIG,curl-config)
 362     AC_ARG_WITH(curl,
 363         AS_HELP_STRING([--with-curl=PATH], [where curl-config is installed]),
 364         [
 365         CURL_CONFIG="${with_curl}"
 366         if ! test -f "${CURL_CONFIG}" ; then
 367             CURL_CONFIG="${with_curl}/bin/curl-config"
 368         fi
 369         ])
 370     if test -f "${CURL_CONFIG}" ; then
 371         CPPFLAGS="`${CURL_CONFIG} --cflags` $CPPFLAGS"
 372         XMLSEC_LIBS="`${CURL_CONFIG} --libs` $XMLSEC_LIBS"
 373     else
 374         AC_MSG_ERROR([curl-config not found, may need to use --with-curl option])
 375     fi
 376
 377     # save and append master libs
 378     save_LIBS="$LIBS"
 379     LIBS="$XMLSEC_LIBS $LIBS"
 380
 381     AC_CHECK_HEADER([curl/curl.h],,AC_MSG_ERROR([unable to find libcurl header files]))
 382     AC_LINK_IFELSE(
 383         [AC_LANG_PROGRAM([[#include <curl/curl.h>]],
 384             [[curl_global_init(CURL_GLOBAL_ALL)]])],,
 385         [AC_MSG_ERROR([unable to link with libcurl])])
 386     AC_MSG_CHECKING([for CURLOPT_SSL_CTX_FUNCTION in curl.h])
 387     AC_EGREP_HEADER([CURLOPT_SSL_CTX_FUNCTION], [curl/curl.h],
 388         [AC_MSG_RESULT(yes)],
 389         [AC_MSG_ERROR([need libcurl that supports CURLOPT_SSL_CTX_FUNCTION])])
 390     AC_CHECK_TYPE([curl_off_t],[AC_DEFINE([HAVE_CURL_OFF_T],[1],[Define to 1 if you have the 'curl_off_t' type.])],,[[#include <curl/curl.h>]])
 391
 392     # restore master libs
 393     LIBS="$save_LIBS"
 394
 395     AC_SUBST(XMLSEC_LIBS)
 396 else
 397     AC_MSG_WARN([xmlsec disabled, building without signature/encryption support])
 398     AC_DEFINE([XMLTOOLING_NO_XMLSEC],[1],[Define to 1 if you wish to disable XML-Security-dependent features.])
 399 fi
 400 AM_CONDITIONAL(BUILD_XMLSEC,test x_$with_xmlsec != x_no)
 401
 402 # Does the STL in use help or screw us?
 403 AC_LINK_IFELSE(
 404     [AC_LANG_PROGRAM([[#include <string>]],[[std::basic_string<unsigned short> foo; foo=foo+(unsigned short)65]])],
 405     [AC_DEFINE([HAVE_GOOD_STL],[1],[Define to 1 if you have an STL implementation that supports useful string specialization.])],[])
 406 AC_LINK_IFELSE(
 407     [AC_LANG_PROGRAM([[#include <vector>]],[[std::iterator_traits<std::vector<int>::iterator>::value_type foo=0]])],
 408     [AC_DEFINE([HAVE_ITERATOR_TRAITS],[1],[Define to 1 if you have an STL implementation that supports std::iterator_traits.])],[])
 409
 410 # Check for unit test support
 411 CXXTEST="/usr/bin/cxxtestgen.pl"
 412 CXXTESTFLAGS=""
 413 AC_ARG_WITH(cxxtest,
 414     AS_HELP_STRING([--with-cxxtest=PATH], [where cxxtest is installed]),
 415     [if test x_$with_cxxtest != x_/usr; then
 416         CXXTEST="${with_cxxtest}/cxxtestgen.pl"
 417         CXXTESTFLAGS="-I${with_cxxtest}"
 418     fi])
 419 if ! test -f "${CXXTEST}"; then
 420     AC_MSG_WARN([cxxtestgen not found, won't build unit tests])
 421 fi
 422
 423 AC_SUBST(CXXTEST)
 424 AC_SUBST(CXXTESTFLAGS)
 425 AM_CONDITIONAL(BUILD_UNITTEST,test -f ${CXXTEST})
 426
 427 AX_CREATE_PKGCONFIG_INFO(,,[$XMLSEC_LIBS -lxmltooling],[OpenSAML XMLTooling-C library])
 428
 429 LIBTOOL="$LIBTOOL --silent"
 430
 431 # output packaging and makefiles
 432 AC_OUTPUT