configure.ac

   1 # Process this file with autoreconf
   2 AC_PREREQ([2.50])
   3 AC_INIT([xmltooling],[1.5],[https://issues.shibboleth.net/],[xmltooling])
   4 AC_CONFIG_SRCDIR(xmltooling)
   5 AC_CONFIG_AUX_DIR(build-aux)
   6 AC_CONFIG_MACRO_DIR(m4)
   7 AM_INIT_AUTOMAKE
   8 AC_DISABLE_STATIC
   9 AC_PROG_LIBTOOL
  10
  11 # Docygen features
  12 DX_HTML_FEATURE(ON)
  13 DX_CHM_FEATURE(OFF)
  14 DX_CHI_FEATURE(OFF)
  15 DX_MAN_FEATURE(OFF)
  16 DX_RTF_FEATURE(OFF)
  17 DX_XML_FEATURE(OFF)
  18 DX_PDF_FEATURE(OFF)
  19 DX_PS_FEATURE(OFF)
  20 DX_INIT_DOXYGEN(xmltooling, doxygen.cfg, doc/api)
  21
  22 AC_ARG_ENABLE(debug,
  23     AS_HELP_STRING([--enable-debug],[Have GCC compile with symbols (Default = no)]),
  24     enable_debug=$enableval, enable_debug=no)
  25
  26 if test "$enable_debug" = "yes" ; then
  27     GCC_CFLAGS="$CFLAGS -g -D_DEBUG"
  28     GCC_CXXFLAGS="$CXXFLAGS -g -D_DEBUG"
  29 else
  30     GCC_CFLAGS="$CFLAGS -O2 -DNDEBUG"
  31     GCC_CXXFLAGS="$CXXFLAGS -O2 -DNDEBUG"
  32 fi
  33
  34 AC_CONFIG_HEADERS([config.h xmltooling/config_pub.h])
  35 AC_CONFIG_FILES([xmltooling.spec])
  36 AC_CONFIG_FILES([Makefile xmltooling/Makefile xmltoolingtest/Makefile schemas/Makefile doc/Makefile])
  37
  38 AC_PROG_CC([gcc gcc3 cc])
  39 AC_PROG_CXX([g++ g++3 c++ CC])
  40 AC_CANONICAL_HOST
  41
  42 if test "$GCC" = "yes" ; then
  43 #    AC_HAVE_GCC_VERSION(4,0,0,0,
  44 #        [
  45 #        AC_DEFINE(GCC_HASCLASSVISIBILITY,1,
  46 #            [Define to enable class visibility control in gcc.])
  47 #        GCC_CFLAGS="$GCC_CFLAGS -fvisibility=hidden -fvisibility-inlines-hidden"
  48 #        GCC_CXXFLAGS="$GCC_CXXFLAGS -fvisibility=hidden -fvisibility-inlines-hidden"
  49 #        ])
  50     CFLAGS="-Wall $GCC_CFLAGS"
  51     CXXFLAGS="-Wall $GCC_CXXFLAGS"
  52 else
  53 # Fix for Sun Workshop compiler in debug mode, may be Sun case #6360993
  54         case "${host_cpu}-${host_os}" in
  55                 *solaris*)
  56                         if test "$CXX" = "CC" ; then
  57                                 CXXFLAGS="$CXXFLAGS -Qoption ccfe -stabs=no%dfltlit+no%dflthlp"
  58                         fi
  59                 ;;
  60         esac
  61 fi
  62
  63 # Checks for typedefs, structures, and compiler characteristics.
  64 AC_C_CONST
  65 AC_TYPE_SIZE_T
  66 AC_CHECK_SIZEOF([long])
  67
  68 # Checks for library functions.
  69 AC_CHECK_FUNCS([strchr strdup strstr timegm strcasecmp])
  70 AC_CHECK_HEADERS([dlfcn.h])
  71 AC_CHECK_FUNC(dlclose, , [ AC_CHECK_LIB(dl, dlopen) ])
  72
  73 # checks for pthreads
  74 ACX_PTHREAD([enable_threads="pthread"],[enable_threads="no"])
  75 if test $enable_threads != "pthread"; then
  76     AC_MSG_ERROR([unable to find pthreads, currently this is required])
  77 else
  78     AC_DEFINE([HAVE_PTHREAD],[1],[Define if you have POSIX threads libraries and header files.])
  79         AM_CONDITIONAL(BUILD_PTHREAD,test "$enable_threads" = "pthread")
  80     LIBS="$PTHREAD_LIBS $LIBS"
  81     CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
  82     CXXFLAGS="$PTHREAD_CFLAGS $CXXFLAGS"
  83 fi
  84
  85 AC_CHECK_FUNCS([pthread_rwlock_init])
  86
  87 AC_LANG([C++])
  88
  89 # C++ requirements
  90 AC_CXX_NAMESPACES
  91 AC_CXX_REQUIRE_STL
  92
  93 # Boost
  94 BOOST_REQUIRE
  95 BOOST_STRING_ALGO
  96 BOOST_LAMBDA
  97
  98 # are covariant methods allowed?
  99 AC_LINK_IFELSE(
 100     [AC_LANG_PROGRAM([[]],
 101         [[
 102         class base { public: virtual base *GetPtr( void ) { return this; } };
 103         class derived: virtual public base { public: virtual derived *GetPtr( void ) { return this; } };
 104         ]])],
 105     [AC_DEFINE([HAVE_COVARIANT_RETURNS],[1],[Define to 1 if C++ compiler supports covariant virtual methods.])])
 106
 107 # is nullptr supported?
 108 AC_COMPILE_IFELSE(
 109     [AC_LANG_PROGRAM([[]],[[const char* ptr = nullptr;]])],
 110     [AC_DEFINE([HAVE_NULLPTR],[1],[Define to 1 if C++ compiler supports nullptr keyword.])])
 111
 112 # log4shib settings (favor this version over the log4cpp code)
 113 AC_PATH_PROG(LOG4SHIB_CONFIG,log4shib-config)
 114 AC_ARG_WITH(log4shib,
 115     AS_HELP_STRING([--with-log4shib=PATH],[where log4shib-config is installed]),
 116     [
 117     LOG4SHIB_CONFIG="${with_log4shib}"
 118     if ! test -f "${LOG4SHIB_CONFIG}" ; then
 119         LOG4SHIB_CONFIG="${with_log4shib}/bin/log4shib-config"
 120     fi
 121     ])
 122 if test -f "${LOG4SHIB_CONFIG}" ; then
 123     LIBS="`${LOG4SHIB_CONFIG} --libs` $LIBS"
 124     CPPFLAGS="`${LOG4SHIB_CONFIG} --cflags` $CPPFLAGS"
 125     AC_CHECK_HEADER([log4shib/CategoryStream.hh],,AC_MSG_ERROR([unable to find log4shib header files]))
 126     AC_LINK_IFELSE(
 127         [AC_LANG_PROGRAM([[#include <log4shib/Category.hh>
 128 #include <log4shib/CategoryStream.hh>]],
 129             [[log4shib::Category::getInstance("foo").errorStream() << log4shib::eol]])],
 130         [AC_DEFINE([XMLTOOLING_LOG4SHIB],[1],[Define to 1 if log4shib library is used.])],
 131         [AC_MSG_ERROR([unable to link with log4shib])])
 132 else
 133     AC_MSG_WARN([log4shib-config not found, may need to use --with-log4shib option])
 134     AC_MSG_WARN([will look for original log4cpp library])
 135
 136     # log4cpp settings
 137     AC_PATH_PROG(LOG4CPP_CONFIG,log4cpp-config)
 138     AC_ARG_WITH(log4cpp,
 139         AS_HELP_STRING([--with-log4cpp=PATH],[where log4cpp-config is installed]),
 140         [
 141         LOG4CPP_CONFIG="${with_log4cpp}"
 142         if ! test -f "${LOG4CPP_CONFIG}" ; then
 143                 LOG4CPP_CONFIG="${with_log4cpp}/bin/log4cpp-config"
 144         fi
 145         ])
 146     if test -f "${LOG4CPP_CONFIG}"; then
 147         AC_MSG_WARN([will try to use log4cpp, note that most non-Internet2 supplied versions are not thread-safe])
 148         LIBS="`${LOG4CPP_CONFIG} --libs` $LIBS"
 149         CPPFLAGS="`${LOG4CPP_CONFIG} --cflags` $CPPFLAGS"
 150         AC_CHECK_HEADER([log4cpp/CategoryStream.hh],,AC_MSG_ERROR([unable to find log4cpp header files]))
 151         AC_LINK_IFELSE(
 152             [AC_LANG_PROGRAM([[#include <log4cpp/Category.hh>
 153 #include <log4cpp/CategoryStream.hh>]],
 154                 [[log4cpp::Category::getInstance("foo").errorStream() << log4cpp::eol]])],
 155             [AC_DEFINE([XMLTOOLING_LOG4CPP],[1],[Define to 1 if log4cpp library is used.])],
 156             [AC_MSG_ERROR([unable to link with log4cpp, need version 1.0 or later])])
 157         else
 158             AC_MSG_ERROR([log4cpp-config not found, may need to use --with-log4cpp option])
 159         fi
 160 fi
 161
 162 # Xerces settings
 163 AC_ARG_WITH(xerces,
 164     AS_HELP_STRING([--with-xerces=PATH],[where xerces-c is installed]),,
 165     [with_xerces=/usr])
 166 if test x_$with_xerces != x_/usr; then
 167     CPPFLAGS="-I${with_xerces}/include $CPPFLAGS"
 168     LIBS="-L${with_xerces}/lib -lxerces-c $LIBS"
 169 else
 170     LIBS="-lxerces-c $LIBS"
 171 fi
 172
 173 AC_CHECK_HEADER([xercesc/dom/DOM.hpp],,AC_MSG_ERROR([unable to find xerces header files]))
 174 AC_MSG_CHECKING([Xerces version])
 175 AC_PREPROC_IFELSE(
 176     [AC_LANG_PROGRAM([#include <xercesc/util/XercesVersion.hpp>],
 177 [#if  _XERCES_VERSION != 20600
 178 int i = 0;
 179 #else
 180 #error cannot use version 2.6.0
 181 #endif])],
 182     [AC_MSG_RESULT(OK)],
 183     [AC_MSG_FAILURE([Xerces-C v2.6.0 has bugs that inhibit use with signed XML, please use a newer version])])
 184 AC_LINK_IFELSE(
 185     [AC_LANG_PROGRAM([[#include <xercesc/util/PlatformUtils.hpp>]],
 186         [[xercesc::XMLPlatformUtils::Initialize()]])],
 187     ,[AC_MSG_ERROR([unable to link with Xerces])])
 188
 189 AC_MSG_CHECKING([whether Xerces is 64-bit clean])
 190 AC_COMPILE_IFELSE(
 191     [AC_LANG_PROGRAM([[#include <xercesc/framework/MemBufInputSource.hpp>]],
 192         [[using namespace XERCES_CPP_NAMESPACE; XMLFilePos testvar;]])],
 193     [AC_MSG_RESULT([yes])AC_DEFINE([XMLTOOLING_XERCESC_64BITSAFE],[1],[Define to 1 if Xerces has a 64-bit-safe API.])],
 194     [AC_MSG_RESULT([no])])
 195
 196 AC_MSG_CHECKING([whether Xerces BinInputStream requires getContentType])
 197 AC_COMPILE_IFELSE(
 198     [AC_LANG_PROGRAM([[#include <xercesc/util/BinMemInputStream.hpp>]],
 199         [[using namespace XERCES_CPP_NAMESPACE; XMLByte buf[1024]; BinMemInputStream in(buf,1024); in.getContentType();]])],
 200     [AC_MSG_RESULT([yes])AC_DEFINE([XMLTOOLING_XERCESC_INPUTSTREAM_HAS_CONTENTTYPE],[1],[Define to 1 if Xerces InputStream class requires getContentType.])],
 201     [AC_MSG_RESULT([no])])
 202
 203 AC_MSG_CHECKING([whether Xerces DOMLS API is compliant])
 204 AC_COMPILE_IFELSE(
 205     [AC_LANG_PROGRAM([[#include <xercesc/dom/DOM.hpp>]],
 206         [[using namespace XERCES_CPP_NAMESPACE;
 207         DOMImplementation *impl = DOMImplementationRegistry::getDOMImplementation(NULL);
 208         DOMLSSerializer *ls = ((DOMImplementationLS*)impl)->createLSSerializer();]])],
 209     [AC_MSG_RESULT([yes])AC_DEFINE([XMLTOOLING_XERCESC_COMPLIANT_DOMLS],[1],[Define to 1 if Xerces supports a compliant DOMLS API.])],
 210     [AC_MSG_RESULT([no])])
 211
 212 AC_MSG_CHECKING([whether Xerces has setIdAttribute(XMLCh*, bool)])
 213 AC_COMPILE_IFELSE(
 214     [AC_LANG_PROGRAM([[#include <xercesc/dom/DOM.hpp>]],
 215         [[using namespace XERCES_CPP_NAMESPACE; DOMElement * elt; elt->setIdAttribute(NULL, false);]])],
 216     [AC_MSG_RESULT([yes])AC_DEFINE([XMLTOOLING_XERCESC_BOOLSETIDATTRIBUTE],[1],[Define to 1 if Xerces DOM ID methods take extra parameter.])],
 217     [AC_MSG_RESULT([no])])
 218
 219 AC_MSG_CHECKING([whether Xerces XMLString::release(XMLByte**) exists])
 220 AC_COMPILE_IFELSE(
 221     [AC_LANG_PROGRAM([[#include <xercesc/util/XMLString.hpp>]],
 222     [[using namespace XERCES_CPP_NAMESPACE; XMLByte* buf=NULL; XMLString::release(&buf);]])],
 223     [AC_MSG_RESULT([yes])AC_DEFINE([XMLTOOLING_XERCESC_HAS_XMLBYTE_RELEASE],[1],[Define to 1 if Xerces XMLString includes XMLByte release.])],
 224     [AC_MSG_RESULT([no])])
 225
 226 # XML-Security settings
 227 AC_ARG_WITH(xmlsec,
 228     AS_HELP_STRING([--with-xmlsec=PATH], [where xmlsec is installed]),,
 229     [with_xmlsec=/usr])
 230
 231 if test x_$with_xmlsec != x_no; then
 232
 233     # OpenSSL settings (need to do this first in case it's in a different spot from xmlsec)
 234     AC_ARG_WITH(openssl,
 235         AS_HELP_STRING([--with-openssl=PATH], [where openssl is installed]),
 236         [if test x_$with_openssl != x_/usr; then
 237             SSLFLAGS="-I${with_openssl}/include"
 238             SSLLIBS="-L${with_openssl}/lib -lcrypto -lssl"
 239         else
 240             SSLLIBS="-lcrypto -lssl"
 241         fi])
 242
 243     if test "x$SSLLIBS" = "x" ; then
 244         AC_PATH_PROG(PKG_CONFIG, pkg-config)
 245         if test "x$PKG_CONFIG" != x && test "x$PKG_CONFIG" != "xno" ; then
 246             if pkg-config openssl ; then
 247                 SSLLIBS="`$PKG_CONFIG --libs openssl`"
 248                 SSLFLAGS="`$PKG_CONFIG --cflags openssl`"
 249             else
 250                 AC_MSG_WARN([OpenSSL not supported by pkg-config, try --with-openssl instead])
 251             fi
 252         fi
 253     fi
 254
 255     if test "x$SSLLIBS" = "x" ; then
 256         SSLLIBS="-lcrypto -lssl"
 257     fi
 258
 259     AC_MSG_CHECKING(for OpenSSL cflags)
 260     AC_MSG_RESULT($SSLFLAGS)
 261     CPPFLAGS="$CPPFLAGS $SSLFLAGS"
 262     AC_MSG_CHECKING(for OpenSSL libraries)
 263     AC_MSG_RESULT($SSLLIBS)
 264     XMLSEC_LIBS="$XMLSEC_LIBS $SSLLIBS"
 265
 266     # save and append master libs
 267     save_LIBS="$LIBS"
 268     LIBS="$XMLSEC_LIBS $LIBS"
 269
 270     AC_CHECK_HEADER([openssl/pem.h],,AC_MSG_ERROR([unable to find openssl header files]))
 271     AC_MSG_CHECKING(for ERR_load_CRYPTO_string)
 272     AC_TRY_LINK_FUNC([ERR_load_CRYPTO_strings],,AC_MSG_ERROR([unable to link with openssl libraries]))
 273     AC_MSG_RESULT(yes)
 274
 275     AC_CHECK_DECL(EVP_sha512,
 276         [AC_DEFINE([XMLTOOLING_OPENSSL_HAVE_SHA2],[1],[Define to 1 if OpenSSL supports the SHA-2 hash family.])],
 277                 ,[#include <openssl/evp.h>])
 278     AC_CHECK_DECL(EVP_PKEY_set1_EC_KEY,
 279         [AC_DEFINE([XMLTOOLING_OPENSSL_HAVE_EC],[1],[Define to 1 if OpenSSL has EC support.])],
 280         ,[#include <openssl/evp.h>])
 281
 282     # restore master libs
 283     LIBS="$save_LIBS"
 284
 285     if test x_$with_xmlsec != x_/usr; then
 286         CPPFLAGS="-I${with_xmlsec}/include $CPPFLAGS"
 287         XMLSEC_LIBS="-L${with_xmlsec}/lib -lxml-security-c $XMLSEC_LIBS"
 288     else
 289         XMLSEC_LIBS="-lxml-security-c $XMLSEC_LIBS"
 290     fi
 291
 292     # save and append master libs
 293     save_LIBS="$LIBS"
 294     LIBS="$XMLSEC_LIBS $LIBS"
 295
 296     AC_CHECK_HEADER([xsec/utils/XSECPlatformUtils.hpp],,AC_MSG_ERROR([unable to find XML-Security header files]))
 297     AC_MSG_CHECKING([XML-Security version])
 298     AC_PREPROC_IFELSE(
 299             [AC_LANG_PROGRAM([#include <xsec/utils/XSECPlatformUtils.hpp>],
 300         [#if XSEC_VERSION_MAJOR > 1 || (XSEC_VERSION_MAJOR == 1 && XSEC_VERSION_MEDIUM > 3)
 301 int i = 0;
 302 #else
 303 #error need version 1.4.0 or later
 304 #endif])],
 305         [AC_MSG_RESULT(OK)],
 306         [AC_MSG_FAILURE([XML-Security version 1.4.0 or greater is required.])])
 307
 308     AC_LINK_IFELSE(
 309         [AC_LANG_PROGRAM([[#include <xsec/utils/XSECPlatformUtils.hpp>]],
 310             [[XSECPlatformUtils::Initialise()]])],,
 311         [AC_MSG_ERROR([unable to link with XML-Security])])
 312     AC_CHECK_TYPE([xsecsize_t],[AC_DEFINE([HAVE_XSECSIZE_T],[1],[Define to 1 if you have the 'xsecsize_t' type.])])
 313
 314     AC_MSG_CHECKING([whether XML-Security-C has multiple CRL support])
 315     AC_COMPILE_IFELSE(
 316         [AC_LANG_PROGRAM([[#include <xsec/dsig/DSIGKeyInfoX509.hpp>]],
 317             [[DSIGKeyInfoX509* klist; klist->getX509CRLListSize();]])],
 318         [AC_MSG_RESULT([yes])AC_DEFINE([XMLTOOLING_XMLSEC_MULTIPLECRL],[1],[Define to 1 if XML-Security-C handles multiple CRLs.])],
 319         [AC_MSG_RESULT([no])])
 320
 321     AC_MSG_CHECKING([whether XML-Security-C exposes the signature algorithm URI])
 322     AC_COMPILE_IFELSE(
 323         [AC_LANG_PROGRAM([[#include <xsec/dsig/DSIGSignature.hpp>]],
 324             [[DSIGSignature* sig; sig->getAlgorithmURI();]])],
 325         [AC_MSG_RESULT([yes])AC_DEFINE([XMLTOOLING_XMLSEC_SIGALGORITHM],[1],[Define to 1 if XML-Security-C exposes the signature algorithm URI.])],
 326         [AC_MSG_RESULT([no])])
 327
 328     AC_MSG_CHECKING([whether XML-Security-C includes ECC support])
 329     AC_COMPILE_IFELSE(
 330         [AC_LANG_PROGRAM([[#include <xsec/dsig/DSIGKeyInfoValue.hpp>]],
 331             [[DSIGKeyInfoValue* info; info->getECNamedCurve();]])],
 332         [AC_MSG_RESULT([yes])AC_DEFINE([XMLTOOLING_XMLSEC_ECC],[1],[Define to 1 if XML-Security-C includes ECC support.])],
 333         [AC_MSG_RESULT([no])])
 334
 335     AC_MSG_CHECKING([whether XML-Security-C includes C14N 1.1 support])
 336     AC_COMPILE_IFELSE(
 337         [AC_LANG_PROGRAM([[#include <xsec/dsig/DSIGConstants.hpp>]],
 338             [[transformType t = TRANSFORM_C14N11;]])],
 339         [AC_MSG_RESULT([yes])AC_DEFINE([XMLTOOLING_XMLSEC_C14N11],[1],[Define to 1 if XML-Security-C includes C14N 1.1 support.])],
 340         [AC_MSG_RESULT([no])])
 341
 342     AC_MSG_CHECKING([whether XML-Security-C includes debug logging support])
 343     AC_COMPILE_IFELSE(
 344         [AC_LANG_PROGRAM([[#include <xsec/utils/XSECPlatformUtils.hpp>]],
 345             [[XSECPlatformUtils::SetReferenceLoggingSink(NULL)]])],
 346         [AC_MSG_RESULT([yes])AC_DEFINE([XMLTOOLING_XMLSEC_DEBUGLOGGING],[1],[Define to 1 if XML-Security-C includes debug logging support.])],
 347         [AC_MSG_RESULT([no])])
 348
 349     # restore master libs
 350     LIBS="$save_LIBS"
 351
 352     # libcurl settings
 353     AC_PATH_PROG(CURL_CONFIG,curl-config)
 354     AC_ARG_WITH(curl,
 355         AS_HELP_STRING([--with-curl=PATH], [where curl-config is installed]),
 356         [
 357         CURL_CONFIG="${with_curl}"
 358         if ! test -f "${CURL_CONFIG}" ; then
 359             CURL_CONFIG="${with_curl}/bin/curl-config"
 360         fi
 361         ])
 362     if test -f "${CURL_CONFIG}" ; then
 363         CPPFLAGS="`${CURL_CONFIG} --cflags` $CPPFLAGS"
 364         XMLSEC_LIBS="`${CURL_CONFIG} --libs` $XMLSEC_LIBS"
 365     else
 366         AC_MSG_ERROR([curl-config not found, may need to use --with-curl option])
 367     fi
 368
 369     # save and append master libs
 370     save_LIBS="$LIBS"
 371     LIBS="$XMLSEC_LIBS $LIBS"
 372
 373     AC_CHECK_HEADER([curl/curl.h],,AC_MSG_ERROR([unable to find libcurl header files]))
 374     AC_LINK_IFELSE(
 375         [AC_LANG_PROGRAM([[#include <curl/curl.h>]],
 376             [[curl_global_init(CURL_GLOBAL_ALL)]])],,
 377         [AC_MSG_ERROR([unable to link with libcurl])])
 378     AC_MSG_CHECKING([for CURLOPT_SSL_CTX_FUNCTION in curl.h])
 379     AC_EGREP_HEADER([CURLOPT_SSL_CTX_FUNCTION], [curl/curl.h],
 380         [AC_MSG_RESULT(yes)],
 381         [AC_MSG_ERROR([need libcurl that supports CURLOPT_SSL_CTX_FUNCTION])])
 382     AC_CHECK_TYPE([curl_off_t],[AC_DEFINE([HAVE_CURL_OFF_T],[1],[Define to 1 if you have the 'curl_off_t' type.])],,[[#include <curl/curl.h>]])
 383
 384     # restore master libs
 385     LIBS="$save_LIBS"
 386
 387     AC_SUBST(XMLSEC_LIBS)
 388 else
 389     AC_MSG_WARN([xmlsec disabled, building without signature/encryption support])
 390     AC_DEFINE([XMLTOOLING_NO_XMLSEC],[1],[Define to 1 if you wish to disable XML-Security-dependent features.])
 391 fi
 392 AM_CONDITIONAL(BUILD_XMLSEC,test x_$with_xmlsec != x_no)
 393
 394 # Does the STL in use help or screw us?
 395 AC_LINK_IFELSE(
 396     [AC_LANG_PROGRAM([[#include <string>]],[[std::basic_string<unsigned short> foo; foo=foo+(unsigned short)65]])],
 397     [AC_DEFINE([HAVE_GOOD_STL],[1],[Define to 1 if you have an STL implementation that supports useful string specialization.])],[])
 398 AC_LINK_IFELSE(
 399     [AC_LANG_PROGRAM([[#include <vector>]],[[std::iterator_traits<std::vector<int>::iterator>::value_type foo=0]])],
 400     [AC_DEFINE([HAVE_ITERATOR_TRAITS],[1],[Define to 1 if you have an STL implementation that supports std::iterator_traits.])],[])
 401
 402 # Check for unit test support
 403 CXXTEST="/usr/bin/cxxtestgen.pl"
 404 CXXTESTFLAGS=""
 405 AC_ARG_WITH(cxxtest,
 406     AS_HELP_STRING([--with-cxxtest=PATH], [where cxxtest is installed]),
 407     [if test x_$with_cxxtest != x_/usr; then
 408         CXXTEST="${with_cxxtest}/cxxtestgen.pl"
 409         CXXTESTFLAGS="-I${with_cxxtest}"
 410     fi])
 411 if ! test -f "${CXXTEST}"; then
 412     AC_MSG_WARN([cxxtestgen not found, won't build unit tests])
 413 fi
 414
 415 AC_SUBST(CXXTEST)
 416 AC_SUBST(CXXTESTFLAGS)
 417 AM_CONDITIONAL(BUILD_UNITTEST,test -f ${CXXTEST})
 418
 419 AX_CREATE_PKGCONFIG_INFO(,,[$XMLSEC_LIBS -lxmltooling],[OpenSAML XMLTooling-C library])
 420
 421 LIBTOOL="$LIBTOOL --silent"
 422
 423 # output packaging and makefiles
 424 AC_OUTPUT