configure.ac

   1 AC_PREREQ([2.50])
   2 AC_INIT([xmltooling], [1.2], [mace-opensaml-users@internet2.edu], [xmltooling])
   3 AM_CONFIG_HEADER(config.h)
   4 AM_CONFIG_HEADER(xmltooling/config_pub.h)
   5 AM_INIT_AUTOMAKE([xmltooling], [1.2])
   6
   7 sinclude(doxygen.m4)
   8 sinclude(acx_pthread.m4)
   9
  10 # Docygen features
  11 DX_HTML_FEATURE(ON)
  12 DX_CHM_FEATURE(OFF)
  13 DX_CHI_FEATURE(OFF)
  14 DX_MAN_FEATURE(OFF)
  15 DX_RTF_FEATURE(OFF)
  16 DX_XML_FEATURE(OFF)
  17 DX_PDF_FEATURE(OFF)
  18 DX_PS_FEATURE(OFF)
  19 DX_INIT_DOXYGEN(xmltooling, doxygen.cfg, doc/api)
  20
  21 AC_ARG_ENABLE(debug,
  22     AC_HELP_STRING(--enable-debug, [Have GCC compile with symbols (Default = no)]),
  23     enable_debug=$enableval, enable_debug=no)
  24
  25 if test "$enable_debug" = "yes" ; then
  26     GCC_CFLAGS="$CFLAGS -g -D_DEBUG"
  27     GCC_CXXFLAGS="$CXXFLAGS -g -D_DEBUG"
  28 else
  29     GCC_CFLAGS="$CFLAGS -O2 -DNDEBUG"
  30     GCC_CXXFLAGS="$CXXFLAGS -O2 -DNDEBUG"
  31 fi
  32
  33 AC_PROG_CC([gcc gcc3 cc])
  34 AC_PROG_CXX([g++ g++3 c++ CC])
  35 AC_CANONICAL_HOST
  36
  37 if test "$GCC" = "yes" ; then
  38 #    AC_HAVE_GCC_VERSION(4,0,0,0,
  39 #        [
  40 #        AC_DEFINE(GCC_HASCLASSVISIBILITY,1,
  41 #            [Define to enable class visibility control in gcc.])
  42 #        GCC_CFLAGS="$GCC_CFLAGS -fvisibility=hidden -fvisibility-inlines-hidden"
  43 #        GCC_CXXFLAGS="$GCC_CXXFLAGS -fvisibility=hidden -fvisibility-inlines-hidden"
  44 #        ])
  45     CFLAGS="-Wall $GCC_CFLAGS"
  46     CXXFLAGS="-Wall $GCC_CXXFLAGS"
  47 else
  48 # Fix for Sun Workshop compiler in debug mode, may be Sun case #6360993
  49         case "${host_cpu}-${host_os}" in
  50                 *solaris*)
  51                         if test "$CXX" = "CC" ; then
  52                                 CXXFLAGS="$CXXFLAGS -Qoption ccfe -stabs=no%dfltlit+no%dflthlp"
  53                         fi
  54                 ;;
  55         esac
  56 fi
  57
  58 AC_DISABLE_STATIC
  59 AC_PROG_LIBTOOL
  60
  61 # Checks for typedefs, structures, and compiler characteristics.
  62 AC_C_CONST
  63 AC_TYPE_SIZE_T
  64 AC_CHECK_SIZEOF([long])
  65
  66 # Checks for library functions.
  67 AC_CHECK_FUNCS([strchr strdup strstr timegm strcasecmp])
  68 AC_CHECK_HEADERS([dlfcn.h])
  69 AC_CHECK_FUNC(dlclose, , [ AC_CHECK_LIB(dl, dlopen) ])
  70
  71 # checks for pthreads
  72 ACX_PTHREAD([enable_threads="pthread"],[enable_threads="no"])
  73 if test $enable_threads != "pthread"; then
  74     AC_MSG_ERROR([unable to find pthreads, currently this is required])
  75 else
  76     AC_DEFINE(HAVE_PTHREAD,1,[Define if you have POSIX threads libraries and header files.])
  77         AM_CONDITIONAL(BUILD_PTHREAD,test "$enable_threads" = "pthread")
  78     LIBS="$PTHREAD_LIBS $LIBS"
  79     CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
  80     CXXFLAGS="$PTHREAD_CFLAGS $CXXFLAGS"
  81 fi
  82
  83 AC_CHECK_FUNCS([pthread_rwlock_init])
  84
  85 AC_LANG(C++)
  86
  87 # C++ requirements
  88 AC_CXX_REQUIRE_STL
  89 AC_CXX_NAMESPACES
  90
  91 # are covariant methods allowed?
  92 AC_TRY_LINK(
  93      [ class base { public: virtual base *GetPtr( void ) { return this; } }; ],
  94      [ class derived: virtual public base { public: virtual derived *GetPtr( void ) { return this; } }; ],
  95      [AC_DEFINE(HAVE_COVARIANT_RETURNS,1,[Define if C++ compiler supports covariant virtual methods.])])
  96
  97 # log4shib settings (favor this version over the log4cpp code)
  98 AC_PATH_PROG(LOG4SHIB_CONFIG,log4shib-config)
  99 AC_ARG_WITH(log4shib,
 100     AC_HELP_STRING([--with-log4shib=PATH], [where log4shib-config is installed]),
 101     [
 102     LOG4SHIB_CONFIG="${with_log4shib}"
 103     if ! test -f "${LOG4SHIB_CONFIG}" ; then
 104         LOG4SHIB_CONFIG="${with_log4shib}/bin/log4shib-config"
 105     fi
 106     ])
 107 if test -f "${LOG4SHIB_CONFIG}"; then
 108     LDFLAGS="`${LOG4SHIB_CONFIG} --libs` $LDFLAGS"
 109     CPPFLAGS="`${LOG4SHIB_CONFIG} --cflags` $CPPFLAGS"
 110         AC_CHECK_HEADER([log4shib/CategoryStream.hh],,AC_MSG_ERROR([unable to find log4shib header files]))
 111         AC_TRY_LINK(
 112                 [#include <log4shib/Category.hh>
 113 #include <log4shib/CategoryStream.hh>],
 114                 [log4shib::Category::getInstance("foo").errorStream() << log4shib::eol],
 115                 [AC_DEFINE(XMLTOOLING_LOG4SHIB,1,[Define if log4shib library is used.])],
 116                 [AC_MSG_ERROR([unable to link with log4shib])])
 117 else
 118     AC_MSG_WARN([log4shib-config not found, may need to use --with-log4shib option])
 119     AC_MSG_WARN([will look for original log4cpp library])
 120
 121         # log4cpp settings
 122         AC_PATH_PROG(LOG4CPP_CONFIG,log4cpp-config)
 123         AC_ARG_WITH(log4cpp,
 124             AC_HELP_STRING([--with-log4cpp=PATH], [where log4cpp-config is installed]),
 125             [
 126             LOG4CPP_CONFIG="${with_log4cpp}"
 127             if ! test -f "${LOG4CPP_CONFIG}" ; then
 128                 LOG4CPP_CONFIG="${with_log4cpp}/bin/log4cpp-config"
 129             fi
 130             ])
 131         if test -f "${LOG4CPP_CONFIG}"; then
 132                 AC_MSG_WARN([will try to use log4cpp, note that most non-Internet2 supplied versions are not thread-safe])
 133             LDFLAGS="`${LOG4CPP_CONFIG} --libs` $LDFLAGS"
 134             CPPFLAGS="`${LOG4CPP_CONFIG} --cflags` $CPPFLAGS"
 135                 AC_CHECK_HEADER([log4cpp/CategoryStream.hh],,AC_MSG_ERROR([unable to find log4cpp header files]))
 136                 AC_TRY_LINK(
 137                         [#include <log4cpp/Category.hh>
 138 #include <log4cpp/CategoryStream.hh>],
 139                         [log4cpp::Category::getInstance("foo").errorStream() << log4cpp::eol],
 140                         [AC_DEFINE(XMLTOOLING_LOG4CPP,1,[Define if log4cpp library is used.])],
 141                         [AC_MSG_ERROR([unable to link with log4cpp, need version 1.0 or later])])
 142         else
 143             AC_MSG_ERROR([log4cpp-config not found, may need to use --with-log4cpp option])
 144         fi
 145 fi
 146
 147 # Xerces settings
 148 AC_ARG_WITH(xerces,
 149             AC_HELP_STRING([--with-xerces=PATH], [where xerces-c is installed]),
 150             [if test x_$with_xerces != x_/usr; then
 151                 LDFLAGS="-L${with_xerces}/lib $LDFLAGS"
 152                 CPPFLAGS="-I${with_xerces}/include $CPPFLAGS"
 153             fi])
 154 LIBS="-lxerces-c $LIBS"
 155 AC_CHECK_HEADER([xercesc/dom/DOM.hpp],,AC_MSG_ERROR([unable to find xerces header files]))
 156 AC_MSG_CHECKING([Xerces version])
 157 AC_PREPROC_IFELSE(
 158     [AC_LANG_PROGRAM([#include <xercesc/util/XercesVersion.hpp>],
 159 [#if  _XERCES_VERSION != 20600
 160 int i = 0;
 161 #else
 162 #error cannot use version 2.6.0
 163 #endif])],
 164     [AC_MSG_RESULT(OK)],
 165     [AC_MSG_FAILURE([Xerces-C v2.6.0 has bugs that inhibit use with signed XML, please use a newer version])])
 166 AC_TRY_LINK(
 167         [#include <xercesc/util/PlatformUtils.hpp>],
 168         [xercesc::XMLPlatformUtils::Initialize()],
 169         [AC_DEFINE(HAVE_LIBXERCESC,1,[Define if Xerces-C library was found])],
 170         [AC_MSG_ERROR([unable to link with Xerces])])
 171
 172 # DOM3 API checks.
 173 AC_CHECK_HEADERS([xercesc/dom/DOMLSParser.hpp xercesc/dom/DOMLSSerializer.hpp xercesc/dom/DOMLSResourceResolver.hpp])
 174
 175
 176 # XML-Security settings
 177 AC_ARG_WITH(xmlsec,
 178             AC_HELP_STRING([--with-xmlsec=PATH], [where xmlsec is installed]),,
 179             [with_xmlsec=/usr])
 180
 181 if test x_$with_xmlsec != x_no; then
 182
 183     # OpenSSL settings (need to do this first in case it's in a different spot from xmlsec)
 184     AC_ARG_WITH(openssl,
 185         AC_HELP_STRING([--with-openssl=PATH], [where openssl is installed]),
 186         [if test x_$with_openssl != x_/usr; then
 187             SSLFLAGS="-I${with_openssl}/include"
 188             SSLLIBS="-L${with_openssl}/lib -lcrypto -lssl"
 189         else
 190             SSLLIBS="-lcrypto -lssl"
 191         fi])
 192
 193     if test "x$SSLLIBS" = "x" ; then
 194         AC_PATH_PROG(PKG_CONFIG, pkg-config)
 195         if test "x$PKG_CONFIG" != x && test "x$PKG_CONFIG" != "xno" ; then
 196             if pkg-config openssl ; then
 197                 SSLLIBS="`$PKG_CONFIG --libs openssl`"
 198                 SSLFLAGS="`$PKG_CONFIG --cflags openssl`"
 199             else
 200                 AC_MSG_ERROR([OpenSSL not supported by pkg-config, try --with-openssl instead])
 201             fi
 202         fi
 203     fi
 204
 205     if test "x$SSLLIBS" = "x" ; then
 206         SSLLIBS="-lcrypto -lssl"
 207     fi
 208
 209     AC_MSG_CHECKING(for OpenSSL cflags)
 210     AC_MSG_RESULT($SSLFLAGS)
 211     CPPFLAGS="$CPPFLAGS $SSLFLAGS"
 212     AC_MSG_CHECKING(for OpenSSL libraries)
 213     AC_MSG_RESULT($SSLLIBS)
 214     XMLSEC_LIBS="$XMLSEC_LIBS $SSLLIBS"
 215
 216     # save and append master libs
 217     save_LIBS="$LIBS"
 218     LIBS="$XMLSEC_LIBS $LIBS"
 219
 220     AC_CHECK_HEADER([openssl/pem.h],,
 221                     AC_MSG_ERROR([unable to find openssl header files]))
 222     AC_MSG_CHECKING(for ERR_load_CRYPTO_string)
 223     AC_TRY_LINK_FUNC([ERR_load_CRYPTO_strings],,
 224                  AC_MSG_ERROR([unable to link with openssl libraries]))
 225     AC_MSG_RESULT(yes)
 226
 227     # restore master libs
 228     LIBS="$save_LIBS"
 229
 230     if test x_$with_xmlsec != x_/usr; then
 231         CPPFLAGS="-I${with_xmlsec}/include $CPPFLAGS"
 232         LDFLAGS="-L${with_xmlsec}/lib $LDFLAGS"
 233     fi
 234     XMLSEC_LIBS="$XMLSEC_LIBS -lxml-security-c"
 235
 236     # save and append master libs
 237     save_LIBS="$LIBS"
 238     LIBS="$XMLSEC_LIBS $LIBS"
 239
 240     AC_CHECK_HEADER([xsec/utils/XSECPlatformUtils.hpp],,AC_MSG_ERROR([unable to find XML-Security header files]))
 241     AC_MSG_CHECKING([XML-Security version])
 242     AC_PREPROC_IFELSE(
 243             [AC_LANG_PROGRAM([#include <xsec/utils/XSECPlatformUtils.hpp>],
 244         [#if XSEC_VERSION_MAJOR > 1 || (XSEC_VERSION_MAJOR == 1 && XSEC_VERSION_MEDIUM > 3)
 245 int i = 0;
 246 #else
 247 #error need version 1.4.0 or later
 248 #endif])],
 249         [AC_MSG_RESULT(OK)],
 250         [AC_MSG_FAILURE([XML-Security version 1.4.0 or greater is required.])])
 251     AC_TRY_LINK(
 252             [#include <xsec/utils/XSECPlatformUtils.hpp>],
 253             [XSECPlatformUtils::Initialise()],,
 254             [AC_MSG_ERROR([unable to link with XML-Security])])
 255
 256         # restore master libs
 257         LIBS="$save_LIBS"
 258
 259         # libcurl settings
 260         AC_PATH_PROG(CURL_CONFIG,curl-config)
 261         AC_ARG_WITH(curl,
 262             AC_HELP_STRING([--with-curl=PATH], [where curl-config is installed]),
 263             [
 264             CURL_CONFIG="${with_curl}"
 265             if ! test -f "${CURL_CONFIG}" ; then
 266                 CURL_CONFIG="${with_curl}/bin/curl-config"
 267             fi
 268             ])
 269         if test -f "${CURL_CONFIG}" ; then
 270             CPPFLAGS="`${CURL_CONFIG} --cflags` $CPPFLAGS"
 271             XMLSEC_LIBS="`${CURL_CONFIG} --libs` $XMLSEC_LIBS"
 272         else
 273             AC_MSG_ERROR([curl-config not found, may need to use --with-curl option])
 274         fi
 275
 276         # save and append master libs
 277         save_LIBS="$LIBS"
 278         LIBS="$XMLSEC_LIBS $LIBS"
 279
 280         AC_CHECK_HEADER([curl/curl.h],,AC_MSG_ERROR([unable to find libcurl header files]))
 281         AC_CHECK_LIB([curl],[curl_global_init],,AC_MSG_ERROR([unable to link with libcurl]))
 282         AC_MSG_CHECKING([for CURLOPT_SSL_CTX_FUNCTION in curl.h])
 283         AC_EGREP_HEADER([CURLOPT_SSL_CTX_FUNCTION], [curl/curl.h],
 284                         [AC_MSG_RESULT(yes)],
 285                         [AC_MSG_ERROR([need libcurl that supports CURLOPT_SSL_CTX_FUNCTION])])
 286
 287         # restore master libs
 288         LIBS="$save_LIBS"
 289
 290         AC_SUBST(XMLSEC_LIBS)
 291 else
 292     AC_MSG_WARN([xmlsec disabled, building without signature/encryption support])
 293     AC_DEFINE(XMLTOOLING_NO_XMLSEC,1,
 294         [Define if you wish to disable XML-Security-dependent features.])
 295 fi
 296 AM_CONDITIONAL(BUILD_XMLSEC,test x_$with_xmlsec != x_no)
 297
 298 # Does the STL in use help or screw us?
 299 AC_TRY_LINK(
 300         [#include <string>],
 301         [std::basic_string<unsigned short> foo; foo=foo+(unsigned short)65],
 302         [AC_DEFINE(HAVE_GOOD_STL,1,
 303             [Define if you have an STL implementation that supports useful string specialization.])],
 304         )
 305 AC_TRY_LINK(
 306         [#include <vector>],
 307         [std::iterator_traits<std::vector<int>::iterator>::value_type foo=0],
 308         [AC_DEFINE(HAVE_ITERATOR_TRAITS,1,
 309             [Define to 1 if you have an STL implementation that supports std::iterator_traits.])],
 310         )
 311
 312 # Check for unit test support
 313 CXXTEST="/usr/bin/cxxtestgen.pl"
 314 CXXTESTFLAGS=""
 315 AC_ARG_WITH(cxxtest,
 316             AC_HELP_STRING([--with-cxxtest=PATH], [where cxxtest is installed]),
 317             [if test x_$with_cxxtest != x_/usr; then
 318                 CXXTEST="${with_cxxtest}/cxxtestgen.pl"
 319                 CXXTESTFLAGS="-I${with_cxxtest}"
 320             fi])
 321 if ! test -f "${CXXTEST}"; then
 322     AC_MSG_WARN([cxxtestgen not found, won't build unit tests])
 323 fi
 324
 325 AC_SUBST(CXXTEST)
 326 AC_SUBST(CXXTESTFLAGS)
 327 AM_CONDITIONAL(BUILD_UNITTEST,test -f ${CXXTEST})
 328
 329 LIBTOOL="$LIBTOOL --silent"
 330
 331 # output makefiles
 332 AC_OUTPUT(Makefile xmltooling/Makefile xmltoolingtest/Makefile schemas/Makefile doc/Makefile)