configure.ac

   1 AC_PREREQ([2.50])
   2 AC_INIT([xmltooling], [1.0], [mace-opensaml-users@internet2.edu], [xmltooling])
   3 AM_CONFIG_HEADER(config.h)
   4 AM_CONFIG_HEADER(xmltooling/config_pub.h)
   5 AM_INIT_AUTOMAKE([xmltooling], [1.0])
   6
   7 sinclude(doxygen.m4)
   8 sinclude(acx_pthread.m4)
   9
  10 # Docygen features
  11 DX_HTML_FEATURE(ON)
  12 DX_CHM_FEATURE(OFF)
  13 DX_CHI_FEATURE(OFF)
  14 DX_MAN_FEATURE(OFF)
  15 DX_RTF_FEATURE(OFF)
  16 DX_XML_FEATURE(OFF)
  17 DX_PDF_FEATURE(OFF)
  18 DX_PS_FEATURE(OFF)
  19 DX_INIT_DOXYGEN(xmltooling, doxygen.cfg, doc/api)
  20
  21 AC_ARG_ENABLE(debug,
  22     AC_HELP_STRING(--enable-debug, [Have GCC compile with symbols (Default = no)]),
  23     enable_debug=$enableval, enable_debug=no)
  24
  25 if test "$enable_debug" = "yes" ; then
  26     GCC_CFLAGS="$CFLAGS -Wall -g -D_DEBUG"
  27     GCC_CXXFLAGS="$CXXFLAGS -Wall -g -D_DEBUG"
  28 else
  29     GCC_CFLAGS="$CFLAGS -Wall -O2 -DNDEBUG"
  30     GCC_CXXFLAGS="$CXXFLAGS -Wall -O2 -DNDEBUG"
  31 fi
  32
  33 AC_PROG_CC([gcc gcc3 cc])
  34 AC_PROG_CXX([g++ g++3 c++ CC])
  35 AC_CANONICAL_HOST
  36
  37 if test "$GCC" = "yes" ; then
  38 #    AC_HAVE_GCC_VERSION(4,0,0,0,
  39 #        [
  40 #        AC_DEFINE(GCC_HASCLASSVISIBILITY,1,
  41 #            [Define to enable class visibility control in gcc.])
  42 #        GCC_CFLAGS="$GCC_CFLAGS -fvisibility=hidden -fvisibility-inlines-hidden"
  43 #        GCC_CXXFLAGS="$GCC_CXXFLAGS -fvisibility=hidden -fvisibility-inlines-hidden"
  44 #        ])
  45     CFLAGS="$GCC_CFLAGS"
  46     CXXFLAGS="$GCC_CXXFLAGS"
  47 else
  48 # Fix for Sun Workshop compiler in debug mode, may be Sun case #6360993
  49         case "${host_cpu}-${host_os}" in
  50                 *solaris*)
  51                         if test "$CXX" = "CC" ; then
  52                                 CXXFLAGS="$CXXFLAGS -Qoption ccfe -stabs=no%dfltlit+no%dflthlp"
  53                         fi
  54                 ;;
  55         esac
  56 fi
  57
  58 AC_DISABLE_STATIC
  59 AC_PROG_LIBTOOL
  60
  61 # Checks for typedefs, structures, and compiler characteristics.
  62 AC_C_CONST
  63 AC_TYPE_SIZE_T
  64
  65 # Checks for library functions.
  66 AC_CHECK_FUNCS([strchr strdup strstr timegm strcasecmp])
  67 AC_CHECK_HEADERS([dlfcn.h])
  68 AC_CHECK_FUNC(dlclose, , [ AC_CHECK_LIB(dl, dlopen) ])
  69
  70 # checks for pthreads
  71 ACX_PTHREAD([enable_threads="pthread"],[enable_threads="no"])
  72 if test $enable_threads != "pthread"; then
  73     AC_MSG_ERROR([unable to find pthreads, currently this is required])
  74 else
  75     AC_DEFINE(HAVE_PTHREAD,1,[Define if you have POSIX threads libraries and header files.])
  76         AM_CONDITIONAL(BUILD_PTHREAD,test "$enable_threads" = "pthread")
  77     LIBS="$PTHREAD_LIBS $LIBS"
  78     CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
  79     CXXFLAGS="$PTHREAD_CFLAGS $CXXFLAGS"
  80 fi
  81
  82 AC_CHECK_FUNCS([pthread_rwlock_init])
  83
  84 # OpenSSL settings
  85 AC_ARG_WITH(openssl,
  86     AC_HELP_STRING([--with-openssl=PATH], [where openssl is installed]),
  87     [if test x_$with_openssl != x_/usr; then
  88         SSLLIBS="-L${with_openssl}/lib -lcrypto -lssl"
  89         SSLFLAGS="-I${with_openssl}/include"
  90     fi])
  91
  92 if test "x$SSLLIBS" = "x" ; then
  93     AC_PATH_PROG(PKG_CONFIG, pkg-config)
  94     if test "x$PKG_CONFIG" != x && test "x$PKG_CONFIG" != "xno" ; then
  95         if pkg-config openssl ; then
  96             SSLLIBS="`$PKG_CONFIG --libs openssl`"
  97             SSLFLAGS="`$PKG_CONFIG --cflags openssl`"
  98         else
  99             AC_MSG_ERROR([OpenSSL not supported by pkg-config, try --with-openssl instead])
 100         fi
 101     fi
 102 fi
 103
 104 if test "x$SSLLIBS" = "x" ; then
 105     SSLLIBS="-lcrypto -lssl"
 106 fi
 107
 108 AC_MSG_CHECKING(for OpenSSL libraries)
 109 AC_MSG_RESULT($SSLLIBS)
 110 LIBS="$LIBS $SSLLIBS"
 111 AC_MSG_CHECKING(for OpenSSL cflags)
 112 AC_MSG_RESULT($SSLFLAGS)
 113 CPPFLAGS="$SSLFLAGS $CPPFLAGS"
 114
 115 AC_CHECK_HEADER([openssl/pem.h],,
 116                 AC_MSG_ERROR([unable to find openssl header files]))
 117 AC_MSG_CHECKING(for ERR_load_CRYPTO_string)
 118 AC_TRY_LINK_FUNC([ERR_load_CRYPTO_strings],,
 119              AC_MSG_ERROR([unable to link with openssl libraries]))
 120 AC_MSG_RESULT(yes)
 121
 122 # libcurl settings
 123 AC_PATH_PROG(CURL_CONFIG,curl-config)
 124 AC_ARG_WITH(curl,
 125     AC_HELP_STRING([--with-curl=PATH], [where curl-config is installed]),
 126     [
 127     CURL_CONFIG="${with_curl}"
 128     if ! test -f "${CURL_CONFIG}" ; then
 129         CURL_CONFIG="${with_curl}/bin/curl-config"
 130     fi
 131     ])
 132 if test -f "${CURL_CONFIG}" ; then
 133     LDFLAGS="`${CURL_CONFIG} --libs` $LDFLAGS"
 134     CPPFLAGS="`${CURL_CONFIG} --cflags` $CPPFLAGS"
 135 else
 136     AC_MSG_ERROR([curl-config not found, may need to use --with-curl option])
 137 fi
 138 AC_CHECK_HEADER([curl/curl.h],,AC_MSG_ERROR([unable to find libcurl header files]))
 139 AC_CHECK_LIB([curl],[curl_global_init],,AC_MSG_ERROR([unable to link with libcurl]))
 140 AC_MSG_CHECKING([for CURLOPT_SSL_CTX_FUNCTION in curl.h])
 141 AC_EGREP_HEADER([CURLOPT_SSL_CTX_FUNCTION], [curl/curl.h],
 142                 [AC_MSG_RESULT(yes)],
 143                 [AC_MSG_ERROR([need libcurl that supports CURLOPT_SSL_CTX_FUNCTION])])
 144
 145
 146 AC_LANG(C++)
 147
 148 # C++ requirements
 149 AC_CXX_REQUIRE_STL
 150 AC_CXX_NAMESPACES
 151
 152 # are covariant methods allowed?
 153 AC_TRY_LINK(
 154      [ class base { public: virtual base *GetPtr( void ) { return this; } }; ],
 155      [ class derived: virtual public base { public: virtual derived *GetPtr( void ) { return this; } }; ],
 156      [AC_DEFINE(HAVE_COVARIANT_RETURNS,1,[Define if C++ compiler supports covariant virtual methods.])])
 157
 158 # log4cpp settings
 159 AC_PATH_PROG(LOG4CPP_CONFIG,log4cpp-config)
 160 AC_ARG_WITH(log4cpp,
 161     AC_HELP_STRING([--with-log4cpp=PATH], [where log4cpp-config is installed]),
 162     [
 163     LOG4CPP_CONFIG="${with_log4cpp}"
 164     if ! test -f "${LOG4CPP_CONFIG}" ; then
 165         LOG4CPP_CONFIG="${with_log4cpp}/bin/log4cpp-config"
 166     fi
 167     ])
 168 if test -f "${LOG4CPP_CONFIG}"; then
 169     LDFLAGS="`${LOG4CPP_CONFIG} --libs` $LDFLAGS"
 170     CPPFLAGS="`${LOG4CPP_CONFIG} --cflags` $CPPFLAGS"
 171 else
 172     AC_MSG_ERROR([log4cpp-config not found, may need to use --with-log4cpp option])
 173     LIBS="-llog4cpp $LIBS"
 174 fi
 175 AC_CHECK_HEADER([log4cpp/Category.hh],,AC_MSG_ERROR([unable to find log4cpp header files]))
 176 AC_CHECK_HEADER([log4cpp/PropertyConfigurator.hh],,AC_MSG_ERROR([you need at least log4cpp 0.3.x]))
 177 AC_TRY_LINK(
 178         [#include <log4cpp/Category.hh>],
 179         [log4cpp::Category::getInstance("foo")],
 180         [AC_DEFINE(HAVE_LIBLOG4CPP,1,[Define if log4cpp library was found])],
 181         [AC_MSG_ERROR([unable to link with log4cpp])])
 182
 183 # Xerces settings
 184 AC_ARG_WITH(xerces,
 185             AC_HELP_STRING([--with-xerces=PATH], [where xerces-c is installed]),
 186             [if test x_$with_xerces != x_/usr; then
 187                 LDFLAGS="-L${with_xerces}/lib $LDFLAGS"
 188                 CPPFLAGS="-I${with_xerces}/include $CPPFLAGS"
 189             fi])
 190 LIBS="-lxerces-c $LIBS"
 191 AC_CHECK_HEADER([xercesc/dom/DOM.hpp],,AC_MSG_ERROR([unable to find xerces header files]))
 192 AC_MSG_CHECKING([Xerces version])
 193 AC_PREPROC_IFELSE(
 194     [AC_LANG_PROGRAM([#include <xercesc/util/XercesVersion.hpp>],
 195 [#if  _XERCES_VERSION != 20600
 196 int i = 0;
 197 #else
 198 #error cannot use version 2.6.0
 199 #endif])],
 200     [AC_MSG_RESULT(OK)],
 201     [AC_MSG_FAILURE([Xerces-C v2.6.0 has bugs that inhibit use with signed XML, please use a newer version])])
 202 AC_TRY_LINK(
 203         [#include <xercesc/util/PlatformUtils.hpp>],
 204         [xercesc::XMLPlatformUtils::Initialize()],
 205         [AC_DEFINE(HAVE_LIBXERCESC,1,[Define if Xerces-C library was found])],
 206         [AC_MSG_ERROR([unable to link with Xerces])])
 207
 208
 209 # XML-Security settings
 210 AC_ARG_WITH(xmlsec,
 211             AC_HELP_STRING([--with-xmlsec=PATH], [where xmlsec is installed]),,
 212             [with_xmlsec=/usr])
 213
 214 if test x_$with_xmlsec != x_no; then
 215     if test x_$with_xmlsec != x_/usr; then
 216         LDFLAGS="-L${with_xmlsec}/lib $LDFLAGS"
 217         CPPFLAGS="-I${with_xmlsec}/include $CPPFLAGS"
 218     fi
 219     LIBS="-lxml-security-c $LIBS"
 220     AC_CHECK_HEADER([xsec/utils/XSECPlatformUtils.hpp],,AC_MSG_ERROR([unable to find XML-Security header files]))
 221     AC_MSG_CHECKING([XML-Security version])
 222     AC_PREPROC_IFELSE(
 223             [AC_LANG_PROGRAM([#include <xsec/utils/XSECPlatformUtils.hpp>],
 224         [#if XSEC_VERSION_MAJOR > 1 || (XSEC_VERSION_MAJOR == 1 && XSEC_VERSION_MEDIUM > 3) || (XSEC_VERSION_MAJOR == 1 && XSEC_VERSION_MEDIUM == 3 && XSEC_VERSION_MINOR > 0)
 225 int i = 0;
 226 #else
 227 #error need version 1.3.1 or later
 228 #endif])],
 229         [AC_MSG_RESULT(OK)],
 230         [AC_MSG_FAILURE([XML-Security version 1.3.1 or greater is required.])])
 231     AC_TRY_LINK(
 232             [#include <xsec/utils/XSECPlatformUtils.hpp>],
 233             [XSECPlatformUtils::Initialise()],,
 234             [AC_MSG_ERROR([unable to link with XML-Sec])])
 235 else
 236     AC_MSG_WARN([xmlsec disabled, building without signature/encryption support])
 237     AC_DEFINE(XMLTOOLING_NO_XMLSEC,1,
 238         [Define if you wish to disable XML-Security-dependent features.])
 239 fi
 240 AM_CONDITIONAL(BUILD_XMLSEC,test x_$with_xmlsec != x_no)
 241
 242 # Does the STL in use help or screw us?
 243 AC_TRY_LINK(
 244         [#include <string>],
 245         [std::basic_string<unsigned short> foo; foo=foo+(unsigned short)65],
 246         [AC_DEFINE(HAVE_GOOD_STL,1,
 247             [Define if you have an STL implementation that supports useful string specialization.])],
 248         )
 249
 250 # Check for unit test support
 251 CXXTEST="/usr/bin/cxxtestgen.pl"
 252 CXXTESTFLAGS=""
 253 AC_ARG_WITH(cxxtest,
 254             AC_HELP_STRING([--with-cxxtest=PATH], [where cxxtest is installed]),
 255             [if test x_$with_cxxtest != x_/usr; then
 256                 CXXTEST="${with_cxxtest}/cxxtestgen.pl"
 257                 CXXTESTFLAGS="-I${with_cxxtest}"
 258             fi])
 259 if ! test -f "${CXXTEST}"; then
 260     AC_MSG_WARN([cxxtestgen not found, won't build unit tests])
 261 fi
 262
 263 AC_SUBST(CXXTEST)
 264 AC_SUBST(CXXTESTFLAGS)
 265 AM_CONDITIONAL(BUILD_UNITTEST,test -f ${CXXTEST})
 266
 267 LIBTOOL="$LIBTOOL --silent"
 268
 269 # output makefiles
 270 AC_OUTPUT(Makefile xmltooling/Makefile xmltoolingtest/Makefile schemas/Makefile)