cmulocal/bsd_sockets.m4

   1 dnl bsd_sockets.m4--which socket libraries do we need?
   2 dnl Derrick Brashear
   3 dnl from Zephyr
   4 dnl $Id: bsd_sockets.m4,v 1.10 2005/04/26 19:14:07 shadow Exp $
   5
   6 dnl Hacked on by Rob Earhart to not just toss stuff in LIBS
   7 dnl It now puts everything required for sockets into LIB_SOCKET
   8
   9 AC_DEFUN([CMU_SOCKETS], [
  10         save_LIBS="$LIBS"
  11         LIB_SOCKET=""
  12         AC_CHECK_FUNC(connect, :,
  13                 AC_CHECK_LIB(nsl, gethostbyname,
  14                              LIB_SOCKET="-lnsl $LIB_SOCKET")
  15                 AC_CHECK_LIB(socket, connect,
  16                              LIB_SOCKET="-lsocket $LIB_SOCKET")
  17         )
  18         LIBS="$LIB_SOCKET $save_LIBS"
  19         AC_CHECK_FUNC(res_search, :,
  20                 LIBS="-lresolv $LIB_SOCKET $save_LIBS"
  21                 AC_TRY_LINK([[
  22 #include <sys/types.h>
  23 #include <netinet/in.h>
  24 #include <arpa/nameser.h>
  25 #ifdef HAVE_ARPA_NAMESER_COMPAT_H
  26 #include <arpa/nameser_compat.h>
  27 #endif
  28 #include <resolv.h>]],[[
  29 const char host[12]="openafs.org";
  30 u_char ans[1024];
  31 res_search( host, C_IN, T_MX, (u_char *)&ans, sizeof(ans));
  32 return 0;
  33 ]], LIB_SOCKET="-lresolv $LIB_SOCKET")
  34         )
  35         LIBS="$LIB_SOCKET $save_LIBS"
  36         AC_CHECK_FUNCS(dn_expand dns_lookup)
  37         LIBS="$save_LIBS"
  38         AC_SUBST(LIB_SOCKET)
  39         ])