cmulocal/libloguse.m4

   1 dnl libloguse.m4--LOGUSE libraries and includes
   2 dnl Derrick Brashear
   3 dnl from KTH krb and Arla
   4 dnl $Id: libloguse.m4,v 1.7 2006/02/25 18:26:22 cg2v Exp $
   5
   6 AC_DEFUN([CMU_LOGUSE_LIB_WHERE1], [
   7 saved_LIBS=$LIBS
   8 LIBS="$saved_LIBS -L$1 -lloguse"
   9 AC_TRY_LINK(,
  10 [loguse("","","");],
  11 [ac_cv_found_loguse_lib=yes],
  12 ac_cv_found_loguse_lib=no)
  13 LIBS=$saved_LIBS
  14 ])
  15
  16 AC_DEFUN([CMU_LOGUSE_LIB_WHERE], [
  17    for i in $1; do
  18       AC_MSG_CHECKING(for loguse library in $i)
  19       CMU_LOGUSE_LIB_WHERE1($i)
  20       CMU_TEST_LIBPATH($i, loguse)
  21       if test "$ac_cv_found_loguse_lib" = "yes" ; then
  22         ac_cv_loguse_where_lib=$i
  23         AC_MSG_RESULT(found)
  24         break
  25       else
  26         AC_MSG_RESULT(no found)
  27       fi
  28     done
  29 ])
  30
  31 AC_DEFUN([CMU_LOGUSE], [
  32 AC_REQUIRE([CMU_FIND_LIB_SUBDIR])
  33 AC_REQUIRE([CMU_SOCKETS])
  34 AC_ARG_WITH(loguse,
  35         [  --with-loguse=PREFIX      Compile with LOGUSE support],
  36         [if test "X$with_loguse" = "X"; then
  37                 with_loguse=yes
  38         fi])
  39
  40         if test "X$with_loguse" != "X"; then
  41           if test "$with_loguse" != "yes"; then
  42             ac_cv_loguse_where_lib=$with_loguse/$CMU_LIB_SUBDIR
  43           fi
  44         fi
  45
  46         if test "X$with_loguse_lib" != "X"; then
  47           ac_cv_loguse_where_lib=$with_loguse_lib
  48         fi
  49         if test "X$ac_cv_loguse_where_lib" = "X"; then
  50           CMU_LOGUSE_LIB_WHERE(/usr/$CMU_LIB_SUBDIR /usr/local/$CMU_LIB_SUBDIR)
  51         fi
  52
  53         AC_MSG_CHECKING(whether to include loguse)
  54         if test "X$ac_cv_loguse_where_lib" = "X"; then
  55           ac_cv_found_loguse=no
  56           AC_MSG_RESULT(no)
  57         else
  58           ac_cv_found_loguse=yes
  59           AC_DEFINE(HAVE_LOGUSE,, [Use libloguse])
  60           AC_MSG_RESULT(yes)
  61           LOGUSE_LIB_DIR=$ac_cv_loguse_where_lib
  62           LOGUSE_LIB_FLAGS="-L${LOGUSE_LIB_DIR} -lloguse"
  63           if test "X$RPATH" = "X"; then
  64                 RPATH=""
  65           fi
  66           case "${host}" in
  67             *-*-linux*)
  68               if test "X$RPATH" = "X"; then
  69                 RPATH="-Wl,-rpath,${LOGUSE_LIB_DIR}"
  70               else
  71                 RPATH="${RPATH}:${LOGUSE_LIB_DIR}"
  72               fi
  73               ;;
  74             *-*-hpux*)
  75               if test "X$RPATH" = "X"; then
  76                 RPATH="-Wl,+b${LOGUSE_LIB_DIR}"
  77               else
  78                 RPATH="${RPATH}:${LOGUSE_LIB_DIR}"
  79               fi
  80               ;;
  81             *-*-irix*)
  82               if test "X$RPATH" = "X"; then
  83                 RPATH="-Wl,-rpath,${LOGUSE_LIB_DIR}"
  84               else
  85                 RPATH="${RPATH}:${LOGUSE_LIB_DIR}"
  86               fi
  87               ;;
  88             *-*-solaris2*)
  89               if test "$ac_cv_prog_gcc" = yes; then
  90                 if test "X$RPATH" = "X"; then
  91                   RPATH="-Wl,-R${LOGUSE_LIB_DIR}"
  92                 else
  93                   RPATH="${RPATH}:${LOGUSE_LIB_DIR}"
  94                 fi
  95               else
  96                 RPATH="${RPATH} -R${LOGUSE_LIB_DIR}"
  97               fi
  98               ;;
  99           esac
 100           AC_SUBST(RPATH)
 101         fi
 102         ])
 103