configure.ac

   1 dnl #############################################################
   2 dnl #
   3 dnl #  For information about autoconf, see:
   4 dnl #
   5 dnl #  http://www.gnu.org/software/autoconf/
   6 dnl #
   7 dnl #  The recommended order is:
   8 dnl #
   9 dnl #  AC_INIT(file)
  10 dnl #  0. checks for compiler, libtool, and command line options
  11 dnl #  1. checks for programs
  12 dnl #  2. checks for libraries
  13 dnl #  3. checks for header files
  14 dnl #  4. checks for typedefs
  15 dnl #  5. checks for structures and functions
  16 dnl #  6. checks for compiler characteristics
  17 dnl #  7. checks for library functions
  18 dnl #  8. checks for system services
  19 dnl #  AC_OUTPUT([file...])
  20 dnl #
  21 dnl #############################################################
  22
  23 AC_PREREQ([2.59])
  24 export CFLAGS LIBS LDFLAGS CPPFLAGS
  25
  26 AC_INIT([freeradius],[$]Id[$],[http://bugs.freeradius.org],,[http://www.freeradius.org])
  27 AC_CONFIG_SRCDIR([src/main/radiusd.c])
  28 AC_CONFIG_HEADER([src/include/autoconf.h])
  29 m4_include([m4/ax_cc.m4])
  30
  31 dnl #############################################################
  32 dnl #
  33 dnl #  Custom hackery to discover version at configure time
  34 dnl #
  35 dnl #############################################################
  36
  37 RADIUSD_MAJOR_VERSION=`cat VERSION | sed 's/\..*//'`
  38 RADIUSD_MINOR_VERSION=`cat VERSION | sed 's/^[[^\.]]*\.//' | sed 's/\..*$//'`
  39 RADIUSD_INCRM_VERSION=`cat VERSION | sed 's/^.*\..*\.//' | sed 's/[[\.-]].*$//'`
  40
  41 RADIUSD_VERSION=`echo | awk -v major="$RADIUSD_MAJOR_VERSION" \
  42 -v minor="$RADIUSD_MINOR_VERSION" \
  43 -v incrm="$RADIUSD_INCRM_VERSION" \
  44 '{ printf "%02i%02i%02i", major, minor, incrm }'`
  45
  46 dnl #
  47 dnl #  Still useful for custom builds
  48 dnl #
  49 RADIUSD_VERSION_STRING=`cat VERSION`
  50
  51 dnl #
  52 dnl #  Add definitions to Make.inc as it's used by various build targets
  53 dnl #
  54 AC_SUBST([RADIUSD_VERSION_STRING])
  55
  56 dnl #
  57 dnl #  Add definitions to autoconf.h, so that the headers that we install
  58 dnl #  contain the version number of the server.
  59 dnl #
  60 AC_DEFINE_UNQUOTED([RADIUSD_VERSION], [${RADIUSD_VERSION}], [Version integer in format <ma><ma><mi><mi><in><in>])
  61 AC_DEFINE_UNQUOTED([RADIUSD_VERSION_STRING], ["${RADIUSD_VERSION_STRING}"], [Raw version string from VERSION file])
  62
  63 dnl #############################################################
  64 dnl #
  65 dnl #  Override some of the default autoconf variables such as
  66 dnl #  CFLAGS if were building in developer mode
  67 dnl #
  68 dnl #############################################################
  69
  70 dnl #
  71 dnl #  Enable developer features like debugging symbols.
  72 dnl #  These checks must be done before expanding the AC_PROG_CC
  73 dnl #  and AC_PROG_CXX macros.
  74 dnl #
  75 AC_ARG_ENABLE(developer,
  76 [  --enable-developer      enables features of interest to developers.],
  77 [ case "$enableval" in
  78   no)
  79     developer=no
  80     ;;
  81   *)
  82     developer=yes
  83   esac ]
  84 )
  85
  86 dnl #
  87 dnl #  Turn on the developer flag when taken from a git checkout (not a release)
  88 dnl #
  89 if test -d $srcdir/.git; then
  90   if test "x$developer" != "xno"; then
  91     AC_MSG_NOTICE([found .git directory, enabling developer build implicitly, disable with --disable-developer])
  92     developer="yes"
  93   fi
  94 fi
  95
  96 dnl #
  97 dnl #  Autoconf sets -O2 and -g by default, but this is a PITA for debugging
  98 dnl #  so we remove the defaults if were building in developer mode, and set
  99 dnl #  -g3 so nice things like macro values are included. Other arguments are
 100 dnl #  added later when we know what compiler were using.
 101 dnl #
 102 if test "x$developer" = "xyes"; then
 103   : ${CFLAGS=-g3}
 104 fi
 105
 106 dnl #############################################################
 107 dnl #
 108 dnl #  0. Checks for compiler, libtool, and command line options.
 109 dnl #
 110 dnl #############################################################
 111
 112 dnl #
 113 dnl #  Get system information
 114 dnl #
 115 AC_CANONICAL_SYSTEM
 116
 117 dnl #
 118 dnl #  Check for GNU cc
 119 dnl #
 120 AC_PROG_CC
 121 AC_PROG_CXX
 122
 123 dnl #
 124 dnl #  check for AIX, to allow us to use some BSD functions
 125 dnl #  must be before macros that call the compiler.
 126 dnl #
 127 AC_AIX
 128
 129 AC_PROG_GCC_TRADITIONAL
 130 AC_PROG_CC_SUNPRO
 131 AC_PROG_RANLIB
 132
 133 dnl #
 134 dnl #  Definitive check for whether the compiler is clang
 135 dnl #
 136 AX_CC_IS_CLANG
 137 if test "x$ax_cv_cc_clang" = "xyes"; then
 138   AC_SUBST(clang_path, "$CC")
 139 else
 140   AC_SUBST(clang_path, "")
 141 fi
 142
 143
 144 dnl #
 145 dnl #  Set Default CFLAGS for GCC compatible compilers
 146 dnl #
 147 if test "x$GCC" = "xyes"; then
 148   CFLAGS="$CFLAGS -Wall -std=c99 -D_GNU_SOURCE"
 149 fi
 150
 151 dnl #
 152 dnl #  -Qunused-arguments means the compiler won't complain about unsupported arguments
 153 dnl #
 154 AX_CC_QUNUSED_ARGUMENTS_FLAG
 155 if test "x$ax_cv_cc_qunused_arguments_flag" = "xyes"; then
 156   CFLAGS="$CFLAGS -Qunused-arguments"
 157   LDFLAGS="$LDFLAGS -Qunused-arguments"
 158 fi
 159
 160 dnl #
 161 dnl #  Compile in large (2G+) file support.
 162 dnl #
 163 AC_SYS_LARGEFILE
 164
 165 dnl #
 166 dnl #  check for system bytesex
 167 dnl #  AC_DEFINES WORDS_BIGENDIAN
 168 dnl #
 169 AC_C_BIGENDIAN(
 170   [AC_DEFINE(BIG_ENDIAN, 1, [Define if your processor stores words with the most significant byte first])],
 171   [AC_DEFINE(LITTLE_ENDIAN, 1, [Define if your processor stores words with the least significant byte first])]
 172 )
 173
 174 dnl #
 175 dnl #  Find GNU Make.
 176 dnl #
 177 AC_CHECK_PROG(GMAKE, gmake, yes, no)
 178 if test $GMAKE = no; then
 179   AC_PATH_PROG(MAKE, make, /usr/local/bin/make)
 180 else
 181   AC_PATH_PROG(MAKE, gmake, /usr/local/gnu/bin/make)
 182 fi
 183 makever=`$ac_cv_path_MAKE --version 2>&1 | grep "GNU Make"`
 184 if test -z "$makever"; then
 185   AC_MSG_ERROR([GNU Make is not installed.  Please download and install it from ftp://prep.ai.mit.edu/pub/gnu/make/ before continuing.])
 186 fi
 187
 188 dnl #
 189 dnl #  autoconf explicitly sets MAKEFLAGS and MFLAGS to '' even though we
 190 dnl #  didn't tell it to, so we have to use FR_MAKEFLAGS.
 191 dnl #
 192 dnl #  determine the number of cores available and set the number of build
 193 dnl #  processes appropriately.
 194 dnl #
 195 AX_SYSTEM_CORES
 196
 197 dnl #  Temporarily disabled because test and installation targets do not
 198 dnl #  have dependencies set up correctly for multiple build processes.
 199 dnl if test "x$ax_cv_system_cores" != "x"; then
 200 dnl  : ${FR_MAKEFLAGS=-j$ax_cv_system_cores}
 201 dnl fi
 202 AC_SUBST(FR_MAKEFLAGS)
 203
 204 dnl #
 205 dnl #  See if we have Git.
 206 dnl #
 207 AC_CHECK_PROG(GIT, git, yes, no)
 208
 209 dnl Put this in later, when all distributed modules use autoconf.
 210 dnl AC_ARG_WITH(disablemodulefoo,
 211 dnl [  --without-rlm_foo         Disables module compilation.  Module list:]
 212 dnl esyscmd([find src/modules -type d -name rlm_\* -print |\
 213 dnl   sed -e 's%src/modules/.*/% (sub)- %; s%.*/%- %' |\
 214 dnl   awk '{print "                            "$0}']))
 215
 216 AC_ARG_ENABLE(strict-dependencies,
 217 [  --enable-strict-dependencies  fail configure on lack of module dependancy.])
 218
 219 AC_ARG_ENABLE(werror,
 220 [  --enable-werror         causes the build to fail if any warnings are generated.],
 221 [ case "$enableval" in
 222     no)
 223       werror=no
 224     ;;
 225     *)
 226       werror=yes
 227   esac ]
 228 )
 229
 230 dnl #
 231 dnl #  extra argument: --with-docdir
 232 dnl #
 233 docdir='${datadir}/doc/freeradius'
 234 AC_MSG_CHECKING([docdir])
 235 AC_ARG_WITH(docdir,
 236 [  --with-docdir=DIR       directory for documentation [DATADIR/doc/freeradius] ],
 237 [ case "$withval" in
 238   no)
 239     docdir=no
 240     ;;
 241   yes)
 242     ;;
 243   [[\\/$]]* | ?:[[\\/]]* )
 244     docdir="$withval"
 245     ;;
 246   *)
 247     AC_MSG_ERROR([expected an absolute directory name for --with-docdir: $withval])
 248     ;;
 249   esac ]
 250 )
 251 AC_SUBST(docdir)
 252 AC_MSG_RESULT($docdir)
 253 if test "x$docdir" = xno; then
 254   AC_MSG_WARN([Documentation files will NOT be installed.])
 255 fi
 256
 257 dnl #
 258 dnl #  extra argument: --with-logdir
 259 dnl #
 260 logdir='${localstatedir}/log/radius'
 261 AC_MSG_CHECKING(logdir)
 262 AC_ARG_WITH(logdir,
 263 [  --with-logdir=DIR       directory for logfiles [LOCALSTATEDIR/log/radius] ],
 264 [ case "$withval" in
 265   no)
 266     AC_MSG_ERROR([Need logdir])
 267     ;;
 268   yes)
 269     ;;
 270   [[\\/$]]* | ?:[[\\/]]* )
 271     logdir="$withval"
 272     ;;
 273   *)
 274     AC_MSG_ERROR([expected an absolute directory name for --with-logdir: $withval])
 275     ;;
 276   esac ]
 277 )
 278 AC_SUBST(logdir)
 279 AC_MSG_RESULT($logdir)
 280
 281 dnl #
 282 dnl #  extra argument: --with-radacctdir
 283 dnl #
 284 radacctdir='${logdir}/radacct'
 285 AC_MSG_CHECKING(radacctdir)
 286 AC_ARG_WITH(radacctdir,
 287 [  --with-radacctdir=DIR   directory for detail files [LOGDIR/radacct] ],
 288 [ case "$withval" in
 289   no)
 290     AC_MSG_ERROR([Need radacctdir])
 291     ;;
 292   yes)
 293     ;;
 294   [[\\/$]]* | ?:[[\\/]]* )
 295     radacctdir="$withval"
 296     ;;
 297   *)
 298     AC_MSG_ERROR([expected an absolute directory name for --with-radacctdir: $withval])
 299     ;;
 300   esac ]
 301 )
 302 AC_SUBST(radacctdir)
 303 AC_MSG_RESULT($radacctdir)
 304
 305 dnl #
 306 dnl #  extra argument: --with-raddbdir
 307 dnl #
 308 raddbdir='${sysconfdir}/raddb'
 309 AC_MSG_CHECKING(raddbdir)
 310 AC_ARG_WITH(raddbdir,
 311 [  --with-raddbdir=DIR     directory for config files [SYSCONFDIR/raddb] ],
 312 [ case "$withval" in
 313   no)
 314     AC_MSG_ERROR([Need raddbdir])
 315     ;;
 316   yes)
 317     ;;
 318   [[\\/$]]* | ?:[[\\/]]* )
 319     raddbdir="$withval"
 320     ;;
 321   *)
 322     AC_MSG_ERROR([expected an absolute directory name for --with-raddbdir: $withval])
 323     ;;
 324   esac ]
 325 )
 326 AC_SUBST(raddbdir)
 327 AC_MSG_RESULT($raddbdir)
 328
 329 dnl #
 330 dnl #  extra argument: --with-dictdir
 331 dnl #
 332 dictdir='${datarootdir}/freeradius'
 333 AC_MSG_CHECKING(dictdir)
 334 AC_ARG_WITH(dictdir,
 335 [  --with-dictdir=DIR      directory for dictionary files [DATAROOTDIR/freeradius] ],
 336 [ case "$withval" in
 337   no)
 338     AC_MSG_ERROR([Need dictdir])
 339     ;;
 340   yes)
 341     ;;
 342   [[\\/$]]* | ?:[[\\/]]* )
 343     dictdir="$withval"
 344     ;;
 345   *)
 346     AC_MSG_ERROR([expected an absolute directory name for --with-dictdir: $withval])
 347     ;;
 348   esac ]
 349 )
 350 AC_SUBST(dictdir)
 351 AC_MSG_RESULT($dictdir)
 352
 353 modconfdir='${raddbdir}/mods-config'
 354 AC_SUBST(modconfdir)
 355
 356 dnl #
 357 dnl #  extra argument: --with-ascend-binary
 358 dnl #
 359 WITH_ASCEND_BINARY=yes
 360 AC_ARG_WITH(ascend-binary,
 361 [  --with-ascend-binary    include support for Ascend binary filter attributes (default=yes)],
 362 [ case "$withval" in
 363   yes)
 364     ;;
 365   *)
 366     WITH_ASCEND_BINARY=no
 367   esac ]
 368 )
 369 if test "x$WITH_ASCEND_BINARY" = "xyes"; then
 370   AC_DEFINE(WITH_ASCEND_BINARY, [1], [include support for Ascend binary filter attributes])
 371 fi
 372
 373 dnl #
 374 dnl #  extra argument: --with-threads
 375 dnl #
 376 WITH_THREADS=yes
 377 AC_ARG_WITH(threads,
 378 [  --with-threads          use threads, if available.  (default=yes) ],
 379 [ case "$withval" in
 380   yes)
 381     ;;
 382   *)
 383     WITH_THREADS=no
 384   esac ]
 385 )
 386
 387 dnl #
 388 dnl #  extra argument: --with-tcp
 389 dnl #
 390 WITH_TCP=yes
 391 AC_ARG_WITH(tcp,
 392 [  --with-tcp              compile in TCP support. (default=yes)],
 393 [ case "$withval" in
 394   yes)
 395     ;;
 396   *)
 397     WITH_TCP=no
 398   esac ]
 399 )
 400 if test "x$WITH_TCP" = "xyes"; then
 401   AC_DEFINE(WITH_TCP, [1], [define if you want TCP support (For RADSec et al)])
 402 fi
 403
 404 dnl #
 405 dnl #  extra argument: --with-vmps
 406 dnl #
 407 WITH_VMPS=yes
 408 AC_ARG_WITH(vmps,
 409 [  --with-vmps             compile in VMPS support. (default=yes)],
 410 [ case "$withval" in
 411   yes)
 412     ;;
 413   *)
 414     WITH_VMPS=no
 415   esac ]
 416 )
 417 if test "x$WITH_VMPS" = "xyes"; then
 418   AC_DEFINE(WITH_VMPS, [1], [define if you want VMPS support])
 419 fi
 420
 421 dnl #
 422 dnl #  extra argument: --with-dhcp
 423 dnl #
 424 WITH_DHCP=yes
 425 AC_ARG_WITH(dhcp,
 426 [  --with-dhcp             compile in DHCP support. (default=yes)],
 427 [ case "$withval" in
 428   yes)
 429     ;;
 430   *)
 431     WITH_DHCP=no
 432   esac ]
 433 )
 434 if test "x$WITH_DHCP" = "xyes"; then
 435   AC_DEFINE(WITH_DHCP, [1], [define if you want DHCP support])
 436 fi
 437
 438 dnl #
 439 dnl #  Allow the user to specify a list of modules to be linked
 440 dnl #  statically to the server.
 441 dnl #
 442 STATIC_MODULES=
 443 AC_ARG_WITH(static_modules,
 444 [  --with-static-modules=QUOTED-MODULE-LIST],[
 445   for i in $withval; do
 446     STATIC_MODULES="$STATIC_MODULES -dlpreopen ../modules/rlm_$i/rlm_$i.la"
 447   done
 448 ])
 449
 450 USE_SHARED_LIBS=yes
 451 AC_ARG_WITH(shared-libs,
 452 [AS_HELP_STRING([--with-shared-libs ],
 453 [build dynamic libraries and link against them. (default=yes)])],
 454 [ case "$withval" in
 455   no)
 456     USE_SHARED_LIBS=no
 457     ;;
 458   *)
 459   esac
 460 ])
 461
 462 MODULES=
 463 AC_ARG_WITH(modules,
 464 [  --with-modules=QUOTED-MODULE-LIST],[
 465  for i in $withval; do
 466    MODULES="$MODULES $i"
 467  done
 468 ])
 469
 470 dnl #
 471 dnl #  extra argument: --with-experimental-modules
 472 dnl #
 473 EXPERIMENTAL=
 474 AC_ARG_WITH(experimental-modules,
 475 [AS_HELP_STRING([--with-experimental-modules],
 476 [use experimental and unstable modules. (default=no, unless --enable-developer=yes)])],
 477 [ case "$withval" in
 478   yes)
 479     EXPERIMENTAL=yes
 480     ;;
 481   no)
 482     EXPERIMENTAL=no
 483     ;;
 484   *)
 485   esac ]
 486 )
 487
 488 dnl #
 489 dnl #  extra argument: --with-udpfromto
 490 dnl #
 491 WITH_UDPFROMTO=yes
 492 AC_ARG_WITH(udpfromto,
 493 [  --with-udpfromto        compile in UDPFROMTO support. (default=yes)],
 494 [ case "$withval" in
 495   yes)
 496     WITH_UDPFROMTO=yes
 497     ;;
 498   *)
 499     WITH_UDPFROMTO=no
 500   esac ]
 501 )
 502
 503 if test "x$WITH_UDPFROMTO" = "xyes"; then
 504   AC_DEFINE(WITH_UDPFROMTO, [], [define if you want udpfromto])
 505 fi
 506
 507 dnl #
 508 dnl #  These next two arguments don't actually do anything.  They're
 509 dnl #  place holders so that the top-level configure script can tell
 510 dnl #  the user how to configure lower-level modules
 511 dnl #
 512
 513 dnl #
 514 dnl #  extra argument: --with-rlm-FOO-lib-dir
 515 dnl #
 516 AC_ARG_WITH(rlm-FOO-lib-dir,
 517 [AS_HELP_STRING([--with-rlm-FOO-lib-dir=DIR],
 518 [directory in which to look for library files used by module FOO])],
 519 [ case "$withval" in
 520   *)
 521     ;;
 522   esac ]
 523 )
 524
 525 dnl #
 526 dnl #  extra argument: --with-rlm-FOO-include-dir
 527 dnl #
 528 AC_ARG_WITH(rlm-FOO-include-dir,
 529 [AS_HELP_STRING([--with-rlm-FOO-include-dir=DIR],
 530 [directory in which to look for include files used by module FOO])],
 531 [ case "$withval" in
 532   *)
 533     ;;
 534   esac ]
 535 )
 536
 537 dnl #
 538 dnl #  extra argument: --with-openssl
 539 dnl #
 540 WITH_OPENSSL=yes
 541 AC_ARG_WITH(openssl,
 542 [  --with-openssl          use OpenSSL. (default=yes)],
 543 [ case "$withval" in
 544   no)
 545     WITH_OPENSSL=no
 546     ;;
 547   *)
 548     WITH_OPENSSL=yes
 549     ;;
 550   esac ]
 551 )
 552
 553 dnl #
 554 dnl #  extra argument: --with-openssl-lib-dir=dir
 555 dnl #
 556 openssl_lib_dir=
 557 AC_ARG_WITH(openssl-lib-dir,
 558 [AS_HELP_STRING([--with-openssl-lib-dir=DIR],
 559 [directory to look for OpenSSL library files])],
 560 [ case "$withval" in
 561   *) openssl_lib_dir="$withval"
 562     ;;
 563   esac ]
 564 )
 565
 566 dnl #
 567 dnl #  extra argument: --with-openssl-includes=dir
 568 dnl #
 569 openssl_include_dir=
 570 AC_ARG_WITH(openssl-include-dir,
 571 [AS_HELP_STRING([--with-openssl-include-dir=DIR],
 572 [directory to look for OpenSSL include files])],
 573 [ case "$withval" in
 574   *) openssl_include_dir="$withval"
 575     ;;
 576   esac ]
 577 )
 578
 579 dnl #############################################################
 580 dnl #
 581 dnl #  1. Checks for programs
 582 dnl #
 583 dnl #############################################################
 584
 585 CHECKRAD=checkrad
 586 AC_PATH_PROG(PERL, perl, /usr/local/bin/perl)
 587 if test "x$ac_cv_path_PERL" = "x"; then
 588   AC_MSG_WARN([perl not found - Simultaneous-Use and checkrad may not work])
 589 fi
 590 AC_PATH_PROG(SNMPGET, snmpget)
 591 if test "x$ac_cv_path_SNMPGET" = "x"; then
 592   AC_MSG_WARN([snmpget not found - Simultaneous-Use and checkrad may not work])
 593 fi
 594
 595 AC_PATH_PROG(SNMPWALK, snmpwalk)
 596 if test "x$ac_cv_path_SNMPWALK" = "x"; then
 597   AC_MSG_WARN([snmpwalk not found - Simultaneous-Use and checkrad may not work])
 598 fi
 599
 600 AC_PATH_PROG(RUSERS, rusers, /usr/bin/rusers)
 601
 602 dnl #
 603 dnl #  FIXME This is truly gross.
 604 dnl #
 605 missing_dir=`cd $ac_aux_dir && pwd`
 606 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
 607 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
 608 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
 609
 610 AC_PATH_PROG(LOCATE,locate)
 611 AC_PATH_PROG(DIRNAME,dirname)
 612 AC_PATH_PROG(GREP,grep)
 613
 614 dnl #############################################################
 615 dnl #
 616 dnl #  2. Checks for libraries
 617 dnl #
 618 dnl #############################################################
 619
 620 dnl Check for talloc
 621 dnl extra argument: --with-talloc-lib-dir=DIR
 622 talloc_lib_dir=
 623 AC_ARG_WITH(talloc-lib-dir,
 624   [AS_HELP_STRING([--with-talloc-lib-dir=DIR],
 625   [directory in which to look for talloc library files])],
 626   [case "$withval" in
 627     no)
 628       AC_MSG_ERROR([Need talloc-lib-dir])
 629       ;;
 630     yes)
 631       ;;
 632     *)
 633       talloc_lib_dir="$withval"
 634       ;;
 635   esac])
 636
 637 dnl extra argument: --with-talloc-include-dir=DIR
 638 talloc_include_dir=
 639 AC_ARG_WITH(talloc-include-dir,
 640   [AS_HELP_STRING([--with-talloc-include-dir=DIR],
 641   [directory in which to look for talloc include files])],
 642   [case "$withval" in
 643     no)
 644       AC_MSG_ERROR([Need talloc-include-dir])
 645       ;;
 646     yes)
 647       ;;
 648     *)
 649       talloc_include_dir="$withval"
 650       ;;
 651   esac])
 652
 653 smart_try_dir="$talloc_lib_dir"
 654 FR_SMART_CHECK_LIB(talloc, _talloc)
 655 if test "x$ac_cv_lib_talloc__talloc" != "xyes"; then
 656   AC_MSG_WARN([talloc library not found. Use --with-talloc-lib-dir=<path>.])
 657   AC_MSG_ERROR([FreeRADIUS requires libtalloc])
 658 fi
 659
 660 TALLOC_LIBS="${smart_lib}"
 661 TALLOC_LDFLAGS="${smart_ldflags}"
 662 AC_SUBST(TALLOC_LIBS)
 663 AC_SUBST(TALLOC_LDFLAGS)
 664 LIBS="$old_LIBS"
 665
 666 dnl #
 667 dnl #  If using pthreads, check for -lpthread (posix) or -lc_r (*BSD)
 668 dnl #
 669 old_CFLAGS=$CFLAGS
 670 if test "x$WITH_THREADS" = "xyes"; then
 671   if test $ac_cv_prog_suncc = "yes"; then
 672     CFLAGS="$CFLAGS -mt"
 673   fi
 674
 675   AC_CHECK_HEADERS(pthread.h, [],
 676     [
 677       WITH_THREADS="no"
 678       fail=[pthread.h]
 679     ])
 680
 681   dnl #
 682   dnl #  pthread stuff is usually in -lpthread
 683   dnl #  or in -lc_r, on *BSD
 684   dnl #
 685   dnl #  On Some systems, we need extra pre-processor flags, to get them to
 686   dnl #  to do the threading properly.
 687   dnl #
 688   AC_CHECK_LIB(pthread, pthread_create,
 689     [
 690       CFLAGS="$CFLAGS -D_REENTRANT -D_POSIX_PTHREAD_SEMANTICS"
 691       LIBS="-lpthread $LIBS"
 692     ],
 693     [
 694       dnl #
 695       dnl # -pthread is not a typo, it's a GCC option which sets additional flags required
 696       dnl # for multithreading with the pthreads library.
 697       dnl #
 698       AC_CHECK_LIB(c_r, pthread_create,
 699         [ CFLAGS="$CFLAGS -pthread -D_THREAD_SAFE" ],
 700         [
 701           WITH_THREADS="no"
 702           fail=[-lpthread]
 703         ]
 704       )
 705     ]
 706   )
 707
 708   if test "x$WITH_THREADS" != "xyes"; then
 709     AC_MSG_WARN([silently not building with thread support.])
 710     AC_MSG_WARN([FAILURE: thread support requires: $fail.])
 711   else
 712     AC_DEFINE(WITH_THREADS, [1], [define if you want thread support])
 713   fi
 714 fi
 715
 716 dnl #
 717 dnl #  If we have NO pthread libraries, remove any knowledge of threads.
 718 dnl #
 719 if test "x$WITH_THREADS" != "xyes"; then
 720   CFLAGS=$old_CFLAGS
 721   ac_cv_header_pthread_h="no"
 722   WITH_THREADS=no
 723 else
 724   dnl #
 725   dnl #  We need sem_init() and friends, as they're the friendliest
 726   dnl #  semaphore functions for threading.
 727   dnl #
 728   dnl #  HP/UX requires linking with librt, too, to get the sem_* symbols.
 729   dnl #  Some systems have them in -lsem
 730   dnl #  Solaris has them in -lposix4
 731   dnl #  NetBSD has them in -lsemaphore
 732   dnl #
 733
 734   AC_SEARCH_LIBS(sem_init, pthread sem posix4 rt semaphore,
 735     [],
 736     [AC_MSG_ERROR([[-lsem not found.  You may want to download it from ftp://ftp.to.gd-es.com/pub/BSDI/libsem.tar.bz2 or ftp://ftp.freeradius.org/pub/radius/contrib/libsem.tar.gz]])]
 737   )
 738 fi
 739
 740 dnl #
 741 dnl #  Check if we need -lsocket
 742 dnl #
 743 AC_CHECK_LIB(dl, dlopen)
 744
 745 dnl #
 746 dnl #  Check if we need -lsocket
 747 dnl #
 748 AC_CHECK_LIB(socket, getsockname)
 749
 750 dnl #
 751 dnl #  Check for -lresolv
 752 dnl #  This library may be needed later.
 753 dnl #
 754 AC_CHECK_LIB(resolv, inet_aton)
 755
 756 dnl #
 757 dnl #  Check if we need -lnsl. Usually if we want to
 758 dnl #  link against -lsocket we need to include -lnsl as well.
 759 dnl #
 760 AC_CHECK_LIB(nsl, inet_ntoa)
 761 AC_CHECK_LIB(ws2_32, htonl)
 762
 763 dnl #
 764 dnl #  Check the pcap library for the RADIUS sniffer.
 765 dnl #
 766 dnl extra argument: --with-pcap-lib-dir=DIR
 767 pcap_lib_dir=
 768 AC_ARG_WITH(pcap-lib-dir,
 769   [AS_HELP_STRING([--with-pcap-lib-dir=DIR],
 770   [directory in which to look for pcap library files])],
 771   [case "$withval" in
 772     no)
 773       AC_MSG_ERROR([Need pcap-lib-dir])
 774       ;;
 775     yes)
 776       ;;
 777     *)
 778       pcap_lib_dir="$withval"
 779       ;;
 780   esac])
 781
 782 dnl extra argument: --with-pcap-include-dir=DIR
 783 pcap_include_dir=
 784 AC_ARG_WITH(pcap-include-dir,
 785   [AS_HELP_STRING([--with-pcap-include-dir=DIR],
 786   [directory in which to look for pcap include files])],
 787   [case "$withval" in
 788     no)
 789       AC_MSG_ERROR([Need pcap-include-dir])
 790       ;;
 791     yes)
 792       ;;
 793     *)
 794       pcap_include_dir="$withval"
 795       ;;
 796   esac])
 797
 798 smart_try_dir="$pcap_lib_dir"
 799 FR_SMART_CHECK_LIB(pcap, pcap_open_live)
 800 if test "x$ac_cv_lib_pcap_pcap_open_live" != "xyes"; then
 801   AC_MSG_WARN([pcap library not found, silently disabling the RADIUS sniffer, and ARP listener.  Use --with-pcap-lib-dir=<path>.])
 802 else
 803   AC_DEFINE(HAVE_LIBPCAP, 1,
 804     [Define to 1 if you have the `pcap' library (-lpcap).]
 805   )
 806
 807   AC_CHECK_FUNCS(\
 808     pcap_fopen_offline \
 809     pcap_dump_fopen \
 810     pcap_create \
 811     pcap_activate
 812   )
 813
 814   PCAP_LIBS="${smart_lib}"
 815   PCAP_LDFLAGS="${smart_ldflags}"
 816 fi
 817 dnl Set by FR_SMART_CHECK_LIB
 818 LIBS="${old_LIBS}"
 819
 820 dnl Check for collectdclient
 821 dnl extra argument: --with-collectdclient-lib-dir=DIR
 822 collectdclient_lib_dir=
 823 AC_ARG_WITH(collectdclient-lib-dir,
 824   [AS_HELP_STRING([--with-collectdclient-lib-dir=DIR],
 825   [directory in which to look for collectdclient library files])],
 826   [case "$withval" in
 827     no)
 828       AC_MSG_ERROR([Need collectdclient-lib-dir])
 829       ;;
 830     yes)
 831       ;;
 832     *)
 833       collectdclient_lib_dir="$withval"
 834       ;;
 835   esac])
 836
 837 dnl extra argument: --with-collectdclient-include-dir=DIR
 838 collectdclient_include_dir=
 839 AC_ARG_WITH(collectdclient-include-dir,
 840   [AS_HELP_STRING([--with-collectdclient-include-dir=DIR],
 841   [directory in which to look for collectdclient include files])],
 842   [case "$withval" in
 843     no)
 844       AC_MSG_ERROR([Need collectdclient-include-dir])
 845       ;;
 846     yes)
 847       ;;
 848     *)
 849       collectdclient_include_dir="$withval"
 850       ;;
 851   esac])
 852
 853 smart_try_dir="$collectdclient_lib_dir"
 854 FR_SMART_CHECK_LIB(collectdclient, lcc_connect)
 855 if test "x$ac_cv_lib_collectdclient_lcc_connect" != "xyes"; then
 856   AC_MSG_WARN([collectdclient library not found. Use --with-collectdclient-lib-dir=<path>.])
 857 else
 858   COLLECTDC_LIBS="${smart_lib}"
 859   COLLECTDC_LDFLAGS="${smart_ldflags}"
 860 fi
 861 dnl Set by FR_SMART_CHECKLIB
 862 LIBS="${old_LIBS}"
 863
 864 VL_LIB_READLINE
 865
 866 dnl #############################################################
 867 dnl #
 868 dnl #  3. Checks for header files
 869 dnl #
 870 dnl #############################################################
 871
 872 dnl #
 873 dnl # Check for talloc header files
 874 dnl #
 875 smart_try_dir="$talloc_include_dir"
 876 FR_SMART_CHECK_INCLUDE([talloc.h])
 877 if test "x$ac_cv_header_talloc_h" != "xyes"; then
 878   AC_MSG_WARN([talloc headers not found. Use --with-talloc-include-dir=<path>.])
 879   AC_MSG_ERROR([FreeRADIUS requires libtalloc])
 880 fi
 881
 882 dnl #
 883 dnl #  Interix requires us to set -D_ALL_SOURCE, otherwise
 884 dnl #  getopt will be #included, but won't link.  <sigh>
 885 dnl #
 886 case "$host" in
 887   *-interix*)
 888     CFLAGS="$CFLAGS -D_ALL_SOURCE"
 889     ;;
 890   *-darwin*)
 891     CFLAGS="$CFLAGS -DDARWIN"
 892     LIBS="-framework DirectoryService $LIBS"
 893     AC_DEFINE([__APPLE_USE_RFC_2292], 1, [Force OSX >= 10.7 Lion to use RFC2292 IPv6 socket options])
 894     ;;
 895 esac
 896
 897 AC_HEADER_DIRENT
 898 AC_HEADER_STDC
 899 AC_HEADER_TIME
 900 AC_HEADER_SYS_WAIT
 901
 902 AC_CHECK_HEADERS( \
 903   dlfcn.h \
 904   unistd.h \
 905   crypt.h \
 906   errno.h \
 907   resource.h \
 908   sys/resource.h \
 909   getopt.h \
 910   malloc.h \
 911   utmp.h \
 912   utmpx.h \
 913   signal.h \
 914   sys/select.h \
 915   syslog.h \
 916   inttypes.h \
 917   stdint.h \
 918   stdio.h \
 919   netdb.h \
 920   semaphore.h \
 921   arpa/inet.h \
 922   netinet/in.h \
 923   sys/types.h \
 924   sys/socket.h \
 925   winsock.h \
 926   utime.h \
 927   sys/time.h \
 928   sys/wait.h \
 929   sys/security.h \
 930   fcntl.h \
 931   sys/fcntl.h \
 932   sys/prctl.h \
 933   sys/ptrace.h \
 934   sys/un.h \
 935   glob.h \
 936   prot.h \
 937   pwd.h \
 938   grp.h \
 939   stddef.h \
 940   fnmatch.h \
 941   sia.h \
 942   siad.h \
 943   features.h \
 944   limits.h
 945 )
 946
 947 dnl #
 948 dnl #  FreeBSD requires sys/socket.h before net/if.h
 949 dnl #
 950 AC_CHECK_HEADERS(net/if.h, [], [],
 951   [
 952     #ifdef HAVE_SYS_SOCKET_H
 953     #  include <sys/socket.h>
 954     #endif
 955   ]
 956 )
 957
 958 dnl #
 959 dnl #  other checks which require headers
 960 dnl #
 961 if test "x$ac_cv_header_sys_security_h" = "xyes" && test "x$ac_cv_header_prot_h" = "xyes"
 962 then
 963   AC_DEFINE(OSFC2, [], [define if you have OSFC2 authentication])
 964 fi
 965
 966 if test "x$ac_cv_header_sia_h" = "xyes" && test "x$ac_cv_header_siad_h" = "xyes"
 967 then
 968   AC_DEFINE(OSFSIA, [], [define if you have OSFSIA authentication])
 969 fi
 970
 971 dnl #
 972 dnl #  Were we told to use OpenSSL, if we were and we find an error, call AC_MSG_FAILURE and exit
 973 dnl #
 974 if test "x$WITH_OPENSSL" = xyes; then
 975   OLD_LIBS="$LIBS"
 976
 977   dnl #
 978   dnl #  Apparently OpenSSL will attempt to build with kerberos if we don't pass this?!
 979   dnl #
 980   CFLAGS="$CFLAGS -DOPENSSL_NO_KRB5"
 981
 982   dnl #
 983   dnl #  Check we can link to libcrypto and libssl
 984   dnl #
 985   smart_try_dir="$openssl_lib_dir"
 986   FR_SMART_CHECK_LIB(crypto, DH_new)
 987   if test "x$ac_cv_lib_crypto_DH_new" = "xyes"; then
 988     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
 989     OPENSSL_LIBS="$smart_lib"
 990     OPENSSL_LDFLAGS="$smart_ldflags"
 991
 992     FR_SMART_CHECK_LIB(ssl, SSL_new)
 993     if test "x$ac_cv_lib_ssl_SSL_new" != "xyes"; then
 994       AC_MSG_FAILURE([failed linking to libssl. Use --with-openssl-lib-dir=<path>, or --with-openssl=no (builds without OpenSSL)])
 995     else
 996       AC_DEFINE(HAVE_LIBSSL, 1, [Define to 1 if you have the `ssl' library (-lssl).])
 997       OPENSSL_LIBS="$OPENSSL_LIBS $smart_lib"
 998
 999       if test "$OPENSSL_LDFLAGS" != "$smart_ldflags"; then
1000         AC_MSG_FAILURE(["inconsistent LDFLAGS between -lssl '$smart_ldflags' and -lcrypto '$OPENSSL_LDFLAGS'"])
1001       fi
1002     fi
1003   else
1004     AC_MSG_FAILURE([failed linking to libcrypto. Use --with-openssl-lib-dir=<path>, or --with-openssl=no (builds without OpenSSL)])
1005   fi
1006
1007   smart_try_dir="$openssl_include_dir"
1008   FR_SMART_CHECK_INCLUDE(openssl/ssl.h)
1009   if test "x$ac_cv_header_openssl_ssl_h" = "xyes"; then
1010     AC_DEFINE(HAVE_OPENSSL_SSL_H, 1, [Define to 1 if you have the <openssl/ssl.h> header file.])
1011
1012     AC_CHECK_HEADERS( \
1013       openssl/crypto.h \
1014       openssl/err.h \
1015       openssl/evp.h \
1016       openssl/md5.h \
1017       openssl/md4.h \
1018       openssl/sha.h \
1019       openssl/ocsp.h \
1020       openssl/engine.h,
1021       [],
1022       [
1023         AC_MSG_FAILURE([failed locating OpenSSL headers. Use --with-openssl-include-dir=<path>, or --with-openssl=no (builds without OpenSSL)])
1024       ]
1025     )
1026
1027     AC_MSG_CHECKING([for OpenSSL version >= 0.9.7])
1028     AC_EGREP_CPP(yes,
1029       [#include <openssl/crypto.h>
1030        #if (OPENSSL_VERSION_NUMBER >= 0x00907000L)
1031        yes
1032        #endif
1033       ],
1034       [
1035         AC_MSG_RESULT(yes)
1036       ],
1037       [
1038         AC_MSG_RESULT(no)
1039         AC_MSG_FAILURE([OpenSSL version too old])
1040       ]
1041     )
1042
1043     dnl #
1044     dnl #  CPPFLAGS are passed to the compiler first, so we use
1045     dnl #  them to ensure things like --sysroot don't override the
1046     dnl #  library location we discovered previously.
1047     dnl #
1048     old_CPPFLAGS="$CPPFLAGS"
1049     CPPFLAGS="$OPENSSL_LDFLAGS $CPPFLAGS"
1050
1051     dnl #
1052     dnl #  Now check that the header versions match the library
1053     dnl #
1054     AC_MSG_CHECKING([OpenSSL library and header version consistency])
1055     AC_RUN_IFELSE(
1056       [AC_LANG_PROGRAM(
1057         [[
1058           #include <stdio.h>
1059           #include <openssl/opensslv.h>
1060           #include <openssl/crypto.h>
1061         ]],
1062         [[
1063           printf("library: %lx header: %lx... ", (unsigned long) SSLeay(), (unsigned long) OPENSSL_VERSION_NUMBER);
1064           if (SSLeay() == OPENSSL_VERSION_NUMBER) {
1065             return 0;
1066           } else {
1067             return 1;
1068           }
1069         ]]
1070       )],
1071       [
1072         AC_MSG_RESULT(yes)
1073       ],
1074       [
1075         AC_MSG_RESULT(no)
1076         AC_MSG_FAILURE([OpenSSL library version does not match header version])
1077       ]
1078     )
1079     CPPFLAGS="$old_CPPFLAGS"
1080   fi
1081
1082   LIBS="$OLD_LIBS"
1083   AC_SUBST(OPENSSL_LIBS)
1084   AC_SUBST(OPENSSL_LDFLAGS)
1085   export OPENSSL_LIBS OPENSSL_LDFLAGS
1086 fi
1087
1088 dnl #
1089 dnl #  Check the pcap includes for the RADIUS sniffer.
1090 dnl #
1091 if test "x$PCAP_LIBS" = x; then
1092   AC_MSG_NOTICE([skipping test for pcap.h.])
1093 else
1094   dnl #
1095   dnl # Check for pcap header files
1096   dnl #
1097   smart_try_dir="$pcap_include_dir"
1098   FR_SMART_CHECK_INCLUDE([pcap.h])
1099   if test "x$ac_cv_header_pcap_h" == "xyes"; then
1100     AC_DEFINE(HAVE_PCAP_H, 1, [Define to 1 if you have the <pcap.h> header file.])
1101     AC_SUBST(PCAP_LIBS)
1102     AC_SUBST(PCAP_LDFLAGS)
1103   else
1104     AC_MSG_WARN([pcap headers not found, silently disabling the RADIUS sniffer, and ARP listener. Use --with-pcap-include-dir=<path>.])
1105   fi
1106 fi
1107
1108 dnl Check for collectd-client
1109 if test "x$COLLECTDC_LIBS" = x; then
1110   AC_MSG_NOTICE([skipping test for collectd/client.h.])
1111 else
1112   dnl #
1113   dnl # Check for collectd-client header files
1114   dnl #
1115   smart_try_dir="$collectdclient_include_dir"
1116   FR_SMART_CHECK_INCLUDE([collectd/client.h])
1117   if test "x$ac_cv_header_collectd_client_h" == "xyes"; then
1118     AC_DEFINE(HAVE_COLLECTDC_H, 1, [Define to 1 if you have the `collectdclient' library (-lcollectdclient).])
1119     AC_SUBST(COLLECTDC_LIBS)
1120     AC_SUBST(COLLECTDC_LDFLAGS)
1121   else
1122     AC_MSG_WARN([collectdclient headers not found. Use --with-collectdclient-include-dir=<path>.])
1123   fi
1124 fi
1125
1126 dnl #############################################################
1127 dnl #
1128 dnl #  4. Checks for typedefs
1129 dnl #
1130 dnl #############################################################
1131
1132 dnl #
1133 dnl #  Ensure that these are defined
1134 dnl #
1135 AC_TYPE_OFF_T
1136 AC_TYPE_PID_T
1137 AC_TYPE_SIZE_T
1138 AC_TYPE_UID_T
1139
1140 dnl #
1141 dnl #  Check for socklen_t
1142 dnl #
1143 FR_CHECK_TYPE_INCLUDE(
1144   [
1145     #ifdef HAVE_SYS_TYPES_H
1146     #  include <sys/types.h>
1147     #endif
1148
1149     #ifdef HAVE_SYS_SOCKET_H
1150     #  include <sys/socket.h>
1151     #endif
1152   ],
1153   socklen_t, int, [socklen_t is generally 'int' on systems which don't use it]
1154 )
1155
1156 dnl #
1157 dnl #  Check for uint8_t
1158 dnl #
1159 FR_CHECK_TYPE_INCLUDE(
1160   [
1161     #ifdef HAVE_INTTYPES_H
1162     #  include <inttypes.h>
1163     #endif
1164
1165     #ifdef HAVE_STDINT_H
1166     #  include <stdint.h>
1167     #endif
1168   ],
1169   uint8_t, unsigned char, [uint8_t should be the canonical 'octet' for network traffic]
1170 )
1171
1172 dnl #
1173 dnl #  Check for uint16_t
1174 dnl #
1175 FR_CHECK_TYPE_INCLUDE(
1176   [
1177     #ifdef HAVE_INTTYPES_H
1178     #  include <inttypes.h>
1179     #endif
1180
1181     #ifdef HAVE_STDINT_H
1182     #  include <stdint.h>
1183     #endif
1184   ],
1185   uint16_t, unsigned short, [uint16_t should be the canonical '2 octets' for network traffic]
1186 )
1187
1188 dnl #
1189 dnl #  Check for uint32_t
1190 dnl #
1191 FR_CHECK_TYPE_INCLUDE(
1192   [
1193     #ifdef HAVE_INTTYPES_H
1194     #  include <inttypes.h>
1195     #endif
1196
1197     #ifdef HAVE_STDINT_H
1198     #  include <stdint.h>
1199     #endif
1200   ],
1201   uint32_t, unsigned int, [uint32_t should be the canonical 'network integer']
1202 )
1203
1204 dnl #
1205 dnl #  Check for uint64_t
1206 dnl #
1207 FR_CHECK_TYPE_INCLUDE(
1208   [
1209     #ifdef HAVE_INTTYPES_H
1210     #  include <inttypes.h>
1211     #endif
1212
1213     #ifdef HAVE_STDINT_H
1214     #  include <stdint.h>
1215     #endif
1216   ],
1217   uint64_t, unsigned long long, [uint64_t is required for larger counters]
1218 )
1219
1220 dnl #
1221 dnl #  Check for __uint128_t (compiler builtin)
1222 dnl #
1223 AC_CHECK_TYPE(__uint128_t, AC_DEFINE(HAVE___UINT128_T, 1, [compiler specific 128 bit unsigned integer]), [], [])
1224
1225 dnl #
1226 dnl #  Check for uint128_t (fictitious future data type)
1227 dnl #
1228 AC_CHECK_TYPE(uint128_t, AC_DEFINE(HAVE_UINT128_T, 1, [128 bit unsigned integer]), [],
1229   [
1230     #ifdef HAVE_INTTYPES_H
1231     #  include <inttypes.h>
1232     #endif
1233
1234     #ifdef HAVE_STDINT_H
1235     #  include <stdint.h>
1236     #endif
1237   ]
1238 )
1239
1240 AC_CHECK_TYPE(struct in6_addr, AC_DEFINE(HAVE_STRUCT_IN6_ADDR, 1, [IPv6 address structure]), [],
1241   [
1242     #ifdef HAVE_NETINET_IN_H
1243     #  include <netinet/in.h>
1244     #endif
1245   ]
1246 )
1247
1248 AC_CHECK_TYPE(struct sockaddr_storage, AC_DEFINE(HAVE_STRUCT_SOCKADDR_STORAGE, 1, [Generic socket addresses]), [],
1249   [
1250     #ifdef HAVE_NETINET_IN_H
1251     #  include <netinet/in.h>
1252     #endif
1253
1254     #ifdef HAVE_SYS_SOCKET_H
1255     #  include <sys/socket.h>
1256     #endif
1257 ])
1258
1259 AC_CHECK_TYPE(struct sockaddr_in6, AC_DEFINE(HAVE_STRUCT_SOCKADDR_IN6, 1, [IPv6 socket addresses]), [],
1260   [
1261     #ifdef HAVE_NETINET_IN_H
1262     #  include <netinet/in.h>
1263     #endif
1264 ])
1265
1266 AC_CHECK_TYPE(struct addrinfo, AC_DEFINE(HAVE_STRUCT_ADDRINFO, 1, [Generic DNS lookups]), [],
1267   [
1268     #ifdef HAVE_SYS_TYPES_H
1269     #  include <sys/types.h>
1270     #endif
1271
1272     #ifdef HAVE_SYS_SOCKET_H
1273     #  include <sys/socket.h>
1274     #endif
1275
1276     #ifdef HAVE_NETDB_H
1277     #  include <netdb.h>
1278     #endif
1279   ]
1280 )
1281
1282 dnl #
1283 dnl #  Check for sig_t
1284 dnl #
1285 dnl #  FR_CHECK_TYPE_INCLUDE doesn't work for callbacks as it doesn't produce typedefs
1286 dnl #
1287 AC_MSG_CHECKING([if sig_t is defined])
1288 AC_LINK_IFELSE(
1289   [AC_LANG_PROGRAM(
1290     [[
1291       #ifdef HAVE_SIGNAL_H
1292       #  include <signal.h>
1293       #endif
1294     ]],
1295     [[
1296       sig_t func;
1297       return 0;
1298     ]]
1299   )],
1300   [
1301       AC_MSG_RESULT(yes)
1302       AC_DEFINE(HAVE_SIG_T, 1, [Define if the type sig_t is defined by signal.h])
1303   ],
1304   [
1305       AC_MSG_RESULT(no)
1306   ]
1307 )
1308
1309 dnl #############################################################
1310 dnl #
1311 dnl #  5. Checks for structures and functions
1312 dnl #
1313 dnl #############################################################
1314 AC_CHECK_FUNCS( \
1315   getopt_long \
1316   fcntl \
1317   strsignal \
1318   sigaction \
1319   sigprocmask \
1320   pthread_sigmask \
1321   snprintf \
1322   vsnprintf \
1323   setsid \
1324   strncasecmp \
1325   strcasecmp \
1326   localtime_r \
1327   ctime_r \
1328   gmtime_r \
1329   strsep \
1330   inet_aton \
1331   inet_pton \
1332   inet_ntop \
1333   mallopt \
1334   setlinebuf \
1335   setvbuf \
1336   getusershell \
1337   initgroups \
1338   getaddrinfo \
1339   getnameinfo \
1340   closefrom \
1341   gettimeofday \
1342   getpeereid \
1343   setuid \
1344   setresuid \
1345   getresuid \
1346   strlcat \
1347   strlcpy
1348 )
1349
1350 AC_TYPE_SIGNAL
1351
1352 dnl #
1353 dnl #  Check if we have utmpx.h
1354 dnl #  if so, check if struct utmpx has entry ut_xtime
1355 dnl #  if not, set it to define ut_xtime == ut_tv.tv_sec
1356 dnl #
1357 if test "x$ac_cv_header_utmpx_h" = "xyes"; then
1358  FR_CHECK_STRUCT_HAS_MEMBER([#include <utmpx.h>], [struct utmpx], ut_xtime)
1359  if test "x$ac_cv_type_struct_utmpx_has_ut_xtime" = "x"; then
1360    AC_DEFINE(ut_xtime, ut_tv.tv_sec, [define to something if you don't have ut_xtime in struct utmpx])
1361  fi
1362 fi
1363
1364 dnl #
1365 dnl #  struct ip_pktinfo
1366 dnl #
1367 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in_pktinfo], ipi_addr)
1368 if test "x$ac_cv_type_struct_in_pktinfo_has_ipi_addr" = "xyes"; then
1369   AC_DEFINE(HAVE_IP_PKTINFO, [], [define if you have IP_PKTINFO (Linux)])
1370 fi
1371
1372 dnl #
1373 dnl #  struct in6_pktinfo
1374 dnl #
1375 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in6_pktinfo], ipi6_addr)
1376 if test "x$ac_cv_type_struct_in6_pktinfo_has_ipi6_addr" = "xyes"; then
1377   AC_DEFINE(HAVE_IN6_PKTINFO, [], [define if you have IN6_PKTINFO (Linux)])
1378 fi
1379
1380 dnl #
1381 dnl #  Check for htonll and htonlll
1382 dnl #
1383 AC_MSG_CHECKING([if htonll is defined])
1384 AC_LINK_IFELSE(
1385   [AC_LANG_PROGRAM(
1386     [[
1387       #include <sys/types.h>
1388       #include <netinet/in.h>
1389     ]],
1390     [[
1391       return htonll(0);
1392     ]]
1393   )],
1394   [
1395       AC_MSG_RESULT(yes)
1396       AC_DEFINE(HAVE_HTONLL, 1, [Define if the function (or macro) htonll exists.])
1397   ],
1398   [
1399       AC_MSG_RESULT(no)
1400   ]
1401 )
1402
1403 AC_MSG_CHECKING([if htonlll is defined])
1404 AC_LINK_IFELSE(
1405   [AC_LANG_PROGRAM(
1406     [[
1407       #include <sys/types.h>
1408       #include <netinet/in.h>
1409     ]],
1410     [[
1411       return htonlll(0);
1412     ]]
1413   )],
1414   [
1415       AC_MSG_RESULT(yes)
1416       AC_DEFINE(HAVE_HTONLLL, 1, [Define if the function (or macro) htonlll exists.])
1417   ],
1418   [
1419       AC_MSG_RESULT(no)
1420   ]
1421 )
1422
1423 dnl #############################################################
1424 dnl #
1425 dnl #  6. Checks for compiler characteristics
1426 dnl #
1427 dnl #############################################################
1428
1429 dnl #
1430 dnl #  Ensure that these are defined
1431 dnl #
1432 AC_C_CONST
1433
1434 dnl #
1435 dnl #  See if this is OS/2
1436 dnl #
1437 AC_MSG_CHECKING([type of OS])
1438 OS=`uname -s`
1439 AC_MSG_RESULT($OS)
1440 if test "$OS" = "OS/2"; then
1441   LIBPREFIX=
1442 else
1443   LIBPREFIX=lib
1444 fi
1445 AC_SUBST(LIBPREFIX)
1446
1447 if test "x$developer" = "xyes"; then
1448   AC_MSG_NOTICE([Setting additional developer CFLAGS])
1449
1450   dnl #
1451   dnl #  Tell the compiler to parse doxygen documentation and verify it against function and variable declarations
1452   dnl #
1453   AX_CC_WDOCUMENTATION_FLAG
1454   if test "x$ax_cv_cc_wdocumentation_flag" = "xyes"; then
1455     devflags="-Wdocumentation"
1456   fi
1457
1458   if test "x$GCC" = "xyes"; then
1459     devflags="$devflags -Wshadow -Wpointer-arith -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -W -Wredundant-decls -Wundef -Wformat-y2k -Wno-format-extra-args -Wno-format-zero-length -Wno-cast-align -Wformat-nonliteral -Wformat-security -Wformat=2 -DWITH_VERIFY_PTR=1"
1460     INSTALLSTRIP=""
1461   fi
1462
1463   AC_MSG_NOTICE([Developer CFLAGS are "$devflags"])
1464
1465   CFLAGS="$CFLAGS $devflags"
1466   dnl #
1467   dnl #  Enable experimental modules (we want to know if code changes breaks one of them)
1468   dnl #
1469   if test "x$EXPERIMENTAL" != "xno"; then
1470     AC_MSG_NOTICE([is developer build, enabling experimental modules implicitly, disable with --without-experimental-modules])
1471     EXPERIMENTAL=yes
1472   fi
1473 else
1474   devflags=""
1475   CFLAGS="$CFLAGS -DNDEBUG"
1476   INSTALLSTRIP=""
1477 fi
1478
1479 dnl #
1480 dnl #  May of been set outside of this configure script
1481 dnl #
1482 AC_MSG_CHECKING([if building with -DNDEBUG])
1483 if echo "$CFLAGS" | grep '\-DNDEBUG' > /dev/null; then
1484   AC_MSG_RESULT([yes])
1485   AC_DEFINE([WITH_NDEBUG], [1], [define if the server was built with -DNDEBUG])
1486 else
1487   AC_MSG_RESULT([no])
1488 fi
1489
1490 export EXPERIMENTAL
1491
1492 dnl #
1493 dnl #  append the current git hash onto the version string
1494 dnl #
1495 if test -d $srcdir/.git -a "x$GIT" = "xyes"; then
1496   RADIUSD_VERSION_COMMIT=`git log --pretty=format:'%h' -n 1`
1497   AC_DEFINE_UNQUOTED([RADIUSD_VERSION_COMMIT],[${RADIUSD_VERSION_COMMIT}],[Commit HEAD at time of configuring])
1498 fi
1499
1500 dnl #
1501 dnl #  check for some compiler features
1502 dnl #
1503 FR_TLS
1504 FR_HAVE_BUILTIN_CHOOSE_EXPR
1505 FR_HAVE_BUILTIN_TYPES_COMPATIBLE_P
1506 FR_HAVE_BUILTIN_BSWAP_64
1507
1508 dnl #############################################################
1509 dnl #
1510 dnl #  7. Checks for library functions
1511 dnl #
1512 dnl #############################################################
1513
1514 dnl #
1515 dnl # Check for talloc_set_memlimit
1516 dnl # This was only included in version 2.0.8
1517 dnl #
1518 AC_CHECK_LIB(talloc, talloc_set_memlimit,
1519   [
1520     AC_DEFINE(HAVE_TALLOC_SET_MEMLIMIT, 1, [Define to 1 if you have the function talloc_set_memlimit.])
1521   ]
1522 )
1523
1524 dnl #
1525 dnl # Check for libcrypt
1526 dnl # We use crypt(3) which may be in libc, or in libcrypt (eg FreeBSD)
1527 dnl #
1528 AC_CHECK_LIB(crypt, crypt,
1529   CRYPTLIB="-lcrypt"
1530 )
1531
1532 if test "$CRYPTLIB" != ""; then
1533   AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function])
1534 else
1535   AC_CHECK_FUNC(crypt, AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function]))
1536 fi
1537
1538 dnl Check for libcipher
1539 AC_CHECK_LIB(cipher, setkey,
1540    CRYPTLIB="${CRYPTLIB} -lcipher"
1541 )
1542 AC_SUBST(CRYPTLIB)
1543
1544 dnl #
1545 dnl #  Check for libexecinfo support, on some systems this is built into libc
1546 dnl #  on others it's a separate library.
1547 dnl #
1548 dnl extra argument: --with-execinfo-lib-dir
1549 execinfo_lib_dir=
1550 AC_ARG_WITH(execinfo-lib-dir,
1551 [AS_HELP_STRING([--with-execinfo-lib-dir=DIR],
1552 [directory in which to look for execinfo library files])],
1553 [ case "$withval" in
1554     no)
1555         AC_MSG_ERROR([Need execinfo-lib-dir])
1556         ;;
1557     yes)
1558         ;;
1559     *)
1560         execinfo_lib_dir="$withval"
1561         ;;
1562   esac ]
1563 )
1564
1565 dnl extra argument: --with-execinfo-include-dir
1566 execinfo_include_dir=
1567 AC_ARG_WITH(execinfo-include-dir,
1568 [AS_HELP_STRING([--with-execinfo-include-dir=DIR],
1569 [directory in which to look for execinfo include files])],
1570 [ case "$withval" in
1571     no)
1572         AC_MSG_ERROR([Need execinfo-include-dir])
1573         ;;
1574     yes)
1575         ;;
1576     *)
1577         execinfo_include_dir="$withval"
1578         ;;
1579   esac ]
1580 )
1581
1582 dnl #
1583 dnl #  Look for execinfo.h and symbols
1584 dnl #
1585 smart_try_dir=$execinfo_include_dir
1586 FR_SMART_CHECK_INCLUDE(execinfo.h)
1587 if test "x$ac_cv_header_execinfo_h" = "xyes"; then
1588   smart_try_dir=$execinfo_lib_dir
1589   FR_SMART_CHECK_LIB(execinfo, backtrace_symbols)
1590   if test "x$ac_cv_lib_execinfo_backtrace_symbols" != "xyes"; then
1591     dnl # Might be provided as part of libc
1592     AC_MSG_CHECKING([if execinfo provided as part of libc])
1593     AC_TRY_LINK(
1594       [
1595         #include <execinfo.h>
1596       ],
1597       [
1598         void *sym[1];
1599         backtrace_symbols(&sym, sizeof(sym)) ],
1600       [
1601         AC_MSG_RESULT(yes)
1602         ac_cv_lib_execinfo_backtrace_symbols="yes"
1603       ],
1604       [
1605         AC_MSG_RESULT(no)
1606       ]
1607     )
1608   fi
1609
1610   if test "x$ac_cv_lib_execinfo_backtrace_symbols" = "xyes"; then
1611     AC_DEFINE(HAVE_EXECINFO, [1], [define this if we have <execinfo.h> and symbols])
1612   fi
1613 fi
1614
1615 dnl #
1616 dnl #  Check for regular expression support, if were using PCRE it MUST be included
1617 dnl #  before all others, else we seem to still pickup the posix symbols for regcomp
1618 dnl #  and regexec, which results in crashes as soon as we call any posix regex
1619 dnl #  functions.
1620 dnl #
1621 dnl extra argument: --with-pcre-lib-dir
1622 pcre_lib_dir=
1623 AC_ARG_WITH(pcre-lib-dir,
1624 [AS_HELP_STRING([--with-pcre-lib-dir=DIR],
1625 [directory in which to look for pcre library files])],
1626 [ case "$withval" in
1627     no)
1628         AC_MSG_ERROR(Need pcre-lib-dir)
1629         ;;
1630     yes)
1631         ;;
1632     *)
1633         pcre_lib_dir="$withval"
1634         ;;
1635   esac ]
1636 )
1637
1638 dnl extra argument: --with-pcre-include--dir
1639 pcre_include_dir=
1640 AC_ARG_WITH(pcre-include-dir,
1641 [AS_HELP_STRING([--with-pcre-include-dir=DIR],
1642 [directory in which to look for pcre include files])],
1643 [ case "$withval" in
1644     no)
1645         AC_MSG_ERROR(Need pcre-include-dir)
1646         ;;
1647     yes)
1648         ;;
1649     *)
1650         pcre_include_dir="$withval"
1651         ;;
1652   esac ]
1653 )
1654
1655 REGEX=no
1656 REGEX_EXTENDED=no
1657 REGEX_PCRE=no
1658
1659 dnl #
1660 dnl #  First look for PCRE
1661 dnl #
1662 smart_try_dir=$pcre_include_dir
1663 FR_SMART_CHECK_INCLUDE(pcreposix.h)
1664 if test "x$ac_cv_header_pcreposix_h" = "xyes"; then
1665   AC_DEFINE(HAVE_REGEX_H, [1], [define if we have any regex])
1666   AC_DEFINE(HAVE_PCREPOSIX_H, [1], [define this if we have the <pcreposix.h> header file])
1667   REGEX=yes
1668   REGEX_EXTENDED=yes
1669   REGEX_PCRE=yes
1670   LIBS="-lpcre -lpcreposix $LIBS"
1671
1672 dnl #
1673 dnl #  Then fallback to POSIX regular expressions
1674 dnl #
1675 else
1676   smart_try_dir=
1677   FR_SMART_CHECK_INCLUDE(regex.h)
1678   if test "x$ac_cv_header_regex_h" = "xyes"; then
1679     AC_DEFINE(HAVE_REGEX_H, [1], [define if we have any regex])
1680     REGEX=yes
1681     AC_EGREP_CPP(yes,
1682       [
1683         #include <regex.h>
1684         #ifdef REG_EXTENDED
1685         yes
1686         #endif
1687        ],
1688     [AC_DEFINE(HAVE_REG_EXTENDED, [1], [define this if we have REG_EXTENDED (from <regex.h>)]) REGEX_EXTENDED=yes]
1689     )
1690 dnl #
1691 dnl # Fixme, this is needed for mingw builds, but not available on some Linux systems
1692 dnl # despite the presence of regex.h
1693 dnl #
1694 dnl # LIBS="$LIBS -lregex"
1695   fi
1696 fi
1697
1698 AC_SUBST(REGEX)
1699 AC_SUBST(REGEX_PCRE)
1700 AC_SUBST(REGEX_EXTENDED)
1701
1702 dnl #
1703 dnl #  Check the style of gethostbyaddr, in order of preference
1704 dnl #  GNU (_r eight args)
1705 dnl #
1706 AC_DEFINE(GNUSTYLE, [1], [GNU-Style get*byaddr_r])
1707
1708 dnl #
1709 dnl #  SYSV (_r six args)
1710 dnl #
1711 AC_DEFINE(SYSVSTYLE, [2], [SYSV-Style get*byaddr_r])
1712
1713 dnl #
1714 dnl #  BSD (three args, may not be thread safe)
1715 dnl #
1716 AC_DEFINE(BSDSTYLE, [3], [BSD-Style get*byaddr_r])
1717
1718 dnl #
1719 dnl #  Tru64 has BSD version, but it is thread safe
1720 dnl #  http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1739____.HTM
1721 dnl #  We need #stdio.h to define NULL on FreeBSD (at least)
1722 dnl #
1723 gethostbyaddrrstyle=""
1724 AC_MSG_CHECKING([gethostbyaddr_r() syntax])
1725 case "$host" in
1726   *-freebsd*)
1727     dnl #
1728     dnl #  With FreeBSD, check if there's a prototype for gethostbyaddr_r.
1729     dnl #  Some versions (FreeBSD 5.1?) have a symbol but no prototype - so we
1730     dnl #  override this test to BSDSTYLE. FreeBSD 6.2 and up have proper GNU
1731     dnl #  style support.
1732     dnl #
1733     AC_CHECK_DECLS([gethostbyaddr_r], [],
1734       [
1735         AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE,
1736           [style of gethostbyaddr_r functions ])
1737         gethostbyaddrrstyle=BSD
1738         AC_MSG_WARN([FreeBSD overridden to BSD-style])
1739       ],
1740       [
1741         #ifdef HAVE_NETDB_H
1742         #include <netdb.h>
1743         #endif
1744       ])
1745     ;;
1746 esac
1747
1748 if test "x$gethostbyaddrrstyle" = "x"; then
1749   AC_TRY_LINK(
1750     [
1751       #include <stdio.h>
1752       #include <netdb.h>
1753     ],
1754     [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL, NULL) ],
1755     [
1756       AC_DEFINE(GETHOSTBYADDRRSTYLE, GNUSTYLE, [style of gethostbyaddr_r functions ])
1757       gethostbyaddrrstyle=GNU
1758     ]
1759   )
1760 fi
1761
1762 if test "x$gethostbyaddrrstyle" = "x"; then
1763   AC_TRY_LINK(
1764     [
1765       #include <stdio.h>
1766       #include <netdb.h>
1767     ],
1768     [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL) ] ,
1769     [
1770       AC_DEFINE(GETHOSTBYADDRRSTYLE, SYSVSTYLE, [style of gethostbyaddr_r functions ])
1771       gethostbyaddrrstyle=SYSV
1772     ]
1773   )
1774 fi
1775
1776
1777 if test "x$gethostbyaddrrstyle" = "x"; then
1778   AC_TRY_LINK(
1779     [
1780       #include <stdio.h>
1781       #include <netdb.h>
1782     ],
1783     [ gethostbyaddr(NULL, 0, 0)  ],
1784     [
1785       AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE, [style of gethostbyaddr_r functions ])
1786       gethostbyaddrrstyle=BSD
1787     ]
1788   )
1789 fi
1790
1791 if test "x$gethostbyaddrrstyle" = "x"; then
1792   AC_MSG_RESULT([none!  It must not exist, here.])
1793 else
1794   AC_MSG_RESULT([${gethostbyaddrrstyle}-style])
1795 fi
1796
1797 if test "x$gethostbyaddrrstyle" = "xBSD"; then
1798   AC_MSG_WARN([ ****** BSD-style gethostbyaddr might NOT be thread-safe! ****** ])
1799 fi
1800
1801 dnl #
1802 dnl #  Check the style of gethostbyname, in order of preference
1803 dnl #  GNU (_r seven args)
1804 dnl #  SYSV (_r five args)
1805 dnl #  BSD (two args, may not be thread safe)
1806 dnl #  Tru64 has BSD version, but it _is_ thread safe
1807 dnl #    http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1946____.HTM
1808 dnl #  We need #stdio.h to define NULL on FreeBSD (at least)
1809 dnl #
1810 gethostbynamerstyle=""
1811 AC_MSG_CHECKING([gethostbyname_r() syntax])
1812 AC_TRY_LINK(
1813   [
1814     #include <stdio.h>
1815     #include <netdb.h>
1816   ],
1817   [ gethostbyname_r(NULL, NULL, NULL, 0, NULL, NULL) ],
1818   [
1819     AC_DEFINE(GETHOSTBYNAMERSTYLE, GNUSTYLE, [style of gethostbyname_r functions ])
1820     gethostbynamerstyle=GNU
1821   ]
1822 )
1823
1824 if test "x$gethostbynamerstyle" = "x"; then
1825   AC_TRY_LINK(
1826     [
1827       #include <stdio.h>
1828       #include <netdb.h>
1829     ],
1830     [ gethostbyname_r(NULL, NULL, NULL, 0, NULL) ] ,
1831     [
1832       AC_DEFINE(GETHOSTBYNAMERSTYLE, SYSVSTYLE, [style of gethostbyname_r functions ])
1833       gethostbynamerstyle=SYSV
1834     ]
1835   )
1836 fi
1837
1838 if test "x$gethostbynamerstyle" = "x"; then
1839   AC_TRY_LINK(
1840     [
1841       #include <stdio.h>
1842       #include <netdb.h>
1843     ],
1844     [ gethostbyname(NULL) ],
1845     [
1846       AC_DEFINE(GETHOSTBYNAMERSTYLE, BSDSTYLE, [style of gethostbyname_r functions ])
1847       gethostbynamerstyle=BSD
1848     ]
1849   )
1850 fi
1851
1852 if test "x$gethostbynamerstyle" = "x"; then
1853   AC_MSG_RESULT([none!  It must not exist, here.])
1854 else
1855   AC_MSG_RESULT([${gethostbynamerstyle}-style])
1856 fi
1857
1858 if test "x$gethostbynamerstyle" = "xBSD"; then
1859   AC_MSG_WARN([ ****** BSD-style gethostbyname might NOT be thread-safe! ****** ])
1860 fi
1861
1862 dnl #
1863 dnl #  Check for non-posix solaris ctime_r (extra buflen int arg)
1864 dnl #
1865 AC_DEFINE(POSIXSTYLE, [1], [Posix-Style ctime_r])
1866 AC_DEFINE(SOLARISSTYLE, [2], [Solaris-Style ctime_r])
1867 ctimerstyle=""
1868 AC_MSG_CHECKING([ctime_r() syntax])
1869 AC_TRY_LINK(
1870   [
1871     #include <time.h>
1872   ],
1873   [ ctime_r(NULL, NULL, 0) ],
1874   [
1875     AC_DEFINE(CTIMERSTYLE, SOLARISSTYLE, [style of ctime_r function])
1876     ctimerstyle="SOLARIS"
1877   ]
1878 )
1879
1880 if test "x$ctimerstyle" = "x"; then
1881   AC_TRY_LINK(
1882     [
1883       #include <time.h>
1884     ],
1885     [ ctime_r(NULL, NULL) ],
1886     [
1887       AC_DEFINE(CTIMERSTYLE, POSIXSTYLE, [style of ctime_r function])
1888       ctimerstyle="POSIX"
1889     ]
1890   )
1891 fi
1892
1893 if test "x$ctimerstyle" = "x"; then
1894     AC_MSG_RESULT([none!  It must not exist, here.])
1895 else
1896     AC_MSG_RESULT([${ctimerstyle}-style])
1897 fi
1898
1899 AC_SUBST(HOSTINFO, $host)
1900
1901 dnl #############################################################
1902 dnl #
1903 dnl #  8. Checks for system services
1904 dnl #
1905 dnl #############################################################
1906
1907 dnl #
1908 dnl #  Figure out where libtool is located,
1909 dnl #
1910 top_builddir=`pwd`
1911 export top_builddir
1912 AC_MSG_RESULT([top_builddir=$top_builddir])
1913 dnl #  AC_SUBST(top_builddir)
1914
1915 dnl #
1916 dnl #  import libtool stuff
1917 dnl #
1918 dnl #############################################################
1919 dnl #
1920 dnl #  Configure in any module directories.
1921 dnl #
1922 dnl #############################################################
1923
1924 dnl ############################################################
1925 dnl #  Remove any conflicting definitions if autoconf.h
1926 dnl #  is being included by a module.
1927 dnl #############################################################
1928 AH_BOTTOM([#include <freeradius-devel/automask.h>])
1929
1930 dnl ############################################################
1931 dnl #  make modules by list
1932 dnl #############################################################
1933 if test "x$EXPERIMENTAL" = "xyes"; then
1934   for foo in `ls -1 "${srcdir}"/src/modules | grep rlm_`; do
1935     MODULES="$MODULES $foo"
1936   done
1937 else
1938    dnl #
1939    dnl #  make ONLY the stable modules
1940    dnl #
1941    for foo in `cat "${srcdir}"/src/modules/stable`; do
1942       MODULES="$MODULES $foo"
1943    done
1944 fi
1945
1946 dnl ############################################################
1947 dnl #  Add autoconf subdirs, based on the module list we
1948 dnl #  previously created.
1949 dnl #############################################################
1950 mysubdirs=""
1951 for bar in $MODULES; do
1952   if test -f "${srcdir}"/src/modules/$bar/configure; then
1953     mysubdirs="$mysubdirs src/modules/$bar"
1954   fi
1955 done
1956
1957 dnl #
1958 dnl #  Don't change the variable name here.  Autoconf goes bonkers
1959 dnl #  if you do.
1960 dnl #
1961 AC_CONFIG_SUBDIRS($mysubdirs)
1962 AC_SUBST(MODULES)
1963
1964 dnl #############################################################
1965 dnl #
1966 dnl #  Add -Werror last, so it doesn't interfere with autoconf's
1967 dnl #  test programs.
1968 dnl #
1969 dnl #############################################################
1970 if test "x$werror" == "xyes"; then
1971   CFLAGS="-Werror $CFLAGS"
1972 fi
1973
1974 dnl #############################################################
1975 dnl #
1976 dnl #  And finally, output the results.
1977 dnl #
1978 dnl #############################################################
1979 AC_CONFIG_COMMANDS([stamp-h], [echo timestamp > src/include/stamp-h])
1980 AC_CONFIG_COMMANDS([build-radpaths-h], [(cd ./src/include && /bin/sh ./build-radpaths-h)])
1981 AC_CONFIG_COMMANDS([main-chmod], [(cd ./src/main && chmod +x checkrad radlast radtest)])
1982 AC_CONFIG_COMMANDS([scripts-chmod], [(cd ./scripts && chmod +x rc.radiusd cron/radiusd.cron.daily cron/radiusd.cron.monthly cryptpasswd)])
1983
1984 dnl #
1985 dnl #  Substitute whatever libraries we found to be necessary
1986 dnl #
1987 AC_SUBST(LIBS)
1988 AC_SUBST(INSTALLSTRIP)
1989
1990 AC_SUBST(USE_SHARED_LIBS)
1991 USE_STATIC_LIBS="yes"
1992 AC_SUBST(USE_STATIC_LIBS)
1993 AC_SUBST(STATIC_MODULES)
1994
1995 AC_OUTPUT(\
1996   ./Make.inc \
1997   ./src/include/build-radpaths-h \
1998   ./src/main/radsniff.mk \
1999   ./src/main/checkrad \
2000   ./src/main/radlast \
2001   ./src/main/radtest \
2002   ./scripts/rc.radiusd \
2003   ./scripts/cron/radiusd.cron.daily \
2004   ./scripts/cron/radiusd.cron.monthly \
2005   ./scripts/cryptpasswd \
2006   ./raddb/radrelay.conf \
2007   ./raddb/radiusd.conf
2008 )