configure.ac

   1 dnl #############################################################
   2 dnl #
   3 dnl #  For information about autoconf, see:
   4 dnl #
   5 dnl #  http://www.gnu.org/software/autoconf/
   6 dnl #
   7 dnl #  The recommended order is:
   8 dnl #
   9 dnl #  AC_INIT(file)
  10 dnl #  0. checks for compiler, libtool, and command line options
  11 dnl #  1. checks for programs
  12 dnl #  2. checks for libraries
  13 dnl #  3. checks for header files
  14 dnl #  4. checks for typedefs
  15 dnl #  5. checks for structures and functions
  16 dnl #  6. checks for compiler characteristics
  17 dnl #  7. checks for library functions
  18 dnl #  8. checks for system services
  19 dnl #  AC_OUTPUT([file...])
  20 dnl #
  21 dnl #############################################################
  22
  23 AC_PREREQ([2.59])
  24 export CFLAGS LIBS LDFLAGS CPPFLAGS
  25
  26 AC_INIT([freeradius],[$]Id[$],[http://bugs.freeradius.org],,[http://www.freeradius.org])
  27 AC_CONFIG_SRCDIR([src/main/radiusd.c])
  28 AC_CONFIG_HEADER([src/include/autoconf.h])
  29 m4_include([m4/ax_cc.m4])
  30
  31 dnl #############################################################
  32 dnl #
  33 dnl #  Custom hackery to discover version at configure time
  34 dnl #
  35 dnl #############################################################
  36
  37 RADIUSD_MAJOR_VERSION=`cat VERSION | sed 's/\..*//'`
  38 RADIUSD_MINOR_VERSION=`cat VERSION | sed 's/^[[^\.]]*\.//' | sed 's/\..*$//'`
  39 RADIUSD_INCRM_VERSION=`cat VERSION | sed 's/^.*\..*\.//' | sed 's/[[\.-]].*$//'`
  40
  41 RADIUSD_VERSION=`echo | awk -v major="$RADIUSD_MAJOR_VERSION" \
  42 -v minor="$RADIUSD_MINOR_VERSION" \
  43 -v incrm="$RADIUSD_INCRM_VERSION" \
  44 '{ printf "%02i%02i%02i", major, minor, incrm }'`
  45
  46 dnl #
  47 dnl #  Still useful for custom builds
  48 dnl #
  49 RADIUSD_VERSION_STRING=`cat VERSION`
  50
  51 dnl #
  52 dnl #  Add definitions to Make.inc as it's used by various build targets
  53 dnl #
  54 AC_SUBST([RADIUSD_VERSION_STRING])
  55
  56 dnl #
  57 dnl #  Add definitions to autoconf.h, so that the headers that we install
  58 dnl #  contain the version number of the server.
  59 dnl #
  60 AC_DEFINE_UNQUOTED([RADIUSD_VERSION], [${RADIUSD_VERSION}], [Version integer in format <ma><ma><mi><mi><in><in>])
  61 AC_DEFINE_UNQUOTED([RADIUSD_VERSION_STRING], ["${RADIUSD_VERSION_STRING}"], [Raw version string from VERSION file])
  62
  63 dnl #############################################################
  64 dnl #
  65 dnl #  Override some of the default autoconf variables such as
  66 dnl #  CFLAGS if were building in developer mode
  67 dnl #
  68 dnl #############################################################
  69
  70 dnl #
  71 dnl #  Enable developer features like debugging symbols.
  72 dnl #  These checks must be done before expanding the AC_PROG_CC
  73 dnl #  and AC_PROG_CXX macros.
  74 dnl #
  75 AC_ARG_ENABLE(developer,
  76 [  --enable-developer      enables features of interest to developers.],
  77 [ case "$enableval" in
  78   no)
  79     developer=no
  80     ;;
  81   *)
  82     developer=yes
  83   esac ]
  84 )
  85
  86 dnl #
  87 dnl #  Turn on the developer flag when taken from a git checkout (not a release)
  88 dnl #
  89 if test -d $srcdir/.git; then
  90   if test "x$developer" != "xno"; then
  91     AC_MSG_NOTICE([found .git directory, enabling developer build implicitly, disable with --disable-developer])
  92     developer="yes"
  93   fi
  94 fi
  95
  96 dnl #
  97 dnl #  Autoconf sets -O2 and -g by default, but this is a PITA for debugging
  98 dnl #  so we remove the defaults if were building in developer mode, and set
  99 dnl #  -g3 so nice things like macro values are included. Other arguments are
 100 dnl #  added later when we know what compiler were using.
 101 dnl #
 102 if test "x$developer" = "xyes"; then
 103   : ${CFLAGS=-g3}
 104 fi
 105
 106 dnl #############################################################
 107 dnl #
 108 dnl #  0. Checks for compiler, libtool, and command line options.
 109 dnl #
 110 dnl #############################################################
 111
 112 dnl #
 113 dnl #  Get system information
 114 dnl #
 115 AC_CANONICAL_SYSTEM
 116
 117 dnl #
 118 dnl #  Check for GNU cc
 119 dnl #
 120 AC_PROG_CC
 121 AC_PROG_CXX
 122
 123 dnl #
 124 dnl #  check for AIX, to allow us to use some BSD functions
 125 dnl #  must be before macros that call the compiler.
 126 dnl #
 127 AC_AIX
 128
 129 AC_PROG_GCC_TRADITIONAL
 130 AC_PROG_CC_SUNPRO
 131 AC_PROG_RANLIB
 132
 133 dnl #
 134 dnl #  Definitive check for whether the compiler is clang
 135 dnl #
 136 AX_CC_IS_CLANG
 137 if test "x$ax_cv_cc_clang" = "xyes"; then
 138   AC_SUBST(clang_path, "$CC")
 139 else
 140   AC_SUBST(clang_path, "")
 141 fi
 142
 143
 144 dnl #
 145 dnl #  Set Default CFLAGS for GCC compatible compilers
 146 dnl #
 147 if test "x$GCC" = "xyes"; then
 148   CFLAGS="$CFLAGS -Wall -std=c99 -D_GNU_SOURCE"
 149 fi
 150
 151 dnl #
 152 dnl #  -Qunused-arguments means the compiler won't complain about unsupported arguments
 153 dnl #
 154 AX_CC_QUNUSED_ARGUMENTS_FLAG
 155 if test "x$ax_cv_cc_qunused_arguments_flag" = "xyes"; then
 156   CFLAGS="$CFLAGS -Qunused-arguments"
 157   LDFLAGS="$LDFLAGS -Qunused-arguments"
 158 fi
 159
 160 dnl #
 161 dnl #  Compile in large (2G+) file support.
 162 dnl #
 163 AC_SYS_LARGEFILE
 164
 165 dnl #
 166 dnl #  check for system bytesex
 167 dnl #  AC_DEFINES WORDS_BIGENDIAN
 168 dnl #
 169 AC_C_BIGENDIAN(
 170   [AC_DEFINE(BIG_ENDIAN, 1, [Define if your processor stores words with the most significant byte first])],
 171   [AC_DEFINE(LITTLE_ENDIAN, 1, [Define if your processor stores words with the least significant byte first])]
 172 )
 173
 174 dnl #
 175 dnl #  Find GNU Make.
 176 dnl #
 177 AC_CHECK_PROG(GMAKE, gmake, yes, no)
 178 if test $GMAKE = no; then
 179   AC_PATH_PROG(MAKE, make, /usr/local/bin/make)
 180 else
 181   AC_PATH_PROG(MAKE, gmake, /usr/local/gnu/bin/make)
 182 fi
 183 makever=`$ac_cv_path_MAKE --version 2>&1 | grep "GNU Make"`
 184 if test -z "$makever"; then
 185   AC_MSG_ERROR([GNU Make is not installed.  Please download and install it from ftp://prep.ai.mit.edu/pub/gnu/make/ before continuing.])
 186 fi
 187
 188 dnl #
 189 dnl #  autoconf explicitly sets MAKEFLAGS and MFLAGS to '' even though we
 190 dnl #  didn't tell it to, so we have to use FR_MAKEFLAGS.
 191 dnl #
 192 dnl #  determine the number of cores available and set the number of build
 193 dnl #  processes appropriately.
 194 dnl #
 195 AX_SYSTEM_CORES
 196
 197 dnl #  Temporarily disabled because test and installation targets do not
 198 dnl #  have dependencies set up correctly for multiple build processes.
 199 dnl if test "x$ax_cv_system_cores" != "x"; then
 200 dnl  : ${FR_MAKEFLAGS=-j$ax_cv_system_cores}
 201 dnl fi
 202 AC_SUBST(FR_MAKEFLAGS)
 203
 204 dnl #
 205 dnl #  See if we have Git.
 206 dnl #
 207 AC_CHECK_PROG(GIT, git, yes, no)
 208
 209 dnl Put this in later, when all distributed modules use autoconf.
 210 dnl AC_ARG_WITH(disablemodulefoo,
 211 dnl [  --without-rlm_foo         Disables module compilation.  Module list:]
 212 dnl esyscmd([find src/modules -type d -name rlm_\* -print |\
 213 dnl   sed -e 's%src/modules/.*/% (sub)- %; s%.*/%- %' |\
 214 dnl   awk '{print "                            "$0}']))
 215
 216 AC_ARG_ENABLE(strict-dependencies,
 217 [  --enable-strict-dependencies  fail configure on lack of module dependancy.])
 218
 219 AC_ARG_ENABLE(werror,
 220 [  --enable-werror         causes the build to fail if any warnings are generated.],
 221 [ case "$enableval" in
 222     no)
 223       werror=no
 224     ;;
 225     *)
 226       werror=yes
 227   esac ]
 228 )
 229
 230 dnl #
 231 dnl #  extra argument: --with-docdir
 232 dnl #
 233 docdir='${datadir}/doc/freeradius'
 234 AC_MSG_CHECKING([docdir])
 235 AC_ARG_WITH(docdir,
 236 [  --with-docdir=DIR       directory for documentation [DATADIR/doc/freeradius] ],
 237 [ case "$withval" in
 238   no)
 239     docdir=no
 240     ;;
 241   yes)
 242     ;;
 243   [[\\/$]]* | ?:[[\\/]]* )
 244     docdir="$withval"
 245     ;;
 246   *)
 247     AC_MSG_ERROR([expected an absolute directory name for --with-docdir: $withval])
 248     ;;
 249   esac ]
 250 )
 251 AC_SUBST(docdir)
 252 AC_MSG_RESULT($docdir)
 253 if test "x$docdir" = xno; then
 254   AC_MSG_WARN([Documentation files will NOT be installed.])
 255 fi
 256
 257 dnl #
 258 dnl #  extra argument: --with-logdir
 259 dnl #
 260 logdir='${localstatedir}/log/radius'
 261 AC_MSG_CHECKING(logdir)
 262 AC_ARG_WITH(logdir,
 263 [  --with-logdir=DIR       directory for logfiles [LOCALSTATEDIR/log/radius] ],
 264 [ case "$withval" in
 265   no)
 266     AC_MSG_ERROR([Need logdir])
 267     ;;
 268   yes)
 269     ;;
 270   [[\\/$]]* | ?:[[\\/]]* )
 271     logdir="$withval"
 272     ;;
 273   *)
 274     AC_MSG_ERROR([expected an absolute directory name for --with-logdir: $withval])
 275     ;;
 276   esac ]
 277 )
 278 AC_SUBST(logdir)
 279 AC_MSG_RESULT($logdir)
 280
 281 dnl #
 282 dnl #  extra argument: --with-radacctdir
 283 dnl #
 284 radacctdir='${logdir}/radacct'
 285 AC_MSG_CHECKING(radacctdir)
 286 AC_ARG_WITH(radacctdir,
 287 [  --with-radacctdir=DIR   directory for detail files [LOGDIR/radacct] ],
 288 [ case "$withval" in
 289   no)
 290     AC_MSG_ERROR([Need radacctdir])
 291     ;;
 292   yes)
 293     ;;
 294   [[\\/$]]* | ?:[[\\/]]* )
 295     radacctdir="$withval"
 296     ;;
 297   *)
 298     AC_MSG_ERROR([expected an absolute directory name for --with-radacctdir: $withval])
 299     ;;
 300   esac ]
 301 )
 302 AC_SUBST(radacctdir)
 303 AC_MSG_RESULT($radacctdir)
 304
 305 dnl #
 306 dnl #  extra argument: --with-raddbdir
 307 dnl #
 308 raddbdir='${sysconfdir}/raddb'
 309 AC_MSG_CHECKING(raddbdir)
 310 AC_ARG_WITH(raddbdir,
 311 [  --with-raddbdir=DIR     directory for config files [SYSCONFDIR/raddb] ],
 312 [ case "$withval" in
 313   no)
 314     AC_MSG_ERROR([Need raddbdir])
 315     ;;
 316   yes)
 317     ;;
 318   [[\\/$]]* | ?:[[\\/]]* )
 319     raddbdir="$withval"
 320     ;;
 321   *)
 322     AC_MSG_ERROR([expected an absolute directory name for --with-raddbdir: $withval])
 323     ;;
 324   esac ]
 325 )
 326 AC_SUBST(raddbdir)
 327 AC_MSG_RESULT($raddbdir)
 328
 329 dnl #
 330 dnl #  extra argument: --with-dictdir
 331 dnl #
 332 dictdir='${datarootdir}/freeradius'
 333 AC_MSG_CHECKING(dictdir)
 334 AC_ARG_WITH(dictdir,
 335 [  --with-dictdir=DIR      directory for dictionary files [DATAROOTDIR/freeradius] ],
 336 [ case "$withval" in
 337   no)
 338     AC_MSG_ERROR([Need dictdir])
 339     ;;
 340   yes)
 341     ;;
 342   [[\\/$]]* | ?:[[\\/]]* )
 343     dictdir="$withval"
 344     ;;
 345   *)
 346     AC_MSG_ERROR([expected an absolute directory name for --with-dictdir: $withval])
 347     ;;
 348   esac ]
 349 )
 350 AC_SUBST(dictdir)
 351 AC_MSG_RESULT($dictdir)
 352
 353 modconfdir='${raddbdir}/mods-config'
 354 AC_SUBST(modconfdir)
 355
 356 dnl #
 357 dnl #  extra argument: --with-ascend-binary
 358 dnl #
 359 WITH_ASCEND_BINARY=yes
 360 AC_ARG_WITH(ascend-binary,
 361 [  --with-ascend-binary    include support for Ascend binary filter attributes (default=yes)],
 362 [ case "$withval" in
 363   yes)
 364     ;;
 365   *)
 366     WITH_ASCEND_BINARY=no
 367   esac ]
 368 )
 369 if test "x$WITH_ASCEND_BINARY" = "xyes"; then
 370   AC_DEFINE(WITH_ASCEND_BINARY, [1], [include support for Ascend binary filter attributes])
 371 fi
 372
 373 dnl #
 374 dnl #  extra argument: --with-threads
 375 dnl #
 376 WITH_THREADS=yes
 377 AC_ARG_WITH(threads,
 378 [  --with-threads          use threads, if available.  (default=yes) ],
 379 [ case "$withval" in
 380   yes)
 381     ;;
 382   *)
 383     WITH_THREADS=no
 384   esac ]
 385 )
 386
 387 dnl #
 388 dnl #  extra argument: --with-tcp
 389 dnl #
 390 WITH_TCP=yes
 391 AC_ARG_WITH(tcp,
 392 [  --with-tcp              compile in TCP support. (default=yes)],
 393 [ case "$withval" in
 394   yes)
 395     ;;
 396   *)
 397     WITH_TCP=no
 398   esac ]
 399 )
 400 if test "x$WITH_TCP" = "xyes"; then
 401   AC_DEFINE(WITH_TCP, [1], [define if you want TCP support (For RADSec et al)])
 402 fi
 403
 404 dnl #
 405 dnl #  extra argument: --with-vmps
 406 dnl #
 407 WITH_VMPS=yes
 408 AC_ARG_WITH(vmps,
 409 [  --with-vmps             compile in VMPS support. (default=yes)],
 410 [ case "$withval" in
 411   yes)
 412     ;;
 413   *)
 414     WITH_VMPS=no
 415   esac ]
 416 )
 417 if test "x$WITH_VMPS" = "xyes"; then
 418   AC_DEFINE(WITH_VMPS, [1], [define if you want VMPS support])
 419 fi
 420
 421 dnl #
 422 dnl #  extra argument: --with-dhcp
 423 dnl #
 424 WITH_DHCP=yes
 425 AC_ARG_WITH(dhcp,
 426 [  --with-dhcp             compile in DHCP support. (default=yes)],
 427 [ case "$withval" in
 428   yes)
 429     ;;
 430   *)
 431     WITH_DHCP=no
 432   esac ]
 433 )
 434 if test "x$WITH_DHCP" = "xyes"; then
 435   AC_DEFINE(WITH_DHCP, [1], [define if you want DHCP support])
 436 fi
 437
 438 dnl #
 439 dnl #  Allow the user to specify a list of modules to be linked
 440 dnl #  statically to the server.
 441 dnl #
 442 STATIC_MODULES=
 443 AC_ARG_WITH(static_modules,
 444 [  --with-static-modules=QUOTED-MODULE-LIST],[
 445   for i in $withval; do
 446     STATIC_MODULES="$STATIC_MODULES -dlpreopen ../modules/rlm_$i/rlm_$i.la"
 447   done
 448 ])
 449
 450 USE_SHARED_LIBS=yes
 451 AC_ARG_WITH(shared-libs,
 452 [AS_HELP_STRING([--with-shared-libs ],
 453 [build dynamic libraries and link against them. (default=yes)])],
 454 [ case "$withval" in
 455   no)
 456     USE_SHARED_LIBS=no
 457     ;;
 458   *)
 459   esac
 460 ])
 461
 462 MODULES=
 463 AC_ARG_WITH(modules,
 464 [  --with-modules=QUOTED-MODULE-LIST],[
 465  for i in $withval; do
 466    MODULES="$MODULES $i"
 467  done
 468 ])
 469
 470 dnl #
 471 dnl #  extra argument: --with-experimental-modules
 472 dnl #
 473 EXPERIMENTAL=
 474 AC_ARG_WITH(experimental-modules,
 475 [AS_HELP_STRING([--with-experimental-modules],
 476 [use experimental and unstable modules. (default=no, unless --enable-developer=yes)])],
 477 [ case "$withval" in
 478   yes)
 479     EXPERIMENTAL=yes
 480     ;;
 481   no)
 482     EXPERIMENTAL=no
 483     ;;
 484   *)
 485   esac ]
 486 )
 487
 488 dnl #
 489 dnl #  extra argument: --with-udpfromto
 490 dnl #
 491 WITH_UDPFROMTO=yes
 492 AC_ARG_WITH(udpfromto,
 493 [  --with-udpfromto        compile in UDPFROMTO support. (default=yes)],
 494 [ case "$withval" in
 495   yes)
 496     WITH_UDPFROMTO=yes
 497     ;;
 498   *)
 499     WITH_UDPFROMTO=no
 500   esac ]
 501 )
 502
 503 if test "x$WITH_UDPFROMTO" = "xyes"; then
 504   AC_DEFINE(WITH_UDPFROMTO, [], [define if you want udpfromto])
 505 fi
 506
 507 dnl #
 508 dnl #  These next two arguments don't actually do anything.  They're
 509 dnl #  place holders so that the top-level configure script can tell
 510 dnl #  the user how to configure lower-level modules
 511 dnl #
 512
 513 dnl #
 514 dnl #  extra argument: --with-rlm-FOO-lib-dir
 515 dnl #
 516 AC_ARG_WITH(rlm-FOO-lib-dir,
 517 [AS_HELP_STRING([--with-rlm-FOO-lib-dir=DIR],
 518 [directory in which to look for library files used by module FOO])],
 519 [ case "$withval" in
 520   *)
 521     ;;
 522   esac ]
 523 )
 524
 525 dnl #
 526 dnl #  extra argument: --with-rlm-FOO-include-dir
 527 dnl #
 528 AC_ARG_WITH(rlm-FOO-include-dir,
 529 [AS_HELP_STRING([--with-rlm-FOO-include-dir=DIR],
 530 [directory in which to look for include files used by module FOO])],
 531 [ case "$withval" in
 532   *)
 533     ;;
 534   esac ]
 535 )
 536
 537 dnl #
 538 dnl #  extra argument: --with-openssl
 539 dnl #
 540 WITH_OPENSSL=yes
 541 AC_ARG_WITH(openssl,
 542 [  --with-openssl          use OpenSSL. (default=yes)],
 543 [ case "$withval" in
 544   no)
 545     WITH_OPENSSL=no
 546     ;;
 547   *)
 548     WITH_OPENSSL=yes
 549     ;;
 550   esac ]
 551 )
 552
 553 dnl #
 554 dnl #  extra argument: --with-openssl-lib-dir=dir
 555 dnl #
 556 openssl_lib_dir=
 557 AC_ARG_WITH(openssl-lib-dir,
 558 [AS_HELP_STRING([--with-openssl-lib-dir=DIR],
 559 [directory to look for OpenSSL library files])],
 560 [ case "$withval" in
 561   *) openssl_lib_dir="$withval"
 562     ;;
 563   esac ]
 564 )
 565
 566 dnl #
 567 dnl #  extra argument: --with-openssl-includes=dir
 568 dnl #
 569 openssl_include_dir=
 570 AC_ARG_WITH(openssl-include-dir,
 571 [AS_HELP_STRING([--with-openssl-include-dir=DIR],
 572 [directory to look for OpenSSL include files])],
 573 [ case "$withval" in
 574   *) openssl_include_dir="$withval"
 575     ;;
 576   esac ]
 577 )
 578
 579 dnl #############################################################
 580 dnl #
 581 dnl #  1. Checks for programs
 582 dnl #
 583 dnl #############################################################
 584
 585 CHECKRAD=checkrad
 586 AC_PATH_PROG(PERL, perl, /usr/local/bin/perl)
 587 if test "x$ac_cv_path_PERL" = "x"; then
 588   AC_MSG_WARN([perl not found - Simultaneous-Use and checkrad may not work])
 589 fi
 590 AC_PATH_PROG(SNMPGET, snmpget)
 591 if test "x$ac_cv_path_SNMPGET" = "x"; then
 592   AC_MSG_WARN([snmpget not found - Simultaneous-Use and checkrad may not work])
 593 fi
 594
 595 AC_PATH_PROG(SNMPWALK, snmpwalk)
 596 if test "x$ac_cv_path_SNMPWALK" = "x"; then
 597   AC_MSG_WARN([snmpwalk not found - Simultaneous-Use and checkrad may not work])
 598 fi
 599
 600 AC_PATH_PROG(RUSERS, rusers, /usr/bin/rusers)
 601
 602 dnl #
 603 dnl #  FIXME This is truly gross.
 604 dnl #
 605 missing_dir=`cd $ac_aux_dir && pwd`
 606 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
 607 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
 608 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
 609
 610 AC_PATH_PROG(LOCATE,locate)
 611 AC_PATH_PROG(DIRNAME,dirname)
 612 AC_PATH_PROG(GREP,grep)
 613
 614 dnl #############################################################
 615 dnl #
 616 dnl #  2. Checks for libraries
 617 dnl #
 618 dnl #############################################################
 619
 620 dnl Check for talloc
 621 dnl extra argument: --with-talloc-lib-dir=DIR
 622 talloc_lib_dir=
 623 AC_ARG_WITH(talloc-lib-dir,
 624   [AS_HELP_STRING([--with-talloc-lib-dir=DIR],
 625   [directory in which to look for talloc library files])],
 626   [case "$withval" in
 627     no)
 628       AC_MSG_ERROR([Need talloc-lib-dir])
 629       ;;
 630     yes)
 631       ;;
 632     *)
 633       talloc_lib_dir="$withval"
 634       ;;
 635   esac])
 636
 637 dnl extra argument: --with-talloc-include-dir=DIR
 638 talloc_include_dir=
 639 AC_ARG_WITH(talloc-include-dir,
 640   [AS_HELP_STRING([--with-talloc-include-dir=DIR],
 641   [directory in which to look for talloc include files])],
 642   [case "$withval" in
 643     no)
 644       AC_MSG_ERROR([Need talloc-include-dir])
 645       ;;
 646     yes)
 647       ;;
 648     *)
 649       talloc_include_dir="$withval"
 650       ;;
 651   esac])
 652
 653 smart_try_dir="$talloc_lib_dir"
 654 FR_SMART_CHECK_LIB(talloc, _talloc)
 655 if test "x$ac_cv_lib_talloc__talloc" != "xyes"; then
 656   AC_MSG_WARN([talloc library not found. Use --with-talloc-lib-dir=<path>.])
 657   AC_MSG_ERROR([FreeRADIUS requires libtalloc])
 658 fi
 659
 660 TALLOC_LIBS="${smart_lib}"
 661 TALLOC_LDFLAGS="${smart_ldflags}"
 662 AC_SUBST(TALLOC_LIBS)
 663 AC_SUBST(TALLOC_LDFLAGS)
 664 LIBS="$old_LIBS"
 665
 666 dnl #
 667 dnl #  If using pthreads, check for -lpthread (posix) or -lc_r (*BSD)
 668 dnl #
 669 old_CFLAGS=$CFLAGS
 670 if test "x$WITH_THREADS" = "xyes"; then
 671   if test $ac_cv_prog_suncc = "yes"; then
 672     CFLAGS="$CFLAGS -mt"
 673   fi
 674
 675   AC_CHECK_HEADERS(pthread.h, [],
 676     [
 677       WITH_THREADS="no"
 678       fail=[pthread.h]
 679     ])
 680
 681   dnl #
 682   dnl #  pthread stuff is usually in -lpthread
 683   dnl #  or in -lc_r, on *BSD
 684   dnl #
 685   dnl #  On Some systems, we need extra pre-processor flags, to get them to
 686   dnl #  to do the threading properly.
 687   dnl #
 688   AC_CHECK_LIB(pthread, pthread_create,
 689     [
 690       CFLAGS="$CFLAGS -D_REENTRANT -D_POSIX_PTHREAD_SEMANTICS"
 691       LIBS="-lpthread $LIBS"
 692     ],
 693     [
 694       dnl #
 695       dnl # -pthread is not a typo, it's a GCC option which sets additional flags required
 696       dnl # for multithreading with the pthreads library.
 697       dnl #
 698       AC_CHECK_LIB(c_r, pthread_create,
 699         [ CFLAGS="$CFLAGS -pthread -D_THREAD_SAFE" ],
 700         [
 701           WITH_THREADS="no"
 702           fail=[-lpthread]
 703         ]
 704       )
 705     ]
 706   )
 707
 708   if test "x$WITH_THREADS" != "xyes"; then
 709     AC_MSG_WARN([silently not building with thread support.])
 710     AC_MSG_WARN([FAILURE: thread support requires: $fail.])
 711   else
 712     AC_DEFINE(WITH_THREADS, [1], [define if you want thread support])
 713   fi
 714 fi
 715
 716 dnl #
 717 dnl #  If we have NO pthread libraries, remove any knowledge of threads.
 718 dnl #
 719 if test "x$WITH_THREADS" != "xyes"; then
 720   CFLAGS=$old_CFLAGS
 721   ac_cv_header_pthread_h="no"
 722   WITH_THREADS=no
 723 else
 724   dnl #
 725   dnl #  We need sem_init() and friends, as they're the friendliest
 726   dnl #  semaphore functions for threading.
 727   dnl #
 728   dnl #  HP/UX requires linking with librt, too, to get the sem_* symbols.
 729   dnl #  Some systems have them in -lsem
 730   dnl #  Solaris has them in -lposix4
 731   dnl #  NetBSD has them in -lsemaphore
 732   dnl #
 733
 734   AC_SEARCH_LIBS(sem_init, pthread sem posix4 rt semaphore,
 735     [],
 736     [AC_MSG_ERROR([[-lsem not found.  You may want to download it from ftp://ftp.to.gd-es.com/pub/BSDI/libsem.tar.bz2 or ftp://ftp.freeradius.org/pub/radius/contrib/libsem.tar.gz]])]
 737   )
 738 fi
 739
 740 dnl #
 741 dnl #  Check if we need -lsocket
 742 dnl #
 743 AC_CHECK_LIB(dl, dlopen)
 744
 745 dnl #
 746 dnl #  Check if we need -lsocket
 747 dnl #
 748 AC_CHECK_LIB(socket, getsockname)
 749
 750 dnl #
 751 dnl #  Check for -lresolv
 752 dnl #  This library may be needed later.
 753 dnl #
 754 AC_CHECK_LIB(resolv, inet_aton)
 755
 756 dnl #
 757 dnl #  Check if we need -lnsl. Usually if we want to
 758 dnl #  link against -lsocket we need to include -lnsl as well.
 759 dnl #
 760 AC_CHECK_LIB(nsl, inet_ntoa)
 761 AC_CHECK_LIB(ws2_32, htonl)
 762
 763 dnl #
 764 dnl #  Check the pcap library for the RADIUS sniffer.
 765 dnl #
 766 dnl extra argument: --with-pcap-lib-dir=DIR
 767 pcap_lib_dir=
 768 AC_ARG_WITH(pcap-lib-dir,
 769   [AS_HELP_STRING([--with-pcap-lib-dir=DIR],
 770   [directory in which to look for pcap library files])],
 771   [case "$withval" in
 772     no)
 773       AC_MSG_ERROR([Need pcap-lib-dir])
 774       ;;
 775     yes)
 776       ;;
 777     *)
 778       pcap_lib_dir="$withval"
 779       ;;
 780   esac])
 781
 782 dnl extra argument: --with-pcap-include-dir=DIR
 783 pcap_include_dir=
 784 AC_ARG_WITH(pcap-include-dir,
 785   [AS_HELP_STRING([--with-pcap-include-dir=DIR],
 786   [directory in which to look for pcap include files])],
 787   [case "$withval" in
 788     no)
 789       AC_MSG_ERROR([Need pcap-include-dir])
 790       ;;
 791     yes)
 792       ;;
 793     *)
 794       pcap_include_dir="$withval"
 795       ;;
 796   esac])
 797
 798 smart_try_dir="$pcap_lib_dir"
 799 FR_SMART_CHECK_LIB(pcap, pcap_open_live)
 800 if test "x$ac_cv_lib_pcap_pcap_open_live" != "xyes"; then
 801   AC_MSG_WARN([pcap library not found, silently disabling the RADIUS sniffer, and ARP listener.  Use --with-pcap-lib-dir=<path>.])
 802 else
 803   AC_DEFINE(HAVE_LIBPCAP, 1,
 804     [Define to 1 if you have the `pcap' library (-lpcap).]
 805   )
 806
 807   AC_CHECK_FUNCS(\
 808     pcap_fopen_offline \
 809     pcap_dump_fopen \
 810     pcap_create \
 811     pcap_activate
 812   )
 813
 814   PCAP_LIBS="${smart_lib}"
 815   PCAP_LDFLAGS="${smart_ldflags}"
 816 fi
 817 dnl Set by FR_SMART_CHECK_LIB
 818 LIBS="${old_LIBS}"
 819
 820 dnl Check for collectdclient
 821 dnl extra argument: --with-collectdclient-lib-dir=DIR
 822 collectdclient_lib_dir=
 823 AC_ARG_WITH(collectdclient-lib-dir,
 824   [AS_HELP_STRING([--with-collectdclient-lib-dir=DIR],
 825   [directory in which to look for collectdclient library files])],
 826   [case "$withval" in
 827     no)
 828       AC_MSG_ERROR([Need collectdclient-lib-dir])
 829       ;;
 830     yes)
 831       ;;
 832     *)
 833       collectdclient_lib_dir="$withval"
 834       ;;
 835   esac])
 836
 837 dnl extra argument: --with-collectdclient-include-dir=DIR
 838 collectdclient_include_dir=
 839 AC_ARG_WITH(collectdclient-include-dir,
 840   [AS_HELP_STRING([--with-collectdclient-include-dir=DIR],
 841   [directory in which to look for collectdclient include files])],
 842   [case "$withval" in
 843     no)
 844       AC_MSG_ERROR([Need collectdclient-include-dir])
 845       ;;
 846     yes)
 847       ;;
 848     *)
 849       collectdclient_include_dir="$withval"
 850       ;;
 851   esac])
 852
 853 smart_try_dir="$collectdclient_lib_dir"
 854 FR_SMART_CHECK_LIB(collectdclient, lcc_connect)
 855 if test "x$ac_cv_lib_collectdclient_lcc_connect" != "xyes"; then
 856   AC_MSG_WARN([collectdclient library not found. Use --with-collectdclient-lib-dir=<path>.])
 857 else
 858   COLLECTDC_LIBS="${smart_lib}"
 859   COLLECTDC_LDFLAGS="${smart_ldflags}"
 860 fi
 861 dnl Set by FR_SMART_CHECKLIB
 862 LIBS="${old_LIBS}"
 863
 864 VL_LIB_READLINE
 865
 866 dnl #############################################################
 867 dnl #
 868 dnl #  3. Checks for header files
 869 dnl #
 870 dnl #############################################################
 871
 872 dnl #
 873 dnl # Check for talloc header files
 874 dnl #
 875 smart_try_dir="$talloc_include_dir"
 876 FR_SMART_CHECK_INCLUDE([talloc.h])
 877 if test "x$ac_cv_header_talloc_h" != "xyes"; then
 878   AC_MSG_WARN([talloc headers not found. Use --with-talloc-include-dir=<path>.])
 879   AC_MSG_ERROR([FreeRADIUS requires libtalloc])
 880 fi
 881
 882 dnl #
 883 dnl #  Interix requires us to set -D_ALL_SOURCE, otherwise
 884 dnl #  getopt will be #included, but won't link.  <sigh>
 885 dnl #
 886 case "$host" in
 887   *-interix*)
 888     CFLAGS="$CFLAGS -D_ALL_SOURCE"
 889     ;;
 890   *-darwin*)
 891     CFLAGS="$CFLAGS -DDARWIN"
 892     LIBS="-framework DirectoryService $LIBS"
 893     ;;
 894 esac
 895
 896 AC_HEADER_DIRENT
 897 AC_HEADER_STDC
 898 AC_HEADER_TIME
 899 AC_HEADER_SYS_WAIT
 900
 901 AC_CHECK_HEADERS( \
 902   dlfcn.h \
 903   unistd.h \
 904   crypt.h \
 905   errno.h \
 906   resource.h \
 907   sys/resource.h \
 908   getopt.h \
 909   malloc.h \
 910   utmp.h \
 911   utmpx.h \
 912   signal.h \
 913   sys/select.h \
 914   syslog.h \
 915   inttypes.h \
 916   stdint.h \
 917   stdio.h \
 918   netdb.h \
 919   semaphore.h \
 920   arpa/inet.h \
 921   netinet/in.h \
 922   sys/types.h \
 923   sys/socket.h \
 924   winsock.h \
 925   utime.h \
 926   sys/time.h \
 927   sys/wait.h \
 928   sys/security.h \
 929   fcntl.h \
 930   sys/fcntl.h \
 931   sys/prctl.h \
 932   sys/un.h \
 933   glob.h \
 934   prot.h \
 935   pwd.h \
 936   grp.h \
 937   stddef.h \
 938   fnmatch.h \
 939   sia.h \
 940   siad.h \
 941   features.h \
 942   limits.h
 943 )
 944
 945 dnl #
 946 dnl #  FreeBSD requires sys/socket.h before net/if.h
 947 dnl #
 948 AC_CHECK_HEADERS(net/if.h, [], [],
 949   [
 950     #ifdef HAVE_SYS_SOCKET_H
 951     #  include <sys/socket.h>
 952     #endif
 953   ]
 954 )
 955
 956 dnl #
 957 dnl #  other checks which require headers
 958 dnl #
 959 if test "x$ac_cv_header_sys_security_h" = "xyes" && test "x$ac_cv_header_prot_h" = "xyes"
 960 then
 961   AC_DEFINE(OSFC2, [], [define if you have OSFC2 authentication])
 962 fi
 963
 964 if test "x$ac_cv_header_sia_h" = "xyes" && test "x$ac_cv_header_siad_h" = "xyes"
 965 then
 966   AC_DEFINE(OSFSIA, [], [define if you have OSFSIA authentication])
 967 fi
 968
 969 dnl #
 970 dnl #  Were we told to use OpenSSL, if we were and we find an error, call AC_MSG_FAILURE and exit
 971 dnl #
 972 if test "x$WITH_OPENSSL" = xyes; then
 973   OLD_LIBS="$LIBS"
 974
 975   dnl #
 976   dnl #  Apparently OpenSSL will attempt to build with kerberos if we don't pass this?!
 977   dnl #
 978   CFLAGS="$CFLAGS -DOPENSSL_NO_KRB5"
 979
 980   dnl #
 981   dnl #  Check we can link to libcrypto and libssl
 982   dnl #
 983   smart_try_dir="$openssl_lib_dir"
 984   FR_SMART_CHECK_LIB(crypto, DH_new)
 985   if test "x$ac_cv_lib_crypto_DH_new" = "xyes"; then
 986     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
 987     OPENSSL_LIBS="$smart_lib"
 988     OPENSSL_LDFLAGS="$smart_ldflags"
 989
 990     FR_SMART_CHECK_LIB(ssl, SSL_new)
 991     if test "x$ac_cv_lib_ssl_SSL_new" != "xyes"; then
 992       AC_MSG_FAILURE([failed linking to libssl. Use --with-openssl-lib-dir=<path>, or --with-openssl=no (builds without OpenSSL)])
 993     else
 994       AC_DEFINE(HAVE_LIBSSL, 1, [Define to 1 if you have the `ssl' library (-lssl).])
 995       OPENSSL_LIBS="$OPENSSL_LIBS $smart_lib"
 996
 997       if test "$OPENSSL_LDFLAGS" != "$smart_ldflags"; then
 998         AC_MSG_FAILURE(["inconsistent LDFLAGS between -lssl '$smart_ldflags' and -lcrypto '$OPENSSL_LDFLAGS'"])
 999       fi
1000     fi
1001   else
1002     AC_MSG_FAILURE([failed linking to libcrypto. Use --with-openssl-lib-dir=<path>, or --with-openssl=no (builds without OpenSSL)])
1003   fi
1004
1005   smart_try_dir="$openssl_include_dir"
1006   FR_SMART_CHECK_INCLUDE(openssl/ssl.h)
1007   if test "x$ac_cv_header_openssl_ssl_h" = "xyes"; then
1008     AC_DEFINE(HAVE_OPENSSL_SSL_H, 1, [Define to 1 if you have the <openssl/ssl.h> header file.])
1009
1010     AC_CHECK_HEADERS( \
1011       openssl/crypto.h \
1012       openssl/err.h \
1013       openssl/evp.h \
1014       openssl/md5.h \
1015       openssl/md4.h \
1016       openssl/sha.h \
1017       openssl/ocsp.h \
1018       openssl/engine.h,
1019       [],
1020       [
1021         AC_MSG_FAILURE([failed locating OpenSSL headers. Use --with-openssl-include-dir=<path>, or --with-openssl=no (builds without OpenSSL)])
1022       ]
1023     )
1024
1025     AC_MSG_CHECKING([for OpenSSL version >= 0.9.7])
1026     AC_EGREP_CPP(yes,
1027       [#include <openssl/crypto.h>
1028        #if (OPENSSL_VERSION_NUMBER >= 0x00907000L)
1029        yes
1030        #endif
1031       ],
1032       [
1033         AC_MSG_RESULT(yes)
1034       ],
1035       [
1036         AC_MSG_RESULT(no)
1037         AC_MSG_FAILURE([OpenSSL version too old])
1038       ]
1039     )
1040
1041     dnl #
1042     dnl #  CPPFLAGS are passed to the compiler first, so we use
1043     dnl #  them to ensure things like --sysroot don't override the
1044     dnl #  library location we discovered previously.
1045     dnl #
1046     old_CPPFLAGS="$CPPFLAGS"
1047     CPPFLAGS="$OPENSSL_LDFLAGS $CPPFLAGS"
1048
1049     dnl #
1050     dnl #  Now check that the header versions match the library
1051     dnl #
1052     AC_MSG_CHECKING([OpenSSL library and header version consistency])
1053     AC_RUN_IFELSE(
1054       [AC_LANG_PROGRAM(
1055         [[
1056           #include <stdio.h>
1057           #include <openssl/opensslv.h>
1058           #include <openssl/crypto.h>
1059         ]],
1060         [[
1061           printf("library: %lx header: %lx... ", (unsigned long) SSLeay(), (unsigned long) OPENSSL_VERSION_NUMBER);
1062           if (SSLeay() == OPENSSL_VERSION_NUMBER) {
1063             return 0;
1064           } else {
1065             return 1;
1066           }
1067         ]]
1068       )],
1069       [
1070         AC_MSG_RESULT(yes)
1071       ],
1072       [
1073         AC_MSG_RESULT(no)
1074         AC_MSG_FAILURE([OpenSSL library version does not match header version])
1075       ]
1076     )
1077     CPPFLAGS="$old_CPPFLAGS"
1078   fi
1079
1080   LIBS="$OLD_LIBS"
1081   AC_SUBST(OPENSSL_LIBS)
1082   AC_SUBST(OPENSSL_LDFLAGS)
1083   export OPENSSL_LIBS OPENSSL_LDFLAGS
1084 fi
1085
1086 dnl #
1087 dnl #  Check the pcap includes for the RADIUS sniffer.
1088 dnl #
1089 if test "x$PCAP_LIBS" = x; then
1090   AC_MSG_NOTICE([skipping test for pcap.h.])
1091 else
1092   dnl #
1093   dnl # Check for pcap header files
1094   dnl #
1095   smart_try_dir="$pcap_include_dir"
1096   FR_SMART_CHECK_INCLUDE([pcap.h])
1097   if test "x$ac_cv_header_pcap_h" == "xyes"; then
1098     AC_DEFINE(HAVE_PCAP_H, 1, [Define to 1 if you have the <pcap.h> header file.])
1099     AC_SUBST(PCAP_LIBS)
1100     AC_SUBST(PCAP_LDFLAGS)
1101   else
1102     AC_MSG_WARN([pcap headers not found, silently disabling the RADIUS sniffer, and ARP listener. Use --with-pcap-include-dir=<path>.])
1103   fi
1104 fi
1105
1106 dnl Check for collectd-client
1107 if test "x$COLLECTDC_LIBS" = x; then
1108   AC_MSG_NOTICE([skipping test for collectd/client.h.])
1109 else
1110   dnl #
1111   dnl # Check for collectd-client header files
1112   dnl #
1113   smart_try_dir="$collectdclient_include_dir"
1114   FR_SMART_CHECK_INCLUDE([collectd/client.h])
1115   if test "x$ac_cv_header_collectd_client_h" == "xyes"; then
1116     AC_DEFINE(HAVE_COLLECTDC_H, 1, [Define to 1 if you have the `collectdclient' library (-lcollectdclient).])
1117     AC_SUBST(COLLECTDC_LIBS)
1118     AC_SUBST(COLLECTDC_LDFLAGS)
1119   else
1120     AC_MSG_WARN([collectdclient headers not found. Use --with-collectdclient-include-dir=<path>.])
1121   fi
1122 fi
1123
1124 dnl #############################################################
1125 dnl #
1126 dnl #  4. Checks for typedefs
1127 dnl #
1128 dnl #############################################################
1129
1130 dnl #
1131 dnl #  Ensure that these are defined
1132 dnl #
1133 AC_TYPE_OFF_T
1134 AC_TYPE_PID_T
1135 AC_TYPE_SIZE_T
1136 AC_TYPE_UID_T
1137
1138 dnl #
1139 dnl #  Check for socklen_t
1140 dnl #
1141 FR_CHECK_TYPE_INCLUDE(
1142   [
1143     #ifdef HAVE_SYS_TYPES_H
1144     #  include <sys/types.h>
1145     #endif
1146
1147     #ifdef HAVE_SYS_SOCKET_H
1148     #  include <sys/socket.h>
1149     #endif
1150   ],
1151   socklen_t, int, [socklen_t is generally 'int' on systems which don't use it]
1152 )
1153
1154 dnl #
1155 dnl #  Check for uint8_t
1156 dnl #
1157 FR_CHECK_TYPE_INCLUDE(
1158   [
1159     #ifdef HAVE_INTTYPES_H
1160     #  include <inttypes.h>
1161     #endif
1162
1163     #ifdef HAVE_STDINT_H
1164     #  include <stdint.h>
1165     #endif
1166   ],
1167   uint8_t, unsigned char, [uint8_t should be the canonical 'octet' for network traffic]
1168 )
1169
1170 dnl #
1171 dnl #  Check for uint16_t
1172 dnl #
1173 FR_CHECK_TYPE_INCLUDE(
1174   [
1175     #ifdef HAVE_INTTYPES_H
1176     #  include <inttypes.h>
1177     #endif
1178
1179     #ifdef HAVE_STDINT_H
1180     #  include <stdint.h>
1181     #endif
1182   ],
1183   uint16_t, unsigned short, [uint16_t should be the canonical '2 octets' for network traffic]
1184 )
1185
1186 dnl #
1187 dnl #  Check for uint32_t
1188 dnl #
1189 FR_CHECK_TYPE_INCLUDE(
1190   [
1191     #ifdef HAVE_INTTYPES_H
1192     #  include <inttypes.h>
1193     #endif
1194
1195     #ifdef HAVE_STDINT_H
1196     #  include <stdint.h>
1197     #endif
1198   ],
1199   uint32_t, unsigned int, [uint32_t should be the canonical 'network integer']
1200 )
1201
1202 dnl #
1203 dnl #  Check for uint64_t
1204 dnl #
1205 FR_CHECK_TYPE_INCLUDE(
1206   [
1207     #ifdef HAVE_INTTYPES_H
1208     #  include <inttypes.h>
1209     #endif
1210
1211     #ifdef HAVE_STDINT_H
1212     #  include <stdint.h>
1213     #endif
1214   ],
1215   uint64_t, unsigned long long, [uint64_t is required for larger counters]
1216 )
1217
1218 dnl #
1219 dnl #  Check for __uint128_t (compiler builtin)
1220 dnl #
1221 AC_CHECK_TYPE(__uint128_t, AC_DEFINE(HAVE___UINT128_T, 1, [compiler specific 128 bit unsigned integer]), [], [])
1222
1223 dnl #
1224 dnl #  Check for uint128_t (fictitious future data type)
1225 dnl #
1226 AC_CHECK_TYPE(uint128_t, AC_DEFINE(HAVE_UINT128_T, 1, [128 bit unsigned integer]), [],
1227   [
1228     #ifdef HAVE_INTTYPES_H
1229     #  include <inttypes.h>
1230     #endif
1231
1232     #ifdef HAVE_STDINT_H
1233     #  include <stdint.h>
1234     #endif
1235   ]
1236 )
1237
1238 AC_CHECK_TYPE(struct in6_addr, AC_DEFINE(HAVE_STRUCT_IN6_ADDR, 1, [IPv6 address structure]), [],
1239   [
1240     #ifdef HAVE_NETINET_IN_H
1241     #  include <netinet/in.h>
1242     #endif
1243   ]
1244 )
1245
1246 AC_CHECK_TYPE(struct sockaddr_storage, AC_DEFINE(HAVE_STRUCT_SOCKADDR_STORAGE, 1, [Generic socket addresses]), [],
1247   [
1248     #ifdef HAVE_NETINET_IN_H
1249     #  include <netinet/in.h>
1250     #endif
1251
1252     #ifdef HAVE_SYS_SOCKET_H
1253     #  include <sys/socket.h>
1254     #endif
1255 ])
1256
1257 AC_CHECK_TYPE(struct sockaddr_in6, AC_DEFINE(HAVE_STRUCT_SOCKADDR_IN6, 1, [IPv6 socket addresses]), [],
1258   [
1259     #ifdef HAVE_NETINET_IN_H
1260     #  include <netinet/in.h>
1261     #endif
1262 ])
1263
1264 AC_CHECK_TYPE(struct addrinfo, AC_DEFINE(HAVE_STRUCT_ADDRINFO, 1, [Generic DNS lookups]), [],
1265   [
1266     #ifdef HAVE_SYS_TYPES_H
1267     #  include <sys/types.h>
1268     #endif
1269
1270     #ifdef HAVE_SYS_SOCKET_H
1271     #  include <sys/socket.h>
1272     #endif
1273
1274     #ifdef HAVE_NETDB_H
1275     #  include <netdb.h>
1276     #endif
1277   ]
1278 )
1279
1280 dnl #
1281 dnl #  Check for sig_t
1282 dnl #
1283 dnl #  FR_CHECK_TYPE_INCLUDE doesn't work for callbacks as it doesn't produce typedefs
1284 dnl #
1285 AC_MSG_CHECKING([if sig_t is defined])
1286 AC_LINK_IFELSE(
1287   [AC_LANG_PROGRAM(
1288     [[
1289       #ifdef HAVE_SIGNAL_H
1290       #  include <signal.h>
1291       #endif
1292     ]],
1293     [[
1294       sig_t func;
1295       return 0;
1296     ]]
1297   )],
1298   [
1299       AC_MSG_RESULT(yes)
1300       AC_DEFINE(HAVE_SIG_T, 1, [Define if the type sig_t is defined by signal.h])
1301   ],
1302   [
1303       AC_MSG_RESULT(no)
1304   ]
1305 )
1306
1307 dnl #############################################################
1308 dnl #
1309 dnl #  5. Checks for structures and functions
1310 dnl #
1311 dnl #############################################################
1312 AC_CHECK_FUNCS( \
1313   getopt_long \
1314   fcntl \
1315   strsignal \
1316   sigaction \
1317   sigprocmask \
1318   pthread_sigmask \
1319   snprintf \
1320   vsnprintf \
1321   setsid \
1322   strncasecmp \
1323   strcasecmp \
1324   localtime_r \
1325   ctime_r \
1326   gmtime_r \
1327   strsep \
1328   inet_aton \
1329   inet_pton \
1330   inet_ntop \
1331   mallopt \
1332   setlinebuf \
1333   setvbuf \
1334   getusershell \
1335   initgroups \
1336   getaddrinfo \
1337   getnameinfo \
1338   closefrom \
1339   gettimeofday \
1340   getpeereid \
1341   setuid \
1342   setresuid \
1343   getresuid \
1344   strlcat \
1345   strlcpy
1346 )
1347
1348 AC_TYPE_SIGNAL
1349
1350 dnl #
1351 dnl #  Check if we have utmpx.h
1352 dnl #  if so, check if struct utmpx has entry ut_xtime
1353 dnl #  if not, set it to define ut_xtime == ut_tv.tv_sec
1354 dnl #
1355 if test "x$ac_cv_header_utmpx_h" = "xyes"; then
1356  FR_CHECK_STRUCT_HAS_MEMBER([#include <utmpx.h>], [struct utmpx], ut_xtime)
1357  if test "x$ac_cv_type_struct_utmpx_has_ut_xtime" = "x"; then
1358    AC_DEFINE(ut_xtime, ut_tv.tv_sec, [define to something if you don't have ut_xtime in struct utmpx])
1359  fi
1360 fi
1361
1362 dnl #
1363 dnl #  struct ip_pktinfo
1364 dnl #
1365 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in_pktinfo], ipi_addr)
1366 if test "x$ac_cv_type_struct_in_pktinfo_has_ipi_addr" = "xyes"; then
1367   AC_DEFINE(HAVE_IP_PKTINFO, [], [define if you have IP_PKTINFO (Linux)])
1368 fi
1369
1370 dnl #
1371 dnl #  struct in6_pktinfo
1372 dnl #
1373 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in6_pktinfo], ipi6_addr)
1374 if test "x$ac_cv_type_struct_in6_pktinfo_has_ipi6_addr" = "xyes"; then
1375   AC_DEFINE(HAVE_IN6_PKTINFO, [], [define if you have IN6_PKTINFO (Linux)])
1376 fi
1377
1378 dnl #
1379 dnl #  Check for htonll and htonlll
1380 dnl #
1381 AC_MSG_CHECKING([if htonll is defined])
1382 AC_LINK_IFELSE(
1383   [AC_LANG_PROGRAM(
1384     [[
1385       #include <sys/types.h>
1386       #include <netinet/in.h>
1387     ]],
1388     [[
1389       return htonll(0);
1390     ]]
1391   )],
1392   [
1393       AC_MSG_RESULT(yes)
1394       AC_DEFINE(HAVE_HTONLL, 1, [Define if the function (or macro) htonll exists.])
1395   ],
1396   [
1397       AC_MSG_RESULT(no)
1398   ]
1399 )
1400
1401 AC_MSG_CHECKING([if htonlll is defined])
1402 AC_LINK_IFELSE(
1403   [AC_LANG_PROGRAM(
1404     [[
1405       #include <sys/types.h>
1406       #include <netinet/in.h>
1407     ]],
1408     [[
1409       return htonlll(0);
1410     ]]
1411   )],
1412   [
1413       AC_MSG_RESULT(yes)
1414       AC_DEFINE(HAVE_HTONLLL, 1, [Define if the function (or macro) htonlll exists.])
1415   ],
1416   [
1417       AC_MSG_RESULT(no)
1418   ]
1419 )
1420
1421 dnl #############################################################
1422 dnl #
1423 dnl #  6. Checks for compiler characteristics
1424 dnl #
1425 dnl #############################################################
1426
1427 dnl #
1428 dnl #  Ensure that these are defined
1429 dnl #
1430 AC_C_CONST
1431
1432 dnl #
1433 dnl #  See if this is OS/2
1434 dnl #
1435 AC_MSG_CHECKING([type of OS])
1436 OS=`uname -s`
1437 AC_MSG_RESULT($OS)
1438 if test "$OS" = "OS/2"; then
1439   LIBPREFIX=
1440 else
1441   LIBPREFIX=lib
1442 fi
1443 AC_SUBST(LIBPREFIX)
1444
1445 if test "x$developer" = "xyes"; then
1446   AC_MSG_NOTICE([Setting additional developer CFLAGS])
1447
1448   dnl #
1449   dnl #  Tell the compiler to parse doxygen documentation and verify it against function and variable declarations
1450   dnl #
1451   AX_CC_WDOCUMENTATION_FLAG
1452   if test "x$ax_cv_cc_wdocumentation_flag" = "xyes"; then
1453     devflags="-Wdocumentation"
1454   fi
1455
1456   if test "x$GCC" = "xyes"; then
1457     devflags="$devflags -Wshadow -Wpointer-arith -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -W -Wredundant-decls -Wundef -Wformat-y2k -Wno-format-extra-args -Wno-format-zero-length -Wno-cast-align -Wformat-nonliteral -Wformat-security -Wformat=2 -DWITH_VERIFY_PTR=1"
1458     INSTALLSTRIP=""
1459   fi
1460
1461   AC_MSG_NOTICE([Developer CFLAGS are "$devflags"])
1462
1463   CFLAGS="$CFLAGS $devflags"
1464   dnl #
1465   dnl #  Enable experimental modules (we want to know if code changes breaks one of them)
1466   dnl #
1467   if test "x$EXPERIMENTAL" != "xno"; then
1468     AC_MSG_NOTICE([is developer build, enabling experimental modules implicitly, disable with --without-experimental-modules])
1469     EXPERIMENTAL=yes
1470   fi
1471 else
1472   devflags=""
1473   CFLAGS="$CFLAGS -DNDEBUG"
1474   INSTALLSTRIP=""
1475 fi
1476
1477 dnl #
1478 dnl #  May of been set outside of this configure script
1479 dnl #
1480 AC_MSG_CHECKING([if building with -DNDEBUG])
1481 if echo "$CFLAGS" | grep '\-DNDEBUG' > /dev/null; then
1482   AC_MSG_RESULT([yes])
1483   AC_DEFINE([WITH_NDEBUG], [1], [define if the server was built with -DNDEBUG])
1484 else
1485   AC_MSG_RESULT([no])
1486 fi
1487
1488 export EXPERIMENTAL
1489
1490 dnl #
1491 dnl #  append the current git hash onto the version string
1492 dnl #
1493 if test -d $srcdir/.git -a "x$GIT" = "xyes"; then
1494   RADIUSD_VERSION_COMMIT=`git log --pretty=format:'%h' -n 1`
1495   AC_DEFINE_UNQUOTED([RADIUSD_VERSION_COMMIT],[${RADIUSD_VERSION_COMMIT}],[Commit HEAD at time of configuring])
1496 fi
1497
1498 dnl #
1499 dnl #  check for some compiler features
1500 dnl #
1501 FR_TLS
1502 FR_HAVE_BUILTIN_CHOOSE_EXPR
1503 FR_HAVE_BUILTIN_TYPES_COMPATIBLE_P
1504 FR_HAVE_BUILTIN_BSWAP_64
1505
1506 dnl #############################################################
1507 dnl #
1508 dnl #  7. Checks for library functions
1509 dnl #
1510 dnl #############################################################
1511
1512 dnl #
1513 dnl # Check for talloc_set_memlimit
1514 dnl # This was only included in version 2.0.8
1515 dnl #
1516 AC_CHECK_LIB(talloc, talloc_set_memlimit,
1517   [
1518     AC_DEFINE(HAVE_TALLOC_SET_MEMLIMIT, 1, [Define to 1 if you have the function talloc_set_memlimit.])
1519   ]
1520 )
1521
1522 dnl #
1523 dnl # Check for libcrypt
1524 dnl # We use crypt(3) which may be in libc, or in libcrypt (eg FreeBSD)
1525 dnl #
1526 AC_CHECK_LIB(crypt, crypt,
1527   CRYPTLIB="-lcrypt"
1528 )
1529
1530 if test "$CRYPTLIB" != ""; then
1531   AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function])
1532 else
1533   AC_CHECK_FUNC(crypt, AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function]))
1534 fi
1535
1536 dnl Check for libcipher
1537 AC_CHECK_LIB(cipher, setkey,
1538    CRYPTLIB="${CRYPTLIB} -lcipher"
1539 )
1540 AC_SUBST(CRYPTLIB)
1541
1542 dnl #
1543 dnl #  Check for libexecinfo support, on some systems this is built into libc
1544 dnl #  on others it's a separate library.
1545 dnl #
1546 dnl extra argument: --with-execinfo-lib-dir
1547 execinfo_lib_dir=
1548 AC_ARG_WITH(execinfo-lib-dir,
1549 [AS_HELP_STRING([--with-execinfo-lib-dir=DIR],
1550 [directory in which to look for execinfo library files])],
1551 [ case "$withval" in
1552     no)
1553         AC_MSG_ERROR([Need execinfo-lib-dir])
1554         ;;
1555     yes)
1556         ;;
1557     *)
1558         execinfo_lib_dir="$withval"
1559         ;;
1560   esac ]
1561 )
1562
1563 dnl extra argument: --with-execinfo-include-dir
1564 execinfo_include_dir=
1565 AC_ARG_WITH(execinfo-include-dir,
1566 [AS_HELP_STRING([--with-execinfo-include-dir=DIR],
1567 [directory in which to look for execinfo include files])],
1568 [ case "$withval" in
1569     no)
1570         AC_MSG_ERROR([Need execinfo-include-dir])
1571         ;;
1572     yes)
1573         ;;
1574     *)
1575         execinfo_include_dir="$withval"
1576         ;;
1577   esac ]
1578 )
1579
1580 dnl #
1581 dnl #  Look for execinfo.h and symbols
1582 dnl #
1583 smart_try_dir=$execinfo_include_dir
1584 FR_SMART_CHECK_INCLUDE(execinfo.h)
1585 if test "x$ac_cv_header_execinfo_h" = "xyes"; then
1586   smart_try_dir=$execinfo_lib_dir
1587   FR_SMART_CHECK_LIB(execinfo, backtrace_symbols)
1588   if test "x$ac_cv_lib_execinfo_backtrace_symbols" != "xyes"; then
1589     dnl # Might be provided as part of libc
1590     AC_MSG_CHECKING([if execinfo provided as part of libc])
1591     AC_TRY_LINK(
1592       [
1593         #include <execinfo.h>
1594       ],
1595       [
1596         void *sym[1];
1597         backtrace_symbols(&sym, sizeof(sym)) ],
1598       [
1599         AC_MSG_RESULT(yes)
1600         ac_cv_lib_execinfo_backtrace_symbols="yes"
1601       ],
1602       [
1603         AC_MSG_RESULT(no)
1604       ]
1605     )
1606   fi
1607
1608   if test "x$ac_cv_lib_execinfo_backtrace_symbols" = "xyes"; then
1609     AC_DEFINE(HAVE_EXECINFO, [1], [define this if we have <execinfo.h> and symbols])
1610   fi
1611 fi
1612
1613 dnl #
1614 dnl #  Check for regular expression support, if were using PCRE it MUST be included
1615 dnl #  before all others, else we seem to still pickup the posix symbols for regcomp
1616 dnl #  and regexec, which results in crashes as soon as we call any posix regex
1617 dnl #  functions.
1618 dnl #
1619 dnl extra argument: --with-pcre-lib-dir
1620 pcre_lib_dir=
1621 AC_ARG_WITH(pcre-lib-dir,
1622 [AS_HELP_STRING([--with-pcre-lib-dir=DIR],
1623 [directory in which to look for pcre library files])],
1624 [ case "$withval" in
1625     no)
1626         AC_MSG_ERROR(Need pcre-lib-dir)
1627         ;;
1628     yes)
1629         ;;
1630     *)
1631         pcre_lib_dir="$withval"
1632         ;;
1633   esac ]
1634 )
1635
1636 dnl extra argument: --with-pcre-include--dir
1637 pcre_include_dir=
1638 AC_ARG_WITH(pcre-include-dir,
1639 [AS_HELP_STRING([--with-pcre-include-dir=DIR],
1640 [directory in which to look for pcre include files])],
1641 [ case "$withval" in
1642     no)
1643         AC_MSG_ERROR(Need pcre-include-dir)
1644         ;;
1645     yes)
1646         ;;
1647     *)
1648         pcre_include_dir="$withval"
1649         ;;
1650   esac ]
1651 )
1652
1653 REGEX=no
1654 REGEX_EXTENDED=no
1655 REGEX_PCRE=no
1656
1657 dnl #
1658 dnl #  First look for PCRE
1659 dnl #
1660 smart_try_dir=$pcre_include_dir
1661 FR_SMART_CHECK_INCLUDE(pcreposix.h)
1662 if test "x$ac_cv_header_pcreposix_h" = "xyes"; then
1663   AC_DEFINE(HAVE_REGEX_H, [1], [define if we have any regex])
1664   AC_DEFINE(HAVE_PCREPOSIX_H, [1], [define this if we have the <pcreposix.h> header file])
1665   REGEX=yes
1666   REGEX_EXTENDED=yes
1667   REGEX_PCRE=yes
1668   LIBS="-lpcre -lpcreposix $LIBS"
1669
1670 dnl #
1671 dnl #  Then fallback to POSIX regular expressions
1672 dnl #
1673 else
1674   smart_try_dir=
1675   FR_SMART_CHECK_INCLUDE(regex.h)
1676   if test "x$ac_cv_header_regex_h" = "xyes"; then
1677     AC_DEFINE(HAVE_REGEX_H, [1], [define if we have any regex])
1678     REGEX=yes
1679     AC_EGREP_CPP(yes,
1680       [
1681         #include <regex.h>
1682         #ifdef REG_EXTENDED
1683         yes
1684         #endif
1685        ],
1686     [AC_DEFINE(HAVE_REG_EXTENDED, [1], [define this if we have REG_EXTENDED (from <regex.h>)]) REGEX_EXTENDED=yes]
1687     )
1688 dnl #
1689 dnl # Fixme, this is needed for mingw builds, but not available on some Linux systems
1690 dnl # despite the presence of regex.h
1691 dnl #
1692 dnl # LIBS="$LIBS -lregex"
1693   fi
1694 fi
1695
1696 AC_SUBST(REGEX)
1697 AC_SUBST(REGEX_PCRE)
1698 AC_SUBST(REGEX_EXTENDED)
1699
1700 dnl #
1701 dnl #  Check the style of gethostbyaddr, in order of preference
1702 dnl #  GNU (_r eight args)
1703 dnl #
1704 AC_DEFINE(GNUSTYLE, [1], [GNU-Style get*byaddr_r])
1705
1706 dnl #
1707 dnl #  SYSV (_r six args)
1708 dnl #
1709 AC_DEFINE(SYSVSTYLE, [2], [SYSV-Style get*byaddr_r])
1710
1711 dnl #
1712 dnl #  BSD (three args, may not be thread safe)
1713 dnl #
1714 AC_DEFINE(BSDSTYLE, [3], [BSD-Style get*byaddr_r])
1715
1716 dnl #
1717 dnl #  Tru64 has BSD version, but it is thread safe
1718 dnl #  http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1739____.HTM
1719 dnl #  We need #stdio.h to define NULL on FreeBSD (at least)
1720 dnl #
1721 gethostbyaddrrstyle=""
1722 AC_MSG_CHECKING([gethostbyaddr_r() syntax])
1723 case "$host" in
1724   *-freebsd*)
1725     dnl #
1726     dnl #  With FreeBSD, check if there's a prototype for gethostbyaddr_r.
1727     dnl #  Some versions (FreeBSD 5.1?) have a symbol but no prototype - so we
1728     dnl #  override this test to BSDSTYLE. FreeBSD 6.2 and up have proper GNU
1729     dnl #  style support.
1730     dnl #
1731     AC_CHECK_DECLS([gethostbyaddr_r], [],
1732       [
1733         AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE,
1734           [style of gethostbyaddr_r functions ])
1735         gethostbyaddrrstyle=BSD
1736         AC_MSG_WARN([FreeBSD overridden to BSD-style])
1737       ],
1738       [
1739         #ifdef HAVE_NETDB_H
1740         #include <netdb.h>
1741         #endif
1742       ])
1743     ;;
1744 esac
1745
1746 if test "x$gethostbyaddrrstyle" = "x"; then
1747   AC_TRY_LINK(
1748     [
1749       #include <stdio.h>
1750       #include <netdb.h>
1751     ],
1752     [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL, NULL) ],
1753     [
1754       AC_DEFINE(GETHOSTBYADDRRSTYLE, GNUSTYLE, [style of gethostbyaddr_r functions ])
1755       gethostbyaddrrstyle=GNU
1756     ]
1757   )
1758 fi
1759
1760 if test "x$gethostbyaddrrstyle" = "x"; then
1761   AC_TRY_LINK(
1762     [
1763       #include <stdio.h>
1764       #include <netdb.h>
1765     ],
1766     [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL) ] ,
1767     [
1768       AC_DEFINE(GETHOSTBYADDRRSTYLE, SYSVSTYLE, [style of gethostbyaddr_r functions ])
1769       gethostbyaddrrstyle=SYSV
1770     ]
1771   )
1772 fi
1773
1774
1775 if test "x$gethostbyaddrrstyle" = "x"; then
1776   AC_TRY_LINK(
1777     [
1778       #include <stdio.h>
1779       #include <netdb.h>
1780     ],
1781     [ gethostbyaddr(NULL, 0, 0)  ],
1782     [
1783       AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE, [style of gethostbyaddr_r functions ])
1784       gethostbyaddrrstyle=BSD
1785     ]
1786   )
1787 fi
1788
1789 if test "x$gethostbyaddrrstyle" = "x"; then
1790   AC_MSG_RESULT([none!  It must not exist, here.])
1791 else
1792   AC_MSG_RESULT([${gethostbyaddrrstyle}-style])
1793 fi
1794
1795 if test "x$gethostbyaddrrstyle" = "xBSD"; then
1796   AC_MSG_WARN([ ****** BSD-style gethostbyaddr might NOT be thread-safe! ****** ])
1797 fi
1798
1799 dnl #
1800 dnl #  Check the style of gethostbyname, in order of preference
1801 dnl #  GNU (_r seven args)
1802 dnl #  SYSV (_r five args)
1803 dnl #  BSD (two args, may not be thread safe)
1804 dnl #  Tru64 has BSD version, but it _is_ thread safe
1805 dnl #    http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1946____.HTM
1806 dnl #  We need #stdio.h to define NULL on FreeBSD (at least)
1807 dnl #
1808 gethostbynamerstyle=""
1809 AC_MSG_CHECKING([gethostbyname_r() syntax])
1810 AC_TRY_LINK(
1811   [
1812     #include <stdio.h>
1813     #include <netdb.h>
1814   ],
1815   [ gethostbyname_r(NULL, NULL, NULL, 0, NULL, NULL) ],
1816   [
1817     AC_DEFINE(GETHOSTBYNAMERSTYLE, GNUSTYLE, [style of gethostbyname_r functions ])
1818     gethostbynamerstyle=GNU
1819   ]
1820 )
1821
1822 if test "x$gethostbynamerstyle" = "x"; then
1823   AC_TRY_LINK(
1824     [
1825       #include <stdio.h>
1826       #include <netdb.h>
1827     ],
1828     [ gethostbyname_r(NULL, NULL, NULL, 0, NULL) ] ,
1829     [
1830       AC_DEFINE(GETHOSTBYNAMERSTYLE, SYSVSTYLE, [style of gethostbyname_r functions ])
1831       gethostbynamerstyle=SYSV
1832     ]
1833   )
1834 fi
1835
1836 if test "x$gethostbynamerstyle" = "x"; then
1837   AC_TRY_LINK(
1838     [
1839       #include <stdio.h>
1840       #include <netdb.h>
1841     ],
1842     [ gethostbyname(NULL) ],
1843     [
1844       AC_DEFINE(GETHOSTBYNAMERSTYLE, BSDSTYLE, [style of gethostbyname_r functions ])
1845       gethostbynamerstyle=BSD
1846     ]
1847   )
1848 fi
1849
1850 if test "x$gethostbynamerstyle" = "x"; then
1851   AC_MSG_RESULT([none!  It must not exist, here.])
1852 else
1853   AC_MSG_RESULT([${gethostbynamerstyle}-style])
1854 fi
1855
1856 if test "x$gethostbynamerstyle" = "xBSD"; then
1857   AC_MSG_WARN([ ****** BSD-style gethostbyname might NOT be thread-safe! ****** ])
1858 fi
1859
1860 dnl #
1861 dnl #  Check for non-posix solaris ctime_r (extra buflen int arg)
1862 dnl #
1863 AC_DEFINE(POSIXSTYLE, [1], [Posix-Style ctime_r])
1864 AC_DEFINE(SOLARISSTYLE, [2], [Solaris-Style ctime_r])
1865 ctimerstyle=""
1866 AC_MSG_CHECKING([ctime_r() syntax])
1867 AC_TRY_LINK(
1868   [
1869     #include <time.h>
1870   ],
1871   [ ctime_r(NULL, NULL, 0) ],
1872   [
1873     AC_DEFINE(CTIMERSTYLE, SOLARISSTYLE, [style of ctime_r function])
1874     ctimerstyle="SOLARIS"
1875   ]
1876 )
1877
1878 if test "x$ctimerstyle" = "x"; then
1879   AC_TRY_LINK(
1880     [
1881       #include <time.h>
1882     ],
1883     [ ctime_r(NULL, NULL) ],
1884     [
1885       AC_DEFINE(CTIMERSTYLE, POSIXSTYLE, [style of ctime_r function])
1886       ctimerstyle="POSIX"
1887     ]
1888   )
1889 fi
1890
1891 if test "x$ctimerstyle" = "x"; then
1892     AC_MSG_RESULT([none!  It must not exist, here.])
1893 else
1894     AC_MSG_RESULT([${ctimerstyle}-style])
1895 fi
1896
1897 AC_SUBST(HOSTINFO, $host)
1898
1899 dnl #############################################################
1900 dnl #
1901 dnl #  8. Checks for system services
1902 dnl #
1903 dnl #############################################################
1904
1905 dnl #
1906 dnl #  Figure out where libtool is located,
1907 dnl #
1908 top_builddir=`pwd`
1909 export top_builddir
1910 AC_MSG_RESULT([top_builddir=$top_builddir])
1911 dnl #  AC_SUBST(top_builddir)
1912
1913 dnl #
1914 dnl #  import libtool stuff
1915 dnl #
1916 dnl #############################################################
1917 dnl #
1918 dnl #  Configure in any module directories.
1919 dnl #
1920 dnl #############################################################
1921
1922 dnl ############################################################
1923 dnl #  Remove any conflicting definitions if autoconf.h
1924 dnl #  is being included by a module.
1925 dnl #############################################################
1926 AH_BOTTOM([#include <freeradius-devel/automask.h>])
1927
1928 dnl ############################################################
1929 dnl #  make modules by list
1930 dnl #############################################################
1931 if test "x$EXPERIMENTAL" = "xyes"; then
1932   for foo in `ls -1 "${srcdir}"/src/modules | grep rlm_`; do
1933     MODULES="$MODULES $foo"
1934   done
1935 else
1936    dnl #
1937    dnl #  make ONLY the stable modules
1938    dnl #
1939    for foo in `cat "${srcdir}"/src/modules/stable`; do
1940       MODULES="$MODULES $foo"
1941    done
1942 fi
1943
1944 dnl ############################################################
1945 dnl #  Add autoconf subdirs, based on the module list we
1946 dnl #  previously created.
1947 dnl #############################################################
1948 mysubdirs=""
1949 for bar in $MODULES; do
1950   if test -f "${srcdir}"/src/modules/$bar/configure; then
1951     mysubdirs="$mysubdirs src/modules/$bar"
1952   fi
1953 done
1954
1955 dnl #
1956 dnl #  Don't change the variable name here.  Autoconf goes bonkers
1957 dnl #  if you do.
1958 dnl #
1959 AC_CONFIG_SUBDIRS($mysubdirs)
1960 AC_SUBST(MODULES)
1961
1962 dnl #############################################################
1963 dnl #
1964 dnl #  Add -Werror last, so it doesn't interfere with autoconf's
1965 dnl #  test programs.
1966 dnl #
1967 dnl #############################################################
1968 if test "x$werror" == "xyes"; then
1969   CFLAGS="-Werror $CFLAGS"
1970 fi
1971
1972 dnl #############################################################
1973 dnl #
1974 dnl #  And finally, output the results.
1975 dnl #
1976 dnl #############################################################
1977 AC_CONFIG_COMMANDS([stamp-h], [echo timestamp > src/include/stamp-h])
1978 AC_CONFIG_COMMANDS([build-radpaths-h], [(cd ./src/include && /bin/sh ./build-radpaths-h)])
1979 AC_CONFIG_COMMANDS([main-chmod], [(cd ./src/main && chmod +x checkrad radlast radtest)])
1980 AC_CONFIG_COMMANDS([scripts-chmod], [(cd ./scripts && chmod +x rc.radiusd cron/radiusd.cron.daily cron/radiusd.cron.monthly cryptpasswd)])
1981
1982 dnl #
1983 dnl #  Substitute whatever libraries we found to be necessary
1984 dnl #
1985 AC_SUBST(LIBS)
1986 AC_SUBST(INSTALLSTRIP)
1987
1988 AC_SUBST(USE_SHARED_LIBS)
1989 USE_STATIC_LIBS="yes"
1990 AC_SUBST(USE_STATIC_LIBS)
1991 AC_SUBST(STATIC_MODULES)
1992
1993 AC_OUTPUT(\
1994   ./Make.inc \
1995   ./src/include/build-radpaths-h \
1996   ./src/main/radsniff.mk \
1997   ./src/main/checkrad \
1998   ./src/main/radlast \
1999   ./src/main/radtest \
2000   ./scripts/rc.radiusd \
2001   ./scripts/cron/radiusd.cron.daily \
2002   ./scripts/cron/radiusd.cron.monthly \
2003   ./scripts/cryptpasswd \
2004   ./raddb/radrelay.conf \
2005   ./raddb/radiusd.conf
2006 )