configure.ac

   1 dnl #############################################################
   2 dnl #
   3 dnl #  For information about autoconf, see:
   4 dnl #
   5 dnl #  http://www.gnu.org/software/autoconf/
   6 dnl #
   7 dnl #  The recommended order is:
   8 dnl #
   9 dnl #  AC_INIT(file)
  10 dnl #  0. checks for compiler, libtool, and command line options
  11 dnl #  1. checks for programs
  12 dnl #  2. checks for libraries
  13 dnl #  3. checks for header files
  14 dnl #  4. checks for typedefs
  15 dnl #  5. checks for structures and functions
  16 dnl #  6. checks for compiler characteristics
  17 dnl #  7. checks for library functions
  18 dnl #  8. checks for system services
  19 dnl #  AC_OUTPUT([file...])
  20 dnl #
  21 dnl #############################################################
  22
  23 AC_PREREQ([2.59])
  24 export CFLAGS LIBS LDFLAGS CPPFLAGS
  25
  26 AC_INIT([freeradius],[$]Id[$],[http://bugs.freeradius.org],,[http://www.freeradius.org])
  27 AC_CONFIG_SRCDIR([src/main/radiusd.c])
  28 AC_CONFIG_HEADER([src/include/autoconf.h])
  29 m4_include([m4/ax_cc.m4])
  30
  31 dnl #############################################################
  32 dnl #
  33 dnl #  Custom hackery to discover version at configure time
  34 dnl #
  35 dnl #############################################################
  36
  37 RADIUSD_MAJOR_VERSION=`cat VERSION | sed 's/\..*//'`
  38 RADIUSD_MINOR_VERSION=`cat VERSION | sed 's/^[[^\.]]*\.//' | sed 's/\..*$//'`
  39 RADIUSD_INCRM_VERSION=`cat VERSION | sed 's/^.*\..*\.//' | sed 's/[[\.-]].*$//'`
  40
  41 RADIUSD_VERSION=`echo | awk -v major="$RADIUSD_MAJOR_VERSION" \
  42 -v minor="$RADIUSD_MINOR_VERSION" \
  43 -v incrm="$RADIUSD_INCRM_VERSION" \
  44 '{ printf "%02i%02i%02i", major, minor, incrm }'`
  45
  46 dnl #
  47 dnl #  Still useful for custom builds
  48 dnl #
  49 RADIUSD_VERSION_STRING=`cat VERSION`
  50
  51 dnl #
  52 dnl #  Add definitions to Make.inc as it's used by various build targets
  53 dnl #
  54 AC_SUBST([RADIUSD_VERSION_STRING])
  55
  56 dnl #
  57 dnl #  Add definitions to autoconf.h, so that the headers that we install
  58 dnl #  contain the version number of the server.
  59 dnl #
  60 AC_DEFINE_UNQUOTED([RADIUSD_VERSION], [${RADIUSD_VERSION}], [Version integer in format <ma><ma><mi><mi><in><in>])
  61 AC_DEFINE_UNQUOTED([RADIUSD_VERSION_STRING], ["${RADIUSD_VERSION_STRING}"], [Raw version string from VERSION file])
  62
  63 dnl #############################################################
  64 dnl #
  65 dnl #  Override some of the default autoconf variables such as
  66 dnl #  CFLAGS if were building in developer mode
  67 dnl #
  68 dnl #############################################################
  69
  70 dnl #
  71 dnl #  Enable developer features like debugging symbols.
  72 dnl #  These checks must be done before expanding the AC_PROG_CC
  73 dnl #  and AC_PROG_CXX macros.
  74 dnl #
  75 AC_ARG_ENABLE(developer,
  76 [  --enable-developer      enables features of interest to developers.],
  77 [ case "$enableval" in
  78   no)
  79     developer=no
  80     ;;
  81   *)
  82     developer=yes
  83   esac ]
  84 )
  85
  86 dnl #
  87 dnl #  Turn on the developer flag when taken from a git checkout (not a release)
  88 dnl #
  89 if test -d $srcdir/.git; then
  90   if test "x$developer" != "xno"; then
  91     AC_MSG_NOTICE([found .git directory, enabling developer build implicitly, disable with --disable-developer])
  92     developer="yes"
  93   fi
  94 fi
  95
  96 dnl #
  97 dnl #  Autoconf sets -O2 and -g by default, but this is a PITA for debugging
  98 dnl #  so we remove the defaults if were building in developer mode, and set
  99 dnl #  -g3 so nice things like macro values are included. Other arguments are
 100 dnl #  added later when we know what compiler were using.
 101 dnl #
 102 if test "x$developer" = "xyes"; then
 103   : ${CFLAGS=-g3}
 104 fi
 105
 106 dnl #############################################################
 107 dnl #
 108 dnl #  0. Checks for compiler, libtool, and command line options.
 109 dnl #
 110 dnl #############################################################
 111
 112 dnl #
 113 dnl #  Get system information
 114 dnl #
 115 AC_CANONICAL_SYSTEM
 116
 117 dnl #
 118 dnl #  Check for GNU cc
 119 dnl #
 120 AC_PROG_CC
 121 AC_PROG_CXX
 122
 123 dnl #
 124 dnl #  check for AIX, to allow us to use some BSD functions
 125 dnl #  must be before macros that call the compiler.
 126 dnl #
 127 AC_AIX
 128
 129 AC_PROG_GCC_TRADITIONAL
 130 AC_PROG_CC_SUNPRO
 131 AC_PROG_RANLIB
 132
 133 dnl #
 134 dnl #  Definitive check for whether the compiler is clang
 135 dnl #
 136 AX_CC_IS_CLANG
 137 if test "x$ax_cv_cc_clang" = "xyes"; then
 138   AC_SUBST(clang_path, "$CC")
 139 else
 140   AC_SUBST(clang_path, "")
 141 fi
 142
 143
 144 dnl #
 145 dnl #  Set Default CFLAGS for GCC compatible compilers
 146 dnl #
 147 if test "x$GCC" = "xyes"; then
 148   CFLAGS="$CFLAGS -Wall -std=c99 -D_GNU_SOURCE"
 149 fi
 150
 151 dnl #
 152 dnl #  -Qunused-arguments means the compiler won't complain about unsupported arguments
 153 dnl #
 154 AX_CC_QUNUSED_ARGUMENTS_FLAG
 155 if test "x$ax_cv_cc_qunused_arguments_flag" = "xyes"; then
 156   CFLAGS="$CFLAGS -Qunused-arguments"
 157   LDFLAGS="$LDFLAGS -Qunused-arguments"
 158 fi
 159
 160 dnl #
 161 dnl #  Compile in large (2G+) file support.
 162 dnl #
 163 AC_SYS_LARGEFILE
 164
 165 dnl #
 166 dnl #  check for system bytesex
 167 dnl #  AC_DEFINES WORDS_BIGENDIAN
 168 dnl #
 169 AC_C_BIGENDIAN(
 170   [AC_DEFINE(BIG_ENDIAN, 1, [Define if your processor stores words with the most significant byte first])],
 171   [AC_DEFINE(LITTLE_ENDIAN, 1, [Define if your processor stores words with the least significant byte first])]
 172 )
 173
 174 dnl #
 175 dnl #  Find GNU Make.
 176 dnl #
 177 AC_CHECK_PROG(GMAKE, gmake, yes, no)
 178 if test $GMAKE = no; then
 179   AC_PATH_PROG(MAKE, make, /usr/local/bin/make)
 180 else
 181   AC_PATH_PROG(MAKE, gmake, /usr/local/gnu/bin/make)
 182 fi
 183 makever=`$ac_cv_path_MAKE --version 2>&1 | grep "GNU Make"`
 184 if test -z "$makever"; then
 185   AC_MSG_ERROR([GNU Make is not installed.  Please download and install it from ftp://prep.ai.mit.edu/pub/gnu/make/ before continuing.])
 186 fi
 187
 188 dnl #
 189 dnl #  autoconf explicitly sets MAKEFLAGS and MFLAGS to '' even though we
 190 dnl #  didn't tell it to, so we have to use FR_MAKEFLAGS.
 191 dnl #
 192 dnl #  determine the number of cores available and set the number of build
 193 dnl #  processes appropriately.
 194 dnl #
 195 AX_SYSTEM_CORES
 196
 197 dnl #  Temporarily disabled because test and installation targets do not
 198 dnl #  have dependencies set up correctly for multiple build processes.
 199 dnl if test "x$ax_cv_system_cores" != "x"; then
 200 dnl  : ${FR_MAKEFLAGS=-j$ax_cv_system_cores}
 201 dnl fi
 202 AC_SUBST(FR_MAKEFLAGS)
 203
 204 dnl #
 205 dnl #  See if we have Git.
 206 dnl #
 207 AC_CHECK_PROG(GIT, git, yes, no)
 208
 209 dnl Put this in later, when all distributed modules use autoconf.
 210 dnl AC_ARG_WITH(disablemodulefoo,
 211 dnl [  --without-rlm_foo         Disables module compilation.  Module list:]
 212 dnl esyscmd([find src/modules -type d -name rlm_\* -print |\
 213 dnl   sed -e 's%src/modules/.*/% (sub)- %; s%.*/%- %' |\
 214 dnl   awk '{print "                            "$0}']))
 215
 216 AC_ARG_ENABLE(strict-dependencies,
 217 [  --enable-strict-dependencies  fail configure on lack of module dependancy.])
 218
 219 AC_ARG_ENABLE(werror,
 220 [  --enable-werror         causes the build to fail if any warnings are generated.],
 221 [ case "$enableval" in
 222     no)
 223       werror=no
 224     ;;
 225     *)
 226       werror=yes
 227   esac ]
 228 )
 229
 230 dnl #
 231 dnl #  extra argument: --with-docdir
 232 dnl #
 233 docdir='${datadir}/doc/freeradius'
 234 AC_MSG_CHECKING([docdir])
 235 AC_ARG_WITH(docdir,
 236 [  --with-docdir=DIR       directory for documentation [DATADIR/doc/freeradius] ],
 237 [ case "$withval" in
 238   no)
 239     docdir=no
 240     ;;
 241   yes)
 242     ;;
 243   [[\\/$]]* | ?:[[\\/]]* )
 244     docdir="$withval"
 245     ;;
 246   *)
 247     AC_MSG_ERROR([expected an absolute directory name for --with-docdir: $withval])
 248     ;;
 249   esac ]
 250 )
 251 AC_SUBST(docdir)
 252 AC_MSG_RESULT($docdir)
 253 if test "x$docdir" = xno; then
 254   AC_MSG_WARN([Documentation files will NOT be installed.])
 255 fi
 256
 257 dnl #
 258 dnl #  extra argument: --with-logdir
 259 dnl #
 260 logdir='${localstatedir}/log/radius'
 261 AC_MSG_CHECKING(logdir)
 262 AC_ARG_WITH(logdir,
 263 [  --with-logdir=DIR       directory for logfiles [LOCALSTATEDIR/log/radius] ],
 264 [ case "$withval" in
 265   no)
 266     AC_MSG_ERROR([Need logdir])
 267     ;;
 268   yes)
 269     ;;
 270   [[\\/$]]* | ?:[[\\/]]* )
 271     logdir="$withval"
 272     ;;
 273   *)
 274     AC_MSG_ERROR([expected an absolute directory name for --with-logdir: $withval])
 275     ;;
 276   esac ]
 277 )
 278 AC_SUBST(logdir)
 279 AC_MSG_RESULT($logdir)
 280
 281 dnl #
 282 dnl #  extra argument: --with-radacctdir
 283 dnl #
 284 radacctdir='${logdir}/radacct'
 285 AC_MSG_CHECKING(radacctdir)
 286 AC_ARG_WITH(radacctdir,
 287 [  --with-radacctdir=DIR   directory for detail files [LOGDIR/radacct] ],
 288 [ case "$withval" in
 289   no)
 290     AC_MSG_ERROR([Need radacctdir])
 291     ;;
 292   yes)
 293     ;;
 294   [[\\/$]]* | ?:[[\\/]]* )
 295     radacctdir="$withval"
 296     ;;
 297   *)
 298     AC_MSG_ERROR([expected an absolute directory name for --with-radacctdir: $withval])
 299     ;;
 300   esac ]
 301 )
 302 AC_SUBST(radacctdir)
 303 AC_MSG_RESULT($radacctdir)
 304
 305 dnl #
 306 dnl #  extra argument: --with-raddbdir
 307 dnl #
 308 raddbdir='${sysconfdir}/raddb'
 309 AC_MSG_CHECKING(raddbdir)
 310 AC_ARG_WITH(raddbdir,
 311 [  --with-raddbdir=DIR     directory for config files [SYSCONFDIR/raddb] ],
 312 [ case "$withval" in
 313   no)
 314     AC_MSG_ERROR([Need raddbdir])
 315     ;;
 316   yes)
 317     ;;
 318   [[\\/$]]* | ?:[[\\/]]* )
 319     raddbdir="$withval"
 320     ;;
 321   *)
 322     AC_MSG_ERROR([expected an absolute directory name for --with-raddbdir: $withval])
 323     ;;
 324   esac ]
 325 )
 326 AC_SUBST(raddbdir)
 327 AC_MSG_RESULT($raddbdir)
 328
 329 dnl #
 330 dnl #  extra argument: --with-dictdir
 331 dnl #
 332 dictdir='${datarootdir}/freeradius'
 333 AC_MSG_CHECKING(dictdir)
 334 AC_ARG_WITH(dictdir,
 335 [  --with-dictdir=DIR      directory for dictionary files [DATAROOTDIR/freeradius] ],
 336 [ case "$withval" in
 337   no)
 338     AC_MSG_ERROR([Need dictdir])
 339     ;;
 340   yes)
 341     ;;
 342   [[\\/$]]* | ?:[[\\/]]* )
 343     dictdir="$withval"
 344     ;;
 345   *)
 346     AC_MSG_ERROR([expected an absolute directory name for --with-dictdir: $withval])
 347     ;;
 348   esac ]
 349 )
 350 AC_SUBST(dictdir)
 351 AC_MSG_RESULT($dictdir)
 352
 353 modconfdir='${raddbdir}/mods-config'
 354 AC_SUBST(modconfdir)
 355
 356 dnl #
 357 dnl #  extra argument: --with-ascend-binary
 358 dnl #
 359 WITH_ASCEND_BINARY=yes
 360 AC_ARG_WITH(ascend-binary,
 361 [  --with-ascend-binary    include support for Ascend binary filter attributes (default=yes)],
 362 [ case "$withval" in
 363   yes)
 364     ;;
 365   *)
 366     WITH_ASCEND_BINARY=no
 367   esac ]
 368 )
 369 if test "x$WITH_ASCEND_BINARY" = "xyes"; then
 370   AC_DEFINE(WITH_ASCEND_BINARY, [1], [include support for Ascend binary filter attributes])
 371 fi
 372
 373 dnl #
 374 dnl #  extra argument: --with-threads
 375 dnl #
 376 WITH_THREADS=yes
 377 AC_ARG_WITH(threads,
 378 [  --with-threads          use threads, if available.  (default=yes) ],
 379 [ case "$withval" in
 380   yes)
 381     ;;
 382   *)
 383     WITH_THREADS=no
 384   esac ]
 385 )
 386
 387 dnl #
 388 dnl #  extra argument: --with-tcp
 389 dnl #
 390 WITH_TCP=yes
 391 AC_ARG_WITH(tcp,
 392 [  --with-tcp              compile in TCP support. (default=yes)],
 393 [ case "$withval" in
 394   yes)
 395     ;;
 396   *)
 397     WITH_TCP=no
 398   esac ]
 399 )
 400 if test "x$WITH_TCP" = "xyes"; then
 401   AC_DEFINE(WITH_TCP, [1], [define if you want TCP support (For RADSec et al)])
 402 fi
 403
 404 dnl #
 405 dnl #  extra argument: --with-vmps
 406 dnl #
 407 WITH_VMPS=yes
 408 AC_ARG_WITH(vmps,
 409 [  --with-vmps             compile in VMPS support. (default=yes)],
 410 [ case "$withval" in
 411   yes)
 412     ;;
 413   *)
 414     WITH_VMPS=no
 415   esac ]
 416 )
 417 if test "x$WITH_VMPS" = "xyes"; then
 418   AC_DEFINE(WITH_VMPS, [1], [define if you want VMPS support])
 419 fi
 420
 421 dnl #
 422 dnl #  extra argument: --with-dhcp
 423 dnl #
 424 WITH_DHCP=yes
 425 AC_ARG_WITH(dhcp,
 426 [  --with-dhcp             compile in DHCP support. (default=yes)],
 427 [ case "$withval" in
 428   yes)
 429     ;;
 430   *)
 431     WITH_DHCP=no
 432   esac ]
 433 )
 434 if test "x$WITH_DHCP" = "xyes"; then
 435   AC_DEFINE(WITH_DHCP, [1], [define if you want DHCP support])
 436 fi
 437
 438 dnl #
 439 dnl #  Allow the user to specify a list of modules to be linked
 440 dnl #  statically to the server.
 441 dnl #
 442 STATIC_MODULES=
 443 AC_ARG_WITH(static_modules,
 444 [  --with-static-modules=QUOTED-MODULE-LIST],[
 445   for i in $withval; do
 446     STATIC_MODULES="$STATIC_MODULES -dlpreopen ../modules/rlm_$i/rlm_$i.la"
 447   done
 448 ])
 449
 450 USE_SHARED_LIBS=yes
 451 AC_ARG_WITH(shared-libs,
 452 [AS_HELP_STRING([--with-shared-libs ],
 453 [build dynamic libraries and link against them. (default=yes)])],
 454 [ case "$withval" in
 455   no)
 456     USE_SHARED_LIBS=no
 457     ;;
 458   *)
 459   esac
 460 ])
 461
 462 MODULES=
 463 AC_ARG_WITH(modules,
 464 [  --with-modules=QUOTED-MODULE-LIST],[
 465  for i in $withval; do
 466    MODULES="$MODULES $i"
 467  done
 468 ])
 469
 470 dnl #
 471 dnl #  extra argument: --with-experimental-modules
 472 dnl #
 473 EXPERIMENTAL=
 474 AC_ARG_WITH(experimental-modules,
 475 [AS_HELP_STRING([--with-experimental-modules],
 476 [use experimental and unstable modules. (default=no, unless --enable-developer=yes)])],
 477 [ case "$withval" in
 478   yes)
 479     EXPERIMENTAL=yes
 480     ;;
 481   no)
 482     EXPERIMENTAL=no
 483     ;;
 484   *)
 485   esac ]
 486 )
 487
 488 dnl #
 489 dnl #  extra argument: --with-udpfromto
 490 dnl #
 491 WITH_UDPFROMTO=yes
 492 AC_ARG_WITH(udpfromto,
 493 [  --with-udpfromto        compile in UDPFROMTO support. (default=yes)],
 494 [ case "$withval" in
 495   yes)
 496     WITH_UDPFROMTO=yes
 497     ;;
 498   *)
 499     WITH_UDPFROMTO=no
 500   esac ]
 501 )
 502
 503 if test "x$WITH_UDPFROMTO" = "xyes"; then
 504   AC_DEFINE(WITH_UDPFROMTO, [], [define if you want udpfromto])
 505 fi
 506
 507 dnl #
 508 dnl #  These next two arguments don't actually do anything.  They're
 509 dnl #  place holders so that the top-level configure script can tell
 510 dnl #  the user how to configure lower-level modules
 511 dnl #
 512
 513 dnl #
 514 dnl #  extra argument: --with-rlm-FOO-lib-dir
 515 dnl #
 516 AC_ARG_WITH(rlm-FOO-lib-dir,
 517 [AS_HELP_STRING([--with-rlm-FOO-lib-dir=DIR],
 518 [directory in which to look for library files used by module FOO])],
 519 [ case "$withval" in
 520   *)
 521     ;;
 522   esac ]
 523 )
 524
 525 dnl #
 526 dnl #  extra argument: --with-rlm-FOO-include-dir
 527 dnl #
 528 AC_ARG_WITH(rlm-FOO-include-dir,
 529 [AS_HELP_STRING([--with-rlm-FOO-include-dir=DIR],
 530 [directory in which to look for include files used by module FOO])],
 531 [ case "$withval" in
 532   *)
 533     ;;
 534   esac ]
 535 )
 536
 537 dnl #
 538 dnl #  extra argument: --with-openssl
 539 dnl #
 540 WITH_OPENSSL=yes
 541 AC_ARG_WITH(openssl,
 542 [  --with-openssl          use OpenSSL. (default=yes)],
 543 [ case "$withval" in
 544   no)
 545     WITH_OPENSSL=no
 546     ;;
 547   *)
 548     WITH_OPENSSL=yes
 549     ;;
 550   esac ]
 551 )
 552
 553 dnl #
 554 dnl #  extra argument: --with-openssl-lib-dir=dir
 555 dnl #
 556 openssl_lib_dir=
 557 AC_ARG_WITH(openssl-lib-dir,
 558 [AS_HELP_STRING([--with-openssl-lib-dir=DIR],
 559 [directory to look for OpenSSL library files])],
 560 [ case "$withval" in
 561   *) openssl_lib_dir="$withval"
 562     ;;
 563   esac ]
 564 )
 565
 566 dnl #
 567 dnl #  extra argument: --with-openssl-includes=dir
 568 dnl #
 569 openssl_include_dir=
 570 AC_ARG_WITH(openssl-include-dir,
 571 [AS_HELP_STRING([--with-openssl-include-dir=DIR],
 572 [directory to look for OpenSSL include files])],
 573 [ case "$withval" in
 574   *) openssl_include_dir="$withval"
 575     ;;
 576   esac ]
 577 )
 578
 579 dnl #############################################################
 580 dnl #
 581 dnl #  1. Checks for programs
 582 dnl #
 583 dnl #############################################################
 584
 585 CHECKRAD=checkrad
 586 AC_PATH_PROG(PERL, perl, /usr/local/bin/perl)
 587 if test "x$ac_cv_path_PERL" = "x"; then
 588   AC_MSG_WARN([perl not found - Simultaneous-Use and checkrad may not work])
 589 fi
 590 AC_PATH_PROG(SNMPGET, snmpget)
 591 if test "x$ac_cv_path_SNMPGET" = "x"; then
 592   AC_MSG_WARN([snmpget not found - Simultaneous-Use and checkrad may not work])
 593 fi
 594
 595 AC_PATH_PROG(SNMPWALK, snmpwalk)
 596 if test "x$ac_cv_path_SNMPWALK" = "x"; then
 597   AC_MSG_WARN([snmpwalk not found - Simultaneous-Use and checkrad may not work])
 598 fi
 599
 600 AC_PATH_PROG(RUSERS, rusers, /usr/bin/rusers)
 601
 602 dnl #
 603 dnl #  FIXME This is truly gross.
 604 dnl #
 605 missing_dir=`cd $ac_aux_dir && pwd`
 606 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
 607 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
 608 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
 609
 610 AC_PATH_PROG(LOCATE,locate)
 611 AC_PATH_PROG(DIRNAME,dirname)
 612 AC_PATH_PROG(GREP,grep)
 613
 614 dnl #############################################################
 615 dnl #
 616 dnl #  2. Checks for libraries
 617 dnl #
 618 dnl #############################################################
 619
 620 dnl Check for talloc
 621 dnl extra argument: --with-talloc-lib-dir=DIR
 622 talloc_lib_dir=
 623 AC_ARG_WITH(talloc-lib-dir,
 624   [AS_HELP_STRING([--with-talloc-lib-dir=DIR],
 625   [directory in which to look for talloc library files])],
 626   [case "$withval" in
 627     no)
 628       AC_MSG_ERROR([Need talloc-lib-dir])
 629       ;;
 630     yes)
 631       ;;
 632     *)
 633       talloc_lib_dir="$withval"
 634       ;;
 635   esac])
 636
 637 dnl extra argument: --with-talloc-include-dir=DIR
 638 talloc_include_dir=
 639 AC_ARG_WITH(talloc-include-dir,
 640   [AS_HELP_STRING([--with-talloc-include-dir=DIR],
 641   [directory in which to look for talloc include files])],
 642   [case "$withval" in
 643     no)
 644       AC_MSG_ERROR([Need talloc-include-dir])
 645       ;;
 646     yes)
 647       ;;
 648     *)
 649       talloc_include_dir="$withval"
 650       ;;
 651   esac])
 652
 653 smart_try_dir="$talloc_lib_dir"
 654 FR_SMART_CHECK_LIB(talloc, _talloc)
 655 if test "x$ac_cv_lib_talloc__talloc" != "xyes"; then
 656   AC_MSG_WARN([talloc library not found. Use --with-talloc-lib-dir=<path>.])
 657   AC_MSG_ERROR([FreeRADIUS requires libtalloc])
 658 fi
 659
 660 TALLOC_LIBS="${smart_lib}"
 661 TALLOC_LDFLAGS="${smart_ldflags}"
 662 AC_SUBST(TALLOC_LIBS)
 663 AC_SUBST(TALLOC_LDFLAGS)
 664 LIBS="$old_LIBS"
 665
 666 dnl #
 667 dnl #  If using pthreads, check for -lpthread (posix) or -lc_r (*BSD)
 668 dnl #
 669 old_CFLAGS=$CFLAGS
 670 if test "x$WITH_THREADS" = "xyes"; then
 671   if test $ac_cv_prog_suncc = "yes"; then
 672     CFLAGS="$CFLAGS -mt"
 673   fi
 674
 675   AC_CHECK_HEADERS(pthread.h, [],
 676     [
 677       WITH_THREADS="no"
 678       fail=[pthread.h]
 679     ])
 680
 681   dnl #
 682   dnl #  pthread stuff is usually in -lpthread
 683   dnl #  or in -lc_r, on *BSD
 684   dnl #
 685   dnl #  On Some systems, we need extra pre-processor flags, to get them to
 686   dnl #  to do the threading properly.
 687   dnl #
 688   AC_CHECK_LIB(pthread, pthread_create,
 689     [
 690       CFLAGS="$CFLAGS -D_REENTRANT -D_POSIX_PTHREAD_SEMANTICS"
 691       LIBS="-lpthread $LIBS"
 692     ],
 693     [
 694       dnl #
 695       dnl # -pthread is not a typo, it's a GCC option which sets additional flags required
 696       dnl # for multithreading with the pthreads library.
 697       dnl #
 698       AC_CHECK_LIB(c_r, pthread_create,
 699         [ CFLAGS="$CFLAGS -pthread -D_THREAD_SAFE" ],
 700         [
 701           WITH_THREADS="no"
 702           fail=[-lpthread]
 703         ]
 704       )
 705     ]
 706   )
 707
 708   if test "x$WITH_THREADS" != "xyes"; then
 709     AC_MSG_WARN([silently not building with thread support.])
 710     AC_MSG_WARN([FAILURE: thread support requires: $fail.])
 711   else
 712     AC_DEFINE(WITH_THREADS, [1], [define if you want thread support])
 713   fi
 714 fi
 715
 716 dnl #
 717 dnl #  If we have NO pthread libraries, remove any knowledge of threads.
 718 dnl #
 719 if test "x$WITH_THREADS" != "xyes"; then
 720   CFLAGS=$old_CFLAGS
 721   ac_cv_header_pthread_h="no"
 722   WITH_THREADS=no
 723 else
 724   dnl #
 725   dnl #  We need sem_init() and friends, as they're the friendliest
 726   dnl #  semaphore functions for threading.
 727   dnl #
 728   dnl #  HP/UX requires linking with librt, too, to get the sem_* symbols.
 729   dnl #  Some systems have them in -lsem
 730   dnl #  Solaris has them in -lposix4
 731   dnl #  NetBSD has them in -lsemaphore
 732   dnl #
 733
 734   AC_SEARCH_LIBS(sem_init, pthread sem posix4 rt semaphore,
 735     [],
 736     [AC_MSG_ERROR([[-lsem not found.  You may want to download it from ftp://ftp.to.gd-es.com/pub/BSDI/libsem.tar.bz2 or ftp://ftp.freeradius.org/pub/radius/contrib/libsem.tar.gz]])]
 737   )
 738 fi
 739
 740 dnl #
 741 dnl #  Check if we need -lsocket
 742 dnl #
 743 AC_CHECK_LIB(dl, dlopen)
 744
 745 dnl #
 746 dnl #  Check if we need -lsocket
 747 dnl #
 748 AC_CHECK_LIB(socket, getsockname)
 749
 750 dnl #
 751 dnl #  Check for -lresolv
 752 dnl #  This library may be needed later.
 753 dnl #
 754 AC_CHECK_LIB(resolv, inet_aton)
 755
 756 dnl #
 757 dnl #  Check if we need -lnsl. Usually if we want to
 758 dnl #  link against -lsocket we need to include -lnsl as well.
 759 dnl #
 760 AC_CHECK_LIB(nsl, inet_ntoa)
 761 AC_CHECK_LIB(ws2_32, htonl)
 762
 763 dnl #
 764 dnl #  Check the pcap library for the RADIUS sniffer.
 765 dnl #
 766 dnl extra argument: --with-pcap-lib-dir=DIR
 767 pcap_lib_dir=
 768 AC_ARG_WITH(pcap-lib-dir,
 769   [AS_HELP_STRING([--with-pcap-lib-dir=DIR],
 770   [directory in which to look for pcap library files])],
 771   [case "$withval" in
 772     no)
 773       AC_MSG_ERROR([Need pcap-lib-dir])
 774       ;;
 775     yes)
 776       ;;
 777     *)
 778       pcap_lib_dir="$withval"
 779       ;;
 780   esac])
 781
 782 dnl extra argument: --with-pcap-include-dir=DIR
 783 pcap_include_dir=
 784 AC_ARG_WITH(pcap-include-dir,
 785   [AS_HELP_STRING([--with-pcap-include-dir=DIR],
 786   [directory in which to look for pcap include files])],
 787   [case "$withval" in
 788     no)
 789       AC_MSG_ERROR([Need pcap-include-dir])
 790       ;;
 791     yes)
 792       ;;
 793     *)
 794       pcap_include_dir="$withval"
 795       ;;
 796   esac])
 797
 798 smart_try_dir="$pcap_lib_dir"
 799 FR_SMART_CHECK_LIB(pcap, pcap_open_live)
 800 if test "x$ac_cv_lib_pcap_pcap_open_live" != "xyes"; then
 801   AC_MSG_WARN([pcap library not found, silently disabling the RADIUS sniffer, and ARP listener.  Use --with-pcap-lib-dir=<path>.])
 802 else
 803   AC_DEFINE(HAVE_LIBPCAP, 1,
 804     [Define to 1 if you have the `pcap' library (-lpcap).]
 805   )
 806
 807   AC_CHECK_FUNCS(\
 808     pcap_fopen_offline \
 809     pcap_dump_fopen \
 810     pcap_create \
 811     pcap_activate
 812   )
 813
 814   PCAP_LIBS="${smart_lib}"
 815   PCAP_LDFLAGS="${smart_ldflags}"
 816 fi
 817 dnl Set by FR_SMART_CHECK_LIB
 818 LIBS="${old_LIBS}"
 819
 820 dnl Check for collectdclient
 821 dnl extra argument: --with-collectdclient-lib-dir=DIR
 822 collectdclient_lib_dir=
 823 AC_ARG_WITH(collectdclient-lib-dir,
 824   [AS_HELP_STRING([--with-collectdclient-lib-dir=DIR],
 825   [directory in which to look for collectdclient library files])],
 826   [case "$withval" in
 827     no)
 828       AC_MSG_ERROR([Need collectdclient-lib-dir])
 829       ;;
 830     yes)
 831       ;;
 832     *)
 833       collectdclient_lib_dir="$withval"
 834       ;;
 835   esac])
 836
 837 dnl extra argument: --with-collectdclient-include-dir=DIR
 838 collectdclient_include_dir=
 839 AC_ARG_WITH(collectdclient-include-dir,
 840   [AS_HELP_STRING([--with-collectdclient-include-dir=DIR],
 841   [directory in which to look for collectdclient include files])],
 842   [case "$withval" in
 843     no)
 844       AC_MSG_ERROR([Need collectdclient-include-dir])
 845       ;;
 846     yes)
 847       ;;
 848     *)
 849       collectdclient_include_dir="$withval"
 850       ;;
 851   esac])
 852
 853 smart_try_dir="$collectdclient_lib_dir"
 854 FR_SMART_CHECK_LIB(collectdclient, lcc_connect)
 855 if test "x$ac_cv_lib_collectdclient_lcc_connect" != "xyes"; then
 856   AC_MSG_WARN([collectdclient library not found. Use --with-collectdclient-lib-dir=<path>.])
 857 else
 858   COLLECTDC_LIBS="${smart_lib}"
 859   COLLECTDC_LDFLAGS="${smart_ldflags}"
 860 fi
 861 dnl Set by FR_SMART_CHECKLIB
 862 LIBS="${old_LIBS}"
 863
 864 VL_LIB_READLINE
 865
 866 dnl #############################################################
 867 dnl #
 868 dnl #  3. Checks for header files
 869 dnl #
 870 dnl #############################################################
 871
 872 dnl #
 873 dnl # Check for talloc header files
 874 dnl #
 875 smart_try_dir="$talloc_include_dir"
 876 FR_SMART_CHECK_INCLUDE([talloc.h])
 877 if test "x$ac_cv_header_talloc_h" != "xyes"; then
 878   AC_MSG_WARN([talloc headers not found. Use --with-talloc-include-dir=<path>.])
 879   AC_MSG_ERROR([FreeRADIUS requires libtalloc])
 880 fi
 881
 882 dnl #
 883 dnl #  Interix requires us to set -D_ALL_SOURCE, otherwise
 884 dnl #  getopt will be #included, but won't link.  <sigh>
 885 dnl #
 886 case "$host" in
 887   *-interix*)
 888     CFLAGS="$CFLAGS -D_ALL_SOURCE"
 889     ;;
 890   *-darwin*)
 891     CFLAGS="$CFLAGS -DDARWIN"
 892     LIBS="-framework DirectoryService $LIBS"
 893     ;;
 894 esac
 895
 896 AC_HEADER_DIRENT
 897 AC_HEADER_STDC
 898 AC_HEADER_TIME
 899 AC_HEADER_SYS_WAIT
 900
 901 AC_CHECK_HEADERS( \
 902   dlfcn.h \
 903   unistd.h \
 904   crypt.h \
 905   errno.h \
 906   resource.h \
 907   sys/resource.h \
 908   getopt.h \
 909   malloc.h \
 910   utmp.h \
 911   utmpx.h \
 912   signal.h \
 913   sys/select.h \
 914   syslog.h \
 915   inttypes.h \
 916   stdint.h \
 917   stdio.h \
 918   netdb.h \
 919   semaphore.h \
 920   arpa/inet.h \
 921   netinet/in.h \
 922   sys/types.h \
 923   sys/socket.h \
 924   winsock.h \
 925   utime.h \
 926   sys/time.h \
 927   sys/wait.h \
 928   sys/security.h \
 929   fcntl.h \
 930   sys/fcntl.h \
 931   sys/prctl.h \
 932   sys/ptrace.h \
 933   sys/un.h \
 934   glob.h \
 935   prot.h \
 936   pwd.h \
 937   grp.h \
 938   stddef.h \
 939   fnmatch.h \
 940   sia.h \
 941   siad.h \
 942   features.h \
 943   limits.h
 944 )
 945
 946 dnl #
 947 dnl #  FreeBSD requires sys/socket.h before net/if.h
 948 dnl #
 949 AC_CHECK_HEADERS(net/if.h, [], [],
 950   [
 951     #ifdef HAVE_SYS_SOCKET_H
 952     #  include <sys/socket.h>
 953     #endif
 954   ]
 955 )
 956
 957 dnl #
 958 dnl #  other checks which require headers
 959 dnl #
 960 if test "x$ac_cv_header_sys_security_h" = "xyes" && test "x$ac_cv_header_prot_h" = "xyes"
 961 then
 962   AC_DEFINE(OSFC2, [], [define if you have OSFC2 authentication])
 963 fi
 964
 965 if test "x$ac_cv_header_sia_h" = "xyes" && test "x$ac_cv_header_siad_h" = "xyes"
 966 then
 967   AC_DEFINE(OSFSIA, [], [define if you have OSFSIA authentication])
 968 fi
 969
 970 dnl #
 971 dnl #  Were we told to use OpenSSL, if we were and we find an error, call AC_MSG_FAILURE and exit
 972 dnl #
 973 if test "x$WITH_OPENSSL" = xyes; then
 974   OLD_LIBS="$LIBS"
 975
 976   dnl #
 977   dnl #  Apparently OpenSSL will attempt to build with kerberos if we don't pass this?!
 978   dnl #
 979   CFLAGS="$CFLAGS -DOPENSSL_NO_KRB5"
 980
 981   dnl #
 982   dnl #  Check we can link to libcrypto and libssl
 983   dnl #
 984   smart_try_dir="$openssl_lib_dir"
 985   FR_SMART_CHECK_LIB(crypto, DH_new)
 986   if test "x$ac_cv_lib_crypto_DH_new" = "xyes"; then
 987     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
 988     OPENSSL_LIBS="$smart_lib"
 989     OPENSSL_LDFLAGS="$smart_ldflags"
 990
 991     FR_SMART_CHECK_LIB(ssl, SSL_new)
 992     if test "x$ac_cv_lib_ssl_SSL_new" != "xyes"; then
 993       AC_MSG_FAILURE([failed linking to libssl. Use --with-openssl-lib-dir=<path>, or --with-openssl=no (builds without OpenSSL)])
 994     else
 995       AC_DEFINE(HAVE_LIBSSL, 1, [Define to 1 if you have the `ssl' library (-lssl).])
 996       OPENSSL_LIBS="$OPENSSL_LIBS $smart_lib"
 997
 998       if test "$OPENSSL_LDFLAGS" != "$smart_ldflags"; then
 999         AC_MSG_FAILURE(["inconsistent LDFLAGS between -lssl '$smart_ldflags' and -lcrypto '$OPENSSL_LDFLAGS'"])
1000       fi
1001     fi
1002   else
1003     AC_MSG_FAILURE([failed linking to libcrypto. Use --with-openssl-lib-dir=<path>, or --with-openssl=no (builds without OpenSSL)])
1004   fi
1005
1006   smart_try_dir="$openssl_include_dir"
1007   FR_SMART_CHECK_INCLUDE(openssl/ssl.h)
1008   if test "x$ac_cv_header_openssl_ssl_h" = "xyes"; then
1009     AC_DEFINE(HAVE_OPENSSL_SSL_H, 1, [Define to 1 if you have the <openssl/ssl.h> header file.])
1010
1011     AC_CHECK_HEADERS( \
1012       openssl/crypto.h \
1013       openssl/err.h \
1014       openssl/evp.h \
1015       openssl/md5.h \
1016       openssl/md4.h \
1017       openssl/sha.h \
1018       openssl/ocsp.h \
1019       openssl/engine.h,
1020       [],
1021       [
1022         AC_MSG_FAILURE([failed locating OpenSSL headers. Use --with-openssl-include-dir=<path>, or --with-openssl=no (builds without OpenSSL)])
1023       ]
1024     )
1025
1026     AC_MSG_CHECKING([for OpenSSL version >= 0.9.7])
1027     AC_EGREP_CPP(yes,
1028       [#include <openssl/crypto.h>
1029        #if (OPENSSL_VERSION_NUMBER >= 0x00907000L)
1030        yes
1031        #endif
1032       ],
1033       [
1034         AC_MSG_RESULT(yes)
1035       ],
1036       [
1037         AC_MSG_RESULT(no)
1038         AC_MSG_FAILURE([OpenSSL version too old])
1039       ]
1040     )
1041
1042     dnl #
1043     dnl #  CPPFLAGS are passed to the compiler first, so we use
1044     dnl #  them to ensure things like --sysroot don't override the
1045     dnl #  library location we discovered previously.
1046     dnl #
1047     old_CPPFLAGS="$CPPFLAGS"
1048     CPPFLAGS="$OPENSSL_LDFLAGS $CPPFLAGS"
1049
1050     dnl #
1051     dnl #  Now check that the header versions match the library
1052     dnl #
1053     AC_MSG_CHECKING([OpenSSL library and header version consistency])
1054     AC_RUN_IFELSE(
1055       [AC_LANG_PROGRAM(
1056         [[
1057           #include <stdio.h>
1058           #include <openssl/opensslv.h>
1059           #include <openssl/crypto.h>
1060         ]],
1061         [[
1062           printf("library: %lx header: %lx... ", (unsigned long) SSLeay(), (unsigned long) OPENSSL_VERSION_NUMBER);
1063           if (SSLeay() == OPENSSL_VERSION_NUMBER) {
1064             return 0;
1065           } else {
1066             return 1;
1067           }
1068         ]]
1069       )],
1070       [
1071         AC_MSG_RESULT(yes)
1072       ],
1073       [
1074         AC_MSG_RESULT(no)
1075         AC_MSG_FAILURE([OpenSSL library version does not match header version])
1076       ]
1077     )
1078     CPPFLAGS="$old_CPPFLAGS"
1079   fi
1080
1081   LIBS="$OLD_LIBS"
1082   AC_SUBST(OPENSSL_LIBS)
1083   AC_SUBST(OPENSSL_LDFLAGS)
1084   export OPENSSL_LIBS OPENSSL_LDFLAGS
1085 fi
1086
1087 dnl #
1088 dnl #  Check the pcap includes for the RADIUS sniffer.
1089 dnl #
1090 if test "x$PCAP_LIBS" = x; then
1091   AC_MSG_NOTICE([skipping test for pcap.h.])
1092 else
1093   dnl #
1094   dnl # Check for pcap header files
1095   dnl #
1096   smart_try_dir="$pcap_include_dir"
1097   FR_SMART_CHECK_INCLUDE([pcap.h])
1098   if test "x$ac_cv_header_pcap_h" == "xyes"; then
1099     AC_DEFINE(HAVE_PCAP_H, 1, [Define to 1 if you have the <pcap.h> header file.])
1100     AC_SUBST(PCAP_LIBS)
1101     AC_SUBST(PCAP_LDFLAGS)
1102   else
1103     AC_MSG_WARN([pcap headers not found, silently disabling the RADIUS sniffer, and ARP listener. Use --with-pcap-include-dir=<path>.])
1104   fi
1105 fi
1106
1107 dnl Check for collectd-client
1108 if test "x$COLLECTDC_LIBS" = x; then
1109   AC_MSG_NOTICE([skipping test for collectd/client.h.])
1110 else
1111   dnl #
1112   dnl # Check for collectd-client header files
1113   dnl #
1114   smart_try_dir="$collectdclient_include_dir"
1115   FR_SMART_CHECK_INCLUDE([collectd/client.h])
1116   if test "x$ac_cv_header_collectd_client_h" == "xyes"; then
1117     AC_DEFINE(HAVE_COLLECTDC_H, 1, [Define to 1 if you have the `collectdclient' library (-lcollectdclient).])
1118     AC_SUBST(COLLECTDC_LIBS)
1119     AC_SUBST(COLLECTDC_LDFLAGS)
1120   else
1121     AC_MSG_WARN([collectdclient headers not found. Use --with-collectdclient-include-dir=<path>.])
1122   fi
1123 fi
1124
1125 dnl #############################################################
1126 dnl #
1127 dnl #  4. Checks for typedefs
1128 dnl #
1129 dnl #############################################################
1130
1131 dnl #
1132 dnl #  Ensure that these are defined
1133 dnl #
1134 AC_TYPE_OFF_T
1135 AC_TYPE_PID_T
1136 AC_TYPE_SIZE_T
1137 AC_TYPE_UID_T
1138
1139 dnl #
1140 dnl #  Check for socklen_t
1141 dnl #
1142 FR_CHECK_TYPE_INCLUDE(
1143   [
1144     #ifdef HAVE_SYS_TYPES_H
1145     #  include <sys/types.h>
1146     #endif
1147
1148     #ifdef HAVE_SYS_SOCKET_H
1149     #  include <sys/socket.h>
1150     #endif
1151   ],
1152   socklen_t, int, [socklen_t is generally 'int' on systems which don't use it]
1153 )
1154
1155 dnl #
1156 dnl #  Check for uint8_t
1157 dnl #
1158 FR_CHECK_TYPE_INCLUDE(
1159   [
1160     #ifdef HAVE_INTTYPES_H
1161     #  include <inttypes.h>
1162     #endif
1163
1164     #ifdef HAVE_STDINT_H
1165     #  include <stdint.h>
1166     #endif
1167   ],
1168   uint8_t, unsigned char, [uint8_t should be the canonical 'octet' for network traffic]
1169 )
1170
1171 dnl #
1172 dnl #  Check for uint16_t
1173 dnl #
1174 FR_CHECK_TYPE_INCLUDE(
1175   [
1176     #ifdef HAVE_INTTYPES_H
1177     #  include <inttypes.h>
1178     #endif
1179
1180     #ifdef HAVE_STDINT_H
1181     #  include <stdint.h>
1182     #endif
1183   ],
1184   uint16_t, unsigned short, [uint16_t should be the canonical '2 octets' for network traffic]
1185 )
1186
1187 dnl #
1188 dnl #  Check for uint32_t
1189 dnl #
1190 FR_CHECK_TYPE_INCLUDE(
1191   [
1192     #ifdef HAVE_INTTYPES_H
1193     #  include <inttypes.h>
1194     #endif
1195
1196     #ifdef HAVE_STDINT_H
1197     #  include <stdint.h>
1198     #endif
1199   ],
1200   uint32_t, unsigned int, [uint32_t should be the canonical 'network integer']
1201 )
1202
1203 dnl #
1204 dnl #  Check for uint64_t
1205 dnl #
1206 FR_CHECK_TYPE_INCLUDE(
1207   [
1208     #ifdef HAVE_INTTYPES_H
1209     #  include <inttypes.h>
1210     #endif
1211
1212     #ifdef HAVE_STDINT_H
1213     #  include <stdint.h>
1214     #endif
1215   ],
1216   uint64_t, unsigned long long, [uint64_t is required for larger counters]
1217 )
1218
1219 dnl #
1220 dnl #  Check for __uint128_t (compiler builtin)
1221 dnl #
1222 AC_CHECK_TYPE(__uint128_t, AC_DEFINE(HAVE___UINT128_T, 1, [compiler specific 128 bit unsigned integer]), [], [])
1223
1224 dnl #
1225 dnl #  Check for uint128_t (fictitious future data type)
1226 dnl #
1227 AC_CHECK_TYPE(uint128_t, AC_DEFINE(HAVE_UINT128_T, 1, [128 bit unsigned integer]), [],
1228   [
1229     #ifdef HAVE_INTTYPES_H
1230     #  include <inttypes.h>
1231     #endif
1232
1233     #ifdef HAVE_STDINT_H
1234     #  include <stdint.h>
1235     #endif
1236   ]
1237 )
1238
1239 AC_CHECK_TYPE(struct in6_addr, AC_DEFINE(HAVE_STRUCT_IN6_ADDR, 1, [IPv6 address structure]), [],
1240   [
1241     #ifdef HAVE_NETINET_IN_H
1242     #  include <netinet/in.h>
1243     #endif
1244   ]
1245 )
1246
1247 AC_CHECK_TYPE(struct sockaddr_storage, AC_DEFINE(HAVE_STRUCT_SOCKADDR_STORAGE, 1, [Generic socket addresses]), [],
1248   [
1249     #ifdef HAVE_NETINET_IN_H
1250     #  include <netinet/in.h>
1251     #endif
1252
1253     #ifdef HAVE_SYS_SOCKET_H
1254     #  include <sys/socket.h>
1255     #endif
1256 ])
1257
1258 AC_CHECK_TYPE(struct sockaddr_in6, AC_DEFINE(HAVE_STRUCT_SOCKADDR_IN6, 1, [IPv6 socket addresses]), [],
1259   [
1260     #ifdef HAVE_NETINET_IN_H
1261     #  include <netinet/in.h>
1262     #endif
1263 ])
1264
1265 AC_CHECK_TYPE(struct addrinfo, AC_DEFINE(HAVE_STRUCT_ADDRINFO, 1, [Generic DNS lookups]), [],
1266   [
1267     #ifdef HAVE_SYS_TYPES_H
1268     #  include <sys/types.h>
1269     #endif
1270
1271     #ifdef HAVE_SYS_SOCKET_H
1272     #  include <sys/socket.h>
1273     #endif
1274
1275     #ifdef HAVE_NETDB_H
1276     #  include <netdb.h>
1277     #endif
1278   ]
1279 )
1280
1281 dnl #
1282 dnl #  Check for sig_t
1283 dnl #
1284 dnl #  FR_CHECK_TYPE_INCLUDE doesn't work for callbacks as it doesn't produce typedefs
1285 dnl #
1286 AC_MSG_CHECKING([if sig_t is defined])
1287 AC_LINK_IFELSE(
1288   [AC_LANG_PROGRAM(
1289     [[
1290       #ifdef HAVE_SIGNAL_H
1291       #  include <signal.h>
1292       #endif
1293     ]],
1294     [[
1295       sig_t func;
1296       return 0;
1297     ]]
1298   )],
1299   [
1300       AC_MSG_RESULT(yes)
1301       AC_DEFINE(HAVE_SIG_T, 1, [Define if the type sig_t is defined by signal.h])
1302   ],
1303   [
1304       AC_MSG_RESULT(no)
1305   ]
1306 )
1307
1308 dnl #############################################################
1309 dnl #
1310 dnl #  5. Checks for structures and functions
1311 dnl #
1312 dnl #############################################################
1313 AC_CHECK_FUNCS( \
1314   getopt_long \
1315   fcntl \
1316   strsignal \
1317   sigaction \
1318   sigprocmask \
1319   pthread_sigmask \
1320   snprintf \
1321   vsnprintf \
1322   setsid \
1323   strncasecmp \
1324   strcasecmp \
1325   localtime_r \
1326   ctime_r \
1327   gmtime_r \
1328   strsep \
1329   inet_aton \
1330   inet_pton \
1331   inet_ntop \
1332   mallopt \
1333   setlinebuf \
1334   setvbuf \
1335   getusershell \
1336   initgroups \
1337   getaddrinfo \
1338   getnameinfo \
1339   closefrom \
1340   gettimeofday \
1341   getpeereid \
1342   setuid \
1343   setresuid \
1344   getresuid \
1345   strlcat \
1346   strlcpy
1347 )
1348
1349 AC_TYPE_SIGNAL
1350
1351 dnl #
1352 dnl #  Check if we have utmpx.h
1353 dnl #  if so, check if struct utmpx has entry ut_xtime
1354 dnl #  if not, set it to define ut_xtime == ut_tv.tv_sec
1355 dnl #
1356 if test "x$ac_cv_header_utmpx_h" = "xyes"; then
1357  FR_CHECK_STRUCT_HAS_MEMBER([#include <utmpx.h>], [struct utmpx], ut_xtime)
1358  if test "x$ac_cv_type_struct_utmpx_has_ut_xtime" = "x"; then
1359    AC_DEFINE(ut_xtime, ut_tv.tv_sec, [define to something if you don't have ut_xtime in struct utmpx])
1360  fi
1361 fi
1362
1363 dnl #
1364 dnl #  struct ip_pktinfo
1365 dnl #
1366 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in_pktinfo], ipi_addr)
1367 if test "x$ac_cv_type_struct_in_pktinfo_has_ipi_addr" = "xyes"; then
1368   AC_DEFINE(HAVE_IP_PKTINFO, [], [define if you have IP_PKTINFO (Linux)])
1369 fi
1370
1371 dnl #
1372 dnl #  struct in6_pktinfo
1373 dnl #
1374 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in6_pktinfo], ipi6_addr)
1375 if test "x$ac_cv_type_struct_in6_pktinfo_has_ipi6_addr" = "xyes"; then
1376   AC_DEFINE(HAVE_IN6_PKTINFO, [], [define if you have IN6_PKTINFO (Linux)])
1377 fi
1378
1379 dnl #
1380 dnl #  Check for htonll and htonlll
1381 dnl #
1382 AC_MSG_CHECKING([if htonll is defined])
1383 AC_LINK_IFELSE(
1384   [AC_LANG_PROGRAM(
1385     [[
1386       #include <sys/types.h>
1387       #include <netinet/in.h>
1388     ]],
1389     [[
1390       return htonll(0);
1391     ]]
1392   )],
1393   [
1394       AC_MSG_RESULT(yes)
1395       AC_DEFINE(HAVE_HTONLL, 1, [Define if the function (or macro) htonll exists.])
1396   ],
1397   [
1398       AC_MSG_RESULT(no)
1399   ]
1400 )
1401
1402 AC_MSG_CHECKING([if htonlll is defined])
1403 AC_LINK_IFELSE(
1404   [AC_LANG_PROGRAM(
1405     [[
1406       #include <sys/types.h>
1407       #include <netinet/in.h>
1408     ]],
1409     [[
1410       return htonlll(0);
1411     ]]
1412   )],
1413   [
1414       AC_MSG_RESULT(yes)
1415       AC_DEFINE(HAVE_HTONLLL, 1, [Define if the function (or macro) htonlll exists.])
1416   ],
1417   [
1418       AC_MSG_RESULT(no)
1419   ]
1420 )
1421
1422 dnl #############################################################
1423 dnl #
1424 dnl #  6. Checks for compiler characteristics
1425 dnl #
1426 dnl #############################################################
1427
1428 dnl #
1429 dnl #  Ensure that these are defined
1430 dnl #
1431 AC_C_CONST
1432
1433 dnl #
1434 dnl #  See if this is OS/2
1435 dnl #
1436 AC_MSG_CHECKING([type of OS])
1437 OS=`uname -s`
1438 AC_MSG_RESULT($OS)
1439 if test "$OS" = "OS/2"; then
1440   LIBPREFIX=
1441 else
1442   LIBPREFIX=lib
1443 fi
1444 AC_SUBST(LIBPREFIX)
1445
1446 if test "x$developer" = "xyes"; then
1447   AC_MSG_NOTICE([Setting additional developer CFLAGS])
1448
1449   dnl #
1450   dnl #  Tell the compiler to parse doxygen documentation and verify it against function and variable declarations
1451   dnl #
1452   AX_CC_WDOCUMENTATION_FLAG
1453   if test "x$ax_cv_cc_wdocumentation_flag" = "xyes"; then
1454     devflags="-Wdocumentation"
1455   fi
1456
1457   if test "x$GCC" = "xyes"; then
1458     devflags="$devflags -Wshadow -Wpointer-arith -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -W -Wredundant-decls -Wundef -Wformat-y2k -Wno-format-extra-args -Wno-format-zero-length -Wno-cast-align -Wformat-nonliteral -Wformat-security -Wformat=2 -DWITH_VERIFY_PTR=1"
1459     INSTALLSTRIP=""
1460   fi
1461
1462   AC_MSG_NOTICE([Developer CFLAGS are "$devflags"])
1463
1464   CFLAGS="$CFLAGS $devflags"
1465   dnl #
1466   dnl #  Enable experimental modules (we want to know if code changes breaks one of them)
1467   dnl #
1468   if test "x$EXPERIMENTAL" != "xno"; then
1469     AC_MSG_NOTICE([is developer build, enabling experimental modules implicitly, disable with --without-experimental-modules])
1470     EXPERIMENTAL=yes
1471   fi
1472 else
1473   devflags=""
1474   CFLAGS="$CFLAGS -DNDEBUG"
1475   INSTALLSTRIP=""
1476 fi
1477
1478 dnl #
1479 dnl #  May of been set outside of this configure script
1480 dnl #
1481 AC_MSG_CHECKING([if building with -DNDEBUG])
1482 if echo "$CFLAGS" | grep '\-DNDEBUG' > /dev/null; then
1483   AC_MSG_RESULT([yes])
1484   AC_DEFINE([WITH_NDEBUG], [1], [define if the server was built with -DNDEBUG])
1485 else
1486   AC_MSG_RESULT([no])
1487 fi
1488
1489 export EXPERIMENTAL
1490
1491 dnl #
1492 dnl #  append the current git hash onto the version string
1493 dnl #
1494 if test -d $srcdir/.git -a "x$GIT" = "xyes"; then
1495   RADIUSD_VERSION_COMMIT=`git log --pretty=format:'%h' -n 1`
1496   AC_DEFINE_UNQUOTED([RADIUSD_VERSION_COMMIT],[${RADIUSD_VERSION_COMMIT}],[Commit HEAD at time of configuring])
1497 fi
1498
1499 dnl #
1500 dnl #  check for some compiler features
1501 dnl #
1502 FR_TLS
1503 FR_HAVE_BUILTIN_CHOOSE_EXPR
1504 FR_HAVE_BUILTIN_TYPES_COMPATIBLE_P
1505 FR_HAVE_BUILTIN_BSWAP_64
1506
1507 dnl #############################################################
1508 dnl #
1509 dnl #  7. Checks for library functions
1510 dnl #
1511 dnl #############################################################
1512
1513 dnl #
1514 dnl # Check for talloc_set_memlimit
1515 dnl # This was only included in version 2.0.8
1516 dnl #
1517 AC_CHECK_LIB(talloc, talloc_set_memlimit,
1518   [
1519     AC_DEFINE(HAVE_TALLOC_SET_MEMLIMIT, 1, [Define to 1 if you have the function talloc_set_memlimit.])
1520   ]
1521 )
1522
1523 dnl #
1524 dnl # Check for libcrypt
1525 dnl # We use crypt(3) which may be in libc, or in libcrypt (eg FreeBSD)
1526 dnl #
1527 AC_CHECK_LIB(crypt, crypt,
1528   CRYPTLIB="-lcrypt"
1529 )
1530
1531 if test "$CRYPTLIB" != ""; then
1532   AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function])
1533 else
1534   AC_CHECK_FUNC(crypt, AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function]))
1535 fi
1536
1537 dnl Check for libcipher
1538 AC_CHECK_LIB(cipher, setkey,
1539    CRYPTLIB="${CRYPTLIB} -lcipher"
1540 )
1541 AC_SUBST(CRYPTLIB)
1542
1543 dnl #
1544 dnl #  Check for libexecinfo support, on some systems this is built into libc
1545 dnl #  on others it's a separate library.
1546 dnl #
1547 dnl extra argument: --with-execinfo-lib-dir
1548 execinfo_lib_dir=
1549 AC_ARG_WITH(execinfo-lib-dir,
1550 [AS_HELP_STRING([--with-execinfo-lib-dir=DIR],
1551 [directory in which to look for execinfo library files])],
1552 [ case "$withval" in
1553     no)
1554         AC_MSG_ERROR([Need execinfo-lib-dir])
1555         ;;
1556     yes)
1557         ;;
1558     *)
1559         execinfo_lib_dir="$withval"
1560         ;;
1561   esac ]
1562 )
1563
1564 dnl extra argument: --with-execinfo-include-dir
1565 execinfo_include_dir=
1566 AC_ARG_WITH(execinfo-include-dir,
1567 [AS_HELP_STRING([--with-execinfo-include-dir=DIR],
1568 [directory in which to look for execinfo include files])],
1569 [ case "$withval" in
1570     no)
1571         AC_MSG_ERROR([Need execinfo-include-dir])
1572         ;;
1573     yes)
1574         ;;
1575     *)
1576         execinfo_include_dir="$withval"
1577         ;;
1578   esac ]
1579 )
1580
1581 dnl #
1582 dnl #  Look for execinfo.h and symbols
1583 dnl #
1584 smart_try_dir=$execinfo_include_dir
1585 FR_SMART_CHECK_INCLUDE(execinfo.h)
1586 if test "x$ac_cv_header_execinfo_h" = "xyes"; then
1587   smart_try_dir=$execinfo_lib_dir
1588   FR_SMART_CHECK_LIB(execinfo, backtrace_symbols)
1589   if test "x$ac_cv_lib_execinfo_backtrace_symbols" != "xyes"; then
1590     dnl # Might be provided as part of libc
1591     AC_MSG_CHECKING([if execinfo provided as part of libc])
1592     AC_TRY_LINK(
1593       [
1594         #include <execinfo.h>
1595       ],
1596       [
1597         void *sym[1];
1598         backtrace_symbols(&sym, sizeof(sym)) ],
1599       [
1600         AC_MSG_RESULT(yes)
1601         ac_cv_lib_execinfo_backtrace_symbols="yes"
1602       ],
1603       [
1604         AC_MSG_RESULT(no)
1605       ]
1606     )
1607   fi
1608
1609   if test "x$ac_cv_lib_execinfo_backtrace_symbols" = "xyes"; then
1610     AC_DEFINE(HAVE_EXECINFO, [1], [define this if we have <execinfo.h> and symbols])
1611   fi
1612 fi
1613
1614 dnl #
1615 dnl #  Check for regular expression support, if were using PCRE it MUST be included
1616 dnl #  before all others, else we seem to still pickup the posix symbols for regcomp
1617 dnl #  and regexec, which results in crashes as soon as we call any posix regex
1618 dnl #  functions.
1619 dnl #
1620 dnl extra argument: --with-pcre-lib-dir
1621 pcre_lib_dir=
1622 AC_ARG_WITH(pcre-lib-dir,
1623 [AS_HELP_STRING([--with-pcre-lib-dir=DIR],
1624 [directory in which to look for pcre library files])],
1625 [ case "$withval" in
1626     no)
1627         AC_MSG_ERROR(Need pcre-lib-dir)
1628         ;;
1629     yes)
1630         ;;
1631     *)
1632         pcre_lib_dir="$withval"
1633         ;;
1634   esac ]
1635 )
1636
1637 dnl extra argument: --with-pcre-include--dir
1638 pcre_include_dir=
1639 AC_ARG_WITH(pcre-include-dir,
1640 [AS_HELP_STRING([--with-pcre-include-dir=DIR],
1641 [directory in which to look for pcre include files])],
1642 [ case "$withval" in
1643     no)
1644         AC_MSG_ERROR(Need pcre-include-dir)
1645         ;;
1646     yes)
1647         ;;
1648     *)
1649         pcre_include_dir="$withval"
1650         ;;
1651   esac ]
1652 )
1653
1654 REGEX=no
1655 REGEX_EXTENDED=no
1656 REGEX_PCRE=no
1657
1658 dnl #
1659 dnl #  First look for PCRE
1660 dnl #
1661 smart_try_dir=$pcre_include_dir
1662 FR_SMART_CHECK_INCLUDE(pcreposix.h)
1663 if test "x$ac_cv_header_pcreposix_h" = "xyes"; then
1664   AC_DEFINE(HAVE_REGEX_H, [1], [define if we have any regex])
1665   AC_DEFINE(HAVE_PCREPOSIX_H, [1], [define this if we have the <pcreposix.h> header file])
1666   REGEX=yes
1667   REGEX_EXTENDED=yes
1668   REGEX_PCRE=yes
1669   LIBS="-lpcre -lpcreposix $LIBS"
1670
1671 dnl #
1672 dnl #  Then fallback to POSIX regular expressions
1673 dnl #
1674 else
1675   smart_try_dir=
1676   FR_SMART_CHECK_INCLUDE(regex.h)
1677   if test "x$ac_cv_header_regex_h" = "xyes"; then
1678     AC_DEFINE(HAVE_REGEX_H, [1], [define if we have any regex])
1679     REGEX=yes
1680     AC_EGREP_CPP(yes,
1681       [
1682         #include <regex.h>
1683         #ifdef REG_EXTENDED
1684         yes
1685         #endif
1686        ],
1687     [AC_DEFINE(HAVE_REG_EXTENDED, [1], [define this if we have REG_EXTENDED (from <regex.h>)]) REGEX_EXTENDED=yes]
1688     )
1689 dnl #
1690 dnl # Fixme, this is needed for mingw builds, but not available on some Linux systems
1691 dnl # despite the presence of regex.h
1692 dnl #
1693 dnl # LIBS="$LIBS -lregex"
1694   fi
1695 fi
1696
1697 AC_SUBST(REGEX)
1698 AC_SUBST(REGEX_PCRE)
1699 AC_SUBST(REGEX_EXTENDED)
1700
1701 dnl #
1702 dnl #  Check the style of gethostbyaddr, in order of preference
1703 dnl #  GNU (_r eight args)
1704 dnl #
1705 AC_DEFINE(GNUSTYLE, [1], [GNU-Style get*byaddr_r])
1706
1707 dnl #
1708 dnl #  SYSV (_r six args)
1709 dnl #
1710 AC_DEFINE(SYSVSTYLE, [2], [SYSV-Style get*byaddr_r])
1711
1712 dnl #
1713 dnl #  BSD (three args, may not be thread safe)
1714 dnl #
1715 AC_DEFINE(BSDSTYLE, [3], [BSD-Style get*byaddr_r])
1716
1717 dnl #
1718 dnl #  Tru64 has BSD version, but it is thread safe
1719 dnl #  http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1739____.HTM
1720 dnl #  We need #stdio.h to define NULL on FreeBSD (at least)
1721 dnl #
1722 gethostbyaddrrstyle=""
1723 AC_MSG_CHECKING([gethostbyaddr_r() syntax])
1724 case "$host" in
1725   *-freebsd*)
1726     dnl #
1727     dnl #  With FreeBSD, check if there's a prototype for gethostbyaddr_r.
1728     dnl #  Some versions (FreeBSD 5.1?) have a symbol but no prototype - so we
1729     dnl #  override this test to BSDSTYLE. FreeBSD 6.2 and up have proper GNU
1730     dnl #  style support.
1731     dnl #
1732     AC_CHECK_DECLS([gethostbyaddr_r], [],
1733       [
1734         AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE,
1735           [style of gethostbyaddr_r functions ])
1736         gethostbyaddrrstyle=BSD
1737         AC_MSG_WARN([FreeBSD overridden to BSD-style])
1738       ],
1739       [
1740         #ifdef HAVE_NETDB_H
1741         #include <netdb.h>
1742         #endif
1743       ])
1744     ;;
1745 esac
1746
1747 if test "x$gethostbyaddrrstyle" = "x"; then
1748   AC_TRY_LINK(
1749     [
1750       #include <stdio.h>
1751       #include <netdb.h>
1752     ],
1753     [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL, NULL) ],
1754     [
1755       AC_DEFINE(GETHOSTBYADDRRSTYLE, GNUSTYLE, [style of gethostbyaddr_r functions ])
1756       gethostbyaddrrstyle=GNU
1757     ]
1758   )
1759 fi
1760
1761 if test "x$gethostbyaddrrstyle" = "x"; then
1762   AC_TRY_LINK(
1763     [
1764       #include <stdio.h>
1765       #include <netdb.h>
1766     ],
1767     [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL) ] ,
1768     [
1769       AC_DEFINE(GETHOSTBYADDRRSTYLE, SYSVSTYLE, [style of gethostbyaddr_r functions ])
1770       gethostbyaddrrstyle=SYSV
1771     ]
1772   )
1773 fi
1774
1775
1776 if test "x$gethostbyaddrrstyle" = "x"; then
1777   AC_TRY_LINK(
1778     [
1779       #include <stdio.h>
1780       #include <netdb.h>
1781     ],
1782     [ gethostbyaddr(NULL, 0, 0)  ],
1783     [
1784       AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE, [style of gethostbyaddr_r functions ])
1785       gethostbyaddrrstyle=BSD
1786     ]
1787   )
1788 fi
1789
1790 if test "x$gethostbyaddrrstyle" = "x"; then
1791   AC_MSG_RESULT([none!  It must not exist, here.])
1792 else
1793   AC_MSG_RESULT([${gethostbyaddrrstyle}-style])
1794 fi
1795
1796 if test "x$gethostbyaddrrstyle" = "xBSD"; then
1797   AC_MSG_WARN([ ****** BSD-style gethostbyaddr might NOT be thread-safe! ****** ])
1798 fi
1799
1800 dnl #
1801 dnl #  Check the style of gethostbyname, in order of preference
1802 dnl #  GNU (_r seven args)
1803 dnl #  SYSV (_r five args)
1804 dnl #  BSD (two args, may not be thread safe)
1805 dnl #  Tru64 has BSD version, but it _is_ thread safe
1806 dnl #    http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1946____.HTM
1807 dnl #  We need #stdio.h to define NULL on FreeBSD (at least)
1808 dnl #
1809 gethostbynamerstyle=""
1810 AC_MSG_CHECKING([gethostbyname_r() syntax])
1811 AC_TRY_LINK(
1812   [
1813     #include <stdio.h>
1814     #include <netdb.h>
1815   ],
1816   [ gethostbyname_r(NULL, NULL, NULL, 0, NULL, NULL) ],
1817   [
1818     AC_DEFINE(GETHOSTBYNAMERSTYLE, GNUSTYLE, [style of gethostbyname_r functions ])
1819     gethostbynamerstyle=GNU
1820   ]
1821 )
1822
1823 if test "x$gethostbynamerstyle" = "x"; then
1824   AC_TRY_LINK(
1825     [
1826       #include <stdio.h>
1827       #include <netdb.h>
1828     ],
1829     [ gethostbyname_r(NULL, NULL, NULL, 0, NULL) ] ,
1830     [
1831       AC_DEFINE(GETHOSTBYNAMERSTYLE, SYSVSTYLE, [style of gethostbyname_r functions ])
1832       gethostbynamerstyle=SYSV
1833     ]
1834   )
1835 fi
1836
1837 if test "x$gethostbynamerstyle" = "x"; then
1838   AC_TRY_LINK(
1839     [
1840       #include <stdio.h>
1841       #include <netdb.h>
1842     ],
1843     [ gethostbyname(NULL) ],
1844     [
1845       AC_DEFINE(GETHOSTBYNAMERSTYLE, BSDSTYLE, [style of gethostbyname_r functions ])
1846       gethostbynamerstyle=BSD
1847     ]
1848   )
1849 fi
1850
1851 if test "x$gethostbynamerstyle" = "x"; then
1852   AC_MSG_RESULT([none!  It must not exist, here.])
1853 else
1854   AC_MSG_RESULT([${gethostbynamerstyle}-style])
1855 fi
1856
1857 if test "x$gethostbynamerstyle" = "xBSD"; then
1858   AC_MSG_WARN([ ****** BSD-style gethostbyname might NOT be thread-safe! ****** ])
1859 fi
1860
1861 dnl #
1862 dnl #  Check for non-posix solaris ctime_r (extra buflen int arg)
1863 dnl #
1864 AC_DEFINE(POSIXSTYLE, [1], [Posix-Style ctime_r])
1865 AC_DEFINE(SOLARISSTYLE, [2], [Solaris-Style ctime_r])
1866 ctimerstyle=""
1867 AC_MSG_CHECKING([ctime_r() syntax])
1868 AC_TRY_LINK(
1869   [
1870     #include <time.h>
1871   ],
1872   [ ctime_r(NULL, NULL, 0) ],
1873   [
1874     AC_DEFINE(CTIMERSTYLE, SOLARISSTYLE, [style of ctime_r function])
1875     ctimerstyle="SOLARIS"
1876   ]
1877 )
1878
1879 if test "x$ctimerstyle" = "x"; then
1880   AC_TRY_LINK(
1881     [
1882       #include <time.h>
1883     ],
1884     [ ctime_r(NULL, NULL) ],
1885     [
1886       AC_DEFINE(CTIMERSTYLE, POSIXSTYLE, [style of ctime_r function])
1887       ctimerstyle="POSIX"
1888     ]
1889   )
1890 fi
1891
1892 if test "x$ctimerstyle" = "x"; then
1893     AC_MSG_RESULT([none!  It must not exist, here.])
1894 else
1895     AC_MSG_RESULT([${ctimerstyle}-style])
1896 fi
1897
1898 AC_SUBST(HOSTINFO, $host)
1899
1900 dnl #############################################################
1901 dnl #
1902 dnl #  8. Checks for system services
1903 dnl #
1904 dnl #############################################################
1905
1906 dnl #
1907 dnl #  Figure out where libtool is located,
1908 dnl #
1909 top_builddir=`pwd`
1910 export top_builddir
1911 AC_MSG_RESULT([top_builddir=$top_builddir])
1912 dnl #  AC_SUBST(top_builddir)
1913
1914 dnl #
1915 dnl #  import libtool stuff
1916 dnl #
1917 dnl #############################################################
1918 dnl #
1919 dnl #  Configure in any module directories.
1920 dnl #
1921 dnl #############################################################
1922
1923 dnl ############################################################
1924 dnl #  Remove any conflicting definitions if autoconf.h
1925 dnl #  is being included by a module.
1926 dnl #############################################################
1927 AH_BOTTOM([#include <freeradius-devel/automask.h>])
1928
1929 dnl ############################################################
1930 dnl #  make modules by list
1931 dnl #############################################################
1932 if test "x$EXPERIMENTAL" = "xyes"; then
1933   for foo in `ls -1 "${srcdir}"/src/modules | grep rlm_`; do
1934     MODULES="$MODULES $foo"
1935   done
1936 else
1937    dnl #
1938    dnl #  make ONLY the stable modules
1939    dnl #
1940    for foo in `cat "${srcdir}"/src/modules/stable`; do
1941       MODULES="$MODULES $foo"
1942    done
1943 fi
1944
1945 dnl ############################################################
1946 dnl #  Add autoconf subdirs, based on the module list we
1947 dnl #  previously created.
1948 dnl #############################################################
1949 mysubdirs=""
1950 for bar in $MODULES; do
1951   if test -f "${srcdir}"/src/modules/$bar/configure; then
1952     mysubdirs="$mysubdirs src/modules/$bar"
1953   fi
1954 done
1955
1956 dnl #
1957 dnl #  Don't change the variable name here.  Autoconf goes bonkers
1958 dnl #  if you do.
1959 dnl #
1960 AC_CONFIG_SUBDIRS($mysubdirs)
1961 AC_SUBST(MODULES)
1962
1963 dnl #############################################################
1964 dnl #
1965 dnl #  Add -Werror last, so it doesn't interfere with autoconf's
1966 dnl #  test programs.
1967 dnl #
1968 dnl #############################################################
1969 if test "x$werror" == "xyes"; then
1970   CFLAGS="-Werror $CFLAGS"
1971 fi
1972
1973 dnl #############################################################
1974 dnl #
1975 dnl #  And finally, output the results.
1976 dnl #
1977 dnl #############################################################
1978 AC_CONFIG_COMMANDS([stamp-h], [echo timestamp > src/include/stamp-h])
1979 AC_CONFIG_COMMANDS([build-radpaths-h], [(cd ./src/include && /bin/sh ./build-radpaths-h)])
1980 AC_CONFIG_COMMANDS([main-chmod], [(cd ./src/main && chmod +x checkrad radlast radtest)])
1981 AC_CONFIG_COMMANDS([scripts-chmod], [(cd ./scripts && chmod +x rc.radiusd cron/radiusd.cron.daily cron/radiusd.cron.monthly cryptpasswd)])
1982
1983 dnl #
1984 dnl #  Substitute whatever libraries we found to be necessary
1985 dnl #
1986 AC_SUBST(LIBS)
1987 AC_SUBST(INSTALLSTRIP)
1988
1989 AC_SUBST(USE_SHARED_LIBS)
1990 USE_STATIC_LIBS="yes"
1991 AC_SUBST(USE_STATIC_LIBS)
1992 AC_SUBST(STATIC_MODULES)
1993
1994 AC_OUTPUT(\
1995   ./Make.inc \
1996   ./src/include/build-radpaths-h \
1997   ./src/main/radsniff.mk \
1998   ./src/main/checkrad \
1999   ./src/main/radlast \
2000   ./src/main/radtest \
2001   ./scripts/rc.radiusd \
2002   ./scripts/cron/radiusd.cron.daily \
2003   ./scripts/cron/radiusd.cron.monthly \
2004   ./scripts/cryptpasswd \
2005   ./raddb/radrelay.conf \
2006   ./raddb/radiusd.conf
2007 )