configure.ac

   1 dnl #############################################################
   2 dnl #
   3 dnl #  For information about autoconf, see:
   4 dnl #
   5 dnl #  http://www.gnu.org/software/autoconf/
   6 dnl #
   7 dnl #  The recommended order is:
   8 dnl #
   9 dnl #  AC_INIT(file)
  10 dnl #  0. checks for compiler, libtool, and command line options
  11 dnl #  1. checks for programs
  12 dnl #  2. checks for libraries
  13 dnl #  3. checks for header files
  14 dnl #  4. checks for typedefs
  15 dnl #  5. checks for structures and functions
  16 dnl #  6. checks for compiler characteristics
  17 dnl #  7. checks for library functions
  18 dnl #  8. checks for system services
  19 dnl #  AC_OUTPUT([file...])
  20 dnl #
  21 dnl #############################################################
  22
  23 AC_PREREQ([2.59])
  24 export CFLAGS LIBS LDFLAGS CPPFLAGS
  25
  26 AC_INIT([freeradius],[$]Id[$],[http://bugs.freeradius.org],,[http://www.freeradius.org])
  27 AC_CONFIG_SRCDIR([src/main/radiusd.c])
  28 AC_CONFIG_HEADER([src/include/autoconf.h])
  29 m4_include([m4/ax_cc.m4])
  30
  31 dnl #############################################################
  32 dnl #
  33 dnl #  Custom hackery to discover version at configure time
  34 dnl #
  35 dnl #############################################################
  36
  37 RADIUSD_MAJOR_VERSION=`cat VERSION | sed 's/\..*//'`
  38 RADIUSD_MINOR_VERSION=`cat VERSION | sed 's/^[[^\.]]*\.//' | sed 's/\..*$//'`
  39 RADIUSD_INCRM_VERSION=`cat VERSION | sed 's/^.*\..*\.//' | sed 's/[[\.-]].*$//'`
  40
  41 RADIUSD_VERSION=`echo | awk -v major="$RADIUSD_MAJOR_VERSION" \
  42 -v minor="$RADIUSD_MINOR_VERSION" \
  43 -v incrm="$RADIUSD_INCRM_VERSION" \
  44 '{ printf "%02i%02i%02i", major, minor, incrm }'`
  45
  46 dnl #
  47 dnl #  Still useful for custom builds
  48 dnl #
  49 RADIUSD_VERSION_STRING=`cat VERSION`
  50
  51 dnl #
  52 dnl #  Add definitions to Make.inc as it's used by various build targets
  53 dnl #
  54 AC_SUBST([RADIUSD_VERSION_STRING])
  55
  56 dnl #
  57 dnl #  Add definitions to autoconf.h, so that the headers that we install
  58 dnl #  contain the version number of the server.
  59 dnl #
  60 AC_DEFINE_UNQUOTED([RADIUSD_VERSION], [${RADIUSD_VERSION}], [Version integer in format <ma><ma><mi><mi><in><in>])
  61 AC_DEFINE_UNQUOTED([RADIUSD_VERSION_STRING], ["${RADIUSD_VERSION_STRING}"], [Raw version string from VERSION file])
  62
  63 dnl #############################################################
  64 dnl #
  65 dnl #  Override some of the default autoconf variables such as
  66 dnl #  CFLAGS if were building in developer mode
  67 dnl #
  68 dnl #############################################################
  69
  70 dnl #
  71 dnl #  Enable developer features like debugging symbols.
  72 dnl #  These checks must be done before expanding the AC_PROG_CC
  73 dnl #  and AC_PROG_CXX macros.
  74 dnl #
  75 AC_ARG_ENABLE(developer,
  76 [  --enable-developer      enables features of interest to developers.],
  77 [ case "$enableval" in
  78   no)
  79     developer=no
  80     ;;
  81   *)
  82     developer=yes
  83   esac ]
  84 )
  85
  86 dnl #
  87 dnl #  Turn on the developer flag when taken from a git checkout (not a release)
  88 dnl #
  89 if test -d $srcdir/.git; then
  90   if test "x$developer" != "xno"; then
  91     AC_MSG_NOTICE([found .git directory, enabling developer build implicitly, disable with --disable-developer])
  92     developer="yes"
  93   fi
  94 fi
  95
  96 dnl #
  97 dnl #  Autoconf sets -O2 and -g by default, but this is a PITA for debugging
  98 dnl #  so we remove the defaults if were building in developer mode, and set
  99 dnl #  -g3 so nice things like macro values are included. Other arguments are
 100 dnl #  added later when we know what compiler were using.
 101 dnl #
 102 if test "x$developer" = "xyes"; then
 103   : ${CFLAGS=-g3}
 104 fi
 105
 106 dnl #############################################################
 107 dnl #
 108 dnl #  0. Checks for compiler, libtool, and command line options.
 109 dnl #
 110 dnl #############################################################
 111
 112 dnl #
 113 dnl #  Get system information
 114 dnl #
 115 AC_CANONICAL_SYSTEM
 116
 117 dnl #
 118 dnl #  Check for GNU cc
 119 dnl #
 120 AC_PROG_CC
 121 AC_PROG_CXX
 122
 123 dnl #
 124 dnl #  check for AIX, to allow us to use some BSD functions
 125 dnl #  must be before macros that call the compiler.
 126 dnl #
 127 AC_AIX
 128
 129 AC_PROG_GCC_TRADITIONAL
 130 AC_PROG_CC_SUNPRO
 131 AC_PROG_RANLIB
 132
 133 dnl #
 134 dnl #  Definitive check for whether the compiler is clang
 135 dnl #
 136 AX_CC_IS_CLANG
 137 if test "x$ax_cv_cc_clang" = "xyes"; then
 138   AC_SUBST(clang_path, "$CC")
 139 else
 140   AC_SUBST(clang_path, "")
 141 fi
 142
 143
 144 dnl #
 145 dnl #  Set Default CFLAGS for GCC compatible compilers
 146 dnl #
 147 if test "x$GCC" = "xyes"; then
 148   CFLAGS="$CFLAGS -Wall -D_GNU_SOURCE"
 149 fi
 150
 151 dnl #
 152 dnl #  -Qunused-arguments means the compiler won't complain about unsupported arguments
 153 dnl #
 154 AX_CC_QUNUSED_ARGUMENTS_FLAG
 155 if test "x$ax_cv_cc_qunused_arguments_flag" = "xyes"; then
 156   CFLAGS="$CFLAGS -Qunused-arguments"
 157   LDFLAGS="$LDFLAGS -Qunused-arguments"
 158 fi
 159
 160 dnl #
 161 dnl #  Compile in large (2G+) file support.
 162 dnl #
 163 AC_SYS_LARGEFILE
 164
 165 dnl #
 166 dnl #  check for system bytesex
 167 dnl #  AC_DEFINES WORDS_BIGENDIAN
 168 dnl #
 169 AC_C_BIGENDIAN(
 170   [AC_DEFINE(BIG_ENDIAN, 1, [Define if your processor stores words with the most significant byte first])],
 171   [AC_DEFINE(LITTLE_ENDIAN, 1, [Define if your processor stores words with the least significant byte first])]
 172 )
 173
 174 dnl #
 175 dnl #  Find GNU Make.
 176 dnl #
 177 AC_CHECK_PROG(GMAKE, gmake, yes, no)
 178 if test $GMAKE = no; then
 179   AC_PATH_PROG(MAKE, make, /usr/local/bin/make)
 180 else
 181   AC_PATH_PROG(MAKE, gmake, /usr/local/gnu/bin/make)
 182 fi
 183 makever=`$ac_cv_path_MAKE --version 2>&1 | grep "GNU Make"`
 184 if test -z "$makever"; then
 185   AC_MSG_ERROR([GNU Make is not installed.  Please download and install it from ftp://prep.ai.mit.edu/pub/gnu/make/ before continuing.])
 186 fi
 187
 188 dnl #
 189 dnl #  autoconf explicitly sets MAKEFLAGS and MFLAGS to '' even though we
 190 dnl #  didn't tell it to, so we have to use FR_MAKEFLAGS.
 191 dnl #
 192 dnl #  determine the number of cores available and set the number of build
 193 dnl #  processes appropriately.
 194 dnl #
 195 AX_SYSTEM_CORES
 196
 197 dnl #  Temporarily disabled because test and installation targets do not
 198 dnl #  have dependencies set up correctly for multiple build processes.
 199 dnl if test "x$ax_cv_system_cores" != "x"; then
 200 dnl  : ${FR_MAKEFLAGS=-j$ax_cv_system_cores}
 201 dnl fi
 202 AC_SUBST(FR_MAKEFLAGS)
 203
 204 dnl #
 205 dnl #  See if we have Git.
 206 dnl #
 207 AC_CHECK_PROG(GIT, git, yes, no)
 208
 209 dnl Put this in later, when all distributed modules use autoconf.
 210 dnl AC_ARG_WITH(disablemodulefoo,
 211 dnl [  --without-rlm_foo         Disables module compilation.  Module list:]
 212 dnl esyscmd([find src/modules -type d -name rlm_\* -print |\
 213 dnl   sed -e 's%src/modules/.*/% (sub)- %; s%.*/%- %' |\
 214 dnl   awk '{print "                            "$0}']))
 215
 216 AC_ARG_ENABLE(strict-dependencies,
 217 [  --enable-strict-dependencies  fail configure on lack of module dependancy.])
 218
 219 AC_ARG_ENABLE(werror,
 220 [  --enable-werror         causes the build to fail if any warnings are generated.],
 221 [ case "$enableval" in
 222     no)
 223       werror=no
 224     ;;
 225     *)
 226       werror=yes
 227   esac ]
 228 )
 229
 230 dnl #
 231 dnl #  extra argument: --with-docdir
 232 dnl #
 233 docdir='${datadir}/doc/freeradius'
 234 AC_MSG_CHECKING([docdir])
 235 AC_ARG_WITH(docdir,
 236 [  --with-docdir=DIR       directory for documentation [DATADIR/doc/freeradius] ],
 237 [ case "$withval" in
 238   no)
 239     docdir=no
 240     ;;
 241   yes)
 242     ;;
 243   [[\\/$]]* | ?:[[\\/]]* )
 244     docdir="$withval"
 245     ;;
 246   *)
 247     AC_MSG_ERROR([expected an absolute directory name for --with-docdir: $withval])
 248     ;;
 249   esac ]
 250 )
 251 AC_SUBST(docdir)
 252 AC_MSG_RESULT($docdir)
 253 if test "x$docdir" = xno; then
 254   AC_MSG_WARN([Documentation files will NOT be installed.])
 255 fi
 256
 257 dnl #
 258 dnl #  extra argument: --with-logdir
 259 dnl #
 260 logdir='${localstatedir}/log/radius'
 261 AC_MSG_CHECKING(logdir)
 262 AC_ARG_WITH(logdir,
 263 [  --with-logdir=DIR       directory for logfiles [LOCALSTATEDIR/log/radius] ],
 264 [ case "$withval" in
 265   no)
 266     AC_MSG_ERROR([Need logdir])
 267     ;;
 268   yes)
 269     ;;
 270   [[\\/$]]* | ?:[[\\/]]* )
 271     logdir="$withval"
 272     ;;
 273   *)
 274     AC_MSG_ERROR([expected an absolute directory name for --with-logdir: $withval])
 275     ;;
 276   esac ]
 277 )
 278 AC_SUBST(logdir)
 279 AC_MSG_RESULT($logdir)
 280
 281 dnl #
 282 dnl #  extra argument: --with-radacctdir
 283 dnl #
 284 radacctdir='${logdir}/radacct'
 285 AC_MSG_CHECKING(radacctdir)
 286 AC_ARG_WITH(radacctdir,
 287 [  --with-radacctdir=DIR   directory for detail files [LOGDIR/radacct] ],
 288 [ case "$withval" in
 289   no)
 290     AC_MSG_ERROR([Need radacctdir])
 291     ;;
 292   yes)
 293     ;;
 294   [[\\/$]]* | ?:[[\\/]]* )
 295     radacctdir="$withval"
 296     ;;
 297   *)
 298     AC_MSG_ERROR([expected an absolute directory name for --with-radacctdir: $withval])
 299     ;;
 300   esac ]
 301 )
 302 AC_SUBST(radacctdir)
 303 AC_MSG_RESULT($radacctdir)
 304
 305 dnl #
 306 dnl #  extra argument: --with-raddbdir
 307 dnl #
 308 raddbdir='${sysconfdir}/raddb'
 309 AC_MSG_CHECKING(raddbdir)
 310 AC_ARG_WITH(raddbdir,
 311 [  --with-raddbdir=DIR     directory for config files [SYSCONFDIR/raddb] ],
 312 [ case "$withval" in
 313   no)
 314     AC_MSG_ERROR([Need raddbdir])
 315     ;;
 316   yes)
 317     ;;
 318   [[\\/$]]* | ?:[[\\/]]* )
 319     raddbdir="$withval"
 320     ;;
 321   *)
 322     AC_MSG_ERROR([expected an absolute directory name for --with-raddbdir: $withval])
 323     ;;
 324   esac ]
 325 )
 326 AC_SUBST(raddbdir)
 327 AC_MSG_RESULT($raddbdir)
 328
 329 dnl #
 330 dnl #  extra argument: --with-dictdir
 331 dnl #
 332 dictdir='${datarootdir}/freeradius'
 333 AC_MSG_CHECKING(dictdir)
 334 AC_ARG_WITH(dictdir,
 335 [  --with-dictdir=DIR      directory for dictionary files [DATAROOTDIR/freeradius] ],
 336 [ case "$withval" in
 337   no)
 338     AC_MSG_ERROR([Need dictdir])
 339     ;;
 340   yes)
 341     ;;
 342   [[\\/$]]* | ?:[[\\/]]* )
 343     dictdir="$withval"
 344     ;;
 345   *)
 346     AC_MSG_ERROR([expected an absolute directory name for --with-dictdir: $withval])
 347     ;;
 348   esac ]
 349 )
 350 AC_SUBST(dictdir)
 351 AC_MSG_RESULT($dictdir)
 352
 353 modconfdir='${raddbdir}/mods-config'
 354 AC_SUBST(modconfdir)
 355
 356 dnl #
 357 dnl #  extra argument: --with-ascend-binary
 358 dnl #
 359 WITH_ASCEND_BINARY=yes
 360 AC_ARG_WITH(ascend-binary,
 361 [  --with-ascend-binary    include support for Ascend binary filter attributes (default=yes)],
 362 [ case "$withval" in
 363   yes)
 364     ;;
 365   *)
 366     WITH_ASCEND_BINARY=no
 367   esac ]
 368 )
 369 if test "x$WITH_ASCEND_BINARY" = "xyes"; then
 370   AC_DEFINE(WITH_ASCEND_BINARY, [1], [include support for Ascend binary filter attributes])
 371 fi
 372
 373 dnl #
 374 dnl #  extra argument: --with-threads
 375 dnl #
 376 WITH_THREADS=yes
 377 AC_ARG_WITH(threads,
 378 [  --with-threads          use threads, if available.  (default=yes) ],
 379 [ case "$withval" in
 380   yes)
 381     ;;
 382   *)
 383     WITH_THREADS=no
 384   esac ]
 385 )
 386
 387 dnl #
 388 dnl #  extra argument: --with-tcp
 389 dnl #
 390 WITH_TCP=yes
 391 AC_ARG_WITH(tcp,
 392 [  --with-tcp              compile in TCP support. (default=yes)],
 393 [ case "$withval" in
 394   yes)
 395     ;;
 396   *)
 397     WITH_TCP=no
 398   esac ]
 399 )
 400 if test "x$WITH_TCP" = "xyes"; then
 401   AC_DEFINE(WITH_TCP, [1], [define if you want TCP support (For RADSec et al)])
 402 fi
 403
 404 dnl #
 405 dnl #  extra argument: --with-vmps
 406 dnl #
 407 WITH_VMPS=yes
 408 AC_ARG_WITH(vmps,
 409 [  --with-vmps             compile in VMPS support. (default=yes)],
 410 [ case "$withval" in
 411   yes)
 412     ;;
 413   *)
 414     WITH_VMPS=no
 415   esac ]
 416 )
 417 if test "x$WITH_VMPS" = "xyes"; then
 418   AC_DEFINE(WITH_VMPS, [1], [define if you want VMPS support])
 419 fi
 420
 421 dnl #
 422 dnl #  extra argument: --with-dhcp
 423 dnl #
 424 WITH_DHCP=yes
 425 AC_ARG_WITH(dhcp,
 426 [  --with-dhcp             compile in DHCP support. (default=yes)],
 427 [ case "$withval" in
 428   yes)
 429     ;;
 430   *)
 431     WITH_DHCP=no
 432   esac ]
 433 )
 434 if test "x$WITH_DHCP" = "xyes"; then
 435   AC_DEFINE(WITH_DHCP, [1], [define if you want DHCP support])
 436 fi
 437
 438 dnl #
 439 dnl #  Allow the user to specify a list of modules to be linked
 440 dnl #  statically to the server.
 441 dnl #
 442 STATIC_MODULES=
 443 AC_ARG_WITH(static_modules,
 444 [  --with-static-modules=QUOTED-MODULE-LIST],[
 445   for i in $withval; do
 446     STATIC_MODULES="$STATIC_MODULES -dlpreopen ../modules/rlm_$i/rlm_$i.la"
 447   done
 448 ])
 449
 450 USE_SHARED_LIBS=yes
 451 AC_ARG_WITH(shared-libs,
 452 [AS_HELP_STRING([--with-shared-libs ],
 453 [build dynamic libraries and link against them. (default=yes)])],
 454 [ case "$withval" in
 455   no)
 456     USE_SHARED_LIBS=no
 457     ;;
 458   *)
 459   esac
 460 ])
 461
 462 MODULES=
 463 AC_ARG_WITH(modules,
 464 [  --with-modules=QUOTED-MODULE-LIST],[
 465  for i in $withval; do
 466    MODULES="$MODULES $i"
 467  done
 468 ])
 469
 470 dnl #
 471 dnl #  extra argument: --with-experimental-modules
 472 dnl #
 473 EXPERIMENTAL=
 474 AC_ARG_WITH(experimental-modules,
 475 [AS_HELP_STRING([--with-experimental-modules],
 476 [use experimental and unstable modules. (default=no, unless --enable-developer=yes)])],
 477 [ case "$withval" in
 478   yes)
 479     EXPERIMENTAL=yes
 480     ;;
 481   no)
 482     EXPERIMENTAL=no
 483     ;;
 484   *)
 485   esac ]
 486 )
 487
 488 dnl #
 489 dnl #  extra argument: --with-udpfromto
 490 dnl #
 491 WITH_UDPFROMTO=yes
 492 AC_ARG_WITH(udpfromto,
 493 [  --with-udpfromto        compile in UDPFROMTO support. (default=yes)],
 494 [ case "$withval" in
 495   yes)
 496     WITH_UDPFROMTO=yes
 497     ;;
 498   *)
 499     WITH_UDPFROMTO=no
 500   esac ]
 501 )
 502
 503 if test "x$WITH_UDPFROMTO" = "xyes"; then
 504   AC_DEFINE(WITH_UDPFROMTO, [], [define if you want udpfromto])
 505 fi
 506
 507 dnl #
 508 dnl #  These next two arguments don't actually do anything.  They're
 509 dnl #  place holders so that the top-level configure script can tell
 510 dnl #  the user how to configure lower-level modules
 511 dnl #
 512
 513 dnl #
 514 dnl #  extra argument: --with-rlm-FOO-lib-dir
 515 dnl #
 516 AC_ARG_WITH(rlm-FOO-lib-dir,
 517 [AS_HELP_STRING([--with-rlm-FOO-lib-dir=DIR],
 518 [directory in which to look for library files used by module FOO])],
 519 [ case "$withval" in
 520   *)
 521     ;;
 522   esac ]
 523 )
 524
 525 dnl #
 526 dnl #  extra argument: --with-rlm-FOO-include-dir
 527 dnl #
 528 AC_ARG_WITH(rlm-FOO-include-dir,
 529 [AS_HELP_STRING([--with-rlm-FOO-include-dir=DIR],
 530 [directory in which to look for include files used by module FOO])],
 531 [ case "$withval" in
 532   *)
 533     ;;
 534   esac ]
 535 )
 536
 537 dnl #
 538 dnl #  extra argument: --with-openssl
 539 dnl #
 540 WITH_OPENSSL=yes
 541 AC_ARG_WITH(openssl,
 542 [  --with-openssl          use OpenSSL. (default=yes)],
 543 [ case "$withval" in
 544   no)
 545     WITH_OPENSSL=no
 546     ;;
 547   *)
 548     WITH_OPENSSL=yes
 549     ;;
 550   esac ]
 551 )
 552
 553 dnl #
 554 dnl #  extra argument: --with-openssl-lib-dir=dir
 555 dnl #
 556 openssl_lib_dir=
 557 AC_ARG_WITH(openssl-lib-dir,
 558 [AS_HELP_STRING([--with-openssl-lib-dir=DIR],
 559 [directory to look for OpenSSL library files])],
 560 [ case "$withval" in
 561   *) openssl_lib_dir="$withval"
 562     ;;
 563   esac ]
 564 )
 565
 566 dnl #
 567 dnl #  extra argument: --with-openssl-includes=dir
 568 dnl #
 569 openssl_include_dir=
 570 AC_ARG_WITH(openssl-include-dir,
 571 [AS_HELP_STRING([--with-openssl-include-dir=DIR],
 572 [directory to look for OpenSSL include files])],
 573 [ case "$withval" in
 574   *) openssl_include_dir="$withval"
 575     ;;
 576   esac ]
 577 )
 578
 579 dnl #############################################################
 580 dnl #
 581 dnl #  1. Checks for programs
 582 dnl #
 583 dnl #############################################################
 584
 585 CHECKRAD=checkrad
 586 AC_PATH_PROG(PERL, perl, /usr/local/bin/perl)
 587 if test "x$ac_cv_path_PERL" = "x"; then
 588   AC_MSG_WARN([perl not found - Simultaneous-Use and checkrad may not work])
 589 fi
 590 AC_PATH_PROG(SNMPGET, snmpget)
 591 if test "x$ac_cv_path_SNMPGET" = "x"; then
 592   AC_MSG_WARN([snmpget not found - Simultaneous-Use and checkrad may not work])
 593 fi
 594
 595 AC_PATH_PROG(SNMPWALK, snmpwalk)
 596 if test "x$ac_cv_path_SNMPWALK" = "x"; then
 597   AC_MSG_WARN([snmpwalk not found - Simultaneous-Use and checkrad may not work])
 598 fi
 599
 600 AC_PATH_PROG(RUSERS, rusers, /usr/bin/rusers)
 601
 602 dnl #
 603 dnl #  FIXME This is truly gross.
 604 dnl #
 605 missing_dir=`cd $ac_aux_dir && pwd`
 606 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
 607 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
 608 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
 609
 610 AC_PATH_PROG(LOCATE,locate)
 611 AC_PATH_PROG(DIRNAME,dirname)
 612 AC_PATH_PROG(GREP,grep)
 613
 614 dnl #############################################################
 615 dnl #
 616 dnl #  2. Checks for libraries
 617 dnl #
 618 dnl #############################################################
 619
 620 dnl Check for talloc
 621 dnl extra argument: --with-talloc-lib-dir=DIR
 622 talloc_lib_dir=
 623 AC_ARG_WITH(talloc-lib-dir,
 624   [AS_HELP_STRING([--with-talloc-lib-dir=DIR],
 625   [directory in which to look for talloc library files])],
 626   [case "$withval" in
 627     no)
 628       AC_MSG_ERROR([Need talloc-lib-dir])
 629       ;;
 630     yes)
 631       ;;
 632     *)
 633       talloc_lib_dir="$withval"
 634       ;;
 635   esac])
 636
 637 dnl extra argument: --with-talloc-include-dir=DIR
 638 talloc_include_dir=
 639 AC_ARG_WITH(talloc-include-dir,
 640   [AS_HELP_STRING([--with-talloc-include-dir=DIR],
 641   [directory in which to look for talloc include files])],
 642   [case "$withval" in
 643     no)
 644       AC_MSG_ERROR([Need talloc-include-dir])
 645       ;;
 646     yes)
 647       ;;
 648     *)
 649       talloc_include_dir="$withval"
 650       ;;
 651   esac])
 652
 653 smart_try_dir="$talloc_lib_dir"
 654 FR_SMART_CHECK_LIB(talloc, _talloc)
 655 if test "x$ac_cv_lib_talloc__talloc" != "xyes"; then
 656   AC_MSG_WARN([talloc library not found. Use --with-talloc-lib-dir=<path>.])
 657   AC_MSG_ERROR([FreeRADIUS requires libtalloc])
 658 fi
 659
 660 TALLOC_LIBS="${smart_lib}"
 661 TALLOC_LDFLAGS="${smart_ldflags}"
 662 AC_SUBST(TALLOC_LIBS)
 663 AC_SUBST(TALLOC_LDFLAGS)
 664 LIBS="$old_LIBS"
 665
 666 dnl #
 667 dnl #  If using pthreads, check for -lpthread (posix) or -lc_r (*BSD)
 668 dnl #
 669 old_CFLAGS=$CFLAGS
 670 if test "x$WITH_THREADS" = "xyes"; then
 671   if test $ac_cv_prog_suncc = "yes"; then
 672     CFLAGS="$CFLAGS -mt"
 673   fi
 674
 675   AC_CHECK_HEADERS(pthread.h, [],
 676     [
 677       WITH_THREADS="no"
 678       fail=[pthread.h]
 679     ])
 680
 681   dnl #
 682   dnl #  pthread stuff is usually in -lpthread
 683   dnl #  or in -lc_r, on *BSD
 684   dnl #
 685   dnl #  On Some systems, we need extra pre-processor flags, to get them to
 686   dnl #  to do the threading properly.
 687   dnl #
 688   AC_CHECK_LIB(pthread, pthread_create,
 689     [
 690       CFLAGS="$CFLAGS -D_REENTRANT -D_POSIX_PTHREAD_SEMANTICS"
 691       LIBS="-lpthread $LIBS"
 692     ],
 693     [
 694       dnl #
 695       dnl # -pthread is not a typo, it's a GCC option which sets additional flags required
 696       dnl # for multithreading with the pthreads library.
 697       dnl #
 698       AC_CHECK_LIB(c_r, pthread_create,
 699         [ CFLAGS="$CFLAGS -pthread -D_THREAD_SAFE" ],
 700         [
 701           WITH_THREADS="no"
 702           fail=[-lpthread]
 703         ]
 704       )
 705     ]
 706   )
 707
 708   if test "x$WITH_THREADS" != "xyes"; then
 709     AC_MSG_WARN([silently not building with thread support.])
 710     AC_MSG_WARN([FAILURE: thread support requires: $fail.])
 711   else
 712     AC_DEFINE(WITH_THREADS, [1], [define if you want thread support])
 713   fi
 714 fi
 715
 716 dnl #
 717 dnl #  If we have NO pthread libraries, remove any knowledge of threads.
 718 dnl #
 719 if test "x$WITH_THREADS" != "xyes"; then
 720   CFLAGS=$old_CFLAGS
 721   ac_cv_header_pthread_h="no"
 722   WITH_THREADS=no
 723 else
 724   dnl #
 725   dnl #  We need sem_init() and friends, as they're the friendliest
 726   dnl #  semaphore functions for threading.
 727   dnl #
 728   dnl #  HP/UX requires linking with librt, too, to get the sem_* symbols.
 729   dnl #  Some systems have them in -lsem
 730   dnl #  Solaris has them in -lposix4
 731   dnl #  NetBSD has them in -lsemaphore
 732   dnl #
 733
 734   AC_SEARCH_LIBS(sem_init, pthread sem posix4 rt semaphore,
 735     [],
 736     [AC_MSG_ERROR([[-lsem not found.  You may want to download it from ftp://ftp.to.gd-es.com/pub/BSDI/libsem.tar.bz2 or ftp://ftp.freeradius.org/pub/radius/contrib/libsem.tar.gz]])]
 737   )
 738 fi
 739
 740 dnl #
 741 dnl #  Check if we need -lsocket
 742 dnl #
 743 AC_CHECK_LIB(dl, dlopen)
 744
 745 dnl #
 746 dnl #  Check if we need -lsocket
 747 dnl #
 748 AC_CHECK_LIB(socket, getsockname)
 749
 750 dnl #
 751 dnl #  Check for -lresolv
 752 dnl #  This library may be needed later.
 753 dnl #
 754 AC_CHECK_LIB(resolv, inet_aton)
 755
 756 dnl #
 757 dnl #  Check if we need -lnsl. Usually if we want to
 758 dnl #  link against -lsocket we need to include -lnsl as well.
 759 dnl #
 760 AC_CHECK_LIB(nsl, inet_ntoa)
 761 AC_CHECK_LIB(ws2_32, htonl)
 762
 763 dnl #
 764 dnl #  Check the pcap library for the RADIUS sniffer.
 765 dnl #
 766 dnl extra argument: --with-pcap-lib-dir=DIR
 767 pcap_lib_dir=
 768 AC_ARG_WITH(pcap-lib-dir,
 769   [AS_HELP_STRING([--with-pcap-lib-dir=DIR],
 770   [directory in which to look for pcap library files])],
 771   [case "$withval" in
 772     no)
 773       AC_MSG_ERROR([Need pcap-lib-dir])
 774       ;;
 775     yes)
 776       ;;
 777     *)
 778       pcap_lib_dir="$withval"
 779       ;;
 780   esac])
 781
 782 dnl extra argument: --with-pcap-include-dir=DIR
 783 pcap_include_dir=
 784 AC_ARG_WITH(pcap-include-dir,
 785   [AS_HELP_STRING([--with-pcap-include-dir=DIR],
 786   [directory in which to look for pcap include files])],
 787   [case "$withval" in
 788     no)
 789       AC_MSG_ERROR([Need pcap-include-dir])
 790       ;;
 791     yes)
 792       ;;
 793     *)
 794       pcap_include_dir="$withval"
 795       ;;
 796   esac])
 797
 798 smart_try_dir="$pcap_lib_dir"
 799 FR_SMART_CHECK_LIB(pcap, pcap_open_live)
 800 if test "x$ac_cv_lib_pcap_pcap_open_live" != "xyes"; then
 801   AC_MSG_WARN([pcap library not found, silently disabling the RADIUS sniffer, and ARP listener.  Use --with-pcap-lib-dir=<path>.])
 802 else
 803   AC_DEFINE(HAVE_LIBPCAP, 1,
 804     [Define to 1 if you have the `pcap' library (-lpcap).]
 805   )
 806
 807   AC_CHECK_FUNCS(\
 808     pcap_fopen_offline \
 809     pcap_dump_fopen \
 810     pcap_create \
 811     pcap_activate
 812   )
 813
 814   PCAP_LIBS="${smart_lib}"
 815   PCAP_LDFLAGS="${smart_ldflags}"
 816 fi
 817 dnl Set by FR_SMART_CHECK_LIB
 818 LIBS="${old_LIBS}"
 819
 820 dnl Check for collectdclient
 821 dnl extra argument: --with-collectdclient-lib-dir=DIR
 822 collectdclient_lib_dir=
 823 AC_ARG_WITH(collectdclient-lib-dir,
 824   [AS_HELP_STRING([--with-collectdclient-lib-dir=DIR],
 825   [directory in which to look for collectdclient library files])],
 826   [case "$withval" in
 827     no)
 828       AC_MSG_ERROR([Need collectdclient-lib-dir])
 829       ;;
 830     yes)
 831       ;;
 832     *)
 833       collectdclient_lib_dir="$withval"
 834       ;;
 835   esac])
 836
 837 dnl extra argument: --with-collectdclient-include-dir=DIR
 838 collectdclient_include_dir=
 839 AC_ARG_WITH(collectdclient-include-dir,
 840   [AS_HELP_STRING([--with-collectdclient-include-dir=DIR],
 841   [directory in which to look for collectdclient include files])],
 842   [case "$withval" in
 843     no)
 844       AC_MSG_ERROR([Need collectdclient-include-dir])
 845       ;;
 846     yes)
 847       ;;
 848     *)
 849       collectdclient_include_dir="$withval"
 850       ;;
 851   esac])
 852
 853 smart_try_dir="$collectdclient_lib_dir"
 854 FR_SMART_CHECK_LIB(collectdclient, lcc_connect)
 855 if test "x$ac_cv_lib_collectdclient_lcc_connect" != "xyes"; then
 856   AC_MSG_WARN([collectdclient library not found. Use --with-collectdclient-lib-dir=<path>.])
 857 else
 858   COLLECTDC_LIBS="${smart_lib}"
 859   COLLECTDC_LDFLAGS="${smart_ldflags}"
 860 fi
 861 dnl Set by FR_SMART_CHECKLIB
 862 LIBS="${old_LIBS}"
 863
 864 VL_LIB_READLINE
 865
 866 dnl #############################################################
 867 dnl #
 868 dnl #  3. Checks for header files
 869 dnl #
 870 dnl #############################################################
 871
 872 dnl #
 873 dnl # Check for talloc header files
 874 dnl #
 875 smart_try_dir="$talloc_include_dir"
 876 FR_SMART_CHECK_INCLUDE([talloc.h])
 877 if test "x$ac_cv_header_talloc_h" != "xyes"; then
 878   AC_MSG_WARN([talloc headers not found. Use --with-talloc-include-dir=<path>.])
 879   AC_MSG_ERROR([FreeRADIUS requires libtalloc])
 880 fi
 881
 882 dnl #
 883 dnl #  Interix requires us to set -D_ALL_SOURCE, otherwise
 884 dnl #  getopt will be #included, but won't link.  <sigh>
 885 dnl #
 886 case "$host" in
 887   *-interix*)
 888     CFLAGS="$CFLAGS -D_ALL_SOURCE"
 889     ;;
 890   *-darwin*)
 891     CFLAGS="$CFLAGS -DDARWIN"
 892     LIBS="-framework DirectoryService $LIBS"
 893     ;;
 894 esac
 895
 896 AC_HEADER_DIRENT
 897 AC_HEADER_STDC
 898 AC_HEADER_TIME
 899 AC_HEADER_SYS_WAIT
 900
 901 AC_CHECK_HEADERS( \
 902   dlfcn.h \
 903   unistd.h \
 904   crypt.h \
 905   errno.h \
 906   resource.h \
 907   sys/resource.h \
 908   getopt.h \
 909   malloc.h \
 910   utmp.h \
 911   utmpx.h \
 912   signal.h \
 913   sys/select.h \
 914   syslog.h \
 915   inttypes.h \
 916   stdint.h \
 917   stdio.h \
 918   netdb.h \
 919   semaphore.h \
 920   arpa/inet.h \
 921   netinet/in.h \
 922   sys/types.h \
 923   sys/socket.h \
 924   winsock.h \
 925   utime.h \
 926   sys/time.h \
 927   sys/wait.h \
 928   sys/security.h \
 929   fcntl.h \
 930   sys/fcntl.h \
 931   sys/prctl.h \
 932   sys/un.h \
 933   glob.h \
 934   prot.h \
 935   pwd.h \
 936   grp.h \
 937   stddef.h \
 938   fnmatch.h \
 939   sia.h \
 940   siad.h \
 941   features.h
 942 )
 943
 944 dnl #
 945 dnl #  FreeBSD requires sys/socket.h before net/if.h
 946 dnl #
 947 AC_CHECK_HEADERS(net/if.h, [], [],
 948   [
 949     #ifdef HAVE_SYS_SOCKET_H
 950     #  include <sys/socket.h>
 951     #endif
 952   ]
 953 )
 954
 955 dnl #
 956 dnl #  other checks which require headers
 957 dnl #
 958 if test "x$ac_cv_header_sys_security_h" = "xyes" && test "x$ac_cv_header_prot_h" = "xyes"
 959 then
 960   AC_DEFINE(OSFC2, [], [define if you have OSFC2 authentication])
 961 fi
 962
 963 if test "x$ac_cv_header_sia_h" = "xyes" && test "x$ac_cv_header_siad_h" = "xyes"
 964 then
 965   AC_DEFINE(OSFSIA, [], [define if you have OSFSIA authentication])
 966 fi
 967
 968 dnl #
 969 dnl #  Were we told to use OpenSSL, if we were and we find an error, call AC_MSG_FAILURE and exit
 970 dnl #
 971 if test "x$WITH_OPENSSL" = xyes; then
 972   OLD_LIBS="$LIBS"
 973
 974   dnl #
 975   dnl #  Apparently OpenSSL will attempt to build with kerberos if we don't pass this?!
 976   dnl #
 977   CFLAGS="$CFLAGS -DOPENSSL_NO_KRB5"
 978
 979   dnl #
 980   dnl #  Check we can link to libcrypto and libssl
 981   dnl #
 982   smart_try_dir="$openssl_lib_dir"
 983   FR_SMART_CHECK_LIB(crypto, DH_new)
 984   if test "x$ac_cv_lib_crypto_DH_new" = "xyes"; then
 985     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
 986     OPENSSL_LIBS="$smart_lib"
 987     OPENSSL_LDFLAGS="$smart_ldflags"
 988
 989     FR_SMART_CHECK_LIB(ssl, SSL_new)
 990     if test "x$ac_cv_lib_ssl_SSL_new" != "xyes"; then
 991       AC_MSG_FAILURE([failed linking to libssl. Use --with-openssl-lib-dir=<path>, or --with-openssl=no (builds without OpenSSL)])
 992     else
 993       AC_DEFINE(HAVE_LIBSSL, 1, [Define to 1 if you have the `ssl' library (-lssl).])
 994       OPENSSL_LIBS="$OPENSSL_LIBS $smart_lib"
 995
 996       if test "$OPENSSL_LDFLAGS" != "$smart_ldflags"; then
 997         AC_MSG_FAILURE(["inconsistent LDFLAGS between -lssl '$smart_ldflags' and -lcrypto '$OPENSSL_LDFLAGS'"])
 998       fi
 999     fi
1000   else
1001     AC_MSG_FAILURE([failed linking to libcrypto. Use --with-openssl-lib-dir=<path>, or --with-openssl=no (builds without OpenSSL)])
1002   fi
1003
1004   smart_try_dir="$openssl_include_dir"
1005   FR_SMART_CHECK_INCLUDE(openssl/ssl.h)
1006   if test "x$ac_cv_header_openssl_ssl_h" = "xyes"; then
1007     AC_DEFINE(HAVE_OPENSSL_SSL_H, 1, [Define to 1 if you have the <openssl/ssl.h> header file.])
1008
1009     AC_CHECK_HEADERS( \
1010       openssl/crypto.h \
1011       openssl/err.h \
1012       openssl/evp.h \
1013       openssl/md5.h \
1014       openssl/md4.h \
1015       openssl/sha.h \
1016       openssl/ocsp.h \
1017       openssl/engine.h,
1018       [],
1019       [
1020         AC_MSG_FAILURE([failed locating OpenSSL headers. Use --with-openssl-include-dir=<path>, or --with-openssl=no (builds without OpenSSL)])
1021       ]
1022     )
1023
1024     AC_MSG_CHECKING([for OpenSSL version >= 0.9.7])
1025     AC_EGREP_CPP(yes,
1026       [#include <openssl/crypto.h>
1027        #if (OPENSSL_VERSION_NUMBER >= 0x00907000L)
1028        yes
1029        #endif
1030       ],
1031       [
1032         AC_MSG_RESULT(yes)
1033       ],
1034       [
1035         AC_MSG_RESULT(no)
1036         AC_MSG_FAILURE([OpenSSL version too old])
1037       ]
1038     )
1039
1040     dnl #
1041     dnl #  CPPFLAGS are passed to the compiler first, so we use
1042     dnl #  them to ensure things like --sysroot don't override the
1043     dnl #  library location we discovered previously.
1044     dnl #
1045     old_CPPFLAGS="$CPPFLAGS"
1046     CPPFLAGS="$OPENSSL_LDFLAGS $CPPFLAGS"
1047
1048     dnl #
1049     dnl #  Now check that the header versions match the library
1050     dnl #
1051     AC_MSG_CHECKING([OpenSSL library and header version consistency])
1052     AC_RUN_IFELSE(
1053       [AC_LANG_PROGRAM(
1054         [[
1055           #include <stdio.h>
1056           #include <openssl/opensslv.h>
1057           #include <openssl/crypto.h>
1058         ]],
1059         [[
1060           printf("library: %lx header: %lx... ", (unsigned long) SSLeay(), (unsigned long) OPENSSL_VERSION_NUMBER);
1061           if (SSLeay() == OPENSSL_VERSION_NUMBER) {
1062             return 0;
1063           } else {
1064             return 1;
1065           }
1066         ]]
1067       )],
1068       [
1069         AC_MSG_RESULT(yes)
1070       ],
1071       [
1072         AC_MSG_RESULT(no)
1073         AC_MSG_FAILURE([OpenSSL library version does not match header version])
1074       ]
1075     )
1076     CPPFLAGS="$old_CPPFLAGS"
1077   fi
1078
1079   LIBS="$OLD_LIBS"
1080   AC_SUBST(OPENSSL_LIBS)
1081   AC_SUBST(OPENSSL_LDFLAGS)
1082   export OPENSSL_LIBS OPENSSL_LDFLAGS
1083 fi
1084
1085 dnl #
1086 dnl #  Check the pcap includes for the RADIUS sniffer.
1087 dnl #
1088 if test "x$PCAP_LIBS" = x; then
1089   AC_MSG_NOTICE([skipping test for pcap.h.])
1090 else
1091   dnl #
1092   dnl # Check for pcap header files
1093   dnl #
1094   smart_try_dir="$pcap_include_dir"
1095   FR_SMART_CHECK_INCLUDE([pcap.h])
1096   if test "x$ac_cv_header_pcap_h" == "xyes"; then
1097     AC_DEFINE(HAVE_PCAP_H, 1, [Define to 1 if you have the <pcap.h> header file.])
1098     AC_SUBST(PCAP_LIBS)
1099     AC_SUBST(PCAP_LDFLAGS)
1100   else
1101     AC_MSG_WARN([pcap headers not found, silently disabling the RADIUS sniffer, and ARP listener. Use --with-pcap-include-dir=<path>.])
1102   fi
1103 fi
1104
1105 dnl Check for collectd-client
1106 if test "x$COLLECTDC_LIBS" = x; then
1107   AC_MSG_NOTICE([skipping test for collectd/client.h.])
1108 else
1109   dnl #
1110   dnl # Check for collectd-client header files
1111   dnl #
1112   smart_try_dir="$collectdclient_include_dir"
1113   FR_SMART_CHECK_INCLUDE([collectd/client.h])
1114   if test "x$ac_cv_header_collectd_client_h" == "xyes"; then
1115     AC_DEFINE(HAVE_COLLECTDC_H, 1, [Define to 1 if you have the `collectdclient' library (-lcollectdclient).])
1116     AC_SUBST(COLLECTDC_LIBS)
1117     AC_SUBST(COLLECTDC_LDFLAGS)
1118   else
1119     AC_MSG_WARN([collectdclient headers not found. Use --with-collectdclient-include-dir=<path>.])
1120   fi
1121 fi
1122
1123 dnl #############################################################
1124 dnl #
1125 dnl #  4. Checks for typedefs
1126 dnl #
1127 dnl #############################################################
1128
1129 dnl #
1130 dnl #  Ensure that these are defined
1131 dnl #
1132 AC_TYPE_OFF_T
1133 AC_TYPE_PID_T
1134 AC_TYPE_SIZE_T
1135 AC_TYPE_UID_T
1136
1137 dnl #
1138 dnl #  Check for socklen_t
1139 dnl #
1140 FR_CHECK_TYPE_INCLUDE(
1141   [
1142     #ifdef HAVE_SYS_TYPES_H
1143     #  include <sys/types.h>
1144     #endif
1145
1146     #ifdef HAVE_SYS_SOCKET_H
1147     #  include <sys/socket.h>
1148     #endif
1149   ],
1150   socklen_t, int, [socklen_t is generally 'int' on systems which don't use it]
1151 )
1152
1153 dnl #
1154 dnl #  Check for uint8_t
1155 dnl #
1156 FR_CHECK_TYPE_INCLUDE(
1157   [
1158     #ifdef HAVE_INTTYPES_H
1159     #  include <inttypes.h>
1160     #endif
1161
1162     #ifdef HAVE_STDINT_H
1163     #  include <stdint.h>
1164     #endif
1165   ],
1166   uint8_t, unsigned char, [uint8_t should be the canonical 'octet' for network traffic]
1167 )
1168
1169 dnl #
1170 dnl #  Check for uint16_t
1171 dnl #
1172 FR_CHECK_TYPE_INCLUDE(
1173   [
1174     #ifdef HAVE_INTTYPES_H
1175     #  include <inttypes.h>
1176     #endif
1177
1178     #ifdef HAVE_STDINT_H
1179     #  include <stdint.h>
1180     #endif
1181   ],
1182   uint16_t, unsigned short, [uint16_t should be the canonical '2 octets' for network traffic]
1183 )
1184
1185 dnl #
1186 dnl #  Check for uint32_t
1187 dnl #
1188 FR_CHECK_TYPE_INCLUDE(
1189   [
1190     #ifdef HAVE_INTTYPES_H
1191     #  include <inttypes.h>
1192     #endif
1193
1194     #ifdef HAVE_STDINT_H
1195     #  include <stdint.h>
1196     #endif
1197   ],
1198   uint32_t, unsigned int, [uint32_t should be the canonical 'network integer']
1199 )
1200
1201 dnl #
1202 dnl #  Check for uint64_t
1203 dnl #
1204 FR_CHECK_TYPE_INCLUDE(
1205   [
1206     #ifdef HAVE_INTTYPES_H
1207     #  include <inttypes.h>
1208     #endif
1209
1210     #ifdef HAVE_STDINT_H
1211     #  include <stdint.h>
1212     #endif
1213   ],
1214   uint64_t, unsigned long long, [uint64_t is required for larger counters]
1215 )
1216
1217 FR_CHECK_TYPE_INCLUDE(
1218   [
1219     #ifdef HAVE_SIGNAL_H
1220     #  include <signal.h>
1221     #endif
1222   ],
1223   sig_t, void(*sig_t)(int), [signal action callback function]
1224 )
1225
1226 dnl #
1227 dnl #  Check for __uint128_t (compiler builtin)
1228 dnl #
1229 AC_CHECK_TYPE(__uint128_t, AC_DEFINE(HAVE___UINT128_T, 1, [compiler specific 128 bit unsigned integer]), [], [])
1230
1231 dnl #
1232 dnl #  Check for uint128_t (fictitious future data type)
1233 dnl #
1234 AC_CHECK_TYPE(uint128_t, AC_DEFINE(HAVE_UINT128_T, 1, [128 bit unsigned integer]), [],
1235   [
1236     #ifdef HAVE_INTTYPES_H
1237     #  include <inttypes.h>
1238     #endif
1239
1240     #ifdef HAVE_STDINT_H
1241     #  include <stdint.h>
1242     #endif
1243   ]
1244 )
1245
1246 AC_CHECK_TYPE(struct in6_addr, AC_DEFINE(HAVE_STRUCT_IN6_ADDR, 1, [IPv6 address structure]), [],
1247   [
1248     #ifdef HAVE_NETINET_IN_H
1249     #  include <netinet/in.h>
1250     #endif
1251   ]
1252 )
1253
1254 AC_CHECK_TYPE(struct sockaddr_storage, AC_DEFINE(HAVE_STRUCT_SOCKADDR_STORAGE, 1, [Generic socket addresses]), [],
1255   [
1256     #ifdef HAVE_NETINET_IN_H
1257     #  include <netinet/in.h>
1258     #endif
1259
1260     #ifdef HAVE_SYS_SOCKET_H
1261     #  include <sys/socket.h>
1262     #endif
1263 ])
1264
1265 AC_CHECK_TYPE(struct sockaddr_in6, AC_DEFINE(HAVE_STRUCT_SOCKADDR_IN6, 1, [IPv6 socket addresses]), [],
1266   [
1267     #ifdef HAVE_NETINET_IN_H
1268     #  include <netinet/in.h>
1269     #endif
1270 ])
1271
1272 AC_CHECK_TYPE(struct addrinfo, AC_DEFINE(HAVE_STRUCT_ADDRINFO, 1, [Generic DNS lookups]), [],
1273   [
1274     #ifdef HAVE_SYS_TYPES_H
1275     #  include <sys/types.h>
1276     #endif
1277
1278     #ifdef HAVE_SYS_SOCKET_H
1279     #  include <sys/socket.h>
1280     #endif
1281
1282     #ifdef HAVE_NETDB_H
1283     #  include <netdb.h>
1284     #endif
1285   ]
1286 )
1287
1288 dnl #############################################################
1289 dnl #
1290 dnl #  5. Checks for structures and functions
1291 dnl #
1292 dnl #############################################################
1293 AC_CHECK_FUNCS( \
1294   getopt_long \
1295   fcntl \
1296   strsignal \
1297   sigaction \
1298   sigprocmask \
1299   pthread_sigmask \
1300   snprintf \
1301   vsnprintf \
1302   setsid \
1303   strncasecmp \
1304   strcasecmp \
1305   localtime_r \
1306   ctime_r \
1307   gmtime_r \
1308   strsep \
1309   inet_aton \
1310   inet_pton \
1311   inet_ntop \
1312   setlinebuf \
1313   setvbuf \
1314   getusershell \
1315   initgroups \
1316   getaddrinfo \
1317   getnameinfo \
1318   closefrom \
1319   gettimeofday \
1320   getpeereid \
1321   setuid \
1322   setresuid \
1323   getresuid \
1324   strlcat \
1325   strlcpy
1326 )
1327
1328 AC_TYPE_SIGNAL
1329
1330 dnl #
1331 dnl #  Check if we have utmpx.h
1332 dnl #  if so, check if struct utmpx has entry ut_xtime
1333 dnl #  if not, set it to define ut_xtime == ut_tv.tv_sec
1334 dnl #
1335 if test "x$ac_cv_header_utmpx_h" = "xyes"; then
1336  FR_CHECK_STRUCT_HAS_MEMBER([#include <utmpx.h>], [struct utmpx], ut_xtime)
1337  if test "x$ac_cv_type_struct_utmpx_has_ut_xtime" = "x"; then
1338    AC_DEFINE(ut_xtime, ut_tv.tv_sec, [define to something if you don't have ut_xtime in struct utmpx])
1339  fi
1340 fi
1341
1342 dnl #
1343 dnl #  struct ip_pktinfo
1344 dnl #
1345 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in_pktinfo], ipi_addr)
1346 if test "x$ac_cv_type_struct_in_pktinfo_has_ipi_addr" = "xyes"; then
1347   AC_DEFINE(HAVE_IP_PKTINFO, [], [define if you have IP_PKTINFO (Linux)])
1348 fi
1349
1350 dnl #
1351 dnl #  struct in6_pktinfo
1352 dnl #
1353 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in6_pktinfo], ipi6_addr)
1354 if test "x$ac_cv_type_struct_in6_pktinfo_has_ipi6_addr" = "xyes"; then
1355   AC_DEFINE(HAVE_IN6_PKTINFO, [], [define if you have IN6_PKTINFO (Linux)])
1356 fi
1357
1358 dnl #############################################################
1359 dnl #
1360 dnl #  6. Checks for compiler characteristics
1361 dnl #
1362 dnl #############################################################
1363
1364 dnl #
1365 dnl #  Ensure that these are defined
1366 dnl #
1367 AC_C_CONST
1368
1369 dnl #
1370 dnl #  See if this is OS/2
1371 dnl #
1372 AC_MSG_CHECKING([type of OS])
1373 OS=`uname -s`
1374 AC_MSG_RESULT($OS)
1375 if test "$OS" = "OS/2"; then
1376   LIBPREFIX=
1377 else
1378   LIBPREFIX=lib
1379 fi
1380 AC_SUBST(LIBPREFIX)
1381
1382 if test "x$developer" = "xyes"; then
1383   AC_MSG_NOTICE([Setting additional developer CFLAGS])
1384
1385   dnl #
1386   dnl #  Tell the compiler to parse doxygen documentation and verify it against function and variable declarations
1387   dnl #
1388   AX_CC_WDOCUMENTATION_FLAG
1389   if test "x$ax_cv_cc_wdocumentation_flag" = "xyes"; then
1390     devflags="-Wdocumentation"
1391   fi
1392
1393   if test "x$GCC" = "xyes"; then
1394     devflags="$devflags -Wshadow -Wpointer-arith -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -W -Wredundant-decls -Wundef -Wformat-y2k -Wno-format-extra-args -Wno-format-zero-length -Wno-cast-align -Wformat-nonliteral -Wformat-security -Wformat=2 -DWITH_VERIFY_PTR=1"
1395     INSTALLSTRIP=""
1396   fi
1397
1398   AC_MSG_NOTICE([Developer CFLAGS are "$devflags"])
1399
1400   CFLAGS="$CFLAGS $devflags"
1401   dnl #
1402   dnl #  Enable experimental modules (we want to know if code changes breaks one of them)
1403   dnl #
1404   if test "x$EXPERIMENTAL" != "xno"; then
1405     AC_MSG_NOTICE([is developer build, enabling experimental modules implicitly, disable with --without-experimental-modules])
1406     EXPERIMENTAL=yes
1407   fi
1408 else
1409   devflags=""
1410   CFLAGS="$CFLAGS -DNDEBUG"
1411   INSTALLSTRIP=""
1412 fi
1413
1414 dnl #
1415 dnl #  May of been set outside of this configure script
1416 dnl #
1417 AC_MSG_CHECKING([if building with -DNDEBUG])
1418 if echo "$CFLAGS" | grep '\-DNDEBUG' > /dev/null; then
1419   AC_MSG_RESULT([yes])
1420   AC_DEFINE([WITH_NDEBUG], [1], [define if the server was built with -DNDEBUG])
1421 else
1422   AC_MSG_RESULT([no])
1423 fi
1424
1425 export EXPERIMENTAL
1426
1427 dnl #
1428 dnl #  append the current git hash onto the version string
1429 dnl #
1430 if test -d $srcdir/.git -a "x$GIT" = "xyes"; then
1431   RADIUSD_VERSION_COMMIT=`git log --pretty=format:'%h' -n 1`
1432   AC_DEFINE_UNQUOTED([RADIUSD_VERSION_COMMIT],[${RADIUSD_VERSION_COMMIT}],[Commit HEAD at time of configuring])
1433 fi
1434
1435 FR_TLS
1436
1437 dnl #############################################################
1438 dnl #
1439 dnl #  7. Checks for library functions
1440 dnl #
1441 dnl #############################################################
1442
1443 dnl #
1444 dnl # Check for talloc_set_memlimit
1445 dnl # This was only included in version 2.0.8
1446 dnl #
1447 AC_CHECK_LIB(talloc, talloc_set_memlimit,
1448   [
1449     AC_DEFINE(HAVE_TALLOC_SET_MEMLIMIT, 1, [Define to 1 if you have the function talloc_set_memlimit.])
1450   ]
1451 )
1452
1453 dnl #
1454 dnl # Check for libcrypt
1455 dnl # We use crypt(3) which may be in libc, or in libcrypt (eg FreeBSD)
1456 dnl #
1457 AC_CHECK_LIB(crypt, crypt,
1458   CRYPTLIB="-lcrypt"
1459 )
1460
1461 if test "$CRYPTLIB" != ""; then
1462   AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function])
1463 else
1464   AC_CHECK_FUNC(crypt, AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function]))
1465 fi
1466
1467 dnl Check for libcipher
1468 AC_CHECK_LIB(cipher, setkey,
1469    CRYPTLIB="${CRYPTLIB} -lcipher"
1470 )
1471 AC_SUBST(CRYPTLIB)
1472
1473 dnl #
1474 dnl #  Check for libexecinfo support, on some systems this is built into libc
1475 dnl #  on others it's a separate library.
1476 dnl #
1477 dnl extra argument: --with-execinfo-lib-dir
1478 execinfo_lib_dir=
1479 AC_ARG_WITH(execinfo-lib-dir,
1480 [AS_HELP_STRING([--with-execinfo-lib-dir=DIR],
1481 [directory in which to look for execinfo library files])],
1482 [ case "$withval" in
1483     no)
1484         AC_MSG_ERROR([Need execinfo-lib-dir])
1485         ;;
1486     yes)
1487         ;;
1488     *)
1489         execinfo_lib_dir="$withval"
1490         ;;
1491   esac ]
1492 )
1493
1494 dnl extra argument: --with-execinfo-include-dir
1495 execinfo_include_dir=
1496 AC_ARG_WITH(execinfo-include-dir,
1497 [AS_HELP_STRING([--with-execinfo-include-dir=DIR],
1498 [directory in which to look for execinfo include files])],
1499 [ case "$withval" in
1500     no)
1501         AC_MSG_ERROR([Need execinfo-include-dir])
1502         ;;
1503     yes)
1504         ;;
1505     *)
1506         execinfo_include_dir="$withval"
1507         ;;
1508   esac ]
1509 )
1510
1511 dnl #
1512 dnl #  Look for execinfo.h and symbols
1513 dnl #
1514 smart_try_dir=$execinfo_include_dir
1515 FR_SMART_CHECK_INCLUDE(execinfo.h)
1516 if test "x$ac_cv_header_execinfo_h" = "xyes"; then
1517   smart_try_dir=$execinfo_lib_dir
1518   FR_SMART_CHECK_LIB(execinfo, backtrace_symbols)
1519   if test "x$ac_cv_lib_execinfo_backtrace_symbols" != "xyes"; then
1520     dnl # Might be provided as part of libc
1521     AC_MSG_CHECKING([if execinfo provided as part of libc])
1522     AC_TRY_LINK(
1523       [
1524         #include <execinfo.h>
1525       ],
1526       [
1527         void *sym[1];
1528         backtrace_symbols(&sym, sizeof(sym)) ],
1529       [
1530         AC_MSG_RESULT(yes)
1531         ac_cv_lib_execinfo_backtrace_symbols="yes"
1532       ],
1533       [
1534         AC_MSG_RESULT(no)
1535       ]
1536     )
1537   fi
1538
1539   if test "x$ac_cv_lib_execinfo_backtrace_symbols" = "xyes"; then
1540     AC_DEFINE(HAVE_EXECINFO, [1], [define this if we have <execinfo.h> and symbols])
1541   fi
1542 fi
1543
1544 dnl #
1545 dnl #  Check for regular expression support, if were using PCRE it MUST be included
1546 dnl #  before all others, else we seem to still pickup the posix symbols for regcomp
1547 dnl #  and regexec, which results in crashes as soon as we call any posix regex
1548 dnl #  functions.
1549 dnl #
1550 dnl extra argument: --with-pcre-lib-dir
1551 pcre_lib_dir=
1552 AC_ARG_WITH(pcre-lib-dir,
1553 [AS_HELP_STRING([--with-pcre-lib-dir=DIR],
1554 [directory in which to look for pcre library files])],
1555 [ case "$withval" in
1556     no)
1557         AC_MSG_ERROR(Need pcre-lib-dir)
1558         ;;
1559     yes)
1560         ;;
1561     *)
1562         pcre_lib_dir="$withval"
1563         ;;
1564   esac ]
1565 )
1566
1567 dnl extra argument: --with-pcre-include--dir
1568 pcre_include_dir=
1569 AC_ARG_WITH(pcre-include-dir,
1570 [AS_HELP_STRING([--with-pcre-include-dir=DIR],
1571 [directory in which to look for pcre include files])],
1572 [ case "$withval" in
1573     no)
1574         AC_MSG_ERROR(Need pcre-include-dir)
1575         ;;
1576     yes)
1577         ;;
1578     *)
1579         pcre_include_dir="$withval"
1580         ;;
1581   esac ]
1582 )
1583
1584 REGEX=no
1585 REGEX_EXTENDED=no
1586 REGEX_PCRE=no
1587
1588 dnl #
1589 dnl #  First look for PCRE
1590 dnl #
1591 smart_try_dir=$pcre_include_dir
1592 FR_SMART_CHECK_INCLUDE(pcreposix.h)
1593 if test "x$ac_cv_header_pcreposix_h" = "xyes"; then
1594   AC_DEFINE(HAVE_REGEX_H, [1], [define if we have any regex])
1595   AC_DEFINE(HAVE_PCREPOSIX_H, [1], [define this if we have the <pcreposix.h> header file])
1596   REGEX=yes
1597   REGEX_EXTENDED=yes
1598   REGEX_PCRE=yes
1599   LIBS="-lpcre -lpcreposix $LIBS"
1600
1601 dnl #
1602 dnl #  Then fallback to POSIX regular expressions
1603 dnl #
1604 else
1605   smart_try_dir=
1606   FR_SMART_CHECK_INCLUDE(regex.h)
1607   if test "x$ac_cv_header_regex_h" = "xyes"; then
1608     AC_DEFINE(HAVE_REGEX_H, [1], [define if we have any regex])
1609     REGEX=yes
1610     AC_EGREP_CPP(yes,
1611       [
1612         #include <regex.h>
1613         #ifdef REG_EXTENDED
1614         yes
1615         #endif
1616        ],
1617     [AC_DEFINE(HAVE_REG_EXTENDED, [1], [define this if we have REG_EXTENDED (from <regex.h>)]) REGEX_EXTENDED=yes]
1618     )
1619 dnl #
1620 dnl # Fixme, this is needed for mingw builds, but not available on some Linux systems
1621 dnl # despite the presence of regex.h
1622 dnl #
1623 dnl # LIBS="$LIBS -lregex"
1624   fi
1625 fi
1626
1627 AC_SUBST(REGEX)
1628 AC_SUBST(REGEX_PCRE)
1629 AC_SUBST(REGEX_EXTENDED)
1630
1631 dnl #
1632 dnl #  Check the style of gethostbyaddr, in order of preference
1633 dnl #  GNU (_r eight args)
1634 dnl #
1635 AC_DEFINE(GNUSTYLE, [1], [GNU-Style get*byaddr_r])
1636
1637 dnl #
1638 dnl #  SYSV (_r six args)
1639 dnl #
1640 AC_DEFINE(SYSVSTYLE, [2], [SYSV-Style get*byaddr_r])
1641
1642 dnl #
1643 dnl #  BSD (three args, may not be thread safe)
1644 dnl #
1645 AC_DEFINE(BSDSTYLE, [3], [BSD-Style get*byaddr_r])
1646
1647 dnl #
1648 dnl #  Tru64 has BSD version, but it is thread safe
1649 dnl #  http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1739____.HTM
1650 dnl #  We need #stdio.h to define NULL on FreeBSD (at least)
1651 dnl #
1652 gethostbyaddrrstyle=""
1653 AC_MSG_CHECKING([gethostbyaddr_r() syntax])
1654 case "$host" in
1655   *-freebsd*)
1656     dnl #
1657     dnl #  With FreeBSD, check if there's a prototype for gethostbyaddr_r.
1658     dnl #  Some versions (FreeBSD 5.1?) have a symbol but no prototype - so we
1659     dnl #  override this test to BSDSTYLE. FreeBSD 6.2 and up have proper GNU
1660     dnl #  style support.
1661     dnl #
1662     AC_CHECK_DECLS([gethostbyaddr_r], [],
1663       [
1664         AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE,
1665           [style of gethostbyaddr_r functions ])
1666         gethostbyaddrrstyle=BSD
1667         AC_MSG_WARN([FreeBSD overridden to BSD-style])
1668       ],
1669       [
1670         #ifdef HAVE_NETDB_H
1671         #include <netdb.h>
1672         #endif
1673       ])
1674     ;;
1675 esac
1676
1677 if test "x$gethostbyaddrrstyle" = "x"; then
1678   AC_TRY_LINK(
1679     [
1680       #include <stdio.h>
1681       #include <netdb.h>
1682     ],
1683     [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL, NULL) ],
1684     [
1685       AC_DEFINE(GETHOSTBYADDRRSTYLE, GNUSTYLE, [style of gethostbyaddr_r functions ])
1686       gethostbyaddrrstyle=GNU
1687     ]
1688   )
1689 fi
1690
1691 if test "x$gethostbyaddrrstyle" = "x"; then
1692   AC_TRY_LINK(
1693     [
1694       #include <stdio.h>
1695       #include <netdb.h>
1696     ],
1697     [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL) ] ,
1698     [
1699       AC_DEFINE(GETHOSTBYADDRRSTYLE, SYSVSTYLE, [style of gethostbyaddr_r functions ])
1700       gethostbyaddrrstyle=SYSV
1701     ]
1702   )
1703 fi
1704
1705
1706 if test "x$gethostbyaddrrstyle" = "x"; then
1707   AC_TRY_LINK(
1708     [
1709       #include <stdio.h>
1710       #include <netdb.h>
1711     ],
1712     [ gethostbyaddr(NULL, 0, 0)  ],
1713     [
1714       AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE, [style of gethostbyaddr_r functions ])
1715       gethostbyaddrrstyle=BSD
1716     ]
1717   )
1718 fi
1719
1720 if test "x$gethostbyaddrrstyle" = "x"; then
1721   AC_MSG_RESULT([none!  It must not exist, here.])
1722 else
1723   AC_MSG_RESULT([${gethostbyaddrrstyle}-style])
1724 fi
1725
1726 if test "x$gethostbyaddrrstyle" = "xBSD"; then
1727   AC_MSG_WARN([ ****** BSD-style gethostbyaddr might NOT be thread-safe! ****** ])
1728 fi
1729
1730 dnl #
1731 dnl #  Check the style of gethostbyname, in order of preference
1732 dnl #  GNU (_r seven args)
1733 dnl #  SYSV (_r five args)
1734 dnl #  BSD (two args, may not be thread safe)
1735 dnl #  Tru64 has BSD version, but it _is_ thread safe
1736 dnl #    http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1946____.HTM
1737 dnl #  We need #stdio.h to define NULL on FreeBSD (at least)
1738 dnl #
1739 gethostbynamerstyle=""
1740 AC_MSG_CHECKING([gethostbyname_r() syntax])
1741 AC_TRY_LINK(
1742   [
1743     #include <stdio.h>
1744     #include <netdb.h>
1745   ],
1746   [ gethostbyname_r(NULL, NULL, NULL, 0, NULL, NULL) ],
1747   [
1748     AC_DEFINE(GETHOSTBYNAMERSTYLE, GNUSTYLE, [style of gethostbyname_r functions ])
1749     gethostbynamerstyle=GNU
1750   ]
1751 )
1752
1753 if test "x$gethostbynamerstyle" = "x"; then
1754   AC_TRY_LINK(
1755     [
1756       #include <stdio.h>
1757       #include <netdb.h>
1758     ],
1759     [ gethostbyname_r(NULL, NULL, NULL, 0, NULL) ] ,
1760     [
1761       AC_DEFINE(GETHOSTBYNAMERSTYLE, SYSVSTYLE, [style of gethostbyname_r functions ])
1762       gethostbynamerstyle=SYSV
1763     ]
1764   )
1765 fi
1766
1767 if test "x$gethostbynamerstyle" = "x"; then
1768   AC_TRY_LINK(
1769     [
1770       #include <stdio.h>
1771       #include <netdb.h>
1772     ],
1773     [ gethostbyname(NULL) ],
1774     [
1775       AC_DEFINE(GETHOSTBYNAMERSTYLE, BSDSTYLE, [style of gethostbyname_r functions ])
1776       gethostbynamerstyle=BSD
1777     ]
1778   )
1779 fi
1780
1781 if test "x$gethostbynamerstyle" = "x"; then
1782   AC_MSG_RESULT([none!  It must not exist, here.])
1783 else
1784   AC_MSG_RESULT([${gethostbynamerstyle}-style])
1785 fi
1786
1787 if test "x$gethostbynamerstyle" = "xBSD"; then
1788   AC_MSG_WARN([ ****** BSD-style gethostbyname might NOT be thread-safe! ****** ])
1789 fi
1790
1791 dnl #
1792 dnl #  Check for non-posix solaris ctime_r (extra buflen int arg)
1793 dnl #
1794 AC_DEFINE(POSIXSTYLE, [1], [Posix-Style ctime_r])
1795 AC_DEFINE(SOLARISSTYLE, [2], [Solaris-Style ctime_r])
1796 ctimerstyle=""
1797 AC_MSG_CHECKING([ctime_r() syntax])
1798 AC_TRY_LINK(
1799   [
1800     #include <time.h>
1801   ],
1802   [ ctime_r(NULL, NULL, 0) ],
1803   [
1804     AC_DEFINE(CTIMERSTYLE, SOLARISSTYLE, [style of ctime_r function])
1805     ctimerstyle="SOLARIS"
1806   ]
1807 )
1808
1809 if test "x$ctimerstyle" = "x"; then
1810   AC_TRY_LINK(
1811     [
1812       #include <time.h>
1813     ],
1814     [ ctime_r(NULL, NULL) ],
1815     [
1816       AC_DEFINE(CTIMERSTYLE, POSIXSTYLE, [style of ctime_r function])
1817       ctimerstyle="POSIX"
1818     ]
1819   )
1820 fi
1821
1822 if test "x$ctimerstyle" = "x"; then
1823     AC_MSG_RESULT([none!  It must not exist, here.])
1824 else
1825     AC_MSG_RESULT([${ctimerstyle}-style])
1826 fi
1827
1828 AC_SUBST(HOSTINFO, $host)
1829
1830 dnl #############################################################
1831 dnl #
1832 dnl #  8. Checks for system services
1833 dnl #
1834 dnl #############################################################
1835
1836 dnl #
1837 dnl #  Figure out where libtool is located,
1838 dnl #
1839 top_builddir=`pwd`
1840 export top_builddir
1841 AC_MSG_RESULT([top_builddir=$top_builddir])
1842 dnl #  AC_SUBST(top_builddir)
1843
1844 dnl #
1845 dnl #  import libtool stuff
1846 dnl #
1847 dnl #############################################################
1848 dnl #
1849 dnl #  Configure in any module directories.
1850 dnl #
1851 dnl #############################################################
1852
1853 dnl ############################################################
1854 dnl #  Remove any conflicting definitions if autoconf.h
1855 dnl #  is being included by a module.
1856 dnl #############################################################
1857 AH_BOTTOM([#include <freeradius-devel/automask.h>])
1858
1859 dnl ############################################################
1860 dnl #  make modules by list
1861 dnl #############################################################
1862 if test "x$EXPERIMENTAL" = "xyes"; then
1863   for foo in `ls -1 "${srcdir}"/src/modules | grep rlm_`; do
1864     MODULES="$MODULES $foo"
1865   done
1866 else
1867    dnl #
1868    dnl #  make ONLY the stable modules
1869    dnl #
1870    for foo in `cat "${srcdir}"/src/modules/stable`; do
1871       MODULES="$MODULES $foo"
1872    done
1873 fi
1874
1875 dnl ############################################################
1876 dnl #  Add autoconf subdirs, based on the module list we
1877 dnl #  previously created.
1878 dnl #############################################################
1879 mysubdirs=""
1880 for bar in $MODULES; do
1881   if test -f "${srcdir}"/src/modules/$bar/configure; then
1882     mysubdirs="$mysubdirs src/modules/$bar"
1883   fi
1884 done
1885
1886 dnl #
1887 dnl #  Don't change the variable name here.  Autoconf goes bonkers
1888 dnl #  if you do.
1889 dnl #
1890 AC_CONFIG_SUBDIRS($mysubdirs)
1891 AC_SUBST(MODULES)
1892
1893 dnl #############################################################
1894 dnl #
1895 dnl #  Add -Werror last, so it doesn't interfere with autoconf's
1896 dnl #  test programs.
1897 dnl #
1898 dnl #############################################################
1899 if test "x$werror" == "xyes"; then
1900   CFLAGS="-Werror $CFLAGS"
1901 fi
1902
1903 dnl #############################################################
1904 dnl #
1905 dnl #  And finally, output the results.
1906 dnl #
1907 dnl #############################################################
1908 AC_CONFIG_COMMANDS([stamp-h], [echo timestamp > src/include/stamp-h])
1909 AC_CONFIG_COMMANDS([build-radpaths-h], [(cd ./src/include && /bin/sh ./build-radpaths-h)])
1910 AC_CONFIG_COMMANDS([main-chmod], [(cd ./src/main && chmod +x checkrad radlast radtest)])
1911 AC_CONFIG_COMMANDS([scripts-chmod], [(cd ./scripts && chmod +x rc.radiusd cron/radiusd.cron.daily cron/radiusd.cron.monthly cryptpasswd)])
1912
1913 dnl #
1914 dnl #  Substitute whatever libraries we found to be necessary
1915 dnl #
1916 AC_SUBST(LIBS)
1917 AC_SUBST(INSTALLSTRIP)
1918
1919 AC_SUBST(USE_SHARED_LIBS)
1920 USE_STATIC_LIBS="yes"
1921 AC_SUBST(USE_STATIC_LIBS)
1922 AC_SUBST(STATIC_MODULES)
1923
1924 AC_OUTPUT(\
1925   ./Make.inc \
1926   ./src/include/build-radpaths-h \
1927   ./src/main/radsniff.mk \
1928   ./src/main/checkrad \
1929   ./src/main/radlast \
1930   ./src/main/radtest \
1931   ./scripts/rc.radiusd \
1932   ./scripts/cron/radiusd.cron.daily \
1933   ./scripts/cron/radiusd.cron.monthly \
1934   ./scripts/cryptpasswd \
1935   ./raddb/radrelay.conf \
1936   ./raddb/radiusd.conf
1937 )