configure.in

   1 dnl #############################################################
   2 dnl #
   3 dnl #  For information about autoconf, see:
   4 dnl #
   5 dnl #  http://www.gnu.org/software/autoconf/
   6 dnl #
   7 dnl #  The recommended order is:
   8 dnl #
   9 dnl #  AC_INIT(file)
  10 dnl #  0. checks for compiler, libtool, and command line options
  11 dnl #  1. checks for programs
  12 dnl #  2. checks for libraries
  13 dnl #  3. checks for header files
  14 dnl #  4. checks for typedefs
  15 dnl #  5. checks for structures and functions
  16 dnl #  6. checks for compiler characteristics
  17 dnl #  7. checks for library functions
  18 dnl #  8. checks for system services
  19 dnl #  AC_OUTPUT([file...])
  20 dnl #
  21 dnl #############################################################
  22
  23 AC_PREREQ([2.59])
  24 export CFLAGS LIBS LDFLAGS CPPFLAGS
  25 AC_INIT(src/main/radiusd.c)
  26 AC_CONFIG_HEADER(src/include/autoconf.h)
  27 AC_REVISION($Revision$)dnl
  28
  29 dnl # The version of the software
  30 RADIUSD_VERSION=`cat VERSION`
  31 RADIUSD_MAJOR_VERSION=`cat VERSION | sed 's/\..*//'`
  32 RADIUSD_MINOR_VERSION=`cat VERSION | sed 's/^2\.//'`
  33 PACKAGE=freeradius
  34
  35 dnl #############################################################
  36 dnl #
  37 dnl #  0. Checks for compiler, libtool, and command line options.
  38 dnl #
  39 dnl #############################################################
  40
  41 dnl Check for GNU cc
  42 AC_PROG_CC
  43 AC_PROG_CXX
  44
  45 dnl #
  46 dnl # check for AIX, to allow us to use some BSD functions
  47 dnl # must be before macros that call the compiler.
  48 dnl #
  49 AC_AIX
  50
  51 AC_PROG_GCC_TRADITIONAL
  52 AC_PROG_CC_SUNPRO
  53 AC_PROG_RANLIB
  54
  55 dnl #
  56 dnl # Set Default CFLAGS
  57 dnl #
  58 if test "x$GCC" = "xyes"; then
  59     CFLAGS="$CFLAGS -Wall -D_GNU_SOURCE"
  60 fi
  61
  62 dnl Compile in large (2G+) file support.
  63 AC_SYS_LARGEFILE
  64
  65 dnl # check for system bytesex
  66 dnl # AC_DEFINES WORDS_BIGENDIAN
  67 AC_C_BIGENDIAN
  68
  69 dnl Find GNU Make.
  70 AC_CHECK_PROG(GMAKE, gmake, yes, no)
  71 if test $GMAKE = no; then
  72   AC_PATH_PROG(MAKE, make, /usr/local/bin/make)
  73 else
  74   AC_PATH_PROG(MAKE, gmake, /usr/local/gnu/bin/make)
  75 fi
  76 makever=`$ac_cv_path_MAKE --version 2>&1 | grep "GNU Make"`
  77 if test -z "$makever"; then
  78   AC_MSG_ERROR(GNU Make is not installed.  Please download and install it
  79                 from ftp://prep.ai.mit.edu/pub/gnu/make/ before continuing.)
  80 fi
  81
  82 AC_ARG_WITH(system-libltdl,
  83 [  --with-system-libltdl   Use the libltdl installed in your system (default=use our own)],
  84 [
  85 LIBLTDL="-lltdl"
  86 INCLTDL=-DWITH_SYSTEM_LTDL
  87 LTDL_SUBDIRS=
  88 enable_ltdl_install=no
  89 ],
  90 [
  91 dnl If libltdl isn't installable, set it to be installable.
  92 [test x"$enable_ltdl_install" = x && enable_ltdl_install=yes]
  93 AC_LIBLTDL_INSTALLABLE
  94
  95 dnl tell Makefile to build ltdl if needed
  96 if test x"$enable_ltdl_install" = x"yes"; then
  97   LTDL_SUBDIRS=libltdl
  98 fi
  99 ])
 100 AC_SUBST(LTDL_SUBDIRS)
 101
 102 dnl use system-wide libtool, if it exists
 103 AC_ARG_WITH(system-libtool,
 104 [  --with-system-libtool   Use the libtool installed in your system (default=use our own)],
 105 [ AC_PATH_PROG(LIBTOOL, libtool,,$PATH:/usr/local/bin) AC_LIBTOOL_DLOPEN
 106  AC_PROG_LIBTOOL],
 107 [
 108   LIBTOOL="`pwd`/libtool"
 109   AC_SUBST(LIBTOOL)
 110   dnl ensure that we're looking for dlopen
 111   AC_LIBTOOL_DLOPEN
 112
 113   dnl Figure out how to build shared libraries
 114   AC_PROG_LIBTOOL
 115 ])
 116
 117
 118 dnl Put this in later, when all distributed modules use autoconf.
 119 dnl AC_ARG_WITH(disablemodulefoo,
 120 dnl [  --without-rlm_foo       Disables module compilation.  Module list:]
 121 dnl esyscmd([find src/modules -type d -name rlm_\* -print |\
 122 dnl     sed -e 's%src/modules/.*/% (sub)- %; s%.*/%- %' |\
 123 dnl     awk '{print "                            "$0}']))
 124
 125 AC_ARG_ENABLE(strict-dependencies,
 126 [  --enable-strict-dependencies  Fail configure on lack of module dependancy.])
 127
 128 dnl extra argument: --with-docdir
 129 docdir='${datadir}/doc/freeradius'
 130 AC_MSG_CHECKING(docdir)
 131 AC_ARG_WITH(docdir,
 132 [  --with-docdir=DIR       Directory for documentation [DATADIR/doc/freeradius] ],
 133 [ case "$withval" in
 134     no)
 135         docdir=no
 136         ;;
 137     yes)
 138         ;;
 139     [[\\/$]]* | ?:[[\\/]]* )
 140         docdir="$withval"
 141         ;;
 142     *)
 143         AC_MSG_ERROR([expected an absolute directory name for --with-docdir: $withval])
 144         ;;
 145   esac ]
 146 )
 147 AC_SUBST(docdir)
 148 AC_MSG_RESULT($docdir)
 149 if test "x$docdir" = xno; then
 150         AC_MSG_WARN(Documentation files will NOT be installed.)
 151 fi
 152
 153 dnl extra argument: --with-logdir
 154 logdir='${localstatedir}/log/radius'
 155 AC_MSG_CHECKING(logdir)
 156 AC_ARG_WITH(logdir,
 157 [  --with-logdir=DIR       Directory for logfiles [LOCALSTATEDIR/log/radius] ],
 158 [ case "$withval" in
 159     no)
 160         AC_MSG_ERROR(Need logdir)
 161         ;;
 162     yes)
 163         ;;
 164     [[\\/$]]* | ?:[[\\/]]* )
 165         logdir="$withval"
 166         ;;
 167     *)
 168         AC_MSG_ERROR([expected an absolute directory name for --with-logdir: $withval])
 169         ;;
 170   esac ]
 171 )
 172 AC_SUBST(logdir)
 173 AC_MSG_RESULT($logdir)
 174
 175 dnl extra argument: --with-radacctdir
 176 radacctdir='${logdir}/radacct'
 177 AC_MSG_CHECKING(radacctdir)
 178 AC_ARG_WITH(radacctdir,
 179 [  --with-radacctdir=DIR   Directory for detail files [LOGDIR/radacct] ],
 180 [ case "$withval" in
 181     no)
 182         AC_MSG_ERROR(Need radacctdir)
 183         ;;
 184     yes)
 185         ;;
 186     [[\\/$]]* | ?:[[\\/]]* )
 187         radacctdir="$withval"
 188         ;;
 189     *)
 190         AC_MSG_ERROR([expected an absolute directory name for --with-radacctdir: $withval])
 191         ;;
 192   esac ]
 193 )
 194 AC_SUBST(radacctdir)
 195 AC_MSG_RESULT($radacctdir)
 196
 197 dnl extra argument: --with-raddbdir
 198 raddbdir='${sysconfdir}/raddb'
 199 AC_MSG_CHECKING(raddbdir)
 200 AC_ARG_WITH(raddbdir,
 201 [  --with-raddbdir=DIR     Directory for config files [SYSCONFDIR/raddb] ],
 202 [ case "$withval" in
 203     no)
 204         AC_MSG_ERROR(Need raddbdir)
 205         ;;
 206     yes)
 207         ;;
 208     [[\\/$]]* | ?:[[\\/]]* )
 209         raddbdir="$withval"
 210         ;;
 211     *)
 212         AC_MSG_ERROR([expected an absolute directory name for --with-raddbdir: $withval])
 213         ;;
 214   esac ]
 215 )
 216 AC_SUBST(raddbdir)
 217 AC_MSG_RESULT($raddbdir)
 218
 219 dnl extra argument: --with-ascend-binary
 220 ASCEND_BINARY=yes
 221 AC_ARG_WITH(ascend-binary,
 222 [  --with-ascend-binary    Include support for Ascend binary filter attributes (default=yes)],
 223 [ case "$withval" in
 224     yes)
 225         ;;
 226     *)
 227         ASCEND_BINARY=""
 228   esac ]
 229 )
 230 if test "X$ASCEND_BINARY" = "Xyes"; then
 231   AC_DEFINE(ASCEND_BINARY, [], [Include support for Ascend binary filter attributes])
 232 fi
 233
 234 dnl extra argument: --with-threads
 235 WITH_THREADS=yes
 236 AC_ARG_WITH(threads,
 237 [  --with-threads          Use threads, if available.  (default=yes) ],
 238 [ case "$withval" in
 239     yes)
 240         ;;
 241     *)
 242         WITH_THREADS=""
 243   esac ]
 244 )
 245
 246 dnl extra argument: --with-vmps
 247 WITH_VMPS=yes
 248 AC_ARG_WITH(vmps,
 249 [  --with-vmps             Compile in VMPS support. (default=yes)],
 250 [ case "$withval" in
 251     yes)
 252         ;;
 253     *)
 254         WITH_VMPS=no
 255   esac ]
 256 )
 257 if test "x$WITH_VMPS" = "xyes"; then
 258         AC_DEFINE(WITH_VMPS, [1], [define if you want VMPS support])
 259 fi
 260
 261 dnl extra argument: --with-dhcp
 262 AC_ARG_WITH(dhcp,
 263 [  --with-dhcp             Compile in DHCP support. (default=no)],
 264 [ case "$withval" in
 265     yes)
 266         AC_DEFINE(WITH_DHCP, [1], [Include experimental support for DHCP])
 267         ;;
 268     *)
 269         ;;
 270   esac ]
 271 )
 272
 273
 274 dnl #
 275 dnl #  Allow the user to specify a list of modules to be linked
 276 dnl #  statically to the server.
 277 dnl #
 278 STATIC_MODULES=
 279 AC_ARG_WITH(static_modules,
 280 [  --with-static-modules=QUOTED-MODULE-LIST],[
 281   for i in $withval; do
 282     STATIC_MODULES="$STATIC_MODULES -dlpreopen ../modules/rlm_$i/rlm_$i.la"
 283   done
 284 ])
 285
 286 MODULES=
 287 AC_ARG_WITH(modules,
 288 [ --with-modules=QUOTED-MODULE-LIST],[
 289  for i in $withval; do
 290    MODULES="$MODULES $i"
 291  done
 292 ])
 293
 294 dnl #
 295 dnl #  Enable developer C compiler warnings
 296 dnl #
 297 AC_ARG_ENABLE(developer,
 298 [  --enable-developer               Enables features of interest to developers.],
 299 [ case "$enableval" in
 300     no)
 301         developer=no
 302         ;;
 303     *)
 304         developer=yes
 305   esac ]
 306 )
 307
 308 if test "x$developer" != "xno" -a -d $srcdir/CVS; then
 309   dnl turn on the developer flag when taken from a CVS checkout (not a release)
 310   developer="yes"
 311 fi
 312
 313 if test "x$developer" != "xno" -a -d $srcdir/.git; then
 314   dnl turn on the developer flag when taken from a git checkout (not a release)
 315   developer="yes"
 316 fi
 317
 318 dnl extra argument: --with-experimental-modules
 319 EXPERIMENTAL=
 320 AC_ARG_WITH(experimental-modules,
 321 [  --with-experimental-modules      Use experimental and unstable modules. (default=no) ],
 322 [ case "$withval" in
 323     yes)
 324         EXPERIMENTAL=yes
 325         ;;
 326     *)
 327   esac ]
 328 )
 329
 330 dnl extra argument: --with-openssl
 331 WITH_OPENSSL=yes
 332 AC_ARG_WITH(openssl,
 333 [  --with-openssl                   Use OpenSSL. (default=yes)],
 334 [ case "$withval" in
 335     no)
 336         WITH_OPENSSL=no
 337         ;;
 338     *)
 339         WITH_OPENSSL=yes
 340         ;;
 341   esac ]
 342 )
 343
 344 dnl #
 345 dnl # extra argument: --with-openssl-includes=dir
 346 dnl #
 347 OPENSSL_INCLUDE_DIR=
 348 AC_ARG_WITH(openssl-includes,
 349 [  --with-openssl-includes=DIR      Directory to look for OpenSSL include files],
 350 [ case "$withval" in
 351     *) OPENSSL_INCLUDE_DIR="$withval"
 352         ;;
 353   esac ]
 354 )
 355
 356 dnl #
 357 dnl # extra argument: --with-openssl-libraries=dir
 358 dnl #
 359 OPENSSL_LIB_DIR=
 360 AC_ARG_WITH(openssl-libraries,
 361 [  --with-openssl-libraries=DIR     Directory to look for OpenSSL library files],
 362 [ case "$withval" in
 363     *) OPENSSL_LIB_DIR="$withval"
 364         ;;
 365   esac ]
 366 )
 367
 368 dnl #
 369 dnl #  These next two arguments don't actually do anything.  They're
 370 dnl #  place holders so that the top-level configure script can tell
 371 dnl #  the user how to configure lower-level modules
 372 dnl #
 373
 374 dnl #
 375 dnl # extra argument: --with-rlm-FOO-lib-dir
 376 dnl #
 377 AC_ARG_WITH(rlm-FOO-lib-dir,
 378 [  --with-rlm-FOO-lib-dir=DIR       Directory to look for library files used by module FOO],
 379 [ case "$withval" in
 380     *)
 381         ;;
 382   esac ]
 383 )
 384
 385 dnl #
 386 dnl # extra argument: --with-rlm-FOO-include-dir
 387 dnl #
 388 AC_ARG_WITH(rlm-FOO-include-dir,
 389 [  --with-rlm-FOO-include-dir=DIR   Directory to look for include files used by module FOO],
 390 [ case "$withval" in
 391     *)
 392         ;;
 393   esac ]
 394 )
 395
 396 dnl See what include-style is used by the make program.
 397 dnl AC_MSG_CHECKING(include style for make)
 398 dnl echo "include /dev/null" > testmake.$$
 399 dnl echo "all:" >> testmake.$$
 400 dnl make -f testmake.$$ >/dev/null 2>&1
 401 dnl if test $? = 0
 402 dnl then
 403 dnl     INCLUDE=include
 404 dnl     IQUOTE=
 405 dnl else
 406 dnl     INCLUDE=.include
 407 dnl     IQUOTE='"'
 408 dnl fi
 409 dnl rm -f testmake.$$
 410 dnl AC_MSG_RESULT(" $INCLUDE")
 411 dnl AC_SUBST(INCLUDE)
 412 dnl AC_SUBST(IQUOTE)
 413
 414 dnl extra argument: --with-udpfromto
 415 WITH_UDPFROMTO=no
 416 AC_ARG_WITH(udpfromto,
 417 [  --with-udpfromto        Compile in UDPFROMTO support. (default=no)],
 418 [ case "$withval" in
 419     yes)
 420         WITH_UDPFROMTO=yes
 421         ;;
 422     *)
 423         WITH_UDPFROMTO=no
 424   esac ]
 425 )
 426
 427 if test "x$WITH_UDPFROMTO" = "xyes"; then
 428         AC_DEFINE(WITH_UDPFROMTO, [], [define if you want udpfromto])
 429 fi
 430
 431 dnl #############################################################
 432 dnl #
 433 dnl #  1. Checks for programs
 434 dnl #
 435 dnl #############################################################
 436
 437 CHECKRAD=checkrad.pl
 438 AC_PATH_PROG(PERL, perl, /usr/local/bin/perl)
 439 if test "x$ac_cv_path_PERL" = "x"; then
 440   AC_MSG_WARN(perl not found - Simultaneous-Use and checkrad.pl may not work)
 441 fi
 442 AC_PATH_PROG(SNMPGET, snmpget)
 443 if test "x$ac_cv_path_SNMPGET" = "x"; then
 444   AC_MSG_WARN(snmpget not found - Simultaneous-Use and checkrad.pl may not work)
 445 fi
 446
 447 AC_PATH_PROG(SNMPWALK, snmpwalk)
 448 if test "x$ac_cv_path_SNMPWALK" = "x"; then
 449   AC_MSG_WARN(snmpwalk not found - Simultaneous-Use and checkrad.pl may not work)
 450 fi
 451
 452 AC_PATH_PROG(RUSERS, rusers, /usr/bin/rusers)
 453
 454 dnl FIXME This is truly gross.
 455 missing_dir=`cd $ac_aux_dir && pwd`
 456 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
 457 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
 458 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
 459
 460 AC_PATH_PROG(LOCATE,locate)
 461 AC_PATH_PROG(DIRNAME,dirname)
 462 AC_PATH_PROG(GREP,grep)
 463
 464 dnl #############################################################
 465 dnl #
 466 dnl #  2. Checks for libraries
 467 dnl #
 468 dnl #############################################################
 469
 470 dnl If using pthreads, check for -lpthread (posix) or -lc_r (*BSD)
 471 old_CFLAGS=$CFLAGS
 472 if test "x$WITH_THREADS" = "xyes"; then
 473   if test $ac_cv_prog_suncc = "yes"; then
 474     CFLAGS="$CFLAGS -mt"
 475   fi
 476
 477   AC_CHECK_HEADERS(pthread.h, [], [ WITH_THREADS="no" ])
 478
 479 dnl #
 480 dnl # pthread stuff is usually in -lpthread
 481 dnl # or in -lc_r, on *BSD
 482 dnl #
 483 dnl # On Some systems, we need extra pre-processor flags, to get them to
 484 dnl # to do the threading properly.
 485 dnl #
 486   AC_CHECK_LIB(pthread, pthread_create,
 487                 [ CFLAGS="$CFLAGS -D_REENTRANT -D_POSIX_PTHREAD_SEMANTICS"
 488                   LIBS="$LIBS -lpthread" ],
 489                 AC_CHECK_LIB(c_r, pthread_create,
 490                             [ CFLAGS="$CFLAGS -pthread -D_THREAD_SAFE" ],
 491                             [ WITH_THREADS="no" ]
 492                             )
 493                 )
 494 fi
 495
 496 dnl #
 497 dnl # If we have NO pthread libraries, remove any knowledge of threads.
 498 dnl #
 499 if test "x$WITH_THREADS" != "xyes"; then
 500   CFLAGS=$old_CFLAGS
 501   ac_cv_header_pthread_h="no"
 502   WITH_THREADS=no
 503 else
 504   dnl #
 505   dnl #  We need sem_init() and friends, as they're the friendliest
 506   dnl #  semaphore functions for threading.
 507   dnl #
 508   dnl # HP/UX requires linking with librt, too, to get the sem_* symbols.
 509   dnl # Some systems have them in -lsem
 510   dnl # Solaris has them in -lposix4
 511   dnl # NetBSD has them in -lsemaphore
 512
 513   AC_SEARCH_LIBS(sem_init, pthread sem posix4 rt semaphore,
 514         [],
 515         [AC_MSG_ERROR(-lsem not found.  You may want to download it from ftp://ftp.to.gd-es.com/pub/BSDI/libsem.tar.bz2 or ftp://ftp.freeradius.org/pub/radius/contrib/libsem.tar.gz)]
 516    )
 517 fi
 518
 519 dnl Check if we need -lsocket
 520 AC_CHECK_LIB(socket, getsockname)
 521
 522 dnl Check for -lresolv
 523 dnl This library may be needed later.
 524 AC_CHECK_LIB(resolv, inet_aton)
 525
 526 dnl Check if we need -lnsl. Usually if we want to
 527 dnl link against -lsocket we need to include -lnsl as well.
 528 AC_CHECK_LIB(nsl, inet_ntoa)
 529
 530 dnl Check for OpenSSL libraries.
 531 OPENSSL_LIBS=
 532 if test "x$WITH_OPENSSL" = xyes; then
 533   old_LIBS=$LIBS
 534   old_LDFLAGS="$LDFLAGS"
 535   if test "x$OPENSSL_LIB_DIR" != "x"; then
 536     LDFLAGS="$LDFLAGS -L$OPENSSL_LIB_DIR"
 537   fi
 538   AC_CHECK_LIB(crypto, DH_new,
 539     [
 540         LIBS="-lcrypto $LIBS"
 541         AC_DEFINE(HAVE_LIBCRYPTO, 1,
 542             [Define to 1 if you have the `crypto' library (-lcrypto).])
 543         AC_CHECK_LIB(ssl, SSL_new,
 544             [
 545                 AC_DEFINE(HAVE_LIBSSL, 1,
 546                     [Define to 1 if you have the `ssl' library (-lssl).])
 547                 if test "x$OPENSSL_LIB_DIR" != "x"; then
 548                     OPENSSL_LIBS="-L$OPENSSL_LIB_DIR"
 549                 fi
 550                 OPENSSL_LIBS="$OPENSSL_LIBS -lcrypto -lssl -lcrypto"
 551             ], [])
 552     ], [])
 553   LIBS=$old_LIBS
 554   LDFLAGS="$old_LDFLAGS"
 555 fi
 556
 557 AC_CHECK_LIB(ws2_32, htonl)
 558
 559 dnl Check the pcap library for the RADIUS sniffer.
 560 PCAP_LIBS=
 561 AC_CHECK_LIB(pcap, pcap_open_live,
 562         [ PCAP_LIBS="-lpcap"
 563         AC_DEFINE(HAVE_LIBPCAP, 1,
 564                 [Define to 1 if you have the `pcap' library (-lpcap).])
 565         ],
 566         [ AC_MSG_WARN([pcap library not found, silently disabling the RADIUS sniffer.]) ])
 567
 568 AC_LIB_READLINE
 569
 570 dnl #############################################################
 571 dnl #
 572 dnl #  3. Checks for header files
 573 dnl #
 574 dnl #############################################################
 575
 576 dnl #
 577 dnl # Interix requires us to set -D_ALL_SOURCE, otherwise
 578 dnl # getopt will be #included, but won't link.  <sigh>
 579 dnl #
 580 dnl #
 581 case "$host" in
 582 *-interix*)
 583         CFLAGS="$CFLAGS -D_ALL_SOURCE"
 584         ;;
 585 *-darwin*)
 586         CFLAGS="$CFLAGS -DDARWIN"
 587         LIBS="-framework DirectoryService $LIBS"
 588         ;;
 589 esac
 590
 591 AC_HEADER_DIRENT
 592 AC_HEADER_STDC
 593 AC_HEADER_TIME
 594 AC_HEADER_SYS_WAIT
 595
 596 AC_CHECK_HEADERS( \
 597         unistd.h \
 598         crypt.h \
 599         errno.h \
 600         resource.h \
 601         sys/resource.h \
 602         getopt.h \
 603         malloc.h \
 604         utmp.h \
 605         utmpx.h \
 606         signal.h \
 607         sys/select.h \
 608         syslog.h \
 609         inttypes.h \
 610         stdint.h \
 611         stdio.h \
 612         netdb.h \
 613         semaphore.h \
 614         arpa/inet.h \
 615         netinet/in.h \
 616         sys/types.h \
 617         sys/socket.h \
 618         winsock.h \
 619         sys/time.h \
 620         sys/wait.h \
 621         sys/security.h \
 622         fcntl.h \
 623         sys/fcntl.h \
 624         sys/prctl.h \
 625         sys/un.h \
 626         glob.h \
 627         prot.h \
 628         pwd.h \
 629         grp.h \
 630         stddef.h \
 631         fnmatch.h \
 632         sia.h \
 633         siad.h
 634 )
 635
 636 dnl FreeBSD requires sys/socket.h before net/if.h
 637 AC_CHECK_HEADERS(net/if.h, [], [],
 638 [#ifdef HAVE_SYS_SOCKET_H
 639 # include <sys/socket.h>
 640 # endif
 641 ])
 642
 643 REGEX=no
 644 AC_CHECK_HEADER(pcreposix.h, AC_DEFINE(HAVE_PCREPOSIX_H, [], [define this if we have the <pcreposix.h> header file]))
 645 if test "x$ac_cv_header_pcreposix_h" = "xyes"; then
 646   AC_DEFINE(HAVE_REGEX_H [], [define if we have any regex])
 647   REGEX_EXTENDED=yes
 648   REGEX_PCRE=yes
 649   REGEX=yes
 650   LIBS="$LIBS -lpcreposix"
 651 else
 652
 653 AC_CHECK_HEADER(regex.h, AC_DEFINE(HAVE_REGEX_H, [], [define this if we have the <regex.h> header file]))
 654 if test "x$ac_cv_header_regex_h" = "xyes"; then
 655   REGEX_EXTENDED=no
 656   REGEX_PCRE=no
 657   REGEX=yes
 658   AC_EGREP_CPP(yes,
 659     [#include <regex.h>
 660      #ifdef REG_EXTENDED
 661        yes
 662      #endif
 663      ], [AC_DEFINE(HAVE_REG_EXTENDED, [], [define this if we have REG_EXTENDED (from <regex.h>)]) REGEX_EXTENDED=yes])
 664 fi
 665 fi
 666
 667 AC_SUBST(REGEX)
 668 AC_SUBST(REGEX_PCRE)
 669 AC_SUBST(REGEX_EXTENDED)
 670
 671 dnl #
 672 dnl #  other checks which require headers
 673 dnl #
 674 if test "x$ac_cv_header_sys_security_h" = "xyes" && test "x$ac_cv_header_prot_h" = "xyes"
 675 then
 676   AC_DEFINE(OSFC2, [], [define if you have OSFC2 authentication])
 677 fi
 678
 679 if test "x$ac_cv_header_sia_h" = "xyes" && test "x$ac_cv_header_siad_h" = "xyes"
 680 then
 681   AC_DEFINE(OSFSIA, [], [define if you have OSFSIA authentication])
 682 fi
 683
 684 dnl Check for OpenSSL includes.
 685 OPENSSL_INCLUDE="-DNO_OPENSSL"
 686 if test "x$WITH_OPENSSL" = xyes; then
 687   if test "x$OPENSSL_LIBS" = "x"; then
 688     AC_MSG_NOTICE([skipping test for openssl/ssl.h])
 689   else
 690     old_CPPFLAGS=$CPPFLAGS
 691     if test "x$OPENSSL_INCLUDE_DIR" != "x"; then
 692         CPPFLAGS="$CPPFLAGS -I$OPENSSL_INCLUDE_DIR"
 693     fi
 694     dnl # stupid RedHat shit
 695     CPPFLAGS="$CPPFLAGS -DOPENSSL_NO_KRB5"
 696     AC_CHECK_HEADERS( \
 697         openssl/ssl.h \
 698         openssl/crypto.h \
 699         openssl/err.h \
 700         openssl/evp.h \
 701         openssl/md5.h \
 702         openssl/md4.h \
 703         openssl/sha.h \
 704         openssl/ocsp.h \
 705         openssl/engine.h,
 706         [],
 707         OPENSSL_LIBS=
 708     )
 709     if test "x$OPENSSL_LIBS" != "x"; then
 710         AC_MSG_CHECKING([for OpenSSL version >= 0.9.7])
 711         AC_EGREP_CPP(yes,
 712             [#include <openssl/crypto.h>
 713              #if (OPENSSL_VERSION_NUMBER >= 0x00907000L)
 714              yes
 715              #endif
 716             ], goodssl="yes")
 717         if test "x$goodssl" != "xyes"; then
 718             AC_MSG_RESULT(no)
 719             OPENSSL_LIBS=
 720         else
 721             AC_MSG_RESULT(yes)
 722             if test "x$OPENSSL_INCLUDE_DIR" != "x"; then
 723                 OPENSSL_INCLUDE="-I$OPENSSL_INCLUDE_DIR -DOPENSSL_NO_KRB5"
 724             else
 725                 OPENSSL_INCLUDE="-DOPENSSL_NO_KRB5"
 726             fi
 727         fi
 728     fi
 729     CPPFLAGS=$old_CPPFLAGS
 730   fi
 731 fi
 732 AC_SUBST(OPENSSL_INCLUDE)
 733 AC_SUBST(OPENSSL_LIBS)
 734 export OPENSSL_LIBS
 735
 736 dnl Check the pcap includes for the RADIUS sniffer.
 737 if test "x$PCAP_LIBS" = x; then
 738     AC_MSG_NOTICE([skipping test for pcap.h.])
 739 else
 740     AC_CHECK_HEADER(pcap.h,
 741         AC_DEFINE(HAVE_PCAP_H, 1,
 742                 [Define to 1 if you have the <pcap.h> header file.]),
 743         [ PCAP_LIBS=
 744         AC_MSG_WARN([pcap.h not found, silently disabling the RADIUS sniffer.])
 745         ])
 746
 747     AC_CHECK_LIB(pcap, pcap_fopen_offline,
 748         [ AC_DEFINE(HAVE_PCAP_FOPEN_OFFLINE, 1,
 749                 [Define to 1 if you have the function pcap_fopen_offline.])
 750         ])
 751     AC_CHECK_LIB(pcap, pcap_dump_fopen,
 752         [ AC_DEFINE(HAVE_PCAP_DUMP_FOPEN, 1,
 753                 [Define to 1 if you have the function pcap_dump_fopen.])
 754         ])
 755 fi
 756 AC_SUBST(PCAP_LIBS)
 757
 758 dnl #############################################################
 759 dnl #
 760 dnl #  4. Checks for typedefs
 761 dnl #
 762 dnl #############################################################
 763
 764 dnl #
 765 dnl # Ensure that these are defined
 766 dnl #
 767 AC_TYPE_OFF_T
 768 AC_TYPE_PID_T
 769 AC_TYPE_SIZE_T
 770 AC_TYPE_UID_T
 771
 772 dnl check for socklen_t
 773 FR_CHECK_TYPE_INCLUDE([
 774 #ifdef HAVE_SYS_TYPES_H
 775 #include <sys/types.h>
 776 #endif
 777 #ifdef HAVE_SYS_SOCKET_H
 778 #include <sys/socket.h>
 779 #endif
 780 ],socklen_t, int, [socklen_t is generally 'int' on systems which don't use it])
 781
 782 dnl check for uint8_t
 783 FR_CHECK_TYPE_INCLUDE([
 784 #ifdef HAVE_INTTYPES_H
 785 #include <inttypes.h>
 786 #endif
 787 #ifdef HAVE_STDINT_H
 788 #include <stdint.h>
 789 #endif
 790 ],uint8_t, unsigned char, [uint8_t should be the canonical 'octet' for network traffic])
 791
 792 dnl check for uint16_t
 793 FR_CHECK_TYPE_INCLUDE([
 794 #ifdef HAVE_INTTYPES_H
 795 #include <inttypes.h>
 796 #endif
 797 #ifdef HAVE_STDINT_H
 798 #include <stdint.h>
 799 #endif
 800 ],uint16_t, unsigned short, [uint16_t should be the canonical '2 octets' for network traffic])
 801
 802 dnl check for uint32_t
 803 FR_CHECK_TYPE_INCLUDE([
 804 #ifdef HAVE_INTTYPES_H
 805 #include <inttypes.h>
 806 #endif
 807 #ifdef HAVE_STDINT_H
 808 #include <stdint.h>
 809 #endif
 810 ],uint32_t, unsigned int, [uint32_t should be the canonical 'network integer])
 811
 812 AC_CHECK_TYPE(struct in6_addr, AC_DEFINE(HAVE_STRUCT_IN6_ADDR, 1, [IPv6 address structure]), [], [
 813 #ifdef HAVE_NETINET_IN_H
 814 #include <netinet/in.h>
 815 #endif
 816 ])
 817
 818 AC_CHECK_TYPE(struct sockaddr_storage, AC_DEFINE(HAVE_STRUCT_SOCKADDR_STORAGE, 1, [Generic socket addresses]), [], [
 819 #ifdef HAVE_NETINET_IN_H
 820 #include <netinet/in.h>
 821 #endif
 822 #ifdef HAVE_SYS_SOCKET_H
 823 #include <sys/socket.h>
 824 #endif
 825 ])
 826
 827 AC_CHECK_TYPE(struct sockaddr_in6, AC_DEFINE(HAVE_STRUCT_SOCKADDR_IN6, 1, [IPv6 socket addresses]), [], [
 828 #ifdef HAVE_NETINET_IN_H
 829 #include <netinet/in.h>
 830 #endif
 831 ])
 832
 833 AC_CHECK_TYPE(struct addrinfo, AC_DEFINE(HAVE_STRUCT_ADDRINFO, 1, [Generic DNS lookups]), [], [
 834 #ifdef HAVE_SYS_TYPES_H
 835 #include <sys/types.h>
 836 #endif
 837 #ifdef HAVE_SYS_SOCKET_H
 838 #include <sys/socket.h>
 839 #endif
 840 #ifdef HAVE_NETDB_H
 841 #include <netdb.h>
 842 #endif
 843 ])
 844
 845 dnl #############################################################
 846 dnl #
 847 dnl #  5. Checks for structures and functions
 848 dnl #
 849 dnl #############################################################
 850 AC_CHECK_FUNCS( \
 851         getopt_long \
 852         lockf \
 853         strsignal \
 854         sigaction \
 855         sigprocmask \
 856         pthread_sigmask \
 857         snprintf \
 858         vsnprintf \
 859         setsid \
 860         strncasecmp \
 861         strcasecmp \
 862         localtime_r \
 863         ctime_r \
 864         gmtime_r \
 865         strsep \
 866         inet_aton \
 867         inet_pton \
 868         inet_ntop \
 869         setlinebuf \
 870         setvbuf \
 871         getusershell \
 872         initgroups \
 873         getaddrinfo \
 874         getnameinfo \
 875         closefrom \
 876         gettimeofday \
 877         getpeereid \
 878         setuid \
 879         setresuid \
 880         getresuid \
 881         strlcat \
 882         strlcpy
 883 )
 884 RADIUSD_NEED_DECLARATIONS( \
 885         crypt \
 886         strncasecmp \
 887         strcasecmp \
 888         inet_aton \
 889         setlinebuf \
 890         getusershell \
 891         endusershell
 892 )
 893
 894 AC_TYPE_SIGNAL
 895
 896 dnl # check if we have utmpx.h
 897 dnl # if so, check if struct utmpx has entry ut_xtime
 898 dnl # if not, set it to define ut_xtime == ut_tv.tv_sec
 899 if test "x$ac_cv_header_utmpx_h" = "xyes"
 900 then
 901  FR_CHECK_STRUCT_HAS_MEMBER([#include <utmpx.h>], [struct utmpx], ut_xtime)
 902  if test "x$ac_cv_type_struct_utmpx_has_ut_xtime" = "x"
 903  then
 904    AC_DEFINE(ut_xtime,ut_tv.tv_sec, [define to something if you don't have ut_xtime in struct utmpx])
 905  fi
 906 fi
 907
 908 dnl # struct ip_pktinfo
 909 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in_pktinfo], ipi_addr)
 910 if test "x$ac_cv_type_struct_in_pktinfo_has_ipi_addr" = "xyes"
 911 then
 912         AC_DEFINE(HAVE_IP_PKTINFO, [], [define if you have IP_PKTINFO (Linux)])
 913 fi
 914
 915 dnl # struct in6_pktinfo
 916 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in6_pktinfo], ipi6_addr)
 917 if test "x$ac_cv_type_struct_in6_pktinfo_has_ipi6_addr" = "xyes"
 918 then
 919         AC_DEFINE(HAVE_IN6_PKTINFO, [], [define if you have IN6_PKTINFO (Linux)])
 920 fi
 921
 922 dnl #############################################################
 923 dnl #
 924 dnl #  6. Checks for compiler characteristics
 925 dnl #
 926 dnl #############################################################
 927
 928 dnl #
 929 dnl # Ensure that these are defined
 930 dnl #
 931 AC_C_CONST
 932
 933 dnl #
 934 dnl # See if this is OS/2
 935 dnl #
 936 AC_MSG_CHECKING(type of OS)
 937 OS=`uname -s`
 938 AC_MSG_RESULT($OS)
 939 if test "$OS" = "OS/2"; then
 940         LIBPREFIX=
 941 else
 942         LIBPREFIX=lib
 943 fi
 944 AC_SUBST(LIBPREFIX)
 945
 946 AC_MSG_CHECKING(for developer gcc flags)
 947 if test "x$developer" = "xyes" -a "x$GCC" = "xyes"; then
 948   devflags="-g -Wshadow -Wpointer-arith -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -W -Wredundant-decls -Wundef"
 949   CFLAGS="$CFLAGS $devflags"
 950   INSTALLSTRIP=""
 951   AC_MSG_RESULT(yes.  Using $devflags)
 952 else
 953   devflags=""
 954   CFLAGS="$CFLAGS -DNDEBUG"
 955   INSTALLSTRIP=""
 956   AC_MSG_RESULT(no.)
 957 fi
 958
 959 FR_TLS
 960
 961 dnl #############################################################
 962 dnl #
 963 dnl #  7. Checks for library functions
 964 dnl #
 965 dnl #############################################################
 966
 967 old_LIBS="$LIBS"
 968 LIBS="$LIBS $LIBLTDL"
 969 AC_CHECK_FUNC(lt_dladvise_init, AC_DEFINE(HAVE_LT_DLADVISE_INIT, [], [Do we have the lt_dladvise_init function]))
 970 LIBS="$old_LIBS"
 971
 972 dnl Check for libcrypt
 973 dnl We use crypt(3) which may be in libc, or in libcrypt (eg FreeBSD)
 974 AC_CHECK_LIB(crypt, crypt,
 975   CRYPTLIB="-lcrypt"
 976 )
 977 if test "$CRYPTLIB" != ""; then
 978   AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function])
 979 else
 980   AC_CHECK_FUNC(crypt, AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function]))
 981 fi
 982
 983 dnl Check for libcipher
 984 AC_CHECK_LIB(cipher, setkey,
 985    CRYPTLIB="${CRYPTLIB} -lcipher"
 986 )
 987 AC_SUBST(CRYPTLIB)
 988
 989 dnl Check the style of gethostbyaddr, in order of preference
 990 dnl GNU (_r eight args)
 991 AC_DEFINE(GNUSTYLE, [1], [GNU-Style get*byaddr_r])
 992 dnl SYSV (_r six args)
 993 AC_DEFINE(SYSVSTYLE, [2], [SYSV-Style get*byaddr_r])
 994 dnl BSD (three args, may not be thread safe)
 995 AC_DEFINE(BSDSTYLE, [3], [BSD-Style get*byaddr_r])
 996 dnl Tru64 has BSD version, but it is thread safe
 997 dnl     http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1739____.HTM
 998 dnl We need #stdio.h to define NULL on FreeBSD (at least)
 999 gethostbyaddrrstyle=""
1000 AC_MSG_CHECKING([gethostbyaddr_r() syntax])
1001 case "$host" in
1002 *-freebsd*)
1003 dnl With FreeBSD, check if there's a prototype for gethostbyaddr_r.
1004 dnl Some versions (FreeBSD 5.1?) have a symbol but no prototype - so we
1005 dnl override this test to BSDSTYLE. FreeBSD 6.2 and up have proper GNU
1006 dnl style support.
1007         AC_CHECK_DECLS([gethostbyaddr_r], [], [
1008                 AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE,
1009                         [style of gethostbyaddr_r functions ])
1010                 gethostbyaddrrstyle=BSD
1011                 AC_MSG_WARN([FreeBSD overridden to BSD-style])
1012         ], [
1013 #ifdef HAVE_NETDB_H
1014 #include <netdb.h>
1015 #endif
1016 ])
1017         ;;
1018 esac
1019 if test "x$gethostbyaddrrstyle" = "x"; then
1020         AC_TRY_LINK([
1021 #include <stdio.h>
1022 #include <netdb.h>
1023 ], [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL, NULL) ], [
1024         AC_DEFINE(GETHOSTBYADDRRSTYLE, GNUSTYLE, [style of gethostbyaddr_r functions ])
1025         gethostbyaddrrstyle=GNU
1026 ])
1027 fi
1028 if test "x$gethostbyaddrrstyle" = "x"; then
1029         AC_TRY_LINK([
1030 #include <stdio.h>
1031 #include <netdb.h>
1032 ], [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL) ] , [
1033                 AC_DEFINE(GETHOSTBYADDRRSTYLE, SYSVSTYLE, [style of gethostbyaddr_r functions ])
1034                 gethostbyaddrrstyle=SYSV
1035         ])
1036 fi
1037 if test "x$gethostbyaddrrstyle" = "x"; then
1038         AC_TRY_LINK([
1039 #include <stdio.h>
1040 #include <netdb.h>
1041 ], [ gethostbyaddr(NULL, 0, 0)  ], [
1042                 AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE, [style of gethostbyaddr_r functions ])
1043                 gethostbyaddrrstyle=BSD
1044         ])
1045 fi
1046
1047 if test "x$gethostbyaddrrstyle" = "x"; then
1048         AC_MSG_RESULT([none!  It must not exist, here.])
1049 else
1050         AC_MSG_RESULT([${gethostbyaddrrstyle}-style])
1051 fi
1052
1053 if test "x$gethostbyaddrrstyle" = "xBSD"; then
1054         AC_MSG_WARN([ ****** BSD-style gethostbyaddr might NOT be thread-safe! ****** ])
1055 fi
1056
1057 dnl Check the style of gethostbyname, in order of preference
1058 dnl GNU (_r seven args)
1059 dnl SYSV (_r five args)
1060 dnl BSD (two args, may not be thread safe)
1061 dnl Tru64 has BSD version, but it _is_ thread safe
1062 dnl     http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1946____.HTM
1063 dnl We need #stdio.h to define NULL on FreeBSD (at least)
1064 gethostbynamerstyle=""
1065 AC_MSG_CHECKING([gethostbyname_r() syntax])
1066 AC_TRY_LINK([
1067 #include <stdio.h>
1068 #include <netdb.h>
1069 ], [ gethostbyname_r(NULL, NULL, NULL, 0, NULL, NULL) ], [
1070         AC_DEFINE(GETHOSTBYNAMERSTYLE, GNUSTYLE, [style of gethostbyname_r functions ])
1071         gethostbynamerstyle=GNU
1072 ])
1073 if test "x$gethostbynamerstyle" = "x"; then
1074         AC_TRY_LINK([
1075 #include <stdio.h>
1076 #include <netdb.h>
1077 ], [ gethostbyname_r(NULL, NULL, NULL, 0, NULL) ] , [
1078                 AC_DEFINE(GETHOSTBYNAMERSTYLE, SYSVSTYLE, [style of gethostbyname_r functions ])
1079                 gethostbynamerstyle=SYSV
1080         ])
1081 fi
1082 if test "x$gethostbynamerstyle" = "x"; then
1083         AC_TRY_LINK([
1084 #include <stdio.h>
1085 #include <netdb.h>
1086 ], [ gethostbyname(NULL)  ], [
1087                 AC_DEFINE(GETHOSTBYNAMERSTYLE, BSDSTYLE, [style of gethostbyname_r functions ])
1088                 gethostbynamerstyle=BSD
1089         ])
1090 fi
1091
1092 if test "x$gethostbynamerstyle" = "x"; then
1093         AC_MSG_RESULT([none!  It must not exist, here.])
1094 else
1095         AC_MSG_RESULT([${gethostbynamerstyle}-style])
1096 fi
1097
1098 if test "x$gethostbynamerstyle" = "xBSD"; then
1099         AC_MSG_WARN([ ****** BSD-style gethostbyname might NOT be thread-safe! ****** ])
1100 fi
1101
1102 dnl check for non-posix solaris ctime_r (extra buflen int arg)
1103 AC_DEFINE(POSIXSTYLE, [1], [Posix-Style ctime_r])
1104 AC_DEFINE(SOLARISSTYLE, [2], [Solaris-Style ctime_r])
1105 ctimerstyle=""
1106 AC_MSG_CHECKING([ctime_r() syntax])
1107 AC_TRY_LINK([
1108 #include <time.h>
1109 ], [ ctime_r(NULL, NULL, 0) ], [
1110         AC_DEFINE(CTIMERSTYLE, SOLARISSTYLE, [style of ctime_r function])
1111         ctimerstyle="SOLARIS"
1112 ])
1113 if test "x$ctimerstyle" = "x"; then
1114         AC_TRY_LINK([
1115 #include <time.h>
1116 ], [ ctime_r(NULL, NULL) ], [
1117                 AC_DEFINE(CTIMERSTYLE, POSIXSTYLE, [style of ctime_r function])
1118                 ctimerstyle="POSIX"
1119         ])
1120 fi
1121
1122 if test "x$ctimerstyle" = "x"; then
1123         AC_MSG_RESULT([none!  It must not exist, here.])
1124 else
1125         AC_MSG_RESULT([${ctimerstyle}-style])
1126 fi
1127
1128 AC_SUBST(HOSTINFO, $host)
1129
1130 dnl #############################################################
1131 dnl #
1132 dnl #  8. Checks for system services
1133 dnl #
1134 dnl #############################################################
1135
1136 dnl #
1137 dnl # Figure out where libtool is located,
1138 dnl #
1139 top_builddir=`pwd`
1140 export top_builddir
1141 AC_MSG_RESULT([top_builddir=$top_builddir])
1142 dnl # AC_SUBST(top_builddir)
1143 AC_SUBST(LIBLTDL)
1144 AC_SUBST(INCLTDL)
1145
1146 dnl import libtool stuff
1147
1148 dnl #############################################################
1149 dnl #
1150 dnl #  Configure in any module directories.
1151 dnl #
1152 dnl #############################################################
1153
1154 mysubdirs="$LIBLTDLPATH"
1155 if test "x$EXPERIMENTAL" = "xyes"; then
1156   bar=`ls -1 "${srcdir}"/src/modules/rlm_*/configure | sed 's%/configure%%'`
1157   dnl # get rid of LF's.
1158   mysubdirs=`echo $mysubdirs $bar`
1159 else
1160   dnl #
1161   dnl # Find 'configure' in ONLY the stable modules
1162   dnl #
1163   for bar in `cat "${srcdir}"/src/modules/stable`; do
1164     if test -f "${srcdir}"/src/modules/$bar/configure; then
1165       mysubdirs="$mysubdirs src/modules/$bar"
1166     fi
1167   done
1168 fi
1169
1170 dnl ############################################################
1171 dnl # make modules by list
1172 dnl #############################################################
1173 if test "x$EXPERIMENTAL" = "xyes"; then
1174   for foo in `ls -1 "${srcdir}"/src/modules | grep rlm_`; do
1175     MODULES="$MODULES $foo"
1176   done
1177 else
1178    dnl #
1179    dnl # make ONLY the stable modules
1180    dnl #
1181    for foo in `cat "${srcdir}"/src/modules/stable`; do
1182     MODULES="$MODULES $foo"
1183    done
1184 fi
1185
1186 dnl #
1187 dnl #  Don't change the variable name here.  Autoconf goes bonkers
1188 dnl #  if you do.
1189 dnl #
1190 AC_CONFIG_SUBDIRS($LTDL_SUBDIRS $mysubdirs)
1191 AC_SUBST(MODULES)
1192
1193 dnl #############################################################
1194 dnl #
1195 dnl #  And finally, output the results.
1196 dnl #
1197 dnl #############################################################
1198
1199 AC_CONFIG_COMMANDS([stamp-h], [echo timestamp > src/include/stamp-h])
1200 AC_CONFIG_COMMANDS([build-radpaths-h], [(cd ./src/include && /bin/sh ./build-radpaths-h)])
1201 AC_CONFIG_COMMANDS([main-chmod], [(cd ./src/main   && chmod +x checkrad.pl radlast radtest)])
1202 AC_CONFIG_COMMANDS([scripts-chmod], [(cd ./scripts    && chmod +x rc.radiusd radwatch radiusd.cron.daily radiusd.cron.monthly cryptpasswd)])
1203
1204 dnl #
1205 dnl #  Substitute whatever libraries we found to be necessary
1206 dnl #
1207 AC_SUBST(LIBS)
1208 AC_SUBST(INSTALLSTRIP)
1209
1210 USE_SHARED_LIBS=$enable_shared
1211 AC_SUBST(USE_SHARED_LIBS)
1212 USE_STATIC_LIBS=$enable_static
1213 AC_SUBST(USE_STATIC_LIBS)
1214 AC_SUBST(STATIC_MODULES)
1215 AC_SUBST(RADIUSD_MAJOR_VERSION)
1216 AC_SUBST(RADIUSD_MINOR_VERSION)
1217 AC_SUBST(RADIUSD_VERSION)
1218
1219 AC_OUTPUT(\
1220         ./Make.inc \
1221         ./src/include/build-radpaths-h \
1222         ./src/main/Makefile \
1223         ./src/main/checkrad.pl \
1224         ./src/main/radlast \
1225         ./src/main/radtest \
1226         ./scripts/rc.radiusd \
1227         ./scripts/radwatch \
1228         ./scripts/radiusd.cron.daily \
1229         ./scripts/radiusd.cron.monthly \
1230         ./scripts/cryptpasswd \
1231         ./raddb/dictionary \
1232         ./raddb/radrelay.conf \
1233         ./raddb/radiusd.conf
1234 )