configure.in

   1 dnl #############################################################
   2 dnl #
   3 dnl #  For information about autoconf, see:
   4 dnl #
   5 dnl #  http://www.gnu.org/software/autoconf/
   6 dnl #
   7 dnl #  The recommended order is:
   8 dnl #
   9 dnl #  AC_INIT(file)
  10 dnl #  0. checks for compiler, libtool, and command line options
  11 dnl #  1. checks for programs
  12 dnl #  2. checks for libraries
  13 dnl #  3. checks for header files
  14 dnl #  4. checks for typedefs
  15 dnl #  5. checks for structures and functions
  16 dnl #  6. checks for compiler characteristics
  17 dnl #  7. checks for library functions
  18 dnl #  8. checks for system services
  19 dnl #  AC_OUTPUT([file...])
  20 dnl #
  21 dnl #############################################################
  22
  23 AC_PREREQ([2.59])
  24 export CFLAGS LIBS LDFLAGS CPPFLAGS
  25 AC_INIT(src/main/radiusd.c)
  26 AC_CONFIG_HEADER(src/include/autoconf.h)
  27 AC_REVISION($Revision$)dnl
  28
  29 dnl # The version of the software
  30 RADIUSD_VERSION=`cat VERSION`
  31 RADIUSD_MAJOR_VERSION=`cat VERSION | sed 's/\..*//'`
  32 RADIUSD_MINOR_VERSION=`cat VERSION | sed 's/^2\.//'`
  33 PACKAGE=freeradius
  34
  35 dnl #############################################################
  36 dnl #
  37 dnl #  0. Checks for compiler, libtool, and command line options.
  38 dnl #
  39 dnl #############################################################
  40
  41 dnl Check for GNU cc
  42 AC_PROG_CC
  43 AC_PROG_CXX
  44
  45 dnl #
  46 dnl # check for AIX, to allow us to use some BSD functions
  47 dnl # must be before macros that call the compiler.
  48 dnl #
  49 AC_AIX
  50
  51 AC_PROG_GCC_TRADITIONAL
  52 AC_PROG_CC_SUNPRO
  53 AC_PROG_RANLIB
  54
  55 dnl Compile in large (2G+) file support.
  56 AC_SYS_LARGEFILE
  57
  58 dnl # check for system bytesex
  59 dnl # AC_DEFINES WORDS_BIGENDIAN
  60 AC_C_BIGENDIAN
  61
  62 dnl Find GNU Make.
  63 AC_CHECK_PROG(GMAKE, gmake, yes, no)
  64 if test $GMAKE = no; then
  65   AC_PATH_PROG(MAKE, make, /usr/local/bin/make)
  66 else
  67   AC_PATH_PROG(MAKE, gmake, /usr/local/gnu/bin/make)
  68 fi
  69 makever=`$ac_cv_path_MAKE --version 2>&1 | grep "GNU Make"`
  70 if test -z "$makever"; then
  71   AC_MSG_ERROR(GNU Make is not installed.  Please download and install it
  72                 from ftp://prep.ai.mit.edu/pub/gnu/make/ before continuing.)
  73 fi
  74
  75 AC_ARG_WITH(system-libtldl,
  76 [  --with-system-libtldl   Use the libltdl installed in your system (default=use our own)],
  77 [
  78 LIBLTDL="-lltdl"
  79 INCLTDL=
  80 LTDL_SUBDIRS=
  81 enable_ltdl_install=no
  82 ],
  83 [
  84 AC_LIBLTDL_INSTALLABLE
  85
  86 dnl tell Makefile to build ltdl if needed
  87 if test x"$enable_ltdl_install" = x"yes"; then
  88   LTDL_SUBDIRS=libltdl
  89 fi
  90 ])
  91 AC_SUBST(LTDL_SUBDIRS)
  92
  93 dnl use system-wide libtool, if it exists
  94 AC_ARG_WITH(system-libtool,
  95 [  --with-system-libtool   Use the libtool installed in your system (default=use our own)],
  96 [ AC_PATH_PROG(LIBTOOL, libtool,,$PATH:/usr/local/bin) ],
  97 [
  98   LIBTOOL="`pwd`/libtool"
  99   AC_SUBST(LIBTOOL)
 100   dnl ensure that we're looking for dlopen
 101   AC_LIBTOOL_DLOPEN
 102
 103   dnl Figure out how to build shared libraries
 104   AC_PROG_LIBTOOL
 105 ])
 106
 107
 108 dnl Put this in later, when all distributed modules use autoconf.
 109 dnl AC_ARG_WITH(disablemodulefoo,
 110 dnl [  --without-rlm_foo       Disables module compilation.  Module list:]
 111 dnl esyscmd([find src/modules -type d -name rlm_\* -print |\
 112 dnl     sed -e 's%src/modules/.*/% (sub)- %; s%.*/%- %' |\
 113 dnl     awk '{print "                            "$0}']))
 114
 115 AC_ARG_ENABLE(strict-dependencies,
 116 [  --enable-strict-dependencies  Fail configure on lack of module dependancy.])
 117
 118 dnl extra argument: --with-docdir
 119 docdir='${datadir}/doc/freeradius'
 120 AC_MSG_CHECKING(docdir)
 121 AC_ARG_WITH(docdir,
 122 [  --with-docdir=DIR       Directory for documentation [DATADIR/doc/freeradius] ],
 123 [ case "$withval" in
 124     no)
 125         docdir=no
 126         ;;
 127     yes)
 128         ;;
 129     [[\\/$]]* | ?:[[\\/]]* )
 130         docdir="$withval"
 131         ;;
 132     *)
 133         AC_MSG_ERROR([expected an absolute directory name for --with-docdir: $withval])
 134         ;;
 135   esac ]
 136 )
 137 AC_SUBST(docdir)
 138 AC_MSG_RESULT($docdir)
 139 if test "x$docdir" = xno; then
 140         AC_MSG_WARN(Documentation files will NOT be installed.)
 141 fi
 142
 143 dnl extra argument: --with-logdir
 144 logdir='${localstatedir}/log/radius'
 145 AC_MSG_CHECKING(logdir)
 146 AC_ARG_WITH(logdir,
 147 [  --with-logdir=DIR       Directory for logfiles [LOCALSTATEDIR/log/radius] ],
 148 [ case "$withval" in
 149     no)
 150         AC_MSG_ERROR(Need logdir)
 151         ;;
 152     yes)
 153         ;;
 154     [[\\/$]]* | ?:[[\\/]]* )
 155         logdir="$withval"
 156         ;;
 157     *)
 158         AC_MSG_ERROR([expected an absolute directory name for --with-logdir: $withval])
 159         ;;
 160   esac ]
 161 )
 162 AC_SUBST(logdir)
 163 AC_MSG_RESULT($logdir)
 164
 165 dnl extra argument: --with-radacctdir
 166 radacctdir='${logdir}/radacct'
 167 AC_MSG_CHECKING(radacctdir)
 168 AC_ARG_WITH(radacctdir,
 169 [  --with-radacctdir=DIR   Directory for detail files [LOGDIR/radacct] ],
 170 [ case "$withval" in
 171     no)
 172         AC_MSG_ERROR(Need radacctdir)
 173         ;;
 174     yes)
 175         ;;
 176     [[\\/$]]* | ?:[[\\/]]* )
 177         radacctdir="$withval"
 178         ;;
 179     *)
 180         AC_MSG_ERROR([expected an absolute directory name for --with-radacctdir: $withval])
 181         ;;
 182   esac ]
 183 )
 184 AC_SUBST(radacctdir)
 185 AC_MSG_RESULT($radacctdir)
 186
 187 dnl extra argument: --with-raddbdir
 188 raddbdir='${sysconfdir}/raddb'
 189 AC_MSG_CHECKING(raddbdir)
 190 AC_ARG_WITH(raddbdir,
 191 [  --with-raddbdir=DIR     Directory for config files [SYSCONFDIR/raddb] ],
 192 [ case "$withval" in
 193     no)
 194         AC_MSG_ERROR(Need raddbdir)
 195         ;;
 196     yes)
 197         ;;
 198     [[\\/$]]* | ?:[[\\/]]* )
 199         raddbdir="$withval"
 200         ;;
 201     *)
 202         AC_MSG_ERROR([expected an absolute directory name for --with-raddbdir: $withval])
 203         ;;
 204   esac ]
 205 )
 206 AC_SUBST(raddbdir)
 207 AC_MSG_RESULT($raddbdir)
 208
 209 dnl extra argument: --with-ascend-binary
 210 ASCEND_BINARY=yes
 211 AC_ARG_WITH(ascend-binary,
 212 [  --with-ascend-binary    Include support for Ascend binary filter attributes (default=yes)],
 213 [ case "$withval" in
 214     yes)
 215         ;;
 216     *)
 217         ASCEND_BINARY=""
 218   esac ]
 219 )
 220 if test "X$ASCEND_BINARY" = "Xyes"; then
 221   AC_DEFINE(ASCEND_BINARY, [], [Include support for Ascend binary filter attributes])
 222 fi
 223
 224 dnl extra argument: --with-threads
 225 WITH_THREADS=yes
 226 AC_ARG_WITH(threads,
 227 [  --with-threads          Use threads, if available.  (default=yes) ],
 228 [ case "$withval" in
 229     yes)
 230         ;;
 231     *)
 232         WITH_THREADS=""
 233   esac ]
 234 )
 235
 236 dnl extra argument: --with-vmps
 237 WITH_VMPS=yes
 238 AC_ARG_WITH(vmps,
 239 [  --with-vmps             Compile in VMPS support. (default=yes)],
 240 [ case "$withval" in
 241     yes)
 242         ;;
 243     *)
 244         WITH_VMPS=no
 245   esac ]
 246 )
 247 if test "x$WITH_VMPS" = "xyes"; then
 248         AC_DEFINE(WITH_VMPS, [1], [define if you want VMPS support])
 249 fi
 250
 251 dnl extra argument: --with-dhcp
 252 AC_ARG_WITH(dhcp,
 253 [  --with-dhcp             Compile in DHCP support. (default=no)],
 254 [ case "$withval" in
 255     yes)
 256         AC_DEFINE(WITH_DHCP, [1], [Include experimental support for DHCP])
 257         ;;
 258     *)
 259         ;;
 260   esac ]
 261 )
 262
 263
 264 dnl #
 265 dnl #  Allow the user to specify a list of modules to be linked
 266 dnl #  statically to the server.
 267 dnl #
 268 STATIC_MODULES=
 269 AC_ARG_WITH(static_modules,
 270 [  --with-static-modules=QUOTED-MODULE-LIST],[
 271   for i in $withval; do
 272     STATIC_MODULES="$STATIC_MODULES -dlpreopen ../modules/rlm_$i/rlm_$i.la"
 273   done
 274 ])
 275
 276 MODULES=
 277 AC_ARG_WITH(modules,
 278 [ --with-modules=QUOTED-MODULE-LIST],[
 279  for i in $withval; do
 280    MODULES="$MODULES $i"
 281  done
 282 ])
 283
 284 dnl #
 285 dnl #  Enable developer C compiler warnings
 286 dnl #
 287 AC_ARG_ENABLE(developer,
 288 [  --enable-developer               Enables features of interest to developers.],
 289 [ case "$enableval" in
 290     no)
 291         developer=no
 292         ;;
 293     *)
 294         developer=yes
 295   esac ]
 296 )
 297
 298 if test "x$developer" != "xno" -a -d $srcdir/CVS; then
 299   dnl turn on the developer flag when taken from a CVS checkout (not a release)
 300   developer="yes"
 301 fi
 302
 303 if test "x$developer" != "xno" -a -d $srcdir/.git; then
 304   dnl turn on the developer flag when taken from a git checkout (not a release)
 305   developer="yes"
 306 fi
 307
 308 dnl extra argument: --with-experimental-modules
 309 EXPERIMENTAL=
 310 AC_ARG_WITH(experimental-modules,
 311 [  --with-experimental-modules      Use experimental and unstable modules. (default=no) ],
 312 [ case "$withval" in
 313     yes)
 314         EXPERIMENTAL=yes
 315         ;;
 316     *)
 317   esac ]
 318 )
 319
 320 dnl extra argument: --with-openssl
 321 WITH_OPENSSL=yes
 322 AC_ARG_WITH(openssl,
 323 [  --with-openssl                   Use OpenSSL. (default=yes)],
 324 [ case "$withval" in
 325     no)
 326         WITH_OPENSSL=no
 327         ;;
 328     *)
 329         WITH_OPENSSL=yes
 330         ;;
 331   esac ]
 332 )
 333
 334 dnl #
 335 dnl # extra argument: --with-openssl-includes=dir
 336 dnl #
 337 OPENSSL_INCLUDE_DIR=
 338 AC_ARG_WITH(openssl-includes,
 339 [  --with-openssl-includes=DIR      Directory to look for OpenSSL include files],
 340 [ case "$withval" in
 341     *) OPENSSL_INCLUDE_DIR="$withval"
 342         ;;
 343   esac ]
 344 )
 345
 346 dnl #
 347 dnl # extra argument: --with-openssl-libraries=dir
 348 dnl #
 349 OPENSSL_LIB_DIR=
 350 AC_ARG_WITH(openssl-libraries,
 351 [  --with-openssl-libraries=DIR     Directory to look for OpenSSL library files],
 352 [ case "$withval" in
 353     *) OPENSSL_LIB_DIR="$withval"
 354         ;;
 355   esac ]
 356 )
 357
 358 dnl #
 359 dnl #  These next two arguments don't actually do anything.  They're
 360 dnl #  place holders so that the top-level configure script can tell
 361 dnl #  the user how to configure lower-level modules
 362 dnl #
 363
 364 dnl #
 365 dnl # extra argument: --with-rlm-FOO-lib-dir
 366 dnl #
 367 AC_ARG_WITH(rlm-FOO-lib-dir,
 368 [  --with-rlm-FOO-lib-dir=DIR       Directory to look for library files used by module FOO],
 369 [ case "$withval" in
 370     *)
 371         ;;
 372   esac ]
 373 )
 374
 375 dnl #
 376 dnl # extra argument: --with-rlm-FOO-include-dir
 377 dnl #
 378 AC_ARG_WITH(rlm-FOO-include-dir,
 379 [  --with-rlm-FOO-include-dir=DIR   Directory to look for include files used by module FOO],
 380 [ case "$withval" in
 381     *)
 382         ;;
 383   esac ]
 384 )
 385
 386 dnl See what include-style is used by the make program.
 387 dnl AC_MSG_CHECKING(include style for make)
 388 dnl echo "include /dev/null" > testmake.$$
 389 dnl echo "all:" >> testmake.$$
 390 dnl make -f testmake.$$ >/dev/null 2>&1
 391 dnl if test $? = 0
 392 dnl then
 393 dnl     INCLUDE=include
 394 dnl     IQUOTE=
 395 dnl else
 396 dnl     INCLUDE=.include
 397 dnl     IQUOTE='"'
 398 dnl fi
 399 dnl rm -f testmake.$$
 400 dnl AC_MSG_RESULT(" $INCLUDE")
 401 dnl AC_SUBST(INCLUDE)
 402 dnl AC_SUBST(IQUOTE)
 403
 404 dnl extra argument: --with-udpfromto
 405 WITH_UDPFROMTO=no
 406 AC_ARG_WITH(udpfromto,
 407 [  --with-udpfromto        Compile in UDPFROMTO support. (default=no)],
 408 [ case "$withval" in
 409     yes)
 410         WITH_UDPFROMTO=yes
 411         ;;
 412     *)
 413         WITH_UDPFROMTO=no
 414   esac ]
 415 )
 416
 417 if test "x$WITH_UDPFROMTO" = "xyes"; then
 418         AC_DEFINE(WITH_UDPFROMTO, [], [define if you want udpfromto])
 419 fi
 420
 421 dnl #############################################################
 422 dnl #
 423 dnl #  1. Checks for programs
 424 dnl #
 425 dnl #############################################################
 426
 427 CHECKRAD=checkrad.pl
 428 AC_PATH_PROG(PERL, perl, /usr/local/bin/perl)
 429 if test "x$ac_cv_path_PERL" = "x"; then
 430   AC_MSG_WARN(perl not found - Simultaneous-Use and checkrad.pl may not work)
 431 fi
 432 AC_PATH_PROG(SNMPGET, snmpget)
 433 if test "x$ac_cv_path_SNMPGET" = "x"; then
 434   AC_MSG_WARN(snmpget not found - Simultaneous-Use and checkrad.pl may not work)
 435 fi
 436
 437 AC_PATH_PROG(SNMPWALK, snmpwalk)
 438 if test "x$ac_cv_path_SNMPWALK" = "x"; then
 439   AC_MSG_WARN(snmpwalk not found - Simultaneous-Use and checkrad.pl may not work)
 440 fi
 441
 442 AC_PATH_PROG(RUSERS, rusers, /usr/bin/rusers)
 443
 444 dnl FIXME This is truly gross.
 445 missing_dir=`cd $ac_aux_dir && pwd`
 446 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
 447 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
 448 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
 449
 450 AC_PATH_PROG(LOCATE,locate)
 451 AC_PATH_PROG(DIRNAME,dirname)
 452 AC_PATH_PROG(GREP,grep)
 453
 454 dnl #############################################################
 455 dnl #
 456 dnl #  2. Checks for libraries
 457 dnl #
 458 dnl #############################################################
 459
 460 dnl If using pthreads, check for -lpthread (posix) or -lc_r (*BSD)
 461 old_CFLAGS=$CFLAGS
 462 if test "x$WITH_THREADS" = "xyes"; then
 463   if test $ac_cv_prog_suncc = "yes"; then
 464     CFLAGS="$CFLAGS -mt"
 465   fi
 466
 467   AC_CHECK_HEADERS(pthread.h, [], [ WITH_THREADS="no" ])
 468
 469 dnl #
 470 dnl # pthread stuff is usually in -lpthread
 471 dnl # or in -lc_r, on *BSD
 472 dnl #
 473 dnl # On Some systems, we need extra pre-processor flags, to get them to
 474 dnl # to do the threading properly.
 475 dnl #
 476   AC_CHECK_LIB(pthread, pthread_create,
 477                 [ CFLAGS="$CFLAGS -D_REENTRANT -D_POSIX_PTHREAD_SEMANTICS"
 478                   LIBS="$LIBS -lpthread" ],
 479                 AC_CHECK_LIB(c_r, pthread_create,
 480                             [ CFLAGS="$CFLAGS -pthread -D_THREAD_SAFE" ],
 481                             [ WITH_THREADS="no" ]
 482                             )
 483                 )
 484 fi
 485
 486 dnl #
 487 dnl # If we have NO pthread libraries, remove any knowledge of threads.
 488 dnl #
 489 if test "x$WITH_THREADS" != "xyes"; then
 490   CFLAGS=$old_CFLAGS
 491   ac_cv_header_pthread_h="no"
 492   WITH_THREADS=no
 493 else
 494   dnl #
 495   dnl #  We need sem_init() and friends, as they're the friendliest
 496   dnl #  semaphore functions for threading.
 497   dnl #
 498   dnl # HP/UX requires linking with librt, too, to get the sem_* symbols.
 499   dnl # Some systems have them in -lsem
 500   dnl # Solaris has them in -lposix4
 501   dnl # NetBSD has them in -lsemaphore
 502
 503   AC_SEARCH_LIBS(sem_init, pthread sem posix4 rt semaphore,
 504         [],
 505         [AC_MSG_ERROR(-lsem not found.  You may want to download it from ftp://ftp.to.gd-es.com/pub/BSDI/libsem.tar.bz2 or ftp://ftp.freeradius.org/pub/radius/contrib/libsem.tar.gz)]
 506    )
 507 fi
 508
 509 dnl Check if we need -lsocket
 510 AC_CHECK_LIB(socket, getsockname)
 511
 512 dnl Check for -lresolv
 513 dnl This library may be needed later.
 514 AC_CHECK_LIB(resolv, inet_aton)
 515
 516 dnl Check if we need -lnsl. Usually if we want to
 517 dnl link against -lsocket we need to include -lnsl as well.
 518 AC_CHECK_LIB(nsl, inet_ntoa)
 519
 520 dnl Check for OpenSSL libraries.
 521 OPENSSL_LIBS=
 522 if test "x$WITH_OPENSSL" = xyes; then
 523   old_LIBS=$LIBS
 524   old_LDFLAGS="$LDFLAGS"
 525   if test "x$OPENSSL_LIB_DIR" != "x"; then
 526     LDFLAGS="$LDFLAGS -L$OPENSSL_LIB_DIR"
 527   fi
 528   AC_CHECK_LIB(crypto, DH_new,
 529     [
 530         LIBS="-lcrypto $LIBS"
 531         AC_DEFINE(HAVE_LIBCRYPTO, 1,
 532             [Define to 1 if you have the `crypto' library (-lcrypto).])
 533         AC_CHECK_LIB(ssl, SSL_new,
 534             [
 535                 AC_DEFINE(HAVE_LIBSSL, 1,
 536                     [Define to 1 if you have the `ssl' library (-lssl).])
 537                 if test "x$OPENSSL_LIB_DIR" != "x"; then
 538                     OPENSSL_LIBS="-L$OPENSSL_LIB_DIR"
 539                 fi
 540                 OPENSSL_LIBS="$OPENSSL_LIBS -lcrypto -lssl -lcrypto"
 541             ], [])
 542     ], [])
 543   LIBS=$old_LIBS
 544   LDFLAGS="$old_LDFLAGS"
 545 fi
 546
 547 AC_CHECK_LIB(ws2_32, htonl)
 548
 549 dnl Check the pcap library for the RADIUS sniffer.
 550 PCAP_LIBS=
 551 AC_CHECK_LIB(pcap, pcap_open_live,
 552         [ PCAP_LIBS="-lpcap"
 553         AC_DEFINE(HAVE_LIBPCAP, 1,
 554                 [Define to 1 if you have the `pcap' library (-lpcap).])
 555         ],
 556         [ AC_MSG_WARN([pcap library not found, silently disabling the RADIUS sniffer.]) ])
 557
 558 AC_LIB_READLINE
 559
 560 dnl #############################################################
 561 dnl #
 562 dnl #  3. Checks for header files
 563 dnl #
 564 dnl #############################################################
 565
 566 dnl #
 567 dnl # Interix requires us to set -D_ALL_SOURCE, otherwise
 568 dnl # getopt will be #included, but won't link.  <sigh>
 569 dnl #
 570 dnl #
 571 case "$host" in
 572 *-interix*)
 573         CFLAGS="$CFLAGS -D_ALL_SOURCE"
 574         ;;
 575 *-darwin*)
 576         CFLAGS="$CFLAGS -DDARWIN"
 577         LIBS="-framework DirectoryService $LIBS"
 578         ;;
 579 esac
 580
 581 AC_HEADER_DIRENT
 582 AC_HEADER_STDC
 583 AC_HEADER_TIME
 584 AC_HEADER_SYS_WAIT
 585
 586 AC_CHECK_HEADERS( \
 587         unistd.h \
 588         crypt.h \
 589         errno.h \
 590         resource.h \
 591         sys/resource.h \
 592         getopt.h \
 593         malloc.h \
 594         utmp.h \
 595         utmpx.h \
 596         signal.h \
 597         sys/select.h \
 598         syslog.h \
 599         inttypes.h \
 600         stdint.h \
 601         stdio.h \
 602         netdb.h \
 603         semaphore.h \
 604         arpa/inet.h \
 605         netinet/in.h \
 606         sys/types.h \
 607         sys/socket.h \
 608         winsock.h \
 609         sys/time.h \
 610         sys/wait.h \
 611         sys/security.h \
 612         fcntl.h \
 613         sys/fcntl.h \
 614         sys/prctl.h \
 615         sys/un.h \
 616         glob.h \
 617         prot.h \
 618         pwd.h \
 619         grp.h \
 620         sia.h \
 621         siad.h
 622 )
 623
 624 dnl FreeBSD requires sys/socket.h before net/if.h
 625 AC_CHECK_HEADERS(net/if.h, [], [],
 626 [#ifdef HAVE_SYS_SOCKET_H
 627 # include <sys/socket.h>
 628 # endif
 629 ])
 630
 631 REGEX=no
 632 AC_CHECK_HEADER(regex.h, AC_DEFINE(HAVE_REGEX_H, [], [define this if we have the <regex.h> header file]))
 633 if test "x$ac_cv_header_regex_h" = "xyes"; then
 634   REGEX_EXTENDED=no
 635   REGEX=yes
 636   AC_EGREP_CPP(yes,
 637     [#include <regex.h>
 638      #ifdef REG_EXTENDED
 639        yes
 640      #endif
 641      ], [AC_DEFINE(HAVE_REG_EXTENDED, [], [define this if we have REG_EXTENDED (from <regex.h>)]) REGEX_EXTENDED=yes])
 642 fi
 643 AC_SUBST(REGEX)
 644 AC_SUBST(REGEX_EXTENDED)
 645
 646 dnl #
 647 dnl #  other checks which require headers
 648 dnl #
 649 if test "x$ac_cv_header_sys_security_h" = "xyes" && test "x$ac_cv_header_prot_h" = "xyes"
 650 then
 651   AC_DEFINE(OSFC2, [], [define if you have OSFC2 authentication])
 652 fi
 653
 654 if test "x$ac_cv_header_sia_h" = "xyes" && test "x$ac_cv_header_siad_h" = "xyes"
 655 then
 656   AC_DEFINE(OSFSIA, [], [define if you have OSFSIA authentication])
 657 fi
 658
 659 dnl Check for OpenSSL includes.
 660 OPENSSL_INCLUDE="-DNO_OPENSSL"
 661 if test "x$WITH_OPENSSL" = xyes; then
 662   if test "x$OPENSSL_LIBS" = "x"; then
 663     AC_MSG_NOTICE([skipping test for openssl/ssl.h])
 664   else
 665     old_CPPFLAGS=$CPPFLAGS
 666     if test "x$OPENSSL_INCLUDE_DIR" != "x"; then
 667         CPPFLAGS="$CPPFLAGS -I$OPENSSL_INCLUDE_DIR"
 668     fi
 669     dnl # stupid RedHat shit
 670     CPPFLAGS="$CPPFLAGS -DOPENSSL_NO_KRB5"
 671     AC_CHECK_HEADERS( \
 672         openssl/ssl.h \
 673         openssl/crypto.h \
 674         openssl/err.h \
 675         openssl/evp.h \
 676         openssl/engine.h,
 677         [],
 678         OPENSSL_LIBS=
 679     )
 680     if test "x$OPENSSL_LIBS" != "x"; then
 681         AC_MSG_CHECKING([for OpenSSL version >= 0.9.7])
 682         AC_EGREP_CPP(yes,
 683             [#include <openssl/crypto.h>
 684              #if (OPENSSL_VERSION_NUMBER >= 0x00907000L)
 685              yes
 686              #endif
 687             ], goodssl="yes")
 688         if test "x$goodssl" != "xyes"; then
 689             AC_MSG_RESULT(no)
 690             OPENSSL_LIBS=
 691         else
 692             AC_MSG_RESULT(yes)
 693             if test "x$OPENSSL_INCLUDE_DIR" != "x"; then
 694                 OPENSSL_INCLUDE="-I$OPENSSL_INCLUDE_DIR -DOPENSSL_NO_KRB5"
 695             else
 696                 OPENSSL_INCLUDE="-DOPENSSL_NO_KRB5"
 697             fi
 698         fi
 699     fi
 700     CPPFLAGS=$old_CPPFLAGS
 701   fi
 702 fi
 703 AC_SUBST(OPENSSL_INCLUDE)
 704 AC_SUBST(OPENSSL_LIBS)
 705 export OPENSSL_LIBS
 706
 707 dnl Check the pcap includes for the RADIUS sniffer.
 708 if test "x$PCAP_LIBS" = x; then
 709     AC_MSG_NOTICE([skipping test for pcap.h.])
 710 else
 711     AC_CHECK_HEADER(pcap.h,
 712         AC_DEFINE(HAVE_PCAP_H, 1,
 713                 [Define to 1 if you have the <pcap.h> header file.]),
 714         [ PCAP_LIBS=
 715         AC_MSG_WARN([pcap.h not found, silently disabling the RADIUS sniffer.])
 716         ])
 717 fi
 718 AC_SUBST(PCAP_LIBS)
 719
 720 dnl #############################################################
 721 dnl #
 722 dnl #  4. Checks for typedefs
 723 dnl #
 724 dnl #############################################################
 725
 726 dnl #
 727 dnl # Ensure that these are defined
 728 dnl #
 729 AC_TYPE_OFF_T
 730 AC_TYPE_PID_T
 731 AC_TYPE_SIZE_T
 732 AC_TYPE_UID_T
 733
 734 dnl check for socklen_t
 735 FR_CHECK_TYPE_INCLUDE([
 736 #ifdef HAVE_SYS_TYPES_H
 737 #include <sys/types.h>
 738 #endif
 739 #ifdef HAVE_SYS_SOCKET_H
 740 #include <sys/socket.h>
 741 #endif
 742 ],socklen_t, int, [socklen_t is generally 'int' on systems which don't use it])
 743
 744 dnl check for uint8_t
 745 FR_CHECK_TYPE_INCLUDE([
 746 #ifdef HAVE_INTTYPES_H
 747 #include <inttypes.h>
 748 #endif
 749 #ifdef HAVE_STDINT_H
 750 #include <stdint.h>
 751 #endif
 752 ],uint8_t, unsigned char, [uint8_t should be the canonical 'octet' for network traffic])
 753
 754 dnl check for uint16_t
 755 FR_CHECK_TYPE_INCLUDE([
 756 #ifdef HAVE_INTTYPES_H
 757 #include <inttypes.h>
 758 #endif
 759 #ifdef HAVE_STDINT_H
 760 #include <stdint.h>
 761 #endif
 762 ],uint16_t, unsigned short, [uint16_t should be the canonical '2 octets' for network traffic])
 763
 764 dnl check for uint32_t
 765 FR_CHECK_TYPE_INCLUDE([
 766 #ifdef HAVE_INTTYPES_H
 767 #include <inttypes.h>
 768 #endif
 769 #ifdef HAVE_STDINT_H
 770 #include <stdint.h>
 771 #endif
 772 ],uint32_t, unsigned int, [uint32_t should be the canonical 'network integer])
 773
 774 AC_CHECK_TYPE(struct in6_addr, AC_DEFINE(HAVE_STRUCT_IN6_ADDR, 1, [IPv6 address structure]), [], [
 775 #ifdef HAVE_NETINET_IN_H
 776 #include <netinet/in.h>
 777 #endif
 778 ])
 779
 780 AC_CHECK_TYPE(struct sockaddr_storage, AC_DEFINE(HAVE_STRUCT_SOCKADDR_STORAGE, 1, [Generic socket addresses]), [], [
 781 #ifdef HAVE_NETINET_IN_H
 782 #include <netinet/in.h>
 783 #endif
 784 #ifdef HAVE_SYS_SOCKET_H
 785 #include <sys/socket.h>
 786 #endif
 787 ])
 788
 789 AC_CHECK_TYPE(struct sockaddr_in6, AC_DEFINE(HAVE_STRUCT_SOCKADDR_IN6, 1, [IPv6 socket addresses]), [], [
 790 #ifdef HAVE_NETINET_IN_H
 791 #include <netinet/in.h>
 792 #endif
 793 ])
 794
 795 AC_CHECK_TYPE(struct addrinfo, AC_DEFINE(HAVE_STRUCT_ADDRINFO, 1, [Generic DNS lookups]), [], [
 796 #ifdef HAVE_SYS_TYPES_H
 797 #include <sys/types.h>
 798 #endif
 799 #ifdef HAVE_SYS_SOCKET_H
 800 #include <sys/socket.h>
 801 #endif
 802 #ifdef HAVE_NETDB_H
 803 #include <netdb.h>
 804 #endif
 805 ])
 806
 807 dnl #############################################################
 808 dnl #
 809 dnl #  5. Checks for structures and functions
 810 dnl #
 811 dnl #############################################################
 812 AC_CHECK_FUNCS( \
 813         getopt_long \
 814         lockf \
 815         strsignal \
 816         sigaction \
 817         sigprocmask \
 818         pthread_sigmask \
 819         snprintf \
 820         vsnprintf \
 821         setsid \
 822         strncasecmp \
 823         strcasecmp \
 824         localtime_r \
 825         ctime_r \
 826         gmtime_r \
 827         strsep \
 828         inet_aton \
 829         inet_pton \
 830         inet_ntop \
 831         setlinebuf \
 832         setvbuf \
 833         getusershell \
 834         initgroups \
 835         getaddrinfo \
 836         getnameinfo \
 837         closefrom \
 838         gettimeofday \
 839         getpeereid \
 840         setuid \
 841         setresuid \
 842         getresuid \
 843         strlcat \
 844         strlcpy
 845 )
 846 RADIUSD_NEED_DECLARATIONS( \
 847         crypt \
 848         strncasecmp \
 849         strcasecmp \
 850         inet_aton \
 851         setlinebuf \
 852         getusershell \
 853         endusershell
 854 )
 855
 856 AC_TYPE_SIGNAL
 857
 858 dnl # check if we have utmpx.h
 859 dnl # if so, check if struct utmpx has entry ut_xtime
 860 dnl # if not, set it to define ut_xtime == ut_tv.tv_sec
 861 if test "x$ac_cv_header_utmpx_h" = "xyes"
 862 then
 863  FR_CHECK_STRUCT_HAS_MEMBER([#include <utmpx.h>], [struct utmpx], ut_xtime)
 864  if test "x$ac_cv_type_struct_utmpx_has_ut_xtime" = "x"
 865  then
 866    AC_DEFINE(ut_xtime,ut_tv.tv_sec, [define to something if you don't have ut_xtime in struct utmpx])
 867  fi
 868 fi
 869
 870 dnl # struct ip_pktinfo
 871 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in_pktinfo], ipi_addr)
 872 if test "x$ac_cv_type_struct_in_pktinfo_has_ipi_addr" = "xyes"
 873 then
 874         AC_DEFINE(HAVE_IP_PKTINFO, [], [define if you have IP_PKTINFO (Linux)])
 875 fi
 876
 877 dnl # struct in6_pktinfo
 878 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in6_pktinfo], ipi6_addr)
 879 if test "x$ac_cv_type_struct_in6_pktinfo_has_ipi6_addr" = "xyes"
 880 then
 881         AC_DEFINE(HAVE_IN6_PKTINFO, [], [define if you have IN6_PKTINFO (Linux)])
 882 fi
 883
 884 dnl #############################################################
 885 dnl #
 886 dnl #  6. Checks for compiler characteristics
 887 dnl #
 888 dnl #############################################################
 889
 890 dnl #
 891 dnl # Ensure that these are defined
 892 dnl #
 893 AC_C_CONST
 894
 895 dnl #
 896 dnl # See if this is OS/2
 897 dnl #
 898 AC_MSG_CHECKING(type of OS)
 899 OS=`uname -s`
 900 AC_MSG_RESULT($OS)
 901 if test "$OS" = "OS/2"; then
 902         LIBPREFIX=
 903 else
 904         LIBPREFIX=lib
 905 fi
 906 AC_SUBST(LIBPREFIX)
 907
 908 dnl #
 909 dnl # Set Default CFLAGS
 910 dnl #
 911 if test "x$GCC" = "xyes"; then
 912     CFLAGS="$CFLAGS -Wall -D_GNU_SOURCE"
 913 fi
 914
 915 AC_MSG_CHECKING(for developer gcc flags)
 916 if test "x$developer" = "xyes" -a "x$GCC" = "xyes"; then
 917   devflags="-g -Wshadow -Wpointer-arith -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -W -Wredundant-decls -Wundef"
 918   CFLAGS="$CFLAGS $devflags"
 919   INSTALLSTRIP=""
 920   AC_MSG_RESULT(yes.  Using $devflags)
 921 else
 922   devflags=""
 923   CFLAGS="$CFLAGS -DNDEBUG"
 924   INSTALLSTRIP=""
 925   AC_MSG_RESULT(no.)
 926 fi
 927
 928 FR_TLS
 929
 930 dnl #############################################################
 931 dnl #
 932 dnl #  7. Checks for library functions
 933 dnl #
 934 dnl #############################################################
 935
 936 old_LIBS="$LIBS"
 937 LIBS="$LIBS $LIBLTDL"
 938 AC_CHECK_FUNC(lt_dladvise_init, AC_DEFINE(HAVE_HAVE_LT_DLADVISE_INIT, [], [Do we have the lt_dladvise_init function]))
 939 LIBS="$old_LIBS"
 940
 941 dnl Check for libcrypt
 942 dnl We use crypt(3) which may be in libc, or in libcrypt (eg FreeBSD)
 943 AC_CHECK_LIB(crypt, crypt,
 944   CRYPTLIB="-lcrypt"
 945 )
 946 if test "$CRYPTLIB" != ""; then
 947   AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function])
 948 else
 949   AC_CHECK_FUNC(crypt, AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function]))
 950 fi
 951
 952 dnl Check for libcipher
 953 AC_CHECK_LIB(cipher, setkey,
 954    CRYPTLIB="${CRYPTLIB} -lcipher"
 955 )
 956 AC_SUBST(CRYPTLIB)
 957
 958 dnl Check the style of gethostbyaddr, in order of preference
 959 dnl GNU (_r eight args)
 960 AC_DEFINE(GNUSTYLE, [1], [GNU-Style get*byaddr_r])
 961 dnl SYSV (_r six args)
 962 AC_DEFINE(SYSVSTYLE, [2], [SYSV-Style get*byaddr_r])
 963 dnl BSD (three args, may not be thread safe)
 964 AC_DEFINE(BSDSTYLE, [3], [BSD-Style get*byaddr_r])
 965 dnl Tru64 has BSD version, but it is thread safe
 966 dnl     http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1739____.HTM
 967 dnl We need #stdio.h to define NULL on FreeBSD (at least)
 968 gethostbyaddrrstyle=""
 969 AC_MSG_CHECKING([gethostbyaddr_r() syntax])
 970 case "$host" in
 971 *-freebsd*)
 972 dnl With FreeBSD, check if there's a prototype for gethostbyaddr_r.
 973 dnl Some versions (FreeBSD 5.1?) have a symbol but no prototype - so we
 974 dnl override this test to BSDSTYLE. FreeBSD 6.2 and up have proper GNU
 975 dnl style support.
 976         AC_CHECK_DECLS([gethostbyaddr_r], [], [
 977                 AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE,
 978                         [style of gethostbyaddr_r functions ])
 979                 gethostbyaddrrstyle=BSD
 980                 AC_MSG_WARN([FreeBSD overridden to BSD-style])
 981         ], [
 982 #ifdef HAVE_NETDB_H
 983 #include <netdb.h>
 984 #endif
 985 ])
 986         ;;
 987 esac
 988 if test "x$gethostbyaddrrstyle" = "x"; then
 989         AC_TRY_LINK([
 990 #include <stdio.h>
 991 #include <netdb.h>
 992 ], [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL, NULL) ], [
 993         AC_DEFINE(GETHOSTBYADDRRSTYLE, GNUSTYLE, [style of gethostbyaddr_r functions ])
 994         gethostbyaddrrstyle=GNU
 995 ])
 996 fi
 997 if test "x$gethostbyaddrrstyle" = "x"; then
 998         AC_TRY_LINK([
 999 #include <stdio.h>
1000 #include <netdb.h>
1001 ], [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL) ] , [
1002                 AC_DEFINE(GETHOSTBYADDRRSTYLE, SYSVSTYLE, [style of gethostbyaddr_r functions ])
1003                 gethostbyaddrrstyle=SYSV
1004         ])
1005 fi
1006 if test "x$gethostbyaddrrstyle" = "x"; then
1007         AC_TRY_LINK([
1008 #include <stdio.h>
1009 #include <netdb.h>
1010 ], [ gethostbyaddr(NULL, 0, 0)  ], [
1011                 AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE, [style of gethostbyaddr_r functions ])
1012                 gethostbyaddrrstyle=BSD
1013         ])
1014 fi
1015
1016 if test "x$gethostbyaddrrstyle" = "x"; then
1017         AC_MSG_RESULT([none!  It must not exist, here.])
1018 else
1019         AC_MSG_RESULT([${gethostbyaddrrstyle}-style])
1020 fi
1021
1022 if test "x$gethostbyaddrrstyle" = "xBSD"; then
1023         AC_MSG_WARN([ ****** BSD-style gethostbyaddr might NOT be thread-safe! ****** ])
1024 fi
1025
1026 dnl Check the style of gethostbyname, in order of preference
1027 dnl GNU (_r seven args)
1028 dnl SYSV (_r five args)
1029 dnl BSD (two args, may not be thread safe)
1030 dnl Tru64 has BSD version, but it _is_ thread safe
1031 dnl     http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1946____.HTM
1032 dnl We need #stdio.h to define NULL on FreeBSD (at least)
1033 gethostbynamerstyle=""
1034 AC_MSG_CHECKING([gethostbyname_r() syntax])
1035 AC_TRY_LINK([
1036 #include <stdio.h>
1037 #include <netdb.h>
1038 ], [ gethostbyname_r(NULL, NULL, NULL, 0, NULL, NULL) ], [
1039         AC_DEFINE(GETHOSTBYNAMERSTYLE, GNUSTYLE, [style of gethostbyname_r functions ])
1040         gethostbynamerstyle=GNU
1041 ])
1042 if test "x$gethostbynamerstyle" = "x"; then
1043         AC_TRY_LINK([
1044 #include <stdio.h>
1045 #include <netdb.h>
1046 ], [ gethostbyname_r(NULL, NULL, NULL, 0, NULL) ] , [
1047                 AC_DEFINE(GETHOSTBYNAMERSTYLE, SYSVSTYLE, [style of gethostbyname_r functions ])
1048                 gethostbynamerstyle=SYSV
1049         ])
1050 fi
1051 if test "x$gethostbynamerstyle" = "x"; then
1052         AC_TRY_LINK([
1053 #include <stdio.h>
1054 #include <netdb.h>
1055 ], [ gethostbyname(NULL)  ], [
1056                 AC_DEFINE(GETHOSTBYNAMERSTYLE, BSDSTYLE, [style of gethostbyname_r functions ])
1057                 gethostbynamerstyle=BSD
1058         ])
1059 fi
1060
1061 if test "x$gethostbynamerstyle" = "x"; then
1062         AC_MSG_RESULT([none!  It must not exist, here.])
1063 else
1064         AC_MSG_RESULT([${gethostbynamerstyle}-style])
1065 fi
1066
1067 if test "x$gethostbynamerstyle" = "xBSD"; then
1068         AC_MSG_WARN([ ****** BSD-style gethostbyname might NOT be thread-safe! ****** ])
1069 fi
1070
1071 dnl check for non-posix solaris ctime_r (extra buflen int arg)
1072 AC_DEFINE(POSIXSTYLE, [1], [Posix-Style ctime_r])
1073 AC_DEFINE(SOLARISSTYLE, [2], [Solaris-Style ctime_r])
1074 ctimerstyle=""
1075 AC_MSG_CHECKING([ctime_r() syntax])
1076 AC_TRY_LINK([
1077 #include <time.h>
1078 ], [ ctime_r(NULL, NULL, 0) ], [
1079         AC_DEFINE(CTIMERSTYLE, SOLARISSTYLE, [style of ctime_r function])
1080         ctimerstyle="SOLARIS"
1081 ])
1082 if test "x$ctimerstyle" = "x"; then
1083         AC_TRY_LINK([
1084 #include <time.h>
1085 ], [ ctime_r(NULL, NULL) ], [
1086                 AC_DEFINE(CTIMERSTYLE, POSIXSTYLE, [style of ctime_r function])
1087                 ctimerstyle="POSIX"
1088         ])
1089 fi
1090
1091 if test "x$ctimerstyle" = "x"; then
1092         AC_MSG_RESULT([none!  It must not exist, here.])
1093 else
1094         AC_MSG_RESULT([${ctimerstyle}-style])
1095 fi
1096
1097 AC_SUBST(HOSTINFO, $host)
1098
1099 dnl #############################################################
1100 dnl #
1101 dnl #  8. Checks for system services
1102 dnl #
1103 dnl #############################################################
1104
1105 dnl #
1106 dnl # Figure out where libtool is located,
1107 dnl #
1108 top_builddir=`pwd`
1109 export top_builddir
1110 AC_MSG_RESULT([top_builddir=$top_builddir])
1111 dnl # AC_SUBST(top_builddir)
1112 AC_SUBST(LIBLTDL)
1113 AC_SUBST(INCLTDL)
1114
1115 dnl import libtool stuff
1116
1117 dnl #############################################################
1118 dnl #
1119 dnl #  Configure in any module directories.
1120 dnl #
1121 dnl #############################################################
1122
1123 mysubdirs="$LIBLTDLPATH"
1124 if test "x$EXPERIMENTAL" = "xyes"; then
1125   bar=`ls -1 "${srcdir}"/src/modules/rlm_*/configure | sed 's%/configure%%'`
1126   dnl # get rid of LF's.
1127   mysubdirs=`echo $mysubdirs $bar`
1128 else
1129   dnl #
1130   dnl # Find 'configure' in ONLY the stable modules
1131   dnl #
1132   for bar in `cat "${srcdir}"/src/modules/stable`; do
1133     if test -f "${srcdir}"/src/modules/$bar/configure; then
1134       mysubdirs="$mysubdirs src/modules/$bar"
1135     fi
1136   done
1137 fi
1138
1139 dnl ############################################################
1140 dnl # make modules by list
1141 dnl #############################################################
1142 if test "x$EXPERIMENTAL" = "xyes"; then
1143   for foo in `ls -1 "${srcdir}"/src/modules | grep rlm_`; do
1144     MODULES="$MODULES $foo"
1145   done
1146 else
1147    dnl #
1148    dnl # make ONLY the stable modules
1149    dnl #
1150    for foo in `cat "${srcdir}"/src/modules/stable`; do
1151     MODULES="$MODULES $foo"
1152    done
1153 fi
1154
1155 dnl #
1156 dnl #  Don't change the variable name here.  Autoconf goes bonkers
1157 dnl #  if you do.
1158 dnl #
1159 AC_CONFIG_SUBDIRS($LTDL_SUBDIRS $mysubdirs)
1160 AC_SUBST(MODULES)
1161
1162 dnl #############################################################
1163 dnl #
1164 dnl #  And finally, output the results.
1165 dnl #
1166 dnl #############################################################
1167
1168 AC_CONFIG_COMMANDS([stamp-h], [echo timestamp > src/include/stamp-h])
1169 AC_CONFIG_COMMANDS([build-radpaths-h], [(cd ./src/include && /bin/sh ./build-radpaths-h)])
1170 AC_CONFIG_COMMANDS([main-chmod], [(cd ./src/main   && chmod +x checkrad.pl radlast radtest)])
1171 AC_CONFIG_COMMANDS([scripts-chmod], [(cd ./scripts    && chmod +x rc.radiusd radwatch radiusd.cron.daily radiusd.cron.monthly cryptpasswd)])
1172
1173 dnl #
1174 dnl #  Substitute whatever libraries we found to be necessary
1175 dnl #
1176 AC_SUBST(LIBS)
1177 AC_SUBST(INSTALLSTRIP)
1178
1179 USE_SHARED_LIBS=$enable_shared
1180 AC_SUBST(USE_SHARED_LIBS)
1181 USE_STATIC_LIBS=$enable_static
1182 AC_SUBST(USE_STATIC_LIBS)
1183 AC_SUBST(STATIC_MODULES)
1184 AC_SUBST(RADIUSD_MAJOR_VERSION)
1185 AC_SUBST(RADIUSD_MINOR_VERSION)
1186 AC_SUBST(RADIUSD_VERSION)
1187
1188 AC_OUTPUT(\
1189         ./Make.inc \
1190         ./src/include/build-radpaths-h \
1191         ./src/main/Makefile \
1192         ./src/main/checkrad.pl \
1193         ./src/main/radlast \
1194         ./src/main/radtest \
1195         ./scripts/rc.radiusd \
1196         ./scripts/radwatch \
1197         ./scripts/radiusd.cron.daily \
1198         ./scripts/radiusd.cron.monthly \
1199         ./scripts/cryptpasswd \
1200         ./raddb/dictionary \
1201         ./raddb/radrelay.conf \
1202         ./raddb/radiusd.conf
1203 )