configure.in

   1 dnl #############################################################
   2 dnl #
   3 dnl #  For information about autoconf, see:
   4 dnl #
   5 dnl #  http://www.gnu.org/software/autoconf/
   6 dnl #
   7 dnl #  The recommended order is:
   8 dnl #
   9 dnl #  AC_INIT(file)
  10 dnl #  0. checks for compiler, libtool, and command line options
  11 dnl #  1. checks for programs
  12 dnl #  2. checks for libraries
  13 dnl #  3. checks for header files
  14 dnl #  4. checks for typedefs
  15 dnl #  5. checks for structures and functions
  16 dnl #  6. checks for compiler characteristics
  17 dnl #  7. checks for library functions
  18 dnl #  8. checks for system services
  19 dnl #  AC_OUTPUT([file...])
  20 dnl #
  21 dnl #############################################################
  22
  23 AC_PREREQ([2.59])
  24 export CFLAGS LIBS LDFLAGS CPPFLAGS
  25 AC_INIT(src/main/radiusd.c)
  26 AC_CONFIG_HEADER(src/include/autoconf.h)
  27 AC_REVISION($Revision$)dnl
  28
  29 dnl # The version of the software
  30 RADIUSD_MAJOR_VERSION=2
  31 RADIUSD_MINOR_VERSION=0.0-pre0
  32 RADIUSD_VERSION="${RADIUSD_MAJOR_VERSION}.${RADIUSD_MINOR_VERSION}"
  33 PACKAGE=freeradius
  34
  35 dnl #############################################################
  36 dnl #
  37 dnl #  0. Checks for compiler, libtool, and command line options.
  38 dnl #
  39 dnl #############################################################
  40
  41 dnl Check for GNU cc
  42 AC_PROG_CC
  43 AC_PROG_CXX
  44
  45 dnl #
  46 dnl # check for AIX, to allow us to use some BSD functions
  47 dnl # must be before macros that call the compiler.
  48 dnl #
  49 AC_AIX
  50
  51 AC_PROG_GCC_TRADITIONAL
  52 AC_PROG_CC_SUNPRO
  53 AC_PROG_RANLIB
  54
  55 dnl Compile in large (2G+) file support.
  56 AC_SYS_LARGEFILE
  57
  58 dnl # check for system bytesex
  59 dnl # AC_DEFINES WORDS_BIGENDIAN
  60 AC_C_BIGENDIAN
  61
  62 dnl Find GNU Make.
  63 AC_CHECK_PROG(GMAKE, gmake, yes, no)
  64 if test $GMAKE = no; then
  65   AC_PATH_PROG(MAKE, make, /usr/local/bin/make)
  66 else
  67   AC_PATH_PROG(MAKE, gmake, /usr/local/gnu/bin/make)
  68 fi
  69 makever=`$ac_cv_path_MAKE --version 2>&1 | grep "GNU Make"`
  70 if test -z "$makever"; then
  71   AC_MSG_ERROR(GNU Make is not installed.  Please download and install it
  72                 from ftp://prep.ai.mit.edu/pub/gnu/make/ before continuing.)
  73 fi
  74
  75 dnl libltdl is installable
  76 AC_LIBLTDL_INSTALLABLE
  77
  78 dnl tell Makefile to build ltdl if needed
  79 if test x"$enable_ltdl_install" = x"yes"; then
  80   LTDL_SUBDIRS=libltdl
  81 fi
  82 AC_SUBST(LTDL_SUBDIRS)
  83
  84 dnl use system-wide libtool, if it exists
  85 AC_ARG_WITH(system-libtool,
  86 [  --with-system-libtool              try to use libtool installed in your system [default=use our own]],
  87 [ AC_PATH_PROG(LIBTOOL, libtool,,$PATH:/usr/local/bin) ],
  88 [
  89   LIBTOOL="`pwd`/libtool"
  90   AC_SUBST(LIBTOOL)
  91   dnl ensure that we're looking for dlopen
  92   AC_LIBTOOL_DLOPEN
  93
  94   dnl Figure out how to build shared libraries
  95   AC_PROG_LIBTOOL
  96 ])
  97
  98
  99 dnl Put this in later, when all distributed modules use autoconf.
 100 dnl AC_ARG_WITH(disablemodulefoo,
 101 dnl [  --without-rlm_foo       Disables module compilation.  Module list:]
 102 dnl esyscmd([find src/modules -type d -name rlm_\* -print |\
 103 dnl     sed -e 's%src/modules/.*/% (sub)- %; s%.*/%- %' |\
 104 dnl     awk '{print "                            "$0}']))
 105
 106 AC_ARG_ENABLE(strict-dependencies,
 107 [  --enable-strict-dependencies  Fail configure on lack of module dependancy.])
 108
 109 dnl extra argument: --with-docdir
 110 docdir='${datadir}/doc/freeradius'
 111 AC_MSG_CHECKING(docdir)
 112 AC_ARG_WITH(docdir,
 113 [  --with-docdir=DIR       Directory for documentation [DATADIR/doc/freeradius] ],
 114 [ case "$withval" in
 115     no)
 116         docdir=no
 117         ;;
 118     yes)
 119         ;;
 120     [[\\/$]]* | ?:[[\\/]]* )
 121         docdir="$withval"
 122         ;;
 123     *)
 124         AC_MSG_ERROR([expected an absolute directory name for --with-docdir: $withval])
 125         ;;
 126   esac ]
 127 )
 128 AC_SUBST(docdir)
 129 AC_MSG_RESULT($docdir)
 130 if test "x$docdir" = xno; then
 131         AC_MSG_WARN(Documentation files will NOT be installed.)
 132 fi
 133
 134 dnl extra argument: --with-logdir
 135 logdir='${localstatedir}/log/radius'
 136 AC_MSG_CHECKING(logdir)
 137 AC_ARG_WITH(logdir,
 138 [  --with-logdir=DIR       Directory for logfiles [LOCALSTATEDIR/log/radius] ],
 139 [ case "$withval" in
 140     no)
 141         AC_MSG_ERROR(Need logdir)
 142         ;;
 143     yes)
 144         ;;
 145     [[\\/$]]* | ?:[[\\/]]* )
 146         logdir="$withval"
 147         ;;
 148     *)
 149         AC_MSG_ERROR([expected an absolute directory name for --with-logdir: $withval])
 150         ;;
 151   esac ]
 152 )
 153 AC_SUBST(logdir)
 154 AC_MSG_RESULT($logdir)
 155
 156 dnl extra argument: --with-radacctdir
 157 radacctdir='${logdir}/radacct'
 158 AC_MSG_CHECKING(radacctdir)
 159 AC_ARG_WITH(radacctdir,
 160 [  --with-radacctdir=DIR   Directory for detail files [LOGDIR/radacct] ],
 161 [ case "$withval" in
 162     no)
 163         AC_MSG_ERROR(Need radacctdir)
 164         ;;
 165     yes)
 166         ;;
 167     [[\\/$]]* | ?:[[\\/]]* )
 168         radacctdir="$withval"
 169         ;;
 170     *)
 171         AC_MSG_ERROR([expected an absolute directory name for --with-radacctdir: $withval])
 172         ;;
 173   esac ]
 174 )
 175 AC_SUBST(radacctdir)
 176 AC_MSG_RESULT($radacctdir)
 177
 178 dnl extra argument: --with-raddbdir
 179 raddbdir='${sysconfdir}/raddb'
 180 AC_MSG_CHECKING(raddbdir)
 181 AC_ARG_WITH(raddbdir,
 182 [  --with-raddbdir=DIR     Directory for config files [SYSCONFDIR/raddb] ],
 183 [ case "$withval" in
 184     no)
 185         AC_MSG_ERROR(Need raddbdir)
 186         ;;
 187     yes)
 188         ;;
 189     [[\\/$]]* | ?:[[\\/]]* )
 190         raddbdir="$withval"
 191         ;;
 192     *)
 193         AC_MSG_ERROR([expected an absolute directory name for --with-raddbdir: $withval])
 194         ;;
 195   esac ]
 196 )
 197 AC_SUBST(raddbdir)
 198 AC_MSG_RESULT($raddbdir)
 199
 200 dnl extra argument: --with-ascend-binary
 201 ASCEND_BINARY=yes
 202 AC_ARG_WITH(ascend-binary,
 203 [  --with-ascend-binary    Include support for Ascend binary filter attributes (default=yes)],
 204 [ case "$withval" in
 205     yes)
 206         ;;
 207     *)
 208         ASCEND_BINARY=""
 209   esac ]
 210 )
 211 if test "X$ASCEND_BINARY" = "Xyes"; then
 212   AC_DEFINE(ASCEND_BINARY, [], [Include support for Ascend binary filter attributes])
 213 fi
 214
 215 dnl extra argument: --with-threads
 216 WITH_THREADS=yes
 217 AC_ARG_WITH(threads,
 218 [  --with-threads          Use threads, if available.  (default=yes) ],
 219 [ case "$withval" in
 220     yes)
 221         ;;
 222     *)
 223         WITH_THREADS=""
 224   esac ]
 225 )
 226
 227 dnl extra argument: --with-snmp
 228 WITH_SNMP=yes
 229 AC_ARG_WITH(snmp,
 230 [  --with-snmp             Compile in SNMP support. (default=yes)],
 231 [ case "$withval" in
 232     yes)
 233         ;;
 234     *)
 235         WITH_SNMP=no
 236   esac ]
 237 )
 238
 239 dnl #
 240 dnl #  Allow the user to specify a list of modules to be linked
 241 dnl #  statically to the server.
 242 dnl #
 243 STATIC_MODULES=
 244 AC_ARG_WITH(static_modules,
 245 [  --with-static-modules=QUOTED-MODULE-LIST],[
 246   for i in $withval; do
 247     STATIC_MODULES="$STATIC_MODULES -dlpreopen ../modules/rlm_$i/rlm_$i.la"
 248   done
 249 ])
 250
 251 MODULES=
 252 AC_ARG_WITH(modules,
 253 [ --with-modules=QUOTED-MODULE-LIST],[
 254  for i in $withval; do
 255    MODULES="$MODULES $i"
 256  done
 257 ])
 258
 259 dnl #
 260 dnl #  Enable developer C compiler warnings
 261 dnl #
 262 AC_ARG_ENABLE(developer,
 263 [  --enable-developer               Enables features of interest to developers.],
 264 [ case "$enableval" in
 265     no)
 266         developer=no
 267         ;;
 268     *)
 269         developer=yes
 270   esac ]
 271 )
 272
 273 if test "x$developer" != "xno" -a -d $srcdir/CVS; then
 274   dnl turn on the developer flag when taken from a CVS checkout (not a release)
 275   developer="yes"
 276 fi
 277
 278 dnl extra argument: --with-experimental-modules
 279 EXPERIMENTAL=
 280 AC_ARG_WITH(experimental-modules,
 281 [  --with-experimental-modules      Use experimental and unstable modules. (default=no) ],
 282 [ case "$withval" in
 283     yes)
 284         EXPERIMENTAL=yes
 285         ;;
 286     *)
 287   esac ]
 288 )
 289
 290 dnl #
 291 dnl # extra argument: --with-openssl-includes=dir
 292 dnl #
 293 OPENSSL_INCLUDE_DIR=
 294 AC_ARG_WITH(openssl-includes,
 295 [  --with-openssl-includes=DIR      Directory to look for OpenSSL include files],
 296 [ case "$withval" in
 297     *) OPENSSL_INCLUDE_DIR="$withval"
 298         ;;
 299   esac ]
 300 )
 301
 302 dnl #
 303 dnl # extra argument: --with-openssl-libraries=dir
 304 dnl #
 305 OPENSSL_LIB_DIR=
 306 AC_ARG_WITH(openssl-libraries,
 307 [  --with-openssl-libraries=DIR     Directory to look for OpenSSL library files],
 308 [ case "$withval" in
 309     *) OPENSSL_LIB_DIR="$withval"
 310         ;;
 311   esac ]
 312 )
 313
 314 dnl #
 315 dnl #  These next two arguments don't actually do anything.  They're
 316 dnl #  place holders so that the top-level configure script can tell
 317 dnl #  the user how to configure lower-level modules
 318 dnl #
 319
 320 dnl #
 321 dnl # extra argument: --with-rlm-FOO-lib-dir
 322 dnl #
 323 AC_ARG_WITH(rlm-FOO-lib-dir,
 324 [  --with-rlm-FOO-lib-dir=DIR       Directory to look for library files used by module FOO],
 325 [ case "$withval" in
 326     *)
 327         ;;
 328   esac ]
 329 )
 330
 331 dnl #
 332 dnl # extra argument: --with-rlm-FOO-include-dir
 333 dnl #
 334 AC_ARG_WITH(rlm-FOO-include-dir,
 335 [  --with-rlm-FOO-include-dir=DIR   Directory to look for include files used by module FOO],
 336 [ case "$withval" in
 337     *)
 338         ;;
 339   esac ]
 340 )
 341
 342 dnl See what include-style is used by the make program.
 343 dnl AC_MSG_CHECKING(include style for make)
 344 dnl echo "include /dev/null" > testmake.$$
 345 dnl echo "all:" >> testmake.$$
 346 dnl make -f testmake.$$ >/dev/null 2>&1
 347 dnl if test $? = 0
 348 dnl then
 349 dnl     INCLUDE=include
 350 dnl     IQUOTE=
 351 dnl else
 352 dnl     INCLUDE=.include
 353 dnl     IQUOTE='"'
 354 dnl fi
 355 dnl rm -f testmake.$$
 356 dnl AC_MSG_RESULT(" $INCLUDE")
 357 dnl AC_SUBST(INCLUDE)
 358 dnl AC_SUBST(IQUOTE)
 359
 360 dnl extra argument: --with-udpfromto
 361 WITH_UDPFROMTO=no
 362 AC_ARG_WITH(udpfromto,
 363 [  --with-udpfromto        Compile in UDPFROMTO support. (default=no)],
 364 [ case "$withval" in
 365     yes)
 366         WITH_UDPFROMTO=yes
 367         ;;
 368     *)
 369         WITH_UDPFROMTO=no
 370   esac ]
 371 )
 372
 373 if test "x$WITH_UDPFROMTO" = "xyes"; then
 374         AC_DEFINE(WITH_UDPFROMTO, [], [define if you want udpfromto])
 375 fi
 376
 377 dnl #############################################################
 378 dnl #
 379 dnl #  1. Checks for programs
 380 dnl #
 381 dnl #############################################################
 382
 383 CHECKRAD=checkrad.pl
 384 AC_PATH_PROG(PERL, perl, /usr/local/bin/perl)
 385 if test "x$ac_cv_path_PERL" = "x"; then
 386   AC_MSG_WARN(perl not found - Simultaneous-Use and checkrad.pl may not work)
 387 fi
 388 AC_PATH_PROG(SNMPGET, snmpget)
 389 if test "x$ac_cv_path_SNMPGET" = "x"; then
 390   AC_MSG_WARN(snmpget not found - Simultaneous-Use and checkrad.pl may not work)
 391 fi
 392
 393 AC_PATH_PROG(SNMPWALK, snmpwalk)
 394 if test "x$ac_cv_path_SNMPWALK" = "x"; then
 395   AC_MSG_WARN(snmpwalk not found - Simultaneous-Use and checkrad.pl may not work)
 396 fi
 397
 398 AC_PATH_PROG(RUSERS, rusers, /usr/bin/rusers)
 399
 400 dnl FIXME This is truly gross.
 401 missing_dir=`cd $ac_aux_dir && pwd`
 402 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
 403 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
 404 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
 405
 406 AC_PATH_PROG(LOCATE,locate)
 407 AC_PATH_PROG(DIRNAME,dirname)
 408 AC_PATH_PROG(GREP,grep)
 409
 410 dnl #############################################################
 411 dnl #
 412 dnl #  2. Checks for libraries
 413 dnl #
 414 dnl #############################################################
 415
 416 dnl If using pthreads, check for -lpthread (posix) or -lc_r (*BSD)
 417 old_CFLAGS=$CFLAGS
 418 if test "x$WITH_THREADS" = "xyes"; then
 419   if test $ac_cv_prog_suncc = "yes"; then
 420     CFLAGS="$CFLAGS -mt"
 421   fi
 422
 423   AC_CHECK_HEADERS(pthread.h, [], [ WITH_THREADS="no" ])
 424
 425 dnl #
 426 dnl # pthread stuff is usually in -lpthread
 427 dnl # or in -lc_r, on *BSD
 428 dnl #
 429 dnl # On Some systems, we need extra pre-processor flags, to get them to
 430 dnl # to do the threading properly.
 431 dnl #
 432   AC_CHECK_LIB(pthread, pthread_create,
 433                 [ CFLAGS="$CFLAGS -D_REENTRANT -D_POSIX_PTHREAD_SEMANTICS"
 434                   LIBS="$LIBS -lpthread" ],
 435                 AC_CHECK_LIB(c_r, pthread_create,
 436                             [ CFLAGS="$CFLAGS -pthread -D_THREAD_SAFE" ],
 437                             [ WITH_THREADS="no" ]
 438                             )
 439                 )
 440 fi
 441
 442 dnl #
 443 dnl # If we have NO pthread libraries, remove any knowledge of threads.
 444 dnl #
 445 if test "x$WITH_THREADS" != "xyes"; then
 446   CFLAGS=$old_CFLAGS
 447   ac_cv_header_pthread_h="no"
 448   WITH_THREADS=no
 449 else
 450   dnl #
 451   dnl #  We need sem_init() and friends, as they're the friendliest
 452   dnl #  semaphore functions for threading.
 453   dnl #
 454   dnl # HP/UX requires linking with librt, too, to get the sem_* symbols.
 455   dnl # Some systems have them in -lsem
 456   dnl # Solaris has them in -lposix4
 457   dnl # NetBSD has them in -lsemaphore
 458
 459   AC_SEARCH_LIBS(sem_init, pthread sem posix4 rt semaphore,
 460         [],
 461         [AC_MSG_ERROR(-lsem not found.  You may want to download it from ftp://ftp.to.gd-es.com/pub/BSDI/libsem.tar.bz2 or ftp://ftp.freeradius.org/pub/radius/contrib/libsem.tar.gz)]
 462    )
 463 fi
 464
 465 dnl Check if we need -lsocket
 466 AC_CHECK_LIB(socket, getsockname)
 467
 468 dnl Check for -lresolv
 469 dnl This library may be needed later.
 470 AC_CHECK_LIB(resolv, inet_aton)
 471
 472 dnl Check if we need -lnsl. Usually if we want to
 473 dnl link against -lsocket we need to include -lnsl as well.
 474 AC_CHECK_LIB(nsl, inet_ntoa)
 475
 476 dnl Check for OpenSSL libraries.
 477 OPENSSL_LIBS=
 478 old_LIBS=$LIBS
 479 if test "x$OPENSSL_LIB_DIR" != "x"; then
 480     LIBS="-L$OPENSSL_LIB_DIR $LIBS"
 481 fi
 482 AC_CHECK_LIB(crypto, DH_new,
 483     [
 484         AC_DEFINE(HAVE_LIBCRYPTO, 1,
 485             [Define to 1 if you have the `crypto' library (-lcrypto).])
 486         AC_CHECK_LIB(ssl, SSL_new,
 487             [
 488                 AC_DEFINE(HAVE_LIBSSL, 1,
 489                     [Define to 1 if you have the `ssl' library (-lssl).])
 490                 if test "x$OPENSSL_LIB_DIR" != "x"; then
 491                     OPENSSL_LIBS="-L$OPENSSL_LIB_DIR"
 492                 fi
 493                 OPENSSL_LIBS="$OPENSSL_LIBS -lcrypto -lssl -lcrypto"
 494             ], [])
 495     ], [])
 496 LIBS=$old_LIBS
 497
 498 dnl Check the pcap library for the RADIUS sniffer.
 499 PCAP_LIBS=
 500 AC_CHECK_LIB(pcap, pcap_open_live,
 501         [ PCAP_LIBS="-lpcap"
 502         AC_DEFINE(HAVE_LIBPCAP, 1,
 503                 [Define to 1 if you have the `pcap' library (-lpcap).])
 504         ],
 505         [ AC_MSG_WARN([pcap library not found, silently disabling the RADIUS sniffer.]) ])
 506
 507 dnl #############################################################
 508 dnl #
 509 dnl #  3. Checks for header files
 510 dnl #
 511 dnl #############################################################
 512
 513 dnl #
 514 dnl # Interix requires us to set -D_ALL_SOURCE, otherwise
 515 dnl # getopt will be #included, but won't link.  <sigh>
 516 dnl #
 517 dnl #
 518 case "$host" in
 519 *-interix*)
 520         CFLAGS="$CFLAGS -D_ALL_SOURCE"
 521         ;;
 522 *-darwin*)
 523         CFLAGS="$CFLAGS -DDARWIN"
 524         ;;
 525 esac
 526
 527 AC_HEADER_DIRENT
 528 AC_HEADER_STDC
 529 AC_HEADER_TIME
 530 AC_HEADER_SYS_WAIT
 531
 532 AC_CHECK_HEADERS( \
 533         unistd.h \
 534         crypt.h \
 535         errno.h \
 536         resource.h \
 537         getopt.h \
 538         malloc.h \
 539         utmp.h \
 540         utmpx.h \
 541         signal.h \
 542         sys/select.h \
 543         syslog.h \
 544         inttypes.h \
 545         stdint.h \
 546         stdio.h \
 547         netdb.h \
 548         semaphore.h \
 549         arpa/inet.h \
 550         netinet/in.h \
 551         sys/types.h \
 552         sys/socket.h \
 553         sys/time.h \
 554         sys/wait.h \
 555         sys/security.h \
 556         fcntl.h \
 557         sys/fcntl.h \
 558         net/if.h \
 559         prot.h \
 560         sia.h \
 561         siad.h
 562 )
 563
 564 REGEX=no
 565 AC_CHECK_HEADER(regex.h, AC_DEFINE(HAVE_REGEX_H, [], [define this if we have the <regex.h> header file]))
 566 if test "x$ac_cv_header_regex_h" = "xyes"; then
 567   REGEX_EXTENDED=no
 568   REGEX=yes
 569   AC_EGREP_CPP(yes,
 570     [#include <regex.h>
 571      #ifdef REG_EXTENDED
 572        yes
 573      #endif
 574      ], [AC_DEFINE(HAVE_REG_EXTENDED, [], [define this if we have REG_EXTENDED (from <regex.h>)]) REGEX_EXTENDED=yes])
 575 fi
 576 AC_SUBST(REGEX)
 577 AC_SUBST(REGEX_EXTENDED)
 578
 579 dnl #
 580 dnl #  other checks which require headers
 581 dnl #
 582 if test "x$ac_cv_header_sys_security_h" = "xyes" && test "x$ac_cv_header_prot_h" = "xyes"
 583 then
 584   AC_DEFINE(OSFC2, [], [define if you have OSFC2 authentication])
 585 fi
 586
 587 if test "x$ac_cv_header_sia_h" = "xyes" && test "x$ac_cv_header_siad_h" = "xyes"
 588 then
 589   AC_DEFINE(OSFSIA, [], [define if you have OSFSIA authentication])
 590 fi
 591
 592 dnl Check for OpenSSL includes.
 593 OPENSSL_INCLUDE="-DNO_OPENSSL"
 594 if test "x$OPENSSL_LIBS" = "x"; then
 595     AC_MSG_NOTICE([skipping test for openssl/ssl.h])
 596 else
 597     old_CPPFLAGS=$CPPFLAGS
 598     if test "x$OPENSSL_INCLUDE_DIR" != "x"; then
 599         CPPFLAGS="$CPPFLAGS -I$OPENSSL_INCLUDE_DIR"
 600     fi
 601     dnl # stupid RedHat shit
 602     CPPFLAGS="$CPPFLAGS -DOPENSSL_NO_KRB5"
 603     AC_CHECK_HEADERS( \
 604         openssl/ssl.h \
 605         openssl/crypto.h \
 606         openssl/err.h \
 607         openssl/engine.h,
 608         [],
 609         OPENSSL_LIBS=
 610     )
 611     if test "x$OPENSSL_LIBS" != "x"; then
 612         AC_MSG_CHECKING([for OpenSSL version >= 0.9.7])
 613         AC_EGREP_CPP(yes,
 614             [#include <openssl/crypto.h>
 615              #if (OPENSSL_VERSION_NUMBER >= 0x00907000L)
 616              yes
 617              #endif
 618             ], goodssl="yes")
 619         if test "x$goodssl" != "xyes"; then
 620             AC_MSG_RESULT(no)
 621             OPENSSL_LIBS=
 622         else
 623             AC_MSG_RESULT(yes)
 624             if test "x$OPENSSL_INCLUDE_DIR" != "x"; then
 625                 OPENSSL_INCLUDE="-I$OPENSSL_INCLUDE_DIR -DOPENSSL_NO_KRB5"
 626             else
 627                 OPENSSL_INCLUDE="-DOPENSSL_NO_KRB5"
 628             fi
 629         fi
 630     fi
 631     CPPFLAGS=$old_CPPFLAGS
 632 fi
 633 AC_SUBST(OPENSSL_INCLUDE)
 634 AC_SUBST(OPENSSL_LIBS)
 635 export OPENSSL_LIBS
 636
 637 dnl Check the pcap includes for the RADIUS sniffer.
 638 if test "x$PCAP_LIBS" = x; then
 639     AC_MSG_NOTICE([skipping test for pcap.h.])
 640 else
 641     AC_CHECK_HEADER(pcap.h,
 642         AC_DEFINE(HAVE_PCAP_H, 1,
 643                 [Define to 1 if you have the <pcap.h> header file.]),
 644         [ PCAP_LIBS=
 645         AC_MSG_WARN([pcap.h not found, silently disabling the RADIUS sniffer.])
 646         ])
 647 fi
 648 AC_SUBST(PCAP_LIBS)
 649
 650 dnl #############################################################
 651 dnl #
 652 dnl #  4. Checks for typedefs
 653 dnl #
 654 dnl #############################################################
 655
 656 dnl #
 657 dnl # Ensure that these are defined
 658 dnl #
 659 AC_TYPE_OFF_T
 660 AC_TYPE_PID_T
 661 AC_TYPE_SIZE_T
 662 AC_TYPE_UID_T
 663
 664 dnl check for socklen_t
 665 FR_CHECK_TYPE_INCLUDE([
 666 #ifdef HAVE_SYS_TYPES_H
 667 #include <sys/types.h>
 668 #endif
 669 #ifdef HAVE_SYS_SOCKET_H
 670 #include <sys/socket.h>
 671 #endif
 672 ],socklen_t, int, [socklen_t is generally 'int' on systems which don't use it])
 673
 674 dnl check for uint8_t
 675 FR_CHECK_TYPE_INCLUDE([
 676 #ifdef HAVE_INTTYPES_H
 677 #include <inttypes.h>
 678 #endif
 679 #ifdef HAVE_STDINT_H
 680 #include <stdint.h>
 681 #endif
 682 ],uint8_t, unsigned char, [uint8_t should be the canonical 'octet' for network traffic])
 683
 684 dnl check for uint16_t
 685 FR_CHECK_TYPE_INCLUDE([
 686 #ifdef HAVE_INTTYPES_H
 687 #include <inttypes.h>
 688 #endif
 689 #ifdef HAVE_STDINT_H
 690 #include <stdint.h>
 691 #endif
 692 ],uint16_t, unsigned short, [uint16_t should be the canonical '2 octets' for network traffic])
 693
 694 dnl check for uint32_t
 695 FR_CHECK_TYPE_INCLUDE([
 696 #ifdef HAVE_INTTYPES_H
 697 #include <inttypes.h>
 698 #endif
 699 #ifdef HAVE_STDINT_H
 700 #include <stdint.h>
 701 #endif
 702 ],uint32_t, unsigned int, [uint32_t should be the canonical 'network integer])
 703
 704 AC_CHECK_TYPE(struct in6_addr, AC_DEFINE(HAVE_STRUCT_IN6_ADDR, 1, [IPv6 address structure]), [], [
 705 #ifdef HAVE_NETINET_IN_H
 706 #include <netinet/in.h>
 707 #endif
 708 ])
 709
 710 AC_CHECK_TYPE(struct sockaddr_storage, AC_DEFINE(HAVE_STRUCT_SOCKADDR_STORAGE, 1, [Generic socket addresses]), [], [
 711 #ifdef HAVE_NETINET_IN_H
 712 #include <netinet/in.h>
 713 #endif
 714 #ifdef HAVE_SYS_SOCKET_H
 715 #include <sys/socket.h>
 716 #endif
 717 ])
 718
 719 AC_CHECK_TYPE(struct sockaddr_in6, AC_DEFINE(HAVE_STRUCT_SOCKADDR_IN6, 1, [IPv6 socket addresses]), [], [
 720 #ifdef HAVE_NETINET_IN_H
 721 #include <netinet/in.h>
 722 #endif
 723 ])
 724
 725 AC_CHECK_TYPE(struct addrinfo, AC_DEFINE(HAVE_STRUCT_ADDRINFO, 1, [Generic DNS lookups]), [], [
 726 #ifdef HAVE_SYS_TYPES_H
 727 #include <sys/types.h>
 728 #endif
 729 #ifdef HAVE_SYS_SOCKET_H
 730 #include <sys/socket.h>
 731 #endif
 732 #ifdef HAVE_NETDB_H
 733 #include <netdb.h>
 734 #endif
 735 ])
 736
 737 dnl #############################################################
 738 dnl #
 739 dnl #  5. Checks for structures and functions
 740 dnl #
 741 dnl #############################################################
 742 AC_CHECK_FUNCS( \
 743         getopt_long \
 744         lockf \
 745         strsignal \
 746         sigaction \
 747         sigprocmask \
 748         pthread_sigmask \
 749         snprintf \
 750         vsnprintf \
 751         setsid \
 752         strncasecmp \
 753         strcasecmp \
 754         localtime_r \
 755         ctime_r \
 756         gmtime_r \
 757         strsep \
 758         inet_aton \
 759         inet_pton \
 760         inet_ntop \
 761         gethostname \
 762         setlinebuf \
 763         setvbuf \
 764         getusershell \
 765         initgroups \
 766         getaddrinfo \
 767         getnameinfo \
 768         closefrom \
 769         strlcat \
 770         strlcpy
 771 )
 772 RADIUSD_NEED_DECLARATIONS( \
 773         crypt \
 774         strncasecmp \
 775         strcasecmp \
 776         inet_aton \
 777         gethostname \
 778         setlinebuf \
 779         getusershell \
 780         endusershell
 781 )
 782
 783 AC_TYPE_SIGNAL
 784
 785 dnl # check if we have utmpx.h
 786 dnl # if so, check if struct utmpx has entry ut_xtime
 787 dnl # if not, set it to define ut_xtime == ut_tv.tv_sec
 788 if test "x$ac_cv_header_utmpx_h" = "xyes"
 789 then
 790  FR_CHECK_STRUCT_HAS_MEMBER([#include <utmpx.h>], [struct utmpx], ut_xtime)
 791  if test "x$ac_cv_type_struct_utmpx_has_ut_xtime" = "x"
 792  then
 793    AC_DEFINE(ut_xtime,ut_tv.tv_sec, [define to something if you don't have ut_xtime in struct utmpx])
 794  fi
 795 fi
 796
 797 dnl # struct ip_pktinfo
 798 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in_pktinfo], ipi_addr)
 799 if test "x$ac_cv_type_struct_in_pktinfo_has_ipi_addr" = "xyes"
 800 then
 801         AC_DEFINE(HAVE_IP_PKTINFO, [], [define if you have IP_PKTINFO (Linux)])
 802 fi
 803
 804 dnl # struct in6_pktinfo
 805 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in6_pktinfo], ipi6_addr)
 806 if test "x$ac_cv_type_struct_in6_pktinfo_has_ipi6_addr" = "xyes"
 807 then
 808         AC_DEFINE(HAVE_IN6_PKTINFO, [], [define if you have IN6_PKTINFO (Linux)])
 809 fi
 810
 811 dnl #############################################################
 812 dnl #
 813 dnl #  6. Checks for compiler characteristics
 814 dnl #
 815 dnl #############################################################
 816
 817 dnl #
 818 dnl # Ensure that these are defined
 819 dnl #
 820 AC_C_CONST
 821
 822 dnl #
 823 dnl # See if this is OS/2
 824 dnl #
 825 AC_MSG_CHECKING(type of OS)
 826 OS=`uname -s`
 827 AC_MSG_RESULT($OS)
 828 if test "$OS" = "OS/2"; then
 829         LIBPREFIX=
 830 else
 831         LIBPREFIX=lib
 832 fi
 833 AC_SUBST(LIBPREFIX)
 834
 835 dnl #
 836 dnl # Set Default CFLAGS
 837 dnl #
 838 if test "x$GCC" = "xyes"; then
 839     CFLAGS="$CFLAGS -Wall -D_GNU_SOURCE"
 840 fi
 841
 842 AC_MSG_CHECKING(for developer gcc flags)
 843 if test "x$developer" = "xyes" -a "x$GCC" = "xyes"; then
 844   devflags="-g -Wshadow -Wpointer-arith -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -W -Wredundant-decls -Wundef"
 845   CFLAGS="$CFLAGS $devflags"
 846   INSTALLSTRIP=""
 847   AC_MSG_RESULT(yes.  Using $devflags)
 848 else
 849   devflags=""
 850   CFLAGS="$CFLAGS -DNDEBUG"
 851   INSTALLSTRIP="-s"
 852   AC_MSG_RESULT(no.)
 853 fi
 854
 855 dnl #############################################################
 856 dnl #
 857 dnl #  7. Checks for library functions
 858 dnl #
 859 dnl #############################################################
 860
 861 dnl Check for libcrypt
 862 dnl We use crypt(3) which may be in libc, or in libcrypt (eg FreeBSD)
 863 AC_CHECK_LIB(crypt, crypt,
 864   CRYPTLIB="-lcrypt"
 865 )
 866 if test "$CRYPTLIB" != ""; then
 867   AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function])
 868 else
 869   AC_CHECK_FUNC(crypt, AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function]))
 870 fi
 871
 872 dnl Check for libcipher
 873 AC_CHECK_LIB(cipher, setkey,
 874    CRYPTLIB="${CRYPTLIB} -lcipher"
 875 )
 876 AC_SUBST(CRYPTLIB)
 877
 878 if test "x$WITH_SNMP" = "xyes"; then
 879   SNMP_CHECKS
 880 fi
 881
 882 dnl Check the style of gethostbyaddr, in order of preference
 883 dnl GNU (_r eight args)
 884 AC_DEFINE(GNUSTYLE, [1], [GNU-Style get*byaddr_r])
 885 dnl SYSV (_r six args)
 886 AC_DEFINE(SYSVSTYLE, [2], [SYSV-Style get*byaddr_r])
 887 dnl BSD (three args, may not be thread safe)
 888 AC_DEFINE(BSDSTYLE, [3], [BSD-Style get*byaddr_r])
 889 dnl Tru64 has BSD version, but it is thread safe
 890 dnl     http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1739____.HTM
 891 dnl We need #stdio.h to define NULL on FreeBSD (at least)
 892 gethostbyaddrrstyle=""
 893 AC_MSG_CHECKING([gethostbyaddr_r() syntax])
 894 case "$host" in
 895 *-freebsd*)
 896         AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE, [style of gethostbyaddr_r functions ])
 897         gethostbyaddrrstyle=BSD
 898         AC_MSG_WARN([FreeBSD overridden to BSD-style])
 899         ;;
 900 esac
 901 if test "x$gethostbyaddrrstyle" = "x"; then
 902         AC_TRY_LINK([
 903 #include <stdio.h>
 904 #include <netdb.h>
 905 ], [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL, NULL) ], [
 906         AC_DEFINE(GETHOSTBYADDRRSTYLE, GNUSTYLE, [style of gethostbyaddr_r functions ])
 907         gethostbyaddrrstyle=GNU
 908 ])
 909 fi
 910 if test "x$gethostbyaddrrstyle" = "x"; then
 911         AC_TRY_LINK([
 912 #include <stdio.h>
 913 #include <netdb.h>
 914 ], [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL) ] , [
 915                 AC_DEFINE(GETHOSTBYADDRRSTYLE, SYSVSTYLE, [style of gethostbyaddr_r functions ])
 916                 gethostbyaddrrstyle=SYSV
 917         ])
 918 fi
 919 if test "x$gethostbyaddrrstyle" = "x"; then
 920         AC_TRY_LINK([
 921 #include <stdio.h>
 922 #include <netdb.h>
 923 ], [ gethostbyaddr(NULL, 0, 0)  ], [
 924                 AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE, [style of gethostbyaddr_r functions ])
 925                 gethostbyaddrrstyle=BSD
 926         ])
 927 fi
 928
 929 if test "x$gethostbyaddrrstyle" = "x"; then
 930         AC_MSG_RESULT([none!  It must not exist, here.])
 931 else
 932         AC_MSG_RESULT([${gethostbyaddrrstyle}-style])
 933 fi
 934
 935 if test "x$gethostbyaddrrstyle" = "xBSD"; then
 936         AC_MSG_WARN([ ****** BSD-style gethostbyaddr might NOT be thread-safe! ****** ])
 937 fi
 938
 939 dnl Check the style of gethostbyname, in order of preference
 940 dnl GNU (_r seven args)
 941 dnl SYSV (_r five args)
 942 dnl BSD (two args, may not be thread safe)
 943 dnl Tru64 has BSD version, but it _is_ thread safe
 944 dnl     http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1946____.HTM
 945 dnl We need #stdio.h to define NULL on FreeBSD (at least)
 946 gethostbynamerstyle=""
 947 AC_MSG_CHECKING([gethostbyname_r() syntax])
 948 AC_TRY_LINK([
 949 #include <stdio.h>
 950 #include <netdb.h>
 951 ], [ gethostbyname_r(NULL, NULL, NULL, 0, NULL, NULL) ], [
 952         AC_DEFINE(GETHOSTBYNAMERSTYLE, GNUSTYLE, [style of gethostbyname_r functions ])
 953         gethostbynamerstyle=GNU
 954 ])
 955 if test "x$gethostbynamerstyle" = "x"; then
 956         AC_TRY_LINK([
 957 #include <stdio.h>
 958 #include <netdb.h>
 959 ], [ gethostbyname_r(NULL, NULL, NULL, 0, NULL) ] , [
 960                 AC_DEFINE(GETHOSTBYNAMERSTYLE, SYSVSTYLE, [style of gethostbyname_r functions ])
 961                 gethostbynamerstyle=SYSV
 962         ])
 963 fi
 964 if test "x$gethostbynamerstyle" = "x"; then
 965         AC_TRY_LINK([
 966 #include <stdio.h>
 967 #include <netdb.h>
 968 ], [ gethostbyname(NULL)  ], [
 969                 AC_DEFINE(GETHOSTBYNAMERSTYLE, BSDSTYLE, [style of gethostbyname_r functions ])
 970                 gethostbynamerstyle=BSD
 971         ])
 972 fi
 973
 974 if test "x$gethostbynamerstyle" = "x"; then
 975         AC_MSG_RESULT([none!  It must not exist, here.])
 976 else
 977         AC_MSG_RESULT([${gethostbynamerstyle}-style])
 978 fi
 979
 980 if test "x$gethostbynamerstyle" = "xBSD"; then
 981         AC_MSG_WARN([ ****** BSD-style gethostbyname might NOT be thread-safe! ****** ])
 982 fi
 983
 984 dnl check for non-posix solaris ctime_r (extra buflen int arg)
 985 AC_DEFINE(POSIXSTYLE, [1], [Posix-Style ctime_r])
 986 AC_DEFINE(SOLARISSTYLE, [2], [Solaris-Style ctime_r])
 987 ctimerstyle=""
 988 AC_MSG_CHECKING([ctime_r() syntax])
 989 AC_TRY_LINK([
 990 #include <time.h>
 991 ], [ ctime_r(NULL, NULL, 0) ], [
 992         AC_DEFINE(CTIMERSTYLE, SOLARISSTYLE, [style of ctime_r function])
 993         ctimerstyle="SOLARIS"
 994 ])
 995 if test "x$ctimerstyle" = "x"; then
 996         AC_TRY_LINK([
 997 #include <time.h>
 998 ], [ ctime_r(NULL, NULL) ], [
 999                 AC_DEFINE(CTIMERSTYLE, POSIXSTYLE, [style of ctime_r function])
1000                 ctimerstyle="POSIX"
1001         ])
1002 fi
1003
1004 if test "x$ctimerstyle" = "x"; then
1005         AC_MSG_RESULT([none!  It must not exist, here.])
1006 else
1007         AC_MSG_RESULT([${ctimerstyle}-style])
1008 fi
1009
1010 AC_SUBST(HOSTINFO, $host)
1011
1012 dnl #############################################################
1013 dnl #
1014 dnl #  8. Checks for system services
1015 dnl #
1016 dnl #############################################################
1017
1018 dnl #
1019 dnl # Figure out where libtool is located,
1020 dnl #
1021 top_builddir=`pwd`
1022 export top_builddir
1023 AC_MSG_RESULT([top_builddir=$top_builddir])
1024 dnl # AC_SUBST(top_builddir)
1025 AC_SUBST(LIBLTDL)
1026 AC_SUBST(INCLTDL)
1027
1028 dnl import libtool stuff
1029
1030 dnl #############################################################
1031 dnl #
1032 dnl #  Configure in any module directories.
1033 dnl #
1034 dnl #############################################################
1035
1036 mysubdirs="$LIBLTDLPATH"
1037 if test "x$EXPERIMENTAL" = "xyes"; then
1038   bar=`ls -1 "${srcdir}"/src/modules/rlm_*/configure | sed 's%/configure%%'`
1039   dnl # get rid of LF's.
1040   mysubdirs=`echo $mysubdirs $bar`
1041 else
1042   dnl #
1043   dnl # Find 'configure' in ONLY the stable modules
1044   dnl #
1045   for bar in `cat "${srcdir}"/src/modules/stable`; do
1046     if test -f "${srcdir}"/src/modules/$bar/configure; then
1047       mysubdirs="$mysubdirs src/modules/$bar"
1048     fi
1049   done
1050 fi
1051
1052 dnl ############################################################
1053 dnl # make modules by list
1054 dnl #############################################################
1055 if test "x$EXPERIMENTAL" = "xyes"; then
1056   for foo in `ls -1 "${srcdir}"/src/modules | grep rlm_`; do
1057     MODULES="$MODULES $foo"
1058   done
1059 else
1060    dnl #
1061    dnl # make ONLY the stable modules
1062    dnl #
1063    for foo in `cat "${srcdir}"/src/modules/stable`; do
1064     MODULES="$MODULES $foo"
1065    done
1066 fi
1067
1068 dnl #
1069 dnl #  Don't change the variable name here.  Autoconf goes bonkers
1070 dnl #  if you do.
1071 dnl #
1072 AC_CONFIG_SUBDIRS($LTDL_SUBDIRS $mysubdirs)
1073 AC_SUBST(MODULES)
1074
1075 dnl #############################################################
1076 dnl #
1077 dnl #  And finally, output the results.
1078 dnl #
1079 dnl #############################################################
1080
1081 AC_CONFIG_COMMANDS([stamp-h], [echo timestamp > src/include/stamp-h])
1082 AC_CONFIG_COMMANDS([build-radpaths-h], [(cd ./src/include && /bin/sh ./build-radpaths-h)])
1083 AC_CONFIG_COMMANDS([main-chmod], [(cd ./src/main   && chmod +x checkrad.pl radlast radtest)])
1084 AC_CONFIG_COMMANDS([scripts-chmod], [(cd ./scripts    && chmod +x rc.radiusd radwatch check-radiusd-config radiusd.cron.daily radiusd.cron.monthly cryptpasswd)])
1085
1086 dnl #
1087 dnl #  Substitute whatever libraries we found to be necessary
1088 dnl #
1089 AC_SUBST(LIBS)
1090 AC_SUBST(INSTALLSTRIP)
1091
1092 USE_SHARED_LIBS=$enable_shared
1093 AC_SUBST(USE_SHARED_LIBS)
1094 USE_STATIC_LIBS=$enable_static
1095 AC_SUBST(USE_STATIC_LIBS)
1096 AC_SUBST(STATIC_MODULES)
1097 AC_SUBST(RADIUSD_MAJOR_VERSION)
1098 AC_SUBST(RADIUSD_MINOR_VERSION)
1099 AC_SUBST(RADIUSD_VERSION)
1100
1101 AC_OUTPUT(\
1102         ./Make.inc \
1103         ./src/include/build-radpaths-h \
1104         ./src/main/Makefile \
1105         ./src/main/checkrad.pl \
1106         ./src/main/radlast \
1107         ./src/main/radtest \
1108         ./scripts/rc.radiusd \
1109         ./scripts/radwatch \
1110         ./scripts/check-radiusd-config \
1111         ./scripts/radiusd.cron.daily \
1112         ./scripts/radiusd.cron.monthly \
1113         ./scripts/cryptpasswd \
1114         ./raddb/dictionary \
1115         ./raddb/radiusd.conf \
1116         ./raddb/radrelay.conf
1117 )