configure.in

   1 dnl #############################################################
   2 dnl #
   3 dnl #  For information about autoconf, see:
   4 dnl #
   5 dnl #  http://www.gnu.org/software/autoconf/
   6 dnl #
   7 dnl #  The recommended order is:
   8 dnl #
   9 dnl #  AC_INIT(file)
  10 dnl #  0. checks for compiler, libtool, and command line options
  11 dnl #  1. checks for programs
  12 dnl #  2. checks for libraries
  13 dnl #  3. checks for header files
  14 dnl #  4. checks for typedefs
  15 dnl #  5. checks for structures and functions
  16 dnl #  6. checks for compiler characteristics
  17 dnl #  7. checks for library functions
  18 dnl #  8. checks for system services
  19 dnl #  AC_OUTPUT([file...])
  20 dnl #
  21 dnl #############################################################
  22
  23 AC_PREREQ([2.59])
  24 export CFLAGS LIBS LDFLAGS CPPFLAGS
  25 AC_INIT(src/main/radiusd.c)
  26 AC_CONFIG_HEADER(src/include/autoconf.h)
  27 AC_REVISION($Revision$)dnl
  28
  29 dnl # The version of the software
  30 RADIUSD_VERSION=`cat VERSION`
  31 RADIUSD_MAJOR_VERSION=`cat VERSION | sed 's/\..*//'`
  32 RADIUSD_MINOR_VERSION=`cat VERSION | sed 's/^2\.//'`
  33 PACKAGE=freeradius
  34
  35 dnl #############################################################
  36 dnl #
  37 dnl #  0. Checks for compiler, libtool, and command line options.
  38 dnl #
  39 dnl #############################################################
  40
  41 dnl Check for GNU cc
  42 AC_PROG_CC
  43 AC_PROG_CXX
  44
  45 dnl #
  46 dnl # check for AIX, to allow us to use some BSD functions
  47 dnl # must be before macros that call the compiler.
  48 dnl #
  49 AC_AIX
  50
  51 AC_PROG_GCC_TRADITIONAL
  52 AC_PROG_CC_SUNPRO
  53 AC_PROG_RANLIB
  54
  55 dnl Compile in large (2G+) file support.
  56 AC_SYS_LARGEFILE
  57
  58 dnl # check for system bytesex
  59 dnl # AC_DEFINES WORDS_BIGENDIAN
  60 AC_C_BIGENDIAN
  61
  62 dnl Find GNU Make.
  63 AC_CHECK_PROG(GMAKE, gmake, yes, no)
  64 if test $GMAKE = no; then
  65   AC_PATH_PROG(MAKE, make, /usr/local/bin/make)
  66 else
  67   AC_PATH_PROG(MAKE, gmake, /usr/local/gnu/bin/make)
  68 fi
  69 makever=`$ac_cv_path_MAKE --version 2>&1 | grep "GNU Make"`
  70 if test -z "$makever"; then
  71   AC_MSG_ERROR(GNU Make is not installed.  Please download and install it
  72                 from ftp://prep.ai.mit.edu/pub/gnu/make/ before continuing.)
  73 fi
  74
  75 dnl libltdl is installable
  76 AC_LIBLTDL_INSTALLABLE
  77
  78 dnl tell Makefile to build ltdl if needed
  79 if test x"$enable_ltdl_install" = x"yes"; then
  80   LTDL_SUBDIRS=libltdl
  81 fi
  82 AC_SUBST(LTDL_SUBDIRS)
  83
  84 dnl use system-wide libtool, if it exists
  85 AC_ARG_WITH(system-libtool,
  86 [  --with-system-libtool              try to use libtool installed in your system [default=use our own]],
  87 [ AC_PATH_PROG(LIBTOOL, libtool,,$PATH:/usr/local/bin) ],
  88 [
  89   LIBTOOL="`pwd`/libtool"
  90   AC_SUBST(LIBTOOL)
  91   dnl ensure that we're looking for dlopen
  92   AC_LIBTOOL_DLOPEN
  93
  94   dnl Figure out how to build shared libraries
  95   AC_PROG_LIBTOOL
  96 ])
  97
  98
  99 dnl Put this in later, when all distributed modules use autoconf.
 100 dnl AC_ARG_WITH(disablemodulefoo,
 101 dnl [  --without-rlm_foo       Disables module compilation.  Module list:]
 102 dnl esyscmd([find src/modules -type d -name rlm_\* -print |\
 103 dnl     sed -e 's%src/modules/.*/% (sub)- %; s%.*/%- %' |\
 104 dnl     awk '{print "                            "$0}']))
 105
 106 AC_ARG_ENABLE(strict-dependencies,
 107 [  --enable-strict-dependencies  Fail configure on lack of module dependancy.])
 108
 109 dnl extra argument: --with-docdir
 110 docdir='${datadir}/doc/freeradius'
 111 AC_MSG_CHECKING(docdir)
 112 AC_ARG_WITH(docdir,
 113 [  --with-docdir=DIR       Directory for documentation [DATADIR/doc/freeradius] ],
 114 [ case "$withval" in
 115     no)
 116         docdir=no
 117         ;;
 118     yes)
 119         ;;
 120     [[\\/$]]* | ?:[[\\/]]* )
 121         docdir="$withval"
 122         ;;
 123     *)
 124         AC_MSG_ERROR([expected an absolute directory name for --with-docdir: $withval])
 125         ;;
 126   esac ]
 127 )
 128 AC_SUBST(docdir)
 129 AC_MSG_RESULT($docdir)
 130 if test "x$docdir" = xno; then
 131         AC_MSG_WARN(Documentation files will NOT be installed.)
 132 fi
 133
 134 dnl extra argument: --with-logdir
 135 logdir='${localstatedir}/log/radius'
 136 AC_MSG_CHECKING(logdir)
 137 AC_ARG_WITH(logdir,
 138 [  --with-logdir=DIR       Directory for logfiles [LOCALSTATEDIR/log/radius] ],
 139 [ case "$withval" in
 140     no)
 141         AC_MSG_ERROR(Need logdir)
 142         ;;
 143     yes)
 144         ;;
 145     [[\\/$]]* | ?:[[\\/]]* )
 146         logdir="$withval"
 147         ;;
 148     *)
 149         AC_MSG_ERROR([expected an absolute directory name for --with-logdir: $withval])
 150         ;;
 151   esac ]
 152 )
 153 AC_SUBST(logdir)
 154 AC_MSG_RESULT($logdir)
 155
 156 dnl extra argument: --with-radacctdir
 157 radacctdir='${logdir}/radacct'
 158 AC_MSG_CHECKING(radacctdir)
 159 AC_ARG_WITH(radacctdir,
 160 [  --with-radacctdir=DIR   Directory for detail files [LOGDIR/radacct] ],
 161 [ case "$withval" in
 162     no)
 163         AC_MSG_ERROR(Need radacctdir)
 164         ;;
 165     yes)
 166         ;;
 167     [[\\/$]]* | ?:[[\\/]]* )
 168         radacctdir="$withval"
 169         ;;
 170     *)
 171         AC_MSG_ERROR([expected an absolute directory name for --with-radacctdir: $withval])
 172         ;;
 173   esac ]
 174 )
 175 AC_SUBST(radacctdir)
 176 AC_MSG_RESULT($radacctdir)
 177
 178 dnl extra argument: --with-raddbdir
 179 raddbdir='${sysconfdir}/raddb'
 180 AC_MSG_CHECKING(raddbdir)
 181 AC_ARG_WITH(raddbdir,
 182 [  --with-raddbdir=DIR     Directory for config files [SYSCONFDIR/raddb] ],
 183 [ case "$withval" in
 184     no)
 185         AC_MSG_ERROR(Need raddbdir)
 186         ;;
 187     yes)
 188         ;;
 189     [[\\/$]]* | ?:[[\\/]]* )
 190         raddbdir="$withval"
 191         ;;
 192     *)
 193         AC_MSG_ERROR([expected an absolute directory name for --with-raddbdir: $withval])
 194         ;;
 195   esac ]
 196 )
 197 AC_SUBST(raddbdir)
 198 AC_MSG_RESULT($raddbdir)
 199
 200 dnl extra argument: --with-ascend-binary
 201 ASCEND_BINARY=yes
 202 AC_ARG_WITH(ascend-binary,
 203 [  --with-ascend-binary    Include support for Ascend binary filter attributes (default=yes)],
 204 [ case "$withval" in
 205     yes)
 206         ;;
 207     *)
 208         ASCEND_BINARY=""
 209   esac ]
 210 )
 211 if test "X$ASCEND_BINARY" = "Xyes"; then
 212   AC_DEFINE(ASCEND_BINARY, [], [Include support for Ascend binary filter attributes])
 213 fi
 214
 215 dnl extra argument: --with-threads
 216 WITH_THREADS=yes
 217 AC_ARG_WITH(threads,
 218 [  --with-threads          Use threads, if available.  (default=yes) ],
 219 [ case "$withval" in
 220     yes)
 221         ;;
 222     *)
 223         WITH_THREADS=""
 224   esac ]
 225 )
 226
 227 dnl extra argument: --with-snmp
 228 WITH_SNMP=yes
 229 AC_ARG_WITH(snmp,
 230 [  --with-snmp             Compile in SNMP support. (default=yes)],
 231 [ case "$withval" in
 232     yes)
 233         ;;
 234     *)
 235         WITH_SNMP=no
 236   esac ]
 237 )
 238
 239 dnl #
 240 dnl # extra argument: --with-snmp-include-dir
 241 dnl #
 242 AC_ARG_WITH(snmp-include-dir,
 243 [  --with-snmp-include-dir=DIR  Directory to look for include files used by SNMP],
 244 [ case "$withval" in
 245     *)
 246         ;;
 247   esac ]
 248 )
 249
 250 dnl extra argument: --with-vmps
 251 WITH_VMPS=yes
 252 AC_ARG_WITH(vmps,
 253 [  --with-vmps             Compile in VMPS support. (default=yes)],
 254 [ case "$withval" in
 255     yes)
 256         ;;
 257     *)
 258         WITH_VMPS=no
 259   esac ]
 260 )
 261 if test "x$WITH_VMPS" = "xyes"; then
 262         AC_DEFINE(WITH_VMPS, [1], [define if you want VMPS support])
 263 fi
 264
 265 dnl extra argument: --with-dhcp
 266 AC_ARG_WITH(dhcp,
 267 [  --with-dhcp             Compile in DHCP support. (default=no)],
 268 [ case "$withval" in
 269     yes)
 270         AC_DEFINE(WITH_DHCP, [1], [Include experimental support for DHCP])
 271         ;;
 272     *)
 273         ;;
 274   esac ]
 275 )
 276
 277
 278 dnl #
 279 dnl #  Allow the user to specify a list of modules to be linked
 280 dnl #  statically to the server.
 281 dnl #
 282 STATIC_MODULES=
 283 AC_ARG_WITH(static_modules,
 284 [  --with-static-modules=QUOTED-MODULE-LIST],[
 285   for i in $withval; do
 286     STATIC_MODULES="$STATIC_MODULES -dlpreopen ../modules/rlm_$i/rlm_$i.la"
 287   done
 288 ])
 289
 290 MODULES=
 291 AC_ARG_WITH(modules,
 292 [ --with-modules=QUOTED-MODULE-LIST],[
 293  for i in $withval; do
 294    MODULES="$MODULES $i"
 295  done
 296 ])
 297
 298 dnl #
 299 dnl #  Enable developer C compiler warnings
 300 dnl #
 301 AC_ARG_ENABLE(developer,
 302 [  --enable-developer               Enables features of interest to developers.],
 303 [ case "$enableval" in
 304     no)
 305         developer=no
 306         ;;
 307     *)
 308         developer=yes
 309   esac ]
 310 )
 311
 312 if test "x$developer" != "xno" -a -d $srcdir/CVS; then
 313   dnl turn on the developer flag when taken from a CVS checkout (not a release)
 314   developer="yes"
 315 fi
 316
 317 dnl extra argument: --with-experimental-modules
 318 EXPERIMENTAL=
 319 AC_ARG_WITH(experimental-modules,
 320 [  --with-experimental-modules      Use experimental and unstable modules. (default=no) ],
 321 [ case "$withval" in
 322     yes)
 323         EXPERIMENTAL=yes
 324         ;;
 325     *)
 326   esac ]
 327 )
 328
 329 dnl extra argument: --with-openssl
 330 WITH_OPENSSL=yes
 331 AC_ARG_WITH(openssl,
 332 [  --with-openssl                   Use OpenSSL. (default=yes)],
 333 [ case "$withval" in
 334     no)
 335         WITH_OPENSSL=no
 336         ;;
 337     *)
 338         WITH_OPENSSL=yes
 339         ;;
 340   esac ]
 341 )
 342
 343 dnl #
 344 dnl # extra argument: --with-openssl-includes=dir
 345 dnl #
 346 OPENSSL_INCLUDE_DIR=
 347 AC_ARG_WITH(openssl-includes,
 348 [  --with-openssl-includes=DIR      Directory to look for OpenSSL include files],
 349 [ case "$withval" in
 350     *) OPENSSL_INCLUDE_DIR="$withval"
 351         ;;
 352   esac ]
 353 )
 354
 355 dnl #
 356 dnl # extra argument: --with-openssl-libraries=dir
 357 dnl #
 358 OPENSSL_LIB_DIR=
 359 AC_ARG_WITH(openssl-libraries,
 360 [  --with-openssl-libraries=DIR     Directory to look for OpenSSL library files],
 361 [ case "$withval" in
 362     *) OPENSSL_LIB_DIR="$withval"
 363         ;;
 364   esac ]
 365 )
 366
 367 dnl #
 368 dnl #  These next two arguments don't actually do anything.  They're
 369 dnl #  place holders so that the top-level configure script can tell
 370 dnl #  the user how to configure lower-level modules
 371 dnl #
 372
 373 dnl #
 374 dnl # extra argument: --with-rlm-FOO-lib-dir
 375 dnl #
 376 AC_ARG_WITH(rlm-FOO-lib-dir,
 377 [  --with-rlm-FOO-lib-dir=DIR       Directory to look for library files used by module FOO],
 378 [ case "$withval" in
 379     *)
 380         ;;
 381   esac ]
 382 )
 383
 384 dnl #
 385 dnl # extra argument: --with-rlm-FOO-include-dir
 386 dnl #
 387 AC_ARG_WITH(rlm-FOO-include-dir,
 388 [  --with-rlm-FOO-include-dir=DIR   Directory to look for include files used by module FOO],
 389 [ case "$withval" in
 390     *)
 391         ;;
 392   esac ]
 393 )
 394
 395 dnl See what include-style is used by the make program.
 396 dnl AC_MSG_CHECKING(include style for make)
 397 dnl echo "include /dev/null" > testmake.$$
 398 dnl echo "all:" >> testmake.$$
 399 dnl make -f testmake.$$ >/dev/null 2>&1
 400 dnl if test $? = 0
 401 dnl then
 402 dnl     INCLUDE=include
 403 dnl     IQUOTE=
 404 dnl else
 405 dnl     INCLUDE=.include
 406 dnl     IQUOTE='"'
 407 dnl fi
 408 dnl rm -f testmake.$$
 409 dnl AC_MSG_RESULT(" $INCLUDE")
 410 dnl AC_SUBST(INCLUDE)
 411 dnl AC_SUBST(IQUOTE)
 412
 413 dnl extra argument: --with-udpfromto
 414 WITH_UDPFROMTO=no
 415 AC_ARG_WITH(udpfromto,
 416 [  --with-udpfromto        Compile in UDPFROMTO support. (default=yes)],
 417 [ case "$withval" in
 418     yes)
 419         WITH_UDPFROMTO=yes
 420         ;;
 421     *)
 422         WITH_UDPFROMTO=no
 423   esac ]
 424 )
 425
 426 if test "x$WITH_UDPFROMTO" = "xyes"; then
 427         AC_DEFINE(WITH_UDPFROMTO, [], [define if you want udpfromto])
 428 fi
 429
 430 dnl #############################################################
 431 dnl #
 432 dnl #  1. Checks for programs
 433 dnl #
 434 dnl #############################################################
 435
 436 CHECKRAD=checkrad.pl
 437 AC_PATH_PROG(PERL, perl, /usr/local/bin/perl)
 438 if test "x$ac_cv_path_PERL" = "x"; then
 439   AC_MSG_WARN(perl not found - Simultaneous-Use and checkrad.pl may not work)
 440 fi
 441 AC_PATH_PROG(SNMPGET, snmpget)
 442 if test "x$ac_cv_path_SNMPGET" = "x"; then
 443   AC_MSG_WARN(snmpget not found - Simultaneous-Use and checkrad.pl may not work)
 444 fi
 445
 446 AC_PATH_PROG(SNMPWALK, snmpwalk)
 447 if test "x$ac_cv_path_SNMPWALK" = "x"; then
 448   AC_MSG_WARN(snmpwalk not found - Simultaneous-Use and checkrad.pl may not work)
 449 fi
 450
 451 AC_PATH_PROG(RUSERS, rusers, /usr/bin/rusers)
 452
 453 dnl FIXME This is truly gross.
 454 missing_dir=`cd $ac_aux_dir && pwd`
 455 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
 456 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
 457 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
 458
 459 AC_PATH_PROG(LOCATE,locate)
 460 AC_PATH_PROG(DIRNAME,dirname)
 461 AC_PATH_PROG(GREP,grep)
 462
 463 dnl #############################################################
 464 dnl #
 465 dnl #  2. Checks for libraries
 466 dnl #
 467 dnl #############################################################
 468
 469 dnl If using pthreads, check for -lpthread (posix) or -lc_r (*BSD)
 470 old_CFLAGS=$CFLAGS
 471 if test "x$WITH_THREADS" = "xyes"; then
 472   if test $ac_cv_prog_suncc = "yes"; then
 473     CFLAGS="$CFLAGS -mt"
 474   fi
 475
 476   AC_CHECK_HEADERS(pthread.h, [], [ WITH_THREADS="no" ])
 477
 478 dnl #
 479 dnl # pthread stuff is usually in -lpthread
 480 dnl # or in -lc_r, on *BSD
 481 dnl #
 482 dnl # On Some systems, we need extra pre-processor flags, to get them to
 483 dnl # to do the threading properly.
 484 dnl #
 485   AC_CHECK_LIB(pthread, pthread_create,
 486                 [ CFLAGS="$CFLAGS -D_REENTRANT -D_POSIX_PTHREAD_SEMANTICS"
 487                   LIBS="$LIBS -lpthread" ],
 488                 AC_CHECK_LIB(c_r, pthread_create,
 489                             [ CFLAGS="$CFLAGS -pthread -D_THREAD_SAFE" ],
 490                             [ WITH_THREADS="no" ]
 491                             )
 492                 )
 493 fi
 494
 495 dnl #
 496 dnl # If we have NO pthread libraries, remove any knowledge of threads.
 497 dnl #
 498 if test "x$WITH_THREADS" != "xyes"; then
 499   CFLAGS=$old_CFLAGS
 500   ac_cv_header_pthread_h="no"
 501   WITH_THREADS=no
 502 else
 503   dnl #
 504   dnl #  We need sem_init() and friends, as they're the friendliest
 505   dnl #  semaphore functions for threading.
 506   dnl #
 507   dnl # HP/UX requires linking with librt, too, to get the sem_* symbols.
 508   dnl # Some systems have them in -lsem
 509   dnl # Solaris has them in -lposix4
 510   dnl # NetBSD has them in -lsemaphore
 511
 512   AC_SEARCH_LIBS(sem_init, pthread sem posix4 rt semaphore,
 513         [],
 514         [AC_MSG_ERROR(-lsem not found.  You may want to download it from ftp://ftp.to.gd-es.com/pub/BSDI/libsem.tar.bz2 or ftp://ftp.freeradius.org/pub/radius/contrib/libsem.tar.gz)]
 515    )
 516 fi
 517
 518 dnl Check if we need -lsocket
 519 AC_CHECK_LIB(socket, getsockname)
 520
 521 dnl Check for -lresolv
 522 dnl This library may be needed later.
 523 AC_CHECK_LIB(resolv, inet_aton)
 524
 525 dnl Check if we need -lnsl. Usually if we want to
 526 dnl link against -lsocket we need to include -lnsl as well.
 527 AC_CHECK_LIB(nsl, inet_ntoa)
 528
 529 dnl Check for OpenSSL libraries.
 530 OPENSSL_LIBS=
 531 if test "x$WITH_OPENSSL" = xyes; then
 532   old_LIBS=$LIBS
 533   if test "x$OPENSSL_LIB_DIR" != "x"; then
 534     LIBS="-L$OPENSSL_LIB_DIR $LIBS"
 535   fi
 536   AC_CHECK_LIB(crypto, DH_new,
 537     [
 538         LIBS="-lcrypto $LIBS"
 539         AC_DEFINE(HAVE_LIBCRYPTO, 1,
 540             [Define to 1 if you have the `crypto' library (-lcrypto).])
 541         AC_CHECK_LIB(ssl, SSL_new,
 542             [
 543                 AC_DEFINE(HAVE_LIBSSL, 1,
 544                     [Define to 1 if you have the `ssl' library (-lssl).])
 545                 if test "x$OPENSSL_LIB_DIR" != "x"; then
 546                     OPENSSL_LIBS="-L$OPENSSL_LIB_DIR"
 547                 fi
 548                 OPENSSL_LIBS="$OPENSSL_LIBS -lcrypto -lssl -lcrypto"
 549             ], [])
 550     ], [])
 551   LIBS=$old_LIBS
 552 fi
 553
 554 AC_CHECK_LIB(ws2_32, htonl)
 555
 556 dnl Check the pcap library for the RADIUS sniffer.
 557 PCAP_LIBS=
 558 AC_CHECK_LIB(pcap, pcap_open_live,
 559         [ PCAP_LIBS="-lpcap"
 560         AC_DEFINE(HAVE_LIBPCAP, 1,
 561                 [Define to 1 if you have the `pcap' library (-lpcap).])
 562         ],
 563         [ AC_MSG_WARN([pcap library not found, silently disabling the RADIUS sniffer.]) ])
 564
 565 dnl #############################################################
 566 dnl #
 567 dnl #  3. Checks for header files
 568 dnl #
 569 dnl #############################################################
 570
 571 dnl #
 572 dnl # Interix requires us to set -D_ALL_SOURCE, otherwise
 573 dnl # getopt will be #included, but won't link.  <sigh>
 574 dnl #
 575 dnl #
 576 case "$host" in
 577 *-interix*)
 578         CFLAGS="$CFLAGS -D_ALL_SOURCE"
 579         ;;
 580 *-darwin*)
 581         CFLAGS="$CFLAGS -DDARWIN"
 582         LIBS="-framework DirectoryService $LIBS"
 583         ;;
 584 esac
 585
 586 AC_HEADER_DIRENT
 587 AC_HEADER_STDC
 588 AC_HEADER_TIME
 589 AC_HEADER_SYS_WAIT
 590
 591 AC_CHECK_HEADERS( \
 592         unistd.h \
 593         crypt.h \
 594         errno.h \
 595         resource.h \
 596         sys/resource.h \
 597         getopt.h \
 598         malloc.h \
 599         utmp.h \
 600         utmpx.h \
 601         signal.h \
 602         sys/select.h \
 603         syslog.h \
 604         inttypes.h \
 605         stdint.h \
 606         stdio.h \
 607         netdb.h \
 608         semaphore.h \
 609         arpa/inet.h \
 610         netinet/in.h \
 611         sys/types.h \
 612         sys/socket.h \
 613         winsock.h \
 614         sys/time.h \
 615         sys/wait.h \
 616         sys/security.h \
 617         fcntl.h \
 618         sys/fcntl.h \
 619         sys/prctl.h \
 620         prot.h \
 621         pwd.h \
 622         grp.h \
 623         sia.h \
 624         siad.h
 625 )
 626
 627 dnl FreeBSD requires sys/socket.h before net/if.h
 628 AC_CHECK_HEADERS(net/if.h, [], [],
 629 [#ifdef HAVE_SYS_SOCKET_H
 630 # include <sys/socket.h>
 631 # endif
 632 ])
 633
 634 REGEX=no
 635 AC_CHECK_HEADER(regex.h, AC_DEFINE(HAVE_REGEX_H, [], [define this if we have the <regex.h> header file]))
 636 if test "x$ac_cv_header_regex_h" = "xyes"; then
 637   REGEX_EXTENDED=no
 638   REGEX=yes
 639   AC_EGREP_CPP(yes,
 640     [#include <regex.h>
 641      #ifdef REG_EXTENDED
 642        yes
 643      #endif
 644      ], [AC_DEFINE(HAVE_REG_EXTENDED, [], [define this if we have REG_EXTENDED (from <regex.h>)]) REGEX_EXTENDED=yes])
 645 fi
 646 AC_SUBST(REGEX)
 647 AC_SUBST(REGEX_EXTENDED)
 648
 649 dnl #
 650 dnl #  other checks which require headers
 651 dnl #
 652 if test "x$ac_cv_header_sys_security_h" = "xyes" && test "x$ac_cv_header_prot_h" = "xyes"
 653 then
 654   AC_DEFINE(OSFC2, [], [define if you have OSFC2 authentication])
 655 fi
 656
 657 if test "x$ac_cv_header_sia_h" = "xyes" && test "x$ac_cv_header_siad_h" = "xyes"
 658 then
 659   AC_DEFINE(OSFSIA, [], [define if you have OSFSIA authentication])
 660 fi
 661
 662 dnl Check for OpenSSL includes.
 663 OPENSSL_INCLUDE="-DNO_OPENSSL"
 664 if test "x$WITH_OPENSSL" = xyes; then
 665   if test "x$OPENSSL_LIBS" = "x"; then
 666     AC_MSG_NOTICE([skipping test for openssl/ssl.h])
 667   else
 668     old_CPPFLAGS=$CPPFLAGS
 669     if test "x$OPENSSL_INCLUDE_DIR" != "x"; then
 670         CPPFLAGS="$CPPFLAGS -I$OPENSSL_INCLUDE_DIR"
 671     fi
 672     dnl # stupid RedHat shit
 673     CPPFLAGS="$CPPFLAGS -DOPENSSL_NO_KRB5"
 674     AC_CHECK_HEADERS( \
 675         openssl/ssl.h \
 676         openssl/crypto.h \
 677         openssl/err.h \
 678         openssl/evp.h \
 679         openssl/engine.h,
 680         [],
 681         OPENSSL_LIBS=
 682     )
 683     if test "x$OPENSSL_LIBS" != "x"; then
 684         AC_MSG_CHECKING([for OpenSSL version >= 0.9.7])
 685         AC_EGREP_CPP(yes,
 686             [#include <openssl/crypto.h>
 687              #if (OPENSSL_VERSION_NUMBER >= 0x00907000L)
 688              yes
 689              #endif
 690             ], goodssl="yes")
 691         if test "x$goodssl" != "xyes"; then
 692             AC_MSG_RESULT(no)
 693             OPENSSL_LIBS=
 694         else
 695             AC_MSG_RESULT(yes)
 696             if test "x$OPENSSL_INCLUDE_DIR" != "x"; then
 697                 OPENSSL_INCLUDE="-I$OPENSSL_INCLUDE_DIR -DOPENSSL_NO_KRB5"
 698             else
 699                 OPENSSL_INCLUDE="-DOPENSSL_NO_KRB5"
 700             fi
 701         fi
 702     fi
 703     CPPFLAGS=$old_CPPFLAGS
 704   fi
 705 fi
 706 AC_SUBST(OPENSSL_INCLUDE)
 707 AC_SUBST(OPENSSL_LIBS)
 708 export OPENSSL_LIBS
 709
 710 dnl Check the pcap includes for the RADIUS sniffer.
 711 if test "x$PCAP_LIBS" = x; then
 712     AC_MSG_NOTICE([skipping test for pcap.h.])
 713 else
 714     AC_CHECK_HEADER(pcap.h,
 715         AC_DEFINE(HAVE_PCAP_H, 1,
 716                 [Define to 1 if you have the <pcap.h> header file.]),
 717         [ PCAP_LIBS=
 718         AC_MSG_WARN([pcap.h not found, silently disabling the RADIUS sniffer.])
 719         ])
 720 fi
 721 AC_SUBST(PCAP_LIBS)
 722
 723 dnl #############################################################
 724 dnl #
 725 dnl #  4. Checks for typedefs
 726 dnl #
 727 dnl #############################################################
 728
 729 dnl #
 730 dnl # Ensure that these are defined
 731 dnl #
 732 AC_TYPE_OFF_T
 733 AC_TYPE_PID_T
 734 AC_TYPE_SIZE_T
 735 AC_TYPE_UID_T
 736
 737 dnl check for socklen_t
 738 FR_CHECK_TYPE_INCLUDE([
 739 #ifdef HAVE_SYS_TYPES_H
 740 #include <sys/types.h>
 741 #endif
 742 #ifdef HAVE_SYS_SOCKET_H
 743 #include <sys/socket.h>
 744 #endif
 745 ],socklen_t, int, [socklen_t is generally 'int' on systems which don't use it])
 746
 747 dnl check for uint8_t
 748 FR_CHECK_TYPE_INCLUDE([
 749 #ifdef HAVE_INTTYPES_H
 750 #include <inttypes.h>
 751 #endif
 752 #ifdef HAVE_STDINT_H
 753 #include <stdint.h>
 754 #endif
 755 ],uint8_t, unsigned char, [uint8_t should be the canonical 'octet' for network traffic])
 756
 757 dnl check for uint16_t
 758 FR_CHECK_TYPE_INCLUDE([
 759 #ifdef HAVE_INTTYPES_H
 760 #include <inttypes.h>
 761 #endif
 762 #ifdef HAVE_STDINT_H
 763 #include <stdint.h>
 764 #endif
 765 ],uint16_t, unsigned short, [uint16_t should be the canonical '2 octets' for network traffic])
 766
 767 dnl check for uint32_t
 768 FR_CHECK_TYPE_INCLUDE([
 769 #ifdef HAVE_INTTYPES_H
 770 #include <inttypes.h>
 771 #endif
 772 #ifdef HAVE_STDINT_H
 773 #include <stdint.h>
 774 #endif
 775 ],uint32_t, unsigned int, [uint32_t should be the canonical 'network integer])
 776
 777 AC_CHECK_TYPE(struct in6_addr, AC_DEFINE(HAVE_STRUCT_IN6_ADDR, 1, [IPv6 address structure]), [], [
 778 #ifdef HAVE_NETINET_IN_H
 779 #include <netinet/in.h>
 780 #endif
 781 ])
 782
 783 AC_CHECK_TYPE(struct sockaddr_storage, AC_DEFINE(HAVE_STRUCT_SOCKADDR_STORAGE, 1, [Generic socket addresses]), [], [
 784 #ifdef HAVE_NETINET_IN_H
 785 #include <netinet/in.h>
 786 #endif
 787 #ifdef HAVE_SYS_SOCKET_H
 788 #include <sys/socket.h>
 789 #endif
 790 ])
 791
 792 AC_CHECK_TYPE(struct sockaddr_in6, AC_DEFINE(HAVE_STRUCT_SOCKADDR_IN6, 1, [IPv6 socket addresses]), [], [
 793 #ifdef HAVE_NETINET_IN_H
 794 #include <netinet/in.h>
 795 #endif
 796 ])
 797
 798 AC_CHECK_TYPE(struct addrinfo, AC_DEFINE(HAVE_STRUCT_ADDRINFO, 1, [Generic DNS lookups]), [], [
 799 #ifdef HAVE_SYS_TYPES_H
 800 #include <sys/types.h>
 801 #endif
 802 #ifdef HAVE_SYS_SOCKET_H
 803 #include <sys/socket.h>
 804 #endif
 805 #ifdef HAVE_NETDB_H
 806 #include <netdb.h>
 807 #endif
 808 ])
 809
 810 dnl #############################################################
 811 dnl #
 812 dnl #  5. Checks for structures and functions
 813 dnl #
 814 dnl #############################################################
 815 AC_CHECK_FUNCS( \
 816         getopt_long \
 817         lockf \
 818         strsignal \
 819         sigaction \
 820         sigprocmask \
 821         pthread_sigmask \
 822         snprintf \
 823         vsnprintf \
 824         setsid \
 825         strncasecmp \
 826         strcasecmp \
 827         localtime_r \
 828         ctime_r \
 829         gmtime_r \
 830         strsep \
 831         inet_aton \
 832         inet_pton \
 833         inet_ntop \
 834         setlinebuf \
 835         setvbuf \
 836         getusershell \
 837         initgroups \
 838         getaddrinfo \
 839         getnameinfo \
 840         closefrom \
 841         gettimeofday \
 842         strlcat \
 843         strlcpy
 844 )
 845 RADIUSD_NEED_DECLARATIONS( \
 846         crypt \
 847         strncasecmp \
 848         strcasecmp \
 849         inet_aton \
 850         setlinebuf \
 851         getusershell \
 852         endusershell
 853 )
 854
 855 AC_TYPE_SIGNAL
 856
 857 dnl # check if we have utmpx.h
 858 dnl # if so, check if struct utmpx has entry ut_xtime
 859 dnl # if not, set it to define ut_xtime == ut_tv.tv_sec
 860 if test "x$ac_cv_header_utmpx_h" = "xyes"
 861 then
 862  FR_CHECK_STRUCT_HAS_MEMBER([#include <utmpx.h>], [struct utmpx], ut_xtime)
 863  if test "x$ac_cv_type_struct_utmpx_has_ut_xtime" = "x"
 864  then
 865    AC_DEFINE(ut_xtime,ut_tv.tv_sec, [define to something if you don't have ut_xtime in struct utmpx])
 866  fi
 867 fi
 868
 869 dnl # struct ip_pktinfo
 870 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in_pktinfo], ipi_addr)
 871 if test "x$ac_cv_type_struct_in_pktinfo_has_ipi_addr" = "xyes"
 872 then
 873         AC_DEFINE(HAVE_IP_PKTINFO, [], [define if you have IP_PKTINFO (Linux)])
 874 fi
 875
 876 dnl # struct in6_pktinfo
 877 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in6_pktinfo], ipi6_addr)
 878 if test "x$ac_cv_type_struct_in6_pktinfo_has_ipi6_addr" = "xyes"
 879 then
 880         AC_DEFINE(HAVE_IN6_PKTINFO, [], [define if you have IN6_PKTINFO (Linux)])
 881 fi
 882
 883 dnl #############################################################
 884 dnl #
 885 dnl #  6. Checks for compiler characteristics
 886 dnl #
 887 dnl #############################################################
 888
 889 dnl #
 890 dnl # Ensure that these are defined
 891 dnl #
 892 AC_C_CONST
 893
 894 dnl #
 895 dnl # See if this is OS/2
 896 dnl #
 897 AC_MSG_CHECKING(type of OS)
 898 OS=`uname -s`
 899 AC_MSG_RESULT($OS)
 900 if test "$OS" = "OS/2"; then
 901         LIBPREFIX=
 902 else
 903         LIBPREFIX=lib
 904 fi
 905 AC_SUBST(LIBPREFIX)
 906
 907 dnl #
 908 dnl # Set Default CFLAGS
 909 dnl #
 910 if test "x$GCC" = "xyes"; then
 911     CFLAGS="$CFLAGS -Wall -D_GNU_SOURCE"
 912 fi
 913
 914 AC_MSG_CHECKING(for developer gcc flags)
 915 if test "x$developer" = "xyes" -a "x$GCC" = "xyes"; then
 916   devflags="-g -Wshadow -Wpointer-arith -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -W -Wredundant-decls -Wundef"
 917   CFLAGS="$CFLAGS $devflags"
 918   INSTALLSTRIP=""
 919   AC_MSG_RESULT(yes.  Using $devflags)
 920 else
 921   devflags=""
 922   CFLAGS="$CFLAGS -DNDEBUG"
 923   INSTALLSTRIP=""
 924   AC_MSG_RESULT(no.)
 925 fi
 926
 927 dnl #############################################################
 928 dnl #
 929 dnl #  7. Checks for library functions
 930 dnl #
 931 dnl #############################################################
 932
 933 dnl Check for libcrypt
 934 dnl We use crypt(3) which may be in libc, or in libcrypt (eg FreeBSD)
 935 AC_CHECK_LIB(crypt, crypt,
 936   CRYPTLIB="-lcrypt"
 937 )
 938 if test "$CRYPTLIB" != ""; then
 939   AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function])
 940 else
 941   AC_CHECK_FUNC(crypt, AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function]))
 942 fi
 943
 944 dnl Check for libcipher
 945 AC_CHECK_LIB(cipher, setkey,
 946    CRYPTLIB="${CRYPTLIB} -lcipher"
 947 )
 948 AC_SUBST(CRYPTLIB)
 949
 950 if test "x$WITH_SNMP" = "xyes"; then
 951   SNMP_CHECKS
 952 fi
 953
 954 dnl Check the style of gethostbyaddr, in order of preference
 955 dnl GNU (_r eight args)
 956 AC_DEFINE(GNUSTYLE, [1], [GNU-Style get*byaddr_r])
 957 dnl SYSV (_r six args)
 958 AC_DEFINE(SYSVSTYLE, [2], [SYSV-Style get*byaddr_r])
 959 dnl BSD (three args, may not be thread safe)
 960 AC_DEFINE(BSDSTYLE, [3], [BSD-Style get*byaddr_r])
 961 dnl Tru64 has BSD version, but it is thread safe
 962 dnl     http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1739____.HTM
 963 dnl We need #stdio.h to define NULL on FreeBSD (at least)
 964 gethostbyaddrrstyle=""
 965 AC_MSG_CHECKING([gethostbyaddr_r() syntax])
 966 case "$host" in
 967 *-freebsd*)
 968 dnl With FreeBSD, check if there's a prototype for gethostbyaddr_r.
 969 dnl Some versions (FreeBSD 5.1?) have a symbol but no prototype - so we
 970 dnl override this test to BSDSTYLE. FreeBSD 6.2 and up have proper GNU
 971 dnl style support.
 972         AC_CHECK_DECLS([gethostbyaddr_r], [], [
 973                 AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE,
 974                         [style of gethostbyaddr_r functions ])
 975                 gethostbyaddrrstyle=BSD
 976                 AC_MSG_WARN([FreeBSD overridden to BSD-style])
 977         ], [
 978 #ifdef HAVE_NETDB_H
 979 #include <netdb.h>
 980 #endif
 981 ])
 982         ;;
 983 esac
 984 if test "x$gethostbyaddrrstyle" = "x"; then
 985         AC_TRY_LINK([
 986 #include <stdio.h>
 987 #include <netdb.h>
 988 ], [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL, NULL) ], [
 989         AC_DEFINE(GETHOSTBYADDRRSTYLE, GNUSTYLE, [style of gethostbyaddr_r functions ])
 990         gethostbyaddrrstyle=GNU
 991 ])
 992 fi
 993 if test "x$gethostbyaddrrstyle" = "x"; then
 994         AC_TRY_LINK([
 995 #include <stdio.h>
 996 #include <netdb.h>
 997 ], [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL) ] , [
 998                 AC_DEFINE(GETHOSTBYADDRRSTYLE, SYSVSTYLE, [style of gethostbyaddr_r functions ])
 999                 gethostbyaddrrstyle=SYSV
1000         ])
1001 fi
1002 if test "x$gethostbyaddrrstyle" = "x"; then
1003         AC_TRY_LINK([
1004 #include <stdio.h>
1005 #include <netdb.h>
1006 ], [ gethostbyaddr(NULL, 0, 0)  ], [
1007                 AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE, [style of gethostbyaddr_r functions ])
1008                 gethostbyaddrrstyle=BSD
1009         ])
1010 fi
1011
1012 if test "x$gethostbyaddrrstyle" = "x"; then
1013         AC_MSG_RESULT([none!  It must not exist, here.])
1014 else
1015         AC_MSG_RESULT([${gethostbyaddrrstyle}-style])
1016 fi
1017
1018 if test "x$gethostbyaddrrstyle" = "xBSD"; then
1019         AC_MSG_WARN([ ****** BSD-style gethostbyaddr might NOT be thread-safe! ****** ])
1020 fi
1021
1022 dnl Check the style of gethostbyname, in order of preference
1023 dnl GNU (_r seven args)
1024 dnl SYSV (_r five args)
1025 dnl BSD (two args, may not be thread safe)
1026 dnl Tru64 has BSD version, but it _is_ thread safe
1027 dnl     http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1946____.HTM
1028 dnl We need #stdio.h to define NULL on FreeBSD (at least)
1029 gethostbynamerstyle=""
1030 AC_MSG_CHECKING([gethostbyname_r() syntax])
1031 AC_TRY_LINK([
1032 #include <stdio.h>
1033 #include <netdb.h>
1034 ], [ gethostbyname_r(NULL, NULL, NULL, 0, NULL, NULL) ], [
1035         AC_DEFINE(GETHOSTBYNAMERSTYLE, GNUSTYLE, [style of gethostbyname_r functions ])
1036         gethostbynamerstyle=GNU
1037 ])
1038 if test "x$gethostbynamerstyle" = "x"; then
1039         AC_TRY_LINK([
1040 #include <stdio.h>
1041 #include <netdb.h>
1042 ], [ gethostbyname_r(NULL, NULL, NULL, 0, NULL) ] , [
1043                 AC_DEFINE(GETHOSTBYNAMERSTYLE, SYSVSTYLE, [style of gethostbyname_r functions ])
1044                 gethostbynamerstyle=SYSV
1045         ])
1046 fi
1047 if test "x$gethostbynamerstyle" = "x"; then
1048         AC_TRY_LINK([
1049 #include <stdio.h>
1050 #include <netdb.h>
1051 ], [ gethostbyname(NULL)  ], [
1052                 AC_DEFINE(GETHOSTBYNAMERSTYLE, BSDSTYLE, [style of gethostbyname_r functions ])
1053                 gethostbynamerstyle=BSD
1054         ])
1055 fi
1056
1057 if test "x$gethostbynamerstyle" = "x"; then
1058         AC_MSG_RESULT([none!  It must not exist, here.])
1059 else
1060         AC_MSG_RESULT([${gethostbynamerstyle}-style])
1061 fi
1062
1063 if test "x$gethostbynamerstyle" = "xBSD"; then
1064         AC_MSG_WARN([ ****** BSD-style gethostbyname might NOT be thread-safe! ****** ])
1065 fi
1066
1067 dnl check for non-posix solaris ctime_r (extra buflen int arg)
1068 AC_DEFINE(POSIXSTYLE, [1], [Posix-Style ctime_r])
1069 AC_DEFINE(SOLARISSTYLE, [2], [Solaris-Style ctime_r])
1070 ctimerstyle=""
1071 AC_MSG_CHECKING([ctime_r() syntax])
1072 AC_TRY_LINK([
1073 #include <time.h>
1074 ], [ ctime_r(NULL, NULL, 0) ], [
1075         AC_DEFINE(CTIMERSTYLE, SOLARISSTYLE, [style of ctime_r function])
1076         ctimerstyle="SOLARIS"
1077 ])
1078 if test "x$ctimerstyle" = "x"; then
1079         AC_TRY_LINK([
1080 #include <time.h>
1081 ], [ ctime_r(NULL, NULL) ], [
1082                 AC_DEFINE(CTIMERSTYLE, POSIXSTYLE, [style of ctime_r function])
1083                 ctimerstyle="POSIX"
1084         ])
1085 fi
1086
1087 if test "x$ctimerstyle" = "x"; then
1088         AC_MSG_RESULT([none!  It must not exist, here.])
1089 else
1090         AC_MSG_RESULT([${ctimerstyle}-style])
1091 fi
1092
1093 AC_SUBST(HOSTINFO, $host)
1094
1095 dnl #############################################################
1096 dnl #
1097 dnl #  8. Checks for system services
1098 dnl #
1099 dnl #############################################################
1100
1101 dnl #
1102 dnl # Figure out where libtool is located,
1103 dnl #
1104 top_builddir=`pwd`
1105 export top_builddir
1106 AC_MSG_RESULT([top_builddir=$top_builddir])
1107 dnl # AC_SUBST(top_builddir)
1108 AC_SUBST(LIBLTDL)
1109 AC_SUBST(INCLTDL)
1110
1111 dnl import libtool stuff
1112
1113 dnl #############################################################
1114 dnl #
1115 dnl #  Configure in any module directories.
1116 dnl #
1117 dnl #############################################################
1118
1119 mysubdirs="$LIBLTDLPATH"
1120 if test "x$EXPERIMENTAL" = "xyes"; then
1121   bar=`ls -1 "${srcdir}"/src/modules/rlm_*/configure | sed 's%/configure%%'`
1122   dnl # get rid of LF's.
1123   mysubdirs=`echo $mysubdirs $bar`
1124 else
1125   dnl #
1126   dnl # Find 'configure' in ONLY the stable modules
1127   dnl #
1128   for bar in `cat "${srcdir}"/src/modules/stable`; do
1129     if test -f "${srcdir}"/src/modules/$bar/configure; then
1130       mysubdirs="$mysubdirs src/modules/$bar"
1131     fi
1132   done
1133 fi
1134
1135 dnl ############################################################
1136 dnl # make modules by list
1137 dnl #############################################################
1138 if test "x$EXPERIMENTAL" = "xyes"; then
1139   for foo in `ls -1 "${srcdir}"/src/modules | grep rlm_`; do
1140     MODULES="$MODULES $foo"
1141   done
1142 else
1143    dnl #
1144    dnl # make ONLY the stable modules
1145    dnl #
1146    for foo in `cat "${srcdir}"/src/modules/stable`; do
1147     MODULES="$MODULES $foo"
1148    done
1149 fi
1150
1151 dnl #
1152 dnl #  Don't change the variable name here.  Autoconf goes bonkers
1153 dnl #  if you do.
1154 dnl #
1155 AC_CONFIG_SUBDIRS($LTDL_SUBDIRS $mysubdirs)
1156 AC_SUBST(MODULES)
1157
1158 dnl #############################################################
1159 dnl #
1160 dnl #  And finally, output the results.
1161 dnl #
1162 dnl #############################################################
1163
1164 AC_CONFIG_COMMANDS([stamp-h], [echo timestamp > src/include/stamp-h])
1165 AC_CONFIG_COMMANDS([build-radpaths-h], [(cd ./src/include && /bin/sh ./build-radpaths-h)])
1166 AC_CONFIG_COMMANDS([main-chmod], [(cd ./src/main   && chmod +x checkrad.pl radlast radtest)])
1167 AC_CONFIG_COMMANDS([scripts-chmod], [(cd ./scripts    && chmod +x rc.radiusd radwatch check-radiusd-config radiusd.cron.daily radiusd.cron.monthly cryptpasswd)])
1168
1169 dnl #
1170 dnl #  Substitute whatever libraries we found to be necessary
1171 dnl #
1172 AC_SUBST(LIBS)
1173 AC_SUBST(INSTALLSTRIP)
1174
1175 USE_SHARED_LIBS=$enable_shared
1176 AC_SUBST(USE_SHARED_LIBS)
1177 USE_STATIC_LIBS=$enable_static
1178 AC_SUBST(USE_STATIC_LIBS)
1179 AC_SUBST(STATIC_MODULES)
1180 AC_SUBST(RADIUSD_MAJOR_VERSION)
1181 AC_SUBST(RADIUSD_MINOR_VERSION)
1182 AC_SUBST(RADIUSD_VERSION)
1183
1184 AC_OUTPUT(\
1185         ./Make.inc \
1186         ./src/include/build-radpaths-h \
1187         ./src/main/Makefile \
1188         ./src/main/checkrad.pl \
1189         ./src/main/radlast \
1190         ./src/main/radtest \
1191         ./scripts/rc.radiusd \
1192         ./scripts/radwatch \
1193         ./scripts/radiusd.cron.daily \
1194         ./scripts/radiusd.cron.monthly \
1195         ./scripts/cryptpasswd \
1196         ./raddb/dictionary \
1197         ./raddb/radiusd.conf
1198 )