configure.in

   1 dnl #############################################################
   2 dnl #
   3 dnl #  For information about autoconf, see:
   4 dnl #
   5 dnl #  http://www.gnu.org/software/autoconf/
   6 dnl #
   7 dnl #  The recommended order is:
   8 dnl #
   9 dnl #  AC_INIT(file)
  10 dnl #  0. checks for compiler, libtool, and command line options
  11 dnl #  1. checks for programs
  12 dnl #  2. checks for libraries
  13 dnl #  3. checks for header files
  14 dnl #  4. checks for typedefs
  15 dnl #  5. checks for structures and functions
  16 dnl #  6. checks for compiler characteristics
  17 dnl #  7. checks for library functions
  18 dnl #  8. checks for system services
  19 dnl #  AC_OUTPUT([file...])
  20 dnl #
  21 dnl #############################################################
  22
  23 AC_PREREQ([2.59])
  24 export CFLAGS LIBS LDFLAGS CPPFLAGS
  25 AC_INIT(src/main/radiusd.c)
  26 AC_CONFIG_HEADER(src/include/autoconf.h)
  27 AC_REVISION($Revision$)dnl
  28
  29 dnl # The version of the software
  30 RADIUSD_MAJOR_VERSION=2
  31 RADIUSD_MINOR_VERSION=0.0-beta
  32 RADIUSD_VERSION="${RADIUSD_MAJOR_VERSION}.${RADIUSD_MINOR_VERSION}"
  33 PACKAGE=freeradius
  34
  35 dnl #############################################################
  36 dnl #
  37 dnl #  0. Checks for compiler, libtool, and command line options.
  38 dnl #
  39 dnl #############################################################
  40
  41 dnl Check for GNU cc
  42 AC_PROG_CC
  43 AC_PROG_CXX
  44
  45 dnl #
  46 dnl # check for AIX, to allow us to use some BSD functions
  47 dnl # must be before macros that call the compiler.
  48 dnl #
  49 AC_AIX
  50
  51 AC_PROG_GCC_TRADITIONAL
  52 AC_PROG_CC_SUNPRO
  53 AC_PROG_RANLIB
  54
  55 dnl Compile in large (2G+) file support.
  56 AC_SYS_LARGEFILE
  57
  58 dnl # check for system bytesex
  59 dnl # AC_DEFINES WORDS_BIGENDIAN
  60 AC_C_BIGENDIAN
  61
  62 dnl Find GNU Make.
  63 AC_CHECK_PROG(GMAKE, gmake, yes, no)
  64 if test $GMAKE = no; then
  65   AC_PATH_PROG(MAKE, make, /usr/local/bin/make)
  66 else
  67   AC_PATH_PROG(MAKE, gmake, /usr/local/gnu/bin/make)
  68 fi
  69 makever=`$ac_cv_path_MAKE --version 2>&1 | grep "GNU Make"`
  70 if test -z "$makever"; then
  71   AC_MSG_ERROR(GNU Make is not installed.  Please download and install it
  72                 from ftp://prep.ai.mit.edu/pub/gnu/make/ before continuing.)
  73 fi
  74
  75 dnl libltdl is installable
  76 AC_LIBLTDL_INSTALLABLE
  77
  78 dnl tell Makefile to build ltdl if needed
  79 if test x"$enable_ltdl_install" = x"yes"; then
  80   LTDL_SUBDIRS=libltdl
  81 fi
  82 AC_SUBST(LTDL_SUBDIRS)
  83
  84 dnl use system-wide libtool, if it exists
  85 AC_ARG_WITH(system-libtool,
  86 [  --with-system-libtool              try to use libtool installed in your system [default=use our own]],
  87 [ AC_PATH_PROG(LIBTOOL, libtool,,$PATH:/usr/local/bin) ],
  88 [
  89   LIBTOOL="`pwd`/libtool"
  90   AC_SUBST(LIBTOOL)
  91   dnl ensure that we're looking for dlopen
  92   AC_LIBTOOL_DLOPEN
  93
  94   dnl Figure out how to build shared libraries
  95   AC_PROG_LIBTOOL
  96 ])
  97
  98
  99 dnl Put this in later, when all distributed modules use autoconf.
 100 dnl AC_ARG_WITH(disablemodulefoo,
 101 dnl [  --without-rlm_foo       Disables module compilation.  Module list:]
 102 dnl esyscmd([find src/modules -type d -name rlm_\* -print |\
 103 dnl     sed -e 's%src/modules/.*/% (sub)- %; s%.*/%- %' |\
 104 dnl     awk '{print "                            "$0}']))
 105
 106 AC_ARG_ENABLE(strict-dependencies,
 107 [  --enable-strict-dependencies  Fail configure on lack of module dependancy.])
 108
 109 dnl extra argument: --with-docdir
 110 docdir='${datadir}/doc/freeradius'
 111 AC_MSG_CHECKING(docdir)
 112 AC_ARG_WITH(docdir,
 113 [  --with-docdir=DIR       Directory for documentation [DATADIR/doc/freeradius] ],
 114 [ case "$withval" in
 115     no)
 116         docdir=no
 117         ;;
 118     yes)
 119         ;;
 120     [[\\/$]]* | ?:[[\\/]]* )
 121         docdir="$withval"
 122         ;;
 123     *)
 124         AC_MSG_ERROR([expected an absolute directory name for --with-docdir: $withval])
 125         ;;
 126   esac ]
 127 )
 128 AC_SUBST(docdir)
 129 AC_MSG_RESULT($docdir)
 130 if test "x$docdir" = xno; then
 131         AC_MSG_WARN(Documentation files will NOT be installed.)
 132 fi
 133
 134 dnl extra argument: --with-logdir
 135 logdir='${localstatedir}/log/radius'
 136 AC_MSG_CHECKING(logdir)
 137 AC_ARG_WITH(logdir,
 138 [  --with-logdir=DIR       Directory for logfiles [LOCALSTATEDIR/log/radius] ],
 139 [ case "$withval" in
 140     no)
 141         AC_MSG_ERROR(Need logdir)
 142         ;;
 143     yes)
 144         ;;
 145     [[\\/$]]* | ?:[[\\/]]* )
 146         logdir="$withval"
 147         ;;
 148     *)
 149         AC_MSG_ERROR([expected an absolute directory name for --with-logdir: $withval])
 150         ;;
 151   esac ]
 152 )
 153 AC_SUBST(logdir)
 154 AC_MSG_RESULT($logdir)
 155
 156 dnl extra argument: --with-radacctdir
 157 radacctdir='${logdir}/radacct'
 158 AC_MSG_CHECKING(radacctdir)
 159 AC_ARG_WITH(radacctdir,
 160 [  --with-radacctdir=DIR   Directory for detail files [LOGDIR/radacct] ],
 161 [ case "$withval" in
 162     no)
 163         AC_MSG_ERROR(Need radacctdir)
 164         ;;
 165     yes)
 166         ;;
 167     [[\\/$]]* | ?:[[\\/]]* )
 168         radacctdir="$withval"
 169         ;;
 170     *)
 171         AC_MSG_ERROR([expected an absolute directory name for --with-radacctdir: $withval])
 172         ;;
 173   esac ]
 174 )
 175 AC_SUBST(radacctdir)
 176 AC_MSG_RESULT($radacctdir)
 177
 178 dnl extra argument: --with-raddbdir
 179 raddbdir='${sysconfdir}/raddb'
 180 AC_MSG_CHECKING(raddbdir)
 181 AC_ARG_WITH(raddbdir,
 182 [  --with-raddbdir=DIR     Directory for config files [SYSCONFDIR/raddb] ],
 183 [ case "$withval" in
 184     no)
 185         AC_MSG_ERROR(Need raddbdir)
 186         ;;
 187     yes)
 188         ;;
 189     [[\\/$]]* | ?:[[\\/]]* )
 190         raddbdir="$withval"
 191         ;;
 192     *)
 193         AC_MSG_ERROR([expected an absolute directory name for --with-raddbdir: $withval])
 194         ;;
 195   esac ]
 196 )
 197 AC_SUBST(raddbdir)
 198 AC_MSG_RESULT($raddbdir)
 199
 200 dnl extra argument: --with-ascend-binary
 201 ASCEND_BINARY=yes
 202 AC_ARG_WITH(ascend-binary,
 203 [  --with-ascend-binary    Include support for Ascend binary filter attributes (default=yes)],
 204 [ case "$withval" in
 205     yes)
 206         ;;
 207     *)
 208         ASCEND_BINARY=""
 209   esac ]
 210 )
 211 if test "X$ASCEND_BINARY" = "Xyes"; then
 212   AC_DEFINE(ASCEND_BINARY, [], [Include support for Ascend binary filter attributes])
 213 fi
 214
 215 dnl extra argument: --with-threads
 216 WITH_THREADS=yes
 217 AC_ARG_WITH(threads,
 218 [  --with-threads          Use threads, if available.  (default=yes) ],
 219 [ case "$withval" in
 220     yes)
 221         ;;
 222     *)
 223         WITH_THREADS=""
 224   esac ]
 225 )
 226
 227 dnl extra argument: --with-snmp
 228 WITH_SNMP=yes
 229 AC_ARG_WITH(snmp,
 230 [  --with-snmp             Compile in SNMP support. (default=yes)],
 231 [ case "$withval" in
 232     yes)
 233         ;;
 234     *)
 235         WITH_SNMP=no
 236   esac ]
 237 )
 238
 239 dnl #
 240 dnl # extra argument: --with-snmp-include-dir
 241 dnl #
 242 AC_ARG_WITH(snmp-include-dir,
 243 [  --with-snmp-include-dir=DIR  Directory to look for include files used by SNMP],
 244 [ case "$withval" in
 245     *)
 246         ;;
 247   esac ]
 248 )
 249
 250 dnl extra argument: --with-vmps
 251 WITH_VMPS=yes
 252 AC_ARG_WITH(vmps,
 253 [  --with-vmps             Compile in VMPS support. (default=yes)],
 254 [ case "$withval" in
 255     yes)
 256         ;;
 257     *)
 258         WITH_VMPS=no
 259   esac ]
 260 )
 261 if test "x$WITH_VMPS" = "xyes"; then
 262         AC_DEFINE(WITH_VMPS, [], [define if you want VMPS support])
 263 fi
 264
 265
 266 dnl #
 267 dnl #  Allow the user to specify a list of modules to be linked
 268 dnl #  statically to the server.
 269 dnl #
 270 STATIC_MODULES=
 271 AC_ARG_WITH(static_modules,
 272 [  --with-static-modules=QUOTED-MODULE-LIST],[
 273   for i in $withval; do
 274     STATIC_MODULES="$STATIC_MODULES -dlpreopen ../modules/rlm_$i/rlm_$i.la"
 275   done
 276 ])
 277
 278 MODULES=
 279 AC_ARG_WITH(modules,
 280 [ --with-modules=QUOTED-MODULE-LIST],[
 281  for i in $withval; do
 282    MODULES="$MODULES $i"
 283  done
 284 ])
 285
 286 dnl #
 287 dnl #  Enable developer C compiler warnings
 288 dnl #
 289 AC_ARG_ENABLE(developer,
 290 [  --enable-developer               Enables features of interest to developers.],
 291 [ case "$enableval" in
 292     no)
 293         developer=no
 294         ;;
 295     *)
 296         developer=yes
 297   esac ]
 298 )
 299
 300 if test "x$developer" != "xno" -a -d $srcdir/CVS; then
 301   dnl turn on the developer flag when taken from a CVS checkout (not a release)
 302   developer="yes"
 303 fi
 304
 305 dnl extra argument: --with-experimental-modules
 306 EXPERIMENTAL=
 307 AC_ARG_WITH(experimental-modules,
 308 [  --with-experimental-modules      Use experimental and unstable modules. (default=no) ],
 309 [ case "$withval" in
 310     yes)
 311         EXPERIMENTAL=yes
 312         ;;
 313     *)
 314   esac ]
 315 )
 316
 317 dnl extra argument: --with-openssl
 318 WITH_OPENSSL=yes
 319 AC_ARG_WITH(openssl,
 320 [  --with-openssl                   Use OpenSSL. (default=yes)],
 321 [ case "$withval" in
 322     no)
 323         WITH_OPENSSL=no
 324         ;;
 325     *)
 326         WITH_OPENSSL=yes
 327         ;;
 328   esac ]
 329 )
 330
 331 dnl #
 332 dnl # extra argument: --with-openssl-includes=dir
 333 dnl #
 334 OPENSSL_INCLUDE_DIR=
 335 AC_ARG_WITH(openssl-includes,
 336 [  --with-openssl-includes=DIR      Directory to look for OpenSSL include files],
 337 [ case "$withval" in
 338     *) OPENSSL_INCLUDE_DIR="$withval"
 339         ;;
 340   esac ]
 341 )
 342
 343 dnl #
 344 dnl # extra argument: --with-openssl-libraries=dir
 345 dnl #
 346 OPENSSL_LIB_DIR=
 347 AC_ARG_WITH(openssl-libraries,
 348 [  --with-openssl-libraries=DIR     Directory to look for OpenSSL library files],
 349 [ case "$withval" in
 350     *) OPENSSL_LIB_DIR="$withval"
 351         ;;
 352   esac ]
 353 )
 354
 355 dnl #
 356 dnl #  These next two arguments don't actually do anything.  They're
 357 dnl #  place holders so that the top-level configure script can tell
 358 dnl #  the user how to configure lower-level modules
 359 dnl #
 360
 361 dnl #
 362 dnl # extra argument: --with-rlm-FOO-lib-dir
 363 dnl #
 364 AC_ARG_WITH(rlm-FOO-lib-dir,
 365 [  --with-rlm-FOO-lib-dir=DIR       Directory to look for library files used by module FOO],
 366 [ case "$withval" in
 367     *)
 368         ;;
 369   esac ]
 370 )
 371
 372 dnl #
 373 dnl # extra argument: --with-rlm-FOO-include-dir
 374 dnl #
 375 AC_ARG_WITH(rlm-FOO-include-dir,
 376 [  --with-rlm-FOO-include-dir=DIR   Directory to look for include files used by module FOO],
 377 [ case "$withval" in
 378     *)
 379         ;;
 380   esac ]
 381 )
 382
 383 dnl See what include-style is used by the make program.
 384 dnl AC_MSG_CHECKING(include style for make)
 385 dnl echo "include /dev/null" > testmake.$$
 386 dnl echo "all:" >> testmake.$$
 387 dnl make -f testmake.$$ >/dev/null 2>&1
 388 dnl if test $? = 0
 389 dnl then
 390 dnl     INCLUDE=include
 391 dnl     IQUOTE=
 392 dnl else
 393 dnl     INCLUDE=.include
 394 dnl     IQUOTE='"'
 395 dnl fi
 396 dnl rm -f testmake.$$
 397 dnl AC_MSG_RESULT(" $INCLUDE")
 398 dnl AC_SUBST(INCLUDE)
 399 dnl AC_SUBST(IQUOTE)
 400
 401 dnl extra argument: --with-udpfromto
 402 WITH_UDPFROMTO=no
 403 AC_ARG_WITH(udpfromto,
 404 [  --with-udpfromto        Compile in UDPFROMTO support. (default=yes)],
 405 [ case "$withval" in
 406     yes)
 407         WITH_UDPFROMTO=yes
 408         ;;
 409     *)
 410         WITH_UDPFROMTO=no
 411   esac ]
 412 )
 413
 414 if test "x$WITH_UDPFROMTO" = "xyes"; then
 415         AC_DEFINE(WITH_UDPFROMTO, [], [define if you want udpfromto])
 416 fi
 417
 418 dnl #############################################################
 419 dnl #
 420 dnl #  1. Checks for programs
 421 dnl #
 422 dnl #############################################################
 423
 424 CHECKRAD=checkrad.pl
 425 AC_PATH_PROG(PERL, perl, /usr/local/bin/perl)
 426 if test "x$ac_cv_path_PERL" = "x"; then
 427   AC_MSG_WARN(perl not found - Simultaneous-Use and checkrad.pl may not work)
 428 fi
 429 AC_PATH_PROG(SNMPGET, snmpget)
 430 if test "x$ac_cv_path_SNMPGET" = "x"; then
 431   AC_MSG_WARN(snmpget not found - Simultaneous-Use and checkrad.pl may not work)
 432 fi
 433
 434 AC_PATH_PROG(SNMPWALK, snmpwalk)
 435 if test "x$ac_cv_path_SNMPWALK" = "x"; then
 436   AC_MSG_WARN(snmpwalk not found - Simultaneous-Use and checkrad.pl may not work)
 437 fi
 438
 439 AC_PATH_PROG(RUSERS, rusers, /usr/bin/rusers)
 440
 441 dnl FIXME This is truly gross.
 442 missing_dir=`cd $ac_aux_dir && pwd`
 443 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
 444 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
 445 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
 446
 447 AC_PATH_PROG(LOCATE,locate)
 448 AC_PATH_PROG(DIRNAME,dirname)
 449 AC_PATH_PROG(GREP,grep)
 450
 451 dnl #############################################################
 452 dnl #
 453 dnl #  2. Checks for libraries
 454 dnl #
 455 dnl #############################################################
 456
 457 dnl If using pthreads, check for -lpthread (posix) or -lc_r (*BSD)
 458 old_CFLAGS=$CFLAGS
 459 if test "x$WITH_THREADS" = "xyes"; then
 460   if test $ac_cv_prog_suncc = "yes"; then
 461     CFLAGS="$CFLAGS -mt"
 462   fi
 463
 464   AC_CHECK_HEADERS(pthread.h, [], [ WITH_THREADS="no" ])
 465
 466 dnl #
 467 dnl # pthread stuff is usually in -lpthread
 468 dnl # or in -lc_r, on *BSD
 469 dnl #
 470 dnl # On Some systems, we need extra pre-processor flags, to get them to
 471 dnl # to do the threading properly.
 472 dnl #
 473   AC_CHECK_LIB(pthread, pthread_create,
 474                 [ CFLAGS="$CFLAGS -D_REENTRANT -D_POSIX_PTHREAD_SEMANTICS"
 475                   LIBS="$LIBS -lpthread" ],
 476                 AC_CHECK_LIB(c_r, pthread_create,
 477                             [ CFLAGS="$CFLAGS -pthread -D_THREAD_SAFE" ],
 478                             [ WITH_THREADS="no" ]
 479                             )
 480                 )
 481 fi
 482
 483 dnl #
 484 dnl # If we have NO pthread libraries, remove any knowledge of threads.
 485 dnl #
 486 if test "x$WITH_THREADS" != "xyes"; then
 487   CFLAGS=$old_CFLAGS
 488   ac_cv_header_pthread_h="no"
 489   WITH_THREADS=no
 490 else
 491   dnl #
 492   dnl #  We need sem_init() and friends, as they're the friendliest
 493   dnl #  semaphore functions for threading.
 494   dnl #
 495   dnl # HP/UX requires linking with librt, too, to get the sem_* symbols.
 496   dnl # Some systems have them in -lsem
 497   dnl # Solaris has them in -lposix4
 498   dnl # NetBSD has them in -lsemaphore
 499
 500   AC_SEARCH_LIBS(sem_init, pthread sem posix4 rt semaphore,
 501         [],
 502         [AC_MSG_ERROR(-lsem not found.  You may want to download it from ftp://ftp.to.gd-es.com/pub/BSDI/libsem.tar.bz2 or ftp://ftp.freeradius.org/pub/radius/contrib/libsem.tar.gz)]
 503    )
 504 fi
 505
 506 dnl Check if we need -lsocket
 507 AC_CHECK_LIB(socket, getsockname)
 508
 509 dnl Check for -lresolv
 510 dnl This library may be needed later.
 511 AC_CHECK_LIB(resolv, inet_aton)
 512
 513 dnl Check if we need -lnsl. Usually if we want to
 514 dnl link against -lsocket we need to include -lnsl as well.
 515 AC_CHECK_LIB(nsl, inet_ntoa)
 516
 517 dnl Check for OpenSSL libraries.
 518 OPENSSL_LIBS=
 519 if test "x$WITH_OPENSSL" = xyes; then
 520   old_LIBS=$LIBS
 521   if test "x$OPENSSL_LIB_DIR" != "x"; then
 522     LIBS="-L$OPENSSL_LIB_DIR $LIBS"
 523   fi
 524   AC_CHECK_LIB(crypto, DH_new,
 525     [
 526         AC_DEFINE(HAVE_LIBCRYPTO, 1,
 527             [Define to 1 if you have the `crypto' library (-lcrypto).])
 528         AC_CHECK_LIB(ssl, SSL_new,
 529             [
 530                 AC_DEFINE(HAVE_LIBSSL, 1,
 531                     [Define to 1 if you have the `ssl' library (-lssl).])
 532                 if test "x$OPENSSL_LIB_DIR" != "x"; then
 533                     OPENSSL_LIBS="-L$OPENSSL_LIB_DIR"
 534                 fi
 535                 OPENSSL_LIBS="$OPENSSL_LIBS -lcrypto -lssl -lcrypto"
 536             ], [])
 537     ], [])
 538   LIBS=$old_LIBS
 539 fi
 540
 541 AC_CHECK_LIB(ws2_32, htonl)
 542
 543 dnl Check the pcap library for the RADIUS sniffer.
 544 PCAP_LIBS=
 545 AC_CHECK_LIB(pcap, pcap_open_live,
 546         [ PCAP_LIBS="-lpcap"
 547         AC_DEFINE(HAVE_LIBPCAP, 1,
 548                 [Define to 1 if you have the `pcap' library (-lpcap).])
 549         ],
 550         [ AC_MSG_WARN([pcap library not found, silently disabling the RADIUS sniffer.]) ])
 551
 552 dnl #############################################################
 553 dnl #
 554 dnl #  3. Checks for header files
 555 dnl #
 556 dnl #############################################################
 557
 558 dnl #
 559 dnl # Interix requires us to set -D_ALL_SOURCE, otherwise
 560 dnl # getopt will be #included, but won't link.  <sigh>
 561 dnl #
 562 dnl #
 563 case "$host" in
 564 *-interix*)
 565         CFLAGS="$CFLAGS -D_ALL_SOURCE"
 566         ;;
 567 *-darwin*)
 568         CFLAGS="$CFLAGS -DDARWIN"
 569         LIBS="-framework DirectoryService $LIBS"
 570         ;;
 571 esac
 572
 573 AC_HEADER_DIRENT
 574 AC_HEADER_STDC
 575 AC_HEADER_TIME
 576 AC_HEADER_SYS_WAIT
 577
 578 AC_CHECK_HEADERS( \
 579         unistd.h \
 580         crypt.h \
 581         errno.h \
 582         resource.h \
 583         sys/resource.h \
 584         getopt.h \
 585         malloc.h \
 586         utmp.h \
 587         utmpx.h \
 588         signal.h \
 589         sys/select.h \
 590         syslog.h \
 591         inttypes.h \
 592         stdint.h \
 593         stdio.h \
 594         netdb.h \
 595         semaphore.h \
 596         arpa/inet.h \
 597         netinet/in.h \
 598         sys/types.h \
 599         sys/socket.h \
 600         winsock.h \
 601         sys/time.h \
 602         sys/wait.h \
 603         sys/security.h \
 604         fcntl.h \
 605         sys/fcntl.h \
 606         sys/prctl.h \
 607         prot.h \
 608         pwd.h \
 609         grp.h \
 610         sia.h \
 611         siad.h
 612 )
 613
 614 dnl FreeBSD requires sys/socket.h before net/if.h
 615 AC_CHECK_HEADERS(net/if.h, [], [],
 616 [#ifdef HAVE_SYS_SOCKET_H
 617 # include <sys/socket.h>
 618 # endif
 619 ])
 620
 621 REGEX=no
 622 AC_CHECK_HEADER(regex.h, AC_DEFINE(HAVE_REGEX_H, [], [define this if we have the <regex.h> header file]))
 623 if test "x$ac_cv_header_regex_h" = "xyes"; then
 624   REGEX_EXTENDED=no
 625   REGEX=yes
 626   AC_EGREP_CPP(yes,
 627     [#include <regex.h>
 628      #ifdef REG_EXTENDED
 629        yes
 630      #endif
 631      ], [AC_DEFINE(HAVE_REG_EXTENDED, [], [define this if we have REG_EXTENDED (from <regex.h>)]) REGEX_EXTENDED=yes])
 632 fi
 633 AC_SUBST(REGEX)
 634 AC_SUBST(REGEX_EXTENDED)
 635
 636 dnl #
 637 dnl #  other checks which require headers
 638 dnl #
 639 if test "x$ac_cv_header_sys_security_h" = "xyes" && test "x$ac_cv_header_prot_h" = "xyes"
 640 then
 641   AC_DEFINE(OSFC2, [], [define if you have OSFC2 authentication])
 642 fi
 643
 644 if test "x$ac_cv_header_sia_h" = "xyes" && test "x$ac_cv_header_siad_h" = "xyes"
 645 then
 646   AC_DEFINE(OSFSIA, [], [define if you have OSFSIA authentication])
 647 fi
 648
 649 dnl Check for OpenSSL includes.
 650 OPENSSL_INCLUDE="-DNO_OPENSSL"
 651 if test "x$WITH_OPENSSL" = xyes; then
 652   if test "x$OPENSSL_LIBS" = "x"; then
 653     AC_MSG_NOTICE([skipping test for openssl/ssl.h])
 654   else
 655     old_CPPFLAGS=$CPPFLAGS
 656     if test "x$OPENSSL_INCLUDE_DIR" != "x"; then
 657         CPPFLAGS="$CPPFLAGS -I$OPENSSL_INCLUDE_DIR"
 658     fi
 659     dnl # stupid RedHat shit
 660     CPPFLAGS="$CPPFLAGS -DOPENSSL_NO_KRB5"
 661     AC_CHECK_HEADERS( \
 662         openssl/ssl.h \
 663         openssl/crypto.h \
 664         openssl/err.h \
 665         openssl/engine.h,
 666         [],
 667         OPENSSL_LIBS=
 668     )
 669     if test "x$OPENSSL_LIBS" != "x"; then
 670         AC_MSG_CHECKING([for OpenSSL version >= 0.9.7])
 671         AC_EGREP_CPP(yes,
 672             [#include <openssl/crypto.h>
 673              #if (OPENSSL_VERSION_NUMBER >= 0x00907000L)
 674              yes
 675              #endif
 676             ], goodssl="yes")
 677         if test "x$goodssl" != "xyes"; then
 678             AC_MSG_RESULT(no)
 679             OPENSSL_LIBS=
 680         else
 681             AC_MSG_RESULT(yes)
 682             if test "x$OPENSSL_INCLUDE_DIR" != "x"; then
 683                 OPENSSL_INCLUDE="-I$OPENSSL_INCLUDE_DIR -DOPENSSL_NO_KRB5"
 684             else
 685                 OPENSSL_INCLUDE="-DOPENSSL_NO_KRB5"
 686             fi
 687         fi
 688     fi
 689     CPPFLAGS=$old_CPPFLAGS
 690   fi
 691 fi
 692 AC_SUBST(OPENSSL_INCLUDE)
 693 AC_SUBST(OPENSSL_LIBS)
 694 export OPENSSL_LIBS
 695
 696 dnl Check the pcap includes for the RADIUS sniffer.
 697 if test "x$PCAP_LIBS" = x; then
 698     AC_MSG_NOTICE([skipping test for pcap.h.])
 699 else
 700     AC_CHECK_HEADER(pcap.h,
 701         AC_DEFINE(HAVE_PCAP_H, 1,
 702                 [Define to 1 if you have the <pcap.h> header file.]),
 703         [ PCAP_LIBS=
 704         AC_MSG_WARN([pcap.h not found, silently disabling the RADIUS sniffer.])
 705         ])
 706 fi
 707 AC_SUBST(PCAP_LIBS)
 708
 709 dnl #############################################################
 710 dnl #
 711 dnl #  4. Checks for typedefs
 712 dnl #
 713 dnl #############################################################
 714
 715 dnl #
 716 dnl # Ensure that these are defined
 717 dnl #
 718 AC_TYPE_OFF_T
 719 AC_TYPE_PID_T
 720 AC_TYPE_SIZE_T
 721 AC_TYPE_UID_T
 722
 723 dnl check for socklen_t
 724 FR_CHECK_TYPE_INCLUDE([
 725 #ifdef HAVE_SYS_TYPES_H
 726 #include <sys/types.h>
 727 #endif
 728 #ifdef HAVE_SYS_SOCKET_H
 729 #include <sys/socket.h>
 730 #endif
 731 ],socklen_t, int, [socklen_t is generally 'int' on systems which don't use it])
 732
 733 dnl check for uint8_t
 734 FR_CHECK_TYPE_INCLUDE([
 735 #ifdef HAVE_INTTYPES_H
 736 #include <inttypes.h>
 737 #endif
 738 #ifdef HAVE_STDINT_H
 739 #include <stdint.h>
 740 #endif
 741 ],uint8_t, unsigned char, [uint8_t should be the canonical 'octet' for network traffic])
 742
 743 dnl check for uint16_t
 744 FR_CHECK_TYPE_INCLUDE([
 745 #ifdef HAVE_INTTYPES_H
 746 #include <inttypes.h>
 747 #endif
 748 #ifdef HAVE_STDINT_H
 749 #include <stdint.h>
 750 #endif
 751 ],uint16_t, unsigned short, [uint16_t should be the canonical '2 octets' for network traffic])
 752
 753 dnl check for uint32_t
 754 FR_CHECK_TYPE_INCLUDE([
 755 #ifdef HAVE_INTTYPES_H
 756 #include <inttypes.h>
 757 #endif
 758 #ifdef HAVE_STDINT_H
 759 #include <stdint.h>
 760 #endif
 761 ],uint32_t, unsigned int, [uint32_t should be the canonical 'network integer])
 762
 763 AC_CHECK_TYPE(struct in6_addr, AC_DEFINE(HAVE_STRUCT_IN6_ADDR, 1, [IPv6 address structure]), [], [
 764 #ifdef HAVE_NETINET_IN_H
 765 #include <netinet/in.h>
 766 #endif
 767 ])
 768
 769 AC_CHECK_TYPE(struct sockaddr_storage, AC_DEFINE(HAVE_STRUCT_SOCKADDR_STORAGE, 1, [Generic socket addresses]), [], [
 770 #ifdef HAVE_NETINET_IN_H
 771 #include <netinet/in.h>
 772 #endif
 773 #ifdef HAVE_SYS_SOCKET_H
 774 #include <sys/socket.h>
 775 #endif
 776 ])
 777
 778 AC_CHECK_TYPE(struct sockaddr_in6, AC_DEFINE(HAVE_STRUCT_SOCKADDR_IN6, 1, [IPv6 socket addresses]), [], [
 779 #ifdef HAVE_NETINET_IN_H
 780 #include <netinet/in.h>
 781 #endif
 782 ])
 783
 784 AC_CHECK_TYPE(struct addrinfo, AC_DEFINE(HAVE_STRUCT_ADDRINFO, 1, [Generic DNS lookups]), [], [
 785 #ifdef HAVE_SYS_TYPES_H
 786 #include <sys/types.h>
 787 #endif
 788 #ifdef HAVE_SYS_SOCKET_H
 789 #include <sys/socket.h>
 790 #endif
 791 #ifdef HAVE_NETDB_H
 792 #include <netdb.h>
 793 #endif
 794 ])
 795
 796 dnl #############################################################
 797 dnl #
 798 dnl #  5. Checks for structures and functions
 799 dnl #
 800 dnl #############################################################
 801 AC_CHECK_FUNCS( \
 802         getopt_long \
 803         lockf \
 804         strsignal \
 805         sigaction \
 806         sigprocmask \
 807         pthread_sigmask \
 808         snprintf \
 809         vsnprintf \
 810         setsid \
 811         strncasecmp \
 812         strcasecmp \
 813         localtime_r \
 814         ctime_r \
 815         gmtime_r \
 816         strsep \
 817         inet_aton \
 818         inet_pton \
 819         inet_ntop \
 820         setlinebuf \
 821         setvbuf \
 822         getusershell \
 823         initgroups \
 824         getaddrinfo \
 825         getnameinfo \
 826         closefrom \
 827         gettimeofday \
 828         strlcat \
 829         strlcpy
 830 )
 831 RADIUSD_NEED_DECLARATIONS( \
 832         crypt \
 833         strncasecmp \
 834         strcasecmp \
 835         inet_aton \
 836         setlinebuf \
 837         getusershell \
 838         endusershell
 839 )
 840
 841 AC_TYPE_SIGNAL
 842
 843 dnl # check if we have utmpx.h
 844 dnl # if so, check if struct utmpx has entry ut_xtime
 845 dnl # if not, set it to define ut_xtime == ut_tv.tv_sec
 846 if test "x$ac_cv_header_utmpx_h" = "xyes"
 847 then
 848  FR_CHECK_STRUCT_HAS_MEMBER([#include <utmpx.h>], [struct utmpx], ut_xtime)
 849  if test "x$ac_cv_type_struct_utmpx_has_ut_xtime" = "x"
 850  then
 851    AC_DEFINE(ut_xtime,ut_tv.tv_sec, [define to something if you don't have ut_xtime in struct utmpx])
 852  fi
 853 fi
 854
 855 dnl # struct ip_pktinfo
 856 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in_pktinfo], ipi_addr)
 857 if test "x$ac_cv_type_struct_in_pktinfo_has_ipi_addr" = "xyes"
 858 then
 859         AC_DEFINE(HAVE_IP_PKTINFO, [], [define if you have IP_PKTINFO (Linux)])
 860 fi
 861
 862 dnl # struct in6_pktinfo
 863 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in6_pktinfo], ipi6_addr)
 864 if test "x$ac_cv_type_struct_in6_pktinfo_has_ipi6_addr" = "xyes"
 865 then
 866         AC_DEFINE(HAVE_IN6_PKTINFO, [], [define if you have IN6_PKTINFO (Linux)])
 867 fi
 868
 869 dnl #############################################################
 870 dnl #
 871 dnl #  6. Checks for compiler characteristics
 872 dnl #
 873 dnl #############################################################
 874
 875 dnl #
 876 dnl # Ensure that these are defined
 877 dnl #
 878 AC_C_CONST
 879
 880 dnl #
 881 dnl # See if this is OS/2
 882 dnl #
 883 AC_MSG_CHECKING(type of OS)
 884 OS=`uname -s`
 885 AC_MSG_RESULT($OS)
 886 if test "$OS" = "OS/2"; then
 887         LIBPREFIX=
 888 else
 889         LIBPREFIX=lib
 890 fi
 891 AC_SUBST(LIBPREFIX)
 892
 893 dnl #
 894 dnl # Set Default CFLAGS
 895 dnl #
 896 if test "x$GCC" = "xyes"; then
 897     CFLAGS="$CFLAGS -Wall -D_GNU_SOURCE"
 898 fi
 899
 900 AC_MSG_CHECKING(for developer gcc flags)
 901 if test "x$developer" = "xyes" -a "x$GCC" = "xyes"; then
 902   devflags="-g -Wshadow -Wpointer-arith -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -W -Wredundant-decls -Wundef"
 903   CFLAGS="$CFLAGS $devflags"
 904   INSTALLSTRIP=""
 905   AC_MSG_RESULT(yes.  Using $devflags)
 906 else
 907   devflags=""
 908   CFLAGS="$CFLAGS -DNDEBUG"
 909   INSTALLSTRIP="-s"
 910   AC_MSG_RESULT(no.)
 911 fi
 912
 913 dnl #############################################################
 914 dnl #
 915 dnl #  7. Checks for library functions
 916 dnl #
 917 dnl #############################################################
 918
 919 dnl Check for libcrypt
 920 dnl We use crypt(3) which may be in libc, or in libcrypt (eg FreeBSD)
 921 AC_CHECK_LIB(crypt, crypt,
 922   CRYPTLIB="-lcrypt"
 923 )
 924 if test "$CRYPTLIB" != ""; then
 925   AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function])
 926 else
 927   AC_CHECK_FUNC(crypt, AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function]))
 928 fi
 929
 930 dnl Check for libcipher
 931 AC_CHECK_LIB(cipher, setkey,
 932    CRYPTLIB="${CRYPTLIB} -lcipher"
 933 )
 934 AC_SUBST(CRYPTLIB)
 935
 936 if test "x$WITH_SNMP" = "xyes"; then
 937   SNMP_CHECKS
 938 fi
 939
 940 dnl Check the style of gethostbyaddr, in order of preference
 941 dnl GNU (_r eight args)
 942 AC_DEFINE(GNUSTYLE, [1], [GNU-Style get*byaddr_r])
 943 dnl SYSV (_r six args)
 944 AC_DEFINE(SYSVSTYLE, [2], [SYSV-Style get*byaddr_r])
 945 dnl BSD (three args, may not be thread safe)
 946 AC_DEFINE(BSDSTYLE, [3], [BSD-Style get*byaddr_r])
 947 dnl Tru64 has BSD version, but it is thread safe
 948 dnl     http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1739____.HTM
 949 dnl We need #stdio.h to define NULL on FreeBSD (at least)
 950 gethostbyaddrrstyle=""
 951 AC_MSG_CHECKING([gethostbyaddr_r() syntax])
 952 case "$host" in
 953 *-freebsd*)
 954 dnl With FreeBSD, check if there's a prototype for gethostbyaddr_r.
 955 dnl Some versions (FreeBSD 5.1?) have a symbol but no prototype - so we
 956 dnl override this test to BSDSTYLE. FreeBSD 6.2 and up have proper GNU
 957 dnl style support.
 958         AC_CHECK_DECLS([gethostbyaddr_r], [], [
 959                 AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE,
 960                         [style of gethostbyaddr_r functions ])
 961                 gethostbyaddrrstyle=BSD
 962                 AC_MSG_WARN([FreeBSD overridden to BSD-style])
 963         ], [
 964 #ifdef HAVE_NETDB_H
 965 #include <netdb.h>
 966 #endif
 967 ])
 968         ;;
 969 esac
 970 if test "x$gethostbyaddrrstyle" = "x"; then
 971         AC_TRY_LINK([
 972 #include <stdio.h>
 973 #include <netdb.h>
 974 ], [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL, NULL) ], [
 975         AC_DEFINE(GETHOSTBYADDRRSTYLE, GNUSTYLE, [style of gethostbyaddr_r functions ])
 976         gethostbyaddrrstyle=GNU
 977 ])
 978 fi
 979 if test "x$gethostbyaddrrstyle" = "x"; then
 980         AC_TRY_LINK([
 981 #include <stdio.h>
 982 #include <netdb.h>
 983 ], [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL) ] , [
 984                 AC_DEFINE(GETHOSTBYADDRRSTYLE, SYSVSTYLE, [style of gethostbyaddr_r functions ])
 985                 gethostbyaddrrstyle=SYSV
 986         ])
 987 fi
 988 if test "x$gethostbyaddrrstyle" = "x"; then
 989         AC_TRY_LINK([
 990 #include <stdio.h>
 991 #include <netdb.h>
 992 ], [ gethostbyaddr(NULL, 0, 0)  ], [
 993                 AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE, [style of gethostbyaddr_r functions ])
 994                 gethostbyaddrrstyle=BSD
 995         ])
 996 fi
 997
 998 if test "x$gethostbyaddrrstyle" = "x"; then
 999         AC_MSG_RESULT([none!  It must not exist, here.])
1000 else
1001         AC_MSG_RESULT([${gethostbyaddrrstyle}-style])
1002 fi
1003
1004 if test "x$gethostbyaddrrstyle" = "xBSD"; then
1005         AC_MSG_WARN([ ****** BSD-style gethostbyaddr might NOT be thread-safe! ****** ])
1006 fi
1007
1008 dnl Check the style of gethostbyname, in order of preference
1009 dnl GNU (_r seven args)
1010 dnl SYSV (_r five args)
1011 dnl BSD (two args, may not be thread safe)
1012 dnl Tru64 has BSD version, but it _is_ thread safe
1013 dnl     http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1946____.HTM
1014 dnl We need #stdio.h to define NULL on FreeBSD (at least)
1015 gethostbynamerstyle=""
1016 AC_MSG_CHECKING([gethostbyname_r() syntax])
1017 AC_TRY_LINK([
1018 #include <stdio.h>
1019 #include <netdb.h>
1020 ], [ gethostbyname_r(NULL, NULL, NULL, 0, NULL, NULL) ], [
1021         AC_DEFINE(GETHOSTBYNAMERSTYLE, GNUSTYLE, [style of gethostbyname_r functions ])
1022         gethostbynamerstyle=GNU
1023 ])
1024 if test "x$gethostbynamerstyle" = "x"; then
1025         AC_TRY_LINK([
1026 #include <stdio.h>
1027 #include <netdb.h>
1028 ], [ gethostbyname_r(NULL, NULL, NULL, 0, NULL) ] , [
1029                 AC_DEFINE(GETHOSTBYNAMERSTYLE, SYSVSTYLE, [style of gethostbyname_r functions ])
1030                 gethostbynamerstyle=SYSV
1031         ])
1032 fi
1033 if test "x$gethostbynamerstyle" = "x"; then
1034         AC_TRY_LINK([
1035 #include <stdio.h>
1036 #include <netdb.h>
1037 ], [ gethostbyname(NULL)  ], [
1038                 AC_DEFINE(GETHOSTBYNAMERSTYLE, BSDSTYLE, [style of gethostbyname_r functions ])
1039                 gethostbynamerstyle=BSD
1040         ])
1041 fi
1042
1043 if test "x$gethostbynamerstyle" = "x"; then
1044         AC_MSG_RESULT([none!  It must not exist, here.])
1045 else
1046         AC_MSG_RESULT([${gethostbynamerstyle}-style])
1047 fi
1048
1049 if test "x$gethostbynamerstyle" = "xBSD"; then
1050         AC_MSG_WARN([ ****** BSD-style gethostbyname might NOT be thread-safe! ****** ])
1051 fi
1052
1053 dnl check for non-posix solaris ctime_r (extra buflen int arg)
1054 AC_DEFINE(POSIXSTYLE, [1], [Posix-Style ctime_r])
1055 AC_DEFINE(SOLARISSTYLE, [2], [Solaris-Style ctime_r])
1056 ctimerstyle=""
1057 AC_MSG_CHECKING([ctime_r() syntax])
1058 AC_TRY_LINK([
1059 #include <time.h>
1060 ], [ ctime_r(NULL, NULL, 0) ], [
1061         AC_DEFINE(CTIMERSTYLE, SOLARISSTYLE, [style of ctime_r function])
1062         ctimerstyle="SOLARIS"
1063 ])
1064 if test "x$ctimerstyle" = "x"; then
1065         AC_TRY_LINK([
1066 #include <time.h>
1067 ], [ ctime_r(NULL, NULL) ], [
1068                 AC_DEFINE(CTIMERSTYLE, POSIXSTYLE, [style of ctime_r function])
1069                 ctimerstyle="POSIX"
1070         ])
1071 fi
1072
1073 if test "x$ctimerstyle" = "x"; then
1074         AC_MSG_RESULT([none!  It must not exist, here.])
1075 else
1076         AC_MSG_RESULT([${ctimerstyle}-style])
1077 fi
1078
1079 AC_SUBST(HOSTINFO, $host)
1080
1081 dnl #############################################################
1082 dnl #
1083 dnl #  8. Checks for system services
1084 dnl #
1085 dnl #############################################################
1086
1087 dnl #
1088 dnl # Figure out where libtool is located,
1089 dnl #
1090 top_builddir=`pwd`
1091 export top_builddir
1092 AC_MSG_RESULT([top_builddir=$top_builddir])
1093 dnl # AC_SUBST(top_builddir)
1094 AC_SUBST(LIBLTDL)
1095 AC_SUBST(INCLTDL)
1096
1097 dnl import libtool stuff
1098
1099 dnl #############################################################
1100 dnl #
1101 dnl #  Configure in any module directories.
1102 dnl #
1103 dnl #############################################################
1104
1105 mysubdirs="$LIBLTDLPATH"
1106 if test "x$EXPERIMENTAL" = "xyes"; then
1107   bar=`ls -1 "${srcdir}"/src/modules/rlm_*/configure | sed 's%/configure%%'`
1108   dnl # get rid of LF's.
1109   mysubdirs=`echo $mysubdirs $bar`
1110 else
1111   dnl #
1112   dnl # Find 'configure' in ONLY the stable modules
1113   dnl #
1114   for bar in `cat "${srcdir}"/src/modules/stable`; do
1115     if test -f "${srcdir}"/src/modules/$bar/configure; then
1116       mysubdirs="$mysubdirs src/modules/$bar"
1117     fi
1118   done
1119 fi
1120
1121 dnl ############################################################
1122 dnl # make modules by list
1123 dnl #############################################################
1124 if test "x$EXPERIMENTAL" = "xyes"; then
1125   for foo in `ls -1 "${srcdir}"/src/modules | grep rlm_`; do
1126     MODULES="$MODULES $foo"
1127   done
1128 else
1129    dnl #
1130    dnl # make ONLY the stable modules
1131    dnl #
1132    for foo in `cat "${srcdir}"/src/modules/stable`; do
1133     MODULES="$MODULES $foo"
1134    done
1135 fi
1136
1137 dnl #
1138 dnl #  Don't change the variable name here.  Autoconf goes bonkers
1139 dnl #  if you do.
1140 dnl #
1141 AC_CONFIG_SUBDIRS($LTDL_SUBDIRS $mysubdirs)
1142 AC_SUBST(MODULES)
1143
1144 dnl #############################################################
1145 dnl #
1146 dnl #  And finally, output the results.
1147 dnl #
1148 dnl #############################################################
1149
1150 AC_CONFIG_COMMANDS([stamp-h], [echo timestamp > src/include/stamp-h])
1151 AC_CONFIG_COMMANDS([build-radpaths-h], [(cd ./src/include && /bin/sh ./build-radpaths-h)])
1152 AC_CONFIG_COMMANDS([main-chmod], [(cd ./src/main   && chmod +x checkrad.pl radlast radtest)])
1153 AC_CONFIG_COMMANDS([scripts-chmod], [(cd ./scripts    && chmod +x rc.radiusd radwatch check-radiusd-config radiusd.cron.daily radiusd.cron.monthly cryptpasswd)])
1154
1155 dnl #
1156 dnl #  Substitute whatever libraries we found to be necessary
1157 dnl #
1158 AC_SUBST(LIBS)
1159 AC_SUBST(INSTALLSTRIP)
1160
1161 USE_SHARED_LIBS=$enable_shared
1162 AC_SUBST(USE_SHARED_LIBS)
1163 USE_STATIC_LIBS=$enable_static
1164 AC_SUBST(USE_STATIC_LIBS)
1165 AC_SUBST(STATIC_MODULES)
1166 AC_SUBST(RADIUSD_MAJOR_VERSION)
1167 AC_SUBST(RADIUSD_MINOR_VERSION)
1168 AC_SUBST(RADIUSD_VERSION)
1169
1170 AC_OUTPUT(\
1171         ./Make.inc \
1172         ./src/include/build-radpaths-h \
1173         ./src/main/Makefile \
1174         ./src/main/checkrad.pl \
1175         ./src/main/radlast \
1176         ./src/main/radtest \
1177         ./scripts/rc.radiusd \
1178         ./scripts/radwatch \
1179         ./scripts/check-radiusd-config \
1180         ./scripts/radiusd.cron.daily \
1181         ./scripts/radiusd.cron.monthly \
1182         ./scripts/cryptpasswd \
1183         ./raddb/dictionary \
1184         ./raddb/radiusd.conf \
1185         ./raddb/vmpsd.conf
1186 )