configure.in

   1 dnl #############################################################
   2 dnl #
   3 dnl #  For information about autoconf, see:
   4 dnl #
   5 dnl #  http://www.gnu.org/software/autoconf/
   6 dnl #
   7 dnl #  The recommended order is:
   8 dnl #
   9 dnl #  AC_INIT(file)
  10 dnl #  0. checks for compiler, libtool, and command line options
  11 dnl #  1. checks for programs
  12 dnl #  2. checks for libraries
  13 dnl #  3. checks for header files
  14 dnl #  4. checks for typedefs
  15 dnl #  5. checks for structures and functions
  16 dnl #  6. checks for compiler characteristics
  17 dnl #  7. checks for library functions
  18 dnl #  8. checks for system services
  19 dnl #  AC_OUTPUT([file...])
  20 dnl #
  21 dnl #############################################################
  22
  23 AC_PREREQ([2.59])
  24 export CFLAGS LIBS LDFLAGS CPPFLAGS
  25 AC_INIT(src/main/radiusd.c)
  26 AC_CONFIG_HEADER(src/include/autoconf.h)
  27 AC_REVISION($Revision$)dnl
  28
  29 dnl # The version of the software
  30 RADIUSD_VERSION=`cat VERSION`
  31 RADIUSD_MAJOR_VERSION=`cat VERSION | sed 's/\..*//'`
  32 RADIUSD_MINOR_VERSION=`cat VERSION | sed 's/^3\.//'`
  33 PACKAGE=freeradius
  34
  35 dnl #############################################################
  36 dnl #
  37 dnl #  0. Checks for compiler, libtool, and command line options.
  38 dnl #
  39 dnl #############################################################
  40
  41 dnl Check for GNU cc
  42 AC_PROG_CC
  43 AC_PROG_CXX
  44
  45 dnl #
  46 dnl # check for AIX, to allow us to use some BSD functions
  47 dnl # must be before macros that call the compiler.
  48 dnl #
  49 AC_AIX
  50
  51 AC_PROG_GCC_TRADITIONAL
  52 AC_PROG_CC_SUNPRO
  53 AC_PROG_RANLIB
  54
  55 dnl #
  56 dnl # Set Default CFLAGS
  57 dnl #
  58 if test "x$GCC" = "xyes"; then
  59     CFLAGS="$CFLAGS -Wall -D_GNU_SOURCE"
  60 fi
  61
  62 dnl Compile in large (2G+) file support.
  63 AC_SYS_LARGEFILE
  64
  65 dnl # check for system bytesex
  66 dnl # AC_DEFINES WORDS_BIGENDIAN
  67 AC_C_BIGENDIAN
  68
  69 dnl Find GNU Make.
  70 AC_CHECK_PROG(GMAKE, gmake, yes, no)
  71 if test $GMAKE = no; then
  72   AC_PATH_PROG(MAKE, make, /usr/local/bin/make)
  73 else
  74   AC_PATH_PROG(MAKE, gmake, /usr/local/gnu/bin/make)
  75 fi
  76 makever=`$ac_cv_path_MAKE --version 2>&1 | grep "GNU Make"`
  77 if test -z "$makever"; then
  78   AC_MSG_ERROR(GNU Make is not installed.  Please download and install it
  79                 from ftp://prep.ai.mit.edu/pub/gnu/make/ before continuing.)
  80 fi
  81
  82 AC_ARG_WITH(system-libltdl,
  83 [  --with-system-libltdl   Use the libltdl installed in your system (default=use dlopen)],
  84 [
  85 LIBLTDL="-lltdl"
  86 INCLTDL=-DWITH_SYSTEM_LTDL
  87 ],
  88 )
  89
  90 dnl use system-wide libtool, if it exists
  91 AC_ARG_WITH(system-libtool,
  92 [  --with-system-libtool   Use the libtool installed in your system (default=use our own)],
  93 [ AC_PATH_PROG(LIBTOOL, libtool,,$PATH:/usr/local/bin) AC_LIBTOOL_DLOPEN
  94  AC_PROG_LIBTOOL],
  95 [
  96   LIBTOOL='${top_srcdir}/scripts/jlibtool'
  97   AC_SUBST(LIBTOOL)
  98   dnl ensure that we're looking for dlopen
  99   AC_LIBTOOL_DLOPEN
 100 ])
 101
 102
 103 dnl Put this in later, when all distributed modules use autoconf.
 104 dnl AC_ARG_WITH(disablemodulefoo,
 105 dnl [  --without-rlm_foo       Disables module compilation.  Module list:]
 106 dnl esyscmd([find src/modules -type d -name rlm_\* -print |\
 107 dnl     sed -e 's%src/modules/.*/% (sub)- %; s%.*/%- %' |\
 108 dnl     awk '{print "                            "$0}']))
 109
 110 AC_ARG_ENABLE(strict-dependencies,
 111 [  --enable-strict-dependencies  Fail configure on lack of module dependancy.])
 112
 113 dnl extra argument: --with-docdir
 114 docdir='${datadir}/doc/freeradius'
 115 AC_MSG_CHECKING(docdir)
 116 AC_ARG_WITH(docdir,
 117 [  --with-docdir=DIR       Directory for documentation [DATADIR/doc/freeradius] ],
 118 [ case "$withval" in
 119     no)
 120         docdir=no
 121         ;;
 122     yes)
 123         ;;
 124     [[\\/$]]* | ?:[[\\/]]* )
 125         docdir="$withval"
 126         ;;
 127     *)
 128         AC_MSG_ERROR([expected an absolute directory name for --with-docdir: $withval])
 129         ;;
 130   esac ]
 131 )
 132 AC_SUBST(docdir)
 133 AC_MSG_RESULT($docdir)
 134 if test "x$docdir" = xno; then
 135         AC_MSG_WARN(Documentation files will NOT be installed.)
 136 fi
 137
 138 dnl extra argument: --with-logdir
 139 logdir='${localstatedir}/log/radius'
 140 AC_MSG_CHECKING(logdir)
 141 AC_ARG_WITH(logdir,
 142 [  --with-logdir=DIR       Directory for logfiles [LOCALSTATEDIR/log/radius] ],
 143 [ case "$withval" in
 144     no)
 145         AC_MSG_ERROR(Need logdir)
 146         ;;
 147     yes)
 148         ;;
 149     [[\\/$]]* | ?:[[\\/]]* )
 150         logdir="$withval"
 151         ;;
 152     *)
 153         AC_MSG_ERROR([expected an absolute directory name for --with-logdir: $withval])
 154         ;;
 155   esac ]
 156 )
 157 AC_SUBST(logdir)
 158 AC_MSG_RESULT($logdir)
 159
 160 dnl extra argument: --with-radacctdir
 161 radacctdir='${logdir}/radacct'
 162 AC_MSG_CHECKING(radacctdir)
 163 AC_ARG_WITH(radacctdir,
 164 [  --with-radacctdir=DIR   Directory for detail files [LOGDIR/radacct] ],
 165 [ case "$withval" in
 166     no)
 167         AC_MSG_ERROR(Need radacctdir)
 168         ;;
 169     yes)
 170         ;;
 171     [[\\/$]]* | ?:[[\\/]]* )
 172         radacctdir="$withval"
 173         ;;
 174     *)
 175         AC_MSG_ERROR([expected an absolute directory name for --with-radacctdir: $withval])
 176         ;;
 177   esac ]
 178 )
 179 AC_SUBST(radacctdir)
 180 AC_MSG_RESULT($radacctdir)
 181
 182 dnl extra argument: --with-raddbdir
 183 raddbdir='${sysconfdir}/raddb'
 184 AC_MSG_CHECKING(raddbdir)
 185 AC_ARG_WITH(raddbdir,
 186 [  --with-raddbdir=DIR     Directory for config files [SYSCONFDIR/raddb] ],
 187 [ case "$withval" in
 188     no)
 189         AC_MSG_ERROR(Need raddbdir)
 190         ;;
 191     yes)
 192         ;;
 193     [[\\/$]]* | ?:[[\\/]]* )
 194         raddbdir="$withval"
 195         ;;
 196     *)
 197         AC_MSG_ERROR([expected an absolute directory name for --with-raddbdir: $withval])
 198         ;;
 199   esac ]
 200 )
 201 AC_SUBST(raddbdir)
 202 AC_MSG_RESULT($raddbdir)
 203
 204 dnl extra argument: --with-ascend-binary
 205 ASCEND_BINARY=yes
 206 AC_ARG_WITH(ascend-binary,
 207 [  --with-ascend-binary    Include support for Ascend binary filter attributes (default=yes)],
 208 [ case "$withval" in
 209     yes)
 210         ;;
 211     *)
 212         ASCEND_BINARY=""
 213   esac ]
 214 )
 215 if test "X$ASCEND_BINARY" = "Xyes"; then
 216   AC_DEFINE(ASCEND_BINARY, [], [Include support for Ascend binary filter attributes])
 217 fi
 218
 219 dnl extra argument: --with-threads
 220 WITH_THREADS=yes
 221 AC_ARG_WITH(threads,
 222 [  --with-threads          Use threads, if available.  (default=yes) ],
 223 [ case "$withval" in
 224     yes)
 225         ;;
 226     *)
 227         WITH_THREADS=""
 228   esac ]
 229 )
 230
 231 dnl extra argument: --with-vmps
 232 WITH_VMPS=yes
 233 AC_ARG_WITH(vmps,
 234 [  --with-vmps             Compile in VMPS support. (default=yes)],
 235 [ case "$withval" in
 236     yes)
 237         ;;
 238     *)
 239         WITH_VMPS=no
 240   esac ]
 241 )
 242 if test "x$WITH_VMPS" = "xyes"; then
 243         AC_DEFINE(WITH_VMPS, [1], [define if you want VMPS support])
 244 fi
 245
 246 dnl extra argument: --with-dhcp
 247 WITH_DHCP=yes
 248 AC_ARG_WITH(dhcp,
 249 [  --with-dhcp             Compile in DHCP support. (default=yes)],
 250 [ case "$withval" in
 251     yes)
 252         ;;
 253     *)
 254         WITH_DHCP=no
 255   esac ]
 256 )
 257 if test "x$WITH_DHCP" = "xyes"; then
 258         AC_DEFINE(WITH_DHCP, [1], [define if you want DHCP support])
 259 fi
 260
 261
 262 dnl #
 263 dnl #  Allow the user to specify a list of modules to be linked
 264 dnl #  statically to the server.
 265 dnl #
 266 STATIC_MODULES=
 267 AC_ARG_WITH(static_modules,
 268 [  --with-static-modules=QUOTED-MODULE-LIST],[
 269   for i in $withval; do
 270     STATIC_MODULES="$STATIC_MODULES -dlpreopen ../modules/rlm_$i/rlm_$i.la"
 271   done
 272 ])
 273
 274 MODULES=
 275 AC_ARG_WITH(modules,
 276 [ --with-modules=QUOTED-MODULE-LIST],[
 277  for i in $withval; do
 278    MODULES="$MODULES $i"
 279  done
 280 ])
 281
 282 dnl #
 283 dnl #  Enable developer C compiler warnings
 284 dnl #
 285 AC_ARG_ENABLE(developer,
 286 [  --enable-developer               Enables features of interest to developers.],
 287 [ case "$enableval" in
 288     no)
 289         developer=no
 290         ;;
 291     *)
 292         developer=yes
 293   esac ]
 294 )
 295
 296 if test "x$developer" != "xno" -a -d $srcdir/CVS; then
 297   dnl turn on the developer flag when taken from a CVS checkout (not a release)
 298   developer="yes"
 299 fi
 300
 301 if test "x$developer" != "xno" -a -d $srcdir/.git; then
 302   dnl turn on the developer flag when taken from a git checkout (not a release)
 303   developer="yes"
 304 fi
 305
 306 dnl extra argument: --with-experimental-modules
 307 EXPERIMENTAL=
 308 AC_ARG_WITH(experimental-modules,
 309 [  --with-experimental-modules      Use experimental and unstable modules. (default=no) ],
 310 [ case "$withval" in
 311     yes)
 312         EXPERIMENTAL=yes
 313         ;;
 314     *)
 315   esac ]
 316 )
 317
 318 dnl extra argument: --with-openssl
 319 WITH_OPENSSL=yes
 320 AC_ARG_WITH(openssl,
 321 [  --with-openssl                   Use OpenSSL. (default=yes)],
 322 [ case "$withval" in
 323     no)
 324         WITH_OPENSSL=no
 325         ;;
 326     *)
 327         WITH_OPENSSL=yes
 328         ;;
 329   esac ]
 330 )
 331
 332 dnl #
 333 dnl # extra argument: --with-openssl-includes=dir
 334 dnl #
 335 OPENSSL_INCLUDE_DIR=
 336 AC_ARG_WITH(openssl-includes,
 337 [  --with-openssl-includes=DIR      Directory to look for OpenSSL include files],
 338 [ case "$withval" in
 339     *) OPENSSL_INCLUDE_DIR="$withval"
 340         ;;
 341   esac ]
 342 )
 343
 344 dnl #
 345 dnl # extra argument: --with-openssl-libraries=dir
 346 dnl #
 347 OPENSSL_LIB_DIR=
 348 AC_ARG_WITH(openssl-libraries,
 349 [  --with-openssl-libraries=DIR     Directory to look for OpenSSL library files],
 350 [ case "$withval" in
 351     *) OPENSSL_LIB_DIR="$withval"
 352         ;;
 353   esac ]
 354 )
 355
 356 dnl #
 357 dnl #  These next two arguments don't actually do anything.  They're
 358 dnl #  place holders so that the top-level configure script can tell
 359 dnl #  the user how to configure lower-level modules
 360 dnl #
 361
 362 dnl #
 363 dnl # extra argument: --with-rlm-FOO-lib-dir
 364 dnl #
 365 AC_ARG_WITH(rlm-FOO-lib-dir,
 366 [  --with-rlm-FOO-lib-dir=DIR       Directory to look for library files used by module FOO],
 367 [ case "$withval" in
 368     *)
 369         ;;
 370   esac ]
 371 )
 372
 373 dnl #
 374 dnl # extra argument: --with-rlm-FOO-include-dir
 375 dnl #
 376 AC_ARG_WITH(rlm-FOO-include-dir,
 377 [  --with-rlm-FOO-include-dir=DIR   Directory to look for include files used by module FOO],
 378 [ case "$withval" in
 379     *)
 380         ;;
 381   esac ]
 382 )
 383
 384 dnl See what include-style is used by the make program.
 385 dnl AC_MSG_CHECKING(include style for make)
 386 dnl echo "include /dev/null" > testmake.$$
 387 dnl echo "all:" >> testmake.$$
 388 dnl make -f testmake.$$ >/dev/null 2>&1
 389 dnl if test $? = 0
 390 dnl then
 391 dnl     INCLUDE=include
 392 dnl     IQUOTE=
 393 dnl else
 394 dnl     INCLUDE=.include
 395 dnl     IQUOTE='"'
 396 dnl fi
 397 dnl rm -f testmake.$$
 398 dnl AC_MSG_RESULT(" $INCLUDE")
 399 dnl AC_SUBST(INCLUDE)
 400 dnl AC_SUBST(IQUOTE)
 401
 402 dnl extra argument: --with-udpfromto
 403 WITH_UDPFROMTO=no
 404 AC_ARG_WITH(udpfromto,
 405 [  --with-udpfromto        Compile in UDPFROMTO support. (default=no)],
 406 [ case "$withval" in
 407     yes)
 408         WITH_UDPFROMTO=yes
 409         ;;
 410     *)
 411         WITH_UDPFROMTO=no
 412   esac ]
 413 )
 414
 415 if test "x$WITH_UDPFROMTO" = "xyes"; then
 416         AC_DEFINE(WITH_UDPFROMTO, [], [define if you want udpfromto])
 417 fi
 418
 419 dnl #############################################################
 420 dnl #
 421 dnl #  1. Checks for programs
 422 dnl #
 423 dnl #############################################################
 424
 425 CHECKRAD=checkrad.pl
 426 AC_PATH_PROG(PERL, perl, /usr/local/bin/perl)
 427 if test "x$ac_cv_path_PERL" = "x"; then
 428   AC_MSG_WARN(perl not found - Simultaneous-Use and checkrad.pl may not work)
 429 fi
 430 AC_PATH_PROG(SNMPGET, snmpget)
 431 if test "x$ac_cv_path_SNMPGET" = "x"; then
 432   AC_MSG_WARN(snmpget not found - Simultaneous-Use and checkrad.pl may not work)
 433 fi
 434
 435 AC_PATH_PROG(SNMPWALK, snmpwalk)
 436 if test "x$ac_cv_path_SNMPWALK" = "x"; then
 437   AC_MSG_WARN(snmpwalk not found - Simultaneous-Use and checkrad.pl may not work)
 438 fi
 439
 440 AC_PATH_PROG(RUSERS, rusers, /usr/bin/rusers)
 441
 442 dnl FIXME This is truly gross.
 443 missing_dir=`cd $ac_aux_dir && pwd`
 444 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
 445 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
 446 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
 447
 448 AC_PATH_PROG(LOCATE,locate)
 449 AC_PATH_PROG(DIRNAME,dirname)
 450 AC_PATH_PROG(GREP,grep)
 451
 452 dnl #############################################################
 453 dnl #
 454 dnl #  2. Checks for libraries
 455 dnl #
 456 dnl #############################################################
 457
 458 dnl If using pthreads, check for -lpthread (posix) or -lc_r (*BSD)
 459 old_CFLAGS=$CFLAGS
 460 if test "x$WITH_THREADS" = "xyes"; then
 461   if test $ac_cv_prog_suncc = "yes"; then
 462     CFLAGS="$CFLAGS -mt"
 463   fi
 464
 465   AC_CHECK_HEADERS(pthread.h, [], [ WITH_THREADS="no" ])
 466
 467 dnl #
 468 dnl # pthread stuff is usually in -lpthread
 469 dnl # or in -lc_r, on *BSD
 470 dnl #
 471 dnl # On Some systems, we need extra pre-processor flags, to get them to
 472 dnl # to do the threading properly.
 473 dnl #
 474   AC_CHECK_LIB(pthread, pthread_create,
 475                 [ CFLAGS="$CFLAGS -D_REENTRANT -D_POSIX_PTHREAD_SEMANTICS"
 476                   LIBS="-lpthread $LIBS" ],
 477                 AC_CHECK_LIB(c_r, pthread_create,
 478                             [ CFLAGS="$CFLAGS -pthread -D_THREAD_SAFE" ],
 479                             [ WITH_THREADS="no" ]
 480                             )
 481                 )
 482 fi
 483
 484 dnl #
 485 dnl # If we have NO pthread libraries, remove any knowledge of threads.
 486 dnl #
 487 if test "x$WITH_THREADS" != "xyes"; then
 488   CFLAGS=$old_CFLAGS
 489   ac_cv_header_pthread_h="no"
 490   WITH_THREADS=no
 491 else
 492   dnl #
 493   dnl #  We need sem_init() and friends, as they're the friendliest
 494   dnl #  semaphore functions for threading.
 495   dnl #
 496   dnl # HP/UX requires linking with librt, too, to get the sem_* symbols.
 497   dnl # Some systems have them in -lsem
 498   dnl # Solaris has them in -lposix4
 499   dnl # NetBSD has them in -lsemaphore
 500
 501   AC_SEARCH_LIBS(sem_init, pthread sem posix4 rt semaphore,
 502         [],
 503         [AC_MSG_ERROR(-lsem not found.  You may want to download it from ftp://ftp.to.gd-es.com/pub/BSDI/libsem.tar.bz2 or ftp://ftp.freeradius.org/pub/radius/contrib/libsem.tar.gz)]
 504    )
 505 fi
 506
 507 dnl Check if we need -lsocket
 508 AC_CHECK_LIB(dl, dlopen)
 509
 510 dnl Check if we need -lsocket
 511 AC_CHECK_LIB(socket, getsockname)
 512
 513 dnl Check for -lresolv
 514 dnl This library may be needed later.
 515 AC_CHECK_LIB(resolv, inet_aton)
 516
 517 dnl Check if we need -lnsl. Usually if we want to
 518 dnl link against -lsocket we need to include -lnsl as well.
 519 AC_CHECK_LIB(nsl, inet_ntoa)
 520
 521 dnl Check for OpenSSL libraries.
 522 OPENSSL_LIBS=
 523 if test "x$WITH_OPENSSL" = xyes; then
 524   old_LIBS=$LIBS
 525   old_LDFLAGS="$LDFLAGS"
 526   if test "x$OPENSSL_LIB_DIR" != "x"; then
 527     LDFLAGS="$LDFLAGS -L$OPENSSL_LIB_DIR"
 528   fi
 529   AC_CHECK_LIB(crypto, DH_new,
 530     [
 531         LIBS="-lcrypto $LIBS"
 532         AC_DEFINE(HAVE_LIBCRYPTO, 1,
 533             [Define to 1 if you have the `crypto' library (-lcrypto).])
 534         AC_CHECK_LIB(ssl, SSL_new,
 535             [
 536                 AC_DEFINE(HAVE_LIBSSL, 1,
 537                     [Define to 1 if you have the `ssl' library (-lssl).])
 538                 if test "x$OPENSSL_LIB_DIR" != "x"; then
 539                     OPENSSL_LIBS="-L$OPENSSL_LIB_DIR"
 540                 fi
 541                 OPENSSL_LIBS="$OPENSSL_LIBS -lcrypto -lssl -lcrypto"
 542             ], [])
 543     ], [])
 544   LIBS=$old_LIBS
 545   LDFLAGS="$old_LDFLAGS"
 546 fi
 547
 548 AC_CHECK_LIB(ws2_32, htonl)
 549
 550 dnl Check the pcap library for the RADIUS sniffer.
 551 PCAP_LIBS=
 552 AC_CHECK_LIB(pcap, pcap_open_live,
 553         [ PCAP_LIBS="-lpcap"
 554         AC_DEFINE(HAVE_LIBPCAP, 1,
 555                 [Define to 1 if you have the `pcap' library (-lpcap).])
 556         ],
 557         [ AC_MSG_WARN([pcap library not found, silently disabling the RADIUS sniffer.]) ])
 558
 559 AC_LIB_READLINE
 560
 561 dnl #############################################################
 562 dnl #
 563 dnl #  3. Checks for header files
 564 dnl #
 565 dnl #############################################################
 566
 567 dnl #
 568 dnl # Interix requires us to set -D_ALL_SOURCE, otherwise
 569 dnl # getopt will be #included, but won't link.  <sigh>
 570 dnl #
 571 dnl #
 572 case "$host" in
 573 *-interix*)
 574         CFLAGS="$CFLAGS -D_ALL_SOURCE"
 575         ;;
 576 *-darwin*)
 577         CFLAGS="$CFLAGS -DDARWIN"
 578         LIBS="-framework DirectoryService $LIBS"
 579         ;;
 580 esac
 581
 582 AC_HEADER_DIRENT
 583 AC_HEADER_STDC
 584 AC_HEADER_TIME
 585 AC_HEADER_SYS_WAIT
 586
 587 AC_CHECK_HEADERS( \
 588         unistd.h \
 589         crypt.h \
 590         errno.h \
 591         resource.h \
 592         sys/resource.h \
 593         getopt.h \
 594         malloc.h \
 595         utmp.h \
 596         utmpx.h \
 597         signal.h \
 598         sys/select.h \
 599         syslog.h \
 600         inttypes.h \
 601         stdint.h \
 602         stdio.h \
 603         netdb.h \
 604         semaphore.h \
 605         arpa/inet.h \
 606         netinet/in.h \
 607         sys/types.h \
 608         sys/socket.h \
 609         winsock.h \
 610         utime.h \
 611         sys/time.h \
 612         sys/wait.h \
 613         sys/security.h \
 614         fcntl.h \
 615         sys/fcntl.h \
 616         sys/prctl.h \
 617         sys/un.h \
 618         glob.h \
 619         prot.h \
 620         pwd.h \
 621         grp.h \
 622         stddef.h \
 623         fnmatch.h \
 624         sia.h \
 625         siad.h
 626 )
 627
 628 dnl FreeBSD requires sys/socket.h before net/if.h
 629 AC_CHECK_HEADERS(net/if.h, [], [],
 630 [#ifdef HAVE_SYS_SOCKET_H
 631 # include <sys/socket.h>
 632 # endif
 633 ])
 634
 635 REGEX=no
 636 AC_CHECK_HEADER(pcreposix.h, AC_DEFINE(HAVE_PCREPOSIX_H, [], [define this if we have the <pcreposix.h> header file]))
 637 if test "x$ac_cv_header_pcreposix_h" = "xyes"; then
 638   AC_DEFINE(HAVE_REGEX_H, [], [define if we have any regex])
 639   REGEX_EXTENDED=yes
 640   REGEX_PCRE=yes
 641   REGEX=yes
 642   LIBS="$LIBS -lpcreposix"
 643 else
 644
 645 AC_CHECK_HEADER(regex.h, AC_DEFINE(HAVE_REGEX_H, [], [define this if we have the <regex.h> header file]))
 646 if test "x$ac_cv_header_regex_h" = "xyes"; then
 647   REGEX_EXTENDED=no
 648   REGEX_PCRE=no
 649   REGEX=yes
 650   AC_EGREP_CPP(yes,
 651     [#include <regex.h>
 652      #ifdef REG_EXTENDED
 653        yes
 654      #endif
 655      ], [AC_DEFINE(HAVE_REG_EXTENDED, [], [define this if we have REG_EXTENDED (from <regex.h>)]) REGEX_EXTENDED=yes])
 656 fi
 657 fi
 658
 659 AC_SUBST(REGEX)
 660 AC_SUBST(REGEX_PCRE)
 661 AC_SUBST(REGEX_EXTENDED)
 662
 663 dnl #
 664 dnl #  other checks which require headers
 665 dnl #
 666 if test "x$ac_cv_header_sys_security_h" = "xyes" && test "x$ac_cv_header_prot_h" = "xyes"
 667 then
 668   AC_DEFINE(OSFC2, [], [define if you have OSFC2 authentication])
 669 fi
 670
 671 if test "x$ac_cv_header_sia_h" = "xyes" && test "x$ac_cv_header_siad_h" = "xyes"
 672 then
 673   AC_DEFINE(OSFSIA, [], [define if you have OSFSIA authentication])
 674 fi
 675
 676 dnl Check for OpenSSL includes.
 677 OPENSSL_INCLUDE="-DNO_OPENSSL"
 678 if test "x$WITH_OPENSSL" = xyes; then
 679   if test "x$OPENSSL_LIBS" = "x"; then
 680     AC_MSG_NOTICE([skipping test for openssl/ssl.h])
 681   else
 682     old_CPPFLAGS=$CPPFLAGS
 683     if test "x$OPENSSL_INCLUDE_DIR" != "x"; then
 684         CPPFLAGS="$CPPFLAGS -I$OPENSSL_INCLUDE_DIR"
 685     fi
 686     dnl # stupid RedHat shit
 687     CPPFLAGS="$CPPFLAGS -DOPENSSL_NO_KRB5"
 688     AC_CHECK_HEADERS( \
 689         openssl/ssl.h \
 690         openssl/crypto.h \
 691         openssl/err.h \
 692         openssl/evp.h \
 693         openssl/md5.h \
 694         openssl/md4.h \
 695         openssl/sha.h \
 696         openssl/ocsp.h \
 697         openssl/engine.h,
 698         [],
 699         OPENSSL_LIBS=
 700     )
 701     if test "x$OPENSSL_LIBS" != "x"; then
 702         AC_MSG_CHECKING([for OpenSSL version >= 0.9.7])
 703         AC_EGREP_CPP(yes,
 704             [#include <openssl/crypto.h>
 705              #if (OPENSSL_VERSION_NUMBER >= 0x00907000L)
 706              yes
 707              #endif
 708             ], goodssl="yes")
 709         if test "x$goodssl" != "xyes"; then
 710             AC_MSG_RESULT(no)
 711             OPENSSL_LIBS=
 712         else
 713             AC_MSG_RESULT(yes)
 714             if test "x$OPENSSL_INCLUDE_DIR" != "x"; then
 715                 OPENSSL_INCLUDE="-I$OPENSSL_INCLUDE_DIR -DOPENSSL_NO_KRB5"
 716             else
 717                 OPENSSL_INCLUDE="-DOPENSSL_NO_KRB5"
 718             fi
 719         fi
 720     fi
 721     CPPFLAGS=$old_CPPFLAGS
 722   fi
 723 fi
 724 AC_SUBST(OPENSSL_INCLUDE)
 725 AC_SUBST(OPENSSL_LIBS)
 726 export OPENSSL_LIBS
 727
 728 dnl Check the pcap includes for the RADIUS sniffer.
 729 if test "x$PCAP_LIBS" = x; then
 730     AC_MSG_NOTICE([skipping test for pcap.h.])
 731 else
 732     AC_CHECK_HEADER(pcap.h,
 733         AC_DEFINE(HAVE_PCAP_H, 1,
 734                 [Define to 1 if you have the <pcap.h> header file.]),
 735         [ PCAP_LIBS=
 736         AC_MSG_WARN([pcap.h not found, silently disabling the RADIUS sniffer.])
 737         ])
 738
 739     AC_CHECK_LIB(pcap, pcap_fopen_offline,
 740         [ AC_DEFINE(HAVE_PCAP_FOPEN_OFFLINE, 1,
 741                 [Define to 1 if you have the function pcap_fopen_offline.])
 742         ])
 743     AC_CHECK_LIB(pcap, pcap_dump_fopen,
 744         [ AC_DEFINE(HAVE_PCAP_DUMP_FOPEN, 1,
 745                 [Define to 1 if you have the function pcap_dump_fopen.])
 746         ])
 747 fi
 748 AC_SUBST(PCAP_LIBS)
 749
 750 dnl #############################################################
 751 dnl #
 752 dnl #  4. Checks for typedefs
 753 dnl #
 754 dnl #############################################################
 755
 756 dnl #
 757 dnl # Ensure that these are defined
 758 dnl #
 759 AC_TYPE_OFF_T
 760 AC_TYPE_PID_T
 761 AC_TYPE_SIZE_T
 762 AC_TYPE_UID_T
 763
 764 dnl check for socklen_t
 765 FR_CHECK_TYPE_INCLUDE([
 766 #ifdef HAVE_SYS_TYPES_H
 767 #include <sys/types.h>
 768 #endif
 769 #ifdef HAVE_SYS_SOCKET_H
 770 #include <sys/socket.h>
 771 #endif
 772 ],socklen_t, int, [socklen_t is generally 'int' on systems which don't use it])
 773
 774 dnl check for uint8_t
 775 FR_CHECK_TYPE_INCLUDE([
 776 #ifdef HAVE_INTTYPES_H
 777 #include <inttypes.h>
 778 #endif
 779 #ifdef HAVE_STDINT_H
 780 #include <stdint.h>
 781 #endif
 782 ],uint8_t, unsigned char, [uint8_t should be the canonical 'octet' for network traffic])
 783
 784 dnl check for uint16_t
 785 FR_CHECK_TYPE_INCLUDE([
 786 #ifdef HAVE_INTTYPES_H
 787 #include <inttypes.h>
 788 #endif
 789 #ifdef HAVE_STDINT_H
 790 #include <stdint.h>
 791 #endif
 792 ],uint16_t, unsigned short, [uint16_t should be the canonical '2 octets' for network traffic])
 793
 794 dnl check for uint32_t
 795 FR_CHECK_TYPE_INCLUDE([
 796 #ifdef HAVE_INTTYPES_H
 797 #include <inttypes.h>
 798 #endif
 799 #ifdef HAVE_STDINT_H
 800 #include <stdint.h>
 801 #endif
 802 ],uint32_t, unsigned int, [uint32_t should be the canonical 'network integer])
 803
 804 AC_CHECK_TYPE(struct in6_addr, AC_DEFINE(HAVE_STRUCT_IN6_ADDR, 1, [IPv6 address structure]), [], [
 805 #ifdef HAVE_NETINET_IN_H
 806 #include <netinet/in.h>
 807 #endif
 808 ])
 809
 810 AC_CHECK_TYPE(struct sockaddr_storage, AC_DEFINE(HAVE_STRUCT_SOCKADDR_STORAGE, 1, [Generic socket addresses]), [], [
 811 #ifdef HAVE_NETINET_IN_H
 812 #include <netinet/in.h>
 813 #endif
 814 #ifdef HAVE_SYS_SOCKET_H
 815 #include <sys/socket.h>
 816 #endif
 817 ])
 818
 819 AC_CHECK_TYPE(struct sockaddr_in6, AC_DEFINE(HAVE_STRUCT_SOCKADDR_IN6, 1, [IPv6 socket addresses]), [], [
 820 #ifdef HAVE_NETINET_IN_H
 821 #include <netinet/in.h>
 822 #endif
 823 ])
 824
 825 AC_CHECK_TYPE(struct addrinfo, AC_DEFINE(HAVE_STRUCT_ADDRINFO, 1, [Generic DNS lookups]), [], [
 826 #ifdef HAVE_SYS_TYPES_H
 827 #include <sys/types.h>
 828 #endif
 829 #ifdef HAVE_SYS_SOCKET_H
 830 #include <sys/socket.h>
 831 #endif
 832 #ifdef HAVE_NETDB_H
 833 #include <netdb.h>
 834 #endif
 835 ])
 836
 837 dnl #############################################################
 838 dnl #
 839 dnl #  5. Checks for structures and functions
 840 dnl #
 841 dnl #############################################################
 842 AC_CHECK_FUNCS( \
 843         getopt_long \
 844         lockf \
 845         strsignal \
 846         sigaction \
 847         sigprocmask \
 848         pthread_sigmask \
 849         snprintf \
 850         vsnprintf \
 851         setsid \
 852         strncasecmp \
 853         strcasecmp \
 854         localtime_r \
 855         ctime_r \
 856         gmtime_r \
 857         strsep \
 858         inet_aton \
 859         inet_pton \
 860         inet_ntop \
 861         setlinebuf \
 862         setvbuf \
 863         getusershell \
 864         initgroups \
 865         getaddrinfo \
 866         getnameinfo \
 867         closefrom \
 868         gettimeofday \
 869         getpeereid \
 870         setuid \
 871         setresuid \
 872         getresuid \
 873         strlcat \
 874         strlcpy
 875 )
 876 RADIUSD_NEED_DECLARATIONS( \
 877         crypt \
 878         strncasecmp \
 879         strcasecmp \
 880         inet_aton \
 881         setlinebuf \
 882         getusershell \
 883         endusershell
 884 )
 885
 886 AC_TYPE_SIGNAL
 887
 888 dnl # check if we have utmpx.h
 889 dnl # if so, check if struct utmpx has entry ut_xtime
 890 dnl # if not, set it to define ut_xtime == ut_tv.tv_sec
 891 if test "x$ac_cv_header_utmpx_h" = "xyes"
 892 then
 893  FR_CHECK_STRUCT_HAS_MEMBER([#include <utmpx.h>], [struct utmpx], ut_xtime)
 894  if test "x$ac_cv_type_struct_utmpx_has_ut_xtime" = "x"
 895  then
 896    AC_DEFINE(ut_xtime,ut_tv.tv_sec, [define to something if you don't have ut_xtime in struct utmpx])
 897  fi
 898 fi
 899
 900 dnl # struct ip_pktinfo
 901 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in_pktinfo], ipi_addr)
 902 if test "x$ac_cv_type_struct_in_pktinfo_has_ipi_addr" = "xyes"
 903 then
 904         AC_DEFINE(HAVE_IP_PKTINFO, [], [define if you have IP_PKTINFO (Linux)])
 905 fi
 906
 907 dnl # struct in6_pktinfo
 908 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in6_pktinfo], ipi6_addr)
 909 if test "x$ac_cv_type_struct_in6_pktinfo_has_ipi6_addr" = "xyes"
 910 then
 911         AC_DEFINE(HAVE_IN6_PKTINFO, [], [define if you have IN6_PKTINFO (Linux)])
 912 fi
 913
 914 dnl #############################################################
 915 dnl #
 916 dnl #  6. Checks for compiler characteristics
 917 dnl #
 918 dnl #############################################################
 919
 920 dnl #
 921 dnl # Ensure that these are defined
 922 dnl #
 923 AC_C_CONST
 924
 925 dnl #
 926 dnl # See if this is OS/2
 927 dnl #
 928 AC_MSG_CHECKING(type of OS)
 929 OS=`uname -s`
 930 AC_MSG_RESULT($OS)
 931 if test "$OS" = "OS/2"; then
 932         LIBPREFIX=
 933 else
 934         LIBPREFIX=lib
 935 fi
 936 AC_SUBST(LIBPREFIX)
 937
 938 AC_MSG_CHECKING(for developer gcc flags)
 939 if test "x$developer" = "xyes" -a "x$GCC" = "xyes"; then
 940   devflags="-g -Wshadow -Wpointer-arith -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -W -Wredundant-decls -Wundef -Wformat-y2k -Wno-format-extra-args -Wno-format-zero-length  -Wformat-nonliteral -Wformat-security -Wformat=2"
 941   CFLAGS="$CFLAGS $devflags"
 942   INSTALLSTRIP=""
 943   AC_MSG_RESULT(yes.  Using $devflags)
 944 else
 945   devflags=""
 946   CFLAGS="$CFLAGS -DNDEBUG"
 947   INSTALLSTRIP=""
 948   AC_MSG_RESULT(no.)
 949 fi
 950
 951 FR_TLS
 952
 953 dnl #############################################################
 954 dnl #
 955 dnl #  7. Checks for library functions
 956 dnl #
 957 dnl #############################################################
 958
 959 old_LIBS="$LIBS"
 960 LIBS="$LIBS $LIBLTDL"
 961 AC_CHECK_FUNC(lt_dladvise_init, AC_DEFINE(HAVE_LT_DLADVISE_INIT, [], [Do we have the lt_dladvise_init function]))
 962 LIBS="$old_LIBS"
 963
 964 dnl Check for libcrypt
 965 dnl We use crypt(3) which may be in libc, or in libcrypt (eg FreeBSD)
 966 AC_CHECK_LIB(crypt, crypt,
 967   CRYPTLIB="-lcrypt"
 968 )
 969 if test "$CRYPTLIB" != ""; then
 970   AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function])
 971 else
 972   AC_CHECK_FUNC(crypt, AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function]))
 973 fi
 974
 975 dnl Check for libcipher
 976 AC_CHECK_LIB(cipher, setkey,
 977    CRYPTLIB="${CRYPTLIB} -lcipher"
 978 )
 979 AC_SUBST(CRYPTLIB)
 980
 981 dnl Check the style of gethostbyaddr, in order of preference
 982 dnl GNU (_r eight args)
 983 AC_DEFINE(GNUSTYLE, [1], [GNU-Style get*byaddr_r])
 984 dnl SYSV (_r six args)
 985 AC_DEFINE(SYSVSTYLE, [2], [SYSV-Style get*byaddr_r])
 986 dnl BSD (three args, may not be thread safe)
 987 AC_DEFINE(BSDSTYLE, [3], [BSD-Style get*byaddr_r])
 988 dnl Tru64 has BSD version, but it is thread safe
 989 dnl     http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1739____.HTM
 990 dnl We need #stdio.h to define NULL on FreeBSD (at least)
 991 gethostbyaddrrstyle=""
 992 AC_MSG_CHECKING([gethostbyaddr_r() syntax])
 993 case "$host" in
 994 *-freebsd*)
 995 dnl With FreeBSD, check if there's a prototype for gethostbyaddr_r.
 996 dnl Some versions (FreeBSD 5.1?) have a symbol but no prototype - so we
 997 dnl override this test to BSDSTYLE. FreeBSD 6.2 and up have proper GNU
 998 dnl style support.
 999         AC_CHECK_DECLS([gethostbyaddr_r], [], [
1000                 AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE,
1001                         [style of gethostbyaddr_r functions ])
1002                 gethostbyaddrrstyle=BSD
1003                 AC_MSG_WARN([FreeBSD overridden to BSD-style])
1004         ], [
1005 #ifdef HAVE_NETDB_H
1006 #include <netdb.h>
1007 #endif
1008 ])
1009         ;;
1010 esac
1011 if test "x$gethostbyaddrrstyle" = "x"; then
1012         AC_TRY_LINK([
1013 #include <stdio.h>
1014 #include <netdb.h>
1015 ], [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL, NULL) ], [
1016         AC_DEFINE(GETHOSTBYADDRRSTYLE, GNUSTYLE, [style of gethostbyaddr_r functions ])
1017         gethostbyaddrrstyle=GNU
1018 ])
1019 fi
1020 if test "x$gethostbyaddrrstyle" = "x"; then
1021         AC_TRY_LINK([
1022 #include <stdio.h>
1023 #include <netdb.h>
1024 ], [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL) ] , [
1025                 AC_DEFINE(GETHOSTBYADDRRSTYLE, SYSVSTYLE, [style of gethostbyaddr_r functions ])
1026                 gethostbyaddrrstyle=SYSV
1027         ])
1028 fi
1029 if test "x$gethostbyaddrrstyle" = "x"; then
1030         AC_TRY_LINK([
1031 #include <stdio.h>
1032 #include <netdb.h>
1033 ], [ gethostbyaddr(NULL, 0, 0)  ], [
1034                 AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE, [style of gethostbyaddr_r functions ])
1035                 gethostbyaddrrstyle=BSD
1036         ])
1037 fi
1038
1039 if test "x$gethostbyaddrrstyle" = "x"; then
1040         AC_MSG_RESULT([none!  It must not exist, here.])
1041 else
1042         AC_MSG_RESULT([${gethostbyaddrrstyle}-style])
1043 fi
1044
1045 if test "x$gethostbyaddrrstyle" = "xBSD"; then
1046         AC_MSG_WARN([ ****** BSD-style gethostbyaddr might NOT be thread-safe! ****** ])
1047 fi
1048
1049 dnl Check the style of gethostbyname, in order of preference
1050 dnl GNU (_r seven args)
1051 dnl SYSV (_r five args)
1052 dnl BSD (two args, may not be thread safe)
1053 dnl Tru64 has BSD version, but it _is_ thread safe
1054 dnl     http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1946____.HTM
1055 dnl We need #stdio.h to define NULL on FreeBSD (at least)
1056 gethostbynamerstyle=""
1057 AC_MSG_CHECKING([gethostbyname_r() syntax])
1058 AC_TRY_LINK([
1059 #include <stdio.h>
1060 #include <netdb.h>
1061 ], [ gethostbyname_r(NULL, NULL, NULL, 0, NULL, NULL) ], [
1062         AC_DEFINE(GETHOSTBYNAMERSTYLE, GNUSTYLE, [style of gethostbyname_r functions ])
1063         gethostbynamerstyle=GNU
1064 ])
1065 if test "x$gethostbynamerstyle" = "x"; then
1066         AC_TRY_LINK([
1067 #include <stdio.h>
1068 #include <netdb.h>
1069 ], [ gethostbyname_r(NULL, NULL, NULL, 0, NULL) ] , [
1070                 AC_DEFINE(GETHOSTBYNAMERSTYLE, SYSVSTYLE, [style of gethostbyname_r functions ])
1071                 gethostbynamerstyle=SYSV
1072         ])
1073 fi
1074 if test "x$gethostbynamerstyle" = "x"; then
1075         AC_TRY_LINK([
1076 #include <stdio.h>
1077 #include <netdb.h>
1078 ], [ gethostbyname(NULL)  ], [
1079                 AC_DEFINE(GETHOSTBYNAMERSTYLE, BSDSTYLE, [style of gethostbyname_r functions ])
1080                 gethostbynamerstyle=BSD
1081         ])
1082 fi
1083
1084 if test "x$gethostbynamerstyle" = "x"; then
1085         AC_MSG_RESULT([none!  It must not exist, here.])
1086 else
1087         AC_MSG_RESULT([${gethostbynamerstyle}-style])
1088 fi
1089
1090 if test "x$gethostbynamerstyle" = "xBSD"; then
1091         AC_MSG_WARN([ ****** BSD-style gethostbyname might NOT be thread-safe! ****** ])
1092 fi
1093
1094 dnl check for non-posix solaris ctime_r (extra buflen int arg)
1095 AC_DEFINE(POSIXSTYLE, [1], [Posix-Style ctime_r])
1096 AC_DEFINE(SOLARISSTYLE, [2], [Solaris-Style ctime_r])
1097 ctimerstyle=""
1098 AC_MSG_CHECKING([ctime_r() syntax])
1099 AC_TRY_LINK([
1100 #include <time.h>
1101 ], [ ctime_r(NULL, NULL, 0) ], [
1102         AC_DEFINE(CTIMERSTYLE, SOLARISSTYLE, [style of ctime_r function])
1103         ctimerstyle="SOLARIS"
1104 ])
1105 if test "x$ctimerstyle" = "x"; then
1106         AC_TRY_LINK([
1107 #include <time.h>
1108 ], [ ctime_r(NULL, NULL) ], [
1109                 AC_DEFINE(CTIMERSTYLE, POSIXSTYLE, [style of ctime_r function])
1110                 ctimerstyle="POSIX"
1111         ])
1112 fi
1113
1114 if test "x$ctimerstyle" = "x"; then
1115         AC_MSG_RESULT([none!  It must not exist, here.])
1116 else
1117         AC_MSG_RESULT([${ctimerstyle}-style])
1118 fi
1119
1120 AC_SUBST(HOSTINFO, $host)
1121
1122 dnl #############################################################
1123 dnl #
1124 dnl #  8. Checks for system services
1125 dnl #
1126 dnl #############################################################
1127
1128 dnl #
1129 dnl # Figure out where libtool is located,
1130 dnl #
1131 top_builddir=`pwd`
1132 export top_builddir
1133 AC_MSG_RESULT([top_builddir=$top_builddir])
1134 dnl # AC_SUBST(top_builddir)
1135 AC_SUBST(LIBLTDL)
1136 AC_SUBST(INCLTDL)
1137
1138 dnl import libtool stuff
1139
1140 dnl #############################################################
1141 dnl #
1142 dnl #  Configure in any module directories.
1143 dnl #
1144 dnl #############################################################
1145
1146 mysubdirs=""
1147 if test "x$EXPERIMENTAL" = "xyes"; then
1148   bar=`ls -1 "${srcdir}"/src/modules/rlm_*/configure | sed 's%/configure%%'`
1149   dnl # get rid of LF's.
1150   mysubdirs=`echo $mysubdirs $bar`
1151 else
1152   dnl #
1153   dnl # Find 'configure' in ONLY the stable modules
1154   dnl #
1155   for bar in `cat "${srcdir}"/src/modules/stable`; do
1156     if test -f "${srcdir}"/src/modules/$bar/configure; then
1157       mysubdirs="$mysubdirs src/modules/$bar"
1158     fi
1159   done
1160 fi
1161
1162 dnl ############################################################
1163 dnl # make modules by list
1164 dnl #############################################################
1165 if test "x$EXPERIMENTAL" = "xyes"; then
1166   for foo in `ls -1 "${srcdir}"/src/modules | grep rlm_`; do
1167     MODULES="$MODULES $foo"
1168   done
1169 else
1170    dnl #
1171    dnl # make ONLY the stable modules
1172    dnl #
1173    for foo in `cat "${srcdir}"/src/modules/stable`; do
1174     MODULES="$MODULES $foo"
1175    done
1176 fi
1177
1178 dnl #
1179 dnl #  Don't change the variable name here.  Autoconf goes bonkers
1180 dnl #  if you do.
1181 dnl #
1182 AC_CONFIG_SUBDIRS($mysubdirs)
1183 AC_SUBST(MODULES)
1184
1185 dnl #############################################################
1186 dnl #
1187 dnl #  And finally, output the results.
1188 dnl #
1189 dnl #############################################################
1190
1191 AC_CONFIG_COMMANDS([stamp-h], [echo timestamp > src/include/stamp-h])
1192 AC_CONFIG_COMMANDS([build-radpaths-h], [(cd ./src/include && /bin/sh ./build-radpaths-h)])
1193 AC_CONFIG_COMMANDS([main-chmod], [(cd ./src/main   && chmod +x checkrad.pl radlast radtest)])
1194 AC_CONFIG_COMMANDS([scripts-chmod], [(cd ./scripts    && chmod +x rc.radiusd radiusd.cron.daily radiusd.cron.monthly cryptpasswd)])
1195
1196 dnl #
1197 dnl #  Substitute whatever libraries we found to be necessary
1198 dnl #
1199 AC_SUBST(LIBS)
1200 AC_SUBST(INSTALLSTRIP)
1201
1202 USE_SHARED_LIBS=$enable_shared
1203 AC_SUBST(USE_SHARED_LIBS)
1204 USE_STATIC_LIBS=$enable_static
1205 AC_SUBST(USE_STATIC_LIBS)
1206 AC_SUBST(STATIC_MODULES)
1207 AC_SUBST(RADIUSD_MAJOR_VERSION)
1208 AC_SUBST(RADIUSD_MINOR_VERSION)
1209 AC_SUBST(RADIUSD_VERSION)
1210
1211 AC_OUTPUT(\
1212         ./Make.inc \
1213         ./src/include/build-radpaths-h \
1214         ./src/main/Makefile \
1215         ./src/main/radsniff.mk \
1216         ./src/main/checkrad.pl \
1217         ./src/main/radlast \
1218         ./src/main/radtest \
1219         ./scripts/rc.radiusd \
1220         ./scripts/radiusd.cron.daily \
1221         ./scripts/radiusd.cron.monthly \
1222         ./scripts/cryptpasswd \
1223         ./raddb/dictionary \
1224         ./raddb/radrelay.conf \
1225         ./raddb/radiusd.conf
1226 )