configure.in

   1 dnl #############################################################
   2 dnl #
   3 dnl #  For information about autoconf, see:
   4 dnl #
   5 dnl #  http://www.gnu.org/software/autoconf/
   6 dnl #
   7 dnl #  The recommended order is:
   8 dnl #
   9 dnl #  AC_INIT(file)
  10 dnl #  0. checks for compiler, libtool, and command line options
  11 dnl #  1. checks for programs
  12 dnl #  2. checks for libraries
  13 dnl #  3. checks for header files
  14 dnl #  4. checks for typedefs
  15 dnl #  5. checks for structures and functions
  16 dnl #  6. checks for compiler characteristics
  17 dnl #  7. checks for library functions
  18 dnl #  8. checks for system services
  19 dnl #  AC_OUTPUT([file...])
  20 dnl #
  21 dnl #############################################################
  22
  23 AC_PREREQ([2.59])
  24 export CFLAGS LIBS LDFLAGS CPPFLAGS
  25 AC_INIT(src/main/radiusd.c)
  26 AC_CONFIG_HEADER(src/include/autoconf.h)
  27 AC_REVISION($Revision$)dnl
  28
  29 dnl # The version of the software
  30 RADIUSD_MAJOR_VERSION=2
  31 RADIUSD_MINOR_VERSION=0.0-pre2
  32 RADIUSD_VERSION="${RADIUSD_MAJOR_VERSION}.${RADIUSD_MINOR_VERSION}"
  33 PACKAGE=freeradius
  34
  35 dnl #############################################################
  36 dnl #
  37 dnl #  0. Checks for compiler, libtool, and command line options.
  38 dnl #
  39 dnl #############################################################
  40
  41 dnl Check for GNU cc
  42 AC_PROG_CC
  43 AC_PROG_CXX
  44
  45 dnl #
  46 dnl # check for AIX, to allow us to use some BSD functions
  47 dnl # must be before macros that call the compiler.
  48 dnl #
  49 AC_AIX
  50
  51 AC_PROG_GCC_TRADITIONAL
  52 AC_PROG_CC_SUNPRO
  53 AC_PROG_RANLIB
  54
  55 dnl Compile in large (2G+) file support.
  56 AC_SYS_LARGEFILE
  57
  58 dnl # check for system bytesex
  59 dnl # AC_DEFINES WORDS_BIGENDIAN
  60 AC_C_BIGENDIAN
  61
  62 dnl Find GNU Make.
  63 AC_CHECK_PROG(GMAKE, gmake, yes, no)
  64 if test $GMAKE = no; then
  65   AC_PATH_PROG(MAKE, make, /usr/local/bin/make)
  66 else
  67   AC_PATH_PROG(MAKE, gmake, /usr/local/gnu/bin/make)
  68 fi
  69 makever=`$ac_cv_path_MAKE --version 2>&1 | grep "GNU Make"`
  70 if test -z "$makever"; then
  71   AC_MSG_ERROR(GNU Make is not installed.  Please download and install it
  72                 from ftp://prep.ai.mit.edu/pub/gnu/make/ before continuing.)
  73 fi
  74
  75 dnl libltdl is installable
  76 AC_LIBLTDL_INSTALLABLE
  77
  78 dnl tell Makefile to build ltdl if needed
  79 if test x"$enable_ltdl_install" = x"yes"; then
  80   LTDL_SUBDIRS=libltdl
  81 fi
  82 AC_SUBST(LTDL_SUBDIRS)
  83
  84 dnl use system-wide libtool, if it exists
  85 AC_ARG_WITH(system-libtool,
  86 [  --with-system-libtool              try to use libtool installed in your system [default=use our own]],
  87 [ AC_PATH_PROG(LIBTOOL, libtool,,$PATH:/usr/local/bin) ],
  88 [
  89   LIBTOOL="`pwd`/libtool"
  90   AC_SUBST(LIBTOOL)
  91   dnl ensure that we're looking for dlopen
  92   AC_LIBTOOL_DLOPEN
  93
  94   dnl Figure out how to build shared libraries
  95   AC_PROG_LIBTOOL
  96 ])
  97
  98
  99 dnl Put this in later, when all distributed modules use autoconf.
 100 dnl AC_ARG_WITH(disablemodulefoo,
 101 dnl [  --without-rlm_foo       Disables module compilation.  Module list:]
 102 dnl esyscmd([find src/modules -type d -name rlm_\* -print |\
 103 dnl     sed -e 's%src/modules/.*/% (sub)- %; s%.*/%- %' |\
 104 dnl     awk '{print "                            "$0}']))
 105
 106 AC_ARG_ENABLE(strict-dependencies,
 107 [  --enable-strict-dependencies  Fail configure on lack of module dependancy.])
 108
 109 dnl extra argument: --with-docdir
 110 docdir='${datadir}/doc/freeradius'
 111 AC_MSG_CHECKING(docdir)
 112 AC_ARG_WITH(docdir,
 113 [  --with-docdir=DIR       Directory for documentation [DATADIR/doc/freeradius] ],
 114 [ case "$withval" in
 115     no)
 116         docdir=no
 117         ;;
 118     yes)
 119         ;;
 120     [[\\/$]]* | ?:[[\\/]]* )
 121         docdir="$withval"
 122         ;;
 123     *)
 124         AC_MSG_ERROR([expected an absolute directory name for --with-docdir: $withval])
 125         ;;
 126   esac ]
 127 )
 128 AC_SUBST(docdir)
 129 AC_MSG_RESULT($docdir)
 130 if test "x$docdir" = xno; then
 131         AC_MSG_WARN(Documentation files will NOT be installed.)
 132 fi
 133
 134 dnl extra argument: --with-logdir
 135 logdir='${localstatedir}/log/radius'
 136 AC_MSG_CHECKING(logdir)
 137 AC_ARG_WITH(logdir,
 138 [  --with-logdir=DIR       Directory for logfiles [LOCALSTATEDIR/log/radius] ],
 139 [ case "$withval" in
 140     no)
 141         AC_MSG_ERROR(Need logdir)
 142         ;;
 143     yes)
 144         ;;
 145     [[\\/$]]* | ?:[[\\/]]* )
 146         logdir="$withval"
 147         ;;
 148     *)
 149         AC_MSG_ERROR([expected an absolute directory name for --with-logdir: $withval])
 150         ;;
 151   esac ]
 152 )
 153 AC_SUBST(logdir)
 154 AC_MSG_RESULT($logdir)
 155
 156 dnl extra argument: --with-radacctdir
 157 radacctdir='${logdir}/radacct'
 158 AC_MSG_CHECKING(radacctdir)
 159 AC_ARG_WITH(radacctdir,
 160 [  --with-radacctdir=DIR   Directory for detail files [LOGDIR/radacct] ],
 161 [ case "$withval" in
 162     no)
 163         AC_MSG_ERROR(Need radacctdir)
 164         ;;
 165     yes)
 166         ;;
 167     [[\\/$]]* | ?:[[\\/]]* )
 168         radacctdir="$withval"
 169         ;;
 170     *)
 171         AC_MSG_ERROR([expected an absolute directory name for --with-radacctdir: $withval])
 172         ;;
 173   esac ]
 174 )
 175 AC_SUBST(radacctdir)
 176 AC_MSG_RESULT($radacctdir)
 177
 178 dnl extra argument: --with-raddbdir
 179 raddbdir='${sysconfdir}/raddb'
 180 AC_MSG_CHECKING(raddbdir)
 181 AC_ARG_WITH(raddbdir,
 182 [  --with-raddbdir=DIR     Directory for config files [SYSCONFDIR/raddb] ],
 183 [ case "$withval" in
 184     no)
 185         AC_MSG_ERROR(Need raddbdir)
 186         ;;
 187     yes)
 188         ;;
 189     [[\\/$]]* | ?:[[\\/]]* )
 190         raddbdir="$withval"
 191         ;;
 192     *)
 193         AC_MSG_ERROR([expected an absolute directory name for --with-raddbdir: $withval])
 194         ;;
 195   esac ]
 196 )
 197 AC_SUBST(raddbdir)
 198 AC_MSG_RESULT($raddbdir)
 199
 200 dnl extra argument: --with-ascend-binary
 201 ASCEND_BINARY=yes
 202 AC_ARG_WITH(ascend-binary,
 203 [  --with-ascend-binary    Include support for Ascend binary filter attributes (default=yes)],
 204 [ case "$withval" in
 205     yes)
 206         ;;
 207     *)
 208         ASCEND_BINARY=""
 209   esac ]
 210 )
 211 if test "X$ASCEND_BINARY" = "Xyes"; then
 212   AC_DEFINE(ASCEND_BINARY, [], [Include support for Ascend binary filter attributes])
 213 fi
 214
 215 dnl extra argument: --with-threads
 216 WITH_THREADS=yes
 217 AC_ARG_WITH(threads,
 218 [  --with-threads          Use threads, if available.  (default=yes) ],
 219 [ case "$withval" in
 220     yes)
 221         ;;
 222     *)
 223         WITH_THREADS=""
 224   esac ]
 225 )
 226
 227 dnl extra argument: --with-snmp
 228 WITH_SNMP=yes
 229 AC_ARG_WITH(snmp,
 230 [  --with-snmp             Compile in SNMP support. (default=yes)],
 231 [ case "$withval" in
 232     yes)
 233         ;;
 234     *)
 235         WITH_SNMP=no
 236   esac ]
 237 )
 238
 239 dnl #
 240 dnl # extra argument: --with-snmp-include-dir
 241 dnl #
 242 AC_ARG_WITH(snmp-include-dir,
 243 [  --with-snmp-include-dir=DIR  Directory to look for include files used by SNMP],
 244 [ case "$withval" in
 245     *)
 246         ;;
 247   esac ]
 248 )
 249
 250 dnl extra argument: --with-vmps
 251 WITH_VMPS=yes
 252 AC_ARG_WITH(vmps,
 253 [  --with-vmps             Compile in VMPS support. (default=yes)],
 254 [ case "$withval" in
 255     yes)
 256         ;;
 257     *)
 258         WITH_VMPS=no
 259   esac ]
 260 )
 261 if test "x$WITH_VMPS" = "xyes"; then
 262         AC_DEFINE(WITH_VMPS, [], [define if you want VMPS support])
 263 fi
 264
 265
 266 dnl #
 267 dnl #  Allow the user to specify a list of modules to be linked
 268 dnl #  statically to the server.
 269 dnl #
 270 STATIC_MODULES=
 271 AC_ARG_WITH(static_modules,
 272 [  --with-static-modules=QUOTED-MODULE-LIST],[
 273   for i in $withval; do
 274     STATIC_MODULES="$STATIC_MODULES -dlpreopen ../modules/rlm_$i/rlm_$i.la"
 275   done
 276 ])
 277
 278 MODULES=
 279 AC_ARG_WITH(modules,
 280 [ --with-modules=QUOTED-MODULE-LIST],[
 281  for i in $withval; do
 282    MODULES="$MODULES $i"
 283  done
 284 ])
 285
 286 dnl #
 287 dnl #  Enable developer C compiler warnings
 288 dnl #
 289 AC_ARG_ENABLE(developer,
 290 [  --enable-developer               Enables features of interest to developers.],
 291 [ case "$enableval" in
 292     no)
 293         developer=no
 294         ;;
 295     *)
 296         developer=yes
 297   esac ]
 298 )
 299
 300 if test "x$developer" != "xno" -a -d $srcdir/CVS; then
 301   dnl turn on the developer flag when taken from a CVS checkout (not a release)
 302   developer="yes"
 303 fi
 304
 305 dnl extra argument: --with-experimental-modules
 306 EXPERIMENTAL=
 307 AC_ARG_WITH(experimental-modules,
 308 [  --with-experimental-modules      Use experimental and unstable modules. (default=no) ],
 309 [ case "$withval" in
 310     yes)
 311         EXPERIMENTAL=yes
 312         ;;
 313     *)
 314   esac ]
 315 )
 316
 317 dnl extra argument: --with-openssl
 318 WITH_OPENSSL=yes
 319 AC_ARG_WITH(openssl,
 320 [  --with-openssl                   Use OpenSSL. (default=yes)],
 321 [ case "$withval" in
 322     no)
 323         WITH_OPENSSL=no
 324         ;;
 325     *)
 326         WITH_OPENSSL=yes
 327         ;;
 328   esac ]
 329 )
 330
 331 dnl #
 332 dnl # extra argument: --with-openssl-includes=dir
 333 dnl #
 334 OPENSSL_INCLUDE_DIR=
 335 AC_ARG_WITH(openssl-includes,
 336 [  --with-openssl-includes=DIR      Directory to look for OpenSSL include files],
 337 [ case "$withval" in
 338     *) OPENSSL_INCLUDE_DIR="$withval"
 339         ;;
 340   esac ]
 341 )
 342
 343 dnl #
 344 dnl # extra argument: --with-openssl-libraries=dir
 345 dnl #
 346 OPENSSL_LIB_DIR=
 347 AC_ARG_WITH(openssl-libraries,
 348 [  --with-openssl-libraries=DIR     Directory to look for OpenSSL library files],
 349 [ case "$withval" in
 350     *) OPENSSL_LIB_DIR="$withval"
 351         ;;
 352   esac ]
 353 )
 354
 355 dnl #
 356 dnl #  These next two arguments don't actually do anything.  They're
 357 dnl #  place holders so that the top-level configure script can tell
 358 dnl #  the user how to configure lower-level modules
 359 dnl #
 360
 361 dnl #
 362 dnl # extra argument: --with-rlm-FOO-lib-dir
 363 dnl #
 364 AC_ARG_WITH(rlm-FOO-lib-dir,
 365 [  --with-rlm-FOO-lib-dir=DIR       Directory to look for library files used by module FOO],
 366 [ case "$withval" in
 367     *)
 368         ;;
 369   esac ]
 370 )
 371
 372 dnl #
 373 dnl # extra argument: --with-rlm-FOO-include-dir
 374 dnl #
 375 AC_ARG_WITH(rlm-FOO-include-dir,
 376 [  --with-rlm-FOO-include-dir=DIR   Directory to look for include files used by module FOO],
 377 [ case "$withval" in
 378     *)
 379         ;;
 380   esac ]
 381 )
 382
 383 dnl See what include-style is used by the make program.
 384 dnl AC_MSG_CHECKING(include style for make)
 385 dnl echo "include /dev/null" > testmake.$$
 386 dnl echo "all:" >> testmake.$$
 387 dnl make -f testmake.$$ >/dev/null 2>&1
 388 dnl if test $? = 0
 389 dnl then
 390 dnl     INCLUDE=include
 391 dnl     IQUOTE=
 392 dnl else
 393 dnl     INCLUDE=.include
 394 dnl     IQUOTE='"'
 395 dnl fi
 396 dnl rm -f testmake.$$
 397 dnl AC_MSG_RESULT(" $INCLUDE")
 398 dnl AC_SUBST(INCLUDE)
 399 dnl AC_SUBST(IQUOTE)
 400
 401 dnl extra argument: --with-udpfromto
 402 WITH_UDPFROMTO=no
 403 AC_ARG_WITH(udpfromto,
 404 [  --with-udpfromto        Compile in UDPFROMTO support. (default=yes)],
 405 [ case "$withval" in
 406     yes)
 407         WITH_UDPFROMTO=yes
 408         ;;
 409     *)
 410         WITH_UDPFROMTO=no
 411   esac ]
 412 )
 413
 414 if test "x$WITH_UDPFROMTO" = "xyes"; then
 415         AC_DEFINE(WITH_UDPFROMTO, [], [define if you want udpfromto])
 416 fi
 417
 418 dnl #############################################################
 419 dnl #
 420 dnl #  1. Checks for programs
 421 dnl #
 422 dnl #############################################################
 423
 424 CHECKRAD=checkrad.pl
 425 AC_PATH_PROG(PERL, perl, /usr/local/bin/perl)
 426 if test "x$ac_cv_path_PERL" = "x"; then
 427   AC_MSG_WARN(perl not found - Simultaneous-Use and checkrad.pl may not work)
 428 fi
 429 AC_PATH_PROG(SNMPGET, snmpget)
 430 if test "x$ac_cv_path_SNMPGET" = "x"; then
 431   AC_MSG_WARN(snmpget not found - Simultaneous-Use and checkrad.pl may not work)
 432 fi
 433
 434 AC_PATH_PROG(SNMPWALK, snmpwalk)
 435 if test "x$ac_cv_path_SNMPWALK" = "x"; then
 436   AC_MSG_WARN(snmpwalk not found - Simultaneous-Use and checkrad.pl may not work)
 437 fi
 438
 439 AC_PATH_PROG(RUSERS, rusers, /usr/bin/rusers)
 440
 441 dnl FIXME This is truly gross.
 442 missing_dir=`cd $ac_aux_dir && pwd`
 443 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
 444 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
 445 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
 446
 447 AC_PATH_PROG(LOCATE,locate)
 448 AC_PATH_PROG(DIRNAME,dirname)
 449 AC_PATH_PROG(GREP,grep)
 450
 451 dnl #############################################################
 452 dnl #
 453 dnl #  2. Checks for libraries
 454 dnl #
 455 dnl #############################################################
 456
 457 dnl If using pthreads, check for -lpthread (posix) or -lc_r (*BSD)
 458 old_CFLAGS=$CFLAGS
 459 if test "x$WITH_THREADS" = "xyes"; then
 460   if test $ac_cv_prog_suncc = "yes"; then
 461     CFLAGS="$CFLAGS -mt"
 462   fi
 463
 464   AC_CHECK_HEADERS(pthread.h, [], [ WITH_THREADS="no" ])
 465
 466 dnl #
 467 dnl # pthread stuff is usually in -lpthread
 468 dnl # or in -lc_r, on *BSD
 469 dnl #
 470 dnl # On Some systems, we need extra pre-processor flags, to get them to
 471 dnl # to do the threading properly.
 472 dnl #
 473   AC_CHECK_LIB(pthread, pthread_create,
 474                 [ CFLAGS="$CFLAGS -D_REENTRANT -D_POSIX_PTHREAD_SEMANTICS"
 475                   LIBS="$LIBS -lpthread" ],
 476                 AC_CHECK_LIB(c_r, pthread_create,
 477                             [ CFLAGS="$CFLAGS -pthread -D_THREAD_SAFE" ],
 478                             [ WITH_THREADS="no" ]
 479                             )
 480                 )
 481 fi
 482
 483 dnl #
 484 dnl # If we have NO pthread libraries, remove any knowledge of threads.
 485 dnl #
 486 if test "x$WITH_THREADS" != "xyes"; then
 487   CFLAGS=$old_CFLAGS
 488   ac_cv_header_pthread_h="no"
 489   WITH_THREADS=no
 490 else
 491   dnl #
 492   dnl #  We need sem_init() and friends, as they're the friendliest
 493   dnl #  semaphore functions for threading.
 494   dnl #
 495   dnl # HP/UX requires linking with librt, too, to get the sem_* symbols.
 496   dnl # Some systems have them in -lsem
 497   dnl # Solaris has them in -lposix4
 498   dnl # NetBSD has them in -lsemaphore
 499
 500   AC_SEARCH_LIBS(sem_init, pthread sem posix4 rt semaphore,
 501         [],
 502         [AC_MSG_ERROR(-lsem not found.  You may want to download it from ftp://ftp.to.gd-es.com/pub/BSDI/libsem.tar.bz2 or ftp://ftp.freeradius.org/pub/radius/contrib/libsem.tar.gz)]
 503    )
 504 fi
 505
 506 dnl Check if we need -lsocket
 507 AC_CHECK_LIB(socket, getsockname)
 508
 509 dnl Check for -lresolv
 510 dnl This library may be needed later.
 511 AC_CHECK_LIB(resolv, inet_aton)
 512
 513 dnl Check if we need -lnsl. Usually if we want to
 514 dnl link against -lsocket we need to include -lnsl as well.
 515 AC_CHECK_LIB(nsl, inet_ntoa)
 516
 517 dnl Check for OpenSSL libraries.
 518 OPENSSL_LIBS=
 519 if test "x$WITH_OPENSSL" = xyes; then
 520   old_LIBS=$LIBS
 521   if test "x$OPENSSL_LIB_DIR" != "x"; then
 522     LIBS="-L$OPENSSL_LIB_DIR $LIBS"
 523   fi
 524   AC_CHECK_LIB(crypto, DH_new,
 525     [
 526         AC_DEFINE(HAVE_LIBCRYPTO, 1,
 527             [Define to 1 if you have the `crypto' library (-lcrypto).])
 528         AC_CHECK_LIB(ssl, SSL_new,
 529             [
 530                 AC_DEFINE(HAVE_LIBSSL, 1,
 531                     [Define to 1 if you have the `ssl' library (-lssl).])
 532                 if test "x$OPENSSL_LIB_DIR" != "x"; then
 533                     OPENSSL_LIBS="-L$OPENSSL_LIB_DIR"
 534                 fi
 535                 OPENSSL_LIBS="$OPENSSL_LIBS -lcrypto -lssl -lcrypto"
 536             ], [])
 537     ], [])
 538   LIBS=$old_LIBS
 539 fi
 540
 541 AC_CHECK_LIB(ws2_32, htonl)
 542
 543 dnl Check the pcap library for the RADIUS sniffer.
 544 PCAP_LIBS=
 545 AC_CHECK_LIB(pcap, pcap_open_live,
 546         [ PCAP_LIBS="-lpcap"
 547         AC_DEFINE(HAVE_LIBPCAP, 1,
 548                 [Define to 1 if you have the `pcap' library (-lpcap).])
 549         ],
 550         [ AC_MSG_WARN([pcap library not found, silently disabling the RADIUS sniffer.]) ])
 551
 552 dnl #############################################################
 553 dnl #
 554 dnl #  3. Checks for header files
 555 dnl #
 556 dnl #############################################################
 557
 558 dnl #
 559 dnl # Interix requires us to set -D_ALL_SOURCE, otherwise
 560 dnl # getopt will be #included, but won't link.  <sigh>
 561 dnl #
 562 dnl #
 563 case "$host" in
 564 *-interix*)
 565         CFLAGS="$CFLAGS -D_ALL_SOURCE"
 566         ;;
 567 *-darwin*)
 568         CFLAGS="$CFLAGS -DDARWIN"
 569         LIBS="-framework DirectoryService $LIBS"
 570         ;;
 571 esac
 572
 573 AC_HEADER_DIRENT
 574 AC_HEADER_STDC
 575 AC_HEADER_TIME
 576 AC_HEADER_SYS_WAIT
 577
 578 AC_CHECK_HEADERS( \
 579         unistd.h \
 580         crypt.h \
 581         errno.h \
 582         resource.h \
 583         sys/resource.h \
 584         getopt.h \
 585         malloc.h \
 586         utmp.h \
 587         utmpx.h \
 588         signal.h \
 589         sys/select.h \
 590         syslog.h \
 591         inttypes.h \
 592         stdint.h \
 593         stdio.h \
 594         netdb.h \
 595         semaphore.h \
 596         arpa/inet.h \
 597         netinet/in.h \
 598         sys/types.h \
 599         sys/socket.h \
 600         winsock.h \
 601         sys/time.h \
 602         sys/wait.h \
 603         sys/security.h \
 604         fcntl.h \
 605         sys/fcntl.h \
 606         prot.h \
 607         pwd.h \
 608         grp.h \
 609         sia.h \
 610         siad.h
 611 )
 612
 613 dnl FreeBSD requires sys/socket.h before net/if.h
 614 AC_CHECK_HEADERS(net/if.h, [], [],
 615 [#ifdef HAVE_SYS_SOCKET_H
 616 # include <sys/socket.h>
 617 # endif
 618 ])
 619
 620 REGEX=no
 621 AC_CHECK_HEADER(regex.h, AC_DEFINE(HAVE_REGEX_H, [], [define this if we have the <regex.h> header file]))
 622 if test "x$ac_cv_header_regex_h" = "xyes"; then
 623   REGEX_EXTENDED=no
 624   REGEX=yes
 625   AC_EGREP_CPP(yes,
 626     [#include <regex.h>
 627      #ifdef REG_EXTENDED
 628        yes
 629      #endif
 630      ], [AC_DEFINE(HAVE_REG_EXTENDED, [], [define this if we have REG_EXTENDED (from <regex.h>)]) REGEX_EXTENDED=yes])
 631 fi
 632 AC_SUBST(REGEX)
 633 AC_SUBST(REGEX_EXTENDED)
 634
 635 dnl #
 636 dnl #  other checks which require headers
 637 dnl #
 638 if test "x$ac_cv_header_sys_security_h" = "xyes" && test "x$ac_cv_header_prot_h" = "xyes"
 639 then
 640   AC_DEFINE(OSFC2, [], [define if you have OSFC2 authentication])
 641 fi
 642
 643 if test "x$ac_cv_header_sia_h" = "xyes" && test "x$ac_cv_header_siad_h" = "xyes"
 644 then
 645   AC_DEFINE(OSFSIA, [], [define if you have OSFSIA authentication])
 646 fi
 647
 648 dnl Check for OpenSSL includes.
 649 OPENSSL_INCLUDE="-DNO_OPENSSL"
 650 if test "x$WITH_OPENSSL" = xyes; then
 651   if test "x$OPENSSL_LIBS" = "x"; then
 652     AC_MSG_NOTICE([skipping test for openssl/ssl.h])
 653   else
 654     old_CPPFLAGS=$CPPFLAGS
 655     if test "x$OPENSSL_INCLUDE_DIR" != "x"; then
 656         CPPFLAGS="$CPPFLAGS -I$OPENSSL_INCLUDE_DIR"
 657     fi
 658     dnl # stupid RedHat shit
 659     CPPFLAGS="$CPPFLAGS -DOPENSSL_NO_KRB5"
 660     AC_CHECK_HEADERS( \
 661         openssl/ssl.h \
 662         openssl/crypto.h \
 663         openssl/err.h \
 664         openssl/engine.h,
 665         [],
 666         OPENSSL_LIBS=
 667     )
 668     if test "x$OPENSSL_LIBS" != "x"; then
 669         AC_MSG_CHECKING([for OpenSSL version >= 0.9.7])
 670         AC_EGREP_CPP(yes,
 671             [#include <openssl/crypto.h>
 672              #if (OPENSSL_VERSION_NUMBER >= 0x00907000L)
 673              yes
 674              #endif
 675             ], goodssl="yes")
 676         if test "x$goodssl" != "xyes"; then
 677             AC_MSG_RESULT(no)
 678             OPENSSL_LIBS=
 679         else
 680             AC_MSG_RESULT(yes)
 681             if test "x$OPENSSL_INCLUDE_DIR" != "x"; then
 682                 OPENSSL_INCLUDE="-I$OPENSSL_INCLUDE_DIR -DOPENSSL_NO_KRB5"
 683             else
 684                 OPENSSL_INCLUDE="-DOPENSSL_NO_KRB5"
 685             fi
 686         fi
 687     fi
 688     CPPFLAGS=$old_CPPFLAGS
 689   fi
 690 fi
 691 AC_SUBST(OPENSSL_INCLUDE)
 692 AC_SUBST(OPENSSL_LIBS)
 693 export OPENSSL_LIBS
 694
 695 dnl Check the pcap includes for the RADIUS sniffer.
 696 if test "x$PCAP_LIBS" = x; then
 697     AC_MSG_NOTICE([skipping test for pcap.h.])
 698 else
 699     AC_CHECK_HEADER(pcap.h,
 700         AC_DEFINE(HAVE_PCAP_H, 1,
 701                 [Define to 1 if you have the <pcap.h> header file.]),
 702         [ PCAP_LIBS=
 703         AC_MSG_WARN([pcap.h not found, silently disabling the RADIUS sniffer.])
 704         ])
 705 fi
 706 AC_SUBST(PCAP_LIBS)
 707
 708 dnl #############################################################
 709 dnl #
 710 dnl #  4. Checks for typedefs
 711 dnl #
 712 dnl #############################################################
 713
 714 dnl #
 715 dnl # Ensure that these are defined
 716 dnl #
 717 AC_TYPE_OFF_T
 718 AC_TYPE_PID_T
 719 AC_TYPE_SIZE_T
 720 AC_TYPE_UID_T
 721
 722 dnl check for socklen_t
 723 FR_CHECK_TYPE_INCLUDE([
 724 #ifdef HAVE_SYS_TYPES_H
 725 #include <sys/types.h>
 726 #endif
 727 #ifdef HAVE_SYS_SOCKET_H
 728 #include <sys/socket.h>
 729 #endif
 730 ],socklen_t, int, [socklen_t is generally 'int' on systems which don't use it])
 731
 732 dnl check for uint8_t
 733 FR_CHECK_TYPE_INCLUDE([
 734 #ifdef HAVE_INTTYPES_H
 735 #include <inttypes.h>
 736 #endif
 737 #ifdef HAVE_STDINT_H
 738 #include <stdint.h>
 739 #endif
 740 ],uint8_t, unsigned char, [uint8_t should be the canonical 'octet' for network traffic])
 741
 742 dnl check for uint16_t
 743 FR_CHECK_TYPE_INCLUDE([
 744 #ifdef HAVE_INTTYPES_H
 745 #include <inttypes.h>
 746 #endif
 747 #ifdef HAVE_STDINT_H
 748 #include <stdint.h>
 749 #endif
 750 ],uint16_t, unsigned short, [uint16_t should be the canonical '2 octets' for network traffic])
 751
 752 dnl check for uint32_t
 753 FR_CHECK_TYPE_INCLUDE([
 754 #ifdef HAVE_INTTYPES_H
 755 #include <inttypes.h>
 756 #endif
 757 #ifdef HAVE_STDINT_H
 758 #include <stdint.h>
 759 #endif
 760 ],uint32_t, unsigned int, [uint32_t should be the canonical 'network integer])
 761
 762 AC_CHECK_TYPE(struct in6_addr, AC_DEFINE(HAVE_STRUCT_IN6_ADDR, 1, [IPv6 address structure]), [], [
 763 #ifdef HAVE_NETINET_IN_H
 764 #include <netinet/in.h>
 765 #endif
 766 ])
 767
 768 AC_CHECK_TYPE(struct sockaddr_storage, AC_DEFINE(HAVE_STRUCT_SOCKADDR_STORAGE, 1, [Generic socket addresses]), [], [
 769 #ifdef HAVE_NETINET_IN_H
 770 #include <netinet/in.h>
 771 #endif
 772 #ifdef HAVE_SYS_SOCKET_H
 773 #include <sys/socket.h>
 774 #endif
 775 ])
 776
 777 AC_CHECK_TYPE(struct sockaddr_in6, AC_DEFINE(HAVE_STRUCT_SOCKADDR_IN6, 1, [IPv6 socket addresses]), [], [
 778 #ifdef HAVE_NETINET_IN_H
 779 #include <netinet/in.h>
 780 #endif
 781 ])
 782
 783 AC_CHECK_TYPE(struct addrinfo, AC_DEFINE(HAVE_STRUCT_ADDRINFO, 1, [Generic DNS lookups]), [], [
 784 #ifdef HAVE_SYS_TYPES_H
 785 #include <sys/types.h>
 786 #endif
 787 #ifdef HAVE_SYS_SOCKET_H
 788 #include <sys/socket.h>
 789 #endif
 790 #ifdef HAVE_NETDB_H
 791 #include <netdb.h>
 792 #endif
 793 ])
 794
 795 dnl #############################################################
 796 dnl #
 797 dnl #  5. Checks for structures and functions
 798 dnl #
 799 dnl #############################################################
 800 AC_CHECK_FUNCS( \
 801         getopt_long \
 802         lockf \
 803         strsignal \
 804         sigaction \
 805         sigprocmask \
 806         pthread_sigmask \
 807         snprintf \
 808         vsnprintf \
 809         setsid \
 810         strncasecmp \
 811         strcasecmp \
 812         localtime_r \
 813         ctime_r \
 814         gmtime_r \
 815         strsep \
 816         inet_aton \
 817         inet_pton \
 818         inet_ntop \
 819         setlinebuf \
 820         setvbuf \
 821         getusershell \
 822         initgroups \
 823         getaddrinfo \
 824         getnameinfo \
 825         closefrom \
 826         gettimeofday \
 827         strlcat \
 828         strlcpy
 829 )
 830 RADIUSD_NEED_DECLARATIONS( \
 831         crypt \
 832         strncasecmp \
 833         strcasecmp \
 834         inet_aton \
 835         setlinebuf \
 836         getusershell \
 837         endusershell
 838 )
 839
 840 AC_TYPE_SIGNAL
 841
 842 dnl # check if we have utmpx.h
 843 dnl # if so, check if struct utmpx has entry ut_xtime
 844 dnl # if not, set it to define ut_xtime == ut_tv.tv_sec
 845 if test "x$ac_cv_header_utmpx_h" = "xyes"
 846 then
 847  FR_CHECK_STRUCT_HAS_MEMBER([#include <utmpx.h>], [struct utmpx], ut_xtime)
 848  if test "x$ac_cv_type_struct_utmpx_has_ut_xtime" = "x"
 849  then
 850    AC_DEFINE(ut_xtime,ut_tv.tv_sec, [define to something if you don't have ut_xtime in struct utmpx])
 851  fi
 852 fi
 853
 854 dnl # struct ip_pktinfo
 855 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in_pktinfo], ipi_addr)
 856 if test "x$ac_cv_type_struct_in_pktinfo_has_ipi_addr" = "xyes"
 857 then
 858         AC_DEFINE(HAVE_IP_PKTINFO, [], [define if you have IP_PKTINFO (Linux)])
 859 fi
 860
 861 dnl # struct in6_pktinfo
 862 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in6_pktinfo], ipi6_addr)
 863 if test "x$ac_cv_type_struct_in6_pktinfo_has_ipi6_addr" = "xyes"
 864 then
 865         AC_DEFINE(HAVE_IN6_PKTINFO, [], [define if you have IN6_PKTINFO (Linux)])
 866 fi
 867
 868 dnl #############################################################
 869 dnl #
 870 dnl #  6. Checks for compiler characteristics
 871 dnl #
 872 dnl #############################################################
 873
 874 dnl #
 875 dnl # Ensure that these are defined
 876 dnl #
 877 AC_C_CONST
 878
 879 dnl #
 880 dnl # See if this is OS/2
 881 dnl #
 882 AC_MSG_CHECKING(type of OS)
 883 OS=`uname -s`
 884 AC_MSG_RESULT($OS)
 885 if test "$OS" = "OS/2"; then
 886         LIBPREFIX=
 887 else
 888         LIBPREFIX=lib
 889 fi
 890 AC_SUBST(LIBPREFIX)
 891
 892 dnl #
 893 dnl # Set Default CFLAGS
 894 dnl #
 895 if test "x$GCC" = "xyes"; then
 896     CFLAGS="$CFLAGS -Wall -D_GNU_SOURCE"
 897 fi
 898
 899 AC_MSG_CHECKING(for developer gcc flags)
 900 if test "x$developer" = "xyes" -a "x$GCC" = "xyes"; then
 901   devflags="-g -Wshadow -Wpointer-arith -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -W -Wredundant-decls -Wundef"
 902   CFLAGS="$CFLAGS $devflags"
 903   INSTALLSTRIP=""
 904   AC_MSG_RESULT(yes.  Using $devflags)
 905 else
 906   devflags=""
 907   CFLAGS="$CFLAGS -DNDEBUG"
 908   INSTALLSTRIP="-s"
 909   AC_MSG_RESULT(no.)
 910 fi
 911
 912 dnl #############################################################
 913 dnl #
 914 dnl #  7. Checks for library functions
 915 dnl #
 916 dnl #############################################################
 917
 918 dnl Check for libcrypt
 919 dnl We use crypt(3) which may be in libc, or in libcrypt (eg FreeBSD)
 920 AC_CHECK_LIB(crypt, crypt,
 921   CRYPTLIB="-lcrypt"
 922 )
 923 if test "$CRYPTLIB" != ""; then
 924   AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function])
 925 else
 926   AC_CHECK_FUNC(crypt, AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function]))
 927 fi
 928
 929 dnl Check for libcipher
 930 AC_CHECK_LIB(cipher, setkey,
 931    CRYPTLIB="${CRYPTLIB} -lcipher"
 932 )
 933 AC_SUBST(CRYPTLIB)
 934
 935 if test "x$WITH_SNMP" = "xyes"; then
 936   SNMP_CHECKS
 937 fi
 938
 939 dnl Check the style of gethostbyaddr, in order of preference
 940 dnl GNU (_r eight args)
 941 AC_DEFINE(GNUSTYLE, [1], [GNU-Style get*byaddr_r])
 942 dnl SYSV (_r six args)
 943 AC_DEFINE(SYSVSTYLE, [2], [SYSV-Style get*byaddr_r])
 944 dnl BSD (three args, may not be thread safe)
 945 AC_DEFINE(BSDSTYLE, [3], [BSD-Style get*byaddr_r])
 946 dnl Tru64 has BSD version, but it is thread safe
 947 dnl     http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1739____.HTM
 948 dnl We need #stdio.h to define NULL on FreeBSD (at least)
 949 gethostbyaddrrstyle=""
 950 AC_MSG_CHECKING([gethostbyaddr_r() syntax])
 951 case "$host" in
 952 *-freebsd*)
 953 dnl With FreeBSD, check if there's a prototype for gethostbyaddr_r.
 954 dnl Some versions (FreeBSD 5.1?) have a symbol but no prototype - so we
 955 dnl override this test to BSDSTYLE. FreeBSD 6.2 and up have proper GNU
 956 dnl style support.
 957         AC_CHECK_DECLS([gethostbyaddr_r], [], [
 958                 AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE,
 959                         [style of gethostbyaddr_r functions ])
 960                 gethostbyaddrrstyle=BSD
 961                 AC_MSG_WARN([FreeBSD overridden to BSD-style])
 962         ], [
 963 #ifdef HAVE_NETDB_H
 964 #include <netdb.h>
 965 #endif
 966 ])
 967         ;;
 968 esac
 969 if test "x$gethostbyaddrrstyle" = "x"; then
 970         AC_TRY_LINK([
 971 #include <stdio.h>
 972 #include <netdb.h>
 973 ], [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL, NULL) ], [
 974         AC_DEFINE(GETHOSTBYADDRRSTYLE, GNUSTYLE, [style of gethostbyaddr_r functions ])
 975         gethostbyaddrrstyle=GNU
 976 ])
 977 fi
 978 if test "x$gethostbyaddrrstyle" = "x"; then
 979         AC_TRY_LINK([
 980 #include <stdio.h>
 981 #include <netdb.h>
 982 ], [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL) ] , [
 983                 AC_DEFINE(GETHOSTBYADDRRSTYLE, SYSVSTYLE, [style of gethostbyaddr_r functions ])
 984                 gethostbyaddrrstyle=SYSV
 985         ])
 986 fi
 987 if test "x$gethostbyaddrrstyle" = "x"; then
 988         AC_TRY_LINK([
 989 #include <stdio.h>
 990 #include <netdb.h>
 991 ], [ gethostbyaddr(NULL, 0, 0)  ], [
 992                 AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE, [style of gethostbyaddr_r functions ])
 993                 gethostbyaddrrstyle=BSD
 994         ])
 995 fi
 996
 997 if test "x$gethostbyaddrrstyle" = "x"; then
 998         AC_MSG_RESULT([none!  It must not exist, here.])
 999 else
1000         AC_MSG_RESULT([${gethostbyaddrrstyle}-style])
1001 fi
1002
1003 if test "x$gethostbyaddrrstyle" = "xBSD"; then
1004         AC_MSG_WARN([ ****** BSD-style gethostbyaddr might NOT be thread-safe! ****** ])
1005 fi
1006
1007 dnl Check the style of gethostbyname, in order of preference
1008 dnl GNU (_r seven args)
1009 dnl SYSV (_r five args)
1010 dnl BSD (two args, may not be thread safe)
1011 dnl Tru64 has BSD version, but it _is_ thread safe
1012 dnl     http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1946____.HTM
1013 dnl We need #stdio.h to define NULL on FreeBSD (at least)
1014 gethostbynamerstyle=""
1015 AC_MSG_CHECKING([gethostbyname_r() syntax])
1016 AC_TRY_LINK([
1017 #include <stdio.h>
1018 #include <netdb.h>
1019 ], [ gethostbyname_r(NULL, NULL, NULL, 0, NULL, NULL) ], [
1020         AC_DEFINE(GETHOSTBYNAMERSTYLE, GNUSTYLE, [style of gethostbyname_r functions ])
1021         gethostbynamerstyle=GNU
1022 ])
1023 if test "x$gethostbynamerstyle" = "x"; then
1024         AC_TRY_LINK([
1025 #include <stdio.h>
1026 #include <netdb.h>
1027 ], [ gethostbyname_r(NULL, NULL, NULL, 0, NULL) ] , [
1028                 AC_DEFINE(GETHOSTBYNAMERSTYLE, SYSVSTYLE, [style of gethostbyname_r functions ])
1029                 gethostbynamerstyle=SYSV
1030         ])
1031 fi
1032 if test "x$gethostbynamerstyle" = "x"; then
1033         AC_TRY_LINK([
1034 #include <stdio.h>
1035 #include <netdb.h>
1036 ], [ gethostbyname(NULL)  ], [
1037                 AC_DEFINE(GETHOSTBYNAMERSTYLE, BSDSTYLE, [style of gethostbyname_r functions ])
1038                 gethostbynamerstyle=BSD
1039         ])
1040 fi
1041
1042 if test "x$gethostbynamerstyle" = "x"; then
1043         AC_MSG_RESULT([none!  It must not exist, here.])
1044 else
1045         AC_MSG_RESULT([${gethostbynamerstyle}-style])
1046 fi
1047
1048 if test "x$gethostbynamerstyle" = "xBSD"; then
1049         AC_MSG_WARN([ ****** BSD-style gethostbyname might NOT be thread-safe! ****** ])
1050 fi
1051
1052 dnl check for non-posix solaris ctime_r (extra buflen int arg)
1053 AC_DEFINE(POSIXSTYLE, [1], [Posix-Style ctime_r])
1054 AC_DEFINE(SOLARISSTYLE, [2], [Solaris-Style ctime_r])
1055 ctimerstyle=""
1056 AC_MSG_CHECKING([ctime_r() syntax])
1057 AC_TRY_LINK([
1058 #include <time.h>
1059 ], [ ctime_r(NULL, NULL, 0) ], [
1060         AC_DEFINE(CTIMERSTYLE, SOLARISSTYLE, [style of ctime_r function])
1061         ctimerstyle="SOLARIS"
1062 ])
1063 if test "x$ctimerstyle" = "x"; then
1064         AC_TRY_LINK([
1065 #include <time.h>
1066 ], [ ctime_r(NULL, NULL) ], [
1067                 AC_DEFINE(CTIMERSTYLE, POSIXSTYLE, [style of ctime_r function])
1068                 ctimerstyle="POSIX"
1069         ])
1070 fi
1071
1072 if test "x$ctimerstyle" = "x"; then
1073         AC_MSG_RESULT([none!  It must not exist, here.])
1074 else
1075         AC_MSG_RESULT([${ctimerstyle}-style])
1076 fi
1077
1078 AC_SUBST(HOSTINFO, $host)
1079
1080 dnl #############################################################
1081 dnl #
1082 dnl #  8. Checks for system services
1083 dnl #
1084 dnl #############################################################
1085
1086 dnl #
1087 dnl # Figure out where libtool is located,
1088 dnl #
1089 top_builddir=`pwd`
1090 export top_builddir
1091 AC_MSG_RESULT([top_builddir=$top_builddir])
1092 dnl # AC_SUBST(top_builddir)
1093 AC_SUBST(LIBLTDL)
1094 AC_SUBST(INCLTDL)
1095
1096 dnl import libtool stuff
1097
1098 dnl #############################################################
1099 dnl #
1100 dnl #  Configure in any module directories.
1101 dnl #
1102 dnl #############################################################
1103
1104 mysubdirs="$LIBLTDLPATH"
1105 if test "x$EXPERIMENTAL" = "xyes"; then
1106   bar=`ls -1 "${srcdir}"/src/modules/rlm_*/configure | sed 's%/configure%%'`
1107   dnl # get rid of LF's.
1108   mysubdirs=`echo $mysubdirs $bar`
1109 else
1110   dnl #
1111   dnl # Find 'configure' in ONLY the stable modules
1112   dnl #
1113   for bar in `cat "${srcdir}"/src/modules/stable`; do
1114     if test -f "${srcdir}"/src/modules/$bar/configure; then
1115       mysubdirs="$mysubdirs src/modules/$bar"
1116     fi
1117   done
1118 fi
1119
1120 dnl ############################################################
1121 dnl # make modules by list
1122 dnl #############################################################
1123 if test "x$EXPERIMENTAL" = "xyes"; then
1124   for foo in `ls -1 "${srcdir}"/src/modules | grep rlm_`; do
1125     MODULES="$MODULES $foo"
1126   done
1127 else
1128    dnl #
1129    dnl # make ONLY the stable modules
1130    dnl #
1131    for foo in `cat "${srcdir}"/src/modules/stable`; do
1132     MODULES="$MODULES $foo"
1133    done
1134 fi
1135
1136 dnl #
1137 dnl #  Don't change the variable name here.  Autoconf goes bonkers
1138 dnl #  if you do.
1139 dnl #
1140 AC_CONFIG_SUBDIRS($LTDL_SUBDIRS $mysubdirs)
1141 AC_SUBST(MODULES)
1142
1143 dnl #############################################################
1144 dnl #
1145 dnl #  And finally, output the results.
1146 dnl #
1147 dnl #############################################################
1148
1149 AC_CONFIG_COMMANDS([stamp-h], [echo timestamp > src/include/stamp-h])
1150 AC_CONFIG_COMMANDS([build-radpaths-h], [(cd ./src/include && /bin/sh ./build-radpaths-h)])
1151 AC_CONFIG_COMMANDS([main-chmod], [(cd ./src/main   && chmod +x checkrad.pl radlast radtest)])
1152 AC_CONFIG_COMMANDS([scripts-chmod], [(cd ./scripts    && chmod +x rc.radiusd radwatch check-radiusd-config radiusd.cron.daily radiusd.cron.monthly cryptpasswd)])
1153
1154 dnl #
1155 dnl #  Substitute whatever libraries we found to be necessary
1156 dnl #
1157 AC_SUBST(LIBS)
1158 AC_SUBST(INSTALLSTRIP)
1159
1160 USE_SHARED_LIBS=$enable_shared
1161 AC_SUBST(USE_SHARED_LIBS)
1162 USE_STATIC_LIBS=$enable_static
1163 AC_SUBST(USE_STATIC_LIBS)
1164 AC_SUBST(STATIC_MODULES)
1165 AC_SUBST(RADIUSD_MAJOR_VERSION)
1166 AC_SUBST(RADIUSD_MINOR_VERSION)
1167 AC_SUBST(RADIUSD_VERSION)
1168
1169 AC_OUTPUT(\
1170         ./Make.inc \
1171         ./src/include/build-radpaths-h \
1172         ./src/main/Makefile \
1173         ./src/main/checkrad.pl \
1174         ./src/main/radlast \
1175         ./src/main/radtest \
1176         ./scripts/rc.radiusd \
1177         ./scripts/radwatch \
1178         ./scripts/check-radiusd-config \
1179         ./scripts/radiusd.cron.daily \
1180         ./scripts/radiusd.cron.monthly \
1181         ./scripts/cryptpasswd \
1182         ./raddb/dictionary \
1183         ./raddb/radiusd.conf \
1184         ./raddb/vmpsd.conf \
1185         ./raddb/radrelay.conf
1186 )