configure.in

   1 dnl #############################################################
   2 dnl #
   3 dnl #  For information about autoconf, see:
   4 dnl #
   5 dnl #  http://www.gnu.org/software/autoconf/
   6 dnl #
   7 dnl #  The recommended order is:
   8 dnl #
   9 dnl #  AC_INIT(file)
  10 dnl #  0. checks for compiler, libtool, and command line options
  11 dnl #  1. checks for programs
  12 dnl #  2. checks for libraries
  13 dnl #  3. checks for header files
  14 dnl #  4. checks for typedefs
  15 dnl #  5. checks for structures and functions
  16 dnl #  6. checks for compiler characteristics
  17 dnl #  7. checks for library functions
  18 dnl #  8. checks for system services
  19 dnl #  AC_OUTPUT([file...])
  20 dnl #
  21 dnl #############################################################
  22
  23 AC_PREREQ([2.59])
  24 export CFLAGS LIBS LDFLAGS CPPFLAGS
  25 AC_INIT(src/main/radiusd.c)
  26 AC_CONFIG_HEADER(src/include/autoconf.h)
  27 AC_REVISION($Revision$)dnl
  28
  29 dnl # The version of the software
  30 RADIUSD_MAJOR_VERSION=2
  31 RADIUSD_MINOR_VERSION=0.0-beta
  32 RADIUSD_VERSION="${RADIUSD_MAJOR_VERSION}.${RADIUSD_MINOR_VERSION}"
  33 PACKAGE=freeradius
  34
  35 dnl #############################################################
  36 dnl #
  37 dnl #  0. Checks for compiler, libtool, and command line options.
  38 dnl #
  39 dnl #############################################################
  40
  41 dnl Check for GNU cc
  42 AC_PROG_CC
  43 AC_PROG_CXX
  44
  45 dnl #
  46 dnl # check for AIX, to allow us to use some BSD functions
  47 dnl # must be before macros that call the compiler.
  48 dnl #
  49 AC_AIX
  50
  51 AC_PROG_GCC_TRADITIONAL
  52 AC_PROG_CC_SUNPRO
  53 AC_PROG_RANLIB
  54
  55 dnl Compile in large (2G+) file support.
  56 AC_SYS_LARGEFILE
  57
  58 dnl # check for system bytesex
  59 dnl # AC_DEFINES WORDS_BIGENDIAN
  60 AC_C_BIGENDIAN
  61
  62 dnl Find GNU Make.
  63 AC_CHECK_PROG(GMAKE, gmake, yes, no)
  64 if test $GMAKE = no; then
  65   AC_PATH_PROG(MAKE, make, /usr/local/bin/make)
  66 else
  67   AC_PATH_PROG(MAKE, gmake, /usr/local/gnu/bin/make)
  68 fi
  69 makever=`$ac_cv_path_MAKE --version 2>&1 | grep "GNU Make"`
  70 if test -z "$makever"; then
  71   AC_MSG_ERROR(GNU Make is not installed.  Please download and install it
  72                 from ftp://prep.ai.mit.edu/pub/gnu/make/ before continuing.)
  73 fi
  74
  75 dnl libltdl is installable
  76 AC_LIBLTDL_INSTALLABLE
  77
  78 dnl tell Makefile to build ltdl if needed
  79 if test x"$enable_ltdl_install" = x"yes"; then
  80   LTDL_SUBDIRS=libltdl
  81 fi
  82 AC_SUBST(LTDL_SUBDIRS)
  83
  84 dnl use system-wide libtool, if it exists
  85 AC_ARG_WITH(system-libtool,
  86 [  --with-system-libtool              try to use libtool installed in your system [default=use our own]],
  87 [ AC_PATH_PROG(LIBTOOL, libtool,,$PATH:/usr/local/bin) ],
  88 [
  89   LIBTOOL="`pwd`/libtool"
  90   AC_SUBST(LIBTOOL)
  91   dnl ensure that we're looking for dlopen
  92   AC_LIBTOOL_DLOPEN
  93
  94   dnl Figure out how to build shared libraries
  95   AC_PROG_LIBTOOL
  96 ])
  97
  98
  99 dnl Put this in later, when all distributed modules use autoconf.
 100 dnl AC_ARG_WITH(disablemodulefoo,
 101 dnl [  --without-rlm_foo       Disables module compilation.  Module list:]
 102 dnl esyscmd([find src/modules -type d -name rlm_\* -print |\
 103 dnl     sed -e 's%src/modules/.*/% (sub)- %; s%.*/%- %' |\
 104 dnl     awk '{print "                            "$0}']))
 105
 106 AC_ARG_ENABLE(strict-dependencies,
 107 [  --enable-strict-dependencies  Fail configure on lack of module dependancy.])
 108
 109 dnl extra argument: --with-docdir
 110 docdir='${datadir}/doc/freeradius'
 111 AC_MSG_CHECKING(docdir)
 112 AC_ARG_WITH(docdir,
 113 [  --with-docdir=DIR       Directory for documentation [DATADIR/doc/freeradius] ],
 114 [ case "$withval" in
 115     no)
 116         docdir=no
 117         ;;
 118     yes)
 119         ;;
 120     [[\\/$]]* | ?:[[\\/]]* )
 121         docdir="$withval"
 122         ;;
 123     *)
 124         AC_MSG_ERROR([expected an absolute directory name for --with-docdir: $withval])
 125         ;;
 126   esac ]
 127 )
 128 AC_SUBST(docdir)
 129 AC_MSG_RESULT($docdir)
 130 if test "x$docdir" = xno; then
 131         AC_MSG_WARN(Documentation files will NOT be installed.)
 132 fi
 133
 134 dnl extra argument: --with-logdir
 135 logdir='${localstatedir}/log/radius'
 136 AC_MSG_CHECKING(logdir)
 137 AC_ARG_WITH(logdir,
 138 [  --with-logdir=DIR       Directory for logfiles [LOCALSTATEDIR/log/radius] ],
 139 [ case "$withval" in
 140     no)
 141         AC_MSG_ERROR(Need logdir)
 142         ;;
 143     yes)
 144         ;;
 145     [[\\/$]]* | ?:[[\\/]]* )
 146         logdir="$withval"
 147         ;;
 148     *)
 149         AC_MSG_ERROR([expected an absolute directory name for --with-logdir: $withval])
 150         ;;
 151   esac ]
 152 )
 153 AC_SUBST(logdir)
 154 AC_MSG_RESULT($logdir)
 155
 156 dnl extra argument: --with-radacctdir
 157 radacctdir='${logdir}/radacct'
 158 AC_MSG_CHECKING(radacctdir)
 159 AC_ARG_WITH(radacctdir,
 160 [  --with-radacctdir=DIR   Directory for detail files [LOGDIR/radacct] ],
 161 [ case "$withval" in
 162     no)
 163         AC_MSG_ERROR(Need radacctdir)
 164         ;;
 165     yes)
 166         ;;
 167     [[\\/$]]* | ?:[[\\/]]* )
 168         radacctdir="$withval"
 169         ;;
 170     *)
 171         AC_MSG_ERROR([expected an absolute directory name for --with-radacctdir: $withval])
 172         ;;
 173   esac ]
 174 )
 175 AC_SUBST(radacctdir)
 176 AC_MSG_RESULT($radacctdir)
 177
 178 dnl extra argument: --with-raddbdir
 179 raddbdir='${sysconfdir}/raddb'
 180 AC_MSG_CHECKING(raddbdir)
 181 AC_ARG_WITH(raddbdir,
 182 [  --with-raddbdir=DIR     Directory for config files [SYSCONFDIR/raddb] ],
 183 [ case "$withval" in
 184     no)
 185         AC_MSG_ERROR(Need raddbdir)
 186         ;;
 187     yes)
 188         ;;
 189     [[\\/$]]* | ?:[[\\/]]* )
 190         raddbdir="$withval"
 191         ;;
 192     *)
 193         AC_MSG_ERROR([expected an absolute directory name for --with-raddbdir: $withval])
 194         ;;
 195   esac ]
 196 )
 197 AC_SUBST(raddbdir)
 198 AC_MSG_RESULT($raddbdir)
 199
 200 dnl extra argument: --with-ascend-binary
 201 ASCEND_BINARY=yes
 202 AC_ARG_WITH(ascend-binary,
 203 [  --with-ascend-binary    Include support for Ascend binary filter attributes (default=yes)],
 204 [ case "$withval" in
 205     yes)
 206         ;;
 207     *)
 208         ASCEND_BINARY=""
 209   esac ]
 210 )
 211 if test "X$ASCEND_BINARY" = "Xyes"; then
 212   AC_DEFINE(ASCEND_BINARY, [], [Include support for Ascend binary filter attributes])
 213 fi
 214
 215 dnl extra argument: --with-threads
 216 WITH_THREADS=yes
 217 AC_ARG_WITH(threads,
 218 [  --with-threads          Use threads, if available.  (default=yes) ],
 219 [ case "$withval" in
 220     yes)
 221         ;;
 222     *)
 223         WITH_THREADS=""
 224   esac ]
 225 )
 226
 227 dnl extra argument: --with-snmp
 228 WITH_SNMP=yes
 229 AC_ARG_WITH(snmp,
 230 [  --with-snmp             Compile in SNMP support. (default=yes)],
 231 [ case "$withval" in
 232     yes)
 233         ;;
 234     *)
 235         WITH_SNMP=no
 236   esac ]
 237 )
 238
 239 dnl #
 240 dnl # extra argument: --with-snmp-include-dir
 241 dnl #
 242 AC_ARG_WITH(snmp-include-dir,
 243 [  --with-snmp-include-dir=DIR  Directory to look for include files used by SNMP],
 244 [ case "$withval" in
 245     *)
 246         ;;
 247   esac ]
 248 )
 249
 250 dnl extra argument: --with-vmps
 251 WITH_VMPS=yes
 252 AC_ARG_WITH(vmps,
 253 [  --with-vmps             Compile in VMPS support. (default=yes)],
 254 [ case "$withval" in
 255     yes)
 256         ;;
 257     *)
 258         WITH_VMPS=no
 259   esac ]
 260 )
 261 if test "x$WITH_VMPS" = "xyes"; then
 262         AC_DEFINE(WITH_VMPS, [], [define if you want VMPS support])
 263 fi
 264
 265
 266 dnl #
 267 dnl #  Allow the user to specify a list of modules to be linked
 268 dnl #  statically to the server.
 269 dnl #
 270 STATIC_MODULES=
 271 AC_ARG_WITH(static_modules,
 272 [  --with-static-modules=QUOTED-MODULE-LIST],[
 273   for i in $withval; do
 274     STATIC_MODULES="$STATIC_MODULES -dlpreopen ../modules/rlm_$i/rlm_$i.la"
 275   done
 276 ])
 277
 278 MODULES=
 279 AC_ARG_WITH(modules,
 280 [ --with-modules=QUOTED-MODULE-LIST],[
 281  for i in $withval; do
 282    MODULES="$MODULES $i"
 283  done
 284 ])
 285
 286 dnl #
 287 dnl #  Enable developer C compiler warnings
 288 dnl #
 289 AC_ARG_ENABLE(developer,
 290 [  --enable-developer               Enables features of interest to developers.],
 291 [ case "$enableval" in
 292     no)
 293         developer=no
 294         ;;
 295     *)
 296         developer=yes
 297   esac ]
 298 )
 299
 300 if test "x$developer" != "xno" -a -d $srcdir/CVS; then
 301   dnl turn on the developer flag when taken from a CVS checkout (not a release)
 302   developer="yes"
 303 fi
 304
 305 dnl extra argument: --with-experimental-modules
 306 EXPERIMENTAL=
 307 AC_ARG_WITH(experimental-modules,
 308 [  --with-experimental-modules      Use experimental and unstable modules. (default=no) ],
 309 [ case "$withval" in
 310     yes)
 311         EXPERIMENTAL=yes
 312         ;;
 313     *)
 314   esac ]
 315 )
 316
 317 dnl extra argument: --with-openssl
 318 WITH_OPENSSL=yes
 319 AC_ARG_WITH(openssl,
 320 [  --with-openssl                   Use OpenSSL. (default=yes)],
 321 [ case "$withval" in
 322     no)
 323         WITH_OPENSSL=no
 324         ;;
 325     *)
 326         WITH_OPENSSL=yes
 327         ;;
 328   esac ]
 329 )
 330
 331 dnl #
 332 dnl # extra argument: --with-openssl-includes=dir
 333 dnl #
 334 OPENSSL_INCLUDE_DIR=
 335 AC_ARG_WITH(openssl-includes,
 336 [  --with-openssl-includes=DIR      Directory to look for OpenSSL include files],
 337 [ case "$withval" in
 338     *) OPENSSL_INCLUDE_DIR="$withval"
 339         ;;
 340   esac ]
 341 )
 342
 343 dnl #
 344 dnl # extra argument: --with-openssl-libraries=dir
 345 dnl #
 346 OPENSSL_LIB_DIR=
 347 AC_ARG_WITH(openssl-libraries,
 348 [  --with-openssl-libraries=DIR     Directory to look for OpenSSL library files],
 349 [ case "$withval" in
 350     *) OPENSSL_LIB_DIR="$withval"
 351         ;;
 352   esac ]
 353 )
 354
 355 dnl #
 356 dnl #  These next two arguments don't actually do anything.  They're
 357 dnl #  place holders so that the top-level configure script can tell
 358 dnl #  the user how to configure lower-level modules
 359 dnl #
 360
 361 dnl #
 362 dnl # extra argument: --with-rlm-FOO-lib-dir
 363 dnl #
 364 AC_ARG_WITH(rlm-FOO-lib-dir,
 365 [  --with-rlm-FOO-lib-dir=DIR       Directory to look for library files used by module FOO],
 366 [ case "$withval" in
 367     *)
 368         ;;
 369   esac ]
 370 )
 371
 372 dnl #
 373 dnl # extra argument: --with-rlm-FOO-include-dir
 374 dnl #
 375 AC_ARG_WITH(rlm-FOO-include-dir,
 376 [  --with-rlm-FOO-include-dir=DIR   Directory to look for include files used by module FOO],
 377 [ case "$withval" in
 378     *)
 379         ;;
 380   esac ]
 381 )
 382
 383 dnl See what include-style is used by the make program.
 384 dnl AC_MSG_CHECKING(include style for make)
 385 dnl echo "include /dev/null" > testmake.$$
 386 dnl echo "all:" >> testmake.$$
 387 dnl make -f testmake.$$ >/dev/null 2>&1
 388 dnl if test $? = 0
 389 dnl then
 390 dnl     INCLUDE=include
 391 dnl     IQUOTE=
 392 dnl else
 393 dnl     INCLUDE=.include
 394 dnl     IQUOTE='"'
 395 dnl fi
 396 dnl rm -f testmake.$$
 397 dnl AC_MSG_RESULT(" $INCLUDE")
 398 dnl AC_SUBST(INCLUDE)
 399 dnl AC_SUBST(IQUOTE)
 400
 401 dnl extra argument: --with-udpfromto
 402 WITH_UDPFROMTO=no
 403 AC_ARG_WITH(udpfromto,
 404 [  --with-udpfromto        Compile in UDPFROMTO support. (default=yes)],
 405 [ case "$withval" in
 406     yes)
 407         WITH_UDPFROMTO=yes
 408         ;;
 409     *)
 410         WITH_UDPFROMTO=no
 411   esac ]
 412 )
 413
 414 if test "x$WITH_UDPFROMTO" = "xyes"; then
 415         AC_DEFINE(WITH_UDPFROMTO, [], [define if you want udpfromto])
 416 fi
 417
 418 dnl #############################################################
 419 dnl #
 420 dnl #  1. Checks for programs
 421 dnl #
 422 dnl #############################################################
 423
 424 CHECKRAD=checkrad.pl
 425 AC_PATH_PROG(PERL, perl, /usr/local/bin/perl)
 426 if test "x$ac_cv_path_PERL" = "x"; then
 427   AC_MSG_WARN(perl not found - Simultaneous-Use and checkrad.pl may not work)
 428 fi
 429 AC_PATH_PROG(SNMPGET, snmpget)
 430 if test "x$ac_cv_path_SNMPGET" = "x"; then
 431   AC_MSG_WARN(snmpget not found - Simultaneous-Use and checkrad.pl may not work)
 432 fi
 433
 434 AC_PATH_PROG(SNMPWALK, snmpwalk)
 435 if test "x$ac_cv_path_SNMPWALK" = "x"; then
 436   AC_MSG_WARN(snmpwalk not found - Simultaneous-Use and checkrad.pl may not work)
 437 fi
 438
 439 AC_PATH_PROG(RUSERS, rusers, /usr/bin/rusers)
 440
 441 dnl FIXME This is truly gross.
 442 missing_dir=`cd $ac_aux_dir && pwd`
 443 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
 444 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
 445 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
 446
 447 AC_PATH_PROG(LOCATE,locate)
 448 AC_PATH_PROG(DIRNAME,dirname)
 449 AC_PATH_PROG(GREP,grep)
 450
 451 dnl #############################################################
 452 dnl #
 453 dnl #  2. Checks for libraries
 454 dnl #
 455 dnl #############################################################
 456
 457 dnl If using pthreads, check for -lpthread (posix) or -lc_r (*BSD)
 458 old_CFLAGS=$CFLAGS
 459 if test "x$WITH_THREADS" = "xyes"; then
 460   if test $ac_cv_prog_suncc = "yes"; then
 461     CFLAGS="$CFLAGS -mt"
 462   fi
 463
 464   AC_CHECK_HEADERS(pthread.h, [], [ WITH_THREADS="no" ])
 465
 466 dnl #
 467 dnl # pthread stuff is usually in -lpthread
 468 dnl # or in -lc_r, on *BSD
 469 dnl #
 470 dnl # On Some systems, we need extra pre-processor flags, to get them to
 471 dnl # to do the threading properly.
 472 dnl #
 473   AC_CHECK_LIB(pthread, pthread_create,
 474                 [ CFLAGS="$CFLAGS -D_REENTRANT -D_POSIX_PTHREAD_SEMANTICS"
 475                   LIBS="$LIBS -lpthread" ],
 476                 AC_CHECK_LIB(c_r, pthread_create,
 477                             [ CFLAGS="$CFLAGS -pthread -D_THREAD_SAFE" ],
 478                             [ WITH_THREADS="no" ]
 479                             )
 480                 )
 481 fi
 482
 483 dnl #
 484 dnl # If we have NO pthread libraries, remove any knowledge of threads.
 485 dnl #
 486 if test "x$WITH_THREADS" != "xyes"; then
 487   CFLAGS=$old_CFLAGS
 488   ac_cv_header_pthread_h="no"
 489   WITH_THREADS=no
 490 else
 491   dnl #
 492   dnl #  We need sem_init() and friends, as they're the friendliest
 493   dnl #  semaphore functions for threading.
 494   dnl #
 495   dnl # HP/UX requires linking with librt, too, to get the sem_* symbols.
 496   dnl # Some systems have them in -lsem
 497   dnl # Solaris has them in -lposix4
 498   dnl # NetBSD has them in -lsemaphore
 499
 500   AC_SEARCH_LIBS(sem_init, pthread sem posix4 rt semaphore,
 501         [],
 502         [AC_MSG_ERROR(-lsem not found.  You may want to download it from ftp://ftp.to.gd-es.com/pub/BSDI/libsem.tar.bz2 or ftp://ftp.freeradius.org/pub/radius/contrib/libsem.tar.gz)]
 503    )
 504 fi
 505
 506 dnl Check if we need -lsocket
 507 AC_CHECK_LIB(socket, getsockname)
 508
 509 dnl Check for -lresolv
 510 dnl This library may be needed later.
 511 AC_CHECK_LIB(resolv, inet_aton)
 512
 513 dnl Check if we need -lnsl. Usually if we want to
 514 dnl link against -lsocket we need to include -lnsl as well.
 515 AC_CHECK_LIB(nsl, inet_ntoa)
 516
 517 dnl Check for OpenSSL libraries.
 518 OPENSSL_LIBS=
 519 if test "x$WITH_OPENSSL" = xyes; then
 520   old_LIBS=$LIBS
 521   if test "x$OPENSSL_LIB_DIR" != "x"; then
 522     LIBS="-L$OPENSSL_LIB_DIR $LIBS"
 523   fi
 524   AC_CHECK_LIB(crypto, DH_new,
 525     [
 526         LIBS="-lcrypto $LIBS"
 527         AC_DEFINE(HAVE_LIBCRYPTO, 1,
 528             [Define to 1 if you have the `crypto' library (-lcrypto).])
 529         AC_CHECK_LIB(ssl, SSL_new,
 530             [
 531                 AC_DEFINE(HAVE_LIBSSL, 1,
 532                     [Define to 1 if you have the `ssl' library (-lssl).])
 533                 if test "x$OPENSSL_LIB_DIR" != "x"; then
 534                     OPENSSL_LIBS="-L$OPENSSL_LIB_DIR"
 535                 fi
 536                 OPENSSL_LIBS="$OPENSSL_LIBS -lcrypto -lssl -lcrypto"
 537             ], [])
 538     ], [])
 539   LIBS=$old_LIBS
 540 fi
 541
 542 AC_CHECK_LIB(ws2_32, htonl)
 543
 544 dnl Check the pcap library for the RADIUS sniffer.
 545 PCAP_LIBS=
 546 AC_CHECK_LIB(pcap, pcap_open_live,
 547         [ PCAP_LIBS="-lpcap"
 548         AC_DEFINE(HAVE_LIBPCAP, 1,
 549                 [Define to 1 if you have the `pcap' library (-lpcap).])
 550         ],
 551         [ AC_MSG_WARN([pcap library not found, silently disabling the RADIUS sniffer.]) ])
 552
 553 dnl #############################################################
 554 dnl #
 555 dnl #  3. Checks for header files
 556 dnl #
 557 dnl #############################################################
 558
 559 dnl #
 560 dnl # Interix requires us to set -D_ALL_SOURCE, otherwise
 561 dnl # getopt will be #included, but won't link.  <sigh>
 562 dnl #
 563 dnl #
 564 case "$host" in
 565 *-interix*)
 566         CFLAGS="$CFLAGS -D_ALL_SOURCE"
 567         ;;
 568 *-darwin*)
 569         CFLAGS="$CFLAGS -DDARWIN"
 570         LIBS="-framework DirectoryService $LIBS"
 571         ;;
 572 esac
 573
 574 AC_HEADER_DIRENT
 575 AC_HEADER_STDC
 576 AC_HEADER_TIME
 577 AC_HEADER_SYS_WAIT
 578
 579 AC_CHECK_HEADERS( \
 580         unistd.h \
 581         crypt.h \
 582         errno.h \
 583         resource.h \
 584         sys/resource.h \
 585         getopt.h \
 586         malloc.h \
 587         utmp.h \
 588         utmpx.h \
 589         signal.h \
 590         sys/select.h \
 591         syslog.h \
 592         inttypes.h \
 593         stdint.h \
 594         stdio.h \
 595         netdb.h \
 596         semaphore.h \
 597         arpa/inet.h \
 598         netinet/in.h \
 599         sys/types.h \
 600         sys/socket.h \
 601         winsock.h \
 602         sys/time.h \
 603         sys/wait.h \
 604         sys/security.h \
 605         fcntl.h \
 606         sys/fcntl.h \
 607         sys/prctl.h \
 608         prot.h \
 609         pwd.h \
 610         grp.h \
 611         sia.h \
 612         siad.h
 613 )
 614
 615 dnl FreeBSD requires sys/socket.h before net/if.h
 616 AC_CHECK_HEADERS(net/if.h, [], [],
 617 [#ifdef HAVE_SYS_SOCKET_H
 618 # include <sys/socket.h>
 619 # endif
 620 ])
 621
 622 REGEX=no
 623 AC_CHECK_HEADER(regex.h, AC_DEFINE(HAVE_REGEX_H, [], [define this if we have the <regex.h> header file]))
 624 if test "x$ac_cv_header_regex_h" = "xyes"; then
 625   REGEX_EXTENDED=no
 626   REGEX=yes
 627   AC_EGREP_CPP(yes,
 628     [#include <regex.h>
 629      #ifdef REG_EXTENDED
 630        yes
 631      #endif
 632      ], [AC_DEFINE(HAVE_REG_EXTENDED, [], [define this if we have REG_EXTENDED (from <regex.h>)]) REGEX_EXTENDED=yes])
 633 fi
 634 AC_SUBST(REGEX)
 635 AC_SUBST(REGEX_EXTENDED)
 636
 637 dnl #
 638 dnl #  other checks which require headers
 639 dnl #
 640 if test "x$ac_cv_header_sys_security_h" = "xyes" && test "x$ac_cv_header_prot_h" = "xyes"
 641 then
 642   AC_DEFINE(OSFC2, [], [define if you have OSFC2 authentication])
 643 fi
 644
 645 if test "x$ac_cv_header_sia_h" = "xyes" && test "x$ac_cv_header_siad_h" = "xyes"
 646 then
 647   AC_DEFINE(OSFSIA, [], [define if you have OSFSIA authentication])
 648 fi
 649
 650 dnl Check for OpenSSL includes.
 651 OPENSSL_INCLUDE="-DNO_OPENSSL"
 652 if test "x$WITH_OPENSSL" = xyes; then
 653   if test "x$OPENSSL_LIBS" = "x"; then
 654     AC_MSG_NOTICE([skipping test for openssl/ssl.h])
 655   else
 656     old_CPPFLAGS=$CPPFLAGS
 657     if test "x$OPENSSL_INCLUDE_DIR" != "x"; then
 658         CPPFLAGS="$CPPFLAGS -I$OPENSSL_INCLUDE_DIR"
 659     fi
 660     dnl # stupid RedHat shit
 661     CPPFLAGS="$CPPFLAGS -DOPENSSL_NO_KRB5"
 662     AC_CHECK_HEADERS( \
 663         openssl/ssl.h \
 664         openssl/crypto.h \
 665         openssl/err.h \
 666         openssl/evp.h \
 667         openssl/engine.h,
 668         [],
 669         OPENSSL_LIBS=
 670     )
 671     if test "x$OPENSSL_LIBS" != "x"; then
 672         AC_MSG_CHECKING([for OpenSSL version >= 0.9.7])
 673         AC_EGREP_CPP(yes,
 674             [#include <openssl/crypto.h>
 675              #if (OPENSSL_VERSION_NUMBER >= 0x00907000L)
 676              yes
 677              #endif
 678             ], goodssl="yes")
 679         if test "x$goodssl" != "xyes"; then
 680             AC_MSG_RESULT(no)
 681             OPENSSL_LIBS=
 682         else
 683             AC_MSG_RESULT(yes)
 684             if test "x$OPENSSL_INCLUDE_DIR" != "x"; then
 685                 OPENSSL_INCLUDE="-I$OPENSSL_INCLUDE_DIR -DOPENSSL_NO_KRB5"
 686             else
 687                 OPENSSL_INCLUDE="-DOPENSSL_NO_KRB5"
 688             fi
 689         fi
 690     fi
 691     CPPFLAGS=$old_CPPFLAGS
 692   fi
 693 fi
 694 AC_SUBST(OPENSSL_INCLUDE)
 695 AC_SUBST(OPENSSL_LIBS)
 696 export OPENSSL_LIBS
 697
 698 dnl Check the pcap includes for the RADIUS sniffer.
 699 if test "x$PCAP_LIBS" = x; then
 700     AC_MSG_NOTICE([skipping test for pcap.h.])
 701 else
 702     AC_CHECK_HEADER(pcap.h,
 703         AC_DEFINE(HAVE_PCAP_H, 1,
 704                 [Define to 1 if you have the <pcap.h> header file.]),
 705         [ PCAP_LIBS=
 706         AC_MSG_WARN([pcap.h not found, silently disabling the RADIUS sniffer.])
 707         ])
 708 fi
 709 AC_SUBST(PCAP_LIBS)
 710
 711 dnl #############################################################
 712 dnl #
 713 dnl #  4. Checks for typedefs
 714 dnl #
 715 dnl #############################################################
 716
 717 dnl #
 718 dnl # Ensure that these are defined
 719 dnl #
 720 AC_TYPE_OFF_T
 721 AC_TYPE_PID_T
 722 AC_TYPE_SIZE_T
 723 AC_TYPE_UID_T
 724
 725 dnl check for socklen_t
 726 FR_CHECK_TYPE_INCLUDE([
 727 #ifdef HAVE_SYS_TYPES_H
 728 #include <sys/types.h>
 729 #endif
 730 #ifdef HAVE_SYS_SOCKET_H
 731 #include <sys/socket.h>
 732 #endif
 733 ],socklen_t, int, [socklen_t is generally 'int' on systems which don't use it])
 734
 735 dnl check for uint8_t
 736 FR_CHECK_TYPE_INCLUDE([
 737 #ifdef HAVE_INTTYPES_H
 738 #include <inttypes.h>
 739 #endif
 740 #ifdef HAVE_STDINT_H
 741 #include <stdint.h>
 742 #endif
 743 ],uint8_t, unsigned char, [uint8_t should be the canonical 'octet' for network traffic])
 744
 745 dnl check for uint16_t
 746 FR_CHECK_TYPE_INCLUDE([
 747 #ifdef HAVE_INTTYPES_H
 748 #include <inttypes.h>
 749 #endif
 750 #ifdef HAVE_STDINT_H
 751 #include <stdint.h>
 752 #endif
 753 ],uint16_t, unsigned short, [uint16_t should be the canonical '2 octets' for network traffic])
 754
 755 dnl check for uint32_t
 756 FR_CHECK_TYPE_INCLUDE([
 757 #ifdef HAVE_INTTYPES_H
 758 #include <inttypes.h>
 759 #endif
 760 #ifdef HAVE_STDINT_H
 761 #include <stdint.h>
 762 #endif
 763 ],uint32_t, unsigned int, [uint32_t should be the canonical 'network integer])
 764
 765 AC_CHECK_TYPE(struct in6_addr, AC_DEFINE(HAVE_STRUCT_IN6_ADDR, 1, [IPv6 address structure]), [], [
 766 #ifdef HAVE_NETINET_IN_H
 767 #include <netinet/in.h>
 768 #endif
 769 ])
 770
 771 AC_CHECK_TYPE(struct sockaddr_storage, AC_DEFINE(HAVE_STRUCT_SOCKADDR_STORAGE, 1, [Generic socket addresses]), [], [
 772 #ifdef HAVE_NETINET_IN_H
 773 #include <netinet/in.h>
 774 #endif
 775 #ifdef HAVE_SYS_SOCKET_H
 776 #include <sys/socket.h>
 777 #endif
 778 ])
 779
 780 AC_CHECK_TYPE(struct sockaddr_in6, AC_DEFINE(HAVE_STRUCT_SOCKADDR_IN6, 1, [IPv6 socket addresses]), [], [
 781 #ifdef HAVE_NETINET_IN_H
 782 #include <netinet/in.h>
 783 #endif
 784 ])
 785
 786 AC_CHECK_TYPE(struct addrinfo, AC_DEFINE(HAVE_STRUCT_ADDRINFO, 1, [Generic DNS lookups]), [], [
 787 #ifdef HAVE_SYS_TYPES_H
 788 #include <sys/types.h>
 789 #endif
 790 #ifdef HAVE_SYS_SOCKET_H
 791 #include <sys/socket.h>
 792 #endif
 793 #ifdef HAVE_NETDB_H
 794 #include <netdb.h>
 795 #endif
 796 ])
 797
 798 dnl #############################################################
 799 dnl #
 800 dnl #  5. Checks for structures and functions
 801 dnl #
 802 dnl #############################################################
 803 AC_CHECK_FUNCS( \
 804         getopt_long \
 805         lockf \
 806         strsignal \
 807         sigaction \
 808         sigprocmask \
 809         pthread_sigmask \
 810         snprintf \
 811         vsnprintf \
 812         setsid \
 813         strncasecmp \
 814         strcasecmp \
 815         localtime_r \
 816         ctime_r \
 817         gmtime_r \
 818         strsep \
 819         inet_aton \
 820         inet_pton \
 821         inet_ntop \
 822         setlinebuf \
 823         setvbuf \
 824         getusershell \
 825         initgroups \
 826         getaddrinfo \
 827         getnameinfo \
 828         closefrom \
 829         gettimeofday \
 830         strlcat \
 831         strlcpy
 832 )
 833 RADIUSD_NEED_DECLARATIONS( \
 834         crypt \
 835         strncasecmp \
 836         strcasecmp \
 837         inet_aton \
 838         setlinebuf \
 839         getusershell \
 840         endusershell
 841 )
 842
 843 AC_TYPE_SIGNAL
 844
 845 dnl # check if we have utmpx.h
 846 dnl # if so, check if struct utmpx has entry ut_xtime
 847 dnl # if not, set it to define ut_xtime == ut_tv.tv_sec
 848 if test "x$ac_cv_header_utmpx_h" = "xyes"
 849 then
 850  FR_CHECK_STRUCT_HAS_MEMBER([#include <utmpx.h>], [struct utmpx], ut_xtime)
 851  if test "x$ac_cv_type_struct_utmpx_has_ut_xtime" = "x"
 852  then
 853    AC_DEFINE(ut_xtime,ut_tv.tv_sec, [define to something if you don't have ut_xtime in struct utmpx])
 854  fi
 855 fi
 856
 857 dnl # struct ip_pktinfo
 858 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in_pktinfo], ipi_addr)
 859 if test "x$ac_cv_type_struct_in_pktinfo_has_ipi_addr" = "xyes"
 860 then
 861         AC_DEFINE(HAVE_IP_PKTINFO, [], [define if you have IP_PKTINFO (Linux)])
 862 fi
 863
 864 dnl # struct in6_pktinfo
 865 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in6_pktinfo], ipi6_addr)
 866 if test "x$ac_cv_type_struct_in6_pktinfo_has_ipi6_addr" = "xyes"
 867 then
 868         AC_DEFINE(HAVE_IN6_PKTINFO, [], [define if you have IN6_PKTINFO (Linux)])
 869 fi
 870
 871 dnl #############################################################
 872 dnl #
 873 dnl #  6. Checks for compiler characteristics
 874 dnl #
 875 dnl #############################################################
 876
 877 dnl #
 878 dnl # Ensure that these are defined
 879 dnl #
 880 AC_C_CONST
 881
 882 dnl #
 883 dnl # See if this is OS/2
 884 dnl #
 885 AC_MSG_CHECKING(type of OS)
 886 OS=`uname -s`
 887 AC_MSG_RESULT($OS)
 888 if test "$OS" = "OS/2"; then
 889         LIBPREFIX=
 890 else
 891         LIBPREFIX=lib
 892 fi
 893 AC_SUBST(LIBPREFIX)
 894
 895 dnl #
 896 dnl # Set Default CFLAGS
 897 dnl #
 898 if test "x$GCC" = "xyes"; then
 899     CFLAGS="$CFLAGS -Wall -D_GNU_SOURCE"
 900 fi
 901
 902 AC_MSG_CHECKING(for developer gcc flags)
 903 if test "x$developer" = "xyes" -a "x$GCC" = "xyes"; then
 904   devflags="-g -Wshadow -Wpointer-arith -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -W -Wredundant-decls -Wundef"
 905   CFLAGS="$CFLAGS $devflags"
 906   INSTALLSTRIP=""
 907   AC_MSG_RESULT(yes.  Using $devflags)
 908 else
 909   devflags=""
 910   CFLAGS="$CFLAGS -DNDEBUG"
 911   INSTALLSTRIP=""
 912   AC_MSG_RESULT(no.)
 913 fi
 914
 915 dnl #############################################################
 916 dnl #
 917 dnl #  7. Checks for library functions
 918 dnl #
 919 dnl #############################################################
 920
 921 dnl Check for libcrypt
 922 dnl We use crypt(3) which may be in libc, or in libcrypt (eg FreeBSD)
 923 AC_CHECK_LIB(crypt, crypt,
 924   CRYPTLIB="-lcrypt"
 925 )
 926 if test "$CRYPTLIB" != ""; then
 927   AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function])
 928 else
 929   AC_CHECK_FUNC(crypt, AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function]))
 930 fi
 931
 932 dnl Check for libcipher
 933 AC_CHECK_LIB(cipher, setkey,
 934    CRYPTLIB="${CRYPTLIB} -lcipher"
 935 )
 936 AC_SUBST(CRYPTLIB)
 937
 938 if test "x$WITH_SNMP" = "xyes"; then
 939   SNMP_CHECKS
 940 fi
 941
 942 dnl Check the style of gethostbyaddr, in order of preference
 943 dnl GNU (_r eight args)
 944 AC_DEFINE(GNUSTYLE, [1], [GNU-Style get*byaddr_r])
 945 dnl SYSV (_r six args)
 946 AC_DEFINE(SYSVSTYLE, [2], [SYSV-Style get*byaddr_r])
 947 dnl BSD (three args, may not be thread safe)
 948 AC_DEFINE(BSDSTYLE, [3], [BSD-Style get*byaddr_r])
 949 dnl Tru64 has BSD version, but it is thread safe
 950 dnl     http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1739____.HTM
 951 dnl We need #stdio.h to define NULL on FreeBSD (at least)
 952 gethostbyaddrrstyle=""
 953 AC_MSG_CHECKING([gethostbyaddr_r() syntax])
 954 case "$host" in
 955 *-freebsd*)
 956 dnl With FreeBSD, check if there's a prototype for gethostbyaddr_r.
 957 dnl Some versions (FreeBSD 5.1?) have a symbol but no prototype - so we
 958 dnl override this test to BSDSTYLE. FreeBSD 6.2 and up have proper GNU
 959 dnl style support.
 960         AC_CHECK_DECLS([gethostbyaddr_r], [], [
 961                 AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE,
 962                         [style of gethostbyaddr_r functions ])
 963                 gethostbyaddrrstyle=BSD
 964                 AC_MSG_WARN([FreeBSD overridden to BSD-style])
 965         ], [
 966 #ifdef HAVE_NETDB_H
 967 #include <netdb.h>
 968 #endif
 969 ])
 970         ;;
 971 esac
 972 if test "x$gethostbyaddrrstyle" = "x"; then
 973         AC_TRY_LINK([
 974 #include <stdio.h>
 975 #include <netdb.h>
 976 ], [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL, NULL) ], [
 977         AC_DEFINE(GETHOSTBYADDRRSTYLE, GNUSTYLE, [style of gethostbyaddr_r functions ])
 978         gethostbyaddrrstyle=GNU
 979 ])
 980 fi
 981 if test "x$gethostbyaddrrstyle" = "x"; then
 982         AC_TRY_LINK([
 983 #include <stdio.h>
 984 #include <netdb.h>
 985 ], [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL) ] , [
 986                 AC_DEFINE(GETHOSTBYADDRRSTYLE, SYSVSTYLE, [style of gethostbyaddr_r functions ])
 987                 gethostbyaddrrstyle=SYSV
 988         ])
 989 fi
 990 if test "x$gethostbyaddrrstyle" = "x"; then
 991         AC_TRY_LINK([
 992 #include <stdio.h>
 993 #include <netdb.h>
 994 ], [ gethostbyaddr(NULL, 0, 0)  ], [
 995                 AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE, [style of gethostbyaddr_r functions ])
 996                 gethostbyaddrrstyle=BSD
 997         ])
 998 fi
 999
1000 if test "x$gethostbyaddrrstyle" = "x"; then
1001         AC_MSG_RESULT([none!  It must not exist, here.])
1002 else
1003         AC_MSG_RESULT([${gethostbyaddrrstyle}-style])
1004 fi
1005
1006 if test "x$gethostbyaddrrstyle" = "xBSD"; then
1007         AC_MSG_WARN([ ****** BSD-style gethostbyaddr might NOT be thread-safe! ****** ])
1008 fi
1009
1010 dnl Check the style of gethostbyname, in order of preference
1011 dnl GNU (_r seven args)
1012 dnl SYSV (_r five args)
1013 dnl BSD (two args, may not be thread safe)
1014 dnl Tru64 has BSD version, but it _is_ thread safe
1015 dnl     http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1946____.HTM
1016 dnl We need #stdio.h to define NULL on FreeBSD (at least)
1017 gethostbynamerstyle=""
1018 AC_MSG_CHECKING([gethostbyname_r() syntax])
1019 AC_TRY_LINK([
1020 #include <stdio.h>
1021 #include <netdb.h>
1022 ], [ gethostbyname_r(NULL, NULL, NULL, 0, NULL, NULL) ], [
1023         AC_DEFINE(GETHOSTBYNAMERSTYLE, GNUSTYLE, [style of gethostbyname_r functions ])
1024         gethostbynamerstyle=GNU
1025 ])
1026 if test "x$gethostbynamerstyle" = "x"; then
1027         AC_TRY_LINK([
1028 #include <stdio.h>
1029 #include <netdb.h>
1030 ], [ gethostbyname_r(NULL, NULL, NULL, 0, NULL) ] , [
1031                 AC_DEFINE(GETHOSTBYNAMERSTYLE, SYSVSTYLE, [style of gethostbyname_r functions ])
1032                 gethostbynamerstyle=SYSV
1033         ])
1034 fi
1035 if test "x$gethostbynamerstyle" = "x"; then
1036         AC_TRY_LINK([
1037 #include <stdio.h>
1038 #include <netdb.h>
1039 ], [ gethostbyname(NULL)  ], [
1040                 AC_DEFINE(GETHOSTBYNAMERSTYLE, BSDSTYLE, [style of gethostbyname_r functions ])
1041                 gethostbynamerstyle=BSD
1042         ])
1043 fi
1044
1045 if test "x$gethostbynamerstyle" = "x"; then
1046         AC_MSG_RESULT([none!  It must not exist, here.])
1047 else
1048         AC_MSG_RESULT([${gethostbynamerstyle}-style])
1049 fi
1050
1051 if test "x$gethostbynamerstyle" = "xBSD"; then
1052         AC_MSG_WARN([ ****** BSD-style gethostbyname might NOT be thread-safe! ****** ])
1053 fi
1054
1055 dnl check for non-posix solaris ctime_r (extra buflen int arg)
1056 AC_DEFINE(POSIXSTYLE, [1], [Posix-Style ctime_r])
1057 AC_DEFINE(SOLARISSTYLE, [2], [Solaris-Style ctime_r])
1058 ctimerstyle=""
1059 AC_MSG_CHECKING([ctime_r() syntax])
1060 AC_TRY_LINK([
1061 #include <time.h>
1062 ], [ ctime_r(NULL, NULL, 0) ], [
1063         AC_DEFINE(CTIMERSTYLE, SOLARISSTYLE, [style of ctime_r function])
1064         ctimerstyle="SOLARIS"
1065 ])
1066 if test "x$ctimerstyle" = "x"; then
1067         AC_TRY_LINK([
1068 #include <time.h>
1069 ], [ ctime_r(NULL, NULL) ], [
1070                 AC_DEFINE(CTIMERSTYLE, POSIXSTYLE, [style of ctime_r function])
1071                 ctimerstyle="POSIX"
1072         ])
1073 fi
1074
1075 if test "x$ctimerstyle" = "x"; then
1076         AC_MSG_RESULT([none!  It must not exist, here.])
1077 else
1078         AC_MSG_RESULT([${ctimerstyle}-style])
1079 fi
1080
1081 AC_SUBST(HOSTINFO, $host)
1082
1083 dnl #############################################################
1084 dnl #
1085 dnl #  8. Checks for system services
1086 dnl #
1087 dnl #############################################################
1088
1089 dnl #
1090 dnl # Figure out where libtool is located,
1091 dnl #
1092 top_builddir=`pwd`
1093 export top_builddir
1094 AC_MSG_RESULT([top_builddir=$top_builddir])
1095 dnl # AC_SUBST(top_builddir)
1096 AC_SUBST(LIBLTDL)
1097 AC_SUBST(INCLTDL)
1098
1099 dnl import libtool stuff
1100
1101 dnl #############################################################
1102 dnl #
1103 dnl #  Configure in any module directories.
1104 dnl #
1105 dnl #############################################################
1106
1107 mysubdirs="$LIBLTDLPATH"
1108 if test "x$EXPERIMENTAL" = "xyes"; then
1109   bar=`ls -1 "${srcdir}"/src/modules/rlm_*/configure | sed 's%/configure%%'`
1110   dnl # get rid of LF's.
1111   mysubdirs=`echo $mysubdirs $bar`
1112 else
1113   dnl #
1114   dnl # Find 'configure' in ONLY the stable modules
1115   dnl #
1116   for bar in `cat "${srcdir}"/src/modules/stable`; do
1117     if test -f "${srcdir}"/src/modules/$bar/configure; then
1118       mysubdirs="$mysubdirs src/modules/$bar"
1119     fi
1120   done
1121 fi
1122
1123 dnl ############################################################
1124 dnl # make modules by list
1125 dnl #############################################################
1126 if test "x$EXPERIMENTAL" = "xyes"; then
1127   for foo in `ls -1 "${srcdir}"/src/modules | grep rlm_`; do
1128     MODULES="$MODULES $foo"
1129   done
1130 else
1131    dnl #
1132    dnl # make ONLY the stable modules
1133    dnl #
1134    for foo in `cat "${srcdir}"/src/modules/stable`; do
1135     MODULES="$MODULES $foo"
1136    done
1137 fi
1138
1139 dnl #
1140 dnl #  Don't change the variable name here.  Autoconf goes bonkers
1141 dnl #  if you do.
1142 dnl #
1143 AC_CONFIG_SUBDIRS($LTDL_SUBDIRS $mysubdirs)
1144 AC_SUBST(MODULES)
1145
1146 dnl #############################################################
1147 dnl #
1148 dnl #  And finally, output the results.
1149 dnl #
1150 dnl #############################################################
1151
1152 AC_CONFIG_COMMANDS([stamp-h], [echo timestamp > src/include/stamp-h])
1153 AC_CONFIG_COMMANDS([build-radpaths-h], [(cd ./src/include && /bin/sh ./build-radpaths-h)])
1154 AC_CONFIG_COMMANDS([main-chmod], [(cd ./src/main   && chmod +x checkrad.pl radlast radtest)])
1155 AC_CONFIG_COMMANDS([scripts-chmod], [(cd ./scripts    && chmod +x rc.radiusd radwatch check-radiusd-config radiusd.cron.daily radiusd.cron.monthly cryptpasswd)])
1156
1157 dnl #
1158 dnl #  Substitute whatever libraries we found to be necessary
1159 dnl #
1160 AC_SUBST(LIBS)
1161 AC_SUBST(INSTALLSTRIP)
1162
1163 USE_SHARED_LIBS=$enable_shared
1164 AC_SUBST(USE_SHARED_LIBS)
1165 USE_STATIC_LIBS=$enable_static
1166 AC_SUBST(USE_STATIC_LIBS)
1167 AC_SUBST(STATIC_MODULES)
1168 AC_SUBST(RADIUSD_MAJOR_VERSION)
1169 AC_SUBST(RADIUSD_MINOR_VERSION)
1170 AC_SUBST(RADIUSD_VERSION)
1171
1172 AC_OUTPUT(\
1173         ./Make.inc \
1174         ./src/include/build-radpaths-h \
1175         ./src/main/Makefile \
1176         ./src/main/checkrad.pl \
1177         ./src/main/radlast \
1178         ./src/main/radtest \
1179         ./scripts/rc.radiusd \
1180         ./scripts/radwatch \
1181         ./scripts/check-radiusd-config \
1182         ./scripts/radiusd.cron.daily \
1183         ./scripts/radiusd.cron.monthly \
1184         ./scripts/cryptpasswd \
1185         ./raddb/dictionary \
1186         ./raddb/radiusd.conf
1187 )