configure.in

   1 dnl #############################################################
   2 dnl #
   3 dnl #  For information about autoconf, see:
   4 dnl #
   5 dnl #  http://www.gnu.org/software/autoconf/
   6 dnl #
   7 dnl #  The recommended order is:
   8 dnl #
   9 dnl #  AC_INIT(file)
  10 dnl #  0. checks for compiler, libtool, and command line options
  11 dnl #  1. checks for programs
  12 dnl #  2. checks for libraries
  13 dnl #  3. checks for header files
  14 dnl #  4. checks for typedefs
  15 dnl #  5. checks for structures and functions
  16 dnl #  6. checks for compiler characteristics
  17 dnl #  7. checks for library functions
  18 dnl #  8. checks for system services
  19 dnl #  AC_OUTPUT([file...])
  20 dnl #
  21 dnl #############################################################
  22
  23 AC_PREREQ([2.59])
  24 export CFLAGS LIBS LDFLAGS CPPFLAGS
  25 AC_INIT(src/main/radiusd.c)
  26 AC_CONFIG_HEADER(src/include/autoconf.h)
  27 AC_REVISION($Revision$)dnl
  28
  29 dnl # The version of the software
  30 RADIUSD_VERSION=`cat VERSION`
  31 RADIUSD_MAJOR_VERSION=`cat VERSION | sed 's/\..*//'`
  32 RADIUSD_MINOR_VERSION=`cat VERSION | sed 's/^2\.//'`
  33 PACKAGE=freeradius
  34
  35 dnl #############################################################
  36 dnl #
  37 dnl #  0. Checks for compiler, libtool, and command line options.
  38 dnl #
  39 dnl #############################################################
  40
  41 dnl Check for GNU cc
  42 AC_PROG_CC
  43 AC_PROG_CXX
  44
  45 dnl #
  46 dnl # check for AIX, to allow us to use some BSD functions
  47 dnl # must be before macros that call the compiler.
  48 dnl #
  49 AC_AIX
  50
  51 AC_PROG_GCC_TRADITIONAL
  52 AC_PROG_CC_SUNPRO
  53 AC_PROG_RANLIB
  54
  55 dnl Compile in large (2G+) file support.
  56 AC_SYS_LARGEFILE
  57
  58 dnl # check for system bytesex
  59 dnl # AC_DEFINES WORDS_BIGENDIAN
  60 AC_C_BIGENDIAN
  61
  62 dnl Find GNU Make.
  63 AC_CHECK_PROG(GMAKE, gmake, yes, no)
  64 if test $GMAKE = no; then
  65   AC_PATH_PROG(MAKE, make, /usr/local/bin/make)
  66 else
  67   AC_PATH_PROG(MAKE, gmake, /usr/local/gnu/bin/make)
  68 fi
  69 makever=`$ac_cv_path_MAKE --version 2>&1 | grep "GNU Make"`
  70 if test -z "$makever"; then
  71   AC_MSG_ERROR(GNU Make is not installed.  Please download and install it
  72                 from ftp://prep.ai.mit.edu/pub/gnu/make/ before continuing.)
  73 fi
  74
  75 dnl libltdl is installable
  76 AC_LIBLTDL_INSTALLABLE
  77
  78 dnl tell Makefile to build ltdl if needed
  79 if test x"$enable_ltdl_install" = x"yes"; then
  80   LTDL_SUBDIRS=libltdl
  81 fi
  82 AC_SUBST(LTDL_SUBDIRS)
  83
  84 dnl use system-wide libtool, if it exists
  85 AC_ARG_WITH(system-libtool,
  86 [  --with-system-libtool              try to use libtool installed in your system [default=use our own]],
  87 [ AC_PATH_PROG(LIBTOOL, libtool,,$PATH:/usr/local/bin) ],
  88 [
  89   LIBTOOL="`pwd`/libtool"
  90   AC_SUBST(LIBTOOL)
  91   dnl ensure that we're looking for dlopen
  92   AC_LIBTOOL_DLOPEN
  93
  94   dnl Figure out how to build shared libraries
  95   AC_PROG_LIBTOOL
  96 ])
  97
  98
  99 dnl Put this in later, when all distributed modules use autoconf.
 100 dnl AC_ARG_WITH(disablemodulefoo,
 101 dnl [  --without-rlm_foo       Disables module compilation.  Module list:]
 102 dnl esyscmd([find src/modules -type d -name rlm_\* -print |\
 103 dnl     sed -e 's%src/modules/.*/% (sub)- %; s%.*/%- %' |\
 104 dnl     awk '{print "                            "$0}']))
 105
 106 AC_ARG_ENABLE(strict-dependencies,
 107 [  --enable-strict-dependencies  Fail configure on lack of module dependancy.])
 108
 109 dnl extra argument: --with-docdir
 110 docdir='${datadir}/doc/freeradius'
 111 AC_MSG_CHECKING(docdir)
 112 AC_ARG_WITH(docdir,
 113 [  --with-docdir=DIR       Directory for documentation [DATADIR/doc/freeradius] ],
 114 [ case "$withval" in
 115     no)
 116         docdir=no
 117         ;;
 118     yes)
 119         ;;
 120     [[\\/$]]* | ?:[[\\/]]* )
 121         docdir="$withval"
 122         ;;
 123     *)
 124         AC_MSG_ERROR([expected an absolute directory name for --with-docdir: $withval])
 125         ;;
 126   esac ]
 127 )
 128 AC_SUBST(docdir)
 129 AC_MSG_RESULT($docdir)
 130 if test "x$docdir" = xno; then
 131         AC_MSG_WARN(Documentation files will NOT be installed.)
 132 fi
 133
 134 dnl extra argument: --with-logdir
 135 logdir='${localstatedir}/log/radius'
 136 AC_MSG_CHECKING(logdir)
 137 AC_ARG_WITH(logdir,
 138 [  --with-logdir=DIR       Directory for logfiles [LOCALSTATEDIR/log/radius] ],
 139 [ case "$withval" in
 140     no)
 141         AC_MSG_ERROR(Need logdir)
 142         ;;
 143     yes)
 144         ;;
 145     [[\\/$]]* | ?:[[\\/]]* )
 146         logdir="$withval"
 147         ;;
 148     *)
 149         AC_MSG_ERROR([expected an absolute directory name for --with-logdir: $withval])
 150         ;;
 151   esac ]
 152 )
 153 AC_SUBST(logdir)
 154 AC_MSG_RESULT($logdir)
 155
 156 dnl extra argument: --with-radacctdir
 157 radacctdir='${logdir}/radacct'
 158 AC_MSG_CHECKING(radacctdir)
 159 AC_ARG_WITH(radacctdir,
 160 [  --with-radacctdir=DIR   Directory for detail files [LOGDIR/radacct] ],
 161 [ case "$withval" in
 162     no)
 163         AC_MSG_ERROR(Need radacctdir)
 164         ;;
 165     yes)
 166         ;;
 167     [[\\/$]]* | ?:[[\\/]]* )
 168         radacctdir="$withval"
 169         ;;
 170     *)
 171         AC_MSG_ERROR([expected an absolute directory name for --with-radacctdir: $withval])
 172         ;;
 173   esac ]
 174 )
 175 AC_SUBST(radacctdir)
 176 AC_MSG_RESULT($radacctdir)
 177
 178 dnl extra argument: --with-raddbdir
 179 raddbdir='${sysconfdir}/raddb'
 180 AC_MSG_CHECKING(raddbdir)
 181 AC_ARG_WITH(raddbdir,
 182 [  --with-raddbdir=DIR     Directory for config files [SYSCONFDIR/raddb] ],
 183 [ case "$withval" in
 184     no)
 185         AC_MSG_ERROR(Need raddbdir)
 186         ;;
 187     yes)
 188         ;;
 189     [[\\/$]]* | ?:[[\\/]]* )
 190         raddbdir="$withval"
 191         ;;
 192     *)
 193         AC_MSG_ERROR([expected an absolute directory name for --with-raddbdir: $withval])
 194         ;;
 195   esac ]
 196 )
 197 AC_SUBST(raddbdir)
 198 AC_MSG_RESULT($raddbdir)
 199
 200 dnl extra argument: --with-ascend-binary
 201 ASCEND_BINARY=yes
 202 AC_ARG_WITH(ascend-binary,
 203 [  --with-ascend-binary    Include support for Ascend binary filter attributes (default=yes)],
 204 [ case "$withval" in
 205     yes)
 206         ;;
 207     *)
 208         ASCEND_BINARY=""
 209   esac ]
 210 )
 211 if test "X$ASCEND_BINARY" = "Xyes"; then
 212   AC_DEFINE(ASCEND_BINARY, [], [Include support for Ascend binary filter attributes])
 213 fi
 214
 215 dnl extra argument: --with-threads
 216 WITH_THREADS=yes
 217 AC_ARG_WITH(threads,
 218 [  --with-threads          Use threads, if available.  (default=yes) ],
 219 [ case "$withval" in
 220     yes)
 221         ;;
 222     *)
 223         WITH_THREADS=""
 224   esac ]
 225 )
 226
 227 dnl extra argument: --with-vmps
 228 WITH_VMPS=yes
 229 AC_ARG_WITH(vmps,
 230 [  --with-vmps             Compile in VMPS support. (default=yes)],
 231 [ case "$withval" in
 232     yes)
 233         ;;
 234     *)
 235         WITH_VMPS=no
 236   esac ]
 237 )
 238 if test "x$WITH_VMPS" = "xyes"; then
 239         AC_DEFINE(WITH_VMPS, [1], [define if you want VMPS support])
 240 fi
 241
 242 dnl extra argument: --with-dhcp
 243 AC_ARG_WITH(dhcp,
 244 [  --with-dhcp             Compile in DHCP support. (default=no)],
 245 [ case "$withval" in
 246     yes)
 247         AC_DEFINE(WITH_DHCP, [1], [Include experimental support for DHCP])
 248         ;;
 249     *)
 250         ;;
 251   esac ]
 252 )
 253
 254
 255 dnl #
 256 dnl #  Allow the user to specify a list of modules to be linked
 257 dnl #  statically to the server.
 258 dnl #
 259 STATIC_MODULES=
 260 AC_ARG_WITH(static_modules,
 261 [  --with-static-modules=QUOTED-MODULE-LIST],[
 262   for i in $withval; do
 263     STATIC_MODULES="$STATIC_MODULES -dlpreopen ../modules/rlm_$i/rlm_$i.la"
 264   done
 265 ])
 266
 267 MODULES=
 268 AC_ARG_WITH(modules,
 269 [ --with-modules=QUOTED-MODULE-LIST],[
 270  for i in $withval; do
 271    MODULES="$MODULES $i"
 272  done
 273 ])
 274
 275 dnl #
 276 dnl #  Enable developer C compiler warnings
 277 dnl #
 278 AC_ARG_ENABLE(developer,
 279 [  --enable-developer               Enables features of interest to developers.],
 280 [ case "$enableval" in
 281     no)
 282         developer=no
 283         ;;
 284     *)
 285         developer=yes
 286   esac ]
 287 )
 288
 289 if test "x$developer" != "xno" -a -d $srcdir/CVS; then
 290   dnl turn on the developer flag when taken from a CVS checkout (not a release)
 291   developer="yes"
 292 fi
 293
 294 dnl extra argument: --with-experimental-modules
 295 EXPERIMENTAL=
 296 AC_ARG_WITH(experimental-modules,
 297 [  --with-experimental-modules      Use experimental and unstable modules. (default=no) ],
 298 [ case "$withval" in
 299     yes)
 300         EXPERIMENTAL=yes
 301         ;;
 302     *)
 303   esac ]
 304 )
 305
 306 dnl extra argument: --with-openssl
 307 WITH_OPENSSL=yes
 308 AC_ARG_WITH(openssl,
 309 [  --with-openssl                   Use OpenSSL. (default=yes)],
 310 [ case "$withval" in
 311     no)
 312         WITH_OPENSSL=no
 313         ;;
 314     *)
 315         WITH_OPENSSL=yes
 316         ;;
 317   esac ]
 318 )
 319
 320 dnl #
 321 dnl # extra argument: --with-openssl-includes=dir
 322 dnl #
 323 OPENSSL_INCLUDE_DIR=
 324 AC_ARG_WITH(openssl-includes,
 325 [  --with-openssl-includes=DIR      Directory to look for OpenSSL include files],
 326 [ case "$withval" in
 327     *) OPENSSL_INCLUDE_DIR="$withval"
 328         ;;
 329   esac ]
 330 )
 331
 332 dnl #
 333 dnl # extra argument: --with-openssl-libraries=dir
 334 dnl #
 335 OPENSSL_LIB_DIR=
 336 AC_ARG_WITH(openssl-libraries,
 337 [  --with-openssl-libraries=DIR     Directory to look for OpenSSL library files],
 338 [ case "$withval" in
 339     *) OPENSSL_LIB_DIR="$withval"
 340         ;;
 341   esac ]
 342 )
 343
 344 dnl #
 345 dnl #  These next two arguments don't actually do anything.  They're
 346 dnl #  place holders so that the top-level configure script can tell
 347 dnl #  the user how to configure lower-level modules
 348 dnl #
 349
 350 dnl #
 351 dnl # extra argument: --with-rlm-FOO-lib-dir
 352 dnl #
 353 AC_ARG_WITH(rlm-FOO-lib-dir,
 354 [  --with-rlm-FOO-lib-dir=DIR       Directory to look for library files used by module FOO],
 355 [ case "$withval" in
 356     *)
 357         ;;
 358   esac ]
 359 )
 360
 361 dnl #
 362 dnl # extra argument: --with-rlm-FOO-include-dir
 363 dnl #
 364 AC_ARG_WITH(rlm-FOO-include-dir,
 365 [  --with-rlm-FOO-include-dir=DIR   Directory to look for include files used by module FOO],
 366 [ case "$withval" in
 367     *)
 368         ;;
 369   esac ]
 370 )
 371
 372 dnl See what include-style is used by the make program.
 373 dnl AC_MSG_CHECKING(include style for make)
 374 dnl echo "include /dev/null" > testmake.$$
 375 dnl echo "all:" >> testmake.$$
 376 dnl make -f testmake.$$ >/dev/null 2>&1
 377 dnl if test $? = 0
 378 dnl then
 379 dnl     INCLUDE=include
 380 dnl     IQUOTE=
 381 dnl else
 382 dnl     INCLUDE=.include
 383 dnl     IQUOTE='"'
 384 dnl fi
 385 dnl rm -f testmake.$$
 386 dnl AC_MSG_RESULT(" $INCLUDE")
 387 dnl AC_SUBST(INCLUDE)
 388 dnl AC_SUBST(IQUOTE)
 389
 390 dnl extra argument: --with-udpfromto
 391 WITH_UDPFROMTO=no
 392 AC_ARG_WITH(udpfromto,
 393 [  --with-udpfromto        Compile in UDPFROMTO support. (default=no)],
 394 [ case "$withval" in
 395     yes)
 396         WITH_UDPFROMTO=yes
 397         ;;
 398     *)
 399         WITH_UDPFROMTO=no
 400   esac ]
 401 )
 402
 403 if test "x$WITH_UDPFROMTO" = "xyes"; then
 404         AC_DEFINE(WITH_UDPFROMTO, [], [define if you want udpfromto])
 405 fi
 406
 407 dnl #############################################################
 408 dnl #
 409 dnl #  1. Checks for programs
 410 dnl #
 411 dnl #############################################################
 412
 413 CHECKRAD=checkrad.pl
 414 AC_PATH_PROG(PERL, perl, /usr/local/bin/perl)
 415 if test "x$ac_cv_path_PERL" = "x"; then
 416   AC_MSG_WARN(perl not found - Simultaneous-Use and checkrad.pl may not work)
 417 fi
 418 AC_PATH_PROG(SNMPGET, snmpget)
 419 if test "x$ac_cv_path_SNMPGET" = "x"; then
 420   AC_MSG_WARN(snmpget not found - Simultaneous-Use and checkrad.pl may not work)
 421 fi
 422
 423 AC_PATH_PROG(SNMPWALK, snmpwalk)
 424 if test "x$ac_cv_path_SNMPWALK" = "x"; then
 425   AC_MSG_WARN(snmpwalk not found - Simultaneous-Use and checkrad.pl may not work)
 426 fi
 427
 428 AC_PATH_PROG(RUSERS, rusers, /usr/bin/rusers)
 429
 430 dnl FIXME This is truly gross.
 431 missing_dir=`cd $ac_aux_dir && pwd`
 432 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
 433 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
 434 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
 435
 436 AC_PATH_PROG(LOCATE,locate)
 437 AC_PATH_PROG(DIRNAME,dirname)
 438 AC_PATH_PROG(GREP,grep)
 439
 440 dnl #############################################################
 441 dnl #
 442 dnl #  2. Checks for libraries
 443 dnl #
 444 dnl #############################################################
 445
 446 dnl If using pthreads, check for -lpthread (posix) or -lc_r (*BSD)
 447 old_CFLAGS=$CFLAGS
 448 if test "x$WITH_THREADS" = "xyes"; then
 449   if test $ac_cv_prog_suncc = "yes"; then
 450     CFLAGS="$CFLAGS -mt"
 451   fi
 452
 453   AC_CHECK_HEADERS(pthread.h, [], [ WITH_THREADS="no" ])
 454
 455 dnl #
 456 dnl # pthread stuff is usually in -lpthread
 457 dnl # or in -lc_r, on *BSD
 458 dnl #
 459 dnl # On Some systems, we need extra pre-processor flags, to get them to
 460 dnl # to do the threading properly.
 461 dnl #
 462   AC_CHECK_LIB(pthread, pthread_create,
 463                 [ CFLAGS="$CFLAGS -D_REENTRANT -D_POSIX_PTHREAD_SEMANTICS"
 464                   LIBS="$LIBS -lpthread" ],
 465                 AC_CHECK_LIB(c_r, pthread_create,
 466                             [ CFLAGS="$CFLAGS -pthread -D_THREAD_SAFE" ],
 467                             [ WITH_THREADS="no" ]
 468                             )
 469                 )
 470 fi
 471
 472 dnl #
 473 dnl # If we have NO pthread libraries, remove any knowledge of threads.
 474 dnl #
 475 if test "x$WITH_THREADS" != "xyes"; then
 476   CFLAGS=$old_CFLAGS
 477   ac_cv_header_pthread_h="no"
 478   WITH_THREADS=no
 479 else
 480   dnl #
 481   dnl #  We need sem_init() and friends, as they're the friendliest
 482   dnl #  semaphore functions for threading.
 483   dnl #
 484   dnl # HP/UX requires linking with librt, too, to get the sem_* symbols.
 485   dnl # Some systems have them in -lsem
 486   dnl # Solaris has them in -lposix4
 487   dnl # NetBSD has them in -lsemaphore
 488
 489   AC_SEARCH_LIBS(sem_init, pthread sem posix4 rt semaphore,
 490         [],
 491         [AC_MSG_ERROR(-lsem not found.  You may want to download it from ftp://ftp.to.gd-es.com/pub/BSDI/libsem.tar.bz2 or ftp://ftp.freeradius.org/pub/radius/contrib/libsem.tar.gz)]
 492    )
 493 fi
 494
 495 dnl Check if we need -lsocket
 496 AC_CHECK_LIB(socket, getsockname)
 497
 498 dnl Check for -lresolv
 499 dnl This library may be needed later.
 500 AC_CHECK_LIB(resolv, inet_aton)
 501
 502 dnl Check if we need -lnsl. Usually if we want to
 503 dnl link against -lsocket we need to include -lnsl as well.
 504 AC_CHECK_LIB(nsl, inet_ntoa)
 505
 506 dnl Check for OpenSSL libraries.
 507 OPENSSL_LIBS=
 508 if test "x$WITH_OPENSSL" = xyes; then
 509   old_LIBS=$LIBS
 510   if test "x$OPENSSL_LIB_DIR" != "x"; then
 511     LIBS="-L$OPENSSL_LIB_DIR $LIBS"
 512   fi
 513   AC_CHECK_LIB(crypto, DH_new,
 514     [
 515         LIBS="-lcrypto $LIBS"
 516         AC_DEFINE(HAVE_LIBCRYPTO, 1,
 517             [Define to 1 if you have the `crypto' library (-lcrypto).])
 518         AC_CHECK_LIB(ssl, SSL_new,
 519             [
 520                 AC_DEFINE(HAVE_LIBSSL, 1,
 521                     [Define to 1 if you have the `ssl' library (-lssl).])
 522                 if test "x$OPENSSL_LIB_DIR" != "x"; then
 523                     OPENSSL_LIBS="-L$OPENSSL_LIB_DIR"
 524                 fi
 525                 OPENSSL_LIBS="$OPENSSL_LIBS -lcrypto -lssl -lcrypto"
 526             ], [])
 527     ], [])
 528   LIBS=$old_LIBS
 529 fi
 530
 531 AC_CHECK_LIB(ws2_32, htonl)
 532
 533 dnl Check the pcap library for the RADIUS sniffer.
 534 PCAP_LIBS=
 535 AC_CHECK_LIB(pcap, pcap_open_live,
 536         [ PCAP_LIBS="-lpcap"
 537         AC_DEFINE(HAVE_LIBPCAP, 1,
 538                 [Define to 1 if you have the `pcap' library (-lpcap).])
 539         ],
 540         [ AC_MSG_WARN([pcap library not found, silently disabling the RADIUS sniffer.]) ])
 541
 542 dnl #############################################################
 543 dnl #
 544 dnl #  3. Checks for header files
 545 dnl #
 546 dnl #############################################################
 547
 548 dnl #
 549 dnl # Interix requires us to set -D_ALL_SOURCE, otherwise
 550 dnl # getopt will be #included, but won't link.  <sigh>
 551 dnl #
 552 dnl #
 553 case "$host" in
 554 *-interix*)
 555         CFLAGS="$CFLAGS -D_ALL_SOURCE"
 556         ;;
 557 *-darwin*)
 558         CFLAGS="$CFLAGS -DDARWIN"
 559         LIBS="-framework DirectoryService $LIBS"
 560         ;;
 561 esac
 562
 563 AC_HEADER_DIRENT
 564 AC_HEADER_STDC
 565 AC_HEADER_TIME
 566 AC_HEADER_SYS_WAIT
 567
 568 AC_CHECK_HEADERS( \
 569         unistd.h \
 570         crypt.h \
 571         errno.h \
 572         resource.h \
 573         sys/resource.h \
 574         getopt.h \
 575         malloc.h \
 576         utmp.h \
 577         utmpx.h \
 578         signal.h \
 579         sys/select.h \
 580         syslog.h \
 581         inttypes.h \
 582         stdint.h \
 583         stdio.h \
 584         netdb.h \
 585         semaphore.h \
 586         arpa/inet.h \
 587         netinet/in.h \
 588         sys/types.h \
 589         sys/socket.h \
 590         winsock.h \
 591         sys/time.h \
 592         sys/wait.h \
 593         sys/security.h \
 594         fcntl.h \
 595         sys/fcntl.h \
 596         sys/prctl.h \
 597         glob.h \
 598         prot.h \
 599         pwd.h \
 600         grp.h \
 601         sia.h \
 602         siad.h
 603 )
 604
 605 dnl FreeBSD requires sys/socket.h before net/if.h
 606 AC_CHECK_HEADERS(net/if.h, [], [],
 607 [#ifdef HAVE_SYS_SOCKET_H
 608 # include <sys/socket.h>
 609 # endif
 610 ])
 611
 612 REGEX=no
 613 AC_CHECK_HEADER(regex.h, AC_DEFINE(HAVE_REGEX_H, [], [define this if we have the <regex.h> header file]))
 614 if test "x$ac_cv_header_regex_h" = "xyes"; then
 615   REGEX_EXTENDED=no
 616   REGEX=yes
 617   AC_EGREP_CPP(yes,
 618     [#include <regex.h>
 619      #ifdef REG_EXTENDED
 620        yes
 621      #endif
 622      ], [AC_DEFINE(HAVE_REG_EXTENDED, [], [define this if we have REG_EXTENDED (from <regex.h>)]) REGEX_EXTENDED=yes])
 623 fi
 624 AC_SUBST(REGEX)
 625 AC_SUBST(REGEX_EXTENDED)
 626
 627 dnl #
 628 dnl #  other checks which require headers
 629 dnl #
 630 if test "x$ac_cv_header_sys_security_h" = "xyes" && test "x$ac_cv_header_prot_h" = "xyes"
 631 then
 632   AC_DEFINE(OSFC2, [], [define if you have OSFC2 authentication])
 633 fi
 634
 635 if test "x$ac_cv_header_sia_h" = "xyes" && test "x$ac_cv_header_siad_h" = "xyes"
 636 then
 637   AC_DEFINE(OSFSIA, [], [define if you have OSFSIA authentication])
 638 fi
 639
 640 dnl Check for OpenSSL includes.
 641 OPENSSL_INCLUDE="-DNO_OPENSSL"
 642 if test "x$WITH_OPENSSL" = xyes; then
 643   if test "x$OPENSSL_LIBS" = "x"; then
 644     AC_MSG_NOTICE([skipping test for openssl/ssl.h])
 645   else
 646     old_CPPFLAGS=$CPPFLAGS
 647     if test "x$OPENSSL_INCLUDE_DIR" != "x"; then
 648         CPPFLAGS="$CPPFLAGS -I$OPENSSL_INCLUDE_DIR"
 649     fi
 650     dnl # stupid RedHat shit
 651     CPPFLAGS="$CPPFLAGS -DOPENSSL_NO_KRB5"
 652     AC_CHECK_HEADERS( \
 653         openssl/ssl.h \
 654         openssl/crypto.h \
 655         openssl/err.h \
 656         openssl/evp.h \
 657         openssl/engine.h,
 658         [],
 659         OPENSSL_LIBS=
 660     )
 661     if test "x$OPENSSL_LIBS" != "x"; then
 662         AC_MSG_CHECKING([for OpenSSL version >= 0.9.7])
 663         AC_EGREP_CPP(yes,
 664             [#include <openssl/crypto.h>
 665              #if (OPENSSL_VERSION_NUMBER >= 0x00907000L)
 666              yes
 667              #endif
 668             ], goodssl="yes")
 669         if test "x$goodssl" != "xyes"; then
 670             AC_MSG_RESULT(no)
 671             OPENSSL_LIBS=
 672         else
 673             AC_MSG_RESULT(yes)
 674             if test "x$OPENSSL_INCLUDE_DIR" != "x"; then
 675                 OPENSSL_INCLUDE="-I$OPENSSL_INCLUDE_DIR -DOPENSSL_NO_KRB5"
 676             else
 677                 OPENSSL_INCLUDE="-DOPENSSL_NO_KRB5"
 678             fi
 679         fi
 680     fi
 681     CPPFLAGS=$old_CPPFLAGS
 682   fi
 683 fi
 684 AC_SUBST(OPENSSL_INCLUDE)
 685 AC_SUBST(OPENSSL_LIBS)
 686 export OPENSSL_LIBS
 687
 688 dnl Check the pcap includes for the RADIUS sniffer.
 689 if test "x$PCAP_LIBS" = x; then
 690     AC_MSG_NOTICE([skipping test for pcap.h.])
 691 else
 692     AC_CHECK_HEADER(pcap.h,
 693         AC_DEFINE(HAVE_PCAP_H, 1,
 694                 [Define to 1 if you have the <pcap.h> header file.]),
 695         [ PCAP_LIBS=
 696         AC_MSG_WARN([pcap.h not found, silently disabling the RADIUS sniffer.])
 697         ])
 698 fi
 699 AC_SUBST(PCAP_LIBS)
 700
 701 dnl #############################################################
 702 dnl #
 703 dnl #  4. Checks for typedefs
 704 dnl #
 705 dnl #############################################################
 706
 707 dnl #
 708 dnl # Ensure that these are defined
 709 dnl #
 710 AC_TYPE_OFF_T
 711 AC_TYPE_PID_T
 712 AC_TYPE_SIZE_T
 713 AC_TYPE_UID_T
 714
 715 dnl check for socklen_t
 716 FR_CHECK_TYPE_INCLUDE([
 717 #ifdef HAVE_SYS_TYPES_H
 718 #include <sys/types.h>
 719 #endif
 720 #ifdef HAVE_SYS_SOCKET_H
 721 #include <sys/socket.h>
 722 #endif
 723 ],socklen_t, int, [socklen_t is generally 'int' on systems which don't use it])
 724
 725 dnl check for uint8_t
 726 FR_CHECK_TYPE_INCLUDE([
 727 #ifdef HAVE_INTTYPES_H
 728 #include <inttypes.h>
 729 #endif
 730 #ifdef HAVE_STDINT_H
 731 #include <stdint.h>
 732 #endif
 733 ],uint8_t, unsigned char, [uint8_t should be the canonical 'octet' for network traffic])
 734
 735 dnl check for uint16_t
 736 FR_CHECK_TYPE_INCLUDE([
 737 #ifdef HAVE_INTTYPES_H
 738 #include <inttypes.h>
 739 #endif
 740 #ifdef HAVE_STDINT_H
 741 #include <stdint.h>
 742 #endif
 743 ],uint16_t, unsigned short, [uint16_t should be the canonical '2 octets' for network traffic])
 744
 745 dnl check for uint32_t
 746 FR_CHECK_TYPE_INCLUDE([
 747 #ifdef HAVE_INTTYPES_H
 748 #include <inttypes.h>
 749 #endif
 750 #ifdef HAVE_STDINT_H
 751 #include <stdint.h>
 752 #endif
 753 ],uint32_t, unsigned int, [uint32_t should be the canonical 'network integer])
 754
 755 AC_CHECK_TYPE(struct in6_addr, AC_DEFINE(HAVE_STRUCT_IN6_ADDR, 1, [IPv6 address structure]), [], [
 756 #ifdef HAVE_NETINET_IN_H
 757 #include <netinet/in.h>
 758 #endif
 759 ])
 760
 761 AC_CHECK_TYPE(struct sockaddr_storage, AC_DEFINE(HAVE_STRUCT_SOCKADDR_STORAGE, 1, [Generic socket addresses]), [], [
 762 #ifdef HAVE_NETINET_IN_H
 763 #include <netinet/in.h>
 764 #endif
 765 #ifdef HAVE_SYS_SOCKET_H
 766 #include <sys/socket.h>
 767 #endif
 768 ])
 769
 770 AC_CHECK_TYPE(struct sockaddr_in6, AC_DEFINE(HAVE_STRUCT_SOCKADDR_IN6, 1, [IPv6 socket addresses]), [], [
 771 #ifdef HAVE_NETINET_IN_H
 772 #include <netinet/in.h>
 773 #endif
 774 ])
 775
 776 AC_CHECK_TYPE(struct addrinfo, AC_DEFINE(HAVE_STRUCT_ADDRINFO, 1, [Generic DNS lookups]), [], [
 777 #ifdef HAVE_SYS_TYPES_H
 778 #include <sys/types.h>
 779 #endif
 780 #ifdef HAVE_SYS_SOCKET_H
 781 #include <sys/socket.h>
 782 #endif
 783 #ifdef HAVE_NETDB_H
 784 #include <netdb.h>
 785 #endif
 786 ])
 787
 788 dnl #############################################################
 789 dnl #
 790 dnl #  5. Checks for structures and functions
 791 dnl #
 792 dnl #############################################################
 793 AC_CHECK_FUNCS( \
 794         getopt_long \
 795         lockf \
 796         strsignal \
 797         sigaction \
 798         sigprocmask \
 799         pthread_sigmask \
 800         snprintf \
 801         vsnprintf \
 802         setsid \
 803         strncasecmp \
 804         strcasecmp \
 805         localtime_r \
 806         ctime_r \
 807         gmtime_r \
 808         strsep \
 809         inet_aton \
 810         inet_pton \
 811         inet_ntop \
 812         setlinebuf \
 813         setvbuf \
 814         getusershell \
 815         initgroups \
 816         getaddrinfo \
 817         getnameinfo \
 818         closefrom \
 819         gettimeofday \
 820         strlcat \
 821         strlcpy
 822 )
 823 RADIUSD_NEED_DECLARATIONS( \
 824         crypt \
 825         strncasecmp \
 826         strcasecmp \
 827         inet_aton \
 828         setlinebuf \
 829         getusershell \
 830         endusershell
 831 )
 832
 833 AC_TYPE_SIGNAL
 834
 835 dnl # check if we have utmpx.h
 836 dnl # if so, check if struct utmpx has entry ut_xtime
 837 dnl # if not, set it to define ut_xtime == ut_tv.tv_sec
 838 if test "x$ac_cv_header_utmpx_h" = "xyes"
 839 then
 840  FR_CHECK_STRUCT_HAS_MEMBER([#include <utmpx.h>], [struct utmpx], ut_xtime)
 841  if test "x$ac_cv_type_struct_utmpx_has_ut_xtime" = "x"
 842  then
 843    AC_DEFINE(ut_xtime,ut_tv.tv_sec, [define to something if you don't have ut_xtime in struct utmpx])
 844  fi
 845 fi
 846
 847 dnl # struct ip_pktinfo
 848 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in_pktinfo], ipi_addr)
 849 if test "x$ac_cv_type_struct_in_pktinfo_has_ipi_addr" = "xyes"
 850 then
 851         AC_DEFINE(HAVE_IP_PKTINFO, [], [define if you have IP_PKTINFO (Linux)])
 852 fi
 853
 854 dnl # struct in6_pktinfo
 855 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in6_pktinfo], ipi6_addr)
 856 if test "x$ac_cv_type_struct_in6_pktinfo_has_ipi6_addr" = "xyes"
 857 then
 858         AC_DEFINE(HAVE_IN6_PKTINFO, [], [define if you have IN6_PKTINFO (Linux)])
 859 fi
 860
 861 dnl #############################################################
 862 dnl #
 863 dnl #  6. Checks for compiler characteristics
 864 dnl #
 865 dnl #############################################################
 866
 867 dnl #
 868 dnl # Ensure that these are defined
 869 dnl #
 870 AC_C_CONST
 871
 872 dnl #
 873 dnl # See if this is OS/2
 874 dnl #
 875 AC_MSG_CHECKING(type of OS)
 876 OS=`uname -s`
 877 AC_MSG_RESULT($OS)
 878 if test "$OS" = "OS/2"; then
 879         LIBPREFIX=
 880 else
 881         LIBPREFIX=lib
 882 fi
 883 AC_SUBST(LIBPREFIX)
 884
 885 dnl #
 886 dnl # Set Default CFLAGS
 887 dnl #
 888 if test "x$GCC" = "xyes"; then
 889     CFLAGS="$CFLAGS -Wall -D_GNU_SOURCE"
 890 fi
 891
 892 AC_MSG_CHECKING(for developer gcc flags)
 893 if test "x$developer" = "xyes" -a "x$GCC" = "xyes"; then
 894   devflags="-g -Wshadow -Wpointer-arith -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -W -Wredundant-decls -Wundef"
 895   CFLAGS="$CFLAGS $devflags"
 896   INSTALLSTRIP=""
 897   AC_MSG_RESULT(yes.  Using $devflags)
 898 else
 899   devflags=""
 900   CFLAGS="$CFLAGS -DNDEBUG"
 901   INSTALLSTRIP=""
 902   AC_MSG_RESULT(no.)
 903 fi
 904
 905 dnl #############################################################
 906 dnl #
 907 dnl #  7. Checks for library functions
 908 dnl #
 909 dnl #############################################################
 910
 911 dnl Check for libcrypt
 912 dnl We use crypt(3) which may be in libc, or in libcrypt (eg FreeBSD)
 913 AC_CHECK_LIB(crypt, crypt,
 914   CRYPTLIB="-lcrypt"
 915 )
 916 if test "$CRYPTLIB" != ""; then
 917   AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function])
 918 else
 919   AC_CHECK_FUNC(crypt, AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function]))
 920 fi
 921
 922 dnl Check for libcipher
 923 AC_CHECK_LIB(cipher, setkey,
 924    CRYPTLIB="${CRYPTLIB} -lcipher"
 925 )
 926 AC_SUBST(CRYPTLIB)
 927
 928 dnl Check the style of gethostbyaddr, in order of preference
 929 dnl GNU (_r eight args)
 930 AC_DEFINE(GNUSTYLE, [1], [GNU-Style get*byaddr_r])
 931 dnl SYSV (_r six args)
 932 AC_DEFINE(SYSVSTYLE, [2], [SYSV-Style get*byaddr_r])
 933 dnl BSD (three args, may not be thread safe)
 934 AC_DEFINE(BSDSTYLE, [3], [BSD-Style get*byaddr_r])
 935 dnl Tru64 has BSD version, but it is thread safe
 936 dnl     http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1739____.HTM
 937 dnl We need #stdio.h to define NULL on FreeBSD (at least)
 938 gethostbyaddrrstyle=""
 939 AC_MSG_CHECKING([gethostbyaddr_r() syntax])
 940 case "$host" in
 941 *-freebsd*)
 942 dnl With FreeBSD, check if there's a prototype for gethostbyaddr_r.
 943 dnl Some versions (FreeBSD 5.1?) have a symbol but no prototype - so we
 944 dnl override this test to BSDSTYLE. FreeBSD 6.2 and up have proper GNU
 945 dnl style support.
 946         AC_CHECK_DECLS([gethostbyaddr_r], [], [
 947                 AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE,
 948                         [style of gethostbyaddr_r functions ])
 949                 gethostbyaddrrstyle=BSD
 950                 AC_MSG_WARN([FreeBSD overridden to BSD-style])
 951         ], [
 952 #ifdef HAVE_NETDB_H
 953 #include <netdb.h>
 954 #endif
 955 ])
 956         ;;
 957 esac
 958 if test "x$gethostbyaddrrstyle" = "x"; then
 959         AC_TRY_LINK([
 960 #include <stdio.h>
 961 #include <netdb.h>
 962 ], [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL, NULL) ], [
 963         AC_DEFINE(GETHOSTBYADDRRSTYLE, GNUSTYLE, [style of gethostbyaddr_r functions ])
 964         gethostbyaddrrstyle=GNU
 965 ])
 966 fi
 967 if test "x$gethostbyaddrrstyle" = "x"; then
 968         AC_TRY_LINK([
 969 #include <stdio.h>
 970 #include <netdb.h>
 971 ], [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL) ] , [
 972                 AC_DEFINE(GETHOSTBYADDRRSTYLE, SYSVSTYLE, [style of gethostbyaddr_r functions ])
 973                 gethostbyaddrrstyle=SYSV
 974         ])
 975 fi
 976 if test "x$gethostbyaddrrstyle" = "x"; then
 977         AC_TRY_LINK([
 978 #include <stdio.h>
 979 #include <netdb.h>
 980 ], [ gethostbyaddr(NULL, 0, 0)  ], [
 981                 AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE, [style of gethostbyaddr_r functions ])
 982                 gethostbyaddrrstyle=BSD
 983         ])
 984 fi
 985
 986 if test "x$gethostbyaddrrstyle" = "x"; then
 987         AC_MSG_RESULT([none!  It must not exist, here.])
 988 else
 989         AC_MSG_RESULT([${gethostbyaddrrstyle}-style])
 990 fi
 991
 992 if test "x$gethostbyaddrrstyle" = "xBSD"; then
 993         AC_MSG_WARN([ ****** BSD-style gethostbyaddr might NOT be thread-safe! ****** ])
 994 fi
 995
 996 dnl Check the style of gethostbyname, in order of preference
 997 dnl GNU (_r seven args)
 998 dnl SYSV (_r five args)
 999 dnl BSD (two args, may not be thread safe)
1000 dnl Tru64 has BSD version, but it _is_ thread safe
1001 dnl     http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1946____.HTM
1002 dnl We need #stdio.h to define NULL on FreeBSD (at least)
1003 gethostbynamerstyle=""
1004 AC_MSG_CHECKING([gethostbyname_r() syntax])
1005 AC_TRY_LINK([
1006 #include <stdio.h>
1007 #include <netdb.h>
1008 ], [ gethostbyname_r(NULL, NULL, NULL, 0, NULL, NULL) ], [
1009         AC_DEFINE(GETHOSTBYNAMERSTYLE, GNUSTYLE, [style of gethostbyname_r functions ])
1010         gethostbynamerstyle=GNU
1011 ])
1012 if test "x$gethostbynamerstyle" = "x"; then
1013         AC_TRY_LINK([
1014 #include <stdio.h>
1015 #include <netdb.h>
1016 ], [ gethostbyname_r(NULL, NULL, NULL, 0, NULL) ] , [
1017                 AC_DEFINE(GETHOSTBYNAMERSTYLE, SYSVSTYLE, [style of gethostbyname_r functions ])
1018                 gethostbynamerstyle=SYSV
1019         ])
1020 fi
1021 if test "x$gethostbynamerstyle" = "x"; then
1022         AC_TRY_LINK([
1023 #include <stdio.h>
1024 #include <netdb.h>
1025 ], [ gethostbyname(NULL)  ], [
1026                 AC_DEFINE(GETHOSTBYNAMERSTYLE, BSDSTYLE, [style of gethostbyname_r functions ])
1027                 gethostbynamerstyle=BSD
1028         ])
1029 fi
1030
1031 if test "x$gethostbynamerstyle" = "x"; then
1032         AC_MSG_RESULT([none!  It must not exist, here.])
1033 else
1034         AC_MSG_RESULT([${gethostbynamerstyle}-style])
1035 fi
1036
1037 if test "x$gethostbynamerstyle" = "xBSD"; then
1038         AC_MSG_WARN([ ****** BSD-style gethostbyname might NOT be thread-safe! ****** ])
1039 fi
1040
1041 dnl check for non-posix solaris ctime_r (extra buflen int arg)
1042 AC_DEFINE(POSIXSTYLE, [1], [Posix-Style ctime_r])
1043 AC_DEFINE(SOLARISSTYLE, [2], [Solaris-Style ctime_r])
1044 ctimerstyle=""
1045 AC_MSG_CHECKING([ctime_r() syntax])
1046 AC_TRY_LINK([
1047 #include <time.h>
1048 ], [ ctime_r(NULL, NULL, 0) ], [
1049         AC_DEFINE(CTIMERSTYLE, SOLARISSTYLE, [style of ctime_r function])
1050         ctimerstyle="SOLARIS"
1051 ])
1052 if test "x$ctimerstyle" = "x"; then
1053         AC_TRY_LINK([
1054 #include <time.h>
1055 ], [ ctime_r(NULL, NULL) ], [
1056                 AC_DEFINE(CTIMERSTYLE, POSIXSTYLE, [style of ctime_r function])
1057                 ctimerstyle="POSIX"
1058         ])
1059 fi
1060
1061 if test "x$ctimerstyle" = "x"; then
1062         AC_MSG_RESULT([none!  It must not exist, here.])
1063 else
1064         AC_MSG_RESULT([${ctimerstyle}-style])
1065 fi
1066
1067 AC_SUBST(HOSTINFO, $host)
1068
1069 dnl #############################################################
1070 dnl #
1071 dnl #  8. Checks for system services
1072 dnl #
1073 dnl #############################################################
1074
1075 dnl #
1076 dnl # Figure out where libtool is located,
1077 dnl #
1078 top_builddir=`pwd`
1079 export top_builddir
1080 AC_MSG_RESULT([top_builddir=$top_builddir])
1081 dnl # AC_SUBST(top_builddir)
1082 AC_SUBST(LIBLTDL)
1083 AC_SUBST(INCLTDL)
1084
1085 dnl import libtool stuff
1086
1087 dnl #############################################################
1088 dnl #
1089 dnl #  Configure in any module directories.
1090 dnl #
1091 dnl #############################################################
1092
1093 mysubdirs="$LIBLTDLPATH"
1094 if test "x$EXPERIMENTAL" = "xyes"; then
1095   bar=`ls -1 "${srcdir}"/src/modules/rlm_*/configure | sed 's%/configure%%'`
1096   dnl # get rid of LF's.
1097   mysubdirs=`echo $mysubdirs $bar`
1098 else
1099   dnl #
1100   dnl # Find 'configure' in ONLY the stable modules
1101   dnl #
1102   for bar in `cat "${srcdir}"/src/modules/stable`; do
1103     if test -f "${srcdir}"/src/modules/$bar/configure; then
1104       mysubdirs="$mysubdirs src/modules/$bar"
1105     fi
1106   done
1107 fi
1108
1109 dnl ############################################################
1110 dnl # make modules by list
1111 dnl #############################################################
1112 if test "x$EXPERIMENTAL" = "xyes"; then
1113   for foo in `ls -1 "${srcdir}"/src/modules | grep rlm_`; do
1114     MODULES="$MODULES $foo"
1115   done
1116 else
1117    dnl #
1118    dnl # make ONLY the stable modules
1119    dnl #
1120    for foo in `cat "${srcdir}"/src/modules/stable`; do
1121     MODULES="$MODULES $foo"
1122    done
1123 fi
1124
1125 dnl #
1126 dnl #  Don't change the variable name here.  Autoconf goes bonkers
1127 dnl #  if you do.
1128 dnl #
1129 AC_CONFIG_SUBDIRS($LTDL_SUBDIRS $mysubdirs)
1130 AC_SUBST(MODULES)
1131
1132 dnl #############################################################
1133 dnl #
1134 dnl #  And finally, output the results.
1135 dnl #
1136 dnl #############################################################
1137
1138 AC_CONFIG_COMMANDS([stamp-h], [echo timestamp > src/include/stamp-h])
1139 AC_CONFIG_COMMANDS([build-radpaths-h], [(cd ./src/include && /bin/sh ./build-radpaths-h)])
1140 AC_CONFIG_COMMANDS([main-chmod], [(cd ./src/main   && chmod +x checkrad.pl radlast radtest)])
1141 AC_CONFIG_COMMANDS([scripts-chmod], [(cd ./scripts    && chmod +x rc.radiusd radwatch radiusd.cron.daily radiusd.cron.monthly cryptpasswd)])
1142
1143 dnl #
1144 dnl #  Substitute whatever libraries we found to be necessary
1145 dnl #
1146 AC_SUBST(LIBS)
1147 AC_SUBST(INSTALLSTRIP)
1148
1149 USE_SHARED_LIBS=$enable_shared
1150 AC_SUBST(USE_SHARED_LIBS)
1151 USE_STATIC_LIBS=$enable_static
1152 AC_SUBST(USE_STATIC_LIBS)
1153 AC_SUBST(STATIC_MODULES)
1154 AC_SUBST(RADIUSD_MAJOR_VERSION)
1155 AC_SUBST(RADIUSD_MINOR_VERSION)
1156 AC_SUBST(RADIUSD_VERSION)
1157
1158 AC_OUTPUT(\
1159         ./Make.inc \
1160         ./src/include/build-radpaths-h \
1161         ./src/main/Makefile \
1162         ./src/main/checkrad.pl \
1163         ./src/main/radlast \
1164         ./src/main/radtest \
1165         ./scripts/rc.radiusd \
1166         ./scripts/radwatch \
1167         ./scripts/radiusd.cron.daily \
1168         ./scripts/radiusd.cron.monthly \
1169         ./scripts/cryptpasswd \
1170         ./raddb/dictionary \
1171         ./raddb/radiusd.conf
1172 )