configure.in

   1 dnl #############################################################
   2 dnl #
   3 dnl #  For information about autoconf, see:
   4 dnl #
   5 dnl #  http://www.gnu.org/software/autoconf/
   6 dnl #
   7 dnl #  The recommended order is:
   8 dnl #
   9 dnl #  AC_INIT(file)
  10 dnl #  0. checks for compiler, libtool, and command line options
  11 dnl #  1. checks for programs
  12 dnl #  2. checks for libraries
  13 dnl #  3. checks for header files
  14 dnl #  4. checks for typedefs
  15 dnl #  5. checks for structures and functions
  16 dnl #  6. checks for compiler characteristics
  17 dnl #  7. checks for library functions
  18 dnl #  8. checks for system services
  19 dnl #  AC_OUTPUT([file...])
  20 dnl #
  21 dnl #############################################################
  22
  23 AC_PREREQ([2.59])
  24 export CFLAGS LIBS LDFLAGS CPPFLAGS
  25 AC_INIT(src/main/radiusd.c)
  26 AC_CONFIG_HEADER(src/include/autoconf.h)
  27 AC_REVISION($Revision$)dnl
  28
  29 dnl # The version of the software
  30 RADIUSD_VERSION=`cat VERSION`
  31 RADIUSD_MAJOR_VERSION=`cat VERSION | sed 's/\..*//'`
  32 RADIUSD_MINOR_VERSION=`cat VERSION | sed 's/^2\.//'`
  33 PACKAGE=freeradius
  34
  35 dnl #############################################################
  36 dnl #
  37 dnl #  0. Checks for compiler, libtool, and command line options.
  38 dnl #
  39 dnl #############################################################
  40
  41 dnl Check for GNU cc
  42 AC_PROG_CC
  43 AC_PROG_CXX
  44
  45 dnl #
  46 dnl # check for AIX, to allow us to use some BSD functions
  47 dnl # must be before macros that call the compiler.
  48 dnl #
  49 AC_AIX
  50
  51 AC_PROG_GCC_TRADITIONAL
  52 AC_PROG_CC_SUNPRO
  53 AC_PROG_RANLIB
  54
  55 dnl Compile in large (2G+) file support.
  56 AC_SYS_LARGEFILE
  57
  58 dnl # check for system bytesex
  59 dnl # AC_DEFINES WORDS_BIGENDIAN
  60 AC_C_BIGENDIAN
  61
  62 dnl Find GNU Make.
  63 AC_CHECK_PROG(GMAKE, gmake, yes, no)
  64 if test $GMAKE = no; then
  65   AC_PATH_PROG(MAKE, make, /usr/local/bin/make)
  66 else
  67   AC_PATH_PROG(MAKE, gmake, /usr/local/gnu/bin/make)
  68 fi
  69 makever=`$ac_cv_path_MAKE --version 2>&1 | grep "GNU Make"`
  70 if test -z "$makever"; then
  71   AC_MSG_ERROR(GNU Make is not installed.  Please download and install it
  72                 from ftp://prep.ai.mit.edu/pub/gnu/make/ before continuing.)
  73 fi
  74
  75 dnl libltdl is installable
  76 AC_LIBLTDL_INSTALLABLE
  77
  78 dnl tell Makefile to build ltdl if needed
  79 if test x"$enable_ltdl_install" = x"yes"; then
  80   LTDL_SUBDIRS=libltdl
  81 fi
  82 AC_SUBST(LTDL_SUBDIRS)
  83
  84 dnl use system-wide libtool, if it exists
  85 AC_ARG_WITH(system-libtool,
  86 [  --with-system-libtool              try to use libtool installed in your system [default=use our own]],
  87 [ AC_PATH_PROG(LIBTOOL, libtool,,$PATH:/usr/local/bin) ],
  88 [
  89   LIBTOOL="`pwd`/libtool"
  90   AC_SUBST(LIBTOOL)
  91   dnl ensure that we're looking for dlopen
  92   AC_LIBTOOL_DLOPEN
  93
  94   dnl Figure out how to build shared libraries
  95   AC_PROG_LIBTOOL
  96 ])
  97
  98
  99 dnl Put this in later, when all distributed modules use autoconf.
 100 dnl AC_ARG_WITH(disablemodulefoo,
 101 dnl [  --without-rlm_foo       Disables module compilation.  Module list:]
 102 dnl esyscmd([find src/modules -type d -name rlm_\* -print |\
 103 dnl     sed -e 's%src/modules/.*/% (sub)- %; s%.*/%- %' |\
 104 dnl     awk '{print "                            "$0}']))
 105
 106 AC_ARG_ENABLE(strict-dependencies,
 107 [  --enable-strict-dependencies  Fail configure on lack of module dependancy.])
 108
 109 dnl extra argument: --with-docdir
 110 docdir='${datadir}/doc/freeradius'
 111 AC_MSG_CHECKING(docdir)
 112 AC_ARG_WITH(docdir,
 113 [  --with-docdir=DIR       Directory for documentation [DATADIR/doc/freeradius] ],
 114 [ case "$withval" in
 115     no)
 116         docdir=no
 117         ;;
 118     yes)
 119         ;;
 120     [[\\/$]]* | ?:[[\\/]]* )
 121         docdir="$withval"
 122         ;;
 123     *)
 124         AC_MSG_ERROR([expected an absolute directory name for --with-docdir: $withval])
 125         ;;
 126   esac ]
 127 )
 128 AC_SUBST(docdir)
 129 AC_MSG_RESULT($docdir)
 130 if test "x$docdir" = xno; then
 131         AC_MSG_WARN(Documentation files will NOT be installed.)
 132 fi
 133
 134 dnl extra argument: --with-logdir
 135 logdir='${localstatedir}/log/radius'
 136 AC_MSG_CHECKING(logdir)
 137 AC_ARG_WITH(logdir,
 138 [  --with-logdir=DIR       Directory for logfiles [LOCALSTATEDIR/log/radius] ],
 139 [ case "$withval" in
 140     no)
 141         AC_MSG_ERROR(Need logdir)
 142         ;;
 143     yes)
 144         ;;
 145     [[\\/$]]* | ?:[[\\/]]* )
 146         logdir="$withval"
 147         ;;
 148     *)
 149         AC_MSG_ERROR([expected an absolute directory name for --with-logdir: $withval])
 150         ;;
 151   esac ]
 152 )
 153 AC_SUBST(logdir)
 154 AC_MSG_RESULT($logdir)
 155
 156 dnl extra argument: --with-radacctdir
 157 radacctdir='${logdir}/radacct'
 158 AC_MSG_CHECKING(radacctdir)
 159 AC_ARG_WITH(radacctdir,
 160 [  --with-radacctdir=DIR   Directory for detail files [LOGDIR/radacct] ],
 161 [ case "$withval" in
 162     no)
 163         AC_MSG_ERROR(Need radacctdir)
 164         ;;
 165     yes)
 166         ;;
 167     [[\\/$]]* | ?:[[\\/]]* )
 168         radacctdir="$withval"
 169         ;;
 170     *)
 171         AC_MSG_ERROR([expected an absolute directory name for --with-radacctdir: $withval])
 172         ;;
 173   esac ]
 174 )
 175 AC_SUBST(radacctdir)
 176 AC_MSG_RESULT($radacctdir)
 177
 178 dnl extra argument: --with-raddbdir
 179 raddbdir='${sysconfdir}/raddb'
 180 AC_MSG_CHECKING(raddbdir)
 181 AC_ARG_WITH(raddbdir,
 182 [  --with-raddbdir=DIR     Directory for config files [SYSCONFDIR/raddb] ],
 183 [ case "$withval" in
 184     no)
 185         AC_MSG_ERROR(Need raddbdir)
 186         ;;
 187     yes)
 188         ;;
 189     [[\\/$]]* | ?:[[\\/]]* )
 190         raddbdir="$withval"
 191         ;;
 192     *)
 193         AC_MSG_ERROR([expected an absolute directory name for --with-raddbdir: $withval])
 194         ;;
 195   esac ]
 196 )
 197 AC_SUBST(raddbdir)
 198 AC_MSG_RESULT($raddbdir)
 199
 200 dnl extra argument: --with-ascend-binary
 201 ASCEND_BINARY=yes
 202 AC_ARG_WITH(ascend-binary,
 203 [  --with-ascend-binary    Include support for Ascend binary filter attributes (default=yes)],
 204 [ case "$withval" in
 205     yes)
 206         ;;
 207     *)
 208         ASCEND_BINARY=""
 209   esac ]
 210 )
 211 if test "X$ASCEND_BINARY" = "Xyes"; then
 212   AC_DEFINE(ASCEND_BINARY, [], [Include support for Ascend binary filter attributes])
 213 fi
 214
 215 dnl extra argument: --with-threads
 216 WITH_THREADS=yes
 217 AC_ARG_WITH(threads,
 218 [  --with-threads          Use threads, if available.  (default=yes) ],
 219 [ case "$withval" in
 220     yes)
 221         ;;
 222     *)
 223         WITH_THREADS=""
 224   esac ]
 225 )
 226
 227 dnl extra argument: --with-vmps
 228 WITH_VMPS=yes
 229 AC_ARG_WITH(vmps,
 230 [  --with-vmps             Compile in VMPS support. (default=yes)],
 231 [ case "$withval" in
 232     yes)
 233         ;;
 234     *)
 235         WITH_VMPS=no
 236   esac ]
 237 )
 238 if test "x$WITH_VMPS" = "xyes"; then
 239         AC_DEFINE(WITH_VMPS, [1], [define if you want VMPS support])
 240 fi
 241
 242 dnl extra argument: --with-dhcp
 243 AC_ARG_WITH(dhcp,
 244 [  --with-dhcp             Compile in DHCP support. (default=no)],
 245 [ case "$withval" in
 246     yes)
 247         AC_DEFINE(WITH_DHCP, [1], [Include experimental support for DHCP])
 248         ;;
 249     *)
 250         ;;
 251   esac ]
 252 )
 253
 254
 255 dnl #
 256 dnl #  Allow the user to specify a list of modules to be linked
 257 dnl #  statically to the server.
 258 dnl #
 259 STATIC_MODULES=
 260 AC_ARG_WITH(static_modules,
 261 [  --with-static-modules=QUOTED-MODULE-LIST],[
 262   for i in $withval; do
 263     STATIC_MODULES="$STATIC_MODULES -dlpreopen ../modules/rlm_$i/rlm_$i.la"
 264   done
 265 ])
 266
 267 MODULES=
 268 AC_ARG_WITH(modules,
 269 [ --with-modules=QUOTED-MODULE-LIST],[
 270  for i in $withval; do
 271    MODULES="$MODULES $i"
 272  done
 273 ])
 274
 275 dnl #
 276 dnl #  Enable developer C compiler warnings
 277 dnl #
 278 AC_ARG_ENABLE(developer,
 279 [  --enable-developer               Enables features of interest to developers.],
 280 [ case "$enableval" in
 281     no)
 282         developer=no
 283         ;;
 284     *)
 285         developer=yes
 286   esac ]
 287 )
 288
 289 if test "x$developer" != "xno" -a -d $srcdir/CVS; then
 290   dnl turn on the developer flag when taken from a CVS checkout (not a release)
 291   developer="yes"
 292 fi
 293
 294 if test "x$developer" != "xno" -a -d $srcdir/.git; then
 295   dnl turn on the developer flag when taken from a git checkout (not a release)
 296   developer="yes"
 297 fi
 298
 299 dnl extra argument: --with-experimental-modules
 300 EXPERIMENTAL=
 301 AC_ARG_WITH(experimental-modules,
 302 [  --with-experimental-modules      Use experimental and unstable modules. (default=no) ],
 303 [ case "$withval" in
 304     yes)
 305         EXPERIMENTAL=yes
 306         ;;
 307     *)
 308   esac ]
 309 )
 310
 311 dnl extra argument: --with-openssl
 312 WITH_OPENSSL=yes
 313 AC_ARG_WITH(openssl,
 314 [  --with-openssl                   Use OpenSSL. (default=yes)],
 315 [ case "$withval" in
 316     no)
 317         WITH_OPENSSL=no
 318         ;;
 319     *)
 320         WITH_OPENSSL=yes
 321         ;;
 322   esac ]
 323 )
 324
 325 dnl #
 326 dnl # extra argument: --with-openssl-includes=dir
 327 dnl #
 328 OPENSSL_INCLUDE_DIR=
 329 AC_ARG_WITH(openssl-includes,
 330 [  --with-openssl-includes=DIR      Directory to look for OpenSSL include files],
 331 [ case "$withval" in
 332     *) OPENSSL_INCLUDE_DIR="$withval"
 333         ;;
 334   esac ]
 335 )
 336
 337 dnl #
 338 dnl # extra argument: --with-openssl-libraries=dir
 339 dnl #
 340 OPENSSL_LIB_DIR=
 341 AC_ARG_WITH(openssl-libraries,
 342 [  --with-openssl-libraries=DIR     Directory to look for OpenSSL library files],
 343 [ case "$withval" in
 344     *) OPENSSL_LIB_DIR="$withval"
 345         ;;
 346   esac ]
 347 )
 348
 349 dnl #
 350 dnl #  These next two arguments don't actually do anything.  They're
 351 dnl #  place holders so that the top-level configure script can tell
 352 dnl #  the user how to configure lower-level modules
 353 dnl #
 354
 355 dnl #
 356 dnl # extra argument: --with-rlm-FOO-lib-dir
 357 dnl #
 358 AC_ARG_WITH(rlm-FOO-lib-dir,
 359 [  --with-rlm-FOO-lib-dir=DIR       Directory to look for library files used by module FOO],
 360 [ case "$withval" in
 361     *)
 362         ;;
 363   esac ]
 364 )
 365
 366 dnl #
 367 dnl # extra argument: --with-rlm-FOO-include-dir
 368 dnl #
 369 AC_ARG_WITH(rlm-FOO-include-dir,
 370 [  --with-rlm-FOO-include-dir=DIR   Directory to look for include files used by module FOO],
 371 [ case "$withval" in
 372     *)
 373         ;;
 374   esac ]
 375 )
 376
 377 dnl See what include-style is used by the make program.
 378 dnl AC_MSG_CHECKING(include style for make)
 379 dnl echo "include /dev/null" > testmake.$$
 380 dnl echo "all:" >> testmake.$$
 381 dnl make -f testmake.$$ >/dev/null 2>&1
 382 dnl if test $? = 0
 383 dnl then
 384 dnl     INCLUDE=include
 385 dnl     IQUOTE=
 386 dnl else
 387 dnl     INCLUDE=.include
 388 dnl     IQUOTE='"'
 389 dnl fi
 390 dnl rm -f testmake.$$
 391 dnl AC_MSG_RESULT(" $INCLUDE")
 392 dnl AC_SUBST(INCLUDE)
 393 dnl AC_SUBST(IQUOTE)
 394
 395 dnl extra argument: --with-udpfromto
 396 WITH_UDPFROMTO=no
 397 AC_ARG_WITH(udpfromto,
 398 [  --with-udpfromto        Compile in UDPFROMTO support. (default=no)],
 399 [ case "$withval" in
 400     yes)
 401         WITH_UDPFROMTO=yes
 402         ;;
 403     *)
 404         WITH_UDPFROMTO=no
 405   esac ]
 406 )
 407
 408 if test "x$WITH_UDPFROMTO" = "xyes"; then
 409         AC_DEFINE(WITH_UDPFROMTO, [], [define if you want udpfromto])
 410 fi
 411
 412 dnl #############################################################
 413 dnl #
 414 dnl #  1. Checks for programs
 415 dnl #
 416 dnl #############################################################
 417
 418 CHECKRAD=checkrad.pl
 419 AC_PATH_PROG(PERL, perl, /usr/local/bin/perl)
 420 if test "x$ac_cv_path_PERL" = "x"; then
 421   AC_MSG_WARN(perl not found - Simultaneous-Use and checkrad.pl may not work)
 422 fi
 423 AC_PATH_PROG(SNMPGET, snmpget)
 424 if test "x$ac_cv_path_SNMPGET" = "x"; then
 425   AC_MSG_WARN(snmpget not found - Simultaneous-Use and checkrad.pl may not work)
 426 fi
 427
 428 AC_PATH_PROG(SNMPWALK, snmpwalk)
 429 if test "x$ac_cv_path_SNMPWALK" = "x"; then
 430   AC_MSG_WARN(snmpwalk not found - Simultaneous-Use and checkrad.pl may not work)
 431 fi
 432
 433 AC_PATH_PROG(RUSERS, rusers, /usr/bin/rusers)
 434
 435 dnl FIXME This is truly gross.
 436 missing_dir=`cd $ac_aux_dir && pwd`
 437 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
 438 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
 439 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
 440
 441 AC_PATH_PROG(LOCATE,locate)
 442 AC_PATH_PROG(DIRNAME,dirname)
 443 AC_PATH_PROG(GREP,grep)
 444
 445 dnl #############################################################
 446 dnl #
 447 dnl #  2. Checks for libraries
 448 dnl #
 449 dnl #############################################################
 450
 451 dnl If using pthreads, check for -lpthread (posix) or -lc_r (*BSD)
 452 old_CFLAGS=$CFLAGS
 453 if test "x$WITH_THREADS" = "xyes"; then
 454   if test $ac_cv_prog_suncc = "yes"; then
 455     CFLAGS="$CFLAGS -mt"
 456   fi
 457
 458   AC_CHECK_HEADERS(pthread.h, [], [ WITH_THREADS="no" ])
 459
 460 dnl #
 461 dnl # pthread stuff is usually in -lpthread
 462 dnl # or in -lc_r, on *BSD
 463 dnl #
 464 dnl # On Some systems, we need extra pre-processor flags, to get them to
 465 dnl # to do the threading properly.
 466 dnl #
 467   AC_CHECK_LIB(pthread, pthread_create,
 468                 [ CFLAGS="$CFLAGS -D_REENTRANT -D_POSIX_PTHREAD_SEMANTICS"
 469                   LIBS="$LIBS -lpthread" ],
 470                 AC_CHECK_LIB(c_r, pthread_create,
 471                             [ CFLAGS="$CFLAGS -pthread -D_THREAD_SAFE" ],
 472                             [ WITH_THREADS="no" ]
 473                             )
 474                 )
 475 fi
 476
 477 dnl #
 478 dnl # If we have NO pthread libraries, remove any knowledge of threads.
 479 dnl #
 480 if test "x$WITH_THREADS" != "xyes"; then
 481   CFLAGS=$old_CFLAGS
 482   ac_cv_header_pthread_h="no"
 483   WITH_THREADS=no
 484 else
 485   dnl #
 486   dnl #  We need sem_init() and friends, as they're the friendliest
 487   dnl #  semaphore functions for threading.
 488   dnl #
 489   dnl # HP/UX requires linking with librt, too, to get the sem_* symbols.
 490   dnl # Some systems have them in -lsem
 491   dnl # Solaris has them in -lposix4
 492   dnl # NetBSD has them in -lsemaphore
 493
 494   AC_SEARCH_LIBS(sem_init, pthread sem posix4 rt semaphore,
 495         [],
 496         [AC_MSG_ERROR(-lsem not found.  You may want to download it from ftp://ftp.to.gd-es.com/pub/BSDI/libsem.tar.bz2 or ftp://ftp.freeradius.org/pub/radius/contrib/libsem.tar.gz)]
 497    )
 498 fi
 499
 500 dnl Check if we need -lsocket
 501 AC_CHECK_LIB(socket, getsockname)
 502
 503 dnl Check for -lresolv
 504 dnl This library may be needed later.
 505 AC_CHECK_LIB(resolv, inet_aton)
 506
 507 dnl Check if we need -lnsl. Usually if we want to
 508 dnl link against -lsocket we need to include -lnsl as well.
 509 AC_CHECK_LIB(nsl, inet_ntoa)
 510
 511 dnl Check for OpenSSL libraries.
 512 OPENSSL_LIBS=
 513 if test "x$WITH_OPENSSL" = xyes; then
 514   old_LIBS=$LIBS
 515   if test "x$OPENSSL_LIB_DIR" != "x"; then
 516     LIBS="-L$OPENSSL_LIB_DIR $LIBS"
 517   fi
 518   AC_CHECK_LIB(crypto, DH_new,
 519     [
 520         LIBS="-lcrypto $LIBS"
 521         AC_DEFINE(HAVE_LIBCRYPTO, 1,
 522             [Define to 1 if you have the `crypto' library (-lcrypto).])
 523         AC_CHECK_LIB(ssl, SSL_new,
 524             [
 525                 AC_DEFINE(HAVE_LIBSSL, 1,
 526                     [Define to 1 if you have the `ssl' library (-lssl).])
 527                 if test "x$OPENSSL_LIB_DIR" != "x"; then
 528                     OPENSSL_LIBS="-L$OPENSSL_LIB_DIR"
 529                 fi
 530                 OPENSSL_LIBS="$OPENSSL_LIBS -lcrypto -lssl -lcrypto"
 531             ], [])
 532     ], [])
 533   LIBS=$old_LIBS
 534 fi
 535
 536 AC_CHECK_LIB(ws2_32, htonl)
 537
 538 dnl Check the pcap library for the RADIUS sniffer.
 539 PCAP_LIBS=
 540 AC_CHECK_LIB(pcap, pcap_open_live,
 541         [ PCAP_LIBS="-lpcap"
 542         AC_DEFINE(HAVE_LIBPCAP, 1,
 543                 [Define to 1 if you have the `pcap' library (-lpcap).])
 544         ],
 545         [ AC_MSG_WARN([pcap library not found, silently disabling the RADIUS sniffer.]) ])
 546
 547 dnl #############################################################
 548 dnl #
 549 dnl #  3. Checks for header files
 550 dnl #
 551 dnl #############################################################
 552
 553 dnl #
 554 dnl # Interix requires us to set -D_ALL_SOURCE, otherwise
 555 dnl # getopt will be #included, but won't link.  <sigh>
 556 dnl #
 557 dnl #
 558 case "$host" in
 559 *-interix*)
 560         CFLAGS="$CFLAGS -D_ALL_SOURCE"
 561         ;;
 562 *-darwin*)
 563         CFLAGS="$CFLAGS -DDARWIN"
 564         LIBS="-framework DirectoryService $LIBS"
 565         ;;
 566 esac
 567
 568 AC_HEADER_DIRENT
 569 AC_HEADER_STDC
 570 AC_HEADER_TIME
 571 AC_HEADER_SYS_WAIT
 572
 573 AC_CHECK_HEADERS( \
 574         unistd.h \
 575         crypt.h \
 576         errno.h \
 577         resource.h \
 578         sys/resource.h \
 579         getopt.h \
 580         malloc.h \
 581         utmp.h \
 582         utmpx.h \
 583         signal.h \
 584         sys/select.h \
 585         syslog.h \
 586         inttypes.h \
 587         stdint.h \
 588         stdio.h \
 589         netdb.h \
 590         semaphore.h \
 591         arpa/inet.h \
 592         netinet/in.h \
 593         sys/types.h \
 594         sys/socket.h \
 595         winsock.h \
 596         sys/time.h \
 597         sys/wait.h \
 598         sys/security.h \
 599         fcntl.h \
 600         sys/fcntl.h \
 601         sys/prctl.h \
 602         sys/un.h \
 603         readline/readline.h \
 604         glob.h \
 605         prot.h \
 606         pwd.h \
 607         grp.h \
 608         sia.h \
 609         siad.h
 610 )
 611
 612 dnl FreeBSD requires sys/socket.h before net/if.h
 613 AC_CHECK_HEADERS(net/if.h, [], [],
 614 [#ifdef HAVE_SYS_SOCKET_H
 615 # include <sys/socket.h>
 616 # endif
 617 ])
 618
 619 REGEX=no
 620 AC_CHECK_HEADER(regex.h, AC_DEFINE(HAVE_REGEX_H, [], [define this if we have the <regex.h> header file]))
 621 if test "x$ac_cv_header_regex_h" = "xyes"; then
 622   REGEX_EXTENDED=no
 623   REGEX=yes
 624   AC_EGREP_CPP(yes,
 625     [#include <regex.h>
 626      #ifdef REG_EXTENDED
 627        yes
 628      #endif
 629      ], [AC_DEFINE(HAVE_REG_EXTENDED, [], [define this if we have REG_EXTENDED (from <regex.h>)]) REGEX_EXTENDED=yes])
 630 fi
 631 AC_SUBST(REGEX)
 632 AC_SUBST(REGEX_EXTENDED)
 633
 634 dnl #
 635 dnl #  other checks which require headers
 636 dnl #
 637 if test "x$ac_cv_header_sys_security_h" = "xyes" && test "x$ac_cv_header_prot_h" = "xyes"
 638 then
 639   AC_DEFINE(OSFC2, [], [define if you have OSFC2 authentication])
 640 fi
 641
 642 if test "x$ac_cv_header_sia_h" = "xyes" && test "x$ac_cv_header_siad_h" = "xyes"
 643 then
 644   AC_DEFINE(OSFSIA, [], [define if you have OSFSIA authentication])
 645 fi
 646
 647 dnl Check for OpenSSL includes.
 648 OPENSSL_INCLUDE="-DNO_OPENSSL"
 649 if test "x$WITH_OPENSSL" = xyes; then
 650   if test "x$OPENSSL_LIBS" = "x"; then
 651     AC_MSG_NOTICE([skipping test for openssl/ssl.h])
 652   else
 653     old_CPPFLAGS=$CPPFLAGS
 654     if test "x$OPENSSL_INCLUDE_DIR" != "x"; then
 655         CPPFLAGS="$CPPFLAGS -I$OPENSSL_INCLUDE_DIR"
 656     fi
 657     dnl # stupid RedHat shit
 658     CPPFLAGS="$CPPFLAGS -DOPENSSL_NO_KRB5"
 659     AC_CHECK_HEADERS( \
 660         openssl/ssl.h \
 661         openssl/crypto.h \
 662         openssl/err.h \
 663         openssl/evp.h \
 664         openssl/engine.h,
 665         [],
 666         OPENSSL_LIBS=
 667     )
 668     if test "x$OPENSSL_LIBS" != "x"; then
 669         AC_MSG_CHECKING([for OpenSSL version >= 0.9.7])
 670         AC_EGREP_CPP(yes,
 671             [#include <openssl/crypto.h>
 672              #if (OPENSSL_VERSION_NUMBER >= 0x00907000L)
 673              yes
 674              #endif
 675             ], goodssl="yes")
 676         if test "x$goodssl" != "xyes"; then
 677             AC_MSG_RESULT(no)
 678             OPENSSL_LIBS=
 679         else
 680             AC_MSG_RESULT(yes)
 681             if test "x$OPENSSL_INCLUDE_DIR" != "x"; then
 682                 OPENSSL_INCLUDE="-I$OPENSSL_INCLUDE_DIR -DOPENSSL_NO_KRB5"
 683             else
 684                 OPENSSL_INCLUDE="-DOPENSSL_NO_KRB5"
 685             fi
 686         fi
 687     fi
 688     CPPFLAGS=$old_CPPFLAGS
 689   fi
 690 fi
 691 AC_SUBST(OPENSSL_INCLUDE)
 692 AC_SUBST(OPENSSL_LIBS)
 693 export OPENSSL_LIBS
 694
 695 dnl Check the pcap includes for the RADIUS sniffer.
 696 if test "x$PCAP_LIBS" = x; then
 697     AC_MSG_NOTICE([skipping test for pcap.h.])
 698 else
 699     AC_CHECK_HEADER(pcap.h,
 700         AC_DEFINE(HAVE_PCAP_H, 1,
 701                 [Define to 1 if you have the <pcap.h> header file.]),
 702         [ PCAP_LIBS=
 703         AC_MSG_WARN([pcap.h not found, silently disabling the RADIUS sniffer.])
 704         ])
 705 fi
 706 AC_SUBST(PCAP_LIBS)
 707
 708 dnl #############################################################
 709 dnl #
 710 dnl #  4. Checks for typedefs
 711 dnl #
 712 dnl #############################################################
 713
 714 dnl #
 715 dnl # Ensure that these are defined
 716 dnl #
 717 AC_TYPE_OFF_T
 718 AC_TYPE_PID_T
 719 AC_TYPE_SIZE_T
 720 AC_TYPE_UID_T
 721
 722 dnl check for socklen_t
 723 FR_CHECK_TYPE_INCLUDE([
 724 #ifdef HAVE_SYS_TYPES_H
 725 #include <sys/types.h>
 726 #endif
 727 #ifdef HAVE_SYS_SOCKET_H
 728 #include <sys/socket.h>
 729 #endif
 730 ],socklen_t, int, [socklen_t is generally 'int' on systems which don't use it])
 731
 732 dnl check for uint8_t
 733 FR_CHECK_TYPE_INCLUDE([
 734 #ifdef HAVE_INTTYPES_H
 735 #include <inttypes.h>
 736 #endif
 737 #ifdef HAVE_STDINT_H
 738 #include <stdint.h>
 739 #endif
 740 ],uint8_t, unsigned char, [uint8_t should be the canonical 'octet' for network traffic])
 741
 742 dnl check for uint16_t
 743 FR_CHECK_TYPE_INCLUDE([
 744 #ifdef HAVE_INTTYPES_H
 745 #include <inttypes.h>
 746 #endif
 747 #ifdef HAVE_STDINT_H
 748 #include <stdint.h>
 749 #endif
 750 ],uint16_t, unsigned short, [uint16_t should be the canonical '2 octets' for network traffic])
 751
 752 dnl check for uint32_t
 753 FR_CHECK_TYPE_INCLUDE([
 754 #ifdef HAVE_INTTYPES_H
 755 #include <inttypes.h>
 756 #endif
 757 #ifdef HAVE_STDINT_H
 758 #include <stdint.h>
 759 #endif
 760 ],uint32_t, unsigned int, [uint32_t should be the canonical 'network integer])
 761
 762 AC_CHECK_TYPE(struct in6_addr, AC_DEFINE(HAVE_STRUCT_IN6_ADDR, 1, [IPv6 address structure]), [], [
 763 #ifdef HAVE_NETINET_IN_H
 764 #include <netinet/in.h>
 765 #endif
 766 ])
 767
 768 AC_CHECK_TYPE(struct sockaddr_storage, AC_DEFINE(HAVE_STRUCT_SOCKADDR_STORAGE, 1, [Generic socket addresses]), [], [
 769 #ifdef HAVE_NETINET_IN_H
 770 #include <netinet/in.h>
 771 #endif
 772 #ifdef HAVE_SYS_SOCKET_H
 773 #include <sys/socket.h>
 774 #endif
 775 ])
 776
 777 AC_CHECK_TYPE(struct sockaddr_in6, AC_DEFINE(HAVE_STRUCT_SOCKADDR_IN6, 1, [IPv6 socket addresses]), [], [
 778 #ifdef HAVE_NETINET_IN_H
 779 #include <netinet/in.h>
 780 #endif
 781 ])
 782
 783 AC_CHECK_TYPE(struct addrinfo, AC_DEFINE(HAVE_STRUCT_ADDRINFO, 1, [Generic DNS lookups]), [], [
 784 #ifdef HAVE_SYS_TYPES_H
 785 #include <sys/types.h>
 786 #endif
 787 #ifdef HAVE_SYS_SOCKET_H
 788 #include <sys/socket.h>
 789 #endif
 790 #ifdef HAVE_NETDB_H
 791 #include <netdb.h>
 792 #endif
 793 ])
 794
 795 dnl #############################################################
 796 dnl #
 797 dnl #  5. Checks for structures and functions
 798 dnl #
 799 dnl #############################################################
 800 AC_CHECK_FUNCS( \
 801         getopt_long \
 802         lockf \
 803         strsignal \
 804         sigaction \
 805         sigprocmask \
 806         pthread_sigmask \
 807         snprintf \
 808         vsnprintf \
 809         setsid \
 810         strncasecmp \
 811         strcasecmp \
 812         localtime_r \
 813         ctime_r \
 814         gmtime_r \
 815         strsep \
 816         inet_aton \
 817         inet_pton \
 818         inet_ntop \
 819         setlinebuf \
 820         setvbuf \
 821         getusershell \
 822         initgroups \
 823         getaddrinfo \
 824         getnameinfo \
 825         closefrom \
 826         gettimeofday \
 827         strlcat \
 828         strlcpy
 829 )
 830 RADIUSD_NEED_DECLARATIONS( \
 831         crypt \
 832         strncasecmp \
 833         strcasecmp \
 834         inet_aton \
 835         setlinebuf \
 836         getusershell \
 837         endusershell
 838 )
 839
 840 AC_TYPE_SIGNAL
 841
 842 dnl # check if we have utmpx.h
 843 dnl # if so, check if struct utmpx has entry ut_xtime
 844 dnl # if not, set it to define ut_xtime == ut_tv.tv_sec
 845 if test "x$ac_cv_header_utmpx_h" = "xyes"
 846 then
 847  FR_CHECK_STRUCT_HAS_MEMBER([#include <utmpx.h>], [struct utmpx], ut_xtime)
 848  if test "x$ac_cv_type_struct_utmpx_has_ut_xtime" = "x"
 849  then
 850    AC_DEFINE(ut_xtime,ut_tv.tv_sec, [define to something if you don't have ut_xtime in struct utmpx])
 851  fi
 852 fi
 853
 854 dnl # struct ip_pktinfo
 855 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in_pktinfo], ipi_addr)
 856 if test "x$ac_cv_type_struct_in_pktinfo_has_ipi_addr" = "xyes"
 857 then
 858         AC_DEFINE(HAVE_IP_PKTINFO, [], [define if you have IP_PKTINFO (Linux)])
 859 fi
 860
 861 dnl # struct in6_pktinfo
 862 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in6_pktinfo], ipi6_addr)
 863 if test "x$ac_cv_type_struct_in6_pktinfo_has_ipi6_addr" = "xyes"
 864 then
 865         AC_DEFINE(HAVE_IN6_PKTINFO, [], [define if you have IN6_PKTINFO (Linux)])
 866 fi
 867
 868 dnl #############################################################
 869 dnl #
 870 dnl #  6. Checks for compiler characteristics
 871 dnl #
 872 dnl #############################################################
 873
 874 dnl #
 875 dnl # Ensure that these are defined
 876 dnl #
 877 AC_C_CONST
 878
 879 dnl #
 880 dnl # See if this is OS/2
 881 dnl #
 882 AC_MSG_CHECKING(type of OS)
 883 OS=`uname -s`
 884 AC_MSG_RESULT($OS)
 885 if test "$OS" = "OS/2"; then
 886         LIBPREFIX=
 887 else
 888         LIBPREFIX=lib
 889 fi
 890 AC_SUBST(LIBPREFIX)
 891
 892 dnl #
 893 dnl # Set Default CFLAGS
 894 dnl #
 895 if test "x$GCC" = "xyes"; then
 896     CFLAGS="$CFLAGS -Wall -D_GNU_SOURCE"
 897 fi
 898
 899 AC_MSG_CHECKING(for developer gcc flags)
 900 if test "x$developer" = "xyes" -a "x$GCC" = "xyes"; then
 901   devflags="-g -Wshadow -Wpointer-arith -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -W -Wredundant-decls -Wundef"
 902   CFLAGS="$CFLAGS $devflags"
 903   INSTALLSTRIP=""
 904   AC_MSG_RESULT(yes.  Using $devflags)
 905 else
 906   devflags=""
 907   CFLAGS="$CFLAGS -DNDEBUG"
 908   INSTALLSTRIP=""
 909   AC_MSG_RESULT(no.)
 910 fi
 911
 912 FR_TLS
 913
 914 dnl #############################################################
 915 dnl #
 916 dnl #  7. Checks for library functions
 917 dnl #
 918 dnl #############################################################
 919
 920 dnl Check for libcrypt
 921 dnl We use crypt(3) which may be in libc, or in libcrypt (eg FreeBSD)
 922 AC_CHECK_LIB(crypt, crypt,
 923   CRYPTLIB="-lcrypt"
 924 )
 925 if test "$CRYPTLIB" != ""; then
 926   AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function])
 927 else
 928   AC_CHECK_FUNC(crypt, AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function]))
 929 fi
 930
 931 dnl Check for libcipher
 932 AC_CHECK_LIB(cipher, setkey,
 933    CRYPTLIB="${CRYPTLIB} -lcipher"
 934 )
 935 AC_SUBST(CRYPTLIB)
 936
 937 dnl Check the style of gethostbyaddr, in order of preference
 938 dnl GNU (_r eight args)
 939 AC_DEFINE(GNUSTYLE, [1], [GNU-Style get*byaddr_r])
 940 dnl SYSV (_r six args)
 941 AC_DEFINE(SYSVSTYLE, [2], [SYSV-Style get*byaddr_r])
 942 dnl BSD (three args, may not be thread safe)
 943 AC_DEFINE(BSDSTYLE, [3], [BSD-Style get*byaddr_r])
 944 dnl Tru64 has BSD version, but it is thread safe
 945 dnl     http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1739____.HTM
 946 dnl We need #stdio.h to define NULL on FreeBSD (at least)
 947 gethostbyaddrrstyle=""
 948 AC_MSG_CHECKING([gethostbyaddr_r() syntax])
 949 case "$host" in
 950 *-freebsd*)
 951 dnl With FreeBSD, check if there's a prototype for gethostbyaddr_r.
 952 dnl Some versions (FreeBSD 5.1?) have a symbol but no prototype - so we
 953 dnl override this test to BSDSTYLE. FreeBSD 6.2 and up have proper GNU
 954 dnl style support.
 955         AC_CHECK_DECLS([gethostbyaddr_r], [], [
 956                 AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE,
 957                         [style of gethostbyaddr_r functions ])
 958                 gethostbyaddrrstyle=BSD
 959                 AC_MSG_WARN([FreeBSD overridden to BSD-style])
 960         ], [
 961 #ifdef HAVE_NETDB_H
 962 #include <netdb.h>
 963 #endif
 964 ])
 965         ;;
 966 esac
 967 if test "x$gethostbyaddrrstyle" = "x"; then
 968         AC_TRY_LINK([
 969 #include <stdio.h>
 970 #include <netdb.h>
 971 ], [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL, NULL) ], [
 972         AC_DEFINE(GETHOSTBYADDRRSTYLE, GNUSTYLE, [style of gethostbyaddr_r functions ])
 973         gethostbyaddrrstyle=GNU
 974 ])
 975 fi
 976 if test "x$gethostbyaddrrstyle" = "x"; then
 977         AC_TRY_LINK([
 978 #include <stdio.h>
 979 #include <netdb.h>
 980 ], [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL) ] , [
 981                 AC_DEFINE(GETHOSTBYADDRRSTYLE, SYSVSTYLE, [style of gethostbyaddr_r functions ])
 982                 gethostbyaddrrstyle=SYSV
 983         ])
 984 fi
 985 if test "x$gethostbyaddrrstyle" = "x"; then
 986         AC_TRY_LINK([
 987 #include <stdio.h>
 988 #include <netdb.h>
 989 ], [ gethostbyaddr(NULL, 0, 0)  ], [
 990                 AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE, [style of gethostbyaddr_r functions ])
 991                 gethostbyaddrrstyle=BSD
 992         ])
 993 fi
 994
 995 if test "x$gethostbyaddrrstyle" = "x"; then
 996         AC_MSG_RESULT([none!  It must not exist, here.])
 997 else
 998         AC_MSG_RESULT([${gethostbyaddrrstyle}-style])
 999 fi
1000
1001 if test "x$gethostbyaddrrstyle" = "xBSD"; then
1002         AC_MSG_WARN([ ****** BSD-style gethostbyaddr might NOT be thread-safe! ****** ])
1003 fi
1004
1005 dnl Check the style of gethostbyname, in order of preference
1006 dnl GNU (_r seven args)
1007 dnl SYSV (_r five args)
1008 dnl BSD (two args, may not be thread safe)
1009 dnl Tru64 has BSD version, but it _is_ thread safe
1010 dnl     http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1946____.HTM
1011 dnl We need #stdio.h to define NULL on FreeBSD (at least)
1012 gethostbynamerstyle=""
1013 AC_MSG_CHECKING([gethostbyname_r() syntax])
1014 AC_TRY_LINK([
1015 #include <stdio.h>
1016 #include <netdb.h>
1017 ], [ gethostbyname_r(NULL, NULL, NULL, 0, NULL, NULL) ], [
1018         AC_DEFINE(GETHOSTBYNAMERSTYLE, GNUSTYLE, [style of gethostbyname_r functions ])
1019         gethostbynamerstyle=GNU
1020 ])
1021 if test "x$gethostbynamerstyle" = "x"; then
1022         AC_TRY_LINK([
1023 #include <stdio.h>
1024 #include <netdb.h>
1025 ], [ gethostbyname_r(NULL, NULL, NULL, 0, NULL) ] , [
1026                 AC_DEFINE(GETHOSTBYNAMERSTYLE, SYSVSTYLE, [style of gethostbyname_r functions ])
1027                 gethostbynamerstyle=SYSV
1028         ])
1029 fi
1030 if test "x$gethostbynamerstyle" = "x"; then
1031         AC_TRY_LINK([
1032 #include <stdio.h>
1033 #include <netdb.h>
1034 ], [ gethostbyname(NULL)  ], [
1035                 AC_DEFINE(GETHOSTBYNAMERSTYLE, BSDSTYLE, [style of gethostbyname_r functions ])
1036                 gethostbynamerstyle=BSD
1037         ])
1038 fi
1039
1040 if test "x$gethostbynamerstyle" = "x"; then
1041         AC_MSG_RESULT([none!  It must not exist, here.])
1042 else
1043         AC_MSG_RESULT([${gethostbynamerstyle}-style])
1044 fi
1045
1046 if test "x$gethostbynamerstyle" = "xBSD"; then
1047         AC_MSG_WARN([ ****** BSD-style gethostbyname might NOT be thread-safe! ****** ])
1048 fi
1049
1050 dnl check for non-posix solaris ctime_r (extra buflen int arg)
1051 AC_DEFINE(POSIXSTYLE, [1], [Posix-Style ctime_r])
1052 AC_DEFINE(SOLARISSTYLE, [2], [Solaris-Style ctime_r])
1053 ctimerstyle=""
1054 AC_MSG_CHECKING([ctime_r() syntax])
1055 AC_TRY_LINK([
1056 #include <time.h>
1057 ], [ ctime_r(NULL, NULL, 0) ], [
1058         AC_DEFINE(CTIMERSTYLE, SOLARISSTYLE, [style of ctime_r function])
1059         ctimerstyle="SOLARIS"
1060 ])
1061 if test "x$ctimerstyle" = "x"; then
1062         AC_TRY_LINK([
1063 #include <time.h>
1064 ], [ ctime_r(NULL, NULL) ], [
1065                 AC_DEFINE(CTIMERSTYLE, POSIXSTYLE, [style of ctime_r function])
1066                 ctimerstyle="POSIX"
1067         ])
1068 fi
1069
1070 if test "x$ctimerstyle" = "x"; then
1071         AC_MSG_RESULT([none!  It must not exist, here.])
1072 else
1073         AC_MSG_RESULT([${ctimerstyle}-style])
1074 fi
1075
1076 AC_SUBST(HOSTINFO, $host)
1077
1078 dnl #############################################################
1079 dnl #
1080 dnl #  8. Checks for system services
1081 dnl #
1082 dnl #############################################################
1083
1084 dnl #
1085 dnl # Figure out where libtool is located,
1086 dnl #
1087 top_builddir=`pwd`
1088 export top_builddir
1089 AC_MSG_RESULT([top_builddir=$top_builddir])
1090 dnl # AC_SUBST(top_builddir)
1091 AC_SUBST(LIBLTDL)
1092 AC_SUBST(INCLTDL)
1093
1094 dnl import libtool stuff
1095
1096 dnl #############################################################
1097 dnl #
1098 dnl #  Configure in any module directories.
1099 dnl #
1100 dnl #############################################################
1101
1102 mysubdirs="$LIBLTDLPATH"
1103 if test "x$EXPERIMENTAL" = "xyes"; then
1104   bar=`ls -1 "${srcdir}"/src/modules/rlm_*/configure | sed 's%/configure%%'`
1105   dnl # get rid of LF's.
1106   mysubdirs=`echo $mysubdirs $bar`
1107 else
1108   dnl #
1109   dnl # Find 'configure' in ONLY the stable modules
1110   dnl #
1111   for bar in `cat "${srcdir}"/src/modules/stable`; do
1112     if test -f "${srcdir}"/src/modules/$bar/configure; then
1113       mysubdirs="$mysubdirs src/modules/$bar"
1114     fi
1115   done
1116 fi
1117
1118 dnl ############################################################
1119 dnl # make modules by list
1120 dnl #############################################################
1121 if test "x$EXPERIMENTAL" = "xyes"; then
1122   for foo in `ls -1 "${srcdir}"/src/modules | grep rlm_`; do
1123     MODULES="$MODULES $foo"
1124   done
1125 else
1126    dnl #
1127    dnl # make ONLY the stable modules
1128    dnl #
1129    for foo in `cat "${srcdir}"/src/modules/stable`; do
1130     MODULES="$MODULES $foo"
1131    done
1132 fi
1133
1134 dnl #
1135 dnl #  Don't change the variable name here.  Autoconf goes bonkers
1136 dnl #  if you do.
1137 dnl #
1138 AC_CONFIG_SUBDIRS($LTDL_SUBDIRS $mysubdirs)
1139 AC_SUBST(MODULES)
1140
1141 dnl #############################################################
1142 dnl #
1143 dnl #  And finally, output the results.
1144 dnl #
1145 dnl #############################################################
1146
1147 AC_CONFIG_COMMANDS([stamp-h], [echo timestamp > src/include/stamp-h])
1148 AC_CONFIG_COMMANDS([build-radpaths-h], [(cd ./src/include && /bin/sh ./build-radpaths-h)])
1149 AC_CONFIG_COMMANDS([main-chmod], [(cd ./src/main   && chmod +x checkrad.pl radlast radtest)])
1150 AC_CONFIG_COMMANDS([scripts-chmod], [(cd ./scripts    && chmod +x rc.radiusd radwatch radiusd.cron.daily radiusd.cron.monthly cryptpasswd)])
1151
1152 dnl #
1153 dnl #  Substitute whatever libraries we found to be necessary
1154 dnl #
1155 AC_SUBST(LIBS)
1156 AC_SUBST(INSTALLSTRIP)
1157
1158 USE_SHARED_LIBS=$enable_shared
1159 AC_SUBST(USE_SHARED_LIBS)
1160 USE_STATIC_LIBS=$enable_static
1161 AC_SUBST(USE_STATIC_LIBS)
1162 AC_SUBST(STATIC_MODULES)
1163 AC_SUBST(RADIUSD_MAJOR_VERSION)
1164 AC_SUBST(RADIUSD_MINOR_VERSION)
1165 AC_SUBST(RADIUSD_VERSION)
1166
1167 AC_OUTPUT(\
1168         ./Make.inc \
1169         ./src/include/build-radpaths-h \
1170         ./src/main/Makefile \
1171         ./src/main/checkrad.pl \
1172         ./src/main/radlast \
1173         ./src/main/radtest \
1174         ./scripts/rc.radiusd \
1175         ./scripts/radwatch \
1176         ./scripts/radiusd.cron.daily \
1177         ./scripts/radiusd.cron.monthly \
1178         ./scripts/cryptpasswd \
1179         ./raddb/dictionary \
1180         ./raddb/radiusd.conf
1181 )