configure.in

   1 dnl #############################################################
   2 dnl #
   3 dnl #  For information about autoconf, see:
   4 dnl #
   5 dnl #  http://www.gnu.org/software/autoconf/
   6 dnl #
   7 dnl #  The recommended order is:
   8 dnl #
   9 dnl #  AC_INIT(file)
  10 dnl #  0. checks for compiler, libtool, and command line options
  11 dnl #  1. checks for programs
  12 dnl #  2. checks for libraries
  13 dnl #  3. checks for header files
  14 dnl #  4. checks for typedefs
  15 dnl #  5. checks for structures and functions
  16 dnl #  6. checks for compiler characteristics
  17 dnl #  7. checks for library functions
  18 dnl #  8. checks for system services
  19 dnl #  AC_OUTPUT([file...])
  20 dnl #
  21 dnl #############################################################
  22
  23 AC_INIT(src/main/radiusd.c)
  24 AC_CONFIG_HEADER(src/include/autoconf.h)
  25 AC_REVISION($Revision$)dnl
  26
  27 dnl # The version of the software
  28 RADIUSD_MAJOR_VERSION=1
  29 RADIUSD_MINOR_VERSION=0.2
  30 RADIUSD_VERSION="${RADIUSD_MAJOR_VERSION}.${RADIUSD_MINOR_VERSION}"
  31
  32 dnl #############################################################
  33 dnl #
  34 dnl #  0. Checks for compiler, libtool, and command line options.
  35 dnl #
  36 dnl #############################################################
  37
  38 dnl Check for GNU cc
  39 AC_PROG_CC
  40
  41 dnl #
  42 dnl # check for AIX, to allow us to use some BSD functions
  43 dnl # must be before macros that call the compiler.
  44 dnl #
  45 AC_AIX
  46
  47 AC_PROG_GCC_TRADITIONAL
  48 AC_PROG_CC_SUNPRO
  49 AC_PROG_RANLIB
  50
  51 abs_top_builddir=`pwd`
  52 AC_SUBST(abs_top_builddir)
  53
  54 dnl # autoconf 2.50 and later
  55 dnl # AC_SYS_LARGEFILE
  56
  57 PACKAGE=freeradius
  58
  59 dnl # check for system bytesex
  60 dnl # AC_DEFINES WORDS_BIGENDIAN
  61 AC_C_BIGENDIAN
  62
  63 dnl Find GNU Make.
  64 AC_CHECK_PROG(GMAKE, gmake, yes, no)
  65 if test $GMAKE = no; then
  66   AC_PATH_PROG(MAKE, make, /usr/local/bin/make)
  67 else
  68   AC_PATH_PROG(MAKE, gmake, /usr/local/gnu/bin/make)
  69 fi
  70 makever=`$ac_cv_path_MAKE --version 2>&1 | grep "GNU Make"`
  71 if test -z "$makever"; then
  72   AC_MSG_ERROR(GNU Make is not installed.  Please download and install it
  73                 from ftp://prep.ai.mit.edu/pub/gnu/make/ before continuing.)
  74 fi
  75
  76 dnl libltdl is installable
  77 AC_LIBLTDL_INSTALLABLE
  78
  79 dnl use system-wide libtool, if it exists
  80 AC_ARG_WITH(system-libtool,
  81 [  --with-system-libtool              try to use libtool installed in your system [default=use our own]],
  82 [ AC_PATH_PROG(LIBTOOL, libtool,,$PATH:/usr/local/bin) ],
  83 [
  84   LIBTOOL="`pwd`/libtool"
  85   AC_SUBST(LIBTOOL)
  86   dnl ensure that we're looking for dlopen
  87   AC_LIBTOOL_DLOPEN
  88
  89   dnl Figure out how to build shared libraries
  90   AC_PROG_LIBTOOL
  91 ])
  92
  93
  94 dnl Put this in later, when all distributed modules use autoconf.
  95 dnl AC_ARG_WITH(disablemodulefoo,
  96 dnl [  --without-rlm_foo       Disables module compilation.  Module list:]
  97 dnl esyscmd([find src/modules -type d -name rlm_\* -print |\
  98 dnl     sed -e 's%src/modules/.*/% (sub)- %; s%.*/%- %' |\
  99 dnl     awk '{print "                            "$0}']))
 100
 101 AC_ARG_ENABLE(strict-dependencies,
 102 [  --enable-strict-dependencies  Fail configure on lack of module dependancy.])
 103
 104 dnl extra argument: --with-logdir
 105 logdir='${localstatedir}/log/radius'
 106 AC_MSG_CHECKING(logdir)
 107 AC_ARG_WITH(logdir,
 108 [  --with-logdir=DIR       Directory for logfiles [LOCALSTATEDIR/log/radius] ],
 109 [ case "$withval" in
 110     no)
 111         AC_MSG_ERROR(Need logdir)
 112         ;;
 113     yes)
 114         ;;
 115     *)
 116         logdir="$withval"
 117         ;;
 118   esac ]
 119 )
 120 AC_SUBST(logdir)
 121 AC_MSG_RESULT($logdir)
 122
 123 dnl extra argument: --with-radacctdir
 124 radacctdir='${logdir}/radacct'
 125 AC_MSG_CHECKING(radacctdir)
 126 AC_ARG_WITH(radacctdir,
 127 [  --with-radacctdir=PATH  Directory for detail files [LOGDIR/radacct] ],
 128 [ case "$withval" in
 129     no)
 130         AC_MSG_ERROR(Need radacctdir)
 131         ;;
 132     yes)
 133         ;;
 134     *)
 135         radacctdir="$withval"
 136         ;;
 137   esac ]
 138 )
 139 AC_SUBST(radacctdir)
 140 AC_MSG_RESULT($radacctdir)
 141
 142 dnl extra argument: --with-raddbdir
 143 raddbdir='${sysconfdir}/raddb'
 144 AC_MSG_CHECKING(raddbdir)
 145 AC_ARG_WITH(raddbdir,
 146 [  --with-raddbdir=DIR     Directory for config files [SYSCONFDIR/raddb] ],
 147 [ case "$withval" in
 148     no)
 149         AC_MSG_ERROR(Need raddbdir)
 150         ;;
 151     yes)
 152         ;;
 153     *)
 154         raddbdir="$withval"
 155         ;;
 156   esac ]
 157 )
 158 AC_SUBST(raddbdir)
 159 AC_MSG_RESULT($raddbdir)
 160
 161 dnl extra argument: --with-ascend-binary
 162 ASCEND_BINARY=yes
 163 AC_ARG_WITH(ascend-binary,
 164 [  --with-ascend-binary    Include support for Ascend binary filter attributes (default=yes)],
 165 [ case "$withval" in
 166     yes)
 167         ;;
 168     *)
 169         ASCEND_BINARY=""
 170   esac ]
 171 )
 172 if test "X$ASCEND_BINARY" = "Xyes"; then
 173   AC_DEFINE(ASCEND_BINARY)
 174 fi
 175
 176 dnl extra argument: --with-threads
 177 WITH_THREADS=yes
 178 AC_ARG_WITH(threads,
 179 [  --with-threads          Use threads, if available.  (default=yes) ],
 180 [ case "$withval" in
 181     yes)
 182         ;;
 183     *)
 184         WITH_THREADS=""
 185   esac ]
 186 )
 187
 188 dnl extra argument: --with-snmp
 189 WITH_SNMP=yes
 190 AC_ARG_WITH(snmp,
 191 [  --with-snmp             Compile in SNMP support. (default=yes)],
 192 [ case "$withval" in
 193     yes)
 194         ;;
 195     *)
 196         WITH_SNMP=no
 197   esac ]
 198 )
 199
 200 dnl extra argument: --with-large-files
 201 rad_enable_largefiles=no
 202 AC_ARG_WITH(large-files,
 203 [  --with-large-files      Compile in large (2G+) file support. (default=no)],
 204 [ case "$withval" in
 205     yes)
 206         rad_enable_largefiles=yes
 207         ;;
 208     *)
 209         ;;
 210   esac ]
 211 )
 212
 213
 214 dnl AC_ARG_ENABLE(ltdl-install,
 215 dnl [  --disable-ltdl-install  do not install libltdl])
 216 dnl if test x"${enable_ltdl_install+set}" != xset; then
 217 dnl   enable_ltdl_install=yes
 218 dnl   ac_configure_args="$ac_configure_args --enable-ltdl-install"
 219 dnl fi
 220 dnl AC_CONFIG_SUBDIRS(libltdl)
 221
 222 dnl #
 223 dnl #  Allow the user to specify a list of modules to be linked
 224 dnl #  statically to the server.
 225 dnl #
 226 STATIC_MODULES=
 227 AC_ARG_WITH(static_modules,
 228 [  --with-static-modules=QUOTED-MODULE-LIST],[
 229   for i in $withval; do
 230     STATIC_MODULES="$STATIC_MODULES -dlpreopen ../modules/rlm_$i/rlm_$i.la"
 231   done
 232 ])
 233
 234 dnl #
 235 dnl #  Enable developer C compiler warnings
 236 dnl #
 237 AC_ARG_ENABLE(developer,
 238 [  --enable-developer               Enables features of interest to developers.],
 239 [ case "$enableval" in
 240     no)
 241         developer=no
 242         ;;
 243     *)
 244         developer=yes
 245   esac ]
 246 )
 247
 248 if test "x$developer" != "xno" -a -d $srcdir/CVS; then
 249   dnl turn on the developer flag when taken from a CVS checkout (not a release)
 250   developer="yes"
 251 fi
 252
 253 dnl extra argument: --with-experimental-modules
 254 EXPERIMENTAL=
 255 AC_ARG_WITH(experimental-modules,
 256 [  --with-experimental-modules      Use experimental and unstable modules. (default=no) ],
 257 [ case "$withval" in
 258     yes)
 259         EXPERIMENTAL=yes
 260         ;;
 261     *)
 262   esac ]
 263 )
 264
 265 dnl #
 266 dnl # extra argument: --openssl-includes=dir
 267 dnl #
 268 AC_ARG_WITH(openssl-includes,
 269 [  --with-openssl-includes=DIR      Directory to look for OpenSSL include files],
 270 [ case "$withval" in
 271     *) OPENSSL_INCLUDE="$withval"
 272         ;;
 273   esac ]
 274 )
 275 AC_SUBST(OPENSSL_INCLUDE)
 276
 277 dnl #
 278 dnl # extra argument: --openssl-libraries=dir
 279 dnl #
 280 AC_ARG_WITH(openssl-libraries,
 281 [  --with-openssl-libraries=DIR     Directory to look for OpenSSL library files],
 282 [ case "$withval" in
 283     *) OPENSSL_LIBS="$withval"
 284         ;;
 285   esac ]
 286 )
 287 AC_SUBST(OPENSSL_LIBS)
 288
 289
 290 dnl #
 291 dnl #  These next two arguments don't actually do anything.  They're
 292 dnl #  place holders so that the top-level configure script can tell
 293 dnl #  the user how to configure lower-level modules
 294 dnl #
 295
 296 dnl #
 297 dnl # extra argument: --with-rlm-FOO-lib-dir
 298 dnl #
 299 AC_ARG_WITH(rlm-FOO-lib-dir,
 300 [  --with-rlm-FOO-lib-dir=DIR       Directory to look for library files used by module FOO],
 301 [ case "$withval" in
 302     *)
 303         ;;
 304   esac ]
 305 )
 306
 307 dnl #
 308 dnl # extra argument: --with-rlm-FOO-include-dir
 309 dnl #
 310 AC_ARG_WITH(rlm-FOO-include-dir,
 311 [  --with-rlm-FOO-include-dir=DIR   Directory to look for include files used by module FOO],
 312 [ case "$withval" in
 313     *)
 314         ;;
 315   esac ]
 316 )
 317
 318 dnl See what include-style is used by the make program.
 319 dnl AC_MSG_CHECKING(include style for make)
 320 dnl echo "include /dev/null" > testmake.$$
 321 dnl echo "all:" >> testmake.$$
 322 dnl make -f testmake.$$ >/dev/null 2>&1
 323 dnl if test $? = 0
 324 dnl then
 325 dnl     INCLUDE=include
 326 dnl     IQUOTE=
 327 dnl else
 328 dnl     INCLUDE=.include
 329 dnl     IQUOTE='"'
 330 dnl fi
 331 dnl rm -f testmake.$$
 332 dnl AC_MSG_RESULT(" $INCLUDE")
 333 dnl AC_SUBST(INCLUDE)
 334 dnl AC_SUBST(IQUOTE)
 335
 336 dnl extra argument: --with-udpfromto
 337 WITH_UDPFROMTO=no
 338 AC_ARG_WITH(udpfromto,
 339 [  --with-udpfromto        Compile in UDPFROMTO support. (default=no)],
 340 [ case "$withval" in
 341     yes)
 342         WITH_UDPFROMTO=yes
 343         ;;
 344     *)
 345         WITH_UDPFROMTO=no
 346   esac ]
 347 )
 348
 349 if test "x$WITH_UDPFROMTO" = "xyes"; then
 350         AC_DEFINE(WITH_UDPFROMTO)
 351 fi
 352
 353 dnl extra argument: --with-edir
 354 dnl If using Novell eDirectory, enable UP and Novell specific code
 355 AC_ARG_WITH(edir,
 356 [  --with-edir             Enable Novell eDirectory integration.  (default=no) ] , [] )
 357
 358 dnl #############################################################
 359 dnl #
 360 dnl #  1. Checks for programs
 361 dnl #
 362 dnl #############################################################
 363
 364 CHECKRAD=checkrad.pl
 365 AC_PATH_PROG(PERL, perl, /usr/local/bin/perl)
 366 if test "x$ac_cv_path_PERL" = "x"; then
 367   AC_MSG_WARN(perl not found - Simultaneous-Use and checkrad.pl may not work)
 368 fi
 369 AC_PATH_PROG(SNMPGET, snmpget)
 370 if test "x$ac_cv_path_SNMPGET" = "x"; then
 371   AC_MSG_WARN(snmpget not found - Simultaneous-Use and checkrad.pl may not work)
 372 fi
 373
 374 AC_PATH_PROG(SNMPWALK, snmpwalk)
 375 if test "x$ac_cv_path_SNMPWALK" = "x"; then
 376   AC_MSG_WARN(snmpwalk not found - Simultaneous-Use and checkrad.pl may not work)
 377 fi
 378
 379 AC_PATH_PROG(RUSERS, rusers, /usr/bin/rusers)
 380
 381 dnl FIXME This is truly gross.
 382 missing_dir=`cd $ac_aux_dir && pwd`
 383 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
 384 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
 385 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
 386
 387 AC_PATH_PROG(LOCATE,locate)
 388 AC_PATH_PROG(DIRNAME,dirname)
 389 AC_PATH_PROG(GREP,grep)
 390
 391 dnl #############################################################
 392 dnl #
 393 dnl #  2. Checks for libraries
 394 dnl #
 395 dnl #############################################################
 396
 397 dnl If using pthreads, check for -lpthread (posix) or -lc_r (*BSD)
 398 old_CFLAGS=$CFLAGS
 399 if test "x$WITH_THREADS" = "xyes"; then
 400   if test $ac_cv_prog_suncc = "yes"; then
 401     CFLAGS="$CFLAGS -mt"
 402   fi
 403
 404   AC_CHECK_HEADERS(pthread.h, [], [ WITH_THREADS="no" ])
 405
 406 dnl #
 407 dnl # pthread stuff is usually in -lpthread
 408 dnl # or in -lc_r, on *BSD
 409 dnl #
 410 dnl # On Some systems, we need extra pre-processor flags, to get them to
 411 dnl # to do the threading properly.
 412 dnl #
 413   AC_CHECK_LIB(pthread, pthread_create,
 414                 [ CFLAGS="$CFLAGS -D_REENTRANT -D_POSIX_PTHREAD_SEMANTICS"
 415                   LIBS="$LIBS -lpthread" ],
 416                 AC_CHECK_LIB(c_r, pthread_create,
 417                             [ CFLAGS="$CFLAGS -pthread -D_THREAD_SAFE" ],
 418                             [ WITH_THREADS="no" ]
 419                             )
 420                 )
 421 fi
 422
 423 dnl #
 424 dnl # If we have NO pthread libraries, remove any knowledge of threads.
 425 dnl #
 426 if test "x$WITH_THREADS" != "xyes"; then
 427   CFLAGS=$old_CFLAGS
 428   ac_cv_header_pthread_h="no"
 429   WITH_THREADS=no
 430 else
 431   dnl #
 432   dnl #  We need sem_init() and friends, as they're the friendliest
 433   dnl #  semaphore functions for threading.
 434   dnl #
 435   dnl # HP/UX requires linking with librt, too, to get the sem_* symbols.
 436   dnl # Some systems have them in -lsem
 437   dnl # Solaris has them in -lposix4
 438
 439   AC_SEARCH_LIBS(sem_init, pthread sem posix4 rt,
 440         [],
 441         [AC_MSG_ERROR(-lsem not found.  You may want to download it from ftp://ftp.to.gd-es.com/pub/BSDI/libsem.tar.bz2 or ftp://ftp.freeradius.org/pub/radius/contrib/libsem.tar.gz)]
 442    )
 443 fi
 444
 445 dnl Check if we need -lsocket
 446 AC_CHECK_LIB(socket, getsockname)
 447
 448 dnl Check for -lresolv
 449 dnl This library may be needed later.
 450 AC_CHECK_LIB(resolv, inet_aton)
 451
 452 dnl Check if we need -lnsl. Usually if we want to
 453 dnl link against -lsocket we need to include -lnsl as well.
 454 AC_CHECK_LIB(nsl, inet_ntoa)
 455
 456 dnl #############################################################
 457 dnl #
 458 dnl #  3. Checks for header files
 459 dnl #
 460 dnl #############################################################
 461
 462 dnl #
 463 dnl # Interix requires us to set -D_ALL_SOURCE, otherwise
 464 dnl # getopt will be #included, but won't link.  <sigh>
 465 dnl #
 466 dnl #
 467 case "$host" in
 468 *-interix*)
 469         CFLAGS="$CFLAGS -D_ALL_SOURCE"
 470         ;;
 471 esac
 472
 473 AC_HEADER_DIRENT
 474 AC_HEADER_STDC
 475 AC_HEADER_TIME
 476 AC_HEADER_SYS_WAIT
 477
 478 AC_CHECK_HEADERS( \
 479         unistd.h \
 480         crypt.h \
 481         errno.h \
 482         resource.h \
 483         getopt.h \
 484         malloc.h \
 485         utmp.h \
 486         utmpx.h \
 487         signal.h \
 488         sys/select.h \
 489         syslog.h \
 490         inttypes.h \
 491         stdint.h \
 492         stdio.h \
 493         netdb.h \
 494         semaphore.h \
 495         arpa/inet.h \
 496         netinet/in.h \
 497         sys/types.h \
 498         sys/socket.h \
 499         sys/time.h \
 500         sys/wait.h \
 501         sys/security.h \
 502         fcntl.h \
 503         sys/fcntl.h \
 504         prot.h \
 505         sia.h \
 506         siad.h
 507 )
 508
 509 REGEX=no
 510 AC_CHECK_HEADER(regex.h, AC_DEFINE(HAVE_REGEX_H))
 511 if test "x$ac_cv_header_regex_h" = "xyes"; then
 512   REGEX_EXTENDED=no
 513   REGEX=yes
 514   AC_EGREP_CPP(yes,
 515     [#include <regex.h>
 516      #ifdef REG_EXTENDED
 517        yes
 518      #endif
 519      ], [AC_DEFINE(HAVE_REG_EXTENDED) REGEX_EXTENDED=yes])
 520 fi
 521 AC_SUBST(REGEX)
 522 AC_SUBST(REGEX_EXTENDED)
 523
 524 dnl #
 525 dnl #  other checks which require headers
 526 dnl #
 527 if test "x$ac_cv_header_sys_security_h" = "xyes" && test "x$ac_cv_header_prot_h" = "xyes"
 528 then
 529   AC_DEFINE(OSFC2)
 530 fi
 531
 532 if test "x$ac_cv_header_sia_h" = "xyes" && test "x$ac_cv_header_siad_h" = "xyes"
 533 then
 534   AC_DEFINE(OSFSIA)
 535 fi
 536
 537 smart_try_dir="$OPENSSL_INCLUDE"
 538 dnl # stupid RedHat shit
 539 CFLAGS="$CFLAGS -DOPENSSL_NO_KRB5"
 540 AC_SMART_CHECK_INCLUDE(openssl/ssl.h)
 541 if test "x$ac_cv_header_openssl_ssl_h" = "xyes"; then
 542   AC_DEFINE(HAVE_OPENSSL_SSL_H)
 543   old_CPPFLAGS="$CPPFLAGS"
 544   if test "x$OPENSSL_INCLUDE" != "x"; then
 545       CPPFLAGS="-I$OPENSSL_INCLUDE $CPPFLAGS"
 546   fi
 547   AC_CHECK_HEADERS( \
 548           openssl/err.h \
 549           openssl/crypto.h \
 550           openssl/rand.h \
 551           openssl/engine.h
 552   )
 553   CPPFLAGS="$old_CPPFLAGS"
 554
 555   AC_MSG_CHECKING([for OpenSSL version >= 0.9.7])
 556        old_CPPFLAGS=$CPPFLAGS
 557        if test "x$OPENSSL_INCLUDE" != "x"; then
 558            CPPFLAGS="-I$OPENSSL_INCLUDE"
 559            fi
 560        AC_EGREP_CPP(yes,
 561        [#include <openssl/crypto.h>
 562        #if (OPENSSL_VERSION_NUMBER >= 0x00907000L)
 563         yes
 564        #endif
 565        ], goodssl="yes")
 566            if test "x$goodssl" != "xyes"; then
 567              AC_MSG_RESULT(no)
 568              OPENSSL_INCLUDE=
 569              OPENSSL_LIBS=
 570            else
 571              AC_MSG_RESULT(yes)
 572
 573              # Look for the OpenSSL libraries.
 574              smart_try_dir=$OPENSSL_LIBS
 575              AC_SMART_CHECK_LIB(crypto, DH_new)
 576              if test "x$ac_cv_lib_crypto_DH_new" = "xyes"; then
 577                AC_SMART_CHECK_LIB(ssl, SSL_new)
 578                if test "x$ac_cv_lib_ssl_SSL_new" != "xyes"; then
 579                  OPENSSL_INCLUDE=
 580                  OPENSSL_LIBS=
 581                fi
 582                export OPENSSL_INCLUDE OPENSSL_LIBS
 583              fi
 584            fi
 585        CPPFLAGS=$old_CPPFLAGS
 586 fi
 587
 588 dnl #############################################################
 589 dnl #
 590 dnl #  4. Checks for typedefs
 591 dnl #
 592 dnl #############################################################
 593
 594 dnl #
 595 dnl # Ensure that these are defined
 596 dnl #
 597 AC_TYPE_OFF_T
 598 AC_TYPE_PID_T
 599 AC_TYPE_SIZE_T
 600 AC_TYPE_UID_T
 601
 602 dnl check for socklen_t
 603 AC_CHECK_TYPE_INCLUDE([
 604 #ifdef HAVE_SYS_TYPES_H
 605 #include <sys/types.h>
 606 #endif
 607 #ifdef HAVE_SYS_SOCKET_H
 608 #include <sys/socket.h>
 609 #endif
 610 ],socklen_t, int)
 611
 612 dnl check for uint8_t
 613 AC_CHECK_TYPE_INCLUDE([
 614 #ifdef HAVE_INTTYPES_H
 615 #include <inttypes.h>
 616 #endif
 617 #ifdef HAVE_STDINT_H
 618 #include <stdint.h>
 619 #endif
 620 ],uint8_t, unsigned char)
 621
 622 dnl check for uint16_t
 623 AC_CHECK_TYPE_INCLUDE([
 624 #ifdef HAVE_INTTYPES_H
 625 #include <inttypes.h>
 626 #endif
 627 #ifdef HAVE_STDINT_H
 628 #include <stdint.h>
 629 #endif
 630 ],uint16_t, unsigned short)
 631
 632 dnl check for uint32_t
 633 AC_CHECK_TYPE_INCLUDE([
 634 #ifdef HAVE_INTTYPES_H
 635 #include <inttypes.h>
 636 #endif
 637 #ifdef HAVE_STDINT_H
 638 #include <stdint.h>
 639 #endif
 640 ],uint32_t, unsigned int)
 641
 642 dnl #############################################################
 643 dnl #
 644 dnl #  5. Checks for structures and functions
 645 dnl #
 646 dnl #############################################################
 647 AC_CHECK_FUNCS( \
 648         getopt_long \
 649         lockf \
 650         strsignal \
 651         sigaction \
 652         sigprocmask \
 653         pthread_sigmask \
 654         snprintf \
 655         vsnprintf \
 656         setsid \
 657         strncasecmp \
 658         strcasecmp \
 659         localtime_r \
 660         ctime_r \
 661         gmtime_r \
 662         strsep \
 663         inet_aton \
 664         inet_pton \
 665         inet_ntop \
 666         gethostname \
 667         setlinebuf \
 668         setvbuf \
 669         getusershell \
 670         initgroups
 671 )
 672 RADIUSD_NEED_DECLARATIONS( \
 673         crypt \
 674         strncasecmp \
 675         strcasecmp \
 676         inet_aton \
 677         gethostname \
 678         setlinebuf \
 679         getusershell \
 680         endusershell
 681 )
 682
 683 AC_TYPE_SIGNAL
 684
 685 dnl # check if we have utmpx.h
 686 dnl # if so, check if struct utmpx has entry ut_xtime
 687 dnl # if not, set it to define ut_xtime == ut_tv.tv_sec
 688 if test "x$ac_cv_header_utmpx_h" = "xyes"
 689 then
 690  AC_CHECK_STRUCT_HAS_MEMBER([#include <utmpx.h>], [struct utmpx], ut_xtime)
 691  if test "x$ac_cv_type_struct_utmpx_has_ut_xtime" = "x"
 692  then
 693    AC_DEFINE(ut_xtime,ut_tv.tv_sec)
 694  fi
 695 fi
 696
 697 dnl # struct ip_pktinfo
 698 AC_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in_pktinfo], ipi_addr)
 699 if test "x$ac_cv_type_struct_in_pktinfo_has_ipi_addr" = "xyes"
 700 then
 701         AC_DEFINE(HAVE_IP_PKTINFO)
 702 fi
 703
 704 dnl #############################################################
 705 dnl #
 706 dnl #  6. Checks for compiler characteristics
 707 dnl #
 708 dnl #############################################################
 709
 710 dnl #
 711 dnl # Ensure that these are defined
 712 dnl #
 713 AC_C_CONST
 714
 715 dnl #
 716 dnl # See if this is OS/2
 717 dnl #
 718 AC_MSG_CHECKING(type of OS)
 719 OS=`uname -s`
 720 AC_MSG_RESULT($OS)
 721 if test "$OS" = "OS/2"; then
 722         LIBPREFIX=
 723 else
 724         LIBPREFIX=lib
 725 fi
 726 AC_SUBST(LIBPREFIX)
 727
 728 dnl #
 729 dnl # Set Default CFLAGS
 730 dnl #
 731 if test "x$GCC" = "xyes"; then
 732     CFLAGS="$CFLAGS -Wall -D_GNU_SOURCE"
 733 fi
 734
 735 AC_MSG_CHECKING(for developer gcc flags)
 736 if test "x$developer" = "xyes" -a "x$GCC" = "xyes"; then
 737   devflags="-g -Wshadow -Wpointer-arith -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -W -Wredundant-decls -Wundef"
 738   CFLAGS="$CFLAGS $devflags"
 739   INSTALLSTRIP=""
 740   AC_MSG_RESULT(yes.  Using $devflags)
 741 else
 742   devflags=""
 743   CFLAGS="$CFLAGS -DNDEBUG"
 744   INSTALLSTRIP="-s"
 745   AC_MSG_RESULT(no.)
 746 fi
 747
 748 dnl #############################################################
 749 dnl #
 750 dnl #  7. Checks for library functions
 751 dnl #
 752 dnl #############################################################
 753
 754 dnl Check for libcrypt
 755 dnl We use crypt(3) which may be in libc, or in libcrypt (eg FreeBSD)
 756 AC_CHECK_LIB(crypt, crypt,
 757   CRYPTLIB="-lcrypt"
 758 )
 759 if test "$CRYPTLIB" != ""; then
 760   AC_DEFINE(HAVE_CRYPT)
 761 else
 762   AC_CHECK_FUNC(crypt, AC_DEFINE(HAVE_CRYPT))
 763 fi
 764
 765 dnl Check for libcipher
 766 AC_CHECK_LIB(cipher, setkey,
 767    CRYPTLIB="${CRYPTLIB} -lcipher"
 768 )
 769 AC_SUBST(CRYPTLIB)
 770
 771 if test "x$WITH_SNMP" = "xyes"; then
 772   SNMP_CHECKS
 773 fi
 774
 775 dnl Check the style of gethostbyaddr, in order of preference
 776 dnl GNU (_r eight args)
 777 dnl SYSV (_r six args)
 778 dnl BSD (three args, may not be thread safe)
 779 dnl Tru64 has BSD version, but it is thread safe
 780 dnl     http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1739____.HTM
 781 dnl We need #stdio.h to define NULL on FreeBSD (at least)
 782 gethostbyaddrrstyle=""
 783 AC_MSG_CHECKING([gethostbyaddr_r() syntax])
 784 case "$host" in
 785 *-freebsd*)
 786         AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE)
 787         gethostbyaddrrstyle=BSD
 788         AC_MSG_WARN([FreeBSD overridden to BSD-style])
 789         ;;
 790 esac
 791 if test "x$gethostbyaddrrstyle" = "x"; then
 792         AC_TRY_LINK([
 793 #include <stdio.h>
 794 #include <netdb.h>
 795 ], [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL, NULL) ], [
 796         AC_DEFINE(GETHOSTBYADDRRSTYLE, GNUSTYLE)
 797         gethostbyaddrrstyle=GNU
 798 ])
 799 fi
 800 if test "x$gethostbyaddrrstyle" = "x"; then
 801         AC_TRY_LINK([
 802 #include <stdio.h>
 803 #include <netdb.h>
 804 ], [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL) ] , [
 805                 AC_DEFINE(GETHOSTBYADDRRSTYLE, SYSVSTYLE)
 806                 gethostbyaddrrstyle=SYSV
 807         ])
 808 fi
 809 if test "x$gethostbyaddrrstyle" = "x"; then
 810         AC_TRY_LINK([
 811 #include <stdio.h>
 812 #include <netdb.h>
 813 ], [ gethostbyaddr(NULL, 0, 0)  ], [
 814                 AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE)
 815                 gethostbyaddrrstyle=BSD
 816         ])
 817 fi
 818
 819 if test "x$gethostbyaddrrstyle" = "x"; then
 820         AC_MSG_RESULT([none!  It must not exist, here.])
 821 else
 822         AC_MSG_RESULT([${gethostbyaddrrstyle}-style])
 823 fi
 824
 825 if test "x$gethostbyaddrrstyle" = "xBSD"; then
 826         AC_MSG_WARN([ ****** BSD-style gethostbyaddr might NOT be thread-safe! ****** ])
 827 fi
 828
 829 dnl Check the style of gethostbyname, in order of preference
 830 dnl GNU (_r seven args)
 831 dnl SYSV (_r five args)
 832 dnl BSD (two args, may not be thread safe)
 833 dnl Tru64 has BSD version, but it _is_ thread safe
 834 dnl     http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1946____.HTM
 835 dnl We need #stdio.h to define NULL on FreeBSD (at least)
 836 gethostbynamerstyle=""
 837 AC_MSG_CHECKING([gethostbyname_r() syntax])
 838 AC_TRY_LINK([
 839 #include <stdio.h>
 840 #include <netdb.h>
 841 ], [ gethostbyname_r(NULL, NULL, NULL, 0, NULL, NULL) ], [
 842         AC_DEFINE(GETHOSTBYNAMERSTYLE, GNUSTYLE)
 843         gethostbynamerstyle=GNU
 844 ])
 845 if test "x$gethostbynamerstyle" = "x"; then
 846         AC_TRY_LINK([
 847 #include <stdio.h>
 848 #include <netdb.h>
 849 ], [ gethostbyname_r(NULL, NULL, NULL, 0, NULL) ] , [
 850                 AC_DEFINE(GETHOSTBYNAMERSTYLE, SYSVSTYLE)
 851                 gethostbynamerstyle=SYSV
 852         ])
 853 fi
 854 if test "x$gethostbynamerstyle" = "x"; then
 855         AC_TRY_LINK([
 856 #include <stdio.h>
 857 #include <netdb.h>
 858 ], [ gethostbyname(NULL)  ], [
 859                 AC_DEFINE(GETHOSTBYNAMERSTYLE, BSDSTYLE)
 860                 gethostbynamerstyle=BSD
 861         ])
 862 fi
 863
 864 if test "x$gethostbynamerstyle" = "x"; then
 865         AC_MSG_RESULT([none!  It must not exist, here.])
 866 else
 867         AC_MSG_RESULT([${gethostbynamerstyle}-style])
 868 fi
 869
 870 if test "x$gethostbynamerstyle" = "xBSD"; then
 871         AC_MSG_WARN([ ****** BSD-style gethostbyname might NOT be thread-safe! ****** ])
 872 fi
 873
 874 dnl check for non-posix solaris ctime_r (extra buflen int arg)
 875 ctimerstyle=""
 876 AC_MSG_CHECKING([ctime_r() syntax])
 877 AC_TRY_LINK([
 878 #include <time.h>
 879 ], [ ctime_r(NULL, NULL, 0) ], [
 880         AC_DEFINE(CTIMERSTYLE, SOLARISSTYLE)
 881         ctimerstyle="SOLARIS"
 882 ])
 883 if test "x$ctimerstyle" = "x"; then
 884         AC_TRY_LINK([
 885 #include <time.h>
 886 ], [ ctime_r(NULL, NULL) ], [
 887                 AC_DEFINE(CTIMERSTYLE, POSIXSTYLE)
 888                 ctimerstyle="POSIX"
 889         ])
 890 fi
 891
 892 if test "x$ctimerstyle" = "x"; then
 893         AC_MSG_RESULT([none!  It must not exist, here.])
 894 else
 895         AC_MSG_RESULT([${ctimerstyle}-style])
 896 fi
 897
 898
 899 dnl If configuring with large file support, determine the right flags to
 900 dnl use based on the platform.  This is the wrong approach; autoconf 2.50
 901 dnl comes with a macro that takes the right approach.  But this works well
 902 dnl enough until we switch to autoconf 2.50 or later.
 903 if test x"$rad_enable_largefiles" = xyes ; then
 904     AC_MSG_CHECKING(for largefile linkage)
 905     case "$host" in
 906     *-aix4.[01]*)
 907         AC_MSG_RESULT(no)
 908         AC_MSG_ERROR([AIX before 4.2 does not support large files])
 909         ;;
 910     *-aix4*)
 911         AC_MSG_RESULT(ok)
 912         LFS_CFLAGS="-D_LARGE_FILES"
 913         LFS_LDFLAGS=""
 914         LFS_LIBS=""
 915         ;;
 916     *-hpux*)
 917         AC_MSG_RESULT(ok)
 918         LFS_CFLAGS="-D_LARGEFILE_SOURCE -D_FILE_OFFSET_BITS=64"
 919         LFS_LDFLAGS=""
 920         LFS_LIBS=""
 921         ;;
 922     *-irix*)
 923         AC_MSG_RESULT(no)
 924         AC_MSG_ERROR([Large files not supported on this platform])
 925         ;;
 926     *-linux*)
 927         AC_MSG_RESULT(maybe)
 928         LFS_CFLAGS="-D_LARGEFILE_SOURCE -D_FILE_OFFSET_BITS=64"
 929         LFS_LDFLAGS=""
 930         LFS_LIBS=""
 931         AC_DEFINE([_GNU_SOURCE], 1,
 932                   [Some versions of glibc need this defined for pread/pwrite.])
 933         ;;
 934     *-solaris*)
 935         AC_MSG_RESULT(ok)
 936         AC_PATH_PROG(GETCONF, getconf)
 937         if test -z "$GETCONF" ; then
 938             AC_MSG_ERROR([getconf required to configure large file support])
 939         fi
 940         LFS_CFLAGS=`$GETCONF LFS_CFLAGS`
 941         LFS_LDFLAGS=`$GETCONF LFS_LDFLAGS`
 942         LFS_LIBS=`$GETCONF LFS_LIBS`
 943         ;;
 944     *)
 945         AC_MSG_RESULT(maybe)
 946         LFS_CFLAGS="-D_LARGEFILE_SOURCE -D_FILE_OFFSET_BITS=64"
 947         LFS_LDFLAGS=""
 948         LFS_LIBS=""
 949         ;;
 950     esac
 951     AC_SUBST(LFS_CFLAGS)
 952     AC_SUBST(LFS_LDFLAGS)
 953     AC_SUBST(LFS_LIBS)
 954 fi
 955
 956 AC_SUBST(HOSTINFO, $host)
 957
 958 dnl #############################################################
 959 dnl #
 960 dnl #  8. Checks for system services
 961 dnl #
 962 dnl #############################################################
 963
 964 dnl #
 965 dnl # Figure out where libtool is located,
 966 dnl #
 967 top_builddir=`pwd`
 968 export top_builddir
 969 AC_MSG_RESULT([top_builddir=$top_builddir])
 970 dnl # AC_SUBST(top_builddir)
 971 AC_SUBST(LIBLTDL)
 972 AC_SUBST(INCLTDL)
 973
 974 dnl #
 975 dnl #  Work around stupid autoconf crap
 976 dnl #
 977 if test "x$INCLTDL" != "x";then
 978   INCLTDL='-I${top_builddir}/''libltdl'
 979 fi
 980
 981 dnl import libtool stuff
 982
 983 dnl #############################################################
 984 dnl #
 985 dnl #  Configure in any module directories.
 986 dnl #
 987 dnl #############################################################
 988
 989 mysubdirs=
 990 if test "x$EXPERIMENTAL" = "xyes"; then
 991   bar=`ls -1 src/modules/rlm_*/configure | sed 's%/configure%%'`
 992   dnl # get rid of LF's.
 993   mysubdirs=`echo $bar`
 994 else
 995   dnl #
 996   dnl # Find 'configure' in ONLY the stable modules
 997   dnl #
 998   for bar in `cat src/modules/stable`; do
 999     if test -f src/modules/$bar/configure; then
1000       mysubdirs="$mysubdirs src/modules/$bar"
1001     fi
1002   done
1003 fi
1004
1005 dnl ############################################################
1006 dnl # make modules by list
1007 dnl #############################################################
1008 MODULES=
1009 if test "x$EXPERIMENTAL" = "xyes"; then
1010   for foo in `ls -1 src/modules | grep rlm_`; do
1011     MODULES="$MODULES $foo"
1012   done
1013 else
1014    dnl #
1015    dnl # make ONLY the stable modules
1016    dnl #
1017    for foo in `cat src/modules/stable`; do
1018     MODULES="$MODULES $foo"
1019    done
1020 fi
1021
1022 dnl #
1023 dnl #  Don't change the variable name here.  Autoconf goes bonkers
1024 dnl #  if you do.
1025 dnl #
1026 AC_CONFIG_SUBDIRS($mysubdirs)
1027 AC_SUBST(MODULES)
1028
1029 dnl #############################################################
1030 dnl #
1031 dnl #  And finally, output the results.
1032 dnl #
1033 dnl #############################################################
1034
1035 dnl #
1036 dnl #  Substitute whatever libraries we found to be necessary
1037 dnl #
1038 AC_SUBST(LIBS)
1039 AC_SUBST(INSTALLSTRIP)
1040
1041 USE_SHARED_LIBS=$enable_shared
1042 AC_SUBST(USE_SHARED_LIBS)
1043 USE_STATIC_LIBS=$enable_static
1044 AC_SUBST(USE_STATIC_LIBS)
1045 AC_SUBST(STATIC_MODULES)
1046 AC_SUBST(RADIUSD_MAJOR_VERSION)
1047 AC_SUBST(RADIUSD_MINOR_VERSION)
1048 AC_SUBST(RADIUSD_VERSION)
1049 export CFLAGS LIBS
1050
1051 AC_OUTPUT(\
1052         ./Make.inc \
1053         ./src/include/build-radpaths-h \
1054         ./src/main/Makefile \
1055         ./src/main/checkrad.pl \
1056         ./src/main/radlast \
1057         ./src/main/radtest \
1058         ./scripts/rc.radiusd \
1059         ./scripts/radwatch \
1060         ./scripts/check-radiusd-config \
1061         ./scripts/radiusd.cron.daily \
1062         ./scripts/radiusd.cron.monthly \
1063         ./scripts/cryptpasswd \
1064         ./raddb/dictionary \
1065         ./raddb/radiusd.conf
1066 )
1067
1068 AC_OUTPUT_COMMANDS([echo timestamp > src/include/stamp-h])
1069 AC_OUTPUT_COMMANDS([(cd ./src/include && /bin/sh ./build-radpaths-h)])
1070 AC_OUTPUT_COMMANDS([(cd ./src/main   && chmod +x checkrad.pl radlast radtest)])
1071 AC_OUTPUT_COMMANDS([(cd ./scripts    && chmod +x rc.radiusd radwatch check-radiusd-config radiusd.cron.daily radiusd.cron.monthly cryptpasswd)])