configure.in

   1 dnl #############################################################
   2 dnl #
   3 dnl #  For information about autoconf, see:
   4 dnl #
   5 dnl #  http://www.gnu.org/software/autoconf/
   6 dnl #
   7 dnl #  The recommended order is:
   8 dnl #
   9 dnl #  AC_INIT(file)
  10 dnl #  0. checks for compiler, libtool, and command line options
  11 dnl #  1. checks for programs
  12 dnl #  2. checks for libraries
  13 dnl #  3. checks for header files
  14 dnl #  4. checks for typedefs
  15 dnl #  5. checks for structures and functions
  16 dnl #  6. checks for compiler characteristics
  17 dnl #  7. checks for library functions
  18 dnl #  8. checks for system services
  19 dnl #  AC_OUTPUT([file...])
  20 dnl #
  21 dnl #############################################################
  22
  23 AC_PREREQ([2.59])
  24 export CFLAGS LIBS LDFLAGS CPPFLAGS
  25 AC_INIT(src/main/radiusd.c)
  26 AC_CONFIG_HEADER(src/include/autoconf.h)
  27 AC_REVISION($Revision$)dnl
  28
  29 dnl # The version of the software
  30 RADIUSD_MAJOR_VERSION=2
  31 RADIUSD_MINOR_VERSION=0.0-pre0
  32 RADIUSD_VERSION="${RADIUSD_MAJOR_VERSION}.${RADIUSD_MINOR_VERSION}"
  33 PACKAGE=freeradius
  34
  35 dnl #############################################################
  36 dnl #
  37 dnl #  0. Checks for compiler, libtool, and command line options.
  38 dnl #
  39 dnl #############################################################
  40
  41 dnl Check for GNU cc
  42 AC_PROG_CC
  43 AC_PROG_CXX
  44
  45 dnl #
  46 dnl # check for AIX, to allow us to use some BSD functions
  47 dnl # must be before macros that call the compiler.
  48 dnl #
  49 AC_AIX
  50
  51 AC_PROG_GCC_TRADITIONAL
  52 AC_PROG_CC_SUNPRO
  53 AC_PROG_RANLIB
  54
  55 dnl Compile in large (2G+) file support.
  56 AC_SYS_LARGEFILE
  57
  58 dnl # check for system bytesex
  59 dnl # AC_DEFINES WORDS_BIGENDIAN
  60 AC_C_BIGENDIAN
  61
  62 dnl Find GNU Make.
  63 AC_CHECK_PROG(GMAKE, gmake, yes, no)
  64 if test $GMAKE = no; then
  65   AC_PATH_PROG(MAKE, make, /usr/local/bin/make)
  66 else
  67   AC_PATH_PROG(MAKE, gmake, /usr/local/gnu/bin/make)
  68 fi
  69 makever=`$ac_cv_path_MAKE --version 2>&1 | grep "GNU Make"`
  70 if test -z "$makever"; then
  71   AC_MSG_ERROR(GNU Make is not installed.  Please download and install it
  72                 from ftp://prep.ai.mit.edu/pub/gnu/make/ before continuing.)
  73 fi
  74
  75 dnl libltdl is installable
  76 AC_LIBLTDL_INSTALLABLE
  77
  78 dnl tell Makefile to build ltdl if needed
  79 if test x"$enable_ltdl_install" = x"yes"; then
  80   LTDL_SUBDIRS=libltdl
  81 fi
  82 AC_SUBST(LTDL_SUBDIRS)
  83
  84 dnl use system-wide libtool, if it exists
  85 AC_ARG_WITH(system-libtool,
  86 [  --with-system-libtool              try to use libtool installed in your system [default=use our own]],
  87 [ AC_PATH_PROG(LIBTOOL, libtool,,$PATH:/usr/local/bin) ],
  88 [
  89   LIBTOOL="`pwd`/libtool"
  90   AC_SUBST(LIBTOOL)
  91   dnl ensure that we're looking for dlopen
  92   AC_LIBTOOL_DLOPEN
  93
  94   dnl Figure out how to build shared libraries
  95   AC_PROG_LIBTOOL
  96 ])
  97
  98
  99 dnl Put this in later, when all distributed modules use autoconf.
 100 dnl AC_ARG_WITH(disablemodulefoo,
 101 dnl [  --without-rlm_foo       Disables module compilation.  Module list:]
 102 dnl esyscmd([find src/modules -type d -name rlm_\* -print |\
 103 dnl     sed -e 's%src/modules/.*/% (sub)- %; s%.*/%- %' |\
 104 dnl     awk '{print "                            "$0}']))
 105
 106 AC_ARG_ENABLE(strict-dependencies,
 107 [  --enable-strict-dependencies  Fail configure on lack of module dependancy.])
 108
 109 dnl extra argument: --with-docdir
 110 docdir='${datadir}/doc/freeradius'
 111 AC_MSG_CHECKING(docdir)
 112 AC_ARG_WITH(docdir,
 113 [  --with-docdir=DIR       Directory for documentation [DATADIR/doc/freeradius] ],
 114 [ case "$withval" in
 115     no)
 116         docdir=no
 117         ;;
 118     yes)
 119         ;;
 120     [[\\/$]]* | ?:[[\\/]]* )
 121         docdir="$withval"
 122         ;;
 123     *)
 124         AC_MSG_ERROR([expected an absolute directory name for --with-docdir: $withval])
 125         ;;
 126   esac ]
 127 )
 128 AC_SUBST(docdir)
 129 AC_MSG_RESULT($docdir)
 130 if test "x$docdir" = xno; then
 131         AC_MSG_WARN(Documentation files will NOT be installed.)
 132 fi
 133
 134 dnl extra argument: --with-logdir
 135 logdir='${localstatedir}/log/radius'
 136 AC_MSG_CHECKING(logdir)
 137 AC_ARG_WITH(logdir,
 138 [  --with-logdir=DIR       Directory for logfiles [LOCALSTATEDIR/log/radius] ],
 139 [ case "$withval" in
 140     no)
 141         AC_MSG_ERROR(Need logdir)
 142         ;;
 143     yes)
 144         ;;
 145     [[\\/$]]* | ?:[[\\/]]* )
 146         logdir="$withval"
 147         ;;
 148     *)
 149         AC_MSG_ERROR([expected an absolute directory name for --with-logdir: $withval])
 150         ;;
 151   esac ]
 152 )
 153 AC_SUBST(logdir)
 154 AC_MSG_RESULT($logdir)
 155
 156 dnl extra argument: --with-radacctdir
 157 radacctdir='${logdir}/radacct'
 158 AC_MSG_CHECKING(radacctdir)
 159 AC_ARG_WITH(radacctdir,
 160 [  --with-radacctdir=DIR   Directory for detail files [LOGDIR/radacct] ],
 161 [ case "$withval" in
 162     no)
 163         AC_MSG_ERROR(Need radacctdir)
 164         ;;
 165     yes)
 166         ;;
 167     [[\\/$]]* | ?:[[\\/]]* )
 168         radacctdir="$withval"
 169         ;;
 170     *)
 171         AC_MSG_ERROR([expected an absolute directory name for --with-radacctdir: $withval])
 172         ;;
 173   esac ]
 174 )
 175 AC_SUBST(radacctdir)
 176 AC_MSG_RESULT($radacctdir)
 177
 178 dnl extra argument: --with-raddbdir
 179 raddbdir='${sysconfdir}/raddb'
 180 AC_MSG_CHECKING(raddbdir)
 181 AC_ARG_WITH(raddbdir,
 182 [  --with-raddbdir=DIR     Directory for config files [SYSCONFDIR/raddb] ],
 183 [ case "$withval" in
 184     no)
 185         AC_MSG_ERROR(Need raddbdir)
 186         ;;
 187     yes)
 188         ;;
 189     [[\\/$]]* | ?:[[\\/]]* )
 190         raddbdir="$withval"
 191         ;;
 192     *)
 193         AC_MSG_ERROR([expected an absolute directory name for --with-raddbdir: $withval])
 194         ;;
 195   esac ]
 196 )
 197 AC_SUBST(raddbdir)
 198 AC_MSG_RESULT($raddbdir)
 199
 200 dnl extra argument: --with-ascend-binary
 201 ASCEND_BINARY=yes
 202 AC_ARG_WITH(ascend-binary,
 203 [  --with-ascend-binary    Include support for Ascend binary filter attributes (default=yes)],
 204 [ case "$withval" in
 205     yes)
 206         ;;
 207     *)
 208         ASCEND_BINARY=""
 209   esac ]
 210 )
 211 if test "X$ASCEND_BINARY" = "Xyes"; then
 212   AC_DEFINE(ASCEND_BINARY, [], [Include support for Ascend binary filter attributes])
 213 fi
 214
 215 dnl extra argument: --with-threads
 216 WITH_THREADS=yes
 217 AC_ARG_WITH(threads,
 218 [  --with-threads          Use threads, if available.  (default=yes) ],
 219 [ case "$withval" in
 220     yes)
 221         ;;
 222     *)
 223         WITH_THREADS=""
 224   esac ]
 225 )
 226
 227 dnl extra argument: --with-snmp
 228 WITH_SNMP=yes
 229 AC_ARG_WITH(snmp,
 230 [  --with-snmp             Compile in SNMP support. (default=yes)],
 231 [ case "$withval" in
 232     yes)
 233         ;;
 234     *)
 235         WITH_SNMP=no
 236   esac ]
 237 )
 238
 239 dnl #
 240 dnl #  Allow the user to specify a list of modules to be linked
 241 dnl #  statically to the server.
 242 dnl #
 243 STATIC_MODULES=
 244 AC_ARG_WITH(static_modules,
 245 [  --with-static-modules=QUOTED-MODULE-LIST],[
 246   for i in $withval; do
 247     STATIC_MODULES="$STATIC_MODULES -dlpreopen ../modules/rlm_$i/rlm_$i.la"
 248   done
 249 ])
 250
 251 MODULES=
 252 AC_ARG_WITH(modules,
 253 [ --with-modules=QUOTED-MODULE-LIST],[
 254  for i in $withval; do
 255    MODULES="$MODULES $i"
 256  done
 257 ])
 258
 259 dnl #
 260 dnl #  Enable developer C compiler warnings
 261 dnl #
 262 AC_ARG_ENABLE(developer,
 263 [  --enable-developer               Enables features of interest to developers.],
 264 [ case "$enableval" in
 265     no)
 266         developer=no
 267         ;;
 268     *)
 269         developer=yes
 270   esac ]
 271 )
 272
 273 if test "x$developer" != "xno" -a -d $srcdir/CVS; then
 274   dnl turn on the developer flag when taken from a CVS checkout (not a release)
 275   developer="yes"
 276 fi
 277
 278 dnl extra argument: --with-experimental-modules
 279 EXPERIMENTAL=
 280 AC_ARG_WITH(experimental-modules,
 281 [  --with-experimental-modules      Use experimental and unstable modules. (default=no) ],
 282 [ case "$withval" in
 283     yes)
 284         EXPERIMENTAL=yes
 285         ;;
 286     *)
 287   esac ]
 288 )
 289
 290 dnl #
 291 dnl # extra argument: --with-openssl-includes=dir
 292 dnl #
 293 OPENSSL_INCLUDE_DIR=
 294 AC_ARG_WITH(openssl-includes,
 295 [  --with-openssl-includes=DIR      Directory to look for OpenSSL include files],
 296 [ case "$withval" in
 297     *) OPENSSL_INCLUDE_DIR="$withval"
 298         ;;
 299   esac ]
 300 )
 301
 302 dnl #
 303 dnl # extra argument: --with-openssl-libraries=dir
 304 dnl #
 305 OPENSSL_LIB_DIR=
 306 AC_ARG_WITH(openssl-libraries,
 307 [  --with-openssl-libraries=DIR     Directory to look for OpenSSL library files],
 308 [ case "$withval" in
 309     *) OPENSSL_LIB_DIR="$withval"
 310         ;;
 311   esac ]
 312 )
 313
 314 dnl #
 315 dnl #  These next two arguments don't actually do anything.  They're
 316 dnl #  place holders so that the top-level configure script can tell
 317 dnl #  the user how to configure lower-level modules
 318 dnl #
 319
 320 dnl #
 321 dnl # extra argument: --with-rlm-FOO-lib-dir
 322 dnl #
 323 AC_ARG_WITH(rlm-FOO-lib-dir,
 324 [  --with-rlm-FOO-lib-dir=DIR       Directory to look for library files used by module FOO],
 325 [ case "$withval" in
 326     *)
 327         ;;
 328   esac ]
 329 )
 330
 331 dnl #
 332 dnl # extra argument: --with-rlm-FOO-include-dir
 333 dnl #
 334 AC_ARG_WITH(rlm-FOO-include-dir,
 335 [  --with-rlm-FOO-include-dir=DIR   Directory to look for include files used by module FOO],
 336 [ case "$withval" in
 337     *)
 338         ;;
 339   esac ]
 340 )
 341
 342 dnl See what include-style is used by the make program.
 343 dnl AC_MSG_CHECKING(include style for make)
 344 dnl echo "include /dev/null" > testmake.$$
 345 dnl echo "all:" >> testmake.$$
 346 dnl make -f testmake.$$ >/dev/null 2>&1
 347 dnl if test $? = 0
 348 dnl then
 349 dnl     INCLUDE=include
 350 dnl     IQUOTE=
 351 dnl else
 352 dnl     INCLUDE=.include
 353 dnl     IQUOTE='"'
 354 dnl fi
 355 dnl rm -f testmake.$$
 356 dnl AC_MSG_RESULT(" $INCLUDE")
 357 dnl AC_SUBST(INCLUDE)
 358 dnl AC_SUBST(IQUOTE)
 359
 360 dnl extra argument: --with-udpfromto
 361 WITH_UDPFROMTO=yes
 362 AC_ARG_WITH(udpfromto,
 363 [  --with-udpfromto        Compile in UDPFROMTO support. (default=yes)],
 364 [ case "$withval" in
 365     yes)
 366         WITH_UDPFROMTO=yes
 367         ;;
 368     *)
 369         WITH_UDPFROMTO=no
 370   esac ]
 371 )
 372
 373 if test "x$WITH_UDPFROMTO" = "xyes"; then
 374         AC_DEFINE(WITH_UDPFROMTO, [], [define if you want udpfromto])
 375 fi
 376
 377 dnl #############################################################
 378 dnl #
 379 dnl #  1. Checks for programs
 380 dnl #
 381 dnl #############################################################
 382
 383 CHECKRAD=checkrad.pl
 384 AC_PATH_PROG(PERL, perl, /usr/local/bin/perl)
 385 if test "x$ac_cv_path_PERL" = "x"; then
 386   AC_MSG_WARN(perl not found - Simultaneous-Use and checkrad.pl may not work)
 387 fi
 388 AC_PATH_PROG(SNMPGET, snmpget)
 389 if test "x$ac_cv_path_SNMPGET" = "x"; then
 390   AC_MSG_WARN(snmpget not found - Simultaneous-Use and checkrad.pl may not work)
 391 fi
 392
 393 AC_PATH_PROG(SNMPWALK, snmpwalk)
 394 if test "x$ac_cv_path_SNMPWALK" = "x"; then
 395   AC_MSG_WARN(snmpwalk not found - Simultaneous-Use and checkrad.pl may not work)
 396 fi
 397
 398 AC_PATH_PROG(RUSERS, rusers, /usr/bin/rusers)
 399
 400 dnl FIXME This is truly gross.
 401 missing_dir=`cd $ac_aux_dir && pwd`
 402 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
 403 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
 404 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
 405
 406 AC_PATH_PROG(LOCATE,locate)
 407 AC_PATH_PROG(DIRNAME,dirname)
 408 AC_PATH_PROG(GREP,grep)
 409
 410 dnl #############################################################
 411 dnl #
 412 dnl #  2. Checks for libraries
 413 dnl #
 414 dnl #############################################################
 415
 416 dnl If using pthreads, check for -lpthread (posix) or -lc_r (*BSD)
 417 old_CFLAGS=$CFLAGS
 418 if test "x$WITH_THREADS" = "xyes"; then
 419   if test $ac_cv_prog_suncc = "yes"; then
 420     CFLAGS="$CFLAGS -mt"
 421   fi
 422
 423   AC_CHECK_HEADERS(pthread.h, [], [ WITH_THREADS="no" ])
 424
 425 dnl #
 426 dnl # pthread stuff is usually in -lpthread
 427 dnl # or in -lc_r, on *BSD
 428 dnl #
 429 dnl # On Some systems, we need extra pre-processor flags, to get them to
 430 dnl # to do the threading properly.
 431 dnl #
 432   AC_CHECK_LIB(pthread, pthread_create,
 433                 [ CFLAGS="$CFLAGS -D_REENTRANT -D_POSIX_PTHREAD_SEMANTICS"
 434                   LIBS="$LIBS -lpthread" ],
 435                 AC_CHECK_LIB(c_r, pthread_create,
 436                             [ CFLAGS="$CFLAGS -pthread -D_THREAD_SAFE" ],
 437                             [ WITH_THREADS="no" ]
 438                             )
 439                 )
 440 fi
 441
 442 dnl #
 443 dnl # If we have NO pthread libraries, remove any knowledge of threads.
 444 dnl #
 445 if test "x$WITH_THREADS" != "xyes"; then
 446   CFLAGS=$old_CFLAGS
 447   ac_cv_header_pthread_h="no"
 448   WITH_THREADS=no
 449 else
 450   dnl #
 451   dnl #  We need sem_init() and friends, as they're the friendliest
 452   dnl #  semaphore functions for threading.
 453   dnl #
 454   dnl # HP/UX requires linking with librt, too, to get the sem_* symbols.
 455   dnl # Some systems have them in -lsem
 456   dnl # Solaris has them in -lposix4
 457   dnl # NetBSD has them in -lsemaphore
 458
 459   AC_SEARCH_LIBS(sem_init, pthread sem posix4 rt semaphore,
 460         [],
 461         [AC_MSG_ERROR(-lsem not found.  You may want to download it from ftp://ftp.to.gd-es.com/pub/BSDI/libsem.tar.bz2 or ftp://ftp.freeradius.org/pub/radius/contrib/libsem.tar.gz)]
 462    )
 463 fi
 464
 465 dnl Check if we need -lsocket
 466 AC_CHECK_LIB(socket, getsockname)
 467
 468 dnl Check for -lresolv
 469 dnl This library may be needed later.
 470 AC_CHECK_LIB(resolv, inet_aton)
 471
 472 dnl Check if we need -lnsl. Usually if we want to
 473 dnl link against -lsocket we need to include -lnsl as well.
 474 AC_CHECK_LIB(nsl, inet_ntoa)
 475
 476 dnl Check for OpenSSL libraries.
 477 OPENSSL_LIBS=
 478 old_LIBS=$LIBS
 479 if test "x$OPENSSL_LIB_DIR" != "x"; then
 480     LIBS="-L$OPENSSL_LIB_DIR $LIBS"
 481 fi
 482 AC_CHECK_LIB(crypto, DH_new,
 483     [
 484         AC_DEFINE(HAVE_LIBCRYPTO, 1,
 485             [Define to 1 if you have the `crypto' library (-lcrypto).])
 486         AC_CHECK_LIB(ssl, SSL_new,
 487             [
 488                 AC_DEFINE(HAVE_LIBSSL, 1,
 489                     [Define to 1 if you have the `ssl' library (-lssl).])
 490                 if test "x$OPENSSL_LIB_DIR" != "x"; then
 491                     OPENSSL_LIBS="-L$OPENSSL_LIB_DIR"
 492                 fi
 493                 OPENSSL_LIBS="$OPENSSL_LIBS -lcrypto -lssl -lcrypto"
 494             ], [])
 495     ], [])
 496 LIBS=$old_LIBS
 497
 498 AC_CHECK_LIB(ws2_32, htonl)
 499
 500 dnl Check the pcap library for the RADIUS sniffer.
 501 PCAP_LIBS=
 502 AC_CHECK_LIB(pcap, pcap_open_live,
 503         [ PCAP_LIBS="-lpcap"
 504         AC_DEFINE(HAVE_LIBPCAP, 1,
 505                 [Define to 1 if you have the `pcap' library (-lpcap).])
 506         ],
 507         [ AC_MSG_WARN([pcap library not found, silently disabling the RADIUS sniffer.]) ])
 508
 509 dnl #############################################################
 510 dnl #
 511 dnl #  3. Checks for header files
 512 dnl #
 513 dnl #############################################################
 514
 515 dnl #
 516 dnl # Interix requires us to set -D_ALL_SOURCE, otherwise
 517 dnl # getopt will be #included, but won't link.  <sigh>
 518 dnl #
 519 dnl #
 520 case "$host" in
 521 *-interix*)
 522         CFLAGS="$CFLAGS -D_ALL_SOURCE"
 523         ;;
 524 *-darwin*)
 525         CFLAGS="$CFLAGS -DDARWIN"
 526         ;;
 527 esac
 528
 529 AC_HEADER_DIRENT
 530 AC_HEADER_STDC
 531 AC_HEADER_TIME
 532 AC_HEADER_SYS_WAIT
 533
 534 AC_CHECK_HEADERS( \
 535         unistd.h \
 536         crypt.h \
 537         errno.h \
 538         resource.h \
 539         sys/resource.h \
 540         getopt.h \
 541         malloc.h \
 542         utmp.h \
 543         utmpx.h \
 544         signal.h \
 545         sys/select.h \
 546         syslog.h \
 547         inttypes.h \
 548         stdint.h \
 549         stdio.h \
 550         netdb.h \
 551         semaphore.h \
 552         arpa/inet.h \
 553         netinet/in.h \
 554         sys/types.h \
 555         sys/socket.h \
 556         winsock.h \
 557         sys/time.h \
 558         sys/wait.h \
 559         sys/security.h \
 560         fcntl.h \
 561         sys/fcntl.h \
 562         net/if.h \
 563         prot.h \
 564         pwd.h \
 565         grp.h \
 566         sia.h \
 567         siad.h
 568 )
 569
 570 REGEX=no
 571 AC_CHECK_HEADER(regex.h, AC_DEFINE(HAVE_REGEX_H, [], [define this if we have the <regex.h> header file]))
 572 if test "x$ac_cv_header_regex_h" = "xyes"; then
 573   REGEX_EXTENDED=no
 574   REGEX=yes
 575   AC_EGREP_CPP(yes,
 576     [#include <regex.h>
 577      #ifdef REG_EXTENDED
 578        yes
 579      #endif
 580      ], [AC_DEFINE(HAVE_REG_EXTENDED, [], [define this if we have REG_EXTENDED (from <regex.h>)]) REGEX_EXTENDED=yes])
 581 fi
 582 AC_SUBST(REGEX)
 583 AC_SUBST(REGEX_EXTENDED)
 584
 585 dnl #
 586 dnl #  other checks which require headers
 587 dnl #
 588 if test "x$ac_cv_header_sys_security_h" = "xyes" && test "x$ac_cv_header_prot_h" = "xyes"
 589 then
 590   AC_DEFINE(OSFC2, [], [define if you have OSFC2 authentication])
 591 fi
 592
 593 if test "x$ac_cv_header_sia_h" = "xyes" && test "x$ac_cv_header_siad_h" = "xyes"
 594 then
 595   AC_DEFINE(OSFSIA, [], [define if you have OSFSIA authentication])
 596 fi
 597
 598 dnl Check for OpenSSL includes.
 599 OPENSSL_INCLUDE="-DNO_OPENSSL"
 600 if test "x$OPENSSL_LIBS" = "x"; then
 601     AC_MSG_NOTICE([skipping test for openssl/ssl.h])
 602 else
 603     old_CPPFLAGS=$CPPFLAGS
 604     if test "x$OPENSSL_INCLUDE_DIR" != "x"; then
 605         CPPFLAGS="$CPPFLAGS -I$OPENSSL_INCLUDE_DIR"
 606     fi
 607     dnl # stupid RedHat shit
 608     CPPFLAGS="$CPPFLAGS -DOPENSSL_NO_KRB5"
 609     AC_CHECK_HEADERS( \
 610         openssl/ssl.h \
 611         openssl/crypto.h \
 612         openssl/err.h \
 613         openssl/engine.h,
 614         [],
 615         OPENSSL_LIBS=
 616     )
 617     if test "x$OPENSSL_LIBS" != "x"; then
 618         AC_MSG_CHECKING([for OpenSSL version >= 0.9.7])
 619         AC_EGREP_CPP(yes,
 620             [#include <openssl/crypto.h>
 621              #if (OPENSSL_VERSION_NUMBER >= 0x00907000L)
 622              yes
 623              #endif
 624             ], goodssl="yes")
 625         if test "x$goodssl" != "xyes"; then
 626             AC_MSG_RESULT(no)
 627             OPENSSL_LIBS=
 628         else
 629             AC_MSG_RESULT(yes)
 630             if test "x$OPENSSL_INCLUDE_DIR" != "x"; then
 631                 OPENSSL_INCLUDE="-I$OPENSSL_INCLUDE_DIR -DOPENSSL_NO_KRB5"
 632             else
 633                 OPENSSL_INCLUDE="-DOPENSSL_NO_KRB5"
 634             fi
 635         fi
 636     fi
 637     CPPFLAGS=$old_CPPFLAGS
 638 fi
 639 AC_SUBST(OPENSSL_INCLUDE)
 640 AC_SUBST(OPENSSL_LIBS)
 641 export OPENSSL_LIBS
 642
 643 dnl Check the pcap includes for the RADIUS sniffer.
 644 if test "x$PCAP_LIBS" = x; then
 645     AC_MSG_NOTICE([skipping test for pcap.h.])
 646 else
 647     AC_CHECK_HEADER(pcap.h,
 648         AC_DEFINE(HAVE_PCAP_H, 1,
 649                 [Define to 1 if you have the <pcap.h> header file.]),
 650         [ PCAP_LIBS=
 651         AC_MSG_WARN([pcap.h not found, silently disabling the RADIUS sniffer.])
 652         ])
 653 fi
 654 AC_SUBST(PCAP_LIBS)
 655
 656 dnl #############################################################
 657 dnl #
 658 dnl #  4. Checks for typedefs
 659 dnl #
 660 dnl #############################################################
 661
 662 dnl #
 663 dnl # Ensure that these are defined
 664 dnl #
 665 AC_TYPE_OFF_T
 666 AC_TYPE_PID_T
 667 AC_TYPE_SIZE_T
 668 AC_TYPE_UID_T
 669
 670 dnl check for socklen_t
 671 FR_CHECK_TYPE_INCLUDE([
 672 #ifdef HAVE_SYS_TYPES_H
 673 #include <sys/types.h>
 674 #endif
 675 #ifdef HAVE_SYS_SOCKET_H
 676 #include <sys/socket.h>
 677 #endif
 678 ],socklen_t, int, [socklen_t is generally 'int' on systems which don't use it])
 679
 680 dnl check for uint8_t
 681 FR_CHECK_TYPE_INCLUDE([
 682 #ifdef HAVE_INTTYPES_H
 683 #include <inttypes.h>
 684 #endif
 685 #ifdef HAVE_STDINT_H
 686 #include <stdint.h>
 687 #endif
 688 ],uint8_t, unsigned char, [uint8_t should be the canonical 'octet' for network traffic])
 689
 690 dnl check for uint16_t
 691 FR_CHECK_TYPE_INCLUDE([
 692 #ifdef HAVE_INTTYPES_H
 693 #include <inttypes.h>
 694 #endif
 695 #ifdef HAVE_STDINT_H
 696 #include <stdint.h>
 697 #endif
 698 ],uint16_t, unsigned short, [uint16_t should be the canonical '2 octets' for network traffic])
 699
 700 dnl check for uint32_t
 701 FR_CHECK_TYPE_INCLUDE([
 702 #ifdef HAVE_INTTYPES_H
 703 #include <inttypes.h>
 704 #endif
 705 #ifdef HAVE_STDINT_H
 706 #include <stdint.h>
 707 #endif
 708 ],uint32_t, unsigned int, [uint32_t should be the canonical 'network integer])
 709
 710 AC_CHECK_TYPE(struct in6_addr, AC_DEFINE(HAVE_STRUCT_IN6_ADDR, 1, [IPv6 address structure]), [], [
 711 #ifdef HAVE_NETINET_IN_H
 712 #include <netinet/in.h>
 713 #endif
 714 ])
 715
 716 AC_CHECK_TYPE(struct sockaddr_storage, AC_DEFINE(HAVE_STRUCT_SOCKADDR_STORAGE, 1, [Generic socket addresses]), [], [
 717 #ifdef HAVE_NETINET_IN_H
 718 #include <netinet/in.h>
 719 #endif
 720 #ifdef HAVE_SYS_SOCKET_H
 721 #include <sys/socket.h>
 722 #endif
 723 ])
 724
 725 AC_CHECK_TYPE(struct sockaddr_in6, AC_DEFINE(HAVE_STRUCT_SOCKADDR_IN6, 1, [IPv6 socket addresses]), [], [
 726 #ifdef HAVE_NETINET_IN_H
 727 #include <netinet/in.h>
 728 #endif
 729 ])
 730
 731 AC_CHECK_TYPE(struct addrinfo, AC_DEFINE(HAVE_STRUCT_ADDRINFO, 1, [Generic DNS lookups]), [], [
 732 #ifdef HAVE_SYS_TYPES_H
 733 #include <sys/types.h>
 734 #endif
 735 #ifdef HAVE_SYS_SOCKET_H
 736 #include <sys/socket.h>
 737 #endif
 738 #ifdef HAVE_NETDB_H
 739 #include <netdb.h>
 740 #endif
 741 ])
 742
 743 dnl #############################################################
 744 dnl #
 745 dnl #  5. Checks for structures and functions
 746 dnl #
 747 dnl #############################################################
 748 AC_CHECK_FUNCS( \
 749         getopt_long \
 750         lockf \
 751         strsignal \
 752         sigaction \
 753         sigprocmask \
 754         pthread_sigmask \
 755         snprintf \
 756         vsnprintf \
 757         setsid \
 758         strncasecmp \
 759         strcasecmp \
 760         localtime_r \
 761         ctime_r \
 762         gmtime_r \
 763         strsep \
 764         inet_aton \
 765         inet_pton \
 766         inet_ntop \
 767         setlinebuf \
 768         setvbuf \
 769         getusershell \
 770         initgroups \
 771         getaddrinfo \
 772         getnameinfo \
 773         closefrom \
 774         gettimeofday \
 775         strlcat \
 776         strlcpy
 777 )
 778 RADIUSD_NEED_DECLARATIONS( \
 779         crypt \
 780         strncasecmp \
 781         strcasecmp \
 782         inet_aton \
 783         setlinebuf \
 784         getusershell \
 785         endusershell
 786 )
 787
 788 AC_TYPE_SIGNAL
 789
 790 dnl # check if we have utmpx.h
 791 dnl # if so, check if struct utmpx has entry ut_xtime
 792 dnl # if not, set it to define ut_xtime == ut_tv.tv_sec
 793 if test "x$ac_cv_header_utmpx_h" = "xyes"
 794 then
 795  FR_CHECK_STRUCT_HAS_MEMBER([#include <utmpx.h>], [struct utmpx], ut_xtime)
 796  if test "x$ac_cv_type_struct_utmpx_has_ut_xtime" = "x"
 797  then
 798    AC_DEFINE(ut_xtime,ut_tv.tv_sec, [define to something if you don't have ut_xtime in struct utmpx])
 799  fi
 800 fi
 801
 802 dnl # struct ip_pktinfo
 803 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in_pktinfo], ipi_addr)
 804 if test "x$ac_cv_type_struct_in_pktinfo_has_ipi_addr" = "xyes"
 805 then
 806         AC_DEFINE(HAVE_IP_PKTINFO, [], [define if you have IP_PKTINFO (Linux)])
 807 fi
 808
 809 dnl # struct in6_pktinfo
 810 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in6_pktinfo], ipi6_addr)
 811 if test "x$ac_cv_type_struct_in6_pktinfo_has_ipi6_addr" = "xyes"
 812 then
 813         AC_DEFINE(HAVE_IN6_PKTINFO, [], [define if you have IN6_PKTINFO (Linux)])
 814 fi
 815
 816 dnl #############################################################
 817 dnl #
 818 dnl #  6. Checks for compiler characteristics
 819 dnl #
 820 dnl #############################################################
 821
 822 dnl #
 823 dnl # Ensure that these are defined
 824 dnl #
 825 AC_C_CONST
 826
 827 dnl #
 828 dnl # See if this is OS/2
 829 dnl #
 830 AC_MSG_CHECKING(type of OS)
 831 OS=`uname -s`
 832 AC_MSG_RESULT($OS)
 833 if test "$OS" = "OS/2"; then
 834         LIBPREFIX=
 835 else
 836         LIBPREFIX=lib
 837 fi
 838 AC_SUBST(LIBPREFIX)
 839
 840 dnl #
 841 dnl # Set Default CFLAGS
 842 dnl #
 843 if test "x$GCC" = "xyes"; then
 844     CFLAGS="$CFLAGS -Wall -D_GNU_SOURCE"
 845 fi
 846
 847 AC_MSG_CHECKING(for developer gcc flags)
 848 if test "x$developer" = "xyes" -a "x$GCC" = "xyes"; then
 849   devflags="-g -Wshadow -Wpointer-arith -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -W -Wredundant-decls -Wundef"
 850   CFLAGS="$CFLAGS $devflags"
 851   INSTALLSTRIP=""
 852   AC_MSG_RESULT(yes.  Using $devflags)
 853 else
 854   devflags=""
 855   CFLAGS="$CFLAGS -DNDEBUG"
 856   INSTALLSTRIP="-s"
 857   AC_MSG_RESULT(no.)
 858 fi
 859
 860 dnl #############################################################
 861 dnl #
 862 dnl #  7. Checks for library functions
 863 dnl #
 864 dnl #############################################################
 865
 866 dnl Check for libcrypt
 867 dnl We use crypt(3) which may be in libc, or in libcrypt (eg FreeBSD)
 868 AC_CHECK_LIB(crypt, crypt,
 869   CRYPTLIB="-lcrypt"
 870 )
 871 if test "$CRYPTLIB" != ""; then
 872   AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function])
 873 else
 874   AC_CHECK_FUNC(crypt, AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function]))
 875 fi
 876
 877 dnl Check for libcipher
 878 AC_CHECK_LIB(cipher, setkey,
 879    CRYPTLIB="${CRYPTLIB} -lcipher"
 880 )
 881 AC_SUBST(CRYPTLIB)
 882
 883 if test "x$WITH_SNMP" = "xyes"; then
 884   SNMP_CHECKS
 885 fi
 886
 887 dnl Check the style of gethostbyaddr, in order of preference
 888 dnl GNU (_r eight args)
 889 AC_DEFINE(GNUSTYLE, [1], [GNU-Style get*byaddr_r])
 890 dnl SYSV (_r six args)
 891 AC_DEFINE(SYSVSTYLE, [2], [SYSV-Style get*byaddr_r])
 892 dnl BSD (three args, may not be thread safe)
 893 AC_DEFINE(BSDSTYLE, [3], [BSD-Style get*byaddr_r])
 894 dnl Tru64 has BSD version, but it is thread safe
 895 dnl     http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1739____.HTM
 896 dnl We need #stdio.h to define NULL on FreeBSD (at least)
 897 gethostbyaddrrstyle=""
 898 AC_MSG_CHECKING([gethostbyaddr_r() syntax])
 899 case "$host" in
 900 *-freebsd*)
 901         AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE, [style of gethostbyaddr_r functions ])
 902         gethostbyaddrrstyle=BSD
 903         AC_MSG_WARN([FreeBSD overridden to BSD-style])
 904         ;;
 905 esac
 906 if test "x$gethostbyaddrrstyle" = "x"; then
 907         AC_TRY_LINK([
 908 #include <stdio.h>
 909 #include <netdb.h>
 910 ], [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL, NULL) ], [
 911         AC_DEFINE(GETHOSTBYADDRRSTYLE, GNUSTYLE, [style of gethostbyaddr_r functions ])
 912         gethostbyaddrrstyle=GNU
 913 ])
 914 fi
 915 if test "x$gethostbyaddrrstyle" = "x"; then
 916         AC_TRY_LINK([
 917 #include <stdio.h>
 918 #include <netdb.h>
 919 ], [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL) ] , [
 920                 AC_DEFINE(GETHOSTBYADDRRSTYLE, SYSVSTYLE, [style of gethostbyaddr_r functions ])
 921                 gethostbyaddrrstyle=SYSV
 922         ])
 923 fi
 924 if test "x$gethostbyaddrrstyle" = "x"; then
 925         AC_TRY_LINK([
 926 #include <stdio.h>
 927 #include <netdb.h>
 928 ], [ gethostbyaddr(NULL, 0, 0)  ], [
 929                 AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE, [style of gethostbyaddr_r functions ])
 930                 gethostbyaddrrstyle=BSD
 931         ])
 932 fi
 933
 934 if test "x$gethostbyaddrrstyle" = "x"; then
 935         AC_MSG_RESULT([none!  It must not exist, here.])
 936 else
 937         AC_MSG_RESULT([${gethostbyaddrrstyle}-style])
 938 fi
 939
 940 if test "x$gethostbyaddrrstyle" = "xBSD"; then
 941         AC_MSG_WARN([ ****** BSD-style gethostbyaddr might NOT be thread-safe! ****** ])
 942 fi
 943
 944 dnl Check the style of gethostbyname, in order of preference
 945 dnl GNU (_r seven args)
 946 dnl SYSV (_r five args)
 947 dnl BSD (two args, may not be thread safe)
 948 dnl Tru64 has BSD version, but it _is_ thread safe
 949 dnl     http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1946____.HTM
 950 dnl We need #stdio.h to define NULL on FreeBSD (at least)
 951 gethostbynamerstyle=""
 952 AC_MSG_CHECKING([gethostbyname_r() syntax])
 953 AC_TRY_LINK([
 954 #include <stdio.h>
 955 #include <netdb.h>
 956 ], [ gethostbyname_r(NULL, NULL, NULL, 0, NULL, NULL) ], [
 957         AC_DEFINE(GETHOSTBYNAMERSTYLE, GNUSTYLE, [style of gethostbyname_r functions ])
 958         gethostbynamerstyle=GNU
 959 ])
 960 if test "x$gethostbynamerstyle" = "x"; then
 961         AC_TRY_LINK([
 962 #include <stdio.h>
 963 #include <netdb.h>
 964 ], [ gethostbyname_r(NULL, NULL, NULL, 0, NULL) ] , [
 965                 AC_DEFINE(GETHOSTBYNAMERSTYLE, SYSVSTYLE, [style of gethostbyname_r functions ])
 966                 gethostbynamerstyle=SYSV
 967         ])
 968 fi
 969 if test "x$gethostbynamerstyle" = "x"; then
 970         AC_TRY_LINK([
 971 #include <stdio.h>
 972 #include <netdb.h>
 973 ], [ gethostbyname(NULL)  ], [
 974                 AC_DEFINE(GETHOSTBYNAMERSTYLE, BSDSTYLE, [style of gethostbyname_r functions ])
 975                 gethostbynamerstyle=BSD
 976         ])
 977 fi
 978
 979 if test "x$gethostbynamerstyle" = "x"; then
 980         AC_MSG_RESULT([none!  It must not exist, here.])
 981 else
 982         AC_MSG_RESULT([${gethostbynamerstyle}-style])
 983 fi
 984
 985 if test "x$gethostbynamerstyle" = "xBSD"; then
 986         AC_MSG_WARN([ ****** BSD-style gethostbyname might NOT be thread-safe! ****** ])
 987 fi
 988
 989 dnl check for non-posix solaris ctime_r (extra buflen int arg)
 990 AC_DEFINE(POSIXSTYLE, [1], [Posix-Style ctime_r])
 991 AC_DEFINE(SOLARISSTYLE, [2], [Solaris-Style ctime_r])
 992 ctimerstyle=""
 993 AC_MSG_CHECKING([ctime_r() syntax])
 994 AC_TRY_LINK([
 995 #include <time.h>
 996 ], [ ctime_r(NULL, NULL, 0) ], [
 997         AC_DEFINE(CTIMERSTYLE, SOLARISSTYLE, [style of ctime_r function])
 998         ctimerstyle="SOLARIS"
 999 ])
1000 if test "x$ctimerstyle" = "x"; then
1001         AC_TRY_LINK([
1002 #include <time.h>
1003 ], [ ctime_r(NULL, NULL) ], [
1004                 AC_DEFINE(CTIMERSTYLE, POSIXSTYLE, [style of ctime_r function])
1005                 ctimerstyle="POSIX"
1006         ])
1007 fi
1008
1009 if test "x$ctimerstyle" = "x"; then
1010         AC_MSG_RESULT([none!  It must not exist, here.])
1011 else
1012         AC_MSG_RESULT([${ctimerstyle}-style])
1013 fi
1014
1015 AC_SUBST(HOSTINFO, $host)
1016
1017 dnl #############################################################
1018 dnl #
1019 dnl #  8. Checks for system services
1020 dnl #
1021 dnl #############################################################
1022
1023 dnl #
1024 dnl # Figure out where libtool is located,
1025 dnl #
1026 top_builddir=`pwd`
1027 export top_builddir
1028 AC_MSG_RESULT([top_builddir=$top_builddir])
1029 dnl # AC_SUBST(top_builddir)
1030 AC_SUBST(LIBLTDL)
1031 AC_SUBST(INCLTDL)
1032
1033 dnl import libtool stuff
1034
1035 dnl #############################################################
1036 dnl #
1037 dnl #  Configure in any module directories.
1038 dnl #
1039 dnl #############################################################
1040
1041 mysubdirs="$LIBLTDLPATH"
1042 if test "x$EXPERIMENTAL" = "xyes"; then
1043   bar=`ls -1 "${srcdir}"/src/modules/rlm_*/configure | sed 's%/configure%%'`
1044   dnl # get rid of LF's.
1045   mysubdirs=`echo $mysubdirs $bar`
1046 else
1047   dnl #
1048   dnl # Find 'configure' in ONLY the stable modules
1049   dnl #
1050   for bar in `cat "${srcdir}"/src/modules/stable`; do
1051     if test -f "${srcdir}"/src/modules/$bar/configure; then
1052       mysubdirs="$mysubdirs src/modules/$bar"
1053     fi
1054   done
1055 fi
1056
1057 dnl ############################################################
1058 dnl # make modules by list
1059 dnl #############################################################
1060 if test "x$EXPERIMENTAL" = "xyes"; then
1061   for foo in `ls -1 "${srcdir}"/src/modules | grep rlm_`; do
1062     MODULES="$MODULES $foo"
1063   done
1064 else
1065    dnl #
1066    dnl # make ONLY the stable modules
1067    dnl #
1068    for foo in `cat "${srcdir}"/src/modules/stable`; do
1069     MODULES="$MODULES $foo"
1070    done
1071 fi
1072
1073 dnl #
1074 dnl #  Don't change the variable name here.  Autoconf goes bonkers
1075 dnl #  if you do.
1076 dnl #
1077 AC_CONFIG_SUBDIRS($LTDL_SUBDIRS $mysubdirs)
1078 AC_SUBST(MODULES)
1079
1080 dnl #############################################################
1081 dnl #
1082 dnl #  And finally, output the results.
1083 dnl #
1084 dnl #############################################################
1085
1086 AC_CONFIG_COMMANDS([stamp-h], [echo timestamp > src/include/stamp-h])
1087 AC_CONFIG_COMMANDS([build-radpaths-h], [(cd ./src/include && /bin/sh ./build-radpaths-h)])
1088 AC_CONFIG_COMMANDS([main-chmod], [(cd ./src/main   && chmod +x checkrad.pl radlast radtest)])
1089 AC_CONFIG_COMMANDS([scripts-chmod], [(cd ./scripts    && chmod +x rc.radiusd radwatch check-radiusd-config radiusd.cron.daily radiusd.cron.monthly cryptpasswd)])
1090
1091 dnl #
1092 dnl #  Substitute whatever libraries we found to be necessary
1093 dnl #
1094 AC_SUBST(LIBS)
1095 AC_SUBST(INSTALLSTRIP)
1096
1097 USE_SHARED_LIBS=$enable_shared
1098 AC_SUBST(USE_SHARED_LIBS)
1099 USE_STATIC_LIBS=$enable_static
1100 AC_SUBST(USE_STATIC_LIBS)
1101 AC_SUBST(STATIC_MODULES)
1102 AC_SUBST(RADIUSD_MAJOR_VERSION)
1103 AC_SUBST(RADIUSD_MINOR_VERSION)
1104 AC_SUBST(RADIUSD_VERSION)
1105
1106 AC_OUTPUT(\
1107         ./Make.inc \
1108         ./src/include/build-radpaths-h \
1109         ./src/main/Makefile \
1110         ./src/main/checkrad.pl \
1111         ./src/main/radlast \
1112         ./src/main/radtest \
1113         ./scripts/rc.radiusd \
1114         ./scripts/radwatch \
1115         ./scripts/check-radiusd-config \
1116         ./scripts/radiusd.cron.daily \
1117         ./scripts/radiusd.cron.monthly \
1118         ./scripts/cryptpasswd \
1119         ./raddb/dictionary \
1120         ./raddb/radiusd.conf \
1121         ./raddb/radrelay.conf
1122 )