configure.in

   1 dnl #############################################################
   2 dnl #
   3 dnl #  For information about autoconf, see:
   4 dnl #
   5 dnl #  http://www.gnu.org/software/autoconf/
   6 dnl #
   7 dnl #  The recommended order is:
   8 dnl #
   9 dnl #  AC_INIT(file)
  10 dnl #  0. checks for compiler, libtool, and command line options
  11 dnl #  1. checks for programs
  12 dnl #  2. checks for libraries
  13 dnl #  3. checks for header files
  14 dnl #  4. checks for typedefs
  15 dnl #  5. checks for structures and functions
  16 dnl #  6. checks for compiler characteristics
  17 dnl #  7. checks for library functions
  18 dnl #  8. checks for system services
  19 dnl #  AC_OUTPUT([file...])
  20 dnl #
  21 dnl #############################################################
  22
  23 AC_PREREQ([2.59])
  24 export CFLAGS LIBS LDFLAGS CPPFLAGS
  25 AC_INIT(src/main/radiusd.c)
  26 AC_CONFIG_HEADER(src/include/autoconf.h)
  27 AC_REVISION($Revision$)dnl
  28
  29 dnl # The version of the software
  30 RADIUSD_VERSION=`cat VERSION`
  31 RADIUSD_MAJOR_VERSION=`cat VERSION | sed 's/\..*//'`
  32 RADIUSD_MINOR_VERSION=`cat VERSION | sed 's/^2\.//'`
  33 PACKAGE=freeradius
  34
  35 dnl #############################################################
  36 dnl #
  37 dnl #  0. Checks for compiler, libtool, and command line options.
  38 dnl #
  39 dnl #############################################################
  40
  41 dnl Check for GNU cc
  42 AC_PROG_CC
  43 AC_PROG_CXX
  44
  45 dnl #
  46 dnl # check for AIX, to allow us to use some BSD functions
  47 dnl # must be before macros that call the compiler.
  48 dnl #
  49 AC_AIX
  50
  51 AC_PROG_GCC_TRADITIONAL
  52 AC_PROG_CC_SUNPRO
  53 AC_PROG_RANLIB
  54
  55 dnl Compile in large (2G+) file support.
  56 AC_SYS_LARGEFILE
  57
  58 dnl # check for system bytesex
  59 dnl # AC_DEFINES WORDS_BIGENDIAN
  60 AC_C_BIGENDIAN
  61
  62 dnl Find GNU Make.
  63 AC_CHECK_PROG(GMAKE, gmake, yes, no)
  64 if test $GMAKE = no; then
  65   AC_PATH_PROG(MAKE, make, /usr/local/bin/make)
  66 else
  67   AC_PATH_PROG(MAKE, gmake, /usr/local/gnu/bin/make)
  68 fi
  69 makever=`$ac_cv_path_MAKE --version 2>&1 | grep "GNU Make"`
  70 if test -z "$makever"; then
  71   AC_MSG_ERROR(GNU Make is not installed.  Please download and install it
  72                 from ftp://prep.ai.mit.edu/pub/gnu/make/ before continuing.)
  73 fi
  74
  75 dnl libltdl is installable
  76 AC_LIBLTDL_INSTALLABLE
  77
  78 dnl tell Makefile to build ltdl if needed
  79 if test x"$enable_ltdl_install" = x"yes"; then
  80   LTDL_SUBDIRS=libltdl
  81 fi
  82 AC_SUBST(LTDL_SUBDIRS)
  83
  84 dnl use system-wide libtool, if it exists
  85 AC_ARG_WITH(system-libtool,
  86 [  --with-system-libtool              try to use libtool installed in your system [default=use our own]],
  87 [ AC_PATH_PROG(LIBTOOL, libtool,,$PATH:/usr/local/bin) ],
  88 [
  89   LIBTOOL="`pwd`/libtool"
  90   AC_SUBST(LIBTOOL)
  91   dnl ensure that we're looking for dlopen
  92   AC_LIBTOOL_DLOPEN
  93
  94   dnl Figure out how to build shared libraries
  95   AC_PROG_LIBTOOL
  96 ])
  97
  98
  99 dnl Put this in later, when all distributed modules use autoconf.
 100 dnl AC_ARG_WITH(disablemodulefoo,
 101 dnl [  --without-rlm_foo       Disables module compilation.  Module list:]
 102 dnl esyscmd([find src/modules -type d -name rlm_\* -print |\
 103 dnl     sed -e 's%src/modules/.*/% (sub)- %; s%.*/%- %' |\
 104 dnl     awk '{print "                            "$0}']))
 105
 106 AC_ARG_ENABLE(strict-dependencies,
 107 [  --enable-strict-dependencies  Fail configure on lack of module dependancy.])
 108
 109 dnl extra argument: --with-docdir
 110 docdir='${datadir}/doc/freeradius'
 111 AC_MSG_CHECKING(docdir)
 112 AC_ARG_WITH(docdir,
 113 [  --with-docdir=DIR       Directory for documentation [DATADIR/doc/freeradius] ],
 114 [ case "$withval" in
 115     no)
 116         docdir=no
 117         ;;
 118     yes)
 119         ;;
 120     [[\\/$]]* | ?:[[\\/]]* )
 121         docdir="$withval"
 122         ;;
 123     *)
 124         AC_MSG_ERROR([expected an absolute directory name for --with-docdir: $withval])
 125         ;;
 126   esac ]
 127 )
 128 AC_SUBST(docdir)
 129 AC_MSG_RESULT($docdir)
 130 if test "x$docdir" = xno; then
 131         AC_MSG_WARN(Documentation files will NOT be installed.)
 132 fi
 133
 134 dnl extra argument: --with-logdir
 135 logdir='${localstatedir}/log/radius'
 136 AC_MSG_CHECKING(logdir)
 137 AC_ARG_WITH(logdir,
 138 [  --with-logdir=DIR       Directory for logfiles [LOCALSTATEDIR/log/radius] ],
 139 [ case "$withval" in
 140     no)
 141         AC_MSG_ERROR(Need logdir)
 142         ;;
 143     yes)
 144         ;;
 145     [[\\/$]]* | ?:[[\\/]]* )
 146         logdir="$withval"
 147         ;;
 148     *)
 149         AC_MSG_ERROR([expected an absolute directory name for --with-logdir: $withval])
 150         ;;
 151   esac ]
 152 )
 153 AC_SUBST(logdir)
 154 AC_MSG_RESULT($logdir)
 155
 156 dnl extra argument: --with-radacctdir
 157 radacctdir='${logdir}/radacct'
 158 AC_MSG_CHECKING(radacctdir)
 159 AC_ARG_WITH(radacctdir,
 160 [  --with-radacctdir=DIR   Directory for detail files [LOGDIR/radacct] ],
 161 [ case "$withval" in
 162     no)
 163         AC_MSG_ERROR(Need radacctdir)
 164         ;;
 165     yes)
 166         ;;
 167     [[\\/$]]* | ?:[[\\/]]* )
 168         radacctdir="$withval"
 169         ;;
 170     *)
 171         AC_MSG_ERROR([expected an absolute directory name for --with-radacctdir: $withval])
 172         ;;
 173   esac ]
 174 )
 175 AC_SUBST(radacctdir)
 176 AC_MSG_RESULT($radacctdir)
 177
 178 dnl extra argument: --with-raddbdir
 179 raddbdir='${sysconfdir}/raddb'
 180 AC_MSG_CHECKING(raddbdir)
 181 AC_ARG_WITH(raddbdir,
 182 [  --with-raddbdir=DIR     Directory for config files [SYSCONFDIR/raddb] ],
 183 [ case "$withval" in
 184     no)
 185         AC_MSG_ERROR(Need raddbdir)
 186         ;;
 187     yes)
 188         ;;
 189     [[\\/$]]* | ?:[[\\/]]* )
 190         raddbdir="$withval"
 191         ;;
 192     *)
 193         AC_MSG_ERROR([expected an absolute directory name for --with-raddbdir: $withval])
 194         ;;
 195   esac ]
 196 )
 197 AC_SUBST(raddbdir)
 198 AC_MSG_RESULT($raddbdir)
 199
 200 dnl extra argument: --with-ascend-binary
 201 ASCEND_BINARY=yes
 202 AC_ARG_WITH(ascend-binary,
 203 [  --with-ascend-binary    Include support for Ascend binary filter attributes (default=yes)],
 204 [ case "$withval" in
 205     yes)
 206         ;;
 207     *)
 208         ASCEND_BINARY=""
 209   esac ]
 210 )
 211 if test "X$ASCEND_BINARY" = "Xyes"; then
 212   AC_DEFINE(ASCEND_BINARY, [], [Include support for Ascend binary filter attributes])
 213 fi
 214
 215 dnl extra argument: --with-threads
 216 WITH_THREADS=yes
 217 AC_ARG_WITH(threads,
 218 [  --with-threads          Use threads, if available.  (default=yes) ],
 219 [ case "$withval" in
 220     yes)
 221         ;;
 222     *)
 223         WITH_THREADS=""
 224   esac ]
 225 )
 226
 227 dnl extra argument: --with-vmps
 228 WITH_VMPS=yes
 229 AC_ARG_WITH(vmps,
 230 [  --with-vmps             Compile in VMPS support. (default=yes)],
 231 [ case "$withval" in
 232     yes)
 233         ;;
 234     *)
 235         WITH_VMPS=no
 236   esac ]
 237 )
 238 if test "x$WITH_VMPS" = "xyes"; then
 239         AC_DEFINE(WITH_VMPS, [1], [define if you want VMPS support])
 240 fi
 241
 242 dnl extra argument: --with-dhcp
 243 AC_ARG_WITH(dhcp,
 244 [  --with-dhcp             Compile in DHCP support. (default=no)],
 245 [ case "$withval" in
 246     yes)
 247         AC_DEFINE(WITH_DHCP, [1], [Include experimental support for DHCP])
 248         ;;
 249     *)
 250         ;;
 251   esac ]
 252 )
 253
 254
 255 dnl #
 256 dnl #  Allow the user to specify a list of modules to be linked
 257 dnl #  statically to the server.
 258 dnl #
 259 STATIC_MODULES=
 260 AC_ARG_WITH(static_modules,
 261 [  --with-static-modules=QUOTED-MODULE-LIST],[
 262   for i in $withval; do
 263     STATIC_MODULES="$STATIC_MODULES -dlpreopen ../modules/rlm_$i/rlm_$i.la"
 264   done
 265 ])
 266
 267 MODULES=
 268 AC_ARG_WITH(modules,
 269 [ --with-modules=QUOTED-MODULE-LIST],[
 270  for i in $withval; do
 271    MODULES="$MODULES $i"
 272  done
 273 ])
 274
 275 dnl #
 276 dnl #  Enable developer C compiler warnings
 277 dnl #
 278 AC_ARG_ENABLE(developer,
 279 [  --enable-developer               Enables features of interest to developers.],
 280 [ case "$enableval" in
 281     no)
 282         developer=no
 283         ;;
 284     *)
 285         developer=yes
 286   esac ]
 287 )
 288
 289 if test "x$developer" != "xno" -a -d $srcdir/CVS; then
 290   dnl turn on the developer flag when taken from a CVS checkout (not a release)
 291   developer="yes"
 292 fi
 293
 294 if test "x$developer" != "xno" -a -d $srcdir/.git; then
 295   dnl turn on the developer flag when taken from a git checkout (not a release)
 296   developer="yes"
 297 fi
 298
 299 dnl extra argument: --with-experimental-modules
 300 EXPERIMENTAL=
 301 AC_ARG_WITH(experimental-modules,
 302 [  --with-experimental-modules      Use experimental and unstable modules. (default=no) ],
 303 [ case "$withval" in
 304     yes)
 305         EXPERIMENTAL=yes
 306         ;;
 307     *)
 308   esac ]
 309 )
 310
 311 dnl extra argument: --with-openssl
 312 WITH_OPENSSL=yes
 313 AC_ARG_WITH(openssl,
 314 [  --with-openssl                   Use OpenSSL. (default=yes)],
 315 [ case "$withval" in
 316     no)
 317         WITH_OPENSSL=no
 318         ;;
 319     *)
 320         WITH_OPENSSL=yes
 321         ;;
 322   esac ]
 323 )
 324
 325 dnl #
 326 dnl # extra argument: --with-openssl-includes=dir
 327 dnl #
 328 OPENSSL_INCLUDE_DIR=
 329 AC_ARG_WITH(openssl-includes,
 330 [  --with-openssl-includes=DIR      Directory to look for OpenSSL include files],
 331 [ case "$withval" in
 332     *) OPENSSL_INCLUDE_DIR="$withval"
 333         ;;
 334   esac ]
 335 )
 336
 337 dnl #
 338 dnl # extra argument: --with-openssl-libraries=dir
 339 dnl #
 340 OPENSSL_LIB_DIR=
 341 AC_ARG_WITH(openssl-libraries,
 342 [  --with-openssl-libraries=DIR     Directory to look for OpenSSL library files],
 343 [ case "$withval" in
 344     *) OPENSSL_LIB_DIR="$withval"
 345         ;;
 346   esac ]
 347 )
 348
 349 dnl #
 350 dnl #  These next two arguments don't actually do anything.  They're
 351 dnl #  place holders so that the top-level configure script can tell
 352 dnl #  the user how to configure lower-level modules
 353 dnl #
 354
 355 dnl #
 356 dnl # extra argument: --with-rlm-FOO-lib-dir
 357 dnl #
 358 AC_ARG_WITH(rlm-FOO-lib-dir,
 359 [  --with-rlm-FOO-lib-dir=DIR       Directory to look for library files used by module FOO],
 360 [ case "$withval" in
 361     *)
 362         ;;
 363   esac ]
 364 )
 365
 366 dnl #
 367 dnl # extra argument: --with-rlm-FOO-include-dir
 368 dnl #
 369 AC_ARG_WITH(rlm-FOO-include-dir,
 370 [  --with-rlm-FOO-include-dir=DIR   Directory to look for include files used by module FOO],
 371 [ case "$withval" in
 372     *)
 373         ;;
 374   esac ]
 375 )
 376
 377 dnl See what include-style is used by the make program.
 378 dnl AC_MSG_CHECKING(include style for make)
 379 dnl echo "include /dev/null" > testmake.$$
 380 dnl echo "all:" >> testmake.$$
 381 dnl make -f testmake.$$ >/dev/null 2>&1
 382 dnl if test $? = 0
 383 dnl then
 384 dnl     INCLUDE=include
 385 dnl     IQUOTE=
 386 dnl else
 387 dnl     INCLUDE=.include
 388 dnl     IQUOTE='"'
 389 dnl fi
 390 dnl rm -f testmake.$$
 391 dnl AC_MSG_RESULT(" $INCLUDE")
 392 dnl AC_SUBST(INCLUDE)
 393 dnl AC_SUBST(IQUOTE)
 394
 395 dnl extra argument: --with-udpfromto
 396 WITH_UDPFROMTO=no
 397 AC_ARG_WITH(udpfromto,
 398 [  --with-udpfromto        Compile in UDPFROMTO support. (default=no)],
 399 [ case "$withval" in
 400     yes)
 401         WITH_UDPFROMTO=yes
 402         ;;
 403     *)
 404         WITH_UDPFROMTO=no
 405   esac ]
 406 )
 407
 408 if test "x$WITH_UDPFROMTO" = "xyes"; then
 409         AC_DEFINE(WITH_UDPFROMTO, [], [define if you want udpfromto])
 410 fi
 411
 412 dnl #############################################################
 413 dnl #
 414 dnl #  1. Checks for programs
 415 dnl #
 416 dnl #############################################################
 417
 418 CHECKRAD=checkrad.pl
 419 AC_PATH_PROG(PERL, perl, /usr/local/bin/perl)
 420 if test "x$ac_cv_path_PERL" = "x"; then
 421   AC_MSG_WARN(perl not found - Simultaneous-Use and checkrad.pl may not work)
 422 fi
 423 AC_PATH_PROG(SNMPGET, snmpget)
 424 if test "x$ac_cv_path_SNMPGET" = "x"; then
 425   AC_MSG_WARN(snmpget not found - Simultaneous-Use and checkrad.pl may not work)
 426 fi
 427
 428 AC_PATH_PROG(SNMPWALK, snmpwalk)
 429 if test "x$ac_cv_path_SNMPWALK" = "x"; then
 430   AC_MSG_WARN(snmpwalk not found - Simultaneous-Use and checkrad.pl may not work)
 431 fi
 432
 433 AC_PATH_PROG(RUSERS, rusers, /usr/bin/rusers)
 434
 435 dnl FIXME This is truly gross.
 436 missing_dir=`cd $ac_aux_dir && pwd`
 437 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
 438 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
 439 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
 440
 441 AC_PATH_PROG(LOCATE,locate)
 442 AC_PATH_PROG(DIRNAME,dirname)
 443 AC_PATH_PROG(GREP,grep)
 444
 445 dnl #############################################################
 446 dnl #
 447 dnl #  2. Checks for libraries
 448 dnl #
 449 dnl #############################################################
 450
 451 dnl If using pthreads, check for -lpthread (posix) or -lc_r (*BSD)
 452 old_CFLAGS=$CFLAGS
 453 if test "x$WITH_THREADS" = "xyes"; then
 454   if test $ac_cv_prog_suncc = "yes"; then
 455     CFLAGS="$CFLAGS -mt"
 456   fi
 457
 458   AC_CHECK_HEADERS(pthread.h, [], [ WITH_THREADS="no" ])
 459
 460 dnl #
 461 dnl # pthread stuff is usually in -lpthread
 462 dnl # or in -lc_r, on *BSD
 463 dnl #
 464 dnl # On Some systems, we need extra pre-processor flags, to get them to
 465 dnl # to do the threading properly.
 466 dnl #
 467   AC_CHECK_LIB(pthread, pthread_create,
 468                 [ CFLAGS="$CFLAGS -D_REENTRANT -D_POSIX_PTHREAD_SEMANTICS"
 469                   LIBS="$LIBS -lpthread" ],
 470                 AC_CHECK_LIB(c_r, pthread_create,
 471                             [ CFLAGS="$CFLAGS -pthread -D_THREAD_SAFE" ],
 472                             [ WITH_THREADS="no" ]
 473                             )
 474                 )
 475 fi
 476
 477 dnl #
 478 dnl # If we have NO pthread libraries, remove any knowledge of threads.
 479 dnl #
 480 if test "x$WITH_THREADS" != "xyes"; then
 481   CFLAGS=$old_CFLAGS
 482   ac_cv_header_pthread_h="no"
 483   WITH_THREADS=no
 484 else
 485   dnl #
 486   dnl #  We need sem_init() and friends, as they're the friendliest
 487   dnl #  semaphore functions for threading.
 488   dnl #
 489   dnl # HP/UX requires linking with librt, too, to get the sem_* symbols.
 490   dnl # Some systems have them in -lsem
 491   dnl # Solaris has them in -lposix4
 492   dnl # NetBSD has them in -lsemaphore
 493
 494   AC_SEARCH_LIBS(sem_init, pthread sem posix4 rt semaphore,
 495         [],
 496         [AC_MSG_ERROR(-lsem not found.  You may want to download it from ftp://ftp.to.gd-es.com/pub/BSDI/libsem.tar.bz2 or ftp://ftp.freeradius.org/pub/radius/contrib/libsem.tar.gz)]
 497    )
 498 fi
 499
 500 dnl Check if we need -lsocket
 501 AC_CHECK_LIB(socket, getsockname)
 502
 503 dnl Check for -lresolv
 504 dnl This library may be needed later.
 505 AC_CHECK_LIB(resolv, inet_aton)
 506
 507 dnl Check if we need -lnsl. Usually if we want to
 508 dnl link against -lsocket we need to include -lnsl as well.
 509 AC_CHECK_LIB(nsl, inet_ntoa)
 510
 511 dnl Check for OpenSSL libraries.
 512 OPENSSL_LIBS=
 513 if test "x$WITH_OPENSSL" = xyes; then
 514   old_LIBS=$LIBS
 515   if test "x$OPENSSL_LIB_DIR" != "x"; then
 516     LIBS="-L$OPENSSL_LIB_DIR $LIBS"
 517   fi
 518   AC_CHECK_LIB(crypto, DH_new,
 519     [
 520         LIBS="-lcrypto $LIBS"
 521         AC_DEFINE(HAVE_LIBCRYPTO, 1,
 522             [Define to 1 if you have the `crypto' library (-lcrypto).])
 523         AC_CHECK_LIB(ssl, SSL_new,
 524             [
 525                 AC_DEFINE(HAVE_LIBSSL, 1,
 526                     [Define to 1 if you have the `ssl' library (-lssl).])
 527                 if test "x$OPENSSL_LIB_DIR" != "x"; then
 528                     OPENSSL_LIBS="-L$OPENSSL_LIB_DIR"
 529                 fi
 530                 OPENSSL_LIBS="$OPENSSL_LIBS -lcrypto -lssl -lcrypto"
 531             ], [])
 532     ], [])
 533   LIBS=$old_LIBS
 534 fi
 535
 536 AC_CHECK_LIB(ws2_32, htonl)
 537
 538 dnl Check the pcap library for the RADIUS sniffer.
 539 PCAP_LIBS=
 540 AC_CHECK_LIB(pcap, pcap_open_live,
 541         [ PCAP_LIBS="-lpcap"
 542         AC_DEFINE(HAVE_LIBPCAP, 1,
 543                 [Define to 1 if you have the `pcap' library (-lpcap).])
 544         ],
 545         [ AC_MSG_WARN([pcap library not found, silently disabling the RADIUS sniffer.]) ])
 546
 547 AC_LIB_READLINE
 548
 549 dnl #############################################################
 550 dnl #
 551 dnl #  3. Checks for header files
 552 dnl #
 553 dnl #############################################################
 554
 555 dnl #
 556 dnl # Interix requires us to set -D_ALL_SOURCE, otherwise
 557 dnl # getopt will be #included, but won't link.  <sigh>
 558 dnl #
 559 dnl #
 560 case "$host" in
 561 *-interix*)
 562         CFLAGS="$CFLAGS -D_ALL_SOURCE"
 563         ;;
 564 *-darwin*)
 565         CFLAGS="$CFLAGS -DDARWIN"
 566         LIBS="-framework DirectoryService $LIBS"
 567         ;;
 568 esac
 569
 570 AC_HEADER_DIRENT
 571 AC_HEADER_STDC
 572 AC_HEADER_TIME
 573 AC_HEADER_SYS_WAIT
 574
 575 AC_CHECK_HEADERS( \
 576         unistd.h \
 577         crypt.h \
 578         errno.h \
 579         resource.h \
 580         sys/resource.h \
 581         getopt.h \
 582         malloc.h \
 583         utmp.h \
 584         utmpx.h \
 585         signal.h \
 586         sys/select.h \
 587         syslog.h \
 588         inttypes.h \
 589         stdint.h \
 590         stdio.h \
 591         netdb.h \
 592         semaphore.h \
 593         arpa/inet.h \
 594         netinet/in.h \
 595         sys/types.h \
 596         sys/socket.h \
 597         winsock.h \
 598         sys/time.h \
 599         sys/wait.h \
 600         sys/security.h \
 601         fcntl.h \
 602         sys/fcntl.h \
 603         sys/prctl.h \
 604         sys/un.h \
 605         glob.h \
 606         prot.h \
 607         pwd.h \
 608         grp.h \
 609         sia.h \
 610         siad.h
 611 )
 612
 613 dnl FreeBSD requires sys/socket.h before net/if.h
 614 AC_CHECK_HEADERS(net/if.h, [], [],
 615 [#ifdef HAVE_SYS_SOCKET_H
 616 # include <sys/socket.h>
 617 # endif
 618 ])
 619
 620 REGEX=no
 621 AC_CHECK_HEADER(regex.h, AC_DEFINE(HAVE_REGEX_H, [], [define this if we have the <regex.h> header file]))
 622 if test "x$ac_cv_header_regex_h" = "xyes"; then
 623   REGEX_EXTENDED=no
 624   REGEX=yes
 625   AC_EGREP_CPP(yes,
 626     [#include <regex.h>
 627      #ifdef REG_EXTENDED
 628        yes
 629      #endif
 630      ], [AC_DEFINE(HAVE_REG_EXTENDED, [], [define this if we have REG_EXTENDED (from <regex.h>)]) REGEX_EXTENDED=yes])
 631 fi
 632 AC_SUBST(REGEX)
 633 AC_SUBST(REGEX_EXTENDED)
 634
 635 dnl #
 636 dnl #  other checks which require headers
 637 dnl #
 638 if test "x$ac_cv_header_sys_security_h" = "xyes" && test "x$ac_cv_header_prot_h" = "xyes"
 639 then
 640   AC_DEFINE(OSFC2, [], [define if you have OSFC2 authentication])
 641 fi
 642
 643 if test "x$ac_cv_header_sia_h" = "xyes" && test "x$ac_cv_header_siad_h" = "xyes"
 644 then
 645   AC_DEFINE(OSFSIA, [], [define if you have OSFSIA authentication])
 646 fi
 647
 648 dnl Check for OpenSSL includes.
 649 OPENSSL_INCLUDE="-DNO_OPENSSL"
 650 if test "x$WITH_OPENSSL" = xyes; then
 651   if test "x$OPENSSL_LIBS" = "x"; then
 652     AC_MSG_NOTICE([skipping test for openssl/ssl.h])
 653   else
 654     old_CPPFLAGS=$CPPFLAGS
 655     if test "x$OPENSSL_INCLUDE_DIR" != "x"; then
 656         CPPFLAGS="$CPPFLAGS -I$OPENSSL_INCLUDE_DIR"
 657     fi
 658     dnl # stupid RedHat shit
 659     CPPFLAGS="$CPPFLAGS -DOPENSSL_NO_KRB5"
 660     AC_CHECK_HEADERS( \
 661         openssl/ssl.h \
 662         openssl/crypto.h \
 663         openssl/err.h \
 664         openssl/evp.h \
 665         openssl/engine.h,
 666         [],
 667         OPENSSL_LIBS=
 668     )
 669     if test "x$OPENSSL_LIBS" != "x"; then
 670         AC_MSG_CHECKING([for OpenSSL version >= 0.9.7])
 671         AC_EGREP_CPP(yes,
 672             [#include <openssl/crypto.h>
 673              #if (OPENSSL_VERSION_NUMBER >= 0x00907000L)
 674              yes
 675              #endif
 676             ], goodssl="yes")
 677         if test "x$goodssl" != "xyes"; then
 678             AC_MSG_RESULT(no)
 679             OPENSSL_LIBS=
 680         else
 681             AC_MSG_RESULT(yes)
 682             if test "x$OPENSSL_INCLUDE_DIR" != "x"; then
 683                 OPENSSL_INCLUDE="-I$OPENSSL_INCLUDE_DIR -DOPENSSL_NO_KRB5"
 684             else
 685                 OPENSSL_INCLUDE="-DOPENSSL_NO_KRB5"
 686             fi
 687         fi
 688     fi
 689     CPPFLAGS=$old_CPPFLAGS
 690   fi
 691 fi
 692 AC_SUBST(OPENSSL_INCLUDE)
 693 AC_SUBST(OPENSSL_LIBS)
 694 export OPENSSL_LIBS
 695
 696 dnl Check the pcap includes for the RADIUS sniffer.
 697 if test "x$PCAP_LIBS" = x; then
 698     AC_MSG_NOTICE([skipping test for pcap.h.])
 699 else
 700     AC_CHECK_HEADER(pcap.h,
 701         AC_DEFINE(HAVE_PCAP_H, 1,
 702                 [Define to 1 if you have the <pcap.h> header file.]),
 703         [ PCAP_LIBS=
 704         AC_MSG_WARN([pcap.h not found, silently disabling the RADIUS sniffer.])
 705         ])
 706 fi
 707 AC_SUBST(PCAP_LIBS)
 708
 709 dnl #############################################################
 710 dnl #
 711 dnl #  4. Checks for typedefs
 712 dnl #
 713 dnl #############################################################
 714
 715 dnl #
 716 dnl # Ensure that these are defined
 717 dnl #
 718 AC_TYPE_OFF_T
 719 AC_TYPE_PID_T
 720 AC_TYPE_SIZE_T
 721 AC_TYPE_UID_T
 722
 723 dnl check for socklen_t
 724 FR_CHECK_TYPE_INCLUDE([
 725 #ifdef HAVE_SYS_TYPES_H
 726 #include <sys/types.h>
 727 #endif
 728 #ifdef HAVE_SYS_SOCKET_H
 729 #include <sys/socket.h>
 730 #endif
 731 ],socklen_t, int, [socklen_t is generally 'int' on systems which don't use it])
 732
 733 dnl check for uint8_t
 734 FR_CHECK_TYPE_INCLUDE([
 735 #ifdef HAVE_INTTYPES_H
 736 #include <inttypes.h>
 737 #endif
 738 #ifdef HAVE_STDINT_H
 739 #include <stdint.h>
 740 #endif
 741 ],uint8_t, unsigned char, [uint8_t should be the canonical 'octet' for network traffic])
 742
 743 dnl check for uint16_t
 744 FR_CHECK_TYPE_INCLUDE([
 745 #ifdef HAVE_INTTYPES_H
 746 #include <inttypes.h>
 747 #endif
 748 #ifdef HAVE_STDINT_H
 749 #include <stdint.h>
 750 #endif
 751 ],uint16_t, unsigned short, [uint16_t should be the canonical '2 octets' for network traffic])
 752
 753 dnl check for uint32_t
 754 FR_CHECK_TYPE_INCLUDE([
 755 #ifdef HAVE_INTTYPES_H
 756 #include <inttypes.h>
 757 #endif
 758 #ifdef HAVE_STDINT_H
 759 #include <stdint.h>
 760 #endif
 761 ],uint32_t, unsigned int, [uint32_t should be the canonical 'network integer])
 762
 763 AC_CHECK_TYPE(struct in6_addr, AC_DEFINE(HAVE_STRUCT_IN6_ADDR, 1, [IPv6 address structure]), [], [
 764 #ifdef HAVE_NETINET_IN_H
 765 #include <netinet/in.h>
 766 #endif
 767 ])
 768
 769 AC_CHECK_TYPE(struct sockaddr_storage, AC_DEFINE(HAVE_STRUCT_SOCKADDR_STORAGE, 1, [Generic socket addresses]), [], [
 770 #ifdef HAVE_NETINET_IN_H
 771 #include <netinet/in.h>
 772 #endif
 773 #ifdef HAVE_SYS_SOCKET_H
 774 #include <sys/socket.h>
 775 #endif
 776 ])
 777
 778 AC_CHECK_TYPE(struct sockaddr_in6, AC_DEFINE(HAVE_STRUCT_SOCKADDR_IN6, 1, [IPv6 socket addresses]), [], [
 779 #ifdef HAVE_NETINET_IN_H
 780 #include <netinet/in.h>
 781 #endif
 782 ])
 783
 784 AC_CHECK_TYPE(struct addrinfo, AC_DEFINE(HAVE_STRUCT_ADDRINFO, 1, [Generic DNS lookups]), [], [
 785 #ifdef HAVE_SYS_TYPES_H
 786 #include <sys/types.h>
 787 #endif
 788 #ifdef HAVE_SYS_SOCKET_H
 789 #include <sys/socket.h>
 790 #endif
 791 #ifdef HAVE_NETDB_H
 792 #include <netdb.h>
 793 #endif
 794 ])
 795
 796 dnl #############################################################
 797 dnl #
 798 dnl #  5. Checks for structures and functions
 799 dnl #
 800 dnl #############################################################
 801 AC_CHECK_FUNCS( \
 802         getopt_long \
 803         lockf \
 804         strsignal \
 805         sigaction \
 806         sigprocmask \
 807         pthread_sigmask \
 808         snprintf \
 809         vsnprintf \
 810         setsid \
 811         strncasecmp \
 812         strcasecmp \
 813         localtime_r \
 814         ctime_r \
 815         gmtime_r \
 816         strsep \
 817         inet_aton \
 818         inet_pton \
 819         inet_ntop \
 820         setlinebuf \
 821         setvbuf \
 822         getusershell \
 823         initgroups \
 824         getaddrinfo \
 825         getnameinfo \
 826         closefrom \
 827         gettimeofday \
 828         getpeereid \
 829         setuid \
 830         setresuid \
 831         getresuid \
 832         strlcat \
 833         strlcpy
 834 )
 835 RADIUSD_NEED_DECLARATIONS( \
 836         crypt \
 837         strncasecmp \
 838         strcasecmp \
 839         inet_aton \
 840         setlinebuf \
 841         getusershell \
 842         endusershell
 843 )
 844
 845 AC_TYPE_SIGNAL
 846
 847 dnl # check if we have utmpx.h
 848 dnl # if so, check if struct utmpx has entry ut_xtime
 849 dnl # if not, set it to define ut_xtime == ut_tv.tv_sec
 850 if test "x$ac_cv_header_utmpx_h" = "xyes"
 851 then
 852  FR_CHECK_STRUCT_HAS_MEMBER([#include <utmpx.h>], [struct utmpx], ut_xtime)
 853  if test "x$ac_cv_type_struct_utmpx_has_ut_xtime" = "x"
 854  then
 855    AC_DEFINE(ut_xtime,ut_tv.tv_sec, [define to something if you don't have ut_xtime in struct utmpx])
 856  fi
 857 fi
 858
 859 dnl # struct ip_pktinfo
 860 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in_pktinfo], ipi_addr)
 861 if test "x$ac_cv_type_struct_in_pktinfo_has_ipi_addr" = "xyes"
 862 then
 863         AC_DEFINE(HAVE_IP_PKTINFO, [], [define if you have IP_PKTINFO (Linux)])
 864 fi
 865
 866 dnl # struct in6_pktinfo
 867 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in6_pktinfo], ipi6_addr)
 868 if test "x$ac_cv_type_struct_in6_pktinfo_has_ipi6_addr" = "xyes"
 869 then
 870         AC_DEFINE(HAVE_IN6_PKTINFO, [], [define if you have IN6_PKTINFO (Linux)])
 871 fi
 872
 873 dnl #############################################################
 874 dnl #
 875 dnl #  6. Checks for compiler characteristics
 876 dnl #
 877 dnl #############################################################
 878
 879 dnl #
 880 dnl # Ensure that these are defined
 881 dnl #
 882 AC_C_CONST
 883
 884 dnl #
 885 dnl # See if this is OS/2
 886 dnl #
 887 AC_MSG_CHECKING(type of OS)
 888 OS=`uname -s`
 889 AC_MSG_RESULT($OS)
 890 if test "$OS" = "OS/2"; then
 891         LIBPREFIX=
 892 else
 893         LIBPREFIX=lib
 894 fi
 895 AC_SUBST(LIBPREFIX)
 896
 897 dnl #
 898 dnl # Set Default CFLAGS
 899 dnl #
 900 if test "x$GCC" = "xyes"; then
 901     CFLAGS="$CFLAGS -Wall -D_GNU_SOURCE"
 902 fi
 903
 904 AC_MSG_CHECKING(for developer gcc flags)
 905 if test "x$developer" = "xyes" -a "x$GCC" = "xyes"; then
 906   devflags="-g -Wshadow -Wpointer-arith -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -W -Wredundant-decls -Wundef"
 907   CFLAGS="$CFLAGS $devflags"
 908   INSTALLSTRIP=""
 909   AC_MSG_RESULT(yes.  Using $devflags)
 910 else
 911   devflags=""
 912   CFLAGS="$CFLAGS -DNDEBUG"
 913   INSTALLSTRIP=""
 914   AC_MSG_RESULT(no.)
 915 fi
 916
 917 FR_TLS
 918
 919 dnl #############################################################
 920 dnl #
 921 dnl #  7. Checks for library functions
 922 dnl #
 923 dnl #############################################################
 924
 925 dnl Check for libcrypt
 926 dnl We use crypt(3) which may be in libc, or in libcrypt (eg FreeBSD)
 927 AC_CHECK_LIB(crypt, crypt,
 928   CRYPTLIB="-lcrypt"
 929 )
 930 if test "$CRYPTLIB" != ""; then
 931   AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function])
 932 else
 933   AC_CHECK_FUNC(crypt, AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function]))
 934 fi
 935
 936 dnl Check for libcipher
 937 AC_CHECK_LIB(cipher, setkey,
 938    CRYPTLIB="${CRYPTLIB} -lcipher"
 939 )
 940 AC_SUBST(CRYPTLIB)
 941
 942 dnl Check the style of gethostbyaddr, in order of preference
 943 dnl GNU (_r eight args)
 944 AC_DEFINE(GNUSTYLE, [1], [GNU-Style get*byaddr_r])
 945 dnl SYSV (_r six args)
 946 AC_DEFINE(SYSVSTYLE, [2], [SYSV-Style get*byaddr_r])
 947 dnl BSD (three args, may not be thread safe)
 948 AC_DEFINE(BSDSTYLE, [3], [BSD-Style get*byaddr_r])
 949 dnl Tru64 has BSD version, but it is thread safe
 950 dnl     http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1739____.HTM
 951 dnl We need #stdio.h to define NULL on FreeBSD (at least)
 952 gethostbyaddrrstyle=""
 953 AC_MSG_CHECKING([gethostbyaddr_r() syntax])
 954 case "$host" in
 955 *-freebsd*)
 956 dnl With FreeBSD, check if there's a prototype for gethostbyaddr_r.
 957 dnl Some versions (FreeBSD 5.1?) have a symbol but no prototype - so we
 958 dnl override this test to BSDSTYLE. FreeBSD 6.2 and up have proper GNU
 959 dnl style support.
 960         AC_CHECK_DECLS([gethostbyaddr_r], [], [
 961                 AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE,
 962                         [style of gethostbyaddr_r functions ])
 963                 gethostbyaddrrstyle=BSD
 964                 AC_MSG_WARN([FreeBSD overridden to BSD-style])
 965         ], [
 966 #ifdef HAVE_NETDB_H
 967 #include <netdb.h>
 968 #endif
 969 ])
 970         ;;
 971 esac
 972 if test "x$gethostbyaddrrstyle" = "x"; then
 973         AC_TRY_LINK([
 974 #include <stdio.h>
 975 #include <netdb.h>
 976 ], [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL, NULL) ], [
 977         AC_DEFINE(GETHOSTBYADDRRSTYLE, GNUSTYLE, [style of gethostbyaddr_r functions ])
 978         gethostbyaddrrstyle=GNU
 979 ])
 980 fi
 981 if test "x$gethostbyaddrrstyle" = "x"; then
 982         AC_TRY_LINK([
 983 #include <stdio.h>
 984 #include <netdb.h>
 985 ], [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL) ] , [
 986                 AC_DEFINE(GETHOSTBYADDRRSTYLE, SYSVSTYLE, [style of gethostbyaddr_r functions ])
 987                 gethostbyaddrrstyle=SYSV
 988         ])
 989 fi
 990 if test "x$gethostbyaddrrstyle" = "x"; then
 991         AC_TRY_LINK([
 992 #include <stdio.h>
 993 #include <netdb.h>
 994 ], [ gethostbyaddr(NULL, 0, 0)  ], [
 995                 AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE, [style of gethostbyaddr_r functions ])
 996                 gethostbyaddrrstyle=BSD
 997         ])
 998 fi
 999
1000 if test "x$gethostbyaddrrstyle" = "x"; then
1001         AC_MSG_RESULT([none!  It must not exist, here.])
1002 else
1003         AC_MSG_RESULT([${gethostbyaddrrstyle}-style])
1004 fi
1005
1006 if test "x$gethostbyaddrrstyle" = "xBSD"; then
1007         AC_MSG_WARN([ ****** BSD-style gethostbyaddr might NOT be thread-safe! ****** ])
1008 fi
1009
1010 dnl Check the style of gethostbyname, in order of preference
1011 dnl GNU (_r seven args)
1012 dnl SYSV (_r five args)
1013 dnl BSD (two args, may not be thread safe)
1014 dnl Tru64 has BSD version, but it _is_ thread safe
1015 dnl     http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1946____.HTM
1016 dnl We need #stdio.h to define NULL on FreeBSD (at least)
1017 gethostbynamerstyle=""
1018 AC_MSG_CHECKING([gethostbyname_r() syntax])
1019 AC_TRY_LINK([
1020 #include <stdio.h>
1021 #include <netdb.h>
1022 ], [ gethostbyname_r(NULL, NULL, NULL, 0, NULL, NULL) ], [
1023         AC_DEFINE(GETHOSTBYNAMERSTYLE, GNUSTYLE, [style of gethostbyname_r functions ])
1024         gethostbynamerstyle=GNU
1025 ])
1026 if test "x$gethostbynamerstyle" = "x"; then
1027         AC_TRY_LINK([
1028 #include <stdio.h>
1029 #include <netdb.h>
1030 ], [ gethostbyname_r(NULL, NULL, NULL, 0, NULL) ] , [
1031                 AC_DEFINE(GETHOSTBYNAMERSTYLE, SYSVSTYLE, [style of gethostbyname_r functions ])
1032                 gethostbynamerstyle=SYSV
1033         ])
1034 fi
1035 if test "x$gethostbynamerstyle" = "x"; then
1036         AC_TRY_LINK([
1037 #include <stdio.h>
1038 #include <netdb.h>
1039 ], [ gethostbyname(NULL)  ], [
1040                 AC_DEFINE(GETHOSTBYNAMERSTYLE, BSDSTYLE, [style of gethostbyname_r functions ])
1041                 gethostbynamerstyle=BSD
1042         ])
1043 fi
1044
1045 if test "x$gethostbynamerstyle" = "x"; then
1046         AC_MSG_RESULT([none!  It must not exist, here.])
1047 else
1048         AC_MSG_RESULT([${gethostbynamerstyle}-style])
1049 fi
1050
1051 if test "x$gethostbynamerstyle" = "xBSD"; then
1052         AC_MSG_WARN([ ****** BSD-style gethostbyname might NOT be thread-safe! ****** ])
1053 fi
1054
1055 dnl check for non-posix solaris ctime_r (extra buflen int arg)
1056 AC_DEFINE(POSIXSTYLE, [1], [Posix-Style ctime_r])
1057 AC_DEFINE(SOLARISSTYLE, [2], [Solaris-Style ctime_r])
1058 ctimerstyle=""
1059 AC_MSG_CHECKING([ctime_r() syntax])
1060 AC_TRY_LINK([
1061 #include <time.h>
1062 ], [ ctime_r(NULL, NULL, 0) ], [
1063         AC_DEFINE(CTIMERSTYLE, SOLARISSTYLE, [style of ctime_r function])
1064         ctimerstyle="SOLARIS"
1065 ])
1066 if test "x$ctimerstyle" = "x"; then
1067         AC_TRY_LINK([
1068 #include <time.h>
1069 ], [ ctime_r(NULL, NULL) ], [
1070                 AC_DEFINE(CTIMERSTYLE, POSIXSTYLE, [style of ctime_r function])
1071                 ctimerstyle="POSIX"
1072         ])
1073 fi
1074
1075 if test "x$ctimerstyle" = "x"; then
1076         AC_MSG_RESULT([none!  It must not exist, here.])
1077 else
1078         AC_MSG_RESULT([${ctimerstyle}-style])
1079 fi
1080
1081 AC_SUBST(HOSTINFO, $host)
1082
1083 dnl #############################################################
1084 dnl #
1085 dnl #  8. Checks for system services
1086 dnl #
1087 dnl #############################################################
1088
1089 dnl #
1090 dnl # Figure out where libtool is located,
1091 dnl #
1092 top_builddir=`pwd`
1093 export top_builddir
1094 AC_MSG_RESULT([top_builddir=$top_builddir])
1095 dnl # AC_SUBST(top_builddir)
1096 AC_SUBST(LIBLTDL)
1097 AC_SUBST(INCLTDL)
1098
1099 dnl import libtool stuff
1100
1101 dnl #############################################################
1102 dnl #
1103 dnl #  Configure in any module directories.
1104 dnl #
1105 dnl #############################################################
1106
1107 mysubdirs="$LIBLTDLPATH"
1108 if test "x$EXPERIMENTAL" = "xyes"; then
1109   bar=`ls -1 "${srcdir}"/src/modules/rlm_*/configure | sed 's%/configure%%'`
1110   dnl # get rid of LF's.
1111   mysubdirs=`echo $mysubdirs $bar`
1112 else
1113   dnl #
1114   dnl # Find 'configure' in ONLY the stable modules
1115   dnl #
1116   for bar in `cat "${srcdir}"/src/modules/stable`; do
1117     if test -f "${srcdir}"/src/modules/$bar/configure; then
1118       mysubdirs="$mysubdirs src/modules/$bar"
1119     fi
1120   done
1121 fi
1122
1123 dnl ############################################################
1124 dnl # make modules by list
1125 dnl #############################################################
1126 if test "x$EXPERIMENTAL" = "xyes"; then
1127   for foo in `ls -1 "${srcdir}"/src/modules | grep rlm_`; do
1128     MODULES="$MODULES $foo"
1129   done
1130 else
1131    dnl #
1132    dnl # make ONLY the stable modules
1133    dnl #
1134    for foo in `cat "${srcdir}"/src/modules/stable`; do
1135     MODULES="$MODULES $foo"
1136    done
1137 fi
1138
1139 dnl #
1140 dnl #  Don't change the variable name here.  Autoconf goes bonkers
1141 dnl #  if you do.
1142 dnl #
1143 AC_CONFIG_SUBDIRS($LTDL_SUBDIRS $mysubdirs)
1144 AC_SUBST(MODULES)
1145
1146 dnl #############################################################
1147 dnl #
1148 dnl #  And finally, output the results.
1149 dnl #
1150 dnl #############################################################
1151
1152 AC_CONFIG_COMMANDS([stamp-h], [echo timestamp > src/include/stamp-h])
1153 AC_CONFIG_COMMANDS([build-radpaths-h], [(cd ./src/include && /bin/sh ./build-radpaths-h)])
1154 AC_CONFIG_COMMANDS([main-chmod], [(cd ./src/main   && chmod +x checkrad.pl radlast radtest)])
1155 AC_CONFIG_COMMANDS([scripts-chmod], [(cd ./scripts    && chmod +x rc.radiusd radwatch radiusd.cron.daily radiusd.cron.monthly cryptpasswd)])
1156
1157 dnl #
1158 dnl #  Substitute whatever libraries we found to be necessary
1159 dnl #
1160 AC_SUBST(LIBS)
1161 AC_SUBST(INSTALLSTRIP)
1162
1163 USE_SHARED_LIBS=$enable_shared
1164 AC_SUBST(USE_SHARED_LIBS)
1165 USE_STATIC_LIBS=$enable_static
1166 AC_SUBST(USE_STATIC_LIBS)
1167 AC_SUBST(STATIC_MODULES)
1168 AC_SUBST(RADIUSD_MAJOR_VERSION)
1169 AC_SUBST(RADIUSD_MINOR_VERSION)
1170 AC_SUBST(RADIUSD_VERSION)
1171
1172 AC_OUTPUT(\
1173         ./Make.inc \
1174         ./src/include/build-radpaths-h \
1175         ./src/main/Makefile \
1176         ./src/main/checkrad.pl \
1177         ./src/main/radlast \
1178         ./src/main/radtest \
1179         ./scripts/rc.radiusd \
1180         ./scripts/radwatch \
1181         ./scripts/radiusd.cron.daily \
1182         ./scripts/radiusd.cron.monthly \
1183         ./scripts/cryptpasswd \
1184         ./raddb/dictionary \
1185         ./raddb/radrelay.conf \
1186         ./raddb/radiusd.conf
1187 )