configure.in

   1 dnl #############################################################
   2 dnl #
   3 dnl #  For information about autoconf, see:
   4 dnl #
   5 dnl #  http://www.gnu.org/software/autoconf/
   6 dnl #
   7 dnl #  The recommended order is:
   8 dnl #
   9 dnl #  AC_INIT(file)
  10 dnl #  0. checks for compiler, libtool, and command line options
  11 dnl #  1. checks for programs
  12 dnl #  2. checks for libraries
  13 dnl #  3. checks for header files
  14 dnl #  4. checks for typedefs
  15 dnl #  5. checks for structures and functions
  16 dnl #  6. checks for compiler characteristics
  17 dnl #  7. checks for library functions
  18 dnl #  8. checks for system services
  19 dnl #  AC_OUTPUT([file...])
  20 dnl #
  21 dnl #############################################################
  22
  23 AC_PREREQ([2.59])
  24 export CFLAGS LIBS LDFLAGS CPPFLAGS
  25 AC_INIT(src/main/radiusd.c)
  26 AC_CONFIG_HEADER(src/include/autoconf.h)
  27 AC_REVISION($Revision$)dnl
  28
  29 dnl # The version of the software
  30 RADIUSD_VERSION=`cat VERSION`
  31 RADIUSD_MAJOR_VERSION=`cat VERSION | sed 's/\..*//'`
  32 RADIUSD_MINOR_VERSION=`cat VERSION | sed 's/^2\.//'`
  33 PACKAGE=freeradius
  34
  35 dnl #############################################################
  36 dnl #
  37 dnl #  0. Checks for compiler, libtool, and command line options.
  38 dnl #
  39 dnl #############################################################
  40
  41 dnl Check for GNU cc
  42 AC_PROG_CC
  43 AC_PROG_CXX
  44
  45 dnl #
  46 dnl # check for AIX, to allow us to use some BSD functions
  47 dnl # must be before macros that call the compiler.
  48 dnl #
  49 AC_AIX
  50
  51 AC_PROG_GCC_TRADITIONAL
  52 AC_PROG_CC_SUNPRO
  53 AC_PROG_RANLIB
  54
  55 dnl Compile in large (2G+) file support.
  56 AC_SYS_LARGEFILE
  57
  58 dnl # check for system bytesex
  59 dnl # AC_DEFINES WORDS_BIGENDIAN
  60 AC_C_BIGENDIAN
  61
  62 dnl Find GNU Make.
  63 AC_CHECK_PROG(GMAKE, gmake, yes, no)
  64 if test $GMAKE = no; then
  65   AC_PATH_PROG(MAKE, make, /usr/local/bin/make)
  66 else
  67   AC_PATH_PROG(MAKE, gmake, /usr/local/gnu/bin/make)
  68 fi
  69 makever=`$ac_cv_path_MAKE --version 2>&1 | grep "GNU Make"`
  70 if test -z "$makever"; then
  71   AC_MSG_ERROR(GNU Make is not installed.  Please download and install it
  72                 from ftp://prep.ai.mit.edu/pub/gnu/make/ before continuing.)
  73 fi
  74
  75 dnl libltdl is installable
  76 AC_LIBLTDL_INSTALLABLE
  77
  78 dnl tell Makefile to build ltdl if needed
  79 if test x"$enable_ltdl_install" = x"yes"; then
  80   LTDL_SUBDIRS=libltdl
  81 fi
  82 AC_SUBST(LTDL_SUBDIRS)
  83
  84 dnl use system-wide libtool, if it exists
  85 AC_ARG_WITH(system-libtool,
  86 [  --with-system-libtool              try to use libtool installed in your system [default=use our own]],
  87 [ AC_PATH_PROG(LIBTOOL, libtool,,$PATH:/usr/local/bin) ],
  88 [
  89   LIBTOOL="`pwd`/libtool"
  90   AC_SUBST(LIBTOOL)
  91   dnl ensure that we're looking for dlopen
  92   AC_LIBTOOL_DLOPEN
  93
  94   dnl Figure out how to build shared libraries
  95   AC_PROG_LIBTOOL
  96 ])
  97
  98
  99 dnl Put this in later, when all distributed modules use autoconf.
 100 dnl AC_ARG_WITH(disablemodulefoo,
 101 dnl [  --without-rlm_foo       Disables module compilation.  Module list:]
 102 dnl esyscmd([find src/modules -type d -name rlm_\* -print |\
 103 dnl     sed -e 's%src/modules/.*/% (sub)- %; s%.*/%- %' |\
 104 dnl     awk '{print "                            "$0}']))
 105
 106 AC_ARG_ENABLE(strict-dependencies,
 107 [  --enable-strict-dependencies  Fail configure on lack of module dependancy.])
 108
 109 dnl extra argument: --with-docdir
 110 docdir='${datadir}/doc/freeradius'
 111 AC_MSG_CHECKING(docdir)
 112 AC_ARG_WITH(docdir,
 113 [  --with-docdir=DIR       Directory for documentation [DATADIR/doc/freeradius] ],
 114 [ case "$withval" in
 115     no)
 116         docdir=no
 117         ;;
 118     yes)
 119         ;;
 120     [[\\/$]]* | ?:[[\\/]]* )
 121         docdir="$withval"
 122         ;;
 123     *)
 124         AC_MSG_ERROR([expected an absolute directory name for --with-docdir: $withval])
 125         ;;
 126   esac ]
 127 )
 128 AC_SUBST(docdir)
 129 AC_MSG_RESULT($docdir)
 130 if test "x$docdir" = xno; then
 131         AC_MSG_WARN(Documentation files will NOT be installed.)
 132 fi
 133
 134 dnl extra argument: --with-logdir
 135 logdir='${localstatedir}/log/radius'
 136 AC_MSG_CHECKING(logdir)
 137 AC_ARG_WITH(logdir,
 138 [  --with-logdir=DIR       Directory for logfiles [LOCALSTATEDIR/log/radius] ],
 139 [ case "$withval" in
 140     no)
 141         AC_MSG_ERROR(Need logdir)
 142         ;;
 143     yes)
 144         ;;
 145     [[\\/$]]* | ?:[[\\/]]* )
 146         logdir="$withval"
 147         ;;
 148     *)
 149         AC_MSG_ERROR([expected an absolute directory name for --with-logdir: $withval])
 150         ;;
 151   esac ]
 152 )
 153 AC_SUBST(logdir)
 154 AC_MSG_RESULT($logdir)
 155
 156 dnl extra argument: --with-radacctdir
 157 radacctdir='${logdir}/radacct'
 158 AC_MSG_CHECKING(radacctdir)
 159 AC_ARG_WITH(radacctdir,
 160 [  --with-radacctdir=DIR   Directory for detail files [LOGDIR/radacct] ],
 161 [ case "$withval" in
 162     no)
 163         AC_MSG_ERROR(Need radacctdir)
 164         ;;
 165     yes)
 166         ;;
 167     [[\\/$]]* | ?:[[\\/]]* )
 168         radacctdir="$withval"
 169         ;;
 170     *)
 171         AC_MSG_ERROR([expected an absolute directory name for --with-radacctdir: $withval])
 172         ;;
 173   esac ]
 174 )
 175 AC_SUBST(radacctdir)
 176 AC_MSG_RESULT($radacctdir)
 177
 178 dnl extra argument: --with-raddbdir
 179 raddbdir='${sysconfdir}/raddb'
 180 AC_MSG_CHECKING(raddbdir)
 181 AC_ARG_WITH(raddbdir,
 182 [  --with-raddbdir=DIR     Directory for config files [SYSCONFDIR/raddb] ],
 183 [ case "$withval" in
 184     no)
 185         AC_MSG_ERROR(Need raddbdir)
 186         ;;
 187     yes)
 188         ;;
 189     [[\\/$]]* | ?:[[\\/]]* )
 190         raddbdir="$withval"
 191         ;;
 192     *)
 193         AC_MSG_ERROR([expected an absolute directory name for --with-raddbdir: $withval])
 194         ;;
 195   esac ]
 196 )
 197 AC_SUBST(raddbdir)
 198 AC_MSG_RESULT($raddbdir)
 199
 200 dnl extra argument: --with-ascend-binary
 201 ASCEND_BINARY=yes
 202 AC_ARG_WITH(ascend-binary,
 203 [  --with-ascend-binary    Include support for Ascend binary filter attributes (default=yes)],
 204 [ case "$withval" in
 205     yes)
 206         ;;
 207     *)
 208         ASCEND_BINARY=""
 209   esac ]
 210 )
 211 if test "X$ASCEND_BINARY" = "Xyes"; then
 212   AC_DEFINE(ASCEND_BINARY, [], [Include support for Ascend binary filter attributes])
 213 fi
 214
 215 dnl extra argument: --with-threads
 216 WITH_THREADS=yes
 217 AC_ARG_WITH(threads,
 218 [  --with-threads          Use threads, if available.  (default=yes) ],
 219 [ case "$withval" in
 220     yes)
 221         ;;
 222     *)
 223         WITH_THREADS=""
 224   esac ]
 225 )
 226
 227 dnl extra argument: --with-vmps
 228 WITH_VMPS=yes
 229 AC_ARG_WITH(vmps,
 230 [  --with-vmps             Compile in VMPS support. (default=yes)],
 231 [ case "$withval" in
 232     yes)
 233         ;;
 234     *)
 235         WITH_VMPS=no
 236   esac ]
 237 )
 238 if test "x$WITH_VMPS" = "xyes"; then
 239         AC_DEFINE(WITH_VMPS, [1], [define if you want VMPS support])
 240 fi
 241
 242 dnl extra argument: --with-dhcp
 243 AC_ARG_WITH(dhcp,
 244 [  --with-dhcp             Compile in DHCP support. (default=no)],
 245 [ case "$withval" in
 246     yes)
 247         AC_DEFINE(WITH_DHCP, [1], [Include experimental support for DHCP])
 248         ;;
 249     *)
 250         ;;
 251   esac ]
 252 )
 253
 254
 255 dnl #
 256 dnl #  Allow the user to specify a list of modules to be linked
 257 dnl #  statically to the server.
 258 dnl #
 259 STATIC_MODULES=
 260 AC_ARG_WITH(static_modules,
 261 [  --with-static-modules=QUOTED-MODULE-LIST],[
 262   for i in $withval; do
 263     STATIC_MODULES="$STATIC_MODULES -dlpreopen ../modules/rlm_$i/rlm_$i.la"
 264   done
 265 ])
 266
 267 MODULES=
 268 AC_ARG_WITH(modules,
 269 [ --with-modules=QUOTED-MODULE-LIST],[
 270  for i in $withval; do
 271    MODULES="$MODULES $i"
 272  done
 273 ])
 274
 275 dnl #
 276 dnl #  Enable developer C compiler warnings
 277 dnl #
 278 AC_ARG_ENABLE(developer,
 279 [  --enable-developer               Enables features of interest to developers.],
 280 [ case "$enableval" in
 281     no)
 282         developer=no
 283         ;;
 284     *)
 285         developer=yes
 286   esac ]
 287 )
 288
 289 if test "x$developer" != "xno" -a -d $srcdir/CVS; then
 290   dnl turn on the developer flag when taken from a CVS checkout (not a release)
 291   developer="yes"
 292 fi
 293
 294 if test "x$developer" != "xno" -a -d $srcdir/.git; then
 295   dnl turn on the developer flag when taken from a git checkout (not a release)
 296   developer="yes"
 297 fi
 298
 299 dnl extra argument: --with-experimental-modules
 300 EXPERIMENTAL=
 301 AC_ARG_WITH(experimental-modules,
 302 [  --with-experimental-modules      Use experimental and unstable modules. (default=no) ],
 303 [ case "$withval" in
 304     yes)
 305         EXPERIMENTAL=yes
 306         ;;
 307     *)
 308   esac ]
 309 )
 310
 311 dnl extra argument: --with-openssl
 312 WITH_OPENSSL=yes
 313 AC_ARG_WITH(openssl,
 314 [  --with-openssl                   Use OpenSSL. (default=yes)],
 315 [ case "$withval" in
 316     no)
 317         WITH_OPENSSL=no
 318         ;;
 319     *)
 320         WITH_OPENSSL=yes
 321         ;;
 322   esac ]
 323 )
 324
 325 dnl #
 326 dnl # extra argument: --with-openssl-includes=dir
 327 dnl #
 328 OPENSSL_INCLUDE_DIR=
 329 AC_ARG_WITH(openssl-includes,
 330 [  --with-openssl-includes=DIR      Directory to look for OpenSSL include files],
 331 [ case "$withval" in
 332     *) OPENSSL_INCLUDE_DIR="$withval"
 333         ;;
 334   esac ]
 335 )
 336
 337 dnl #
 338 dnl # extra argument: --with-openssl-libraries=dir
 339 dnl #
 340 OPENSSL_LIB_DIR=
 341 AC_ARG_WITH(openssl-libraries,
 342 [  --with-openssl-libraries=DIR     Directory to look for OpenSSL library files],
 343 [ case "$withval" in
 344     *) OPENSSL_LIB_DIR="$withval"
 345         ;;
 346   esac ]
 347 )
 348
 349 dnl #
 350 dnl #  These next two arguments don't actually do anything.  They're
 351 dnl #  place holders so that the top-level configure script can tell
 352 dnl #  the user how to configure lower-level modules
 353 dnl #
 354
 355 dnl #
 356 dnl # extra argument: --with-rlm-FOO-lib-dir
 357 dnl #
 358 AC_ARG_WITH(rlm-FOO-lib-dir,
 359 [  --with-rlm-FOO-lib-dir=DIR       Directory to look for library files used by module FOO],
 360 [ case "$withval" in
 361     *)
 362         ;;
 363   esac ]
 364 )
 365
 366 dnl #
 367 dnl # extra argument: --with-rlm-FOO-include-dir
 368 dnl #
 369 AC_ARG_WITH(rlm-FOO-include-dir,
 370 [  --with-rlm-FOO-include-dir=DIR   Directory to look for include files used by module FOO],
 371 [ case "$withval" in
 372     *)
 373         ;;
 374   esac ]
 375 )
 376
 377 dnl See what include-style is used by the make program.
 378 dnl AC_MSG_CHECKING(include style for make)
 379 dnl echo "include /dev/null" > testmake.$$
 380 dnl echo "all:" >> testmake.$$
 381 dnl make -f testmake.$$ >/dev/null 2>&1
 382 dnl if test $? = 0
 383 dnl then
 384 dnl     INCLUDE=include
 385 dnl     IQUOTE=
 386 dnl else
 387 dnl     INCLUDE=.include
 388 dnl     IQUOTE='"'
 389 dnl fi
 390 dnl rm -f testmake.$$
 391 dnl AC_MSG_RESULT(" $INCLUDE")
 392 dnl AC_SUBST(INCLUDE)
 393 dnl AC_SUBST(IQUOTE)
 394
 395 dnl extra argument: --with-udpfromto
 396 WITH_UDPFROMTO=no
 397 AC_ARG_WITH(udpfromto,
 398 [  --with-udpfromto        Compile in UDPFROMTO support. (default=no)],
 399 [ case "$withval" in
 400     yes)
 401         WITH_UDPFROMTO=yes
 402         ;;
 403     *)
 404         WITH_UDPFROMTO=no
 405   esac ]
 406 )
 407
 408 if test "x$WITH_UDPFROMTO" = "xyes"; then
 409         AC_DEFINE(WITH_UDPFROMTO, [], [define if you want udpfromto])
 410 fi
 411
 412 dnl #############################################################
 413 dnl #
 414 dnl #  1. Checks for programs
 415 dnl #
 416 dnl #############################################################
 417
 418 CHECKRAD=checkrad.pl
 419 AC_PATH_PROG(PERL, perl, /usr/local/bin/perl)
 420 if test "x$ac_cv_path_PERL" = "x"; then
 421   AC_MSG_WARN(perl not found - Simultaneous-Use and checkrad.pl may not work)
 422 fi
 423 AC_PATH_PROG(SNMPGET, snmpget)
 424 if test "x$ac_cv_path_SNMPGET" = "x"; then
 425   AC_MSG_WARN(snmpget not found - Simultaneous-Use and checkrad.pl may not work)
 426 fi
 427
 428 AC_PATH_PROG(SNMPWALK, snmpwalk)
 429 if test "x$ac_cv_path_SNMPWALK" = "x"; then
 430   AC_MSG_WARN(snmpwalk not found - Simultaneous-Use and checkrad.pl may not work)
 431 fi
 432
 433 AC_PATH_PROG(RUSERS, rusers, /usr/bin/rusers)
 434
 435 dnl FIXME This is truly gross.
 436 missing_dir=`cd $ac_aux_dir && pwd`
 437 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
 438 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
 439 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
 440
 441 AC_PATH_PROG(LOCATE,locate)
 442 AC_PATH_PROG(DIRNAME,dirname)
 443 AC_PATH_PROG(GREP,grep)
 444
 445 dnl #############################################################
 446 dnl #
 447 dnl #  2. Checks for libraries
 448 dnl #
 449 dnl #############################################################
 450
 451 dnl If using pthreads, check for -lpthread (posix) or -lc_r (*BSD)
 452 old_CFLAGS=$CFLAGS
 453 if test "x$WITH_THREADS" = "xyes"; then
 454   if test $ac_cv_prog_suncc = "yes"; then
 455     CFLAGS="$CFLAGS -mt"
 456   fi
 457
 458   AC_CHECK_HEADERS(pthread.h, [], [ WITH_THREADS="no" ])
 459
 460 dnl #
 461 dnl # pthread stuff is usually in -lpthread
 462 dnl # or in -lc_r, on *BSD
 463 dnl #
 464 dnl # On Some systems, we need extra pre-processor flags, to get them to
 465 dnl # to do the threading properly.
 466 dnl #
 467   AC_CHECK_LIB(pthread, pthread_create,
 468                 [ CFLAGS="$CFLAGS -D_REENTRANT -D_POSIX_PTHREAD_SEMANTICS"
 469                   LIBS="$LIBS -lpthread" ],
 470                 AC_CHECK_LIB(c_r, pthread_create,
 471                             [ CFLAGS="$CFLAGS -pthread -D_THREAD_SAFE" ],
 472                             [ WITH_THREADS="no" ]
 473                             )
 474                 )
 475 fi
 476
 477 dnl #
 478 dnl # If we have NO pthread libraries, remove any knowledge of threads.
 479 dnl #
 480 if test "x$WITH_THREADS" != "xyes"; then
 481   CFLAGS=$old_CFLAGS
 482   ac_cv_header_pthread_h="no"
 483   WITH_THREADS=no
 484 else
 485   dnl #
 486   dnl #  We need sem_init() and friends, as they're the friendliest
 487   dnl #  semaphore functions for threading.
 488   dnl #
 489   dnl # HP/UX requires linking with librt, too, to get the sem_* symbols.
 490   dnl # Some systems have them in -lsem
 491   dnl # Solaris has them in -lposix4
 492   dnl # NetBSD has them in -lsemaphore
 493
 494   AC_SEARCH_LIBS(sem_init, pthread sem posix4 rt semaphore,
 495         [],
 496         [AC_MSG_ERROR(-lsem not found.  You may want to download it from ftp://ftp.to.gd-es.com/pub/BSDI/libsem.tar.bz2 or ftp://ftp.freeradius.org/pub/radius/contrib/libsem.tar.gz)]
 497    )
 498 fi
 499
 500 dnl Check if we need -lsocket
 501 AC_CHECK_LIB(socket, getsockname)
 502
 503 dnl Check for -lresolv
 504 dnl This library may be needed later.
 505 AC_CHECK_LIB(resolv, inet_aton)
 506
 507 dnl Check if we need -lnsl. Usually if we want to
 508 dnl link against -lsocket we need to include -lnsl as well.
 509 AC_CHECK_LIB(nsl, inet_ntoa)
 510
 511 dnl Check for OpenSSL libraries.
 512 OPENSSL_LIBS=
 513 if test "x$WITH_OPENSSL" = xyes; then
 514   old_LIBS=$LIBS
 515   if test "x$OPENSSL_LIB_DIR" != "x"; then
 516     LIBS="-L$OPENSSL_LIB_DIR $LIBS"
 517   fi
 518   AC_CHECK_LIB(crypto, DH_new,
 519     [
 520         LIBS="-lcrypto $LIBS"
 521         AC_DEFINE(HAVE_LIBCRYPTO, 1,
 522             [Define to 1 if you have the `crypto' library (-lcrypto).])
 523         AC_CHECK_LIB(ssl, SSL_new,
 524             [
 525                 AC_DEFINE(HAVE_LIBSSL, 1,
 526                     [Define to 1 if you have the `ssl' library (-lssl).])
 527                 if test "x$OPENSSL_LIB_DIR" != "x"; then
 528                     OPENSSL_LIBS="-L$OPENSSL_LIB_DIR"
 529                 fi
 530                 OPENSSL_LIBS="$OPENSSL_LIBS -lcrypto -lssl -lcrypto"
 531             ], [])
 532     ], [])
 533   LIBS=$old_LIBS
 534 fi
 535
 536 AC_CHECK_LIB(ws2_32, htonl)
 537
 538 dnl Check the pcap library for the RADIUS sniffer.
 539 PCAP_LIBS=
 540 AC_CHECK_LIB(pcap, pcap_open_live,
 541         [ PCAP_LIBS="-lpcap"
 542         AC_DEFINE(HAVE_LIBPCAP, 1,
 543                 [Define to 1 if you have the `pcap' library (-lpcap).])
 544         ],
 545         [ AC_MSG_WARN([pcap library not found, silently disabling the RADIUS sniffer.]) ])
 546
 547 dnl #############################################################
 548 dnl #
 549 dnl #  3. Checks for header files
 550 dnl #
 551 dnl #############################################################
 552
 553 dnl #
 554 dnl # Interix requires us to set -D_ALL_SOURCE, otherwise
 555 dnl # getopt will be #included, but won't link.  <sigh>
 556 dnl #
 557 dnl #
 558 case "$host" in
 559 *-interix*)
 560         CFLAGS="$CFLAGS -D_ALL_SOURCE"
 561         ;;
 562 *-darwin*)
 563         CFLAGS="$CFLAGS -DDARWIN"
 564         LIBS="-framework DirectoryService $LIBS"
 565         ;;
 566 esac
 567
 568 AC_HEADER_DIRENT
 569 AC_HEADER_STDC
 570 AC_HEADER_TIME
 571 AC_HEADER_SYS_WAIT
 572
 573 AC_CHECK_HEADERS( \
 574         unistd.h \
 575         crypt.h \
 576         errno.h \
 577         resource.h \
 578         sys/resource.h \
 579         getopt.h \
 580         malloc.h \
 581         utmp.h \
 582         utmpx.h \
 583         signal.h \
 584         sys/select.h \
 585         syslog.h \
 586         inttypes.h \
 587         stdint.h \
 588         stdio.h \
 589         netdb.h \
 590         semaphore.h \
 591         arpa/inet.h \
 592         netinet/in.h \
 593         sys/types.h \
 594         sys/socket.h \
 595         winsock.h \
 596         sys/time.h \
 597         sys/wait.h \
 598         sys/security.h \
 599         fcntl.h \
 600         sys/fcntl.h \
 601         sys/prctl.h \
 602         glob.h \
 603         prot.h \
 604         pwd.h \
 605         grp.h \
 606         sia.h \
 607         siad.h
 608 )
 609
 610 dnl FreeBSD requires sys/socket.h before net/if.h
 611 AC_CHECK_HEADERS(net/if.h, [], [],
 612 [#ifdef HAVE_SYS_SOCKET_H
 613 # include <sys/socket.h>
 614 # endif
 615 ])
 616
 617 REGEX=no
 618 AC_CHECK_HEADER(regex.h, AC_DEFINE(HAVE_REGEX_H, [], [define this if we have the <regex.h> header file]))
 619 if test "x$ac_cv_header_regex_h" = "xyes"; then
 620   REGEX_EXTENDED=no
 621   REGEX=yes
 622   AC_EGREP_CPP(yes,
 623     [#include <regex.h>
 624      #ifdef REG_EXTENDED
 625        yes
 626      #endif
 627      ], [AC_DEFINE(HAVE_REG_EXTENDED, [], [define this if we have REG_EXTENDED (from <regex.h>)]) REGEX_EXTENDED=yes])
 628 fi
 629 AC_SUBST(REGEX)
 630 AC_SUBST(REGEX_EXTENDED)
 631
 632 dnl #
 633 dnl #  other checks which require headers
 634 dnl #
 635 if test "x$ac_cv_header_sys_security_h" = "xyes" && test "x$ac_cv_header_prot_h" = "xyes"
 636 then
 637   AC_DEFINE(OSFC2, [], [define if you have OSFC2 authentication])
 638 fi
 639
 640 if test "x$ac_cv_header_sia_h" = "xyes" && test "x$ac_cv_header_siad_h" = "xyes"
 641 then
 642   AC_DEFINE(OSFSIA, [], [define if you have OSFSIA authentication])
 643 fi
 644
 645 dnl Check for OpenSSL includes.
 646 OPENSSL_INCLUDE="-DNO_OPENSSL"
 647 if test "x$WITH_OPENSSL" = xyes; then
 648   if test "x$OPENSSL_LIBS" = "x"; then
 649     AC_MSG_NOTICE([skipping test for openssl/ssl.h])
 650   else
 651     old_CPPFLAGS=$CPPFLAGS
 652     if test "x$OPENSSL_INCLUDE_DIR" != "x"; then
 653         CPPFLAGS="$CPPFLAGS -I$OPENSSL_INCLUDE_DIR"
 654     fi
 655     dnl # stupid RedHat shit
 656     CPPFLAGS="$CPPFLAGS -DOPENSSL_NO_KRB5"
 657     AC_CHECK_HEADERS( \
 658         openssl/ssl.h \
 659         openssl/crypto.h \
 660         openssl/err.h \
 661         openssl/evp.h \
 662         openssl/engine.h,
 663         [],
 664         OPENSSL_LIBS=
 665     )
 666     if test "x$OPENSSL_LIBS" != "x"; then
 667         AC_MSG_CHECKING([for OpenSSL version >= 0.9.7])
 668         AC_EGREP_CPP(yes,
 669             [#include <openssl/crypto.h>
 670              #if (OPENSSL_VERSION_NUMBER >= 0x00907000L)
 671              yes
 672              #endif
 673             ], goodssl="yes")
 674         if test "x$goodssl" != "xyes"; then
 675             AC_MSG_RESULT(no)
 676             OPENSSL_LIBS=
 677         else
 678             AC_MSG_RESULT(yes)
 679             if test "x$OPENSSL_INCLUDE_DIR" != "x"; then
 680                 OPENSSL_INCLUDE="-I$OPENSSL_INCLUDE_DIR -DOPENSSL_NO_KRB5"
 681             else
 682                 OPENSSL_INCLUDE="-DOPENSSL_NO_KRB5"
 683             fi
 684         fi
 685     fi
 686     CPPFLAGS=$old_CPPFLAGS
 687   fi
 688 fi
 689 AC_SUBST(OPENSSL_INCLUDE)
 690 AC_SUBST(OPENSSL_LIBS)
 691 export OPENSSL_LIBS
 692
 693 dnl Check the pcap includes for the RADIUS sniffer.
 694 if test "x$PCAP_LIBS" = x; then
 695     AC_MSG_NOTICE([skipping test for pcap.h.])
 696 else
 697     AC_CHECK_HEADER(pcap.h,
 698         AC_DEFINE(HAVE_PCAP_H, 1,
 699                 [Define to 1 if you have the <pcap.h> header file.]),
 700         [ PCAP_LIBS=
 701         AC_MSG_WARN([pcap.h not found, silently disabling the RADIUS sniffer.])
 702         ])
 703 fi
 704 AC_SUBST(PCAP_LIBS)
 705
 706 dnl #############################################################
 707 dnl #
 708 dnl #  4. Checks for typedefs
 709 dnl #
 710 dnl #############################################################
 711
 712 dnl #
 713 dnl # Ensure that these are defined
 714 dnl #
 715 AC_TYPE_OFF_T
 716 AC_TYPE_PID_T
 717 AC_TYPE_SIZE_T
 718 AC_TYPE_UID_T
 719
 720 dnl check for socklen_t
 721 FR_CHECK_TYPE_INCLUDE([
 722 #ifdef HAVE_SYS_TYPES_H
 723 #include <sys/types.h>
 724 #endif
 725 #ifdef HAVE_SYS_SOCKET_H
 726 #include <sys/socket.h>
 727 #endif
 728 ],socklen_t, int, [socklen_t is generally 'int' on systems which don't use it])
 729
 730 dnl check for uint8_t
 731 FR_CHECK_TYPE_INCLUDE([
 732 #ifdef HAVE_INTTYPES_H
 733 #include <inttypes.h>
 734 #endif
 735 #ifdef HAVE_STDINT_H
 736 #include <stdint.h>
 737 #endif
 738 ],uint8_t, unsigned char, [uint8_t should be the canonical 'octet' for network traffic])
 739
 740 dnl check for uint16_t
 741 FR_CHECK_TYPE_INCLUDE([
 742 #ifdef HAVE_INTTYPES_H
 743 #include <inttypes.h>
 744 #endif
 745 #ifdef HAVE_STDINT_H
 746 #include <stdint.h>
 747 #endif
 748 ],uint16_t, unsigned short, [uint16_t should be the canonical '2 octets' for network traffic])
 749
 750 dnl check for uint32_t
 751 FR_CHECK_TYPE_INCLUDE([
 752 #ifdef HAVE_INTTYPES_H
 753 #include <inttypes.h>
 754 #endif
 755 #ifdef HAVE_STDINT_H
 756 #include <stdint.h>
 757 #endif
 758 ],uint32_t, unsigned int, [uint32_t should be the canonical 'network integer])
 759
 760 AC_CHECK_TYPE(struct in6_addr, AC_DEFINE(HAVE_STRUCT_IN6_ADDR, 1, [IPv6 address structure]), [], [
 761 #ifdef HAVE_NETINET_IN_H
 762 #include <netinet/in.h>
 763 #endif
 764 ])
 765
 766 AC_CHECK_TYPE(struct sockaddr_storage, AC_DEFINE(HAVE_STRUCT_SOCKADDR_STORAGE, 1, [Generic socket addresses]), [], [
 767 #ifdef HAVE_NETINET_IN_H
 768 #include <netinet/in.h>
 769 #endif
 770 #ifdef HAVE_SYS_SOCKET_H
 771 #include <sys/socket.h>
 772 #endif
 773 ])
 774
 775 AC_CHECK_TYPE(struct sockaddr_in6, AC_DEFINE(HAVE_STRUCT_SOCKADDR_IN6, 1, [IPv6 socket addresses]), [], [
 776 #ifdef HAVE_NETINET_IN_H
 777 #include <netinet/in.h>
 778 #endif
 779 ])
 780
 781 AC_CHECK_TYPE(struct addrinfo, AC_DEFINE(HAVE_STRUCT_ADDRINFO, 1, [Generic DNS lookups]), [], [
 782 #ifdef HAVE_SYS_TYPES_H
 783 #include <sys/types.h>
 784 #endif
 785 #ifdef HAVE_SYS_SOCKET_H
 786 #include <sys/socket.h>
 787 #endif
 788 #ifdef HAVE_NETDB_H
 789 #include <netdb.h>
 790 #endif
 791 ])
 792
 793 dnl #############################################################
 794 dnl #
 795 dnl #  5. Checks for structures and functions
 796 dnl #
 797 dnl #############################################################
 798 AC_CHECK_FUNCS( \
 799         getopt_long \
 800         lockf \
 801         strsignal \
 802         sigaction \
 803         sigprocmask \
 804         pthread_sigmask \
 805         snprintf \
 806         vsnprintf \
 807         setsid \
 808         strncasecmp \
 809         strcasecmp \
 810         localtime_r \
 811         ctime_r \
 812         gmtime_r \
 813         strsep \
 814         inet_aton \
 815         inet_pton \
 816         inet_ntop \
 817         setlinebuf \
 818         setvbuf \
 819         getusershell \
 820         initgroups \
 821         getaddrinfo \
 822         getnameinfo \
 823         closefrom \
 824         gettimeofday \
 825         strlcat \
 826         strlcpy
 827 )
 828 RADIUSD_NEED_DECLARATIONS( \
 829         crypt \
 830         strncasecmp \
 831         strcasecmp \
 832         inet_aton \
 833         setlinebuf \
 834         getusershell \
 835         endusershell
 836 )
 837
 838 AC_TYPE_SIGNAL
 839
 840 dnl # check if we have utmpx.h
 841 dnl # if so, check if struct utmpx has entry ut_xtime
 842 dnl # if not, set it to define ut_xtime == ut_tv.tv_sec
 843 if test "x$ac_cv_header_utmpx_h" = "xyes"
 844 then
 845  FR_CHECK_STRUCT_HAS_MEMBER([#include <utmpx.h>], [struct utmpx], ut_xtime)
 846  if test "x$ac_cv_type_struct_utmpx_has_ut_xtime" = "x"
 847  then
 848    AC_DEFINE(ut_xtime,ut_tv.tv_sec, [define to something if you don't have ut_xtime in struct utmpx])
 849  fi
 850 fi
 851
 852 dnl # struct ip_pktinfo
 853 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in_pktinfo], ipi_addr)
 854 if test "x$ac_cv_type_struct_in_pktinfo_has_ipi_addr" = "xyes"
 855 then
 856         AC_DEFINE(HAVE_IP_PKTINFO, [], [define if you have IP_PKTINFO (Linux)])
 857 fi
 858
 859 dnl # struct in6_pktinfo
 860 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in6_pktinfo], ipi6_addr)
 861 if test "x$ac_cv_type_struct_in6_pktinfo_has_ipi6_addr" = "xyes"
 862 then
 863         AC_DEFINE(HAVE_IN6_PKTINFO, [], [define if you have IN6_PKTINFO (Linux)])
 864 fi
 865
 866 dnl #############################################################
 867 dnl #
 868 dnl #  6. Checks for compiler characteristics
 869 dnl #
 870 dnl #############################################################
 871
 872 dnl #
 873 dnl # Ensure that these are defined
 874 dnl #
 875 AC_C_CONST
 876
 877 dnl #
 878 dnl # See if this is OS/2
 879 dnl #
 880 AC_MSG_CHECKING(type of OS)
 881 OS=`uname -s`
 882 AC_MSG_RESULT($OS)
 883 if test "$OS" = "OS/2"; then
 884         LIBPREFIX=
 885 else
 886         LIBPREFIX=lib
 887 fi
 888 AC_SUBST(LIBPREFIX)
 889
 890 dnl #
 891 dnl # Set Default CFLAGS
 892 dnl #
 893 if test "x$GCC" = "xyes"; then
 894     CFLAGS="$CFLAGS -Wall -D_GNU_SOURCE"
 895 fi
 896
 897 AC_MSG_CHECKING(for developer gcc flags)
 898 if test "x$developer" = "xyes" -a "x$GCC" = "xyes"; then
 899   devflags="-g -Wshadow -Wpointer-arith -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -W -Wredundant-decls -Wundef"
 900   CFLAGS="$CFLAGS $devflags"
 901   INSTALLSTRIP=""
 902   AC_MSG_RESULT(yes.  Using $devflags)
 903 else
 904   devflags=""
 905   CFLAGS="$CFLAGS -DNDEBUG"
 906   INSTALLSTRIP=""
 907   AC_MSG_RESULT(no.)
 908 fi
 909
 910 FR_TLS
 911
 912 dnl #############################################################
 913 dnl #
 914 dnl #  7. Checks for library functions
 915 dnl #
 916 dnl #############################################################
 917
 918 dnl Check for libcrypt
 919 dnl We use crypt(3) which may be in libc, or in libcrypt (eg FreeBSD)
 920 AC_CHECK_LIB(crypt, crypt,
 921   CRYPTLIB="-lcrypt"
 922 )
 923 if test "$CRYPTLIB" != ""; then
 924   AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function])
 925 else
 926   AC_CHECK_FUNC(crypt, AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function]))
 927 fi
 928
 929 dnl Check for libcipher
 930 AC_CHECK_LIB(cipher, setkey,
 931    CRYPTLIB="${CRYPTLIB} -lcipher"
 932 )
 933 AC_SUBST(CRYPTLIB)
 934
 935 dnl Check the style of gethostbyaddr, in order of preference
 936 dnl GNU (_r eight args)
 937 AC_DEFINE(GNUSTYLE, [1], [GNU-Style get*byaddr_r])
 938 dnl SYSV (_r six args)
 939 AC_DEFINE(SYSVSTYLE, [2], [SYSV-Style get*byaddr_r])
 940 dnl BSD (three args, may not be thread safe)
 941 AC_DEFINE(BSDSTYLE, [3], [BSD-Style get*byaddr_r])
 942 dnl Tru64 has BSD version, but it is thread safe
 943 dnl     http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1739____.HTM
 944 dnl We need #stdio.h to define NULL on FreeBSD (at least)
 945 gethostbyaddrrstyle=""
 946 AC_MSG_CHECKING([gethostbyaddr_r() syntax])
 947 case "$host" in
 948 *-freebsd*)
 949 dnl With FreeBSD, check if there's a prototype for gethostbyaddr_r.
 950 dnl Some versions (FreeBSD 5.1?) have a symbol but no prototype - so we
 951 dnl override this test to BSDSTYLE. FreeBSD 6.2 and up have proper GNU
 952 dnl style support.
 953         AC_CHECK_DECLS([gethostbyaddr_r], [], [
 954                 AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE,
 955                         [style of gethostbyaddr_r functions ])
 956                 gethostbyaddrrstyle=BSD
 957                 AC_MSG_WARN([FreeBSD overridden to BSD-style])
 958         ], [
 959 #ifdef HAVE_NETDB_H
 960 #include <netdb.h>
 961 #endif
 962 ])
 963         ;;
 964 esac
 965 if test "x$gethostbyaddrrstyle" = "x"; then
 966         AC_TRY_LINK([
 967 #include <stdio.h>
 968 #include <netdb.h>
 969 ], [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL, NULL) ], [
 970         AC_DEFINE(GETHOSTBYADDRRSTYLE, GNUSTYLE, [style of gethostbyaddr_r functions ])
 971         gethostbyaddrrstyle=GNU
 972 ])
 973 fi
 974 if test "x$gethostbyaddrrstyle" = "x"; then
 975         AC_TRY_LINK([
 976 #include <stdio.h>
 977 #include <netdb.h>
 978 ], [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL) ] , [
 979                 AC_DEFINE(GETHOSTBYADDRRSTYLE, SYSVSTYLE, [style of gethostbyaddr_r functions ])
 980                 gethostbyaddrrstyle=SYSV
 981         ])
 982 fi
 983 if test "x$gethostbyaddrrstyle" = "x"; then
 984         AC_TRY_LINK([
 985 #include <stdio.h>
 986 #include <netdb.h>
 987 ], [ gethostbyaddr(NULL, 0, 0)  ], [
 988                 AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE, [style of gethostbyaddr_r functions ])
 989                 gethostbyaddrrstyle=BSD
 990         ])
 991 fi
 992
 993 if test "x$gethostbyaddrrstyle" = "x"; then
 994         AC_MSG_RESULT([none!  It must not exist, here.])
 995 else
 996         AC_MSG_RESULT([${gethostbyaddrrstyle}-style])
 997 fi
 998
 999 if test "x$gethostbyaddrrstyle" = "xBSD"; then
1000         AC_MSG_WARN([ ****** BSD-style gethostbyaddr might NOT be thread-safe! ****** ])
1001 fi
1002
1003 dnl Check the style of gethostbyname, in order of preference
1004 dnl GNU (_r seven args)
1005 dnl SYSV (_r five args)
1006 dnl BSD (two args, may not be thread safe)
1007 dnl Tru64 has BSD version, but it _is_ thread safe
1008 dnl     http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1946____.HTM
1009 dnl We need #stdio.h to define NULL on FreeBSD (at least)
1010 gethostbynamerstyle=""
1011 AC_MSG_CHECKING([gethostbyname_r() syntax])
1012 AC_TRY_LINK([
1013 #include <stdio.h>
1014 #include <netdb.h>
1015 ], [ gethostbyname_r(NULL, NULL, NULL, 0, NULL, NULL) ], [
1016         AC_DEFINE(GETHOSTBYNAMERSTYLE, GNUSTYLE, [style of gethostbyname_r functions ])
1017         gethostbynamerstyle=GNU
1018 ])
1019 if test "x$gethostbynamerstyle" = "x"; then
1020         AC_TRY_LINK([
1021 #include <stdio.h>
1022 #include <netdb.h>
1023 ], [ gethostbyname_r(NULL, NULL, NULL, 0, NULL) ] , [
1024                 AC_DEFINE(GETHOSTBYNAMERSTYLE, SYSVSTYLE, [style of gethostbyname_r functions ])
1025                 gethostbynamerstyle=SYSV
1026         ])
1027 fi
1028 if test "x$gethostbynamerstyle" = "x"; then
1029         AC_TRY_LINK([
1030 #include <stdio.h>
1031 #include <netdb.h>
1032 ], [ gethostbyname(NULL)  ], [
1033                 AC_DEFINE(GETHOSTBYNAMERSTYLE, BSDSTYLE, [style of gethostbyname_r functions ])
1034                 gethostbynamerstyle=BSD
1035         ])
1036 fi
1037
1038 if test "x$gethostbynamerstyle" = "x"; then
1039         AC_MSG_RESULT([none!  It must not exist, here.])
1040 else
1041         AC_MSG_RESULT([${gethostbynamerstyle}-style])
1042 fi
1043
1044 if test "x$gethostbynamerstyle" = "xBSD"; then
1045         AC_MSG_WARN([ ****** BSD-style gethostbyname might NOT be thread-safe! ****** ])
1046 fi
1047
1048 dnl check for non-posix solaris ctime_r (extra buflen int arg)
1049 AC_DEFINE(POSIXSTYLE, [1], [Posix-Style ctime_r])
1050 AC_DEFINE(SOLARISSTYLE, [2], [Solaris-Style ctime_r])
1051 ctimerstyle=""
1052 AC_MSG_CHECKING([ctime_r() syntax])
1053 AC_TRY_LINK([
1054 #include <time.h>
1055 ], [ ctime_r(NULL, NULL, 0) ], [
1056         AC_DEFINE(CTIMERSTYLE, SOLARISSTYLE, [style of ctime_r function])
1057         ctimerstyle="SOLARIS"
1058 ])
1059 if test "x$ctimerstyle" = "x"; then
1060         AC_TRY_LINK([
1061 #include <time.h>
1062 ], [ ctime_r(NULL, NULL) ], [
1063                 AC_DEFINE(CTIMERSTYLE, POSIXSTYLE, [style of ctime_r function])
1064                 ctimerstyle="POSIX"
1065         ])
1066 fi
1067
1068 if test "x$ctimerstyle" = "x"; then
1069         AC_MSG_RESULT([none!  It must not exist, here.])
1070 else
1071         AC_MSG_RESULT([${ctimerstyle}-style])
1072 fi
1073
1074 AC_SUBST(HOSTINFO, $host)
1075
1076 dnl #############################################################
1077 dnl #
1078 dnl #  8. Checks for system services
1079 dnl #
1080 dnl #############################################################
1081
1082 dnl #
1083 dnl # Figure out where libtool is located,
1084 dnl #
1085 top_builddir=`pwd`
1086 export top_builddir
1087 AC_MSG_RESULT([top_builddir=$top_builddir])
1088 dnl # AC_SUBST(top_builddir)
1089 AC_SUBST(LIBLTDL)
1090 AC_SUBST(INCLTDL)
1091
1092 dnl import libtool stuff
1093
1094 dnl #############################################################
1095 dnl #
1096 dnl #  Configure in any module directories.
1097 dnl #
1098 dnl #############################################################
1099
1100 mysubdirs="$LIBLTDLPATH"
1101 if test "x$EXPERIMENTAL" = "xyes"; then
1102   bar=`ls -1 "${srcdir}"/src/modules/rlm_*/configure | sed 's%/configure%%'`
1103   dnl # get rid of LF's.
1104   mysubdirs=`echo $mysubdirs $bar`
1105 else
1106   dnl #
1107   dnl # Find 'configure' in ONLY the stable modules
1108   dnl #
1109   for bar in `cat "${srcdir}"/src/modules/stable`; do
1110     if test -f "${srcdir}"/src/modules/$bar/configure; then
1111       mysubdirs="$mysubdirs src/modules/$bar"
1112     fi
1113   done
1114 fi
1115
1116 dnl ############################################################
1117 dnl # make modules by list
1118 dnl #############################################################
1119 if test "x$EXPERIMENTAL" = "xyes"; then
1120   for foo in `ls -1 "${srcdir}"/src/modules | grep rlm_`; do
1121     MODULES="$MODULES $foo"
1122   done
1123 else
1124    dnl #
1125    dnl # make ONLY the stable modules
1126    dnl #
1127    for foo in `cat "${srcdir}"/src/modules/stable`; do
1128     MODULES="$MODULES $foo"
1129    done
1130 fi
1131
1132 dnl #
1133 dnl #  Don't change the variable name here.  Autoconf goes bonkers
1134 dnl #  if you do.
1135 dnl #
1136 AC_CONFIG_SUBDIRS($LTDL_SUBDIRS $mysubdirs)
1137 AC_SUBST(MODULES)
1138
1139 dnl #############################################################
1140 dnl #
1141 dnl #  And finally, output the results.
1142 dnl #
1143 dnl #############################################################
1144
1145 AC_CONFIG_COMMANDS([stamp-h], [echo timestamp > src/include/stamp-h])
1146 AC_CONFIG_COMMANDS([build-radpaths-h], [(cd ./src/include && /bin/sh ./build-radpaths-h)])
1147 AC_CONFIG_COMMANDS([main-chmod], [(cd ./src/main   && chmod +x checkrad.pl radlast radtest)])
1148 AC_CONFIG_COMMANDS([scripts-chmod], [(cd ./scripts    && chmod +x rc.radiusd radwatch radiusd.cron.daily radiusd.cron.monthly cryptpasswd)])
1149
1150 dnl #
1151 dnl #  Substitute whatever libraries we found to be necessary
1152 dnl #
1153 AC_SUBST(LIBS)
1154 AC_SUBST(INSTALLSTRIP)
1155
1156 USE_SHARED_LIBS=$enable_shared
1157 AC_SUBST(USE_SHARED_LIBS)
1158 USE_STATIC_LIBS=$enable_static
1159 AC_SUBST(USE_STATIC_LIBS)
1160 AC_SUBST(STATIC_MODULES)
1161 AC_SUBST(RADIUSD_MAJOR_VERSION)
1162 AC_SUBST(RADIUSD_MINOR_VERSION)
1163 AC_SUBST(RADIUSD_VERSION)
1164
1165 AC_OUTPUT(\
1166         ./Make.inc \
1167         ./src/include/build-radpaths-h \
1168         ./src/main/Makefile \
1169         ./src/main/checkrad.pl \
1170         ./src/main/radlast \
1171         ./src/main/radtest \
1172         ./scripts/rc.radiusd \
1173         ./scripts/radwatch \
1174         ./scripts/radiusd.cron.daily \
1175         ./scripts/radiusd.cron.monthly \
1176         ./scripts/cryptpasswd \
1177         ./raddb/dictionary \
1178         ./raddb/radiusd.conf
1179 )