configure.in

   1 dnl #############################################################
   2 dnl #
   3 dnl #  For information about autoconf, see:
   4 dnl #
   5 dnl #  http://www.gnu.org/software/autoconf/
   6 dnl #
   7 dnl #  The recommended order is:
   8 dnl #
   9 dnl #  AC_INIT(file)
  10 dnl #  0. checks for compiler, libtool, and command line options
  11 dnl #  1. checks for programs
  12 dnl #  2. checks for libraries
  13 dnl #  3. checks for header files
  14 dnl #  4. checks for typedefs
  15 dnl #  5. checks for structures and functions
  16 dnl #  6. checks for compiler characteristics
  17 dnl #  7. checks for library functions
  18 dnl #  8. checks for system services
  19 dnl #  AC_OUTPUT([file...])
  20 dnl #
  21 dnl #############################################################
  22
  23 AC_PREREQ([2.59])
  24 export CFLAGS LIBS LDFLAGS CPPFLAGS
  25 AC_INIT(src/main/radiusd.c)
  26 AC_CONFIG_HEADER(src/include/autoconf.h)
  27 AC_REVISION($Revision$)dnl
  28
  29 dnl # The version of the software
  30 RADIUSD_VERSION=`cat VERSION`
  31 RADIUSD_MAJOR_VERSION=`cat VERSION | sed 's/\..*//'`
  32 RADIUSD_MINOR_VERSION=`cat VERSION | sed 's/^2\.//'`
  33 PACKAGE=freeradius
  34
  35 dnl #############################################################
  36 dnl #
  37 dnl #  0. Checks for compiler, libtool, and command line options.
  38 dnl #
  39 dnl #############################################################
  40
  41 dnl Check for GNU cc
  42 AC_PROG_CC
  43 AC_PROG_CXX
  44
  45 dnl #
  46 dnl # check for AIX, to allow us to use some BSD functions
  47 dnl # must be before macros that call the compiler.
  48 dnl #
  49 AC_AIX
  50
  51 AC_PROG_GCC_TRADITIONAL
  52 AC_PROG_CC_SUNPRO
  53 AC_PROG_RANLIB
  54
  55 dnl Compile in large (2G+) file support.
  56 AC_SYS_LARGEFILE
  57
  58 dnl # check for system bytesex
  59 dnl # AC_DEFINES WORDS_BIGENDIAN
  60 AC_C_BIGENDIAN
  61
  62 dnl Find GNU Make.
  63 AC_CHECK_PROG(GMAKE, gmake, yes, no)
  64 if test $GMAKE = no; then
  65   AC_PATH_PROG(MAKE, make, /usr/local/bin/make)
  66 else
  67   AC_PATH_PROG(MAKE, gmake, /usr/local/gnu/bin/make)
  68 fi
  69 makever=`$ac_cv_path_MAKE --version 2>&1 | grep "GNU Make"`
  70 if test -z "$makever"; then
  71   AC_MSG_ERROR(GNU Make is not installed.  Please download and install it
  72                 from ftp://prep.ai.mit.edu/pub/gnu/make/ before continuing.)
  73 fi
  74
  75 dnl libltdl is installable
  76 AC_LIBLTDL_INSTALLABLE
  77
  78 dnl tell Makefile to build ltdl if needed
  79 if test x"$enable_ltdl_install" = x"yes"; then
  80   LTDL_SUBDIRS=libltdl
  81 fi
  82 AC_SUBST(LTDL_SUBDIRS)
  83
  84 dnl use system-wide libtool, if it exists
  85 AC_ARG_WITH(system-libtool,
  86 [  --with-system-libtool              try to use libtool installed in your system [default=use our own]],
  87 [ AC_PATH_PROG(LIBTOOL, libtool,,$PATH:/usr/local/bin) ],
  88 [
  89   LIBTOOL="`pwd`/libtool"
  90   AC_SUBST(LIBTOOL)
  91   dnl ensure that we're looking for dlopen
  92   AC_LIBTOOL_DLOPEN
  93
  94   dnl Figure out how to build shared libraries
  95   AC_PROG_LIBTOOL
  96 ])
  97
  98
  99 dnl Put this in later, when all distributed modules use autoconf.
 100 dnl AC_ARG_WITH(disablemodulefoo,
 101 dnl [  --without-rlm_foo       Disables module compilation.  Module list:]
 102 dnl esyscmd([find src/modules -type d -name rlm_\* -print |\
 103 dnl     sed -e 's%src/modules/.*/% (sub)- %; s%.*/%- %' |\
 104 dnl     awk '{print "                            "$0}']))
 105
 106 AC_ARG_ENABLE(strict-dependencies,
 107 [  --enable-strict-dependencies  Fail configure on lack of module dependancy.])
 108
 109 dnl extra argument: --with-docdir
 110 docdir='${datadir}/doc/freeradius'
 111 AC_MSG_CHECKING(docdir)
 112 AC_ARG_WITH(docdir,
 113 [  --with-docdir=DIR       Directory for documentation [DATADIR/doc/freeradius] ],
 114 [ case "$withval" in
 115     no)
 116         docdir=no
 117         ;;
 118     yes)
 119         ;;
 120     [[\\/$]]* | ?:[[\\/]]* )
 121         docdir="$withval"
 122         ;;
 123     *)
 124         AC_MSG_ERROR([expected an absolute directory name for --with-docdir: $withval])
 125         ;;
 126   esac ]
 127 )
 128 AC_SUBST(docdir)
 129 AC_MSG_RESULT($docdir)
 130 if test "x$docdir" = xno; then
 131         AC_MSG_WARN(Documentation files will NOT be installed.)
 132 fi
 133
 134 dnl extra argument: --with-logdir
 135 logdir='${localstatedir}/log/radius'
 136 AC_MSG_CHECKING(logdir)
 137 AC_ARG_WITH(logdir,
 138 [  --with-logdir=DIR       Directory for logfiles [LOCALSTATEDIR/log/radius] ],
 139 [ case "$withval" in
 140     no)
 141         AC_MSG_ERROR(Need logdir)
 142         ;;
 143     yes)
 144         ;;
 145     [[\\/$]]* | ?:[[\\/]]* )
 146         logdir="$withval"
 147         ;;
 148     *)
 149         AC_MSG_ERROR([expected an absolute directory name for --with-logdir: $withval])
 150         ;;
 151   esac ]
 152 )
 153 AC_SUBST(logdir)
 154 AC_MSG_RESULT($logdir)
 155
 156 dnl extra argument: --with-radacctdir
 157 radacctdir='${logdir}/radacct'
 158 AC_MSG_CHECKING(radacctdir)
 159 AC_ARG_WITH(radacctdir,
 160 [  --with-radacctdir=DIR   Directory for detail files [LOGDIR/radacct] ],
 161 [ case "$withval" in
 162     no)
 163         AC_MSG_ERROR(Need radacctdir)
 164         ;;
 165     yes)
 166         ;;
 167     [[\\/$]]* | ?:[[\\/]]* )
 168         radacctdir="$withval"
 169         ;;
 170     *)
 171         AC_MSG_ERROR([expected an absolute directory name for --with-radacctdir: $withval])
 172         ;;
 173   esac ]
 174 )
 175 AC_SUBST(radacctdir)
 176 AC_MSG_RESULT($radacctdir)
 177
 178 dnl extra argument: --with-raddbdir
 179 raddbdir='${sysconfdir}/raddb'
 180 AC_MSG_CHECKING(raddbdir)
 181 AC_ARG_WITH(raddbdir,
 182 [  --with-raddbdir=DIR     Directory for config files [SYSCONFDIR/raddb] ],
 183 [ case "$withval" in
 184     no)
 185         AC_MSG_ERROR(Need raddbdir)
 186         ;;
 187     yes)
 188         ;;
 189     [[\\/$]]* | ?:[[\\/]]* )
 190         raddbdir="$withval"
 191         ;;
 192     *)
 193         AC_MSG_ERROR([expected an absolute directory name for --with-raddbdir: $withval])
 194         ;;
 195   esac ]
 196 )
 197 AC_SUBST(raddbdir)
 198 AC_MSG_RESULT($raddbdir)
 199
 200 dnl extra argument: --with-ascend-binary
 201 ASCEND_BINARY=yes
 202 AC_ARG_WITH(ascend-binary,
 203 [  --with-ascend-binary    Include support for Ascend binary filter attributes (default=yes)],
 204 [ case "$withval" in
 205     yes)
 206         ;;
 207     *)
 208         ASCEND_BINARY=""
 209   esac ]
 210 )
 211 if test "X$ASCEND_BINARY" = "Xyes"; then
 212   AC_DEFINE(ASCEND_BINARY, [], [Include support for Ascend binary filter attributes])
 213 fi
 214
 215 dnl extra argument: --with-threads
 216 WITH_THREADS=yes
 217 AC_ARG_WITH(threads,
 218 [  --with-threads          Use threads, if available.  (default=yes) ],
 219 [ case "$withval" in
 220     yes)
 221         ;;
 222     *)
 223         WITH_THREADS=""
 224   esac ]
 225 )
 226
 227 dnl extra argument: --with-vmps
 228 WITH_VMPS=yes
 229 AC_ARG_WITH(vmps,
 230 [  --with-vmps             Compile in VMPS support. (default=yes)],
 231 [ case "$withval" in
 232     yes)
 233         ;;
 234     *)
 235         WITH_VMPS=no
 236   esac ]
 237 )
 238 if test "x$WITH_VMPS" = "xyes"; then
 239         AC_DEFINE(WITH_VMPS, [1], [define if you want VMPS support])
 240 fi
 241
 242 dnl extra argument: --with-dhcp
 243 AC_ARG_WITH(dhcp,
 244 [  --with-dhcp             Compile in DHCP support. (default=no)],
 245 [ case "$withval" in
 246     yes)
 247         AC_DEFINE(WITH_DHCP, [1], [Include experimental support for DHCP])
 248         ;;
 249     *)
 250         ;;
 251   esac ]
 252 )
 253
 254
 255 dnl #
 256 dnl #  Allow the user to specify a list of modules to be linked
 257 dnl #  statically to the server.
 258 dnl #
 259 STATIC_MODULES=
 260 AC_ARG_WITH(static_modules,
 261 [  --with-static-modules=QUOTED-MODULE-LIST],[
 262   for i in $withval; do
 263     STATIC_MODULES="$STATIC_MODULES -dlpreopen ../modules/rlm_$i/rlm_$i.la"
 264   done
 265 ])
 266
 267 MODULES=
 268 AC_ARG_WITH(modules,
 269 [ --with-modules=QUOTED-MODULE-LIST],[
 270  for i in $withval; do
 271    MODULES="$MODULES $i"
 272  done
 273 ])
 274
 275 dnl #
 276 dnl #  Enable developer C compiler warnings
 277 dnl #
 278 AC_ARG_ENABLE(developer,
 279 [  --enable-developer               Enables features of interest to developers.],
 280 [ case "$enableval" in
 281     no)
 282         developer=no
 283         ;;
 284     *)
 285         developer=yes
 286   esac ]
 287 )
 288
 289 if test "x$developer" != "xno" -a -d $srcdir/CVS; then
 290   dnl turn on the developer flag when taken from a CVS checkout (not a release)
 291   developer="yes"
 292 fi
 293
 294 if test "x$developer" != "xno" -a -d $srcdir/.git; then
 295   dnl turn on the developer flag when taken from a git checkout (not a release)
 296   developer="yes"
 297 fi
 298
 299 dnl extra argument: --with-experimental-modules
 300 EXPERIMENTAL=
 301 AC_ARG_WITH(experimental-modules,
 302 [  --with-experimental-modules      Use experimental and unstable modules. (default=no) ],
 303 [ case "$withval" in
 304     yes)
 305         EXPERIMENTAL=yes
 306         ;;
 307     *)
 308   esac ]
 309 )
 310
 311 dnl extra argument: --with-openssl
 312 WITH_OPENSSL=yes
 313 AC_ARG_WITH(openssl,
 314 [  --with-openssl                   Use OpenSSL. (default=yes)],
 315 [ case "$withval" in
 316     no)
 317         WITH_OPENSSL=no
 318         ;;
 319     *)
 320         WITH_OPENSSL=yes
 321         ;;
 322   esac ]
 323 )
 324
 325 dnl #
 326 dnl # extra argument: --with-openssl-includes=dir
 327 dnl #
 328 OPENSSL_INCLUDE_DIR=
 329 AC_ARG_WITH(openssl-includes,
 330 [  --with-openssl-includes=DIR      Directory to look for OpenSSL include files],
 331 [ case "$withval" in
 332     *) OPENSSL_INCLUDE_DIR="$withval"
 333         ;;
 334   esac ]
 335 )
 336
 337 dnl #
 338 dnl # extra argument: --with-openssl-libraries=dir
 339 dnl #
 340 OPENSSL_LIB_DIR=
 341 AC_ARG_WITH(openssl-libraries,
 342 [  --with-openssl-libraries=DIR     Directory to look for OpenSSL library files],
 343 [ case "$withval" in
 344     *) OPENSSL_LIB_DIR="$withval"
 345         ;;
 346   esac ]
 347 )
 348
 349 dnl #
 350 dnl #  These next two arguments don't actually do anything.  They're
 351 dnl #  place holders so that the top-level configure script can tell
 352 dnl #  the user how to configure lower-level modules
 353 dnl #
 354
 355 dnl #
 356 dnl # extra argument: --with-rlm-FOO-lib-dir
 357 dnl #
 358 AC_ARG_WITH(rlm-FOO-lib-dir,
 359 [  --with-rlm-FOO-lib-dir=DIR       Directory to look for library files used by module FOO],
 360 [ case "$withval" in
 361     *)
 362         ;;
 363   esac ]
 364 )
 365
 366 dnl #
 367 dnl # extra argument: --with-rlm-FOO-include-dir
 368 dnl #
 369 AC_ARG_WITH(rlm-FOO-include-dir,
 370 [  --with-rlm-FOO-include-dir=DIR   Directory to look for include files used by module FOO],
 371 [ case "$withval" in
 372     *)
 373         ;;
 374   esac ]
 375 )
 376
 377 dnl See what include-style is used by the make program.
 378 dnl AC_MSG_CHECKING(include style for make)
 379 dnl echo "include /dev/null" > testmake.$$
 380 dnl echo "all:" >> testmake.$$
 381 dnl make -f testmake.$$ >/dev/null 2>&1
 382 dnl if test $? = 0
 383 dnl then
 384 dnl     INCLUDE=include
 385 dnl     IQUOTE=
 386 dnl else
 387 dnl     INCLUDE=.include
 388 dnl     IQUOTE='"'
 389 dnl fi
 390 dnl rm -f testmake.$$
 391 dnl AC_MSG_RESULT(" $INCLUDE")
 392 dnl AC_SUBST(INCLUDE)
 393 dnl AC_SUBST(IQUOTE)
 394
 395 dnl extra argument: --with-udpfromto
 396 WITH_UDPFROMTO=no
 397 AC_ARG_WITH(udpfromto,
 398 [  --with-udpfromto        Compile in UDPFROMTO support. (default=no)],
 399 [ case "$withval" in
 400     yes)
 401         WITH_UDPFROMTO=yes
 402         ;;
 403     *)
 404         WITH_UDPFROMTO=no
 405   esac ]
 406 )
 407
 408 if test "x$WITH_UDPFROMTO" = "xyes"; then
 409         AC_DEFINE(WITH_UDPFROMTO, [], [define if you want udpfromto])
 410 fi
 411
 412 dnl #############################################################
 413 dnl #
 414 dnl #  1. Checks for programs
 415 dnl #
 416 dnl #############################################################
 417
 418 CHECKRAD=checkrad.pl
 419 AC_PATH_PROG(PERL, perl, /usr/local/bin/perl)
 420 if test "x$ac_cv_path_PERL" = "x"; then
 421   AC_MSG_WARN(perl not found - Simultaneous-Use and checkrad.pl may not work)
 422 fi
 423 AC_PATH_PROG(SNMPGET, snmpget)
 424 if test "x$ac_cv_path_SNMPGET" = "x"; then
 425   AC_MSG_WARN(snmpget not found - Simultaneous-Use and checkrad.pl may not work)
 426 fi
 427
 428 AC_PATH_PROG(SNMPWALK, snmpwalk)
 429 if test "x$ac_cv_path_SNMPWALK" = "x"; then
 430   AC_MSG_WARN(snmpwalk not found - Simultaneous-Use and checkrad.pl may not work)
 431 fi
 432
 433 AC_PATH_PROG(RUSERS, rusers, /usr/bin/rusers)
 434
 435 dnl FIXME This is truly gross.
 436 missing_dir=`cd $ac_aux_dir && pwd`
 437 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
 438 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
 439 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
 440
 441 AC_PATH_PROG(LOCATE,locate)
 442 AC_PATH_PROG(DIRNAME,dirname)
 443 AC_PATH_PROG(GREP,grep)
 444
 445 dnl #############################################################
 446 dnl #
 447 dnl #  2. Checks for libraries
 448 dnl #
 449 dnl #############################################################
 450
 451 dnl If using pthreads, check for -lpthread (posix) or -lc_r (*BSD)
 452 old_CFLAGS=$CFLAGS
 453 if test "x$WITH_THREADS" = "xyes"; then
 454   if test $ac_cv_prog_suncc = "yes"; then
 455     CFLAGS="$CFLAGS -mt"
 456   fi
 457
 458   AC_CHECK_HEADERS(pthread.h, [], [ WITH_THREADS="no" ])
 459
 460 dnl #
 461 dnl # pthread stuff is usually in -lpthread
 462 dnl # or in -lc_r, on *BSD
 463 dnl #
 464 dnl # On Some systems, we need extra pre-processor flags, to get them to
 465 dnl # to do the threading properly.
 466 dnl #
 467   AC_CHECK_LIB(pthread, pthread_create,
 468                 [ CFLAGS="$CFLAGS -D_REENTRANT -D_POSIX_PTHREAD_SEMANTICS"
 469                   LIBS="$LIBS -lpthread" ],
 470                 AC_CHECK_LIB(c_r, pthread_create,
 471                             [ CFLAGS="$CFLAGS -pthread -D_THREAD_SAFE" ],
 472                             [ WITH_THREADS="no" ]
 473                             )
 474                 )
 475 fi
 476
 477 dnl #
 478 dnl # If we have NO pthread libraries, remove any knowledge of threads.
 479 dnl #
 480 if test "x$WITH_THREADS" != "xyes"; then
 481   CFLAGS=$old_CFLAGS
 482   ac_cv_header_pthread_h="no"
 483   WITH_THREADS=no
 484 else
 485   dnl #
 486   dnl #  We need sem_init() and friends, as they're the friendliest
 487   dnl #  semaphore functions for threading.
 488   dnl #
 489   dnl # HP/UX requires linking with librt, too, to get the sem_* symbols.
 490   dnl # Some systems have them in -lsem
 491   dnl # Solaris has them in -lposix4
 492   dnl # NetBSD has them in -lsemaphore
 493
 494   AC_SEARCH_LIBS(sem_init, pthread sem posix4 rt semaphore,
 495         [],
 496         [AC_MSG_ERROR(-lsem not found.  You may want to download it from ftp://ftp.to.gd-es.com/pub/BSDI/libsem.tar.bz2 or ftp://ftp.freeradius.org/pub/radius/contrib/libsem.tar.gz)]
 497    )
 498 fi
 499
 500 dnl Check if we need -lsocket
 501 AC_CHECK_LIB(socket, getsockname)
 502
 503 dnl Check for -lresolv
 504 dnl This library may be needed later.
 505 AC_CHECK_LIB(resolv, inet_aton)
 506
 507 dnl Check if we need -lnsl. Usually if we want to
 508 dnl link against -lsocket we need to include -lnsl as well.
 509 AC_CHECK_LIB(nsl, inet_ntoa)
 510
 511 dnl Check for OpenSSL libraries.
 512 OPENSSL_LIBS=
 513 if test "x$WITH_OPENSSL" = xyes; then
 514   old_LIBS=$LIBS
 515   if test "x$OPENSSL_LIB_DIR" != "x"; then
 516     LIBS="-L$OPENSSL_LIB_DIR $LIBS"
 517   fi
 518   AC_CHECK_LIB(crypto, DH_new,
 519     [
 520         LIBS="-lcrypto $LIBS"
 521         AC_DEFINE(HAVE_LIBCRYPTO, 1,
 522             [Define to 1 if you have the `crypto' library (-lcrypto).])
 523         AC_CHECK_LIB(ssl, SSL_new,
 524             [
 525                 AC_DEFINE(HAVE_LIBSSL, 1,
 526                     [Define to 1 if you have the `ssl' library (-lssl).])
 527                 if test "x$OPENSSL_LIB_DIR" != "x"; then
 528                     OPENSSL_LIBS="-L$OPENSSL_LIB_DIR"
 529                 fi
 530                 OPENSSL_LIBS="$OPENSSL_LIBS -lcrypto -lssl -lcrypto"
 531             ], [])
 532     ], [])
 533   LIBS=$old_LIBS
 534 fi
 535
 536 AC_CHECK_LIB(ws2_32, htonl)
 537
 538 dnl Check the pcap library for the RADIUS sniffer.
 539 PCAP_LIBS=
 540 AC_CHECK_LIB(pcap, pcap_open_live,
 541         [ PCAP_LIBS="-lpcap"
 542         AC_DEFINE(HAVE_LIBPCAP, 1,
 543                 [Define to 1 if you have the `pcap' library (-lpcap).])
 544         ],
 545         [ AC_MSG_WARN([pcap library not found, silently disabling the RADIUS sniffer.]) ])
 546
 547 AC_CHECK_LIB(readline, readline,
 548         [ LIBREADLINE="-lreadline" AC_SUBST(LIBREADLINE) ])
 549
 550 dnl #############################################################
 551 dnl #
 552 dnl #  3. Checks for header files
 553 dnl #
 554 dnl #############################################################
 555
 556 dnl #
 557 dnl # Interix requires us to set -D_ALL_SOURCE, otherwise
 558 dnl # getopt will be #included, but won't link.  <sigh>
 559 dnl #
 560 dnl #
 561 case "$host" in
 562 *-interix*)
 563         CFLAGS="$CFLAGS -D_ALL_SOURCE"
 564         ;;
 565 *-darwin*)
 566         CFLAGS="$CFLAGS -DDARWIN"
 567         LIBS="-framework DirectoryService $LIBS"
 568         ;;
 569 esac
 570
 571 AC_HEADER_DIRENT
 572 AC_HEADER_STDC
 573 AC_HEADER_TIME
 574 AC_HEADER_SYS_WAIT
 575
 576 AC_CHECK_HEADERS( \
 577         unistd.h \
 578         crypt.h \
 579         errno.h \
 580         resource.h \
 581         sys/resource.h \
 582         getopt.h \
 583         malloc.h \
 584         utmp.h \
 585         utmpx.h \
 586         signal.h \
 587         sys/select.h \
 588         syslog.h \
 589         inttypes.h \
 590         stdint.h \
 591         stdio.h \
 592         netdb.h \
 593         semaphore.h \
 594         arpa/inet.h \
 595         netinet/in.h \
 596         sys/types.h \
 597         sys/socket.h \
 598         winsock.h \
 599         sys/time.h \
 600         sys/wait.h \
 601         sys/security.h \
 602         fcntl.h \
 603         sys/fcntl.h \
 604         sys/prctl.h \
 605         sys/un.h \
 606         readline/readline.h \
 607         glob.h \
 608         prot.h \
 609         pwd.h \
 610         grp.h \
 611         sia.h \
 612         siad.h
 613 )
 614
 615 dnl FreeBSD requires sys/socket.h before net/if.h
 616 AC_CHECK_HEADERS(net/if.h, [], [],
 617 [#ifdef HAVE_SYS_SOCKET_H
 618 # include <sys/socket.h>
 619 # endif
 620 ])
 621
 622 REGEX=no
 623 AC_CHECK_HEADER(regex.h, AC_DEFINE(HAVE_REGEX_H, [], [define this if we have the <regex.h> header file]))
 624 if test "x$ac_cv_header_regex_h" = "xyes"; then
 625   REGEX_EXTENDED=no
 626   REGEX=yes
 627   AC_EGREP_CPP(yes,
 628     [#include <regex.h>
 629      #ifdef REG_EXTENDED
 630        yes
 631      #endif
 632      ], [AC_DEFINE(HAVE_REG_EXTENDED, [], [define this if we have REG_EXTENDED (from <regex.h>)]) REGEX_EXTENDED=yes])
 633 fi
 634 AC_SUBST(REGEX)
 635 AC_SUBST(REGEX_EXTENDED)
 636
 637 dnl #
 638 dnl #  other checks which require headers
 639 dnl #
 640 if test "x$ac_cv_header_sys_security_h" = "xyes" && test "x$ac_cv_header_prot_h" = "xyes"
 641 then
 642   AC_DEFINE(OSFC2, [], [define if you have OSFC2 authentication])
 643 fi
 644
 645 if test "x$ac_cv_header_sia_h" = "xyes" && test "x$ac_cv_header_siad_h" = "xyes"
 646 then
 647   AC_DEFINE(OSFSIA, [], [define if you have OSFSIA authentication])
 648 fi
 649
 650 dnl Check for OpenSSL includes.
 651 OPENSSL_INCLUDE="-DNO_OPENSSL"
 652 if test "x$WITH_OPENSSL" = xyes; then
 653   if test "x$OPENSSL_LIBS" = "x"; then
 654     AC_MSG_NOTICE([skipping test for openssl/ssl.h])
 655   else
 656     old_CPPFLAGS=$CPPFLAGS
 657     if test "x$OPENSSL_INCLUDE_DIR" != "x"; then
 658         CPPFLAGS="$CPPFLAGS -I$OPENSSL_INCLUDE_DIR"
 659     fi
 660     dnl # stupid RedHat shit
 661     CPPFLAGS="$CPPFLAGS -DOPENSSL_NO_KRB5"
 662     AC_CHECK_HEADERS( \
 663         openssl/ssl.h \
 664         openssl/crypto.h \
 665         openssl/err.h \
 666         openssl/evp.h \
 667         openssl/engine.h,
 668         [],
 669         OPENSSL_LIBS=
 670     )
 671     if test "x$OPENSSL_LIBS" != "x"; then
 672         AC_MSG_CHECKING([for OpenSSL version >= 0.9.7])
 673         AC_EGREP_CPP(yes,
 674             [#include <openssl/crypto.h>
 675              #if (OPENSSL_VERSION_NUMBER >= 0x00907000L)
 676              yes
 677              #endif
 678             ], goodssl="yes")
 679         if test "x$goodssl" != "xyes"; then
 680             AC_MSG_RESULT(no)
 681             OPENSSL_LIBS=
 682         else
 683             AC_MSG_RESULT(yes)
 684             if test "x$OPENSSL_INCLUDE_DIR" != "x"; then
 685                 OPENSSL_INCLUDE="-I$OPENSSL_INCLUDE_DIR -DOPENSSL_NO_KRB5"
 686             else
 687                 OPENSSL_INCLUDE="-DOPENSSL_NO_KRB5"
 688             fi
 689         fi
 690     fi
 691     CPPFLAGS=$old_CPPFLAGS
 692   fi
 693 fi
 694 AC_SUBST(OPENSSL_INCLUDE)
 695 AC_SUBST(OPENSSL_LIBS)
 696 export OPENSSL_LIBS
 697
 698 dnl Check the pcap includes for the RADIUS sniffer.
 699 if test "x$PCAP_LIBS" = x; then
 700     AC_MSG_NOTICE([skipping test for pcap.h.])
 701 else
 702     AC_CHECK_HEADER(pcap.h,
 703         AC_DEFINE(HAVE_PCAP_H, 1,
 704                 [Define to 1 if you have the <pcap.h> header file.]),
 705         [ PCAP_LIBS=
 706         AC_MSG_WARN([pcap.h not found, silently disabling the RADIUS sniffer.])
 707         ])
 708 fi
 709 AC_SUBST(PCAP_LIBS)
 710
 711 dnl #############################################################
 712 dnl #
 713 dnl #  4. Checks for typedefs
 714 dnl #
 715 dnl #############################################################
 716
 717 dnl #
 718 dnl # Ensure that these are defined
 719 dnl #
 720 AC_TYPE_OFF_T
 721 AC_TYPE_PID_T
 722 AC_TYPE_SIZE_T
 723 AC_TYPE_UID_T
 724
 725 dnl check for socklen_t
 726 FR_CHECK_TYPE_INCLUDE([
 727 #ifdef HAVE_SYS_TYPES_H
 728 #include <sys/types.h>
 729 #endif
 730 #ifdef HAVE_SYS_SOCKET_H
 731 #include <sys/socket.h>
 732 #endif
 733 ],socklen_t, int, [socklen_t is generally 'int' on systems which don't use it])
 734
 735 dnl check for uint8_t
 736 FR_CHECK_TYPE_INCLUDE([
 737 #ifdef HAVE_INTTYPES_H
 738 #include <inttypes.h>
 739 #endif
 740 #ifdef HAVE_STDINT_H
 741 #include <stdint.h>
 742 #endif
 743 ],uint8_t, unsigned char, [uint8_t should be the canonical 'octet' for network traffic])
 744
 745 dnl check for uint16_t
 746 FR_CHECK_TYPE_INCLUDE([
 747 #ifdef HAVE_INTTYPES_H
 748 #include <inttypes.h>
 749 #endif
 750 #ifdef HAVE_STDINT_H
 751 #include <stdint.h>
 752 #endif
 753 ],uint16_t, unsigned short, [uint16_t should be the canonical '2 octets' for network traffic])
 754
 755 dnl check for uint32_t
 756 FR_CHECK_TYPE_INCLUDE([
 757 #ifdef HAVE_INTTYPES_H
 758 #include <inttypes.h>
 759 #endif
 760 #ifdef HAVE_STDINT_H
 761 #include <stdint.h>
 762 #endif
 763 ],uint32_t, unsigned int, [uint32_t should be the canonical 'network integer])
 764
 765 AC_CHECK_TYPE(struct in6_addr, AC_DEFINE(HAVE_STRUCT_IN6_ADDR, 1, [IPv6 address structure]), [], [
 766 #ifdef HAVE_NETINET_IN_H
 767 #include <netinet/in.h>
 768 #endif
 769 ])
 770
 771 AC_CHECK_TYPE(struct sockaddr_storage, AC_DEFINE(HAVE_STRUCT_SOCKADDR_STORAGE, 1, [Generic socket addresses]), [], [
 772 #ifdef HAVE_NETINET_IN_H
 773 #include <netinet/in.h>
 774 #endif
 775 #ifdef HAVE_SYS_SOCKET_H
 776 #include <sys/socket.h>
 777 #endif
 778 ])
 779
 780 AC_CHECK_TYPE(struct sockaddr_in6, AC_DEFINE(HAVE_STRUCT_SOCKADDR_IN6, 1, [IPv6 socket addresses]), [], [
 781 #ifdef HAVE_NETINET_IN_H
 782 #include <netinet/in.h>
 783 #endif
 784 ])
 785
 786 AC_CHECK_TYPE(struct addrinfo, AC_DEFINE(HAVE_STRUCT_ADDRINFO, 1, [Generic DNS lookups]), [], [
 787 #ifdef HAVE_SYS_TYPES_H
 788 #include <sys/types.h>
 789 #endif
 790 #ifdef HAVE_SYS_SOCKET_H
 791 #include <sys/socket.h>
 792 #endif
 793 #ifdef HAVE_NETDB_H
 794 #include <netdb.h>
 795 #endif
 796 ])
 797
 798 dnl #############################################################
 799 dnl #
 800 dnl #  5. Checks for structures and functions
 801 dnl #
 802 dnl #############################################################
 803 AC_CHECK_FUNCS( \
 804         getopt_long \
 805         lockf \
 806         strsignal \
 807         sigaction \
 808         sigprocmask \
 809         pthread_sigmask \
 810         snprintf \
 811         vsnprintf \
 812         setsid \
 813         strncasecmp \
 814         strcasecmp \
 815         localtime_r \
 816         ctime_r \
 817         gmtime_r \
 818         strsep \
 819         inet_aton \
 820         inet_pton \
 821         inet_ntop \
 822         setlinebuf \
 823         setvbuf \
 824         getusershell \
 825         initgroups \
 826         getaddrinfo \
 827         getnameinfo \
 828         closefrom \
 829         gettimeofday \
 830         getpeereid \
 831         strlcat \
 832         strlcpy
 833 )
 834 RADIUSD_NEED_DECLARATIONS( \
 835         crypt \
 836         strncasecmp \
 837         strcasecmp \
 838         inet_aton \
 839         setlinebuf \
 840         getusershell \
 841         endusershell
 842 )
 843
 844 AC_TYPE_SIGNAL
 845
 846 dnl # check if we have utmpx.h
 847 dnl # if so, check if struct utmpx has entry ut_xtime
 848 dnl # if not, set it to define ut_xtime == ut_tv.tv_sec
 849 if test "x$ac_cv_header_utmpx_h" = "xyes"
 850 then
 851  FR_CHECK_STRUCT_HAS_MEMBER([#include <utmpx.h>], [struct utmpx], ut_xtime)
 852  if test "x$ac_cv_type_struct_utmpx_has_ut_xtime" = "x"
 853  then
 854    AC_DEFINE(ut_xtime,ut_tv.tv_sec, [define to something if you don't have ut_xtime in struct utmpx])
 855  fi
 856 fi
 857
 858 dnl # struct ip_pktinfo
 859 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in_pktinfo], ipi_addr)
 860 if test "x$ac_cv_type_struct_in_pktinfo_has_ipi_addr" = "xyes"
 861 then
 862         AC_DEFINE(HAVE_IP_PKTINFO, [], [define if you have IP_PKTINFO (Linux)])
 863 fi
 864
 865 dnl # struct in6_pktinfo
 866 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in6_pktinfo], ipi6_addr)
 867 if test "x$ac_cv_type_struct_in6_pktinfo_has_ipi6_addr" = "xyes"
 868 then
 869         AC_DEFINE(HAVE_IN6_PKTINFO, [], [define if you have IN6_PKTINFO (Linux)])
 870 fi
 871
 872 dnl #############################################################
 873 dnl #
 874 dnl #  6. Checks for compiler characteristics
 875 dnl #
 876 dnl #############################################################
 877
 878 dnl #
 879 dnl # Ensure that these are defined
 880 dnl #
 881 AC_C_CONST
 882
 883 dnl #
 884 dnl # See if this is OS/2
 885 dnl #
 886 AC_MSG_CHECKING(type of OS)
 887 OS=`uname -s`
 888 AC_MSG_RESULT($OS)
 889 if test "$OS" = "OS/2"; then
 890         LIBPREFIX=
 891 else
 892         LIBPREFIX=lib
 893 fi
 894 AC_SUBST(LIBPREFIX)
 895
 896 dnl #
 897 dnl # Set Default CFLAGS
 898 dnl #
 899 if test "x$GCC" = "xyes"; then
 900     CFLAGS="$CFLAGS -Wall -D_GNU_SOURCE"
 901 fi
 902
 903 AC_MSG_CHECKING(for developer gcc flags)
 904 if test "x$developer" = "xyes" -a "x$GCC" = "xyes"; then
 905   devflags="-g -Wshadow -Wpointer-arith -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -W -Wredundant-decls -Wundef"
 906   CFLAGS="$CFLAGS $devflags"
 907   INSTALLSTRIP=""
 908   AC_MSG_RESULT(yes.  Using $devflags)
 909 else
 910   devflags=""
 911   CFLAGS="$CFLAGS -DNDEBUG"
 912   INSTALLSTRIP=""
 913   AC_MSG_RESULT(no.)
 914 fi
 915
 916 FR_TLS
 917
 918 dnl #############################################################
 919 dnl #
 920 dnl #  7. Checks for library functions
 921 dnl #
 922 dnl #############################################################
 923
 924 dnl Check for libcrypt
 925 dnl We use crypt(3) which may be in libc, or in libcrypt (eg FreeBSD)
 926 AC_CHECK_LIB(crypt, crypt,
 927   CRYPTLIB="-lcrypt"
 928 )
 929 if test "$CRYPTLIB" != ""; then
 930   AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function])
 931 else
 932   AC_CHECK_FUNC(crypt, AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function]))
 933 fi
 934
 935 dnl Check for libcipher
 936 AC_CHECK_LIB(cipher, setkey,
 937    CRYPTLIB="${CRYPTLIB} -lcipher"
 938 )
 939 AC_SUBST(CRYPTLIB)
 940
 941 dnl Check the style of gethostbyaddr, in order of preference
 942 dnl GNU (_r eight args)
 943 AC_DEFINE(GNUSTYLE, [1], [GNU-Style get*byaddr_r])
 944 dnl SYSV (_r six args)
 945 AC_DEFINE(SYSVSTYLE, [2], [SYSV-Style get*byaddr_r])
 946 dnl BSD (three args, may not be thread safe)
 947 AC_DEFINE(BSDSTYLE, [3], [BSD-Style get*byaddr_r])
 948 dnl Tru64 has BSD version, but it is thread safe
 949 dnl     http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1739____.HTM
 950 dnl We need #stdio.h to define NULL on FreeBSD (at least)
 951 gethostbyaddrrstyle=""
 952 AC_MSG_CHECKING([gethostbyaddr_r() syntax])
 953 case "$host" in
 954 *-freebsd*)
 955 dnl With FreeBSD, check if there's a prototype for gethostbyaddr_r.
 956 dnl Some versions (FreeBSD 5.1?) have a symbol but no prototype - so we
 957 dnl override this test to BSDSTYLE. FreeBSD 6.2 and up have proper GNU
 958 dnl style support.
 959         AC_CHECK_DECLS([gethostbyaddr_r], [], [
 960                 AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE,
 961                         [style of gethostbyaddr_r functions ])
 962                 gethostbyaddrrstyle=BSD
 963                 AC_MSG_WARN([FreeBSD overridden to BSD-style])
 964         ], [
 965 #ifdef HAVE_NETDB_H
 966 #include <netdb.h>
 967 #endif
 968 ])
 969         ;;
 970 esac
 971 if test "x$gethostbyaddrrstyle" = "x"; then
 972         AC_TRY_LINK([
 973 #include <stdio.h>
 974 #include <netdb.h>
 975 ], [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL, NULL) ], [
 976         AC_DEFINE(GETHOSTBYADDRRSTYLE, GNUSTYLE, [style of gethostbyaddr_r functions ])
 977         gethostbyaddrrstyle=GNU
 978 ])
 979 fi
 980 if test "x$gethostbyaddrrstyle" = "x"; then
 981         AC_TRY_LINK([
 982 #include <stdio.h>
 983 #include <netdb.h>
 984 ], [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL) ] , [
 985                 AC_DEFINE(GETHOSTBYADDRRSTYLE, SYSVSTYLE, [style of gethostbyaddr_r functions ])
 986                 gethostbyaddrrstyle=SYSV
 987         ])
 988 fi
 989 if test "x$gethostbyaddrrstyle" = "x"; then
 990         AC_TRY_LINK([
 991 #include <stdio.h>
 992 #include <netdb.h>
 993 ], [ gethostbyaddr(NULL, 0, 0)  ], [
 994                 AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE, [style of gethostbyaddr_r functions ])
 995                 gethostbyaddrrstyle=BSD
 996         ])
 997 fi
 998
 999 if test "x$gethostbyaddrrstyle" = "x"; then
1000         AC_MSG_RESULT([none!  It must not exist, here.])
1001 else
1002         AC_MSG_RESULT([${gethostbyaddrrstyle}-style])
1003 fi
1004
1005 if test "x$gethostbyaddrrstyle" = "xBSD"; then
1006         AC_MSG_WARN([ ****** BSD-style gethostbyaddr might NOT be thread-safe! ****** ])
1007 fi
1008
1009 dnl Check the style of gethostbyname, in order of preference
1010 dnl GNU (_r seven args)
1011 dnl SYSV (_r five args)
1012 dnl BSD (two args, may not be thread safe)
1013 dnl Tru64 has BSD version, but it _is_ thread safe
1014 dnl     http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1946____.HTM
1015 dnl We need #stdio.h to define NULL on FreeBSD (at least)
1016 gethostbynamerstyle=""
1017 AC_MSG_CHECKING([gethostbyname_r() syntax])
1018 AC_TRY_LINK([
1019 #include <stdio.h>
1020 #include <netdb.h>
1021 ], [ gethostbyname_r(NULL, NULL, NULL, 0, NULL, NULL) ], [
1022         AC_DEFINE(GETHOSTBYNAMERSTYLE, GNUSTYLE, [style of gethostbyname_r functions ])
1023         gethostbynamerstyle=GNU
1024 ])
1025 if test "x$gethostbynamerstyle" = "x"; then
1026         AC_TRY_LINK([
1027 #include <stdio.h>
1028 #include <netdb.h>
1029 ], [ gethostbyname_r(NULL, NULL, NULL, 0, NULL) ] , [
1030                 AC_DEFINE(GETHOSTBYNAMERSTYLE, SYSVSTYLE, [style of gethostbyname_r functions ])
1031                 gethostbynamerstyle=SYSV
1032         ])
1033 fi
1034 if test "x$gethostbynamerstyle" = "x"; then
1035         AC_TRY_LINK([
1036 #include <stdio.h>
1037 #include <netdb.h>
1038 ], [ gethostbyname(NULL)  ], [
1039                 AC_DEFINE(GETHOSTBYNAMERSTYLE, BSDSTYLE, [style of gethostbyname_r functions ])
1040                 gethostbynamerstyle=BSD
1041         ])
1042 fi
1043
1044 if test "x$gethostbynamerstyle" = "x"; then
1045         AC_MSG_RESULT([none!  It must not exist, here.])
1046 else
1047         AC_MSG_RESULT([${gethostbynamerstyle}-style])
1048 fi
1049
1050 if test "x$gethostbynamerstyle" = "xBSD"; then
1051         AC_MSG_WARN([ ****** BSD-style gethostbyname might NOT be thread-safe! ****** ])
1052 fi
1053
1054 dnl check for non-posix solaris ctime_r (extra buflen int arg)
1055 AC_DEFINE(POSIXSTYLE, [1], [Posix-Style ctime_r])
1056 AC_DEFINE(SOLARISSTYLE, [2], [Solaris-Style ctime_r])
1057 ctimerstyle=""
1058 AC_MSG_CHECKING([ctime_r() syntax])
1059 AC_TRY_LINK([
1060 #include <time.h>
1061 ], [ ctime_r(NULL, NULL, 0) ], [
1062         AC_DEFINE(CTIMERSTYLE, SOLARISSTYLE, [style of ctime_r function])
1063         ctimerstyle="SOLARIS"
1064 ])
1065 if test "x$ctimerstyle" = "x"; then
1066         AC_TRY_LINK([
1067 #include <time.h>
1068 ], [ ctime_r(NULL, NULL) ], [
1069                 AC_DEFINE(CTIMERSTYLE, POSIXSTYLE, [style of ctime_r function])
1070                 ctimerstyle="POSIX"
1071         ])
1072 fi
1073
1074 if test "x$ctimerstyle" = "x"; then
1075         AC_MSG_RESULT([none!  It must not exist, here.])
1076 else
1077         AC_MSG_RESULT([${ctimerstyle}-style])
1078 fi
1079
1080 AC_SUBST(HOSTINFO, $host)
1081
1082 dnl #############################################################
1083 dnl #
1084 dnl #  8. Checks for system services
1085 dnl #
1086 dnl #############################################################
1087
1088 dnl #
1089 dnl # Figure out where libtool is located,
1090 dnl #
1091 top_builddir=`pwd`
1092 export top_builddir
1093 AC_MSG_RESULT([top_builddir=$top_builddir])
1094 dnl # AC_SUBST(top_builddir)
1095 AC_SUBST(LIBLTDL)
1096 AC_SUBST(INCLTDL)
1097
1098 dnl import libtool stuff
1099
1100 dnl #############################################################
1101 dnl #
1102 dnl #  Configure in any module directories.
1103 dnl #
1104 dnl #############################################################
1105
1106 mysubdirs="$LIBLTDLPATH"
1107 if test "x$EXPERIMENTAL" = "xyes"; then
1108   bar=`ls -1 "${srcdir}"/src/modules/rlm_*/configure | sed 's%/configure%%'`
1109   dnl # get rid of LF's.
1110   mysubdirs=`echo $mysubdirs $bar`
1111 else
1112   dnl #
1113   dnl # Find 'configure' in ONLY the stable modules
1114   dnl #
1115   for bar in `cat "${srcdir}"/src/modules/stable`; do
1116     if test -f "${srcdir}"/src/modules/$bar/configure; then
1117       mysubdirs="$mysubdirs src/modules/$bar"
1118     fi
1119   done
1120 fi
1121
1122 dnl ############################################################
1123 dnl # make modules by list
1124 dnl #############################################################
1125 if test "x$EXPERIMENTAL" = "xyes"; then
1126   for foo in `ls -1 "${srcdir}"/src/modules | grep rlm_`; do
1127     MODULES="$MODULES $foo"
1128   done
1129 else
1130    dnl #
1131    dnl # make ONLY the stable modules
1132    dnl #
1133    for foo in `cat "${srcdir}"/src/modules/stable`; do
1134     MODULES="$MODULES $foo"
1135    done
1136 fi
1137
1138 dnl #
1139 dnl #  Don't change the variable name here.  Autoconf goes bonkers
1140 dnl #  if you do.
1141 dnl #
1142 AC_CONFIG_SUBDIRS($LTDL_SUBDIRS $mysubdirs)
1143 AC_SUBST(MODULES)
1144
1145 dnl #############################################################
1146 dnl #
1147 dnl #  And finally, output the results.
1148 dnl #
1149 dnl #############################################################
1150
1151 AC_CONFIG_COMMANDS([stamp-h], [echo timestamp > src/include/stamp-h])
1152 AC_CONFIG_COMMANDS([build-radpaths-h], [(cd ./src/include && /bin/sh ./build-radpaths-h)])
1153 AC_CONFIG_COMMANDS([main-chmod], [(cd ./src/main   && chmod +x checkrad.pl radlast radtest)])
1154 AC_CONFIG_COMMANDS([scripts-chmod], [(cd ./scripts    && chmod +x rc.radiusd radwatch radiusd.cron.daily radiusd.cron.monthly cryptpasswd)])
1155
1156 dnl #
1157 dnl #  Substitute whatever libraries we found to be necessary
1158 dnl #
1159 AC_SUBST(LIBS)
1160 AC_SUBST(INSTALLSTRIP)
1161
1162 USE_SHARED_LIBS=$enable_shared
1163 AC_SUBST(USE_SHARED_LIBS)
1164 USE_STATIC_LIBS=$enable_static
1165 AC_SUBST(USE_STATIC_LIBS)
1166 AC_SUBST(STATIC_MODULES)
1167 AC_SUBST(RADIUSD_MAJOR_VERSION)
1168 AC_SUBST(RADIUSD_MINOR_VERSION)
1169 AC_SUBST(RADIUSD_VERSION)
1170
1171 AC_OUTPUT(\
1172         ./Make.inc \
1173         ./src/include/build-radpaths-h \
1174         ./src/main/Makefile \
1175         ./src/main/checkrad.pl \
1176         ./src/main/radlast \
1177         ./src/main/radtest \
1178         ./scripts/rc.radiusd \
1179         ./scripts/radwatch \
1180         ./scripts/radiusd.cron.daily \
1181         ./scripts/radiusd.cron.monthly \
1182         ./scripts/cryptpasswd \
1183         ./raddb/dictionary \
1184         ./raddb/radiusd.conf
1185 )