configure.in

   1 dnl #############################################################
   2 dnl #
   3 dnl #  For information about autoconf, see:
   4 dnl #
   5 dnl #  http://www.gnu.org/software/autoconf/
   6 dnl #
   7 dnl #  The recommended order is:
   8 dnl #
   9 dnl #  AC_INIT(file)
  10 dnl #  0. checks for compiler, libtool, and command line options
  11 dnl #  1. checks for programs
  12 dnl #  2. checks for libraries
  13 dnl #  3. checks for header files
  14 dnl #  4. checks for typedefs
  15 dnl #  5. checks for structures and functions
  16 dnl #  6. checks for compiler characteristics
  17 dnl #  7. checks for library functions
  18 dnl #  8. checks for system services
  19 dnl #  AC_OUTPUT([file...])
  20 dnl #
  21 dnl #############################################################
  22
  23 AC_PREREQ([2.59])
  24 export CFLAGS LIBS LDFLAGS CPPFLAGS
  25 AC_INIT(src/main/radiusd.c)
  26 AC_CONFIG_HEADER(src/include/autoconf.h)
  27 AC_REVISION($Revision$)dnl
  28
  29 dnl # The version of the software
  30 RADIUSD_MAJOR_VERSION=2
  31 RADIUSD_MINOR_VERSION=0.0-pre0
  32 RADIUSD_VERSION="${RADIUSD_MAJOR_VERSION}.${RADIUSD_MINOR_VERSION}"
  33 PACKAGE=freeradius
  34
  35 dnl #############################################################
  36 dnl #
  37 dnl #  0. Checks for compiler, libtool, and command line options.
  38 dnl #
  39 dnl #############################################################
  40
  41 dnl Check for GNU cc
  42 AC_PROG_CC
  43 AC_PROG_CXX
  44
  45 dnl #
  46 dnl # check for AIX, to allow us to use some BSD functions
  47 dnl # must be before macros that call the compiler.
  48 dnl #
  49 AC_AIX
  50
  51 AC_PROG_GCC_TRADITIONAL
  52 AC_PROG_CC_SUNPRO
  53 AC_PROG_RANLIB
  54
  55 dnl Compile in large (2G+) file support.
  56 AC_SYS_LARGEFILE
  57
  58 dnl # check for system bytesex
  59 dnl # AC_DEFINES WORDS_BIGENDIAN
  60 AC_C_BIGENDIAN
  61
  62 dnl Find GNU Make.
  63 AC_CHECK_PROG(GMAKE, gmake, yes, no)
  64 if test $GMAKE = no; then
  65   AC_PATH_PROG(MAKE, make, /usr/local/bin/make)
  66 else
  67   AC_PATH_PROG(MAKE, gmake, /usr/local/gnu/bin/make)
  68 fi
  69 makever=`$ac_cv_path_MAKE --version 2>&1 | grep "GNU Make"`
  70 if test -z "$makever"; then
  71   AC_MSG_ERROR(GNU Make is not installed.  Please download and install it
  72                 from ftp://prep.ai.mit.edu/pub/gnu/make/ before continuing.)
  73 fi
  74
  75 dnl libltdl is installable
  76 AC_LIBLTDL_INSTALLABLE
  77
  78 dnl use system-wide libtool, if it exists
  79 AC_ARG_WITH(system-libtool,
  80 [  --with-system-libtool              try to use libtool installed in your system [default=use our own]],
  81 [ AC_PATH_PROG(LIBTOOL, libtool,,$PATH:/usr/local/bin) ],
  82 [
  83   LIBTOOL="`pwd`/libtool"
  84   AC_SUBST(LIBTOOL)
  85   dnl ensure that we're looking for dlopen
  86   AC_LIBTOOL_DLOPEN
  87
  88   dnl Figure out how to build shared libraries
  89   AC_PROG_LIBTOOL
  90 ])
  91
  92
  93 dnl Put this in later, when all distributed modules use autoconf.
  94 dnl AC_ARG_WITH(disablemodulefoo,
  95 dnl [  --without-rlm_foo       Disables module compilation.  Module list:]
  96 dnl esyscmd([find src/modules -type d -name rlm_\* -print |\
  97 dnl     sed -e 's%src/modules/.*/% (sub)- %; s%.*/%- %' |\
  98 dnl     awk '{print "                            "$0}']))
  99
 100 AC_ARG_ENABLE(strict-dependencies,
 101 [  --enable-strict-dependencies  Fail configure on lack of module dependancy.])
 102
 103 dnl extra argument: --with-logdir
 104 logdir='${localstatedir}/log/radius'
 105 AC_MSG_CHECKING(logdir)
 106 AC_ARG_WITH(logdir,
 107 [  --with-logdir=DIR       Directory for logfiles [LOCALSTATEDIR/log/radius] ],
 108 [ case "$withval" in
 109     no)
 110         AC_MSG_ERROR(Need logdir)
 111         ;;
 112     yes)
 113         ;;
 114     *)
 115         logdir="$withval"
 116         ;;
 117   esac ]
 118 )
 119 AC_SUBST(logdir)
 120 AC_MSG_RESULT($logdir)
 121
 122 dnl extra argument: --with-radacctdir
 123 radacctdir='${logdir}/radacct'
 124 AC_MSG_CHECKING(radacctdir)
 125 AC_ARG_WITH(radacctdir,
 126 [  --with-radacctdir=PATH  Directory for detail files [LOGDIR/radacct] ],
 127 [ case "$withval" in
 128     no)
 129         AC_MSG_ERROR(Need radacctdir)
 130         ;;
 131     yes)
 132         ;;
 133     *)
 134         radacctdir="$withval"
 135         ;;
 136   esac ]
 137 )
 138 AC_SUBST(radacctdir)
 139 AC_MSG_RESULT($radacctdir)
 140
 141 dnl extra argument: --with-raddbdir
 142 raddbdir='${sysconfdir}/raddb'
 143 AC_MSG_CHECKING(raddbdir)
 144 AC_ARG_WITH(raddbdir,
 145 [  --with-raddbdir=DIR     Directory for config files [SYSCONFDIR/raddb] ],
 146 [ case "$withval" in
 147     no)
 148         AC_MSG_ERROR(Need raddbdir)
 149         ;;
 150     yes)
 151         ;;
 152     *)
 153         raddbdir="$withval"
 154         ;;
 155   esac ]
 156 )
 157 AC_SUBST(raddbdir)
 158 AC_MSG_RESULT($raddbdir)
 159
 160 dnl extra argument: --with-ascend-binary
 161 ASCEND_BINARY=yes
 162 AC_ARG_WITH(ascend-binary,
 163 [  --with-ascend-binary    Include support for Ascend binary filter attributes (default=yes)],
 164 [ case "$withval" in
 165     yes)
 166         ;;
 167     *)
 168         ASCEND_BINARY=""
 169   esac ]
 170 )
 171 if test "X$ASCEND_BINARY" = "Xyes"; then
 172   AC_DEFINE(ASCEND_BINARY, [], [Include support for Ascend binary filter attributes])
 173 fi
 174
 175 dnl extra argument: --with-threads
 176 WITH_THREADS=yes
 177 AC_ARG_WITH(threads,
 178 [  --with-threads          Use threads, if available.  (default=yes) ],
 179 [ case "$withval" in
 180     yes)
 181         ;;
 182     *)
 183         WITH_THREADS=""
 184   esac ]
 185 )
 186
 187 dnl extra argument: --with-snmp
 188 WITH_SNMP=yes
 189 AC_ARG_WITH(snmp,
 190 [  --with-snmp             Compile in SNMP support. (default=yes)],
 191 [ case "$withval" in
 192     yes)
 193         ;;
 194     *)
 195         WITH_SNMP=no
 196   esac ]
 197 )
 198
 199 dnl AC_ARG_ENABLE(ltdl-install,
 200 dnl [  --disable-ltdl-install  do not install libltdl])
 201 dnl if test x"${enable_ltdl_install+set}" != xset; then
 202 dnl   enable_ltdl_install=yes
 203 dnl   ac_configure_args="$ac_configure_args --enable-ltdl-install"
 204 dnl fi
 205 dnl AC_CONFIG_SUBDIRS(libltdl)
 206
 207 dnl #
 208 dnl #  Allow the user to specify a list of modules to be linked
 209 dnl #  statically to the server.
 210 dnl #
 211 STATIC_MODULES=
 212 AC_ARG_WITH(static_modules,
 213 [  --with-static-modules=QUOTED-MODULE-LIST],[
 214   for i in $withval; do
 215     STATIC_MODULES="$STATIC_MODULES -dlpreopen ../modules/rlm_$i/rlm_$i.la"
 216   done
 217 ])
 218
 219 dnl #
 220 dnl #  Enable developer C compiler warnings
 221 dnl #
 222 AC_ARG_ENABLE(developer,
 223 [  --enable-developer               Enables features of interest to developers.],
 224 [ case "$enableval" in
 225     no)
 226         developer=no
 227         ;;
 228     *)
 229         developer=yes
 230   esac ]
 231 )
 232
 233 if test "x$developer" != "xno" -a -d $srcdir/CVS; then
 234   dnl turn on the developer flag when taken from a CVS checkout (not a release)
 235   developer="yes"
 236 fi
 237
 238 dnl extra argument: --with-experimental-modules
 239 EXPERIMENTAL=
 240 AC_ARG_WITH(experimental-modules,
 241 [  --with-experimental-modules      Use experimental and unstable modules. (default=no) ],
 242 [ case "$withval" in
 243     yes)
 244         EXPERIMENTAL=yes
 245         ;;
 246     *)
 247   esac ]
 248 )
 249
 250 dnl #
 251 dnl # extra argument: --with-openssl-includes=dir
 252 dnl #
 253 OPENSSL_INCLUDE_DIR=
 254 AC_ARG_WITH(openssl-includes,
 255 [  --with-openssl-includes=DIR      Directory to look for OpenSSL include files],
 256 [ case "$withval" in
 257     *) OPENSSL_INCLUDE_DIR="$withval"
 258         ;;
 259   esac ]
 260 )
 261
 262 dnl #
 263 dnl # extra argument: --with-openssl-libraries=dir
 264 dnl #
 265 OPENSSL_LIB_DIR=
 266 AC_ARG_WITH(openssl-libraries,
 267 [  --with-openssl-libraries=DIR     Directory to look for OpenSSL library files],
 268 [ case "$withval" in
 269     *) OPENSSL_LIB_DIR="$withval"
 270         ;;
 271   esac ]
 272 )
 273
 274 dnl #
 275 dnl #  These next two arguments don't actually do anything.  They're
 276 dnl #  place holders so that the top-level configure script can tell
 277 dnl #  the user how to configure lower-level modules
 278 dnl #
 279
 280 dnl #
 281 dnl # extra argument: --with-rlm-FOO-lib-dir
 282 dnl #
 283 AC_ARG_WITH(rlm-FOO-lib-dir,
 284 [  --with-rlm-FOO-lib-dir=DIR       Directory to look for library files used by module FOO],
 285 [ case "$withval" in
 286     *)
 287         ;;
 288   esac ]
 289 )
 290
 291 dnl #
 292 dnl # extra argument: --with-rlm-FOO-include-dir
 293 dnl #
 294 AC_ARG_WITH(rlm-FOO-include-dir,
 295 [  --with-rlm-FOO-include-dir=DIR   Directory to look for include files used by module FOO],
 296 [ case "$withval" in
 297     *)
 298         ;;
 299   esac ]
 300 )
 301
 302 dnl See what include-style is used by the make program.
 303 dnl AC_MSG_CHECKING(include style for make)
 304 dnl echo "include /dev/null" > testmake.$$
 305 dnl echo "all:" >> testmake.$$
 306 dnl make -f testmake.$$ >/dev/null 2>&1
 307 dnl if test $? = 0
 308 dnl then
 309 dnl     INCLUDE=include
 310 dnl     IQUOTE=
 311 dnl else
 312 dnl     INCLUDE=.include
 313 dnl     IQUOTE='"'
 314 dnl fi
 315 dnl rm -f testmake.$$
 316 dnl AC_MSG_RESULT(" $INCLUDE")
 317 dnl AC_SUBST(INCLUDE)
 318 dnl AC_SUBST(IQUOTE)
 319
 320 dnl extra argument: --with-udpfromto
 321 WITH_UDPFROMTO=no
 322 AC_ARG_WITH(udpfromto,
 323 [  --with-udpfromto        Compile in UDPFROMTO support. (default=no)],
 324 [ case "$withval" in
 325     yes)
 326         WITH_UDPFROMTO=yes
 327         ;;
 328     *)
 329         WITH_UDPFROMTO=no
 330   esac ]
 331 )
 332
 333 if test "x$WITH_UDPFROMTO" = "xyes"; then
 334         AC_DEFINE(WITH_UDPFROMTO, [], [define if you want udpfromto])
 335 fi
 336
 337 dnl #############################################################
 338 dnl #
 339 dnl #  1. Checks for programs
 340 dnl #
 341 dnl #############################################################
 342
 343 CHECKRAD=checkrad.pl
 344 AC_PATH_PROG(PERL, perl, /usr/local/bin/perl)
 345 if test "x$ac_cv_path_PERL" = "x"; then
 346   AC_MSG_WARN(perl not found - Simultaneous-Use and checkrad.pl may not work)
 347 fi
 348 AC_PATH_PROG(SNMPGET, snmpget)
 349 if test "x$ac_cv_path_SNMPGET" = "x"; then
 350   AC_MSG_WARN(snmpget not found - Simultaneous-Use and checkrad.pl may not work)
 351 fi
 352
 353 AC_PATH_PROG(SNMPWALK, snmpwalk)
 354 if test "x$ac_cv_path_SNMPWALK" = "x"; then
 355   AC_MSG_WARN(snmpwalk not found - Simultaneous-Use and checkrad.pl may not work)
 356 fi
 357
 358 AC_PATH_PROG(RUSERS, rusers, /usr/bin/rusers)
 359
 360 dnl FIXME This is truly gross.
 361 missing_dir=`cd $ac_aux_dir && pwd`
 362 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
 363 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
 364 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
 365
 366 AC_PATH_PROG(LOCATE,locate)
 367 AC_PATH_PROG(DIRNAME,dirname)
 368 AC_PATH_PROG(GREP,grep)
 369
 370 dnl #############################################################
 371 dnl #
 372 dnl #  2. Checks for libraries
 373 dnl #
 374 dnl #############################################################
 375
 376 dnl If using pthreads, check for -lpthread (posix) or -lc_r (*BSD)
 377 old_CFLAGS=$CFLAGS
 378 if test "x$WITH_THREADS" = "xyes"; then
 379   if test $ac_cv_prog_suncc = "yes"; then
 380     CFLAGS="$CFLAGS -mt"
 381   fi
 382
 383   AC_CHECK_HEADERS(pthread.h, [], [ WITH_THREADS="no" ])
 384
 385 dnl #
 386 dnl # pthread stuff is usually in -lpthread
 387 dnl # or in -lc_r, on *BSD
 388 dnl #
 389 dnl # On Some systems, we need extra pre-processor flags, to get them to
 390 dnl # to do the threading properly.
 391 dnl #
 392   AC_CHECK_LIB(pthread, pthread_create,
 393                 [ CFLAGS="$CFLAGS -D_REENTRANT -D_POSIX_PTHREAD_SEMANTICS"
 394                   LIBS="$LIBS -lpthread" ],
 395                 AC_CHECK_LIB(c_r, pthread_create,
 396                             [ CFLAGS="$CFLAGS -pthread -D_THREAD_SAFE" ],
 397                             [ WITH_THREADS="no" ]
 398                             )
 399                 )
 400 fi
 401
 402 dnl #
 403 dnl # If we have NO pthread libraries, remove any knowledge of threads.
 404 dnl #
 405 if test "x$WITH_THREADS" != "xyes"; then
 406   CFLAGS=$old_CFLAGS
 407   ac_cv_header_pthread_h="no"
 408   WITH_THREADS=no
 409 else
 410   dnl #
 411   dnl #  We need sem_init() and friends, as they're the friendliest
 412   dnl #  semaphore functions for threading.
 413   dnl #
 414   dnl # HP/UX requires linking with librt, too, to get the sem_* symbols.
 415   dnl # Some systems have them in -lsem
 416   dnl # Solaris has them in -lposix4
 417   dnl # NetBSD has them in -lsemaphore
 418
 419   AC_SEARCH_LIBS(sem_init, pthread sem posix4 rt semaphore,
 420         [],
 421         [AC_MSG_ERROR(-lsem not found.  You may want to download it from ftp://ftp.to.gd-es.com/pub/BSDI/libsem.tar.bz2 or ftp://ftp.freeradius.org/pub/radius/contrib/libsem.tar.gz)]
 422    )
 423 fi
 424
 425 dnl Check if we need -lsocket
 426 AC_CHECK_LIB(socket, getsockname)
 427
 428 dnl Check for -lresolv
 429 dnl This library may be needed later.
 430 AC_CHECK_LIB(resolv, inet_aton)
 431
 432 dnl Check if we need -lnsl. Usually if we want to
 433 dnl link against -lsocket we need to include -lnsl as well.
 434 AC_CHECK_LIB(nsl, inet_ntoa)
 435
 436 dnl Check for OpenSSL libraries.
 437 OPENSSL_LIBS=
 438 old_LIBS=$LIBS
 439 if test "x$OPENSSL_LIB_DIR" != "x"; then
 440     LIBS="-L$OPENSSL_LIB_DIR $LIBS"
 441 fi
 442 AC_CHECK_LIB(crypto, DH_new,
 443     [
 444         AC_DEFINE(HAVE_LIBCRYPTO, 1,
 445             [Define to 1 if you have the `crypto' library (-lcrypto).])
 446         AC_CHECK_LIB(ssl, SSL_new,
 447             [
 448                 AC_DEFINE(HAVE_LIBSSL, 1,
 449                     [Define to 1 if you have the `ssl' library (-lssl).])
 450                 if test "x$OPENSSL_LIB_DIR" != "x"; then
 451                     OPENSSL_LIBS="-L$OPENSSL_LIB_DIR"
 452                 fi
 453                 OPENSSL_LIBS="$OPENSSL_LIBS -lcrypto -lssl -lcrypto"
 454             ], [])
 455     ], [])
 456 LIBS=$old_LIBS
 457
 458 dnl Check the pcap library for the RADIUS sniffer.
 459 PCAP_LIBS=
 460 AC_CHECK_LIB(pcap, pcap_open_live,
 461         [ PCAP_LIBS="-lpcap"
 462         AC_DEFINE(HAVE_LIBPCAP, 1,
 463                 [Define to 1 if you have the `pcap' library (-lpcap).])
 464         ],
 465         [ AC_MSG_WARN([pcap library not found, silently disabling the RADIUS sniffer.]) ])
 466
 467 dnl #############################################################
 468 dnl #
 469 dnl #  3. Checks for header files
 470 dnl #
 471 dnl #############################################################
 472
 473 dnl #
 474 dnl # Interix requires us to set -D_ALL_SOURCE, otherwise
 475 dnl # getopt will be #included, but won't link.  <sigh>
 476 dnl #
 477 dnl #
 478 case "$host" in
 479 *-interix*)
 480         CFLAGS="$CFLAGS -D_ALL_SOURCE"
 481         ;;
 482 *-darwin*)
 483         CFLAGS="$CFLAGS -DDARWIN"
 484         ;;
 485 esac
 486
 487 AC_HEADER_DIRENT
 488 AC_HEADER_STDC
 489 AC_HEADER_TIME
 490 AC_HEADER_SYS_WAIT
 491
 492 AC_CHECK_HEADERS( \
 493         unistd.h \
 494         crypt.h \
 495         errno.h \
 496         resource.h \
 497         getopt.h \
 498         malloc.h \
 499         utmp.h \
 500         utmpx.h \
 501         signal.h \
 502         sys/select.h \
 503         syslog.h \
 504         inttypes.h \
 505         stdint.h \
 506         stdio.h \
 507         netdb.h \
 508         semaphore.h \
 509         arpa/inet.h \
 510         netinet/in.h \
 511         sys/types.h \
 512         sys/socket.h \
 513         sys/time.h \
 514         sys/wait.h \
 515         sys/security.h \
 516         fcntl.h \
 517         sys/fcntl.h \
 518         net/if.h \
 519         prot.h \
 520         sia.h \
 521         siad.h
 522 )
 523
 524 REGEX=no
 525 AC_CHECK_HEADER(regex.h, AC_DEFINE(HAVE_REGEX_H, [], [define this if we have the <regex.h> header file]))
 526 if test "x$ac_cv_header_regex_h" = "xyes"; then
 527   REGEX_EXTENDED=no
 528   REGEX=yes
 529   AC_EGREP_CPP(yes,
 530     [#include <regex.h>
 531      #ifdef REG_EXTENDED
 532        yes
 533      #endif
 534      ], [AC_DEFINE(HAVE_REG_EXTENDED, [], [define this if we have REG_EXTENDED (from <regex.h>)]) REGEX_EXTENDED=yes])
 535 fi
 536 AC_SUBST(REGEX)
 537 AC_SUBST(REGEX_EXTENDED)
 538
 539 dnl #
 540 dnl #  other checks which require headers
 541 dnl #
 542 if test "x$ac_cv_header_sys_security_h" = "xyes" && test "x$ac_cv_header_prot_h" = "xyes"
 543 then
 544   AC_DEFINE(OSFC2, [], [define if you have OSFC2 authentication])
 545 fi
 546
 547 if test "x$ac_cv_header_sia_h" = "xyes" && test "x$ac_cv_header_siad_h" = "xyes"
 548 then
 549   AC_DEFINE(OSFSIA, [], [define if you have OSFSIA authentication])
 550 fi
 551
 552 dnl Check for OpenSSL includes.
 553 OPENSSL_INCLUDE="-DNO_OPENSSL"
 554 if test "x$OPENSSL_LIBS" = "x"; then
 555     AC_MSG_NOTICE([skipping test for openssl/ssl.h])
 556 else
 557     old_CPPFLAGS=$CPPFLAGS
 558     if test "x$OPENSSL_INCLUDE_DIR" != "x"; then
 559         CPPFLAGS="$CPPFLAGS -I$OPENSSL_INCLUDE_DIR"
 560     fi
 561     dnl # stupid RedHat shit
 562     CPPFLAGS="$CPPFLAGS -DOPENSSL_NO_KRB5"
 563     AC_CHECK_HEADERS( \
 564         openssl/ssl.h \
 565         openssl/crypto.h \
 566         openssl/err.h \
 567         openssl/engine.h,
 568         [],
 569         OPENSSL_LIBS=
 570     )
 571     if test "x$OPENSSL_LIBS" != "x"; then
 572         AC_MSG_CHECKING([for OpenSSL version >= 0.9.7])
 573         AC_EGREP_CPP(yes,
 574             [#include <openssl/crypto.h>
 575              #if (OPENSSL_VERSION_NUMBER >= 0x00907000L)
 576              yes
 577              #endif
 578             ], goodssl="yes")
 579         if test "x$goodssl" != "xyes"; then
 580             AC_MSG_RESULT(no)
 581             OPENSSL_LIBS=
 582         else
 583             AC_MSG_RESULT(yes)
 584             if test "x$OPENSSL_INCLUDE_DIR" != "x"; then
 585                 OPENSSL_INCLUDE="-I$OPENSSL_INCLUDE_DIR -DOPENSSL_NO_KRB5"
 586             else
 587                 OPENSSL_INCLUDE="-DOPENSSL_NO_KRB5"
 588             fi
 589         fi
 590     fi
 591     CPPFLAGS=$old_CPPFLAGS
 592 fi
 593 AC_SUBST(OPENSSL_INCLUDE)
 594 AC_SUBST(OPENSSL_LIBS)
 595 export OPENSSL_LIBS
 596
 597 dnl Check the pcap includes for the RADIUS sniffer.
 598 if test "x$PCAP_LIBS" = x; then
 599     AC_MSG_NOTICE([skipping test for pcap.h.])
 600 else
 601     AC_CHECK_HEADER(pcap.h,
 602         AC_DEFINE(HAVE_PCAP_H, 1,
 603                 [Define to 1 if you have the <pcap.h> header file.]),
 604         [ PCAP_LIBS=
 605         AC_MSG_WARN([pcap.h not found, silently disabling the RADIUS sniffer.])
 606         ])
 607 fi
 608 AC_SUBST(PCAP_LIBS)
 609
 610 dnl #############################################################
 611 dnl #
 612 dnl #  4. Checks for typedefs
 613 dnl #
 614 dnl #############################################################
 615
 616 dnl #
 617 dnl # Ensure that these are defined
 618 dnl #
 619 AC_TYPE_OFF_T
 620 AC_TYPE_PID_T
 621 AC_TYPE_SIZE_T
 622 AC_TYPE_UID_T
 623
 624 dnl check for socklen_t
 625 FR_CHECK_TYPE_INCLUDE([
 626 #ifdef HAVE_SYS_TYPES_H
 627 #include <sys/types.h>
 628 #endif
 629 #ifdef HAVE_SYS_SOCKET_H
 630 #include <sys/socket.h>
 631 #endif
 632 ],socklen_t, int, [socklen_t is generally 'int' on systems which don't use it])
 633
 634 dnl check for uint8_t
 635 FR_CHECK_TYPE_INCLUDE([
 636 #ifdef HAVE_INTTYPES_H
 637 #include <inttypes.h>
 638 #endif
 639 #ifdef HAVE_STDINT_H
 640 #include <stdint.h>
 641 #endif
 642 ],uint8_t, unsigned char, [uint8_t should be the canonical 'octet' for network traffic])
 643
 644 dnl check for uint16_t
 645 FR_CHECK_TYPE_INCLUDE([
 646 #ifdef HAVE_INTTYPES_H
 647 #include <inttypes.h>
 648 #endif
 649 #ifdef HAVE_STDINT_H
 650 #include <stdint.h>
 651 #endif
 652 ],uint16_t, unsigned short, [uint16_t should be the canonical '2 octets' for network traffic])
 653
 654 dnl check for uint32_t
 655 FR_CHECK_TYPE_INCLUDE([
 656 #ifdef HAVE_INTTYPES_H
 657 #include <inttypes.h>
 658 #endif
 659 #ifdef HAVE_STDINT_H
 660 #include <stdint.h>
 661 #endif
 662 ],uint32_t, unsigned int, [uint32_t should be the canonical 'network integer])
 663
 664 AC_CHECK_TYPE(struct in6_addr, AC_DEFINE(HAVE_STRUCT_IN6_ADDR, 1, [IPv6 address structure]), [], [
 665 #ifdef HAVE_NETINET_IN_H
 666 #include <netinet/in.h>
 667 #endif
 668 ])
 669
 670 AC_CHECK_TYPE(struct sockaddr_storage, AC_DEFINE(HAVE_STRUCT_SOCKADDR_STORAGE, 1, [Generic socket addresses]), [], [
 671 #ifdef HAVE_NETINET_IN_H
 672 #include <netinet/in.h>
 673 #endif
 674 #ifdef HAVE_SYS_SOCKET_H
 675 #include <sys/socket.h>
 676 #endif
 677 ])
 678
 679 AC_CHECK_TYPE(struct sockaddr_in6, AC_DEFINE(HAVE_STRUCT_SOCKADDR_IN6, 1, [IPv6 socket addresses]), [], [
 680 #ifdef HAVE_NETINET_IN_H
 681 #include <netinet/in.h>
 682 #endif
 683 ])
 684
 685 AC_CHECK_TYPE(struct addrinfo, AC_DEFINE(HAVE_STRUCT_ADDRINFO, 1, [Generic DNS lookups]), [], [
 686 #ifdef HAVE_SYS_TYPES_H
 687 #include <sys/types.h>
 688 #endif
 689 #ifdef HAVE_SYS_SOCKET_H
 690 #include <sys/socket.h>
 691 #endif
 692 #ifdef HAVE_NETDB_H
 693 #include <netdb.h>
 694 #endif
 695 ])
 696
 697 dnl #############################################################
 698 dnl #
 699 dnl #  5. Checks for structures and functions
 700 dnl #
 701 dnl #############################################################
 702 AC_CHECK_FUNCS( \
 703         getopt_long \
 704         lockf \
 705         strsignal \
 706         sigaction \
 707         sigprocmask \
 708         pthread_sigmask \
 709         snprintf \
 710         vsnprintf \
 711         setsid \
 712         strncasecmp \
 713         strcasecmp \
 714         localtime_r \
 715         ctime_r \
 716         gmtime_r \
 717         strsep \
 718         inet_aton \
 719         inet_pton \
 720         inet_ntop \
 721         gethostname \
 722         setlinebuf \
 723         setvbuf \
 724         getusershell \
 725         initgroups \
 726         getaddrinfo \
 727         getnameinfo \
 728         closefrom \
 729         strlcat \
 730         strlcpy
 731 )
 732 RADIUSD_NEED_DECLARATIONS( \
 733         crypt \
 734         strncasecmp \
 735         strcasecmp \
 736         inet_aton \
 737         gethostname \
 738         setlinebuf \
 739         getusershell \
 740         endusershell
 741 )
 742
 743 AC_TYPE_SIGNAL
 744
 745 dnl # check if we have utmpx.h
 746 dnl # if so, check if struct utmpx has entry ut_xtime
 747 dnl # if not, set it to define ut_xtime == ut_tv.tv_sec
 748 if test "x$ac_cv_header_utmpx_h" = "xyes"
 749 then
 750  FR_CHECK_STRUCT_HAS_MEMBER([#include <utmpx.h>], [struct utmpx], ut_xtime)
 751  if test "x$ac_cv_type_struct_utmpx_has_ut_xtime" = "x"
 752  then
 753    AC_DEFINE(ut_xtime,ut_tv.tv_sec, [define to something if you don't have ut_xtime in struct utmpx])
 754  fi
 755 fi
 756
 757 dnl # struct ip_pktinfo
 758 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in_pktinfo], ipi_addr)
 759 if test "x$ac_cv_type_struct_in_pktinfo_has_ipi_addr" = "xyes"
 760 then
 761         AC_DEFINE(HAVE_IP_PKTINFO, [], [define if you have IP_PKTINFO (Linux)])
 762 fi
 763
 764 dnl # struct in6_pktinfo
 765 FR_CHECK_STRUCT_HAS_MEMBER([#include <netinet/in.h>], [struct in6_pktinfo], ipi6_addr)
 766 if test "x$ac_cv_type_struct_in6_pktinfo_has_ipi6_addr" = "xyes"
 767 then
 768         AC_DEFINE(HAVE_IN6_PKTINFO, [], [define if you have IN6_PKTINFO (Linux)])
 769 fi
 770
 771 dnl #############################################################
 772 dnl #
 773 dnl #  6. Checks for compiler characteristics
 774 dnl #
 775 dnl #############################################################
 776
 777 dnl #
 778 dnl # Ensure that these are defined
 779 dnl #
 780 AC_C_CONST
 781
 782 dnl #
 783 dnl # See if this is OS/2
 784 dnl #
 785 AC_MSG_CHECKING(type of OS)
 786 OS=`uname -s`
 787 AC_MSG_RESULT($OS)
 788 if test "$OS" = "OS/2"; then
 789         LIBPREFIX=
 790 else
 791         LIBPREFIX=lib
 792 fi
 793 AC_SUBST(LIBPREFIX)
 794
 795 dnl #
 796 dnl # Set Default CFLAGS
 797 dnl #
 798 if test "x$GCC" = "xyes"; then
 799     CFLAGS="$CFLAGS -Wall -D_GNU_SOURCE"
 800 fi
 801
 802 AC_MSG_CHECKING(for developer gcc flags)
 803 if test "x$developer" = "xyes" -a "x$GCC" = "xyes"; then
 804   devflags="-g -Wshadow -Wpointer-arith -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -W -Wredundant-decls -Wundef"
 805   CFLAGS="$CFLAGS $devflags"
 806   INSTALLSTRIP=""
 807   AC_MSG_RESULT(yes.  Using $devflags)
 808 else
 809   devflags=""
 810   CFLAGS="$CFLAGS -DNDEBUG"
 811   INSTALLSTRIP="-s"
 812   AC_MSG_RESULT(no.)
 813 fi
 814
 815 dnl #############################################################
 816 dnl #
 817 dnl #  7. Checks for library functions
 818 dnl #
 819 dnl #############################################################
 820
 821 dnl Check for libcrypt
 822 dnl We use crypt(3) which may be in libc, or in libcrypt (eg FreeBSD)
 823 AC_CHECK_LIB(crypt, crypt,
 824   CRYPTLIB="-lcrypt"
 825 )
 826 if test "$CRYPTLIB" != ""; then
 827   AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function])
 828 else
 829   AC_CHECK_FUNC(crypt, AC_DEFINE(HAVE_CRYPT, [], [Do we have the crypt function]))
 830 fi
 831
 832 dnl Check for libcipher
 833 AC_CHECK_LIB(cipher, setkey,
 834    CRYPTLIB="${CRYPTLIB} -lcipher"
 835 )
 836 AC_SUBST(CRYPTLIB)
 837
 838 if test "x$WITH_SNMP" = "xyes"; then
 839   SNMP_CHECKS
 840 fi
 841
 842 dnl Check the style of gethostbyaddr, in order of preference
 843 dnl GNU (_r eight args)
 844 AC_DEFINE(GNUSTYLE, [1], [GNU-Style get*byaddr_r])
 845 dnl SYSV (_r six args)
 846 AC_DEFINE(SYSVSTYLE, [2], [SYSV-Style get*byaddr_r])
 847 dnl BSD (three args, may not be thread safe)
 848 AC_DEFINE(BSDSTYLE, [3], [BSD-Style get*byaddr_r])
 849 dnl Tru64 has BSD version, but it is thread safe
 850 dnl     http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1739____.HTM
 851 dnl We need #stdio.h to define NULL on FreeBSD (at least)
 852 gethostbyaddrrstyle=""
 853 AC_MSG_CHECKING([gethostbyaddr_r() syntax])
 854 case "$host" in
 855 *-freebsd*)
 856         AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE, [style of gethostbyaddr_r functions ])
 857         gethostbyaddrrstyle=BSD
 858         AC_MSG_WARN([FreeBSD overridden to BSD-style])
 859         ;;
 860 esac
 861 if test "x$gethostbyaddrrstyle" = "x"; then
 862         AC_TRY_LINK([
 863 #include <stdio.h>
 864 #include <netdb.h>
 865 ], [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL, NULL) ], [
 866         AC_DEFINE(GETHOSTBYADDRRSTYLE, GNUSTYLE, [style of gethostbyaddr_r functions ])
 867         gethostbyaddrrstyle=GNU
 868 ])
 869 fi
 870 if test "x$gethostbyaddrrstyle" = "x"; then
 871         AC_TRY_LINK([
 872 #include <stdio.h>
 873 #include <netdb.h>
 874 ], [ gethostbyaddr_r(NULL, 0, 0, NULL, NULL, 0, NULL) ] , [
 875                 AC_DEFINE(GETHOSTBYADDRRSTYLE, SYSVSTYLE, [style of gethostbyaddr_r functions ])
 876                 gethostbyaddrrstyle=SYSV
 877         ])
 878 fi
 879 if test "x$gethostbyaddrrstyle" = "x"; then
 880         AC_TRY_LINK([
 881 #include <stdio.h>
 882 #include <netdb.h>
 883 ], [ gethostbyaddr(NULL, 0, 0)  ], [
 884                 AC_DEFINE(GETHOSTBYADDRRSTYLE, BSDSTYLE, [style of gethostbyaddr_r functions ])
 885                 gethostbyaddrrstyle=BSD
 886         ])
 887 fi
 888
 889 if test "x$gethostbyaddrrstyle" = "x"; then
 890         AC_MSG_RESULT([none!  It must not exist, here.])
 891 else
 892         AC_MSG_RESULT([${gethostbyaddrrstyle}-style])
 893 fi
 894
 895 if test "x$gethostbyaddrrstyle" = "xBSD"; then
 896         AC_MSG_WARN([ ****** BSD-style gethostbyaddr might NOT be thread-safe! ****** ])
 897 fi
 898
 899 dnl Check the style of gethostbyname, in order of preference
 900 dnl GNU (_r seven args)
 901 dnl SYSV (_r five args)
 902 dnl BSD (two args, may not be thread safe)
 903 dnl Tru64 has BSD version, but it _is_ thread safe
 904 dnl     http://h30097.www3.hp.com/docs/base_doc/DOCUMENTATION/V51B_HTML/MAN/MAN3/1946____.HTM
 905 dnl We need #stdio.h to define NULL on FreeBSD (at least)
 906 gethostbynamerstyle=""
 907 AC_MSG_CHECKING([gethostbyname_r() syntax])
 908 AC_TRY_LINK([
 909 #include <stdio.h>
 910 #include <netdb.h>
 911 ], [ gethostbyname_r(NULL, NULL, NULL, 0, NULL, NULL) ], [
 912         AC_DEFINE(GETHOSTBYNAMERSTYLE, GNUSTYLE, [style of gethostbyname_r functions ])
 913         gethostbynamerstyle=GNU
 914 ])
 915 if test "x$gethostbynamerstyle" = "x"; then
 916         AC_TRY_LINK([
 917 #include <stdio.h>
 918 #include <netdb.h>
 919 ], [ gethostbyname_r(NULL, NULL, NULL, 0, NULL) ] , [
 920                 AC_DEFINE(GETHOSTBYNAMERSTYLE, SYSVSTYLE, [style of gethostbyname_r functions ])
 921                 gethostbynamerstyle=SYSV
 922         ])
 923 fi
 924 if test "x$gethostbynamerstyle" = "x"; then
 925         AC_TRY_LINK([
 926 #include <stdio.h>
 927 #include <netdb.h>
 928 ], [ gethostbyname(NULL)  ], [
 929                 AC_DEFINE(GETHOSTBYNAMERSTYLE, BSDSTYLE, [style of gethostbyname_r functions ])
 930                 gethostbynamerstyle=BSD
 931         ])
 932 fi
 933
 934 if test "x$gethostbynamerstyle" = "x"; then
 935         AC_MSG_RESULT([none!  It must not exist, here.])
 936 else
 937         AC_MSG_RESULT([${gethostbynamerstyle}-style])
 938 fi
 939
 940 if test "x$gethostbynamerstyle" = "xBSD"; then
 941         AC_MSG_WARN([ ****** BSD-style gethostbyname might NOT be thread-safe! ****** ])
 942 fi
 943
 944 dnl check for non-posix solaris ctime_r (extra buflen int arg)
 945 AC_DEFINE(POSIXSTYLE, [1], [Posix-Style ctime_r])
 946 AC_DEFINE(SOLARISSTYLE, [2], [Solaris-Style ctime_r])
 947 ctimerstyle=""
 948 AC_MSG_CHECKING([ctime_r() syntax])
 949 AC_TRY_LINK([
 950 #include <time.h>
 951 ], [ ctime_r(NULL, NULL, 0) ], [
 952         AC_DEFINE(CTIMERSTYLE, SOLARISSTYLE, [style of ctime_r function])
 953         ctimerstyle="SOLARIS"
 954 ])
 955 if test "x$ctimerstyle" = "x"; then
 956         AC_TRY_LINK([
 957 #include <time.h>
 958 ], [ ctime_r(NULL, NULL) ], [
 959                 AC_DEFINE(CTIMERSTYLE, POSIXSTYLE, [style of ctime_r function])
 960                 ctimerstyle="POSIX"
 961         ])
 962 fi
 963
 964 if test "x$ctimerstyle" = "x"; then
 965         AC_MSG_RESULT([none!  It must not exist, here.])
 966 else
 967         AC_MSG_RESULT([${ctimerstyle}-style])
 968 fi
 969
 970 AC_SUBST(HOSTINFO, $host)
 971
 972 dnl #############################################################
 973 dnl #
 974 dnl #  8. Checks for system services
 975 dnl #
 976 dnl #############################################################
 977
 978 dnl #
 979 dnl # Figure out where libtool is located,
 980 dnl #
 981 top_builddir=`pwd`
 982 export top_builddir
 983 AC_MSG_RESULT([top_builddir=$top_builddir])
 984 dnl # AC_SUBST(top_builddir)
 985 AC_SUBST(LIBLTDL)
 986 AC_SUBST(INCLTDL)
 987
 988 dnl #
 989 dnl #  Work around stupid autoconf crap
 990 dnl #
 991 if test "x$INCLTDL" != "x";then
 992   INCLTDL='-I${top_builddir}/''libltdl'
 993 fi
 994
 995 dnl import libtool stuff
 996
 997 dnl #############################################################
 998 dnl #
 999 dnl #  Configure in any module directories.
1000 dnl #
1001 dnl #############################################################
1002
1003 mysubdirs="$LIBLTDLPATH"
1004 if test "x$EXPERIMENTAL" = "xyes"; then
1005   bar=`ls -1 "${srcdir}"/src/modules/rlm_*/configure | sed 's%/configure%%'`
1006   dnl # get rid of LF's.
1007   mysubdirs=`echo $mysubdirs $bar`
1008 else
1009   dnl #
1010   dnl # Find 'configure' in ONLY the stable modules
1011   dnl #
1012   for bar in `cat "${srcdir}"/src/modules/stable`; do
1013     if test -f "${srcdir}"/src/modules/$bar/configure; then
1014       mysubdirs="$mysubdirs src/modules/$bar"
1015     fi
1016   done
1017 fi
1018
1019 dnl ############################################################
1020 dnl # make modules by list
1021 dnl #############################################################
1022 MODULES=
1023 if test "x$EXPERIMENTAL" = "xyes"; then
1024   for foo in `ls -1 "${srcdir}"/src/modules | grep rlm_`; do
1025     MODULES="$MODULES $foo"
1026   done
1027 else
1028    dnl #
1029    dnl # make ONLY the stable modules
1030    dnl #
1031    for foo in `cat "${srcdir}"/src/modules/stable`; do
1032     MODULES="$MODULES $foo"
1033    done
1034 fi
1035
1036 dnl #
1037 dnl #  Don't change the variable name here.  Autoconf goes bonkers
1038 dnl #  if you do.
1039 dnl #
1040 AC_CONFIG_SUBDIRS($mysubdirs)
1041 AC_SUBST(MODULES)
1042
1043 dnl #############################################################
1044 dnl #
1045 dnl #  And finally, output the results.
1046 dnl #
1047 dnl #############################################################
1048
1049 AC_CONFIG_COMMANDS([stamp-h], [echo timestamp > src/include/stamp-h])
1050 AC_CONFIG_COMMANDS([build-radpaths-h], [(cd ./src/include && /bin/sh ./build-radpaths-h)])
1051 AC_CONFIG_COMMANDS([main-chmod], [(cd ./src/main   && chmod +x checkrad.pl radlast radtest)])
1052 AC_CONFIG_COMMANDS([scripts-chmod], [(cd ./scripts    && chmod +x rc.radiusd radwatch check-radiusd-config radiusd.cron.daily radiusd.cron.monthly cryptpasswd)])
1053
1054 dnl #
1055 dnl #  Substitute whatever libraries we found to be necessary
1056 dnl #
1057 AC_SUBST(LIBS)
1058 AC_SUBST(INSTALLSTRIP)
1059
1060 USE_SHARED_LIBS=$enable_shared
1061 AC_SUBST(USE_SHARED_LIBS)
1062 USE_STATIC_LIBS=$enable_static
1063 AC_SUBST(USE_STATIC_LIBS)
1064 AC_SUBST(STATIC_MODULES)
1065 AC_SUBST(RADIUSD_MAJOR_VERSION)
1066 AC_SUBST(RADIUSD_MINOR_VERSION)
1067 AC_SUBST(RADIUSD_VERSION)
1068
1069 AC_OUTPUT(\
1070         ./Make.inc \
1071         ./src/include/build-radpaths-h \
1072         ./src/main/Makefile \
1073         ./src/main/checkrad.pl \
1074         ./src/main/radlast \
1075         ./src/main/radtest \
1076         ./scripts/rc.radiusd \
1077         ./scripts/radwatch \
1078         ./scripts/check-radiusd-config \
1079         ./scripts/radiusd.cron.daily \
1080         ./scripts/radiusd.cron.monthly \
1081         ./scripts/cryptpasswd \
1082         ./raddb/dictionary \
1083         ./raddb/radiusd.conf \
1084         ./raddb/radrelay.conf
1085 )