libeap/wpa_supplicant/wpa_gui-qt4/wpa_gui.pro

   1 TEMPLATE        = app
   2 LANGUAGE        = C++
   3 TRANSLATIONS    = lang/wpa_gui_de.ts
   4 greaterThan(QT_MAJOR_VERSION, 4): QT += widgets
   5
   6 CONFIG  += qt warn_on release
   7
   8 DEFINES += CONFIG_CTRL_IFACE
   9
  10 win32 {
  11   LIBS += -lws2_32 -static
  12   DEFINES += CONFIG_NATIVE_WINDOWS CONFIG_CTRL_IFACE_NAMED_PIPE
  13   SOURCES += ../../src/utils/os_win32.c
  14 } else:win32-g++ {
  15   # cross compilation to win32
  16   LIBS += -lws2_32 -static -mwindows
  17   DEFINES += CONFIG_NATIVE_WINDOWS CONFIG_CTRL_IFACE_NAMED_PIPE
  18   SOURCES += ../../src/utils/os_win32.c
  19   RESOURCES += icons_png.qrc
  20 } else:win32-x-g++ {
  21   # cross compilation to win32
  22   LIBS += -lws2_32 -static -mwindows
  23   DEFINES += CONFIG_NATIVE_WINDOWS CONFIG_CTRL_IFACE_NAMED_PIPE
  24   DEFINES += _X86_
  25   SOURCES += ../../src/utils/os_win32.c
  26   RESOURCES += icons_png.qrc
  27 } else {
  28   DEFINES += CONFIG_CTRL_IFACE_UNIX
  29   SOURCES += ../../src/utils/os_unix.c
  30 }
  31
  32 INCLUDEPATH     += . .. ../../src ../../src/utils
  33
  34 HEADERS += wpamsg.h \
  35         wpagui.h \
  36         eventhistory.h \
  37         scanresults.h \
  38         scanresultsitem.h \
  39         signalbar.h \
  40         userdatarequest.h \
  41         networkconfig.h \
  42         addinterface.h \
  43         peers.h \
  44         stringquery.h
  45
  46 SOURCES += main.cpp \
  47         wpagui.cpp \
  48         eventhistory.cpp \
  49         scanresults.cpp \
  50         scanresultsitem.cpp \
  51         signalbar.cpp \
  52         userdatarequest.cpp \
  53         networkconfig.cpp \
  54         addinterface.cpp \
  55         peers.cpp \
  56         stringquery.cpp \
  57         ../../src/common/wpa_ctrl.c
  58
  59 RESOURCES += icons.qrc
  60
  61 FORMS   = wpagui.ui \
  62         eventhistory.ui \
  63         scanresults.ui \
  64         userdatarequest.ui \
  65         networkconfig.ui \
  66         peers.ui
  67
  68
  69 unix {
  70   UI_DIR = .ui
  71   MOC_DIR = .moc
  72   OBJECTS_DIR = .obj
  73 }