wpa_supplicant/wpa_gui-qt4/wpa_gui.pro

   1 TEMPLATE        = app
   2 LANGUAGE        = C++
   3
   4 CONFIG  += qt warn_on release
   5
   6 DEFINES += CONFIG_CTRL_IFACE
   7
   8 win32 {
   9   LIBS += -lws2_32 -static
  10   DEFINES += CONFIG_NATIVE_WINDOWS CONFIG_CTRL_IFACE_NAMED_PIPE
  11   SOURCES += ../../src/utils/os_win32.c
  12 } else:win32-g++ {
  13   # cross compilation to win32
  14   LIBS += -lws2_32 -static -mwindows
  15   DEFINES += CONFIG_NATIVE_WINDOWS CONFIG_CTRL_IFACE_NAMED_PIPE
  16   SOURCES += ../../src/utils/os_win32.c
  17   RESOURCES += icons_png.qrc
  18 } else:win32-x-g++ {
  19   # cross compilation to win32
  20   LIBS += -lws2_32 -static -mwindows
  21   DEFINES += CONFIG_NATIVE_WINDOWS CONFIG_CTRL_IFACE_NAMED_PIPE
  22   DEFINES += _X86_
  23   SOURCES += ../../src/utils/os_win32.c
  24   RESOURCES += icons_png.qrc
  25 } else {
  26   DEFINES += CONFIG_CTRL_IFACE_UNIX
  27   SOURCES += ../../src/utils/os_unix.c
  28 }
  29
  30 INCLUDEPATH     += . .. ../../src/utils ../../src/common
  31
  32 HEADERS += wpamsg.h \
  33         wpagui.h \
  34         eventhistory.h \
  35         scanresults.h \
  36         userdatarequest.h \
  37         networkconfig.h \
  38         addinterface.h
  39
  40 SOURCES += main.cpp \
  41         wpagui.cpp \
  42         eventhistory.cpp \
  43         scanresults.cpp \
  44         userdatarequest.cpp \
  45         networkconfig.cpp \
  46         addinterface.cpp \
  47         ../../src/common/wpa_ctrl.c
  48
  49 RESOURCES += icons.qrc
  50
  51 FORMS   = wpagui.ui \
  52         eventhistory.ui \
  53         scanresults.ui \
  54         userdatarequest.ui \
  55         networkconfig.ui
  56
  57
  58 unix {
  59   UI_DIR = .ui
  60   MOC_DIR = .moc
  61   OBJECTS_DIR = .obj
  62 }