configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 AC_REVISION($Revision$)
   3 AC_PREREQ(2.57)
   4 AC_INIT(mod_auth_kerb, 5.2, modauthkerb-developers@lists.sourceforge.net)
   5 AC_CONFIG_SRCDIR([src/mod_auth_kerb.c])
   6 AC_CONFIG_HEADER([config.h])
   7
   8 # Checks for programs.
   9 AC_PROG_CC
  10 AC_PROG_MAKE_SET
  11
  12 # Checks for libraries.
  13 # FIXME: Replace `main' with a function in `-lresolv':
  14 LIB_resolv=""
  15 AC_CHECK_LIB([resolv], [main], [LIB_resolv=-lresolv])
  16 AC_SUBST(LIB_resolv)
  17
  18 # Checks for header files.
  19 AC_HEADER_STDC
  20 AC_CHECK_HEADERS([limits.h netdb.h stddef.h stdlib.h string.h unistd.h])
  21
  22 # Checks for typedefs, structures, and compiler characteristics.
  23 #AC_C_CONST
  24 AC_TYPE_SIZE_T
  25 AC_STRUCT_TM
  26
  27 # Checks for library functions.
  28 #AC_FUNC_MALLOC
  29 #AC_FUNC_MEMCMP
  30 #AC_CHECK_FUNCS([gethostbyname memset putenv strcasecmp strchr strdup strerror])
  31
  32 #
  33 # kerberos5 enviroment
  34 #
  35 krb5_config_command=krb5-config
  36 SPNEGO_SRCS=""
  37
  38 AC_ARG_WITH(krb5,
  39   AC_HELP_STRING([--with-krb5=dir],[use krb5 in dir]),
  40   [ with_krb5="$withval" ])
  41
  42 if test "x$with_krb5" != "xno" ; then
  43   ac_save_CPPFLAGS="$CPPFLAGS"
  44   ac_save_LDFLAGS="$LDFLAGS"
  45   ac_save_LIBS="$LIBS"
  46
  47   if test -n "$with_krb5"; then
  48      if test -x "$with_krb5/bin/krb5-config"; then
  49         krb5_config_command="$with_krb5/bin/krb5-config"
  50      else
  51         krb5_config_command=""
  52      fi
  53   fi
  54
  55   dnl
  56   dnl find header files
  57   dnl
  58
  59   if test -z "$KRB5_CPPFLAGS"; then
  60      TMP_KRB5_CPPFLAGS=""
  61      if test -n "$krb5_config_command"; then
  62         TMP_KRB5_CPPFLAGS=`$krb5_config_command --cflags gssapi 2>/dev/null`
  63      fi
  64      if test -z "$TMP_KRB5_CPPFLAGS"; then
  65         TMP_KRB5_CPPFLAGS="-I$with_krb5/include"
  66      fi
  67      CPPFLAGS="$CPPFLAGS $TMP_KRB5_CPPFLAGS"
  68      AC_CHECK_HEADERS(gssapi.h,
  69                       [ KRB5_CPPFLAGS="$TMP_KRB5_CPPFLAGS" ])
  70      if test -z "$KRB5_CPPFLAGS"; then
  71         AC_CHECK_HEADERS(gssapi/gssapi.h,
  72                          [ KRB5_CPPFLAGS="$TMP_KRB5_CPPFLAGS" ])
  73      fi
  74      CPPFLAGS="$ac_save_CPPFLAGS"
  75   fi
  76
  77   dnl
  78   dnl find libraries
  79   dnl
  80
  81   if test -z "$KRB5_LDFLAGS" -a -n "$krb5_config_command"; then
  82      TMP_KRB5_LDFLAGS=`$krb5_config_command --libs gssapi 2>/dev/null`
  83      if test -n "$TMP_KRB5_LDFLAGS"; then
  84         LIBS="$LIBS $TMP_KRB5_LDFLAGS $LIB_resolv"
  85         AC_CHECK_LIB(krb5, krb5_init_context,
  86                      [ KRB5_LDFLAGS="$TMP_KRB5_LDFLAGS" ])
  87         LIBS="$ac_save_LIBS"
  88      fi
  89   fi
  90
  91   if test -z "$KRB5_LDFLAGS"; then
  92      #try MIT
  93      TMP_KRB5_LDFLAGS="-L$with_krb5/lib -lgssapi_krb5 -lkrb5 -lk5crypto -lcom_err"
  94      LIBS="$LIBS $TMP_KRB5_LDFLAGS $LIB_resolv"
  95      AC_CHECK_LIB(krb5, krb5_init_context, [ KRB5_LDFLAGS="$TMP_KRB5_LDFLAGS" ])
  96      LIBS="$ac_save_LIBS"
  97   fi
  98
  99   if test -z "$KRB5_LDFLAGS"; then
 100      #Try Heimdal
 101      TMP_KRB5_LDFLAGS="-L$with_krb5/lib -lgssapi -lkrb5 -lasn1 -lcrypto -lroken -lcrypt"
 102      LIBS="$LIBS $TMP_KRB5_LDFLAGS $LIB_resolv"
 103      AC_CHECK_LIB(krb5, krb5_init_context, [ KRB5_LDFLAGS="$TMP_KRB5_LDFLAGS" ])
 104      LIBS="$ac_save_LIBS"
 105   fi
 106
 107   if test -z "$KRB5_LDFLAGS"; then
 108      #Try Heimdal on OpenBSD
 109      TMP_KRB5_LDFLAGS="-L$with_krb5/lib -lgssapi -lkrb5 -lasn1 -ldes -lcrypto"
 110      LIBS="$LIBS $TMP_KRB5_LDFLAGS $LIB_resolv"
 111      AC_CHECK_LIB(krb5, krb5_init_context, [ KRB5_LDFLAGS="$TMP_KRB5_LDFLAGS" ])
 112      LIBS="$ac_save_LIBS"
 113   fi
 114
 115   if test -z "$KRB5_LDFLAGS"; then
 116      with_krb5=no
 117   else
 118      with_krb5=yes
 119      AC_DEFINE(KRB5)
 120
 121      # check for Heimdal
 122      have_heimdal=""
 123      AC_MSG_CHECKING(whether we are using Heimdal)
 124      ac_save_CFLAGS="$CFLAGS"
 125      CFLAGS="$KRB5_CPPFLAGS"
 126      AC_TRY_COMPILE([#include <krb5.h>],
 127                     [ char *tmp = heimdal_version; ],
 128                     [ AC_MSG_RESULT(yes)
 129                       AC_DEFINE(HEIMDAL)
 130                       have_heimdal=yes ],
 131                     [ AC_MSG_RESULT(no) ])
 132      CFLAGS="$ac_save_CFLAGS"
 133
 134 # If SPNEGO is supported by the gssapi libraries, we shouln't build our support.
 135 # SPNEGO is supported as of Heimdal 0.7, and MIT 1.5.
 136      gssapi_supports_spnego=""
 137      AC_MSG_CHECKING(whether the GSSAPI libraries support SPNEGO)
 138
 139      ac_save_CFLAGS="$CFLAGS"
 140      CFLAGS="$KRB5_CPPFLAGS"
 141      ac_save_LDFLAGS="$LDFLAGS"
 142      LDFLAGS=$KRB5_LDFLAGS
 143
 144      AC_TRY_RUN([
 145 #include <string.h>
 146 #include <krb5.h>
 147 #ifdef HEIMDAL
 148 #include <gssapi.h>
 149 #else
 150 #include <gssapi/gssapi.h>
 151 #endif
 152 int main(int argc, char** argv)
 153 {
 154        OM_uint32 major_status, minor_status;
 155        gss_OID_set mech_set;
 156        gss_OID_desc spnego_oid_desc = {6, (void *)"\x2b\x06\x01\x05\x05\x02"};
 157        int SPNEGO = 0;
 158
 159        major_status = gss_indicate_mechs(&minor_status, &mech_set);
 160        if (GSS_ERROR(major_status))
 161                return 1;
 162        else {
 163                unsigned int i;
 164                for (i=0; i < mech_set->count && !SPNEGO; i++) {
 165                        gss_OID tmp_oid = &mech_set->elements[i];
 166                       if (tmp_oid->length == spnego_oid_desc.length &&
 167                            !memcmp(tmp_oid->elements, spnego_oid_desc.elements,
 168                                    tmp_oid->length)) {
 169                                SPNEGO = 1;
 170                                break;
 171                        }
 172                }
 173                gss_release_oid_set(&minor_status, &mech_set);
 174                return (!SPNEGO);
 175        }
 176 }],
 177                 [ if test $? -eq 0; then
 178                      AC_MSG_RESULT(yes)
 179                      AC_DEFINE(GSSAPI_SUPPORTS_SPNEGO)
 180                      gssapi_supports_spnego=yes
 181                   else
 182                      AC_MSG_RESULT(no)
 183                   fi],
 184                 [AC_MSG_RESULT(no)])
 185
 186      CFLAGS="$ac_save_CFLAGS"
 187      LDFLAGS="$ac_save_LDFLAGS"
 188
 189      if test -z "$gssapi_supports_spnego"; then
 190         if test -n "$have_heimdal"; then SPNEGO_SRCS="\
 191                 spnegokrb5/asn1_MechType.c         \
 192                 spnegokrb5/asn1_MechTypeList.c     \
 193                 spnegokrb5/asn1_ContextFlags.c     \
 194                 spnegokrb5/asn1_NegTokenInit.c     \
 195                 spnegokrb5/asn1_NegTokenTarg.c     \
 196                 spnegokrb5/init_sec_context.c      \
 197                 spnegokrb5/accept_sec_context.c    \
 198                 spnegokrb5/encapsulate.c           \
 199                 spnegokrb5/decapsulate.c           \
 200                 spnegokrb5/external.c"
 201         else SPNEGO_SRCS="\
 202                 spnegokrb5/asn1_MechType.c         \
 203                 spnegokrb5/asn1_MechTypeList.c     \
 204                 spnegokrb5/asn1_ContextFlags.c     \
 205                 spnegokrb5/asn1_NegTokenInit.c     \
 206                 spnegokrb5/asn1_NegTokenTarg.c     \
 207                 spnegokrb5/der_get.c               \
 208                 spnegokrb5/der_put.c               \
 209                 spnegokrb5/der_free.c              \
 210                 spnegokrb5/der_length.c            \
 211                 spnegokrb5/der_copy.c              \
 212                 spnegokrb5/timegm.c                \
 213                 spnegokrb5/init_sec_context.c      \
 214                 spnegokrb5/accept_sec_context.c    \
 215                 spnegokrb5/encapsulate.c           \
 216                 spnegokrb5/decapsulate.c           \
 217                 spnegokrb5/external.c"
 218         fi
 219      fi
 220   fi
 221 fi
 222 AC_SUBST(KRB5_CPPFLAGS)
 223 AC_SUBST(KRB5_LDFLAGS)
 224 AC_SUBST(SPNEGO_SRCS)
 225
 226 #
 227 # Kerberos4 enviroment
 228 #
 229
 230 AC_ARG_WITH(krb4,
 231   AC_HELP_STRING([--with-krb4=dir], [use krb4 in dir]),
 232   [ with_krb4="$withval" ])
 233
 234 if test "x$with_krb4" != "xno"; then
 235   AC_MSG_CHECKING([for Kerberos4 installation])
 236   if test "x$with_krb4" != "x"; then
 237      if test -x "$with_krb4/bin/krb4-config"; then
 238         KRB4_CPPFLAGS=`$with_krb4/bin/krb4-config --cflags krb4 2>/dev/null`
 239         KRB4_LDFLAGS=`$with_krb4/bin/krb4-config --libs krb4 2>/dev/null`
 240      elif test -x "$with_krb4/bin/krb5-config"; then
 241         KRB4_CPPFLAGS=`$with_krb4/bin/krb5-config --cflags krb4 2>/dev/null`
 242         KRB4_LDFLAGS=`$with_krb4/bin/krb5-config --libs krb4 2>/dev/null`
 243      else
 244         AC_MSG_ERROR([failed to find krb4-config or krb5-config in $with_krb4/bin])
 245      fi
 246   else
 247      KRB4_CPPFLAGS=`krb4-config --cflags krb4 2>/dev/null`
 248      KRB4_LDFLAGS=`krb4-config --libs krb4 2>/dev/null`
 249      if test "x$KRB4_LDFLAGS" = "x" -a -n "$krb5_config_command"; then
 250         KRB4_CPPFLAGS=`$krb5_config_command --cflags krb4 2>/dev/null`
 251         KRB4_LDFLAGS=`$krb5_config_command --libs krb4 2>/dev/null`
 252         if test $? -ne 0; then
 253            KRB4_CPPFLAGS=""
 254            KRB4_LDFLAGS=""
 255         fi
 256      fi
 257   fi
 258   if test "x$KRB4_LDFLAGS" = "x"; then
 259      with_krb4=no
 260      AC_MSG_RESULT(no)
 261   else
 262      AC_MSG_RESULT(yes)
 263
 264      ac_save_CFLAGS=$CFLAGS
 265      ac_save_CPPFLAGS=$CPPFLAGS
 266      ac_save_LDFLAGS=$LDFLAGS
 267      ac_save_LIBS=$LIBS
 268      CFLAGS="$CFLAGS $KRB4_CPPFLAGS"
 269      CPPFLAGS="$CFLAGS $KRB4_CPPFLAGS"
 270      LDFLAGS="$LDFLAGS $KRB4_LDFLAGS"
 271      LIBS="$LIBS $LDFLAGS $LIB_resolv"
 272
 273 #    if not found krb.h suppose it's in the kerberosIV subdirectory
 274      AC_CHECK_HEADER(krb.h, , with_krb4=no)
 275      if test "x$with_krb4" = "xno"; then
 276          KRB4_CPPFLAGS="$KRB4_CPPFLAGS ${KRB4_CPPFLAGS}/kerberosIV"
 277 #        second run of AC_CHECK_HEADER for the same library returns the cached
 278 #        result created by previous run :-(
 279          AC_CHECK_HEADER(kerberosIV/krb.h, with_krb4=yes,
 280                          [  with_krb4=no
 281                             KRB4_CPPFLAGS=""
 282                             KRB4_LDFLAGS=""])
 283      fi
 284
 285      if test "x$with_krb4" != "xno"; then
 286         AC_CHECK_LIB(krb4, krb_get_pw_in_tkt, [], [with_krb4=no])
 287         if test "x$with_krb4" = "xno"; then
 288            AC_CHECK_LIB(krb, krb_get_pw_in_tkt, [with_krb4=yes],
 289                         [with_krb4=no
 290                          KRB4_CPPFLAGS=""
 291                          KRB4_LDFLAGS=""])
 292         fi
 293      fi
 294
 295      CFLAGS=$ac_save_CFLAGS
 296      CPPFLAGS=$ac_save_CPPFLAGS
 297      LDFLAGS=$ac_save_LDFLAGS
 298      LIBS=$ac_save_LIBS
 299
 300      AC_DEFINE(KRB4)
 301   fi
 302 fi
 303 AC_SUBST(KRB4_CPPFLAGS)
 304 AC_SUBST(KRB4_LDFLAGS)
 305
 306
 307 if test "x$with_krb5" = "xno" -a "x$with_krb4" = "xno"; then
 308   AC_MSG_ERROR([No Kerberos enviroment found])
 309 fi
 310
 311 #
 312 # Apache enviroment
 313 #
 314 AC_ARG_WITH(apache,
 315   AC_HELP_STRING([--with-apache=dir],[use apache in dir]),
 316   [ with_apache="$withval" ])
 317
 318 AC_PATH_PROG([APXS], [apxs], [], [$with_apache/bin:$with_apache/sbin:$PATH])
 319 if test -z "$APXS"; then
 320    AC_PATH_PROG([APXS], [apxs2], [], [$with_apache/bin:$with_apache/sbin:$PATH])
 321    if test -z "$APXS"; then
 322       AC_MSG_ERROR([failed to find apache apxs executable])
 323    fi
 324 fi
 325 AC_SUBST(APXS)
 326
 327 AC_CONFIG_FILES([Makefile])
 328
 329 AC_OUTPUT