configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 AC_REVISION($Revision$)
   3 AC_PREREQ(2.53)
   4 AC_INIT(mod_auth_kerb, 0.5-rc3, modauthkerb-developers@lists.sourceforge.net)
   5 AC_CONFIG_SRCDIR([src/mod_auth_kerb.c])
   6 AC_CONFIG_HEADER([config.h])
   7
   8 # Checks for programs.
   9 AC_PROG_CC
  10 AC_PROG_MAKE_SET
  11
  12 # Checks for libraries.
  13 # FIXME: Replace `main' with a function in `-lresolv':
  14 LIB_resolv=""
  15 AC_CHECK_LIB([resolv], [main], [LIB_resolv=-lresolv])
  16 AC_SUBST(LIB_resolv)
  17
  18 # Checks for header files.
  19 AC_HEADER_STDC
  20 AC_CHECK_HEADERS([limits.h netdb.h stddef.h stdlib.h string.h unistd.h])
  21
  22 # Checks for typedefs, structures, and compiler characteristics.
  23 #AC_C_CONST
  24 AC_TYPE_SIZE_T
  25 AC_STRUCT_TM
  26
  27 # Checks for library functions.
  28 #AC_FUNC_MALLOC
  29 #AC_FUNC_MEMCMP
  30 #AC_CHECK_FUNCS([gethostbyname memset putenv strcasecmp strchr strdup strerror])
  31
  32 #
  33 # kerberos5 enviroment
  34 #
  35 KRB5_CPPFLAGS=""
  36 KRB5_LDFLAGS=""
  37 krb5_config_command=krb5-config
  38 DO_KRB5=
  39
  40 AC_ARG_WITH(krb5,
  41   AC_HELP_STRING([--with-krb5=dir],[use krb5 in dir]),
  42   [ with_krb5="$withval" ])
  43
  44 if test "x$with_krb5" != "xno" ; then
  45   AC_MSG_CHECKING([for Kerberos5 installation])
  46   if test "x$with_krb5" != "x"; then
  47      if test ! -x "$with_krb5/bin/krb5-config"; then
  48         AC_MSG_ERROR([failed to find krb5-config in $with_krb5/bin])
  49      fi
  50      krb5_config_command="$with_krb5/bin/krb5-config"
  51   fi
  52
  53   KRB5_CPPFLAGS=`$krb5_config_command --cflags gssapi 2>/dev/null`
  54   KRB5_LDFLAGS=`$krb5_config_command --libs gssapi 2>/dev/null`
  55   if test "x$KRB5_LDFLAGS" = "x"; then
  56      with_krb5=no
  57      AC_MSG_RESULT(no)
  58   else
  59      AC_MSG_RESULT(yes)
  60
  61      ac_save_CFLAGS=$CFLAGS
  62      ac_save_LDFLAGS=$LDFLAGS
  63      ac_save_LIBS=$LIBS
  64      CFLAGS="$CFLAGS $KRB5_CPPFLAGS"
  65      LDFLAGS="$LDFLAGS $KRB5_LDFLAGS"
  66      LIBS="$LIBS $LDFLAGS $LIB_resolv"
  67
  68      AC_CHECK_LIB(krb5, krb5_init_context, [], [with_krb5=no])
  69
  70      if test "x$with_krb5" != "xno"; then
  71         # check if krb5_cc_gen_new() is implemented by the krb5 library
  72         AC_CHECK_FUNC(krb5_cc_gen_new, [AC_DEFINE(HAVE_KRB5_CC_GEN_NEW)])
  73
  74         # check for Heimdal
  75         AC_MSG_CHECKING(whether we are using Heimdal)
  76         AC_TRY_COMPILE([#include <krb5.h>],
  77                        [ char *tmp = heimdal_version; ],
  78                        [ AC_MSG_RESULT(yes)
  79                          AC_DEFINE(HEIMDAL) ],
  80                        [ AC_MSG_RESULT(no) ])
  81      fi
  82
  83      CFLAGS=$ac_save_CFLAGS
  84      LDFLAGS=$ac_save_LDFLAGS
  85      LIBS=$ac_save_LIBS
  86      AC_DEFINE(KRB5)
  87      DO_KRB5=yes
  88   fi
  89 fi
  90 AC_SUBST(KRB5_CPPFLAGS)
  91 AC_SUBST(KRB5_LDFLAGS)
  92 AC_SUBST(DO_KRB5)
  93
  94 #
  95 # Kerberos4 enviroment
  96 #
  97 KRB4_CPPFLAGS=""
  98 KRB4_LDFLAGS=""
  99
 100 AC_ARG_WITH(krb4,
 101   AC_HELP_STRING([--with-krb4=dir], [use krb4 in dir]),
 102   [ with_krb4="$withval" ])
 103
 104 if test "x$with_krb4" != "xno"; then
 105   AC_MSG_CHECKING([for Kerberos4 installation])
 106   if test "x$with_krb4" != "x"; then
 107      if test -x "$with_krb4/bin/krb4-config"; then
 108         KRB4_CPPFLAGS=`$with_krb4/bin/krb4-config --cflags krb4 2>/dev/null`
 109         KRB4_LDFLAGS=`$with_krb4/bin/krb4-config --libs krb4 2>/dev/null`
 110      elif test -x "$with_krb4/bin/krb5-config"; then
 111         KRB4_CPPFLAGS=`$with_krb4/bin/krb5-config --cflags krb4 2>/dev/null`
 112         KRB4_LDFLAGS=`$with_krb4/bin/krb5-config --libs krb4 2>/dev/null`
 113      else
 114         AC_MSG_ERROR([failed to find krb4-config or krb5-config in $with_krb4/bin])
 115      fi
 116   else
 117      KRB4_CPPFLAGS=`krb4-config --cflags krb4 2>/dev/null`
 118      KRB4_LDFLAGS=`krb4-config --libs krb4 2>/dev/null`
 119      if test "x$KRB4_LDFLAGS" = "x"; then
 120         KRB4_CPPFLAGS=`$krb5_config_command --cflags krb4 2>/dev/null`
 121         KRB4_LDFLAGS=`$krb5_config_command --libs krb4 2>/dev/null`
 122         if test $? -ne 0; then
 123            KRB4_CPPFLAGS=""
 124            KRB4_LDFLAGS=""
 125         fi
 126      fi
 127   fi
 128   if test "x$KRB4_LDFLAGS" = "x"; then
 129      with_krb4=no
 130      AC_MSG_RESULT(no)
 131   else
 132      AC_MSG_RESULT(yes)
 133
 134      ac_save_CFLAGS=$CFLAGS
 135      ac_save_CPPFLAGS=$CPPFLAGS
 136      ac_save_LDFLAGS=$LDFLAGS
 137      ac_save_LIBS=$LIBS
 138      CFLAGS="$CFLAGS $KRB4_CPPFLAGS"
 139      CPPFLAGS="$CFLAGS $KRB4_CPPFLAGS"
 140      LDFLAGS="$LDFLAGS $KRB4_LDFLAGS"
 141      LIBS="$LIBS $LDFLAGS $LIB_resolv"
 142
 143 #    if not found krb.h suppose it's in the kerberosIV subdirectory
 144      AC_CHECK_HEADER(krb.h, , with_krb4=no)
 145      if test "x$with_krb4" = "xno"; then
 146          KRB4_CPPFLAGS="$KRB4_CPPFLAGS ${KRB4_CPPFLAGS}/kerberosIV"
 147 #        second run of AC_CHECK_HEADER for the same library returns the cached
 148 #        result created by previous run :-(
 149          AC_CHECK_HEADER(kerberosIV/krb.h, with_krb4=yes,
 150                          [  with_krb4=no
 151                             KRB4_CPPFLAGS=""
 152                             KRB4_LDFLAGS=""])
 153      fi
 154
 155      if test "x$with_krb4" != "xno"; then
 156         AC_CHECK_LIB(krb4, krb_get_pw_in_tkt, [], [with_krb4=no])
 157         if test "x$with_krb4" = "xno"; then
 158            AC_CHECK_LIB(krb, krb_get_pw_in_tkt, [with_krb4=yes],
 159                         [with_krb4=no
 160                          KRB4_CPPFLAGS=""
 161                          KRB4_LDFLAGS=""])
 162         fi
 163      fi
 164
 165      CFLAGS=$ac_save_CFLAGS
 166      CPPFLAGS=$ac_save_CPPFLAGS
 167      LDFLAGS=$ac_save_LDFLAGS
 168      LIBS=$ac_save_LIBS
 169
 170      AC_DEFINE(KRB4)
 171   fi
 172 fi
 173 AC_SUBST(KRB4_CPPFLAGS)
 174 AC_SUBST(KRB4_LDFLAGS)
 175
 176
 177 if test "x$with_krb5" = "xno" -a "x$with_krb4" = "xno"; then
 178   AC_MSG_ERROR([No Kerberos enviroment found])
 179 fi
 180
 181 #
 182 # Apache enviroment
 183 #
 184 AC_ARG_WITH(apache,
 185   AC_HELP_STRING([--with-apache=dir],[use apache in dir]),
 186   [ with_apache="$withval" ])
 187
 188 AC_MSG_CHECKING([for Apache installation])
 189
 190 APXS="apxs"
 191 HTTPD="httpd"
 192 if test "x$with_apache" != "x"; then
 193   if test ! -x "$with_apache/bin/httpd" -o ! -x "$with_apache/bin/apxs"; then
 194      AC_MSG_ERROR([failed to find apache files in $with_apache])
 195   fi
 196   APXS="$with_apache/bin/apxs"
 197   if test ! -x $APXS; then
 198      APXS="$with_apache/sbin/apxs"
 199   fi
 200   HTTPD="$with_apache/bin/httpd"
 201   if test ! -x $HTTPD; then
 202      HTTPD"$with_apache/sbin/httpd"
 203   fi
 204 fi
 205
 206 apache_v1_3=`$HTTPD -v | grep "^Server version: Apache/1.3."`
 207 apache_v2_0=`$HTTPD -v | grep "^Server version: Apache/2.0."`
 208 if test "x$apache_v1_3" = "x" -a "x$apache_v2_0" = "x"; then
 209   AC_MSG_ERROR([cannot find valid apache installation on your system])
 210 fi
 211 if test -n "$apache_v1_3"; then
 212   AC_DEFINE(APXS1)
 213 fi
 214 AC_MSG_RESULT(yes)
 215
 216 AC_SUBST(APXS)
 217
 218 AC_CONFIG_FILES([Makefile
 219                  spnegokrb5/Makefile])
 220
 221 AC_OUTPUT