configure.ac

   1 AC_PREREQ([2.66])
   2 AC_INIT([Moonshot],
   3         [0.0.1],
   4         [BUG-REPORT-ADDRESS],
   5         [moonshot])
   6
   7 AC_CONFIG_HEADERS([config.h])
   8 AC_CONFIG_SRCDIR([configure.ac])
   9 AC_CONFIG_MACRO_DIR([m4])
  10 AC_CONFIG_AUX_DIR([build-aux])
  11
  12 AM_INIT_AUTOMAKE([1.11 -Wall foreign subdir-objects tar-pax no-dist-gzip dist-xz])
  13 AM_SILENT_RULES([yes])
  14 AM_MAINTAINER_MODE([enable])
  15
  16 LT_PREREQ([2.2])
  17 LT_INIT([win32-dll])
  18
  19 PKG_PROG_PKG_CONFIG([0.24])
  20
  21 # Platform checks
  22 AC_CANONICAL_HOST
  23
  24 case "$host" in
  25   *-*-mingw*)
  26     win32=yes
  27     SERVER_IPC_MODULE="msrpc-glib2-1.0"
  28     CLIENT_IPC_MODULE="msrpc-mingw-1.0"
  29     ;;
  30   *)
  31     win32=no
  32     SERVER_IPC_MODULE="dbus-glib-1"
  33     CLIENT_IPC_MODULE="dbus-glib-1"
  34     ;;
  35 esac
  36
  37 AM_CONDITIONAL([OS_LINUX], [test "$win32" != "yes"])
  38 AM_CONDITIONAL([OS_WIN32], [test "$win32" = "yes"])
  39 AM_CONDITIONAL([IPC_MSRPC], [test "$SERVER_IPC_MODULE" = "msrpc-glib2-1.0"])
  40 AM_CONDITIONAL([IPC_DBUS], [test "$SERVER_IPC_MODULE" = "dbus-glib-1"])
  41
  42 # Checks for programs.
  43 AC_PROG_CC
  44 AM_PROG_CC_C_O
  45 AM_PROG_VALAC([0.9])
  46
  47 if test "$SERVER_IPC_MODULE" = "msrpc-glib2-1.0"; then
  48   # MS RPC utilities
  49   AC_PATH_MSRPC_MINGW([0.1.0], :,
  50     AC_MSG_ERROR([
  51 *** msrpc-mingw 0.1.0 or better is required.]))
  52
  53   AC_PATH_PROG([MIDL], [midl], no,
  54                [/c/Program\ Files/Microsoft\ SDKs/Windows/v7.0/Bin$PATH_SEPARATOR$PATH])
  55   if test "$MIDL" = "no"; then
  56      AC_MSG_ERROR([
  57 *** Could not find the Microsoft interface compiler MIDL.EXE.
  58 *** This program is available as part of the MS Windows SDK, in
  59 *** the Win32 Development Tools package. If it is not in the PATH
  60 *** or its default location you may set the 'MIDL' environment
  61 *** variable to point to its location and rerun configure.])
  62   fi
  63 fi
  64
  65 if test "$win32" = "yes"; then
  66   # Other Windows-specific tools
  67
  68   # LIB.EXE from MSVC to build an MSVC-compatible import library.
  69   AC_PATH_PROG([MSVC_LIB], [lib], no)
  70
  71   if test "$MSVC_LIB" = "no"; then
  72      AC_MSG_WARN([
  73 *** Could not find the Microsoft 'LIB.EXE' program. This is required
  74 *** to build the Visual C import library for libmoonshot. Use the
  75 *** MSVC_LIB environment variable to pass its location if this is
  76 *** outside the PATH.])
  77   fi
  78
  79
  80   # ImageMagick for the 'make icons' target. Watch that it doesn't pick up
  81   # c:/windows/system32/convert.exe, which is nothing to do with ImageMagick
  82   AC_PATH_PROG([IMAGEMAGICK_CONVERT], [convert], no,
  83                [/c/Program\ Files/ImageMagick$PATH_SEPARATOR$PATH])
  84
  85   if test "$IMAGEMAGICK_CONVERT" = "no"; then
  86      AC_MSG_WARN([
  87 *** Could not find ImageMagick convert.exe. This is required for the
  88 *** 'make icons' target. Use the IMAGEMAGICK_CONVERT environment
  89 *** variable to pass its location if this is outside the PATH.])
  90   fi
  91
  92
  93   # Windows Installer XML tools
  94   AC_PATH_PROG([WIX_CANDLE], [candle], no,
  95                [/c/Program\ Files/Windows\ Installer\ XML\ v3.5/bin$PATH_SEPARATOR$PATH])
  96   AC_PATH_PROG([WIX_LIGHT], [light], no,
  97                [/c/Program\ Files/Windows\ Installer\ XML\ v3.5/bin$PATH_SEPARATOR$PATH])
  98
  99   if test "$WIX_CANDLE" = "no" || test "$WIX_LIGHT" = "no"; then
 100      AC_MSG_WARN([
 101 *** Could not find the Windows Installer XML tools. These are required
 102 *** for the 'make installer' target. Use the WIX_CANDLE and WIX_LIGHT
 103 *** environment variables to pass their locations if they are outside
 104 *** the PATH.])
 105   fi
 106 fi
 107
 108 if test "$win32" != "yes"; then
 109   AC_PATH_PROG([UPDATE_MIME_DATABASE], [update-mime-database], [no])
 110   if test "$UPDATE_MIME_DATABASE" = "no"; then
 111     AC_MSG_ERROR([
 112 *** Could not find the Freedesktop.org  mime database update tool.
 113 *** Web provisioning files could not be automatically installed.])
 114   fi
 115   AC_PATH_PROG([UPDATE_DESKTOP_DATABASE], [update-desktop-database], [no])
 116   if test "$UPDATE_DESKTOP_DATABASE" = "no"; then
 117     AC_MSG_ERROR([
 118 *** Could not find the Freedesktop.org desktop entry database update
 119 *** tool. Web provisioning files could not be automatically installed.])
 120   fi
 121 fi
 122
 123 MOONSHOT_APP="$bindir/moonshot"
 124 MOONSHOT_WEBP="$bindir/moonshot-webp"
 125
 126 AC_SUBST(MIDL)
 127 AC_SUBST(MSVC_LIB)
 128 AC_SUBST(IMAGEMAGICK_CONVERT)
 129 AC_SUBST(WIX_CANDLE)
 130 AC_SUBST(WIX_LIGHT)
 131 AC_SUBST(UPDATE_MIME_DATABASE)
 132 AC_SUBST(UPDATE_DESKTOP_DATABASE)
 133 AC_SUBST(MOONSHOT_APP)
 134 AC_SUBST(MOONSHOT_WEBP)
 135
 136 # Dependencies
 137 PKG_CHECK_MODULES(moonshot,[
 138         atk >= 1.20
 139         glib-2.0 >= 2.24
 140         gobject-2.0 >= 2.24
 141         gtk+-2.0 >= 2.20
 142         $SERVER_IPC_MODULE
 143 ])
 144
 145 PKG_CHECK_MODULES(libmoonshot,[
 146         $CLIENT_IPC_MODULE
 147 ])
 148
 149 # i18n stuff
 150 AM_GNU_GETTEXT([external])
 151 AM_GNU_GETTEXT_VERSION([0.17])
 152
 153 AC_SUBST([GETTEXT_PACKAGE],[PACKAGE_TARNAME])
 154 AC_DEFINE([GETTEXT_PACKAGE],[PACKAGE_TARNAME],[Define to the gettext package name.])
 155
 156 AC_CONFIG_FILES([
 157         Makefile
 158         po/Makefile.in
 159         moonshot.desktop
 160         moonshot-webp.desktop
 161 ])
 162
 163 AC_OUTPUT