configure.ac

   1 AC_PREREQ([2.66])
   2 AC_INIT([Moonshot],
   3         [0.0.1],
   4         [BUG-REPORT-ADDRESS],
   5         [moonshot])
   6
   7 AC_CONFIG_HEADERS([config.h])
   8 AC_CONFIG_SRCDIR([configure.ac])
   9 AC_CONFIG_MACRO_DIR([m4])
  10 AC_CONFIG_AUX_DIR([build-aux])
  11
  12 AM_INIT_AUTOMAKE([1.11 -Wall foreign subdir-objects tar-pax no-dist-gzip dist-xz])
  13 AM_SILENT_RULES([yes])
  14 AM_MAINTAINER_MODE([enable])
  15
  16 LT_PREREQ([2.2])
  17 LT_INIT([win32-dll])
  18
  19 PKG_PROG_PKG_CONFIG([0.24])
  20
  21 # Platform checks
  22 AC_CANONICAL_HOST
  23
  24 case "$host" in
  25   *-*-mingw*)
  26     win32=yes
  27     IPC_MODULE="msrpc-glib2-1.0"
  28     ;;
  29   *)
  30     win32=no
  31     IPC_MODULE="dbus-glib-1"
  32     ;;
  33 esac
  34
  35 AM_CONDITIONAL([OS_WIN32], [test "$win32" = "yes"])
  36 AM_CONDITIONAL([IPC_MSRPC], [test "$IPC_MODULE" = "msrpc-glib2-1.0"])
  37 AM_CONDITIONAL([IPC_DBUS], [test "$IPC_MODULE" = "dbus-glib-1"])
  38
  39 # Checks for programs.
  40 AC_PROG_CC
  41 AM_PROG_CC_C_O
  42 AM_PROG_VALAC([0.9])
  43
  44 if test "$IPC_MODULE" = "msrpc-glib2-1.0"; then
  45   # MS RPC utilities
  46   AC_PATH_MSRPC_MINGW([0.1.0], :,
  47     AC_MSG_ERROR([
  48 *** msrpc-mingw 0.1.0 or better is required.]))
  49
  50   AC_PATH_PROG([MIDL], [midl], no,
  51                [/c/Program\ Files/Microsoft\ SDKs/Windows/v7.0/Bin$PATH_SEPARATOR$PATH])
  52   if test "$MIDL" = "no"; then
  53      AC_MSG_ERROR([
  54 *** Could not find the Microsoft interface compiler MIDL.EXE.
  55 *** This program is available as part of the MS Windows SDK, in
  56 *** the Win32 Development Tools package. If it is not in the PATH
  57 *** or its default location you may set the 'MIDL' environment
  58 *** variable to point to its location and rerun configure.])
  59   fi
  60 fi
  61
  62 if test "$win32" = "yes"; then
  63   # Other Windows-specific tools
  64
  65   # ImageMagick for the 'make icons' target. Watch that it doesn't pick up
  66   # c:/windows/system32/convert.exe, which is nothing to do with ImageMagick
  67   AC_PATH_PROG([IMAGEMAGICK_CONVERT], [convert], ,
  68                [/c/Program\ Files/ImageMagick$PATH_SEPARATOR$PATH])
  69
  70   # Windows Installer XML tools
  71   AC_PATH_PROG([WIX_CANDLE], [candle], ,
  72                [/c/Program\ Files/Windows\ Installer\ XML\ v3.5/bin$PATH_SEPARATOR$PATH])
  73   AC_PATH_PROG([WIX_LIGHT], [light], ,
  74                [/c/Program\ Files/Windows\ Installer\ XML\ v3.5/bin$PATH_SEPARATOR$PATH])
  75 fi
  76
  77 AC_SUBST(MIDL)
  78 AC_SUBST(IMAGEMAGICK_CONVERT)
  79 AC_SUBST(WIX_CANDLE)
  80 AC_SUBST(WIX_LIGHT)
  81
  82 # Dependencies
  83 PKG_CHECK_MODULES(moonshot,[
  84         atk >= 1.20
  85         glib-2.0 >= 2.24
  86         gobject-2.0 >= 2.24
  87         gtk+-2.0 >= 2.20
  88         $IPC_MODULE
  89 ])
  90
  91 PKG_CHECK_MODULES(libmoonshot,[
  92         $IPC_MODULE
  93 ])
  94
  95 # i18n stuff
  96 AM_GNU_GETTEXT([external])
  97 AM_GNU_GETTEXT_VERSION([0.17])
  98
  99 AC_SUBST([GETTEXT_PACKAGE],[PACKAGE_TARNAME])
 100 AC_DEFINE([GETTEXT_PACKAGE],[PACKAGE_TARNAME],[Define to the gettext package name.])
 101
 102 AC_CONFIG_FILES([
 103         Makefile
 104         po/Makefile.in
 105 ])
 106
 107 AC_OUTPUT