configure.ac

   1 AC_PREREQ([2.66])
   2 AC_INIT([Moonshot],
   3         [0.0.1],
   4         [BUG-REPORT-ADDRESS],
   5         [moonshot])
   6
   7 AC_CONFIG_HEADERS([config.h])
   8 AC_CONFIG_SRCDIR([configure.ac])
   9 AC_CONFIG_MACRO_DIR([m4])
  10 AC_CONFIG_AUX_DIR([build-aux])
  11
  12 AM_INIT_AUTOMAKE([1.11 -Wall foreign subdir-objects tar-pax no-dist-gzip dist-xz])
  13 AM_SILENT_RULES([yes])
  14 AM_MAINTAINER_MODE([enable])
  15
  16 LT_PREREQ([2.2])
  17 LT_INIT([win32-dll])
  18
  19 PKG_PROG_PKG_CONFIG([0.24])
  20
  21 # Platform checks
  22 AC_CANONICAL_HOST
  23
  24 case "$host" in
  25   *-*-mingw*)
  26     win32=yes
  27     SERVER_IPC_MODULE="msrpc-glib2-1.0"
  28     CLIENT_IPC_MODULE="msrpc-mingw-1.0"
  29     ;;
  30   *)
  31     win32=no
  32     SERVER_IPC_MODULE="dbus-glib-1"
  33     CLIENT_IPC_MODULE="dbus-glib-1"
  34     ;;
  35 esac
  36
  37 AM_CONDITIONAL([OS_WIN32], [test "$win32" = "yes"])
  38 AM_CONDITIONAL([IPC_MSRPC], [test "$SERVER_IPC_MODULE" = "msrpc-glib2-1.0"])
  39 AM_CONDITIONAL([IPC_DBUS], [test "$SERVER_IPC_MODULE" = "dbus-glib-1"])
  40
  41 # Checks for programs.
  42 AC_PROG_CC
  43 AM_PROG_CC_C_O
  44 AM_PROG_VALAC([0.9])
  45
  46 if test "$SERVER_IPC_MODULE" = "msrpc-glib2-1.0"; then
  47   # MS RPC utilities
  48   AC_PATH_MSRPC_MINGW([0.1.0], :,
  49     AC_MSG_ERROR([
  50 *** msrpc-mingw 0.1.0 or better is required.]))
  51
  52   AC_PATH_PROG([MIDL], [midl], no,
  53                [/c/Program\ Files/Microsoft\ SDKs/Windows/v7.0/Bin$PATH_SEPARATOR$PATH])
  54   if test "$MIDL" = "no"; then
  55      AC_MSG_ERROR([
  56 *** Could not find the Microsoft interface compiler MIDL.EXE.
  57 *** This program is available as part of the MS Windows SDK, in
  58 *** the Win32 Development Tools package. If it is not in the PATH
  59 *** or its default location you may set the 'MIDL' environment
  60 *** variable to point to its location and rerun configure.])
  61   fi
  62 fi
  63
  64 if test "$win32" = "yes"; then
  65   # Other Windows-specific tools
  66
  67   # LIB.EXE from MSVC to build an MSVC-compatible import library.
  68   AC_PATH_PROG([MSVC_LIB], [lib], no)
  69
  70   if test "$MSVC_LIB" = "no"; then
  71      AC_MSG_WARN([
  72 *** Could not find the Microsoft 'LIB.EXE' program. This is required
  73 *** to build the Visual C import library for libmoonshot. Use the
  74 *** MSVC_LIB environment variable to pass its location if this is
  75 *** outside the PATH.])
  76   fi
  77
  78
  79   # ImageMagick for the 'make icons' target. Watch that it doesn't pick up
  80   # c:/windows/system32/convert.exe, which is nothing to do with ImageMagick
  81   AC_PATH_PROG([IMAGEMAGICK_CONVERT], [convert], no,
  82                [/c/Program\ Files/ImageMagick$PATH_SEPARATOR$PATH])
  83
  84   if test "$IMAGEMAGICK_CONVERT" = "no"; then
  85      AC_MSG_WARN([
  86 *** Could not find ImageMagick convert.exe. This is required for the
  87 *** 'make icons' target. Use the IMAGEMAGICK_CONVERT environment
  88 *** variable to pass its location if this is outside the PATH.])
  89   fi
  90
  91
  92   # Windows Installer XML tools
  93   AC_PATH_PROG([WIX_CANDLE], [candle], no,
  94                [/c/Program\ Files/Windows\ Installer\ XML\ v3.5/bin$PATH_SEPARATOR$PATH])
  95   AC_PATH_PROG([WIX_LIGHT], [light], no,
  96                [/c/Program\ Files/Windows\ Installer\ XML\ v3.5/bin$PATH_SEPARATOR$PATH])
  97
  98   if test "$WIX_CANDLE" = "no" || test "$WIX_LIGHT" = "no"; then
  99      AC_MSG_WARN([
 100 *** Could not find the Windows Installer XML tools. These are required
 101 *** for the 'make installer' target. Use the WIX_CANDLE and WIX_LIGHT
 102 *** environment variables to pass their locations if they are outside
 103 *** the PATH.])
 104   fi
 105 fi
 106
 107 AC_SUBST(MIDL)
 108 AC_SUBST(MSVC_LIB)
 109 AC_SUBST(IMAGEMAGICK_CONVERT)
 110 AC_SUBST(WIX_CANDLE)
 111 AC_SUBST(WIX_LIGHT)
 112
 113 # Dependencies
 114 PKG_CHECK_MODULES(moonshot,[
 115         atk >= 1.20
 116         glib-2.0 >= 2.24
 117         gobject-2.0 >= 2.24
 118         gtk+-2.0 >= 2.20
 119         $SERVER_IPC_MODULE
 120 ])
 121
 122 PKG_CHECK_MODULES(libmoonshot,[
 123         $CLIENT_IPC_MODULE
 124 ])
 125
 126 # i18n stuff
 127 AM_GNU_GETTEXT([external])
 128 AM_GNU_GETTEXT_VERSION([0.17])
 129
 130 AC_SUBST([GETTEXT_PACKAGE],[PACKAGE_TARNAME])
 131 AC_DEFINE([GETTEXT_PACKAGE],[PACKAGE_TARNAME],[Define to the gettext package name.])
 132
 133 AC_CONFIG_FILES([
 134         Makefile
 135         po/Makefile.in
 136 ])
 137
 138 AC_OUTPUT